*                                                                       00000620
         GBLC  &LIB                     DEFINE GLOBAL CHARACTER         00001220
*                                       * VARIABLE.                     00001820
&LIB     SETC  'LIB1'                   SET VALUE FOR &LIB              00002420
*                                                                       00003020
         TITLE 'IGC0106C (IHJACP01) CHKPT HOUSEKEEPING RTN - 2ND LOAD'  00004018
*TITLE:  CHKPT HOUSEKEEPING - SECOND LOAD                               00008017
*0000775000                                                     SA61849 00008421
*0000                                                           SA53956 00010021
*0000900058,900072,900098                                       S21940  00010421
*0900109500-110300,113700                                        S20038 00012020
*1190395000,407000-408000                                        A44785 00013021
*1190                                                            A39163 00014021
*127000-150000                                                   M0968  00014421
*                                                                M0969  00014821
*469000,629000,752000                                            M1355  00015221
*0000214000                                                      A54532 00015621
*0000070000                                                      A54568 00015721
*STATUS:  CHANGE LEVEL 000                                              00016017
*FUNCTION/OPERATION:  IGC0106C WILL DO THE FOLLOWING:                   00024017
*   1.)  CHECK FOR ENVIRONMENT ERROR CONDITIONS. THESE ERROR CONDITIONS 00034017
*   AND THEIR ASSOCIATED ERROR CODES ARE LISTED BELOW IN THE OUTPUT     00044017
*   SECTION.                                                            00054017
*                                                                       00064017
*   IF THE BLKSIZE SPECIFIED IN THE DCB IS ZERO, A DEVTYP SVC WILL BE   00081617
*   ISSUED TO OBTAIN THE MAXIMUM BLOCKSIZE OF THE DEVICE CONTAINING     00082417
*   THE CHECKPOINT DATA SET.  THIS BLOCKSIZE WILL BE MOVED TO THE DCB   00083217
*   AND USED BY THE CHECKPOINT ROUTINES IN WRITING THE CHECKPOINT DATA  00084017
*   SET.  A BIT WILL BE SET IN CKFLAG2 AND THE CHECKPOINT EXIT ROUTINE  00084817
*   WILL RESTORE THE BLKSIZE FIELD TO ZERO BEFORE IT XCTLS TO THE       00085617
*   MESSAGE MODULE.                                                     00086417
*   IF OUTSTANDING ENQUEUE REQUESTS ARE FOUND, A RETURN CODE OF X'10'   00088017
*   IS PUT IN CHKWA TO INDICATE A POSSIBLE ERROR AND THEN CONTINUE      00096017
*   NORMAL PROCESSING. IF ANY OF THE ABOVE ERRORS ARE FOUND, A RETURN   00104017
*   CODE OF X'08' IS PLACED IN CHKWA AND XCTL TO  IGC0Q06C.             00112017
*   2.) IF THE USER SUPPLIED A CHECKID THIS ROUTINE WILL CHECK FOR      00120017
*   VALID LENGTH AND CHARACTERS. IF EITHER ARE INVALID A RETURN CODE    00128017
*   OF X'08' IS PLACED IN CHKWA AND XCTL TO IGC0Q06C.                   00136017
*ENTRY POINTS   IGC0105B                                                00144017
*INPUT:  ADDRESS OF CHKPT WORK AREA IN REGISTER 1.                      00152017
*OUTPUT:                                                                00160017
*    1.) FOR NORMAL PROCESSING THE ADDRESS OF CHKPT WORK AREA IS IN     00168017
*        REGISTER 1.                                                    00176017
*    2.) A RETURN CODE OF X'10' IS GIVEN WHEN THERE ARE OUTSTANDING     00184017
*        ENQUEUES AND A MESSAGE CODE OF X'0100' IS PLACED IN THE        00190017
*        CHECKPOINT WORK AREA.  A RETURN CODE OF X'08' IS GIVEN FOR     00196017
*        ANY OTHER ERROR CONDITIONS THAT OCCUR                          00202017
*   WHEN AN ERROR OCCURS ONE OF THE FOLLOWING MESSAGE CODES IS PLACED   00208017
*   INTO CHKWA TO BE PRINTED IN THE CONSOLE MESSAGE BY CHKPT EXIT ROU-  00216017
*   TINE:                                                               00224017
*        DEC VALUE  MNEMONIC               MEANING                      00232017
*           5       CKERPG5         FOR D.A., KEYLENGTH SPECIFIED NOT   00237017
*                                   EQUAL TO ZERO                       00242017
*           6       CKERPG6        ERROR IN DCBRECFM                    00248017
*           7       CKERPG7        ERROR IN DCBDSORG                    00256017
*           8       CKERPG8        ACTIVE TQE                           00264017
*           9       CKERPG9        ERROR IN RBSTAB                      00272017
*          11       CKERPG11       CURRENT TCB IS NOT JOB STEP TCB      00288017
*          12       CKERPG12       TCB HAS DAUGHTER TASKS               00296017
*          14       CKERPG14       OUTSTANDING WTOR                     00312017
*          15       CKERPG15       INCORRECT CHECKID LENGTH/FORMAT      00320017
*          16       CKERPG16       CHKPT D.S. DEVICE TYPE ERROR         00328017
*          18       CKERPG18       BLKSIZE BELOW MINIMUM AND NOT ZERO   00336017
*          19       CKERPG19       CHKPT D.S. NOT OPENED TO WRITE       00344017
*          21       CKERPG21       USASI LABEL TYPE NOT ALLOWED   19200 00351019
*          32       CKERPG32       ISAM DATA SET OPEN DISP=SHR  SA61849 00353021
*EXTERNAL ROUTINES:  NONE                                               00354017
*SVC'S USED   XCTL, DEVTYPE                                             00361017
*EXITS-NORMAL:  XCTL TO IGC0206C                                        00368017
*EXITS-ERROR:  CONTROL WILL TRANSFER TO IGC0Q06C IF ANY OF THE ERROR    00376017
*   CONDITIONS THAT ARE LISTED UNDER OUTPUT ARE FOUND.                  00384017
*TABLES/WORKAREAS CREATED:  CHKTABLE-CONTAINS ALL VALID CHARACTERS FOR  00392017
*   CHECKID.                                                            00400017
*TABLES/WORKAREAS REFERENCED  CHKWA, DCB, TCB, TIOT, TQE, RBS, CHKTABLE 00408017
*   CVT, UCM, RQE                                                       00416017
*ATTRIBUTES:  REENTRANT, SUPERVISOR STATE, TYPE 4 SVC ROUTINE.          00424017
*RESTRICTIONS:  MAY NOT BE USED IN OS/MFT                               00432017
*NOTES:  NONE                                                           00462017
IGC0106C CSECT                                                          00662017
*1190225000                                                      A43190 00682021
* 003480,243000,341520-341560,820000,900084,902500               A26719 00702019
*225200-264000,325000                                              I250 00742019
* 135000,900700                                                   19200 00822019
* 780000                                                           I272 00902019
         USING CHKWA,RC            ADDRESS CHKPT W.A.                   01000017
         USING IHADCB,R2           ADDRESS CHKPT DCB.                   01500017
         USING TCBSECT,R4          ADDRESS TCB.                         02000017
         USING RBSECT,R5           ADDRESS RBS.                         02500017
         BALR  RB,0                BASE ADDR                            02700018
