*                                                                       00000820
         GBLC  &LIB                     DEFINE GLOBAL CHARACTER         00001620
*                                       * VARIABLE.                     00002420
&LIB     SETC  'LIB1'                   SET VALUE FOR &LIB              00003220
*                                                                       00004020
         TITLE 'IGC0206C (IHJACP02) CHKPT HOUSEKEEPING RTN - 3RD LOAD'  00005018
*TITLE:  CHKPT HOUSEKEEPING - 3RD LOAD                                  00010017
*                                                                       00012000
*        RELEASE 23 DELETIONS/CHANGES                                   00014021
*        RELEASE 22 DELETIONS/CHANGES                                   00014421
*        RELEASE 21.8 DELETIONS/CHANGES                                 00015021
*0000026000,387500-388000,389000,901820-901840,903020           SA69185 00015121
*        RELEASE 21 DELETIONS/CHANGES                                   00016421
*0000016000,024000,262000,300000,424000,586000,652000-656000,    S21940 00016521
*0000860000,900950                                               S21940 00017521
*                                                               SA51163 00018421
*        RELEASE 20 DELETIONS/CHANGES                                   00023221
*2993571000,578000-638000,844000-848000                          M0367  00027400
*STATUS CHANGE LEVEL 003                                                00031600
*FUNCTION/OPERATION:  THIS ROUTINE WILL DO THE FOLLOWING:               00035800
*        1.) CONSTRUCT AN XDAP, ECB, IOB, AND CHANNEL PROGRAM IN CHKWA. 00040017
*            THE CONTROL BLOCKS AND THE CHANNEL PROGRAM WILL BE USED BY 00050017
*            ALL CHKPT ROUTINES WHICH WISH TO READ FROM OR WRITE TO THE 00060017
*            JOB QUEUE.                                                 00070017
*        2.) READ IN THE JCT.                                           00080017
*        3.) GIVE CONTROL TO THE CHKPT EXIT ROUTINE IF 'CANCEL' WAS     00090017
*            REQUESTED.                                                 00100017
*        4.) CONSTRUCT CHECKPOINT HEADER RECORD (CHR).                  00110017
*        5.) UPDATE THE JCTNRCKP AND JCTCKIDL FIELDS IN THE JCT.        00120017
*        6.) GENERATE A CHECKID IF USER DID NOT SUPPLY A CHECKID.       00130017
*ENTRY POINTS:  IHJACP02                                                00140017
*INPUT:  ADDRESS OF CHKPT WORK AREA IN REGISTER 1.                      00150017
*OUTPUT:  IF AN I/O ERROR WAS FOUND WHEN READING THE JCT                00160017
*        A RETURN CODE OF X'0C' IS PLACED IN CHKWA TO INDICATE A        00170017
*        CHKPT I/O ERROR. A MESSAGE CODE OF X'19' IS PLACED IN CHKWA    00180017
*        AND CONTROL IS PASSED TO THE ERROR EXIT ROUTINE.               00190017
*EXTERNAL ROUTINES:  IECPCNVT - CONVERTS TTR TO MBBCCHHR                00200017
*SVCS USED:  XDAP, WAIT, CHECK, XCTL                                    00210017
*EXITS-NORMAL:  XCTL TO CHKDCB, IGC0506C, UNLESS CANCEL WAS REQUESTED   00220017
*        THEN XCTL TO CHKPT EXIT ROUTINE IGC0Q06C                       00230017
*EXITS-ERROR:  IF AN I/O ERROR WAS FOUND READING THE JCT CONTROL IS     00240017
*        PASSED TO IGC0Q06C                                             00250017
*TABLES/WORKAREAS CREATED:  NONE                                        00260017
*TABLES/WORKAREAS REFERENCED:  TCB,CHKWA,CVT,ECB,IOB,DCB,DEB,JCT,TIOT,  00270017
*        DECB,CSCB,JOB Q WORKAREA,CHR                                   00280017
*ATTRIBUTES:  REENTRANT, SUPERVISOR STATE, TYPE 4 SVC ROUTINE           00290017
*RESTRICTIONS ON USE OF ROUTINE:  MAY NOT BE USED IN OS/MFT             00300017
*NOTES:  NONE                                                           00350017
         EJECT                                                          00500021
IGC0206C CSECT                                                          00550017
         BALR  RB,0                BASE ADDR                            00850018
         USING *,RB                ADDRESS MODULE.                      01200017
         USING TCB,R4              ADDRESS TCB.                  S21940 01600021
         USING CHKWA,RC            ADDRESS WORK AREA.                   02000017
         USING CVT,RF              ADDRESS CVT.                  S21940 02400021
         LR    RC,R1               SAVE W.A. ADDRESS.                   02800017
         LA    RD,CKREGSAV         INITIALIZE SAVE AREA REG.            03200017
         L     R4,CKTCBAD          GET ADDR OF TCB.                     03600017
         L     RF,CVTPTR(R0)       GET CVT ADDR.                        04000017
**********************************************************************  04060017
*                                                                     * 04120017
*        CONSTRUCT AN XDAP, ECB, IOB, AND CHANNEL PROGRAM IN CHKWA    * 04180017
*                                                                     * 04240017
**********************************************************************  04300017
CHRBKPRB EQU   *                                                        04400017
         XC    DXECB(EICL),DXECB   ZERO OUT ECB/IOB/CCW WORK AREA       04800017
         MVC   IOBDCBPT(LNADDR),CVTJOB1      MOVE JOB Q DCB ADDR TO IOB 05200018
         LA    R3,DXECB            GET ADDR OF ECB.                     05600017
         ST    R3,IOBECBPT         STORE ECB ADDR IN IOB.               06000017
         LA    R2,DXCCW            GET ADDR OF CP.                      06400017
         ST    R2,IOBSIOCC         STORE CP ADDR IN IOB                 06800018
         MVC   DXCCW1(CCWL),CHRCCW1 MOVE READ IN CCWS TO W.A.           07200017
         LA    RE,DXDASEEK         GET ADDR OF IOBSEEK FIELD            07600018
         ST    RE,CHRAD            STORE IN CCW1.                       08000017
         MVC   DXCCW11(LNADDR),CHRAD1                                   08400018
         ST    R2,CHRAD            STORE CCW1 ADDR IN CCW2.             08800017
         MVC   DXCCW21(LNADDR),CHRAD1                                   09200018
         OI    IOBFLAG1,NOTREL     TURN ON IOB FLAGS.                   09600017
         L     R5,CVTJOB           GET ADDR OF JOB Q DCB.               10000017
         USING QJOB,R5             ADDRESS JOB Q WORK AREA.             10400017
         LA    RA,SCADEB           GET ADDR OF JOB Q DEB.               10800017
**********************************************************************  10860017
*                                                                     * 10920017
*        FOR PCP, CALCULATE JCT TTR                                   * 10980017
*                                                                     * 11040017
**********************************************************************  11100017
         TM    CKFLAG1,CKMVT+CKMFT     MVT OR MFT SYSTEM          MFTCR 11300018
         BM    CHRMVT2             BRANCH IF EITHER               MFTCR 11600018
         XR    R8,R8               CLEAR REGISTER.                      12000017
         IC    R8,SCARECPT         LOAD NUMBER OF RECORDS PER TRK.      12400017
         XR    R6,R6               CLEAR REGISTER FOR DIVIDE            12800017
         LA    R7,SDJCT            LOAD RECORD NUMBER                   13200017
         DR    R6,R8               DIVIDE NUMBER OF RECORDS PER         13600017
*                                  TRK INTO RECORD NUMBER.              14000017
         LA    R6,ADDONE(R6)       ADJUST RECORD BY ONE                 14400018
         SLL   R6,ADJR             SET RECORD TO BYTE 3                 14800018
         SLL   R7,ADJTT            SET TRACK TO BYTES 1 AND 2           15200018
         OR    R6,R7               FORM TTR.                            15600017
         LR    R0,R6               SET UP PARM REG FOR CONVERT ROUTINE. 16000017
**********************************************************************  16060017
*                                                                     * 16120017
*        BRANCH TO TTR CONVERT ROUTINE                                * 16180017
*                                                                     * 16240017
**********************************************************************  16300017
CHRTRAG  EQU   *                                                        16400017
CHRCOM   EQU   *                                                        16800017
         LR    R8,RC               SAVE ADDR OF W.A.                    17200017
         STM   R9,RD,CKREGSAV      SAVE REGS. 9-13 IN W.A.              17600017
         LR    R1,RA               LOAD JOB Q ADDR.                     18000017
         LA    R2,DXDAADDR         ADDR OF MBBCCHHR FIELD IN IOB.       18400017
         L     RF,CVTPCNVT         GET ADDR OF TTR CONVERT ROUTINE.     18800017
         DROP  RF                  CVT NO LONGER ADDRESSABLE     S21940 18850021
         BALR  RE,RF               GO TO CONVERT ROUTINE.               19200017
         DROP  RC                                                       19600017
         USING CHKWA,R8            ADDRESS CHKWA.                       20000017
         LM    R9,RD,CKREGSAV      RESTORE REGS. 9-13 FROM W.A.         20400017
         DROP  R8                                                       20800017