*                                                                     * 02900018
*********************************************************************** 03100018
         USING *,RB                ADDRESS MODULE.                      03500017
         LR    RC,R1               SAVE ADDRESS OF CHKPT W.A.           04000017
         L     R2,CKDCBAD          GET ADDR OF CHKPT DCB.               04500017
         L     R4,CKTCBAD          GET TCB ADDR                         05000017
         L     R5,TCBRBP           GET ADDR OF CHKPT SVRB               05500017
*                                                                     * 05530018
*********************************************************************** 05560018
*                                                                     * 05600017
*        CHECK DCBDEVT FIELD IN DCB FOR DEVICE TYPE                   * 05700017
*         AND DCBDSORG FOR DS ORGANIZATION                       M0968  05750021
*                                                                     * 05800017
*********************************************************************** 05860018
*                                                                     * 05920018
         LA    RA,CKERPG7               LOAD RETURN CODE FOR ERR M0968  05970021
         TM    DCBDSORG,PHYSEQO         WAS DS OPENED FOR PS     M0968  05980021
         BO    CHKDEVT                  YES-SKIP TEST FOR PO     M0968  05992021
         TM    DCBDSORG,PARTORG         WAS DS OPENED FOR BPAM   M0968  05996021
         BZ    CHRERX                   NO-IS ERROR              M0968  05998021
         OI    CKFLAG1,CKBPAM           SET BPAM INDICATOR       M0968  05998421
CHKDEVT  EQU   *                                                 M0968  05998821
         TM    DCBDEVT,DADCK       IS DATA SET ON DIR. ACC. DEVICE      06000017
         BO    CHRDACL             YES-GO TO CHECK KEY LENGTH SPECIFIED 06500017
         LA    RA,CKERPG16          LOAD RETURN CODE IF ERROR OCCURS.   06700017
         TM    DCBDEVT,TAPE        IS DATA SET ON MAGNETIC TAPE  A54568 07000021
         BZ    CHRERX              NO-GO TO ERROR EXIT ROUTINE.  A54568 07500021
         OI    CKFLAG1,CKTAPE      INDICATE DATA SET ON TPAE.           08000017
*                                                                     * 08060017
*********************************************************************** 08090018
*        CHECK DCBRECFM FIELD IN DCB FOR UNDEFINED FORMAT AND TRACK   * 08120017
*        OVERFLOW OPTION                                              * 08180017
*                                                                     * 08260018
*********************************************************************** 08340018
*                                                                     * 08420018
CHRTRFM  EQU   *                                                        08500017
         LA    RA,CKERPG6           LOAD RETURN CODE IF ERROR OCCURS.   08700017
         TM    DCBRECFM,UNDEFIND   IS RECFM UNDEFINED                   09300018
         BM    CHRERX              NO-GO TO ERROR EXIT RTN              09900017
         TM    DCBRECFM,TRKOVF    IS TRACK OVERFLOW SPECIFIED           10600017
         BZ    CHRDSORG           NO-SKIP CODE TO SET CKFLAG1           10700017
         OI    CKFLAG1,CKTRKOV    SET TRACK OVERFLOW INDICATOR.         10800017
*                                                                     * 10806018
*********************************************************************** 10812018
*                                                                     * 10820017
*        CHECK MINIMUM BLOCKSIZE, DCBMACRF IN DCB FOR OPENED TO WRITE,* 10840017
*        AND DCBDSORG IN DCB FOR DATA SET ORGANIZATION                * 10860017
*                                                                     * 10880017
*********************************************************************** 10886018
*                                                                     * 10892018
CHRDSORG EQU   *                                                        10900017
         LR    R1,RC               GET ADDRESS OF WORK AREA             11050017
         A     R1,CKBFOFST         GET OFFSET TO DEVTYP WORK AREA       11070017
         USING DVTPSECT,R1                                              11090017
         L     RA,TCBTIO           GET TIOT ADDRESS                     11110017
         AH    RA,DCBTIOT          GET ADDRESS OF TIOT ENTRY FOR        11130017
*                                  THE CHECKPT DATA CET                 11150017
         USING TIOELNGH,RA                                              11170017
         MVC   DVTPDDNM(DVTPFLGS-DVTPDDNM),TIOEDDNM                     11180018
*                                  MOVE DDNAME TO PARAMETER LIST        11190018
         DROP  RA                                                S20038 11200020
         LA    R0,DVTPFLGS         POINT TO INFORMATION AREA            11210018
         LR    RA,R1               SAVE REGISTER ONE                    11230017
         SVC   DEVTYP              ISSUE DEVTYP SVC TO GET MAX. BLKSIZE 11250018
*        THIS DEVTYP INFORMATION IS ALSO USED BY THE FOLLOWING   S20038 11256020
*        ROUTINE WITH THE LABEL CHROPTCD. SAVE R1.               S20038 11262020
         LR    R1,RA               RETORE R1                            11270017
         LA    RA,CKERPG18             LOAD RETURN CODE IN CASE  S20038 11271020
*                                      AN ERROR OCCURS.          S20038 11272020
         CLC   DCBBLKSI(HALFWD),CHKMINBK IS BLOCKSIZE ABOVE THE  S20038 11273020
*                                      MINIMUM                   S20038 11274020
         BNL   CHRMVBLK                BRANCH IF IT IS           S20038 11275020
         NC    DCBBLKSI(HALFWD),DCBBLKSI IS BLOCKSIZE ZERO       S20038 11276020
         BNZ   CHRERX                  BRANCH IF NOT TO INDICATE S20038 11277020
*                                      AN ERROR                  S20038 11278020
         MVC   DCBBLKSI(DVTPEND-DVTPBLK2),DVTPBLK2                      11280018
*                                  MOVE BLOCKSIZE TO DCB                11290018
         OI    CKFLAG2,CKSPBKSZ    CHECKPOINT PROVIDED BLKSIZE          11310017
CHRMVBLK EQU   *                                                        11330017
         MVC   CKBUFLN(CKBUFLN-CKBUFL),DCBBLKSI   MOVE BLKSIZE FROM DCB 11350018
         LA    RA,CKERPG19         LOAD MESSAGE CODE IF ERROR OCCURS    11700017
         TM    DCBMACF2,WRITEF     WAS DATA OPENED TO 'WRITE'    S21940 12100021
         BZ    CHRERX              NO-GO TO ERROR EXIT ROUTINE.         12500017
         L     R6,DCBIFLGS              GET DEB ADDR             M0969  12550021
         USING DEBSECT,R6                                        M0969  12600021
         TM    DEBOPATB,OUTMETH         OUTPUT PROCESSING        M0969  12650021
         BNO   CHRERX                   NO-IS ERROR              M0969  12660021
         EJECT                                                          15001019
*                                                                 19200 15002019
****************************************************************  19200 15003019
*                                                                 19200 15004019
*        THIS CODE CHECKS LABEL TYPE FIELD ON CHK. PT. DD CARD    19200 15005019
*        IF   LABEL=AL OR LABEL=AUL THEN THE USER IS IN ERROR     19200 15006019
*        USASI  CODE CAN NOT BE USED IN A CHECKPOINT  DATA SET.   19200 15007019
*                                                                 19200 15008019
****************************************************************  19200 15009019
*                                                                 19200 15010019
CHRLABEL EQU   *                       CHECK LABEL TYPE           19200 15011019
         L     RF,TCBTIO               GET ADDRESS OF TIOT        19200 15012019
         AH    RF,DCBTIOT              COMPUTE CK.PT. DD ADDRESS  19200 15013019
         LA    RA,CKERPG21             INDICATE JCL LABEL ERROR   19200 15014019
*                                      IN CASE OF ERROR           19200 15015019
         USING TIOENTRY,RF             TIOT ENTRY ADDRESSABILITY  19200 15016019
         TM    TIOESTTA,USALABEL       TEST FOR USASI LABEL TYPE  19200 15017019
         DROP  RF                      DROP ADDRESSABILITY        19200 15018019
         BO    CHRERX                  USASI LABEL NOT ALLOWED    19200 15019019
*                                                                S20038 15019520
**************************************************************** S20038 15020020
*                                                                S20038 15020520
*        THIS CODE CHECKS THE DCB OPTCD FIELD TO SEE THAT THERE  S20038 15021020
*        IS NO ATTEMPT TO TAKE A CHECK POINT ON TAPE AFTER       S20038 15021520
*        SPECIFYING OPTCD=Q. OPTCD=Q MEANS ANSI TRANSLATION.     S20038 15022020
*                                                                S20038 15022520
**************************************************************** S20038 15023020
*                                                                S20038 15023520
CHROPTCD EQU   *                                                 S20038 15024020
         TM    DVTPDVCL,TAPE           IS THIS TAPE ?            S20038 15024520
         BNO   CHRTME                  NO. SKIP OPTION CODE TEST S20038 15025020
*        TEST FOR TAPE IS NECESSARY DO TO FACT THAT THE SAME BIT S20038 15025520
*        IS USED TO MEAN TRACK OVERFLOW FOR DIRECT ACCESS.       S20038 15026020
*        TRACK OVERFLOW IS ACCEPTABLE FOR CHECKPOINTS.           S20038 15026520
*        ANSI DOES NOT APPLY TO DIRECT ACCESS.                   S20038 15027020
         DROP  R1                                                S20038 15027520
         LA    RA,CKERPG29             IN CASE OF ERROR          S20038 15028020
*                                      INDICATE DCB OPTCD ERROR  S20038 15028520
         TM    DCBOPTCD,DCBOPTQ        ANSI ENCODING SPECIFIED ? S20038 15029020
         BO    CHRERX                  OPTCD=Q NOT ALLOWED       S20038 15029520
*                                                                     * 15030018
*********************************************************************** 15060018
*                                                                     * 15100017
*        TEST FOR ACTIVE TQE                                          * 15200017
*                                                                     * 15300017
*********************************************************************** 15360018
*                                                                       15420018
CHRTME   EQU   *                                                        15500017
         L     RF,CVTPTR           GET ADDRESS OF CVT                   15570017
         USING CVTSECT,RF                                               15640017
         L     RF,CVTTPC           GET ADDRESS OF PSEUDO CLOCK          15710017
         LTR   RF,RF               IS THERE A TIMER                     15780017
         BZ    CHRBT               BRANCH IF NO--SKIP ACTIVE TQE TEST   15850017
         DROP  RF                                                       15920017
         NC    TCBTME1(LNADDR),TCBTME1  IS THERE A TQE                  16120018
         BZ    CHRBT               NO-SKIP CODE TO PROCESS TQE.         16500017
         L     RF,TCBTME           GET ADDR OF TQE.                     17000017
         LA    RA,CKERPG8           LOAD RETURN CODE IF ERROR OCCURS.   17200017
         USING TQESECT,RF          MAPPING OF TQE                       17400018
         TM    TQEFLAG,TQENTQ      IS TQE ACTIVE                        17600018
         DROP  RF                                                       17800018
         BZ    CHRERX              YES-GO TO ERROR ROUTINE.             18000017
*                                                                       18030018
*********************************************************************** 18060018
*                                                                     * 18100017
*        TEST FOR INVALID RB ON RB CHAIN                              * 18200017
*                                                                     * 18300017
*********************************************************************** 18360018
*                                                                       18420018
CHRBT    EQU   *                                                        18500017
         L     R5,RBLINKPT         GET ADDR NEXT RB                     18800018
         LA    RA,CKERPG9                                               19200017
         TM    RBSTAB,IRBSIRB      IS THIS AN IRB OR AN SIRB            20500017
         BM    CHRERX              YES-GO TO ERROR EXIT ROUTINE.        21000017
         BZ    CHRLSRB             BRANCH IF ITS A PRB                  21100017
         TM    RBSTAB,RBEOVFLG     IS THIS EOV SVRB                     21200017
         BZ    CHRERX              BRANCH IF NO--ERROR                  21300017
CHRLSRB  EQU   *                                                        21500017
         TM    RBSTAB1,RBTCBNXT    IS THIS THE LAST RB                  22000018
         BZ    CHRBT          NO - GO TO GET ADDR OF NEXT RB.    A43190 22020021
*                                                                       22040021
**********************************************************************  22060021
*                                                                       22080021
*        TEST FOR ACTIVE SPIE                                           22100021
*                                                                       22120021
**********************************************************************  22140021
*                                                                       22160021
         L     R3,TCBPIE      GET ADDRESS OF PIE                 A43190 22200021
         LA    R3,0(R3)       ZERO HIGH BYTE                     A43190 22220021
         LTR   R3,R3          IS THERE A PIE                     A43190 22240021
         BZ    CHKENV         NO -- GO CHECK   ENVIRONMENT       A43190 22260021
         TM    0(R3),PIEFLAG  HAS PIE BEEN ENTERED               A43190 22280021
         BO    CHRERX         YES -- GO TO ERROR EXIT            A43190 22300021