**********************************************************************  20860017
*                                                                     * 20920017
*        READ JCT INTO CHKWA                                          * 20980017
*                                                                     * 21040017
**********************************************************************  21100017
         USING CHKWA,RC                                                 21200017
         MVC   CKJCTMB(CKREGSAV-CKJCTMB),DXDAADDR                       21400018
*                                  SAVE JCT MBBCCHHR ADDR IN WA         21600018
         LA    R7,INJMJCT          LOAD READ-IN AREA ADDR.              22000017
         XDAP  (R3),RI,(R5),(R7),,,,MF=E     READ IN JCT.               22400017
**********************************************************************  22460017
*                                                                     * 22520017
*        WAIT FOR COMPLETION OF I/O AND TEST FOR SUCCESSFUL READ      * 22580017
*                                                                     * 22640017
**********************************************************************  22700017
         LR    R1,R3               ADDR OF I/O ECB.                     22800017
         WAIT  1,ECB=(1)           WAIT COMPLETION OF I/O.              23200017
         USING ECBSECT,R3          MAPPING OF ECB                       23400018
         CLI   IOCMPFLG,SUREAD     WAS READ SUCCESSFUL                  23600018
         DROP  R3                                                       23800018
         BNE   CHRQERRW             NO-GO TO ERROR ROUTINE              24000017
**********************************************************************  24060017
*                                                                     * 24120017
*        FOR CANCEL REQUEST, BRANCH TO XCTL TO EXIT ROUTINE           * 24180017
*                                                                     * 24240017
**********************************************************************  24300017
         TM    CKFLAG1,CKCANCEL    WAS CANCEL REQUESTED                 24400017
         BO    CHRQCOM             YES-GO TO EXIT ROUTINE.              24800017
         L     R8,CKPARMAD         GET ADDR OF PARM LIST.               25200017
         LR    RA,RC               GET ADDR OF W.A                      25600017
         A     RA,CKBFOFST         GET ADDR OF BUFFER.                  26000017
         SH    RA,HALFCHR          POINT TO BEGINNING OF CHR     S21940 26200021
         L     R5,CKDCBAD          GET ADDR OF CHKPT DCB.               26400017
         USING IHADCB,R5           ADDRESS CHKPT DCB.                   26800017
         USING CHRSECT,RA                                               27200017
**********************************************************************  27260017
*                                                                     * 27320017
*        INCREMENT JCTNRCKP FIELD IN JCT BY ONE                       * 27380017
*                                                                     * 27440017
**********************************************************************  27500017
         LH    RF,JCTNRCKP         GET NO. CHKPT'S TAKEN.               27600017
         LA    RF,ADDONE(RF)       UPDATE NO. CHKPT'S TAKEN             28000018
         STH    RF,JCTNRCKP        STORE UPDATED COUNT IN JCT           28400017
**********************************************************************  28460017
*                                                                     * 28520017
*        BRANCH TO GENERATE CHECKID IF USER DID NOT SUPPLY CHECKID    * 28580017
*                                                                     * 28640017
**********************************************************************  28700017
         TM    CKFLAG2,CKUSPCHD    DID USER SUPPLY CHECKID              28800017
         BZ    CHRGNID             NO-GO TO GENERATE ID.                29200017
         XR    R1,R1                                                    29600017
         USING PARMSECT,R8         MAPPING OF CHKPT PARMLST             29700018
         IC    R1,LNCHKID          GET LENGTH OF CHECKID                29800018
         L     RF,IDADDR           GET ADDR OF CHECKID                  29900018
**********************************************************************  30440017
*                                                                     * 30480017
*        UPDATE JCTCKIDL FIELD IN JCT                                 * 30520017
*        CONSTRUCT CHECKPOINT HEADER RECORD                           * 30560018
*                  CHRCOUNT - NUMBER CHECKPOINTS TAKEN                * 30600017
*                  CHRCKIDL - LENGTH OF CHECKID                       * 30640017
*                                                                     * 30680017
**********************************************************************  30720017
CHRSKP4  EQU   *                                                        30800017
         STH   R1,CHRCKIDL         MOVE CHECKID LENGTH TO BUFFER.       31200017
         MVC   CHRCOUNT(CHRCKIDL-CHRCOUNT),JCTNRCKP                     31400018
*                                  PUT NO. OF CHKPT IN CHR.             31600018
         STC   R1,JCTCKIDL         MOVE CHECKID LENGTH TO JCT.          32000017