*                                                                       22320021
CHKENV   EQU   *                                                 A43190 22340021
*                                                             *  A39163 22509021
***************************************************************  A39163 22518021
*                                                             *  A39163 22527021
*    TEST FOR GRAPHICS DCB'S, OR ISAM DCB'S OPEN FOR SHR      * SA61849 22536021
*                                                             *  A39163 22545021
***************************************************************  A39163 22554021
*                                                             *  A39163 22563021
*                                                                       22565021
*        TEST FOR GRAPHICS DCB'S                                        22567021
*                                                                       22569021
         LA    RA,CKPERG10    SET MSG CODE FOR ERR               A39163 22572021
         L     R6,TCBDEB      GET DEB ADDRESS                    A39163 22581021
         USING DEBSECT,R6     ADDRESS DEB                        A39163 22590021
CHKGRAPH EQU   *                                                 A39163 22599021
         LA    R6,0(R6)       CLEAR HIGH BYTE                    A39163 22608021
         LTR   R6,R6          ANY MORE DEBS                      A39163 22617021
         BZ    LSTDEB         NO -- EXIT                         A39163 22626021
         L     R2,DEBDCB      GET ADDR OF DCB                    A39163 22635021
         TM    DCBDSRG2,GRAPHORG  IS GRAPHICS DS ORG             A39163 22644021
         BO    CHRERX         YES -- IS ERROR                    A39163 22653021
*                                                                       22655021
*        TEST FOR ISAM DATA SETS OPEN FOR DISP=SHR              SA61849 22657021
*                                                                       22659021
         TM    DCBDSRG1,DCBDSGIS   IS THIS AN ISAM DCB?         SA61849 22661021
         BZ    CHKNXDEB            NO, GET NEXT DEB             SA61849 22661421
         TM    DCBMACF2,DCBMRPUT   IS THIS QISAM LOAD MODE?     SA61849 22661821
         BO    CHKNXDEB            YES, DISP=SHR NOT POSSIBLE   SA61849 22661921
         TM    DCBMACF1,DCBMRGET   IS THIS QISAM SCAN MODE?     SA61849 22668221
         BO    CHKISCAN            YES, CHECK SCAN MODE W/A     SA61849 22670221
         TM    DCBMACF1,DCBMRRD    IS THIS BISAM READ?          SA61849 22672221
         BO    CHKBISAM            YES, CHECK BISAM WORK AREA   SA61849 22674221
         TM    DCBMACF2,DCBMRWRT   IS THIS BISAM WRITE?         SA61849 22674621
         BZ    CHKNXDEB            NO, NONE OF THE ABOVE,       SA61849 22674721
*                                  GET NEXT DEB FOR CHECKING    SA61849 22676421
CHKBISAM EQU   *                                                SA61849 22678421
         L     RD,DCBWKPT2         GET BISAM WORK AREA POINTER  SA61849 22678821
         USING BISAMWA,RD                                       SA61849 22679221
         TM    DCWDCBFA,ISAMSHR    IS IT OPEN FOR DISP=SHR?     SA61849 22679621
         BZ    CHKNXDEB            NO, NOT SHARED               SA61849 22679721
         DROP  RD                                               SA61849 22679821
CHKISERR EQU   *                                                SA61849 22679921
         LA    RA,CKERPG32         ISAM DISP=SHR ERROR CODE     SA61849 22681721
         B     CHRERX              GO TO ERROR EXIT             SA61849 22683721
CHKISCAN EQU   *                                                SA61849 22684121
         L     RD,DCBWKPT1         GET SCAN MODE WORK AREA PTR  SA61849 22684521
         USING SCANWA,RD                                        SA61849 22684921
         TM    W1DCBFA,ISAMSHR     IS IT OPEN FOR DISP=SHR?     SA61849 22685321
         BO    CHKISERR            YES, IT IS SHARED            SA61849 22685821
         DROP  RD                                               SA61849 22686221
CHKNXDEB EQU   *                                                SA61849 22686621
         L     R6,DEBLINK     GET NEXT DEB                       A39163 22686921
         B     CHKGRAPH       GO CHK NXT DEB                     A39163 22687421
*                                                                       22689021
LSTDEB   EQU   *                                                 A39163 22693721
         EJECT 1                                                   I250 22700019
*******************************************************************I250 22900019
*                                                                  I250 23100019
*        MVT AND MFT ENVIRONMENT TESTING -                         I250 23300019
*              OUTSTANDING ENQUEUES                                I250 23500019
*              OUTSTANDING WTOR                                    I250 23700019
*              ANY DAUGHTER TASKS                                  I250 23900019
*              IS TCB A JOB STEP TCB  (SYSTEM DEPENDENT TEST)      I250 24100019
*                                                                  I250 24500019
*******************************************************************I250 24700019
*                                                                  I250 24900019
         TM    CKFLAG1,CKMFT+CKMVT IS THIS MFT OR MVT              I250 25100019
         BZ    CHRCKT              BRANCH IF NO                    I250 25300019
         LA    RA,CKERENQS         LOAD MESSAGE CODE FOR POSSIBLE ERROR 26600017
         NC    TCBFSA(1),TCBFSA    ARE THERE ANY OUTSTANDING ENQUEUES.  27000017
         BNZ   CHRPRE                   PRE CHRPROBR BRANCH       MFTCR 27500018
CHRNXT   EQU   *                                                        28000017
         L     RF,CVTPTR(R0)       GET ADDR OF CVT.                     28500017
         USING CVTSECT,RF          ADDRESS CVT.                         29000017
         L     R1,CVTCUCB          GET ADDR OF UCM TABLE                29500017
         USING UCMSECT,R1     ADDRESS UCM.                              30000017
         L     R1,UCMRPYQ          GET ADDR OF FIRST RQE.               30500017
         USING RQESECT,R1          ADDRESS REPLY QUEUE ELEMENT.         31000017
CHRWTORQ EQU   *                                                        31500017
         LTR   R1,R1               ARE THERE ANY MORE RQE               32000017
         BZ    CHRCKATT            NO-GO CHECK FOR DAUGHTER TASKS  I250 32300019
         LA    RA,CKERPG14          LOAD RETURN CODE IF ERROR OCCURS.   32700017
         C     R4,RQETCB           IS THERE AN OUTSTANDING WTOR         33100017
         BE    CHRERX             YES-GO TO ERROR EXIT RTN              33500017
         L     R1,RQELKP           GET ADDR OF NEXT REPLY Q. ELEMENT.   34000017
         B     CHRWTORQ            CONTINUE CHECKING RQE CHAIN          34100018
CHRCKATT EQU   *                                                   I250 34104019
         LA    RA,CKERPG12         LOAD MSG CODE IF ERROR OCCURS   I250 34108019
         NC    TCBLTC1(LNADDR),TCBLTC1  ANY DAUGHTER TASKS         I250 34112019
         BNZ   CHRERX              YES, GO TO ERROR ROUTINE        I250 34116019
         TM    CKFLAG1,CKMVT       IS THIS MVT                     I250 34120019
         BZ    CHRMFT              BRANCH IF NO--ITS MFT           I250 34124019
         SPACE 1                                                   I250 34128019