**********************************************************************  32060017
*                                                                     * 32120017
*        INITIALIZE CHRCHKID FIELD IN JCT WITH CHECKID                * 32180017
*                                                                     * 32240017
**********************************************************************  32300017
CHRAG1   EQU   *                                                        32400017
         MVI   CHRCHKID,BLANK      INITIALIZE CHECKID FIELD WITH BLANKS 32800018
         MVC   CHRCKID2(LNG15),CHRCHKID                                 33200018
         BCTR  R1,0                DECREMENT COUNT FOR MOVES.           33600017
         EX    R1,CHRMVC1          MOVE CHECKID TO BUFFER.              34000017
**********************************************************************  34070017
*                                                                     * 34140017
*        RETURN SYSTEM-GENERATED CHECKID TO USER IF REQUESTED.        * 34210017
*                                                                     * 34280017
**********************************************************************  34350017
         L     RF,CKPARMAD         GET ADDR OF PARM LIST                34440017
         USING PARMSECT,RF         UPDATE NO. CHKPT'S TAKEN             34460018
         CLI   PARMFLG,NOID        REQUEST FOR RETURN OF GEN. CHECKID   34480018
         BE    CHRMVR              NO-SKIP CODE TO RETURN CHECKID       34520017
         CLI   LNCHKID,RETCKID     REQUEST FOR RETURN OF GEN. CHECKID   34560018
         BNE   CHRMVR              NO-SKIP CODE TO RETURN CHECKID.      34600017
         L     RF,IDADDR           GET ADDR OF CHECKID-RETURN-AREA      34620018
         DROP  RF                                                       34640018
         MVC   0(LNGENID,RF),CHRCHKID                                   34680018
*                                  MOVE CHECKID TO USER SPECIFIED       34690018
*                                  RETURN AREA                          34700018
**********************************************************************  34726017
*                                                                     * 34732017
*        BUILD REMAINDER OF CHR                                       * 34738017
*                                                                     * 34744017
**********************************************************************  34750017
CHRMVR   EQU   *                                                        34760017
         LH    RF,DCBTIOT          GET OFFSET TO CHKPT ENTRY IN TIOT.   34800017
         L     RE,TCBTIO           GET ADDR OF TIOT.                    35200017
         AR    RE,RF               GET ADDR OF CHKPT ENTRY IN TIOT.     35600017
         USING TIOELNGH,RE         ADDRESS CHKPT DD ENTRY IN TIOT.      36000017
*                                  FILL IN CHR WITH INFORMATION THAT    36200018
*                                  WILL BE NEEDED AT RESTART TIME       36400018
         MVC   CHRDDNM(CHRPPM-CHRDDNM),TIOEDDNM                         36600018
         MVC   CHRPPM(CHRBLKSI-CHRPPM),CKPPM                            36800018
         MVC   CHRPPML(CHRPADH-CHRPPML),CKPPML                          37000018
         MVC   CHRBLKSI(CHRTIOTL-CHRBLKSI),DCBBLKSI                     37200018
         MVC   CHRTIOTL(CHRFLAGS-CHRTIOTL),CKTIOTLN                     37400018
         MVC   CHRFLAGS(CHRWACL-CHRFLAGS),CKFLAG1                       37600018
         ST    RC,CHRCKWAD                                              38100018
         MVC   CHRFLAG2(CHRWACL-CHRFLAGS),CKFLAG2                       38300018
         MVC   CHRWACL(CHRFLAG2-CHRWACL),CKWACL1                        38500018
         MVC   CHRSVRB(CHRPPML-CHRSVRB),TCBRBP    ADDR OF CHKPT SVRB    38700018
*  SAVE VOL SEQ FOR RESTART TO USE TO OPEN MULTI-VOLUME CHKPT DATA SET  38720021
         MVI   CHRSVRB,K1          BPAM VOL SEQ = 1 INTO CHR    SA69185 38750021
         CLI   CKFLAG1,CKBPAM      IS CHKPT DATA SET BPAM       SA69185 38800021
         BE    CHRMVR1             BR IF YES, VOL SEQ = 1       SA69185 38820021
         L     R3,DCBDEBAD         POINT TO CHKPT DEB           SA51163 38850021
         USING DEBBASIC,R3         DEFINE BASE TO DEB BASE      SA69185 38860021
         SR    R1,R1               GET NUMBER OF TAPE OR        SA69185 38870021
         IC    R1,DEBNMEXT         DA EXTENTS                   SA69185 38880021
         IC    RF,DEBEXSCL         GET EXTENT SHIFT SIZE        SA69185 38890021
         SLL   R1,0(RF)            MULTIPLY BY 4 OR 16          SA69185 38900021
         AR    R3,R1               BYPASS DEB ENTENTS           SA69185 38910021
*                                  SAVE VOL SEQ IN CHR          SA69185 38920021
         MVC   CHRSVRB(K1),DEBVOLSQ+K1-DEBACSMD+DEBBASND-DEBBASIC(R3)   38930021
         DROP  R3                  DROP BASE TO DEB             SA69185 38940021
CHRMVR1  EQU   *                                                SA51163 38950021
*  SAVE VOL SEQ FOR IEFDSDRP TO USE DURING IMMEDIATE RESTART            39000021
         MVC   JCTVOLSQ,CHRSVRB    SAME VOL SEQ AS RESTART      SA69185 39050021
*                                                                       39100021
**********************************************************************  39260017
*                                                                     * 39320017
*        PAD REMAINDER OF BUFFER WITH ONES.                           * 39380017
*                                                                     * 39440017
**********************************************************************  39500017
         LR    R9,RC               CALCULATE NUMBER                     39600017
         A     R9,CKWACL           OF BYTES IN BUFFER                   40000017
         LA    RF,CHRPADH          THAT NEED TO BE PADDED WITH ONES.    40400017
         SR    R9,RF                                                    40800017
CHRAG2   EQU   *                                                        41200017
         MVI   CHRPADH,CHRPAD      MOVE A BYTE OF ONES TO BUFFER        41500018
         BCTR  R9,0                DECREMENT COUNT.                     41800017
CHRBPAD  EQU   *                                                        42000017
         CH    R9,CHRK256          ARE THERE MORE THAN 256 BYTES LEFT   42400021
         BH    CHRPADNG            YES-GO TO PAD 256 BYTES.             42800017
         BCTR  R9,0                DECREMENT                            43200017
         EX    R9,CERMVC3          PAD REST OF BUFFER WITH ONES.        43600017
**********************************************************************  43900017
*                                                                     * 44200017
*        SET PARAMETER REGISTER AND XCTL TO IGC0506C.                 * 44500017
*                                                                     * 44800017
**********************************************************************  45100017
CHREXL   EQU   *                                                        45900017
         MVC   CHRXL(LXCTLNAM),CHRXLIST                                 46100018
CHRXIT   EQU   *                                                        46400017
         LR    R1,RC               PLACE ADDR OF W.A. IN PARM REG.      46800017
         LA    RF,CHRXL            SET PARAMETERS FOR XCTL.             47200017
         ST    RF,CHRAD                                                 47600018
         LA    RF,CHRAD                                                 48000018
         XCTL  SF=(E,(15))         TRANSFER CONTROL TO CHKDCB.          48400017
CHRMVC1  MVC   CHRCHKID(1),0(RF)   EXECUTED MOVE OF CHECKID TO BUFFER.  48800017
**********************************************************************  48880017
*                                                                     * 48960017
*        ERROR ROUTINE WHEN I/O ERROR OCCURS READING JCT - SET CODE   * 49040017
*        AND XCTL TO EXIT ROUTINE, IGC0Q06C                           * 49120017
*                                                                     * 49200017
**********************************************************************  49280017
CHRQERRW EQU   *                                                        49400017
         MVI   CKRETCD2,CKIOERR    PUT RETURN CODE IN WA                49450018
         MVI   CKMSGCD2,CKERIO7    PUT MESSAGE CODE IN WA               49500018
         OI    CKFLAG2,CKMSG1      INDICATES WTO MESSAGE=NOT TAKEN      49550017
CHRQCOM  EQU   *                                                        52800017
         MVC   CHRXL(LXCTLNAM),CHRXLST MOVE IGCOQ06C TO XCTL PARMLST    53200018
         B     CHRXIT              GO TO TRANSFER CONTROL TO CER        53600017
**********************************************************************  53660017
*                                                                     * 53720017
*        GENERATE SYSTEM CHECKID AND STORE IN CHKWA                   * 53780017
*                                                                     * 53840017
**********************************************************************  53900017
CHRGNID  EQU   *                                                        54000017
         CVD   RF,CHRDEC           CONVERT BINARY COUNT TO PACKED DEC.  54400017
         UNPK  CHRCON(LNCNVID),CHRCHAR4(LNG5)   CONVERT TO UNPACKED DEC 54800018
         MVZ   CHRCON10(1),CHRCONC9                                     55200018
         MVI   CHRCONC2,CHARC      INSERT C INTO 1ST BYTE OF CHECKID    55500018
         LA    RF,CHRCONC2                                              55800018
         MVC   CKCHEKID(LNGENID),CHRCONC2                               56000018