***    MVT TEST FOR JOB STEP TCB AND ROLLOUT      **               I250 34132019
         SPACE 1                                                   I250 34136019
         LA    RA,CKERPG11         LOAD MSG CODE IF ERROR OCCURS   I250 34140019
         C     R4,TCBJSTCB         IS THIS A JOB STEP TCB          I250 34144019
         BNE   CHRERX              BRANCH IF NO TO ERROR ROUTINE   I250 34148019
         B     CHRCKT              GO CHECK CHECKID                I250 34160019
CHRMFT   EQU   *                                                   I250 34164019
         SPACE 1                                                   I250 34168019
**  MFT TEST FOR JOB STEP TCB                                      I250 34172019
         SPACE 1                                                   I250 34176019
         DROP  RF                                               SA53956 34176421
         L     R1,CVTPTR           GET CVT PTR                  SA53956 34178021
         USING CVTSECT,R1                                       SA53956 34178421
         TM    CVTOPTA,CVTATTCH    IS ATTACH OPERATIVE          SA53956 34178821
         BZ    CHRCKT           NO, DON'T TEST FOR JOB STEP TCB SA53956 34179221
         DROP  R1                                               SA53956 34179621
         LA    RA,CKERPG11         LOAD MSG CODE IF ERROR OCCURS   I250 34180019
         C     R4,TCBJPQ           IS THIS A JOB STEP TCB          I250 34184019
         BNE   CHRERX              BRANCH IF NO TO ERROR ROUTINE   I250 34188019
         EJECT 1                                                   I250 34192019
*                                                                     * 34200018
*********************************************************************** 34300018
*                                                                     * 34600017
*        CHECK LENGTH OF CHECKID                                      * 34700017
*                                                                     * 34800017
*********************************************************************** 34860018
*                                                                     * 34920018
CHRCKT   EQU   *                                                        35000017
         L     R3,CKPARMAD          GET ADDR OF PARAMETER LIST.         35200017
         USING PARMSECT,R3         MAPPING CHKPT PARAMETER LIST         35400018
         TM    PARMFLG,NOID        DID USER SUPPLY CHECKID              35600018
         BO    CHRBKPRB            NO-SKIP CODE TO EXAMINE CHECKID.     36000017
         TM    LNCHKID,USERID      Q. DID USER SUPPLY CHECKID           36500018
         BO    CHRBKPRB            NO-SKIP CODE TO EXAMINE CHECKID.     37000017
         OI    CKFLAG2,CKUSPCHD    INDICATE USER SUPPLIED CHECKID.      37500017
         LA    RA,CKERPG15          LOAD RETURN CODE IF ERROR OCCURS.   37550017
         CLI   LNCHKID,LNGZERO     DOES CHECKID LENGTH = 0              37620018
         BE    CHRERX              YES-GO TO ERROR EXIT RTN             37700017
         CLI   LNCHKID,CHR16       IS CHECKID TOO LONG                  38100018
         BH    CHRERX              YES-GO TO ERROR EXIT ROUTINE.        38500017
         TM    CKFLAG1,CKBPAM      WAS CHKPT DATA SET OPENED FOR BPAM.  39000017
         BZ    CHKCHARS       NO-SKIP CODE TO CHECK BPAM LENGTH  A44785 39500021
         CLI   LNCHKID,BPAMLNG     IS CHECKID TOO LONG                  40000018
         BH    CHRERX              YES-GO TO ERROR EXIT ROUTINE.        40500017
*                                                                     * 40530018
*********************************************************************** 40560018
*                                                                     * 40600017
*        TEST USER'S CHECKID FOR VALID CHARACTERS                     * 40670021
*                                                                     * 40740021
*********************************************************************** 40830018
*                                                                       40860018
*                                                                     * 40900017
CHKCHARS EQU   *                                                 A44785 40950021
         XR    R6,R6               SET SWITCH TO INDICATE FIRST CHAR.   41000017
         XR    R7,R7               CLEAR REGISTER                       41300017
         IC    R7,LNCHKID          GET LENGTH OF CHECKID                41600018
         L     R9,IDADDR           GET ADDR OF CHECKID                  41900018
         DROP  R3                                                       42200018
CHRTAB   EQU   *                                                        42500017
         LA    R8,CHKTABLE         GET ADDR OF TABLE OF VALID CHAR.     43000017
         XR    RE,RE                                                    43500017
CHRBGN   EQU   *                                                        44000017
         CLC   0(1,R8),0(R9)       DOES CHECKID CHAR. MATCH A VALID ONE 44500017
         BE    CHROUT              YES-EXAMINE NEXT CHAR.               45000017
         LTR   R6,R6               IS THIS THE FIRST CHAR               45500017
         BNZ   CHRTST2             NO-GO TO SEE IF END OF TABLE.        46000017
         CH    RE,=H'28'           END OF ALPHABETIC PART OF TABLE      46500017
         BL    CHRCOMUP       NO-EXAMINE NEXT CHAR IN TABLE      A44785 46600021
         TM    CKFLAG1,CKBPAM IS BPAM ORGANIZATION               A44785 46700021
         BO    CHRERX         YES-GO TO ERROR EXIT ROUTINE       A44785 46800021
         CH    RE,=H'50'                END NATL CHAR TBL        M1355  46850021
         BE    CHRERX              YES-GO TO ERROR EXIT ROUTINE.        47000017
         B     CHRCOMUP            NO-EXAMINE NEXT CHAR IN TABLE.       47500017
CHROUT   EQU   *                                                        48000017
         LR    R6,R9               SET SWITCH TO INDICATE NOT-1ST-CHAR. 48500017
         LA    R9,ADDONE(R9)       UPDATE POINTER TO NEXT CHAR IN CKID  49000018
         BCT   R7,CHRTAB           END OF TESTING-NO-TEST NEXT CHAR     49500018
CHRBKPRB EQU   *                                                        50000017
*                                                                     * 50030018
*********************************************************************** 50060018
*                                                                     * 50100017
*        SET PARAMETER REGISTER AND XCTL TO IGC0206C                  * 50200017
*                                                                     * 50300017
*********************************************************************** 50360018
*                                                                     * 50420018
         LR    R1,RC               LOAD PARM REG WITH W.A. ADDR.        50500017
         MVC   CKJCT(LXCTLNAM),CHRXLIST      SET UP XCTL PARM LIST      50800018
CHREXT   EQU   *                                                        51100017
CHKCER   EQU   *                                                        51200017
         LA    RF,CKJCT                                                 51500017
         USING XCTLSECT,RF         MAPPING OF XCTL PARM LIST            51700018
         ST    RF,XCPARMPT                                              51900018
         LA    RF,XCPARMPT                                              52100018
         DROP  RF                                                       52300018
         XCTL  SF=(E,(15))                                              53000017