*                                  MOVE GENERATED CHECKID TO CHKWA      56200018
         LA    R1,LNGENID          SUPPLY LENGTH OF GENERATED CHECKID   56500018
         B     CHRSKP4             GO TO UPDATE FIELDS IN JCT           56700018
**********************************************************************  56900017
*                                                                     * 57000017
* FOR MVT AND MFT GET THE TTR OF THE JCT FROM THE JSCB           M0367  57100020
*                                                                     * 57200017
**********************************************************************  57300017
CHRMVT2  EQU   *                                                        57600017
         L     R1,TCBJSCB         ADDRESS OF P/P JSCB           S21940  58600021
         USING IEZJSCB,R1                                        M0367  59600020
         L     R0,JSCBJCT         TTR OF JCT                     M0367  60600020
         SLL   R0,HIORDER         CLEAR LOW ORDER BYTE           M0367  61600020
         B     CHRTRAG            CONVERT TTR                    M0367  62600020
**********************************************************************  64060017
*                                                                     * 64120017
*        ROUTINE TO PAD BUFFER WITH 256 BYTES OF ONES.                * 64180017
*                                                                     * 64240017
**********************************************************************  64300017
CHRPADNG EQU   *                                                        64400017
         MVC   1(256,RF),0(RF)     PAD 256 BYTES OF BUFFER WITH ONES.   64800017
         AH    RF,CHRK256          UPDATE POINTER TO NEXT BYTE   S21940 65200021
*                                  IN BUFFER                     S21940 65201021
         SH    R9,CHRK256          UPDATE NUMBER-OF-BYTES-LEFT   S21940 65600021
*                                  COUNTER                       S21940 65601021
         B     CHRBPAD             GO TO CHECK IF BUFFER ALL PADDED     66000018
CERMVC3  MVC   1(1,RF),0(RF)       EXECUTE MOVE.PROPAGATES ONES THROUGH 66400017
*                                  REST OF BUFFER.                      66800017
*                                                                S21940 66801021
*****    CONSTANTS                                               S21940 66802021
*                                                                S21940 66803021
HALFCHR  DC    H'200'              HALF OF THE CHR LENGTH        S21940 66804021
CHRK256  DC    H'256'              MAX LNG FOR 'MVC' INSTRUCTION S21940 66805021
CHRXLST  DC    C'IGC0Q06C'         CHKPT EXIT RTN(ERROR OR CANCEL)      67100018
CHRXLIST DC    C'IGC0506C'         CHECK I/O(NORMAL FLOW)               67400018
*        MASK  USED FOR CONVERTING CHECKID TO UNPACKED DEC            * 67700018
CHREDIT  DC    X'2120202020202020'                                      68000017
         DC    X'2020'                                                  68400017
HIORDER  EQU   8         USED TO SHIFT TTR TO HIGH ORDER BYTES    MFTCR 68500018
*                                                                       68600018
*        CHANNEL PROGRAM USED BY ALL CHKPT RTN TO ACCESS JOB QUEUE    * 68700018
CHRCCW1  DC    X'31' SET OPCODE                                         68800017
         DC    AL3(0)    IOBSEEK+3 ADDR                                 69200017
         DC    X'40' FLAG BYTE                                          69600017
         DC    X'00'                                                    70000017
         DC    H'05' SET UP COUNT FIELD                                 70400017
CHRCCW2  DC    X'08' SET OPCODE                                         70800017
         DC    AL3(0)    ADDR OF CCW1                                   71200017
         DC    X'00000000' 2ND WORD IN CCW2                             71600017
CHRCCW3  DC    AL1(14) SET OPCODE                                       72000017
         DC    AL3(0)                                                   72400017
         DC    X'00' FLAG BYTE IN CCW3                                  72800017
         DC    X'00'                                                    73200017
         DC    H'176' LENGTH OF RECORD                                  73600017
*                                                                S21940 73612021
*********************************************************************** 73613021
*        PATCH AREA DEFINITION                                        * 73614021
*********************************************************************** 73615021
*                                                                S21940 73616021
LNG206C  EQU   *-IGC0206C          LENGTH BEFORE PATCH AREA      S21940 73617021
*                                                                S21940 73618021
PATCHLNG EQU   1024-LNG206C        PATCH AREA LENGTH             S21940 73619021
*                                                                S21940 73619221
         DC    (PATCHLNG)X'00'     ZEROED PATCH AREA             S21940 73619421