*                                                                     * 53100017
*********************************************************************** 53150018
*        ERROR ROUTINE - SETS RETURN CODE AND SAVES MESSAGE CODE IN   * 53200017
*        CHKWA; ALTERS XCTL PARM LIST TO TRANSFER CONTROL TO IGC0Q06C * 53300017
*                                                                     * 53400017
*********************************************************************** 53430018
*                                                                     * 53460018
CHRERX   EQU   *                                                        53500017
         LR    R1,RC                                                    53520017
         OI    CKFLAG2,CKMSG1      INDICATES MSG-ENVIRONMENT ERROR      53560017
         OI    CKFLAG2,CKFREEM     INDICATES ONLY FREEMAIN WA IN CER    53580017
         MVI   CKRETCD1,CKPGMERR   SAVE RETURN CODE IN CHKWA            53610018
         STH   RA,CKMSGCOD         SAVE MESSAGE CODE IN WA              53650017
         LA    RF,CKJCT                                                 54050018
         USING XCTLSECT,RF         MAPPING OF XCTL PARM LIST            54450018
         MVC   XCTLNAME(LXCTLNAM),CHRXLIST   SET UP XCTL PARMLST TO     54850018
         MVI   XCTLNM2,CHARQ                 TRANSFER CONTROL TO CER    55250018
         B     CHKCER              GO TO TRANSFER CONTROL               55710017
CHRBLANK EQU   *                                                        59500017
         BCTR  R7,0                DECREMENT COUNT FOR MOVES.           60000017
         EX    R7,CHRCLC1          ARE REST OF CHARS. BLANKS.           60500017
         BNE   CHRERX              NO-GO TO ERROR EXIT ROUTINE.         61000017
         B     CHRBKPRB            YES-VALID CHECKID,GO ON PROCESSING.  61500017
CHRTST2  EQU   *                                                        62000017
         CH    RE,=H'38'           END OF TABLE                         62500017
         BL    CHRCOMUP       NO-EXAMINE NEXT CHAR IN TABLE      A44785 62600021
         TM    CKFLAG1,CKBPAM IS BPAM ORGANIZATION               A44785 62700021
         BO    CHRBLANK       YES-SEE IF REST OF CHARS ARE BLANK A44785 62800021
         CH    RE,=H'50'      END OF NATIONAL CHAR PART OF TABLE M1355  62900021
         BE    CHRBLANK            GO TO SEE IF REST OF CHAR.ARE BLANKS 63000017
CHRCOMUP EQU   *                                                        63500017
         LA    RE,ADDONE(RE)       UPDATE COUNT OF CHAR TRIED           64000018
         LA    R8,ADDONE(R8)       UPDATE POINTER TO NEXT CHAR IN TABLE 64500018
         B     CHRBGN              GO TO TRY NEXT CHAR IN TABLE.        65000017
         USING RBSECT,R5           ADDRESS RB.                          65500017
CHRPRE   EQU   *                                                  MFTCR 65560018
         TM    CKFLAG1,CKMVT            IS THIS AN MVT SYSTEM     MFTCR 65620018
         BO    CHRPROBR            YES-BYPASS MFT DSI ENQ SERCH   MFTCR 65680018