*                                                                S21940 73619621
         EJECT                                                   S21940 73619821
*                                                                     * 73620018
*        MAPPING OF ECB                                               * 73640018
*                                                                     * 73660018
ECBSECT  DSECT                                                          73680018
IOCMPFLG DS    1C        COMPLETION FLAG FOR I/O EVENT                  73700018
IORBPNT  DS    3C        RB ADDR WHILE WAITING FOR EVENT              * 73720018
*                                                                     * 73740018
*        MAPPING OF CHKPT PARAMETER LIST                              * 73760018
*                                                                     * 73780018
PARMSECT DSECT                                                          73800018
PARMFLG  DS    1C        BYTE INDICATING USER/SYSTEM/SYSTEM-RETURN CKID 73820018
PARMDCB  DS    3C        ADDR OF CHKPT DCB                              73840018
IDADDR   DS    0F                                                       73860018
LNCHKID  DS    CL1       LENGTH OF CHECKID OR INDICATES RETURN OF       73880018
*                        SYSTEM-GENERATED CHECKID                       73900018
         DS    CL3       CHECKID ADDR                                   73920018
*                                                                       73940018
*        MAPPING OF CHECKPOINT HEADER RECORD(CHR)                     * 73960018
*                                                                       73980018
CHRSECT  DSECT                                                          74000017
         DS    0D                                                       74400017
CHRCOUNT DS    H    NUMBER OF CHKPTS TAKEN                              74800017
CHRCKIDL DS    H    LENGTH OF CHECKID                                   75200017
CHRCHKID DS    4F   CHECKID                                             75600017
CHRDDNM  DS    2F   DDNAME OF CHECKPOINT DATA SET.                      76000017
CHRPPM   DS    CL4       LOW ORDER ADDR P/P CORE                        76200018
CHRPPE   DS    CL4       HIGH ORDER ADDRESS P/P CORE                    76400018
CHRBLKSI DS    CL2       CHKPT D.S.  BLKSIZE                            76600018
CHRTIOTL DS    CL2       LENGTH OF TIOT                                 76800018
CHRFLAGS DS    CL1       CHKPT FLAG 1                                   77000018
CHRWACL  DS    CL3       CHKPT W.A. LENGTH                              77200018
CHRCKWAD DS    0F                                                       77400018
CHRFLAG2 DS    CL1       CHKPT FLAG 2                                   77600018
CHRWAAD  DS    CL3       CHKPT W.A. ADDR                                77800018
CHRSVRB  DS    CL4       ADDR OF CHKPT SVRB                             78000018
CHRPPML  DS    CL4       LOW ORDER ADDR CHKPT SVRB                      78200018
CHRPPEL  DS    CL4       HIGH ORDER ADDR CHKPT SVRB                     78400018
CHRCKID2 EQU   CHRCHKID+1                                               78600018
CHRPADH  EQU   *    PADDING BEGINS HERE.                                80000017
         IEEVCHWA   CHRWA                                               80400017
*                                                                     * 80410018
*        WORK AREA USED FOR CONVERTING CHECKID TO PRINTABLE CHARACTERS* 80420018
*                                                                     * 80430018
CHRDEC   DS    0D                                                       80440018
CHRCHAR1 DS    3C        AREA FOR CHECKID TO BE CONVERTED               80450018
CHRCHAR4 DS    1C                                                       80460018
CHRCHAR5 DS    4C                                                       80470018
CHRCON   DS    0H        AREA  FOR CONVERTED CHECKID                    80480018
CHRCONC1 DS    1C        EXTRA BYTE USED FOR CONVERSION                 80490018
         DS    1C                                                       80500018
CHRCONC2 DS    3H        GENERATED NUMBER                               80510018
CHRCONC9 DS    CL1                                                      80520018
CHRCON10 DS    CL2       ZONE BYTE MUST BE UPDATED IN CONVERTED ID      80530018
CHRXL    DS    2F      NAME OF MODULE TO TRANSFER CONTROL TO            80640017
CHRAD    DS    0F        POINTER TO XCTL PARMLST(ALSO,WORK SPACE)       80660018
         DS    1C                                                       80680018
CHRAD1   DS    3C                                                       80700018
         EJECT                                                          80710021