*                                                                       65740018
********                                                          MFTCR 65800018
*              FOLLOWING IS AN MFT TEST FOR DATA SET INTEGRITY(DSI)     65860018
*              ONLY ENQUEUES                                            65920018
********                                                          MFTCR 65980018
*                                                                       66040018
         L     R3,CVTPTR           GET CVT ADDR                   MFTCR 66100018
         USING CVTSECT,R3                                         MFTCR 66160018
         L     R3,CVTBTERM         GET ABTERM ADDR                MFTCR 66220018
         DROP  R3                                                 MFTCR 66280018
         L     R3,HEADQCB(R3)      PICK UP HEAD QCB PTR(ASSEMBLED MFTCR 66340018
*                                  IN IEAOABOO(ABTERM MOD.)             66400018
CHRQCBLP EQU   *                                                  MFTCR 66460018
         USING QCBSECT,R3          MAPPING OF QCB                 MFTCR 66520018
         L     R3,CHAINPTR         PICK UP NEXT QCB               MFTCR 66580018
         LTR   R3,R3                    IS IT END OF QCB'S        MFTCR 66640018
         BZ    CHRNXT              YES-GO TO CONT. ENVIRO.        MFTCR 66700018
*                                  CHECKING                       MFTCR 66760018
         CLC   ENQNAME,SYSDSN      DOES 'MAJOR NAME' INDICATE     MFTCR 66820018
*                                  DSENQ                          MFTCR 66880018
         BNE   CHRSERCH            CHECK ALL QEL'S ASSOCIATED     MFTCR 66940018
*                                  WITH THIS MAJOR FOR ENQING TCB MFTCR 67000018
         CLC   CHAINPTR,ZERO       END OF QCB CHAIN               MFTCR 67060018
         BE    CHRNXT              YES-GO TO CONT.ENVIRO.CHECKING MFTCR 67120018
         B     CHRQCBLP            GO TO GET NEXT QCB             MFTCR 67180018
CHRSERCH EQU   *                                                  MFTCR 67240018
         L     R6,MINORQCB         PICK UP ADDR OF FIRST MINOR    MFTCR 67300018
CHRQELAD EQU   *                                                  MFTCR 67360018
         USING MQCBSECT,R6         MAPPING OF MINOR QCB                 67420018
         L     R7,QELPTR           PICK UP FIRST QEL FOR MINOR    MFTCR 67480018
CHRTCBCK EQU   *                                                  MFTCR 67540018
         USING QELSECT,R7          MAPPING OF QEL                       67600018
         CLC   QELTCB,CKTCBAD      DOES TCB ADDR=CHKPT TCB ADDR   MFTCR 67660018
         BE    CHRPROBR            YES-SET PROBABLE ERROR BIT     MFTCR 67720018
         L     R7,QELCHAIN         NO-PICK UP NEXT QEL ADDR       MFTCR 67780018
         LA    R7,0(R7)            ZERO OUT HIGH ORDER BYTE       MFTCR 67840018
         LTR   R7,R7               IS IT LAST QEL                 MFTCR 67900018
         BNZ   CHRTCBCK            NO-GO CHECK TCB ADDRS          MFTCR 67960018
         L     R6,NEXTMQCB         PICK UP NEXT MINOR ADDR        MFTCR 68020018
         LTR   R6,R6                    IS IT LAST MINOR          MFTCR 68080018
         BNZ   CHRQELAD            NO-GO PICK UP 1ST QEL FOR      MFTCR 68140018
*                                  MINOR                          MFTCR 68200018
         B     CHRQCBLP            GO TO GET NEXT QCB             MFTCR 68260018
*                                                                       68320018
*********************************************************************** 68380018
*                                                                       68440018
*        SET RETURN CODE = PROBABLE ERROR                               68500018
*                                                                       68560018
*********************************************************************** 68620018
*                                                                       68680018
CHRPROBR EQU   *                                                        69000017
         MVI   CKRETCD1,CKPSBERR   INDICATE PROBABLE ERROR              69200018
*                                  DOES CHECKID CHAR. MATCH A VALID ONE 69400018
         STH   RA,CKMSGCOD         STORE MESSAGE CODE                   69700017
         B     CHRNXT             GO TO CONTINUE ENVIRONMENT CHECKING   70000017
*                                                                     * 70030018
*********************************************************************** 70060018
*                                                                     * 70100017
*        FOR CHKPT DATA SET ON DIRECT ACCESS, CHECK KEYLENGTH IN DCB  * 70200017
*        EQUAL TO ZERO.                                               * 70300017
*                                                                     * 70400017
*********************************************************************** 70430018
*                                                                     * 70460018
CHRDACL  EQU   *                                                        70500017
         LA    RA,CKERPG5           LOADED RETURN CODE IF ERROR OCCURS. 70700017
         CLI   DCBKEYLE,LNGZERO    IS KEYLENGTH ZERO                    71100018
         BNE   CHRERX              NO-GO TO ERROR EXIT ROUTINE.         71500017
         B     CHRTRFM             YES-CONTINUE ENVIRONMENT CHECKING.   72000017
CHRCLC1  CLC   0(1,R9),BLANKS      EXECUTED COMPARE FOR PADDED BLANKS.  72500017
C551A    DC    C'551A' IGG0551A SYNCHES TO CHKPT EXIT ROUTINE.          73000017
*                                                                       73100018
*        TABLE CONTAINING VALID CHARACTERS FOR CHECKID                  73200018
*                                                                       73300018
CHKTABLE EQU   *                                                        73500017
         DC    CL26'ABCDEFGHIJKLMNOPQRSTUVWXYZ'                         74000017
         DC    CL3'$#@'                                                 74500017
         DC    CL10'0123456789'                                         75000017
         DC    CL12',./''()*&&+-= '     NATIONAL CHARACTERS      M1355  75200021
BLANKS   DC    C'       '                                               75500017
*                                                                       75800018
CHKMINBK DC    H'600'    MINIMUM BLKSIZE FOR CHKPT DATA SET             76100018
CHRXLIST DC    C'IGC0206C'         TRANSFER CONTROL(NORMAL FLOW)        76200018
SYSDSN   DC    C'SYSDSN'           SYSTEM DATA SET ENQ MAJOR NAME MFTCR 76300018
HEADQCB  EQU   12        OFFSET OF PTR TO FIRST QCB IN ABTERM     MFTCR 76400018
*                        MODULE IEAOAB00                          MFTCR 76500018
ZERO     DC    F'0'                                               MFTCR 76600018
RBEOVFLG EQU   X'04'                                                    76800017
*                                                                       76808018
*        MAPPING OF USER-SUPPLIED CHECKID                               76816018
*                                                                       76824018
IDSECT   DSECT                                                          76832018
*                                                                       76840018
*        DSECTS FOR MFT2  - QCB, MINOR QCB, QEL                         76848018
*                                                                       76856018
QCBSECT  DSECT                                                          76864018
CHAINPTR DS    1F        ADDR OF NEXT QCB                               76872018
         DS    1F                                                       76880018
MINORQCB DS    1F        ADDR MINOR QCB                                 76888018
ENQNAME  DS    CL6       MAJOR NAME FOR ENQ.                            76896018
*                                                                       76904018
MQCBSECT DSECT                                                          76912018
QELPTR   DS    1F        ADDR QEL                                       76920018
         DS    1F                                                       76928018
NEXTMQCB DS    1F        ADDR NEXT MINOR QCB                            76936018
*                                                                       76944018
QELSECT  DSECT                                                          76952018
QELCHAIN DS    1F        ADDR OF NEXT QEL                               76960018
         DS    1F                                                       76968018
QELTCB   DS    1F        ADDR OF TCB FOR QUEUE ELEMENT                  76976018
         IEEVCHWA                                                       77000017
         DCBD  DSORG=(BS,PO,IS),DEVD=(DA,TA)                    SA61849 77500021
*                                                                     * 77520018
*        MAPPING OF PARAMETER LIST FOR DEVTYP MACRO                     77540018
*                                                                     * 77560018
DVTPSECT DSECT                                                          77580018
DVTPDDNM DS    2F   DDNAME                                              77630018
DVTPFLGS DS    1C   FLAG BYTE                                           77680018
DVTPOPT  DS    1C   OPTION BYTE                                         77740018
DVTPDVCL DS    1C   DEVICE TYPE                                         77800018
DVTPUTYP DS    1C   UNIT TYPE                                           77860018
DVTPBKSZ DS    F    BLOCKSIZE RETURNED                                  77864018
DVTPBLK2 EQU   DVTPBKSZ+2                                               77868018
DVTPEND  EQU   *                                                        77872018
*                                                                       77876018
*        MAPPING OF TIMER QUEUE ELEMENT(TQE)                            77880018
*                                                                       77884018
TQESECT  DSECT                                                          77888018
TQEFLAG  DS    1C   FLAG BYTE                                           77892018
TQETCB   DS    3C   TCB ADDR                                            77896018
TQEFILL  DS    7F                                                       77900018
*                                                                     * 77904018
*        MAPPING OF CHECKPOINT PARAMETER LIST                         * 77908018
*                                                                     * 77912018
PARMSECT DSECT                                                          77916018
PARMFLG  DS    1C   FLAG BYTE                                           77920018
NOID     EQU   X'80'     INDICATES NO CHECKID SPECIFIED BY USER AND     77924018
*                        GENERATED CHECKID ADDR NOT TO BE RETURNED      77928018
CHKID    EQU   X'00'     USER-SPECIFIED CHECKID                         77932018
PARMDCB  DS    3C        ADDR OF CHKPT DCB                              77936018
IDADDR   DS    0F                                                       77940018
LNCHKID  DS    1C        LENGTH OF USER-SPECIFIED CHECKID               77944018
USERID   EQU   X'FF'     INDICATES USER WANTS SYSTEM-GENERATED CHECKID  77948018
*                        AND RETURNED AT LOCATION SPECIFIED BY IDADDR   77952018
         DS    3C        ADDR OF USER-SUPPLIED CHECKID,OR, CONTAINS     77956018
*                        RETURN ADDRESS OF SYSTEM-GENERATED CHKID       77960018
*                                                                     * 77964018
*        MAPPING OF XCTL PARAMETER LIST                               * 77968018
*                                                                     * 77972018
XCTLSECT DSECT                                                          77976018
XCTLNAME DS    1F        MODULE NAME TO TRANSFER CONTROL                77980018
XCTLNM2  DS    1F                                                       77984018
XCPARMPT DS    1F        POINTER TO XCTL PARM LIST                      77988018
UCMSECT  DSECT                                                          78500017
         IEECUCM                                                        79000017
RQESECT  DSECT                                                          79500017
         IEECVMUG RQE                                                   80000017
         IHBABCTL                                                       80500017
CKTIOTD  DSECT                                                          81000017
         IEFTIOT1                                                       81500017
         EJECT                                                          81550021
SCANWA   IGGSCAN                                                SA61849 81600021
         EJECT                                                          81650021
BISAMWA  IGGBISAM                                               SA61849 81700021
         EJECT                                                          81750021
PCPIRB   EQU   X'40'     RBSTAB FIELD-INDICATES IRB IN PCP.             82500017
PCPSIRB  EQU   X'80'     RBSTAB FIELD-INDICATES SIRB IN PCP.            83000017
IRBSIRB  EQU   X'C0'     RBSTAB-INDICATES EITHER SIRB OR IRB IN MVT.    83500017
SVRB34   EQU   X'D0'     INDICATES TYPE 3 OR 4 SVRB.                    83700017
CHR16    EQU   16     MAXIMUM LENGTH FOR A CHECKID                      84500017
TQENTQ   EQU   X'80'     INDICATES TQE IS NOT ON TIMER QUEUE.           85000017
FIXD     EQU   128     DCBRECFM FIELD- INDCIATES FIXED                  85500017
WRITEF   EQU   32      DCBMACRF FIELD- INDICATES WRITE LOGIC            86000017
PHYSEQO  EQU   64      DCBDSORG FIELD- INDCIATES PHY. SEQUENTIAL ORG.   86500017
PARTORG  EQU   2       DCBDSORG- INDICATES PARTITIONED ORGANIZATION     87000017
BLKL     EQU   2       LENGTH OF DCBBLKSI FIELD                         87500017
TRKOVF   EQU   32            DCBRECFM FIELD-INDICATES TRACK OVERFLOW    87700017
UNDF     EQU   X'C0'   DCBRECFM FIELD- INDICATES UNDEFINED              88000017
FIXUND   EQU   128     DCBRECFM FIELD- INDCIATES FIXED OR UNDEFINED     88500017
DADCK    EQU   32   DCBDEVT FIELD-INDICATES DIRECT ACCESS DEVICE        89000017
TAPECK   EQU   X'81'   DCBDEVT FIELD- INDICATES TAPE                    89500017
CLOSEOPT EQU   128  OPTION BYTE FOR CLOSE'S PARM LIST.                  90000017
UNDEFIND EQU   X'C0'     DCB RECFM = UNDEFINED                          90000418
RBLINKPT EQU   RBWCF     POINTER TO RBLINK FIELD IN RB                  90000818
EOVFLG   EQU   X'FB'     USED TO TURN OFF EOV FLAG IN RB                90001218
USERCKID EQU   X'FF'     INDICATES USER SUPPLIED CHECKID                90001618
LNGZERO  EQU   X'00'     LENGTH = ZERO                                  90002018
BPAMLNG  EQU   X'08'     CHECKID LENGTH = 8                             90002418
CHARQ    EQU   C'Q'      USED TO ALTER PARMLST TO XCTL TO CER           90002818
LNADDR   EQU   3         LENGTH OF ADDRESS                              90003218
ADDONE   EQU   1         INCREMENT QUANTITY                             90003618
ONECHAR  EQU   1         INDICATES ONE CHARACTER COMPARE                90004018
LXCTLNAM EQU   8         LENGTH OF XCTL PARAMETER LIST NAME             90004418
CKSPBKSZ EQU   8         INDICATES CHKPT PROVIDED BLKSIZE FOR CHKPT DS  90004818
HALFWD   EQU   2         LENGTH OF HALF-WORD                            90005218
DEVTYP   EQU   24        SVC NUMBER FOR DEVTYP MACRO                    90005618
TAPE     EQU   X'80'      TAPE BIT OF DEVTYPE FIELD              S20038 90005720
GRAPHORG EQU   X'80'          GRAPHICS DS ORGANIZATION           A39163 90005921
OUTMETH  EQU   X'0F'                    OUTPUT METHOD            M0969  90006021
ISAMSHR  EQU   X'80'     BIT IN ISAM WORK AREAS INDICATING SHR  SA61849 90006121
*                                                                       90006421
*        ADDRESSING BYTES WITHIN DSECTS                                 90006521
DEBOPATB EQU   DEBSECT+12               TYPE IO METHOD           M0969  90006621
CKBUFLN  EQU   CKBUFL+2                                                 90006818
TCBTME1  EQU   TCBTME+1                                                 90007618
RBSTAB1  EQU   RBSTAB+1                                                 90008018
TCBLTC1  EQU   TCBLTC+1                                                 90008818
CKRETCD1 EQU   CKRETCOD+1                                               90009218
USALABEL EQU   TIOSLABL+TIOSLTYP       COMBINED BITS=USASI LABEL  19200 90009619
PIEFLAG  EQU   X'80'                                             A43190 90009721
CKMSG1   EQU   32    WTO MESSAGE-NOT TAKEN-ENVIRONMENT ERROR            90010017
CKERPG5  EQU   X'05'    FOR D.A.,KEYLENGTH SPECIFIED=0                  90020017
CKERPG6  EQU   X'06'    ERROR IN DCBRECFM                               90030017
CKERPG7  EQU   X'07'    ERROR IN DCBDSORG                               90040017
CKERPG8  EQU   X'08'    ACTIVE TQE                                      90050017
CKERPG9  EQU   X'09'    ERROR IN RBSTAB                                 90060017
CKPERG10 EQU   X'0A'          GRAPHICS DSORG ERR CODE            A39163 90070021
CKERPG11 EQU   X'0B'    CURRENT TCB IS NOT JOB STEP TCB                 90080017
CKERPG12 EQU   X'0C'    TCB HAS DAUGHTER TASKS                          90090017
CKERENQS EQU   X'0100'             OUTSTANDING ENQS                     90100017
CKERPG14 EQU   X'0E'    OUTSTANDING WTOR                                90110017
CKERPG15 EQU   X'0F'    INCORRECT CKID LN/FORMAT                        90120017
CKERPG16 EQU   X'10'    CHKPT D.S. NOT ON D.A. OR TAPE                  90130017
CKERPG18 EQU X'12'    CHKPT BLKSIZD BELOW MINIMUM                       90140017
CKERPG19 EQU X'13'    CHKPT DS NOT OPENED TO WRITE                      90150017
CKERPG21 EQU   X'15'    MSG CODE FOR JCL LABEL ERROR              19200 90350019
CKERPG29 EQU   X'1D'    MSG CODE FOR OPTCD FIELD OF DCB ERROR    S20038 90420020
CKERPG32 EQU   X'20'  MSG CODE FOR ISAM DATA SETS OPEN DISP=SHR SA61849 90470021
         END                                                            90500017