*                                                                       80720018
*        JOB QUEUE WORK AREA                                          * 80740018
*                                                                       80760018
QJOB     DSECT                                                          80800017
SCALADCB DS    13F                                                      81200017
SCADEB   DS    12F                                                      81600017
SCATALLY DS    F                                                        82000017
SCASTRKS DS    H    TT OF FIRST TRACT IN Q.                             82400017
SCALTRKS DS    H    TT OF LAST TRACK IN Q.                              82800017
SCARECPT DS    CL1  NUMBER OF RECORDS PER PHYSICAL TRACK.               83200017
         IEFSD005                                                       83600017
         EJECT                                                          83800021
         IEEBASEA                                                       84000017
         EJECT                                                          84200021
         IEZJSCB                                                        84600020
         EJECT                                                          84800021
TIOTSECT DSECT                                                          85200017
         IEFTIOT1                                                       85600017
         EJECT                                                          85610021
CVT      DSECT ,                                                 S21940 85650021
         CVT   ,                                                 S21940 85700021
         EJECT                                                          85710021
         IKJTCB ,                                                S21940 85750021
         EJECT                                                          86000021
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               86400017
         EJECT                                                          86500021
         IEZDEB ,                  DATA EXTENT BLOCK            SA69185 86600021
         EJECT                                                          86700021
NOTREL   EQU   X'42' INDICATES COMMAND CHAINING AND  NON-RELATED CP.    86800017
NOID     EQU   X'80'               SIGNIFIES LAST WORD IN PARM LIST.    87000017
DDL      EQU   8         LENGTH OF TIOEDDNM FIELD                       87600017
CHRPAD   EQU   X'FF'     PADDING FOR CHR                                88000017
PREL     EQU   4              LENGTH OF CHECKID LENGTH FIELD IN CHR.    88400017
CCWL     EQU   24   LENGTH OF CHANNEL PROGRAM TO READ OR WRITE TO JOB Q 88800017
EICL     EQU   68   LENGTH OF  ECB/IOB/CCW WORK AREA                    89200017
CHRL     EQU   24   LENGTH OF PARM LIST IN CHR.                         89600017
SUREAD   EQU   X'7F'     RETURN CODE FOR SUCCESSFUL I/O COMPLETION.     90000017
CKMSG1   EQU   32                  WTO MSG-NOT TAKEN-ENVIRONMENT ERROR  90030017
CKERIO7  EQU   X'19'    I/O ERROR WHILE READING IN JCT                  90060017
*                                                                       90070018
*        ADDRESSING BYTES WITHIN DSECTS                                 90080018
*                                                                       90090018
CVTJOB1  EQU   CVTJOB+1            JOB Q DCB ADDR                       90100018
DXDASEEK EQU   DXDAADDR+3          ADDR OF IOBSEEK FIELD                90110018
CKTIOTLN EQU   CKTIOLN+2           ADDRESSING TIOT LNG IN CHKWA         90120018
DXCCW11  EQU   DXCCW1+1            1ST CCW                              90130018
DXCCW21  EQU   DXCCW2+1            2ND CCW                              90140018
CKTIOTL2 EQU   CKTIOLN+2           LENGTH OF TIOT IN CHKWA              90150018
CKWACL1  EQU   CKWACL+1            LENGTH OF CHKWA                      90160018
CKRETCD2 EQU   CKRETCOD+1          CHKPT RETURN CODE                    90170018
CKMSGCD2 EQU   CKMSGCOD+1     CHKPT MESSAGE CODE                        90180018
LXCTLNAM EQU   8         LENGTH OF MODULE NAME FOR XCTL PARMLST         90190018
LNADDR   EQU   3         LENGTH OF ADDRESS                              90200018
ADDONE   EQU   1         INCREMENT QUANTITY                             90210018
ADJR     EQU   8         USED TO ADJUST R OF TTR                        90220018
ADJTT    EQU   16        USED TO ADJUST TT OF TTR                       90230018
BLANK    EQU   C' '      BLANKS USED TO INITIALIZE CHECKID FIELD IN CHR 90240018
LNG15    EQU   15        MAXIMUM LENGTH OF CHECKID MINUS ONE            90250018
RETCKID  EQU   X'FF'     INDICATES USER REQ. RETURN OF GEN.CHECKID      90260018
LNCNVID  EQU   10             LENGTH OF CHECKID TO BE CONVERTED         90270018
LNGENID  EQU   8              LENGTH OF GENERATED CHECKID               90280018
LNJOBNAM EQU   8              JOB NAME LENGTH IN CSCB                   90290018
CHARC    EQU   C'C'      USED TO ALTER MODULE NAME TO IGC0206C          90300018
K1       EQU   1                   CONSTANT 1                   SA69185 90302021
LNG5     EQU   5         LNG USED IN UNPACK INSTRUC FOR CHECKID         90310018
 END                                                                    90400017
