         TITLE 'IGC0A06C (IHJACP20) -PRESERVE 1 (CHR)'                  00300018
IGC0A06C CSECT                                                          00700017
*FUNCTION/OPERATION  THIS ROUTINE WRITES OUT THE CHECKPOINT HEADER      01400017
*                    RECORD (CHR)                                       02100017
*                                                                       02800017
*ENTRY POINTS  IGC0A06C                                                 03500017
*                                                                       04200017
*INPUT  ADDRESS OF THE CHECKPOINT WORK AREA IN REGISTER 1               04900017
*                                                                       05600017
*OUTPUT  ADDRESS OF THE CHECKPOINT WORK AREA IN REGISTER 1              06300017
*                                                                       07000017
*EXITS-NORMAL                                                           07700017
*         1.) XCTL TO IGC0D06C TO WRITE OUT DSDRS                       08400017
*         2.) XCTL TO IGC0206C IF EOV OCCURS FOR THE FIRST TIME WITH    09100017
*                       CHKPT DATA SET ON TAPE                          09800017
*                                                                       10500017
*     -ERROR XCTL TO I/O RESUME AFTER INITIALIZING CKMSGCOD AND         11200017
*             CKRETCOD AS FOLLOWS                                       11900017
*                 CKRETCOD    CKMSGCOD     ERROR CONDITION              12600017
*                 X'000C'      X'0317'       I/O ERROR CREATING CHKPT   13300017
*                                                        DATA SET       14000017
*                  X'0008'     X'031B'       EOV ON DA OR FOR A SECOND  14700017
*                                              TIME ON TAPE             15400017
*                                                                       16100017
*TABLES/WORK AREAS  CHKWA,TCB,DCB,DEB                                   16800017
*                                                                       17500017
*ATTRIBUTES  REENTRANT, SUPERVISOR STATE, TYPE 4 SVC ROUTINE            18200017
*                                                                       18900017
*RESTRICTIONS  MAY NOT BE USED IN OS/MFT                                19600017
*                                                                       20300017
*NOTES NONE                                                             21000017
         EJECT                                                          21700017
         USING CHKWA,RC                                                 22400017
         BALR  RB,0                BASE ADDR.                           23100018
         USING *,RB                                                     23800017
         LR    RC,R1               GET ADDRESS OF CHKPT WORK AREA       24500017
         LA    RD,CKREGSAV                                              25200017
         L     R2,CKDCBAD          GET DCB ADDRESS                      25900017
         USING IHADCB,R2                                                26600017
*                                                                     * 26660018
*********************************************************************** 26720018
*        TESTING FOR END-OF-VOLUME ON CHKPT D.S.                      * 26780018
*        FOR DA - DEB ADDR IS SAVED AND USED FOR COMPARISON TO TEST   * 26840018
*          FOR EOV CONDITION BECAUSE EOV GETS A NEW DEB               * 26900018
*        FOR TAPE - VOLUME SEQUENCE NUMBER IN DEB IS SAVED AND USED   * 26960018
*          FOR TESTING AN EOV CONDITION BECAUSE EOV INCREMENTS VOL    * 27020018
*          SEQ NO                                                     * 27080018
*********************************************************************** 27140018
*                                                                     * 27200018
         L     RF,DCBDEBAD         GET DEB ADDRESS                      27300017
         TM    CKFLAG1,CKTAPE      IS CHKPT DATA SET ON TAPE            28000017
         BO    PRETAPE             BRANCH IF YES                        28700017
         MVC   CKTSTEOV(BYTE),DEBNMEXT(RF)   SAVE NUMBER OF EXTENTS FOR 29400018
*                                          END OF VOLUME TESTS          30100017
         B     PREBUFF             SKIP SAVING EOV INFO FOR TAPE        30800018
PRETAPE  EQU   *                                                        31500017
         USING DEBSECT,RF          MAPPING OF DEB                       31900018
         LA    RF,VOLSEQNO         GET ADDR OF VOLUME SEQ. NO. IN DEB   32300018
         ST    RF,CKTSTEOV         SAVE INFO FOR EOV TEST               32900017
         MVC   CKEOVCMR(LNWORD),ZERO(RF)                                33000018
*                                                                       33100018
*********************************************************************** 33200018
*                                                                     * 33300018
*        INITIALIZE CONTROL BLOCKS AND THEN WRITE CHR TO CHKPT D.S.   * 33400018
*                                                                     * 33500018
*********************************************************************** 33600018
*                                                                     * 33700018
PREBUFF  EQU   *                                                        34300017
         LR    R9,RC                                                    35000017
         A     R9,CKBFOFST         GET ADDRESS OF BUFFER                35700017
         SH    R9,=H'200'                                               36400017
         ST    R9,PRENXB           INITIALIZE OUTPUT BUFFER HANDLER'S   37100017
         MVC   PRENOB(LNWORD),DSDRLN         PARAMETERS                 37800018
         ST    R9,CKAREA1                                               38500017
         LA    RF,CHRLN                                                 39200017
         STH   RF,CKLNGTH1         INITIALIZE DECB1                     39900017
         LA    R9,PRESYNAD         MODIFY DCBSYNAD SO THAT PRESERVE     40600017
         ST    R9,PREAD            SYNAD WILL GET CONTROL IF I/O ERROR  41300017
         MVC   DCBSYN1(LNADDR),PREAD2            OCCURS                 42000018
         LA    R9,CKDECB1          GET DECB ADDRESS                     42700017
         WRITE (R9),SF,,,,,,MF=E   WRITE OUT CHR                        43400017
         CHECK (R9)                                                     44100017
         OI    CKFLAG2,CKCHR       SET FLAG - CHR WRITTEN               44800017
*                                                                     * 44808018
*********************************************************************** 44816018
*                                                                     * 44824018
*        TEST FOR SUCCESSFUL WRITE - I/O ERROR OR EOV CONDITION       * 44832018
*        IF ERROR OCCURS STORE ERROR CODES IN CHKWA AND XCTL TO       * 44840018
*        IGC0N06C - CHKPT D.S. NOT COMPLETED                          * 44848018
*                                                                     * 44856018
*********************************************************************** 44864018
*                                                                     * 44872018
         TM    CKFLAG1,CKTAPE      CHKPT DATA SET ON TAPE               44880017
         BO    PRETAEOV            BRANCH IF YES                        44960017
         L     RF,DCBDEBAD         GET DEB ADDRESS                      45040017
         CLC   CKTSTEOV(BYTE),DEBNMEXT(RF)   NUMBER OF EXTENTS CHANGED  45120018
         BNE   PREOVER             BRANCH IF YES--EOV ON D.A. ERROR     45200017
         B     PREIOCHK            BRANCH TO CHECK FOR I/O ERROR        45280017
PRETAEOV EQU   *                                                        45360017
         L     RF,CKTSTEOV                                              45500017
         CLC   ZERO(LNWORD,RF),CKEOVCMR      DID EOV OCCUR              46200018
         BNE   PREEOV              BRANCH IF YES                        46900017
PREIOCHK EQU   *                                                        47200017
         CLI   CKRETCD1,CKIOERR    DID I/O ERROR OCCUR                  47700018
         BE    PREERXIT            BRANCH IF YES                        48300017
         TM    CKFLAG1,CKBPAM      IS CHKPT DATA SET OPENED FOR BPAM    49000017
*                                                                     * 49070018
*********************************************************************** 49140018
*                                                                     * 49210018
*        IF CHKPT D.S BPAM - NOTE CHR SO THAT D.S CAN BE STOWED UNDER * 49280018
*        CHECKID IN CHKPT EXIT RTN                                    * 49350018
*                                                                     * 49420018
*********************************************************************** 49490018
*                                                                     * 49560018
         BZ    PREXIT              BRANCH IF NO--SKIP NOTE              49700017
         NOTE  (R2)                                                     50400017
         ST    R1,CKTTR            SAVE NOTED TTRZ                      51100017
*                                                                     * 51180018
*********************************************************************** 51260018
*                                                                     * 51340018
*        TRANSFER CONTROL TO NEXT MODULE                              * 51420018
*                                                                     * 51500018
*********************************************************************** 51580018
*                                                                     * 51660018
PREXIT   EQU   *                                                        51800017
         MVC   PRESV(LXCTLST),PREDSDR   TRANSFER CONTROL TO IGC0D06C    52500018
PREOUT   EQU   *                                                        53200017
         LR    R1,RC               PUT W. A. ADDRESS IN PARM REG        53900017
         LA    RF,PRESV            SET UP PARAMETER LIST FOR XCTL       54600017
         ST    RF,PRESV8                                                55300018
         LA    RF,PRESV8                                                56000018
         XCTL  SF=(E,(15))         TRANSFER CONTROL TO NEXT MODULE      56700017
*                                                                     * 56750018
*********************************************************************** 56800018
*        EOV ERROR RTN - IF CHKPT D.S. ON DISC, CHKPT NOT CONTINUED   * 56850018
*        AND CONTROL IS TRANSFERED TO IGC0N06C TO RESTORE I/O AND EXIT* 56900018
*        IF CHKPT D.S. ON TAPE, CONTROL IS TRANSFERED TO IGC0206C TO  * 56950018
*        ATTEMPT TO WRITE A COMPLETE ENTRY ON ONE VOLUME. IF EOV      * 57000018
*        OCCURS FOR A 2ND TIME ON TAPE(INDICATING ONE ENTRY CANNOT FIT* 57050018
*        ON ONE VOLUME) CHKPT IS NOT CONTINUED AND THE SAME PATH IS   * 57100018
*        FOLLOWED AS EOV ON DISC.                                     * 57150018
*                                                                     * 57200018
*********************************************************************** 57250018
*                                                                     * 57300018
PREEOV   EQU   *                                                        57400017
         TM    CKFLAG2,CKEOV       HAS EOV OCCURRED BEFORE              58100017
         BO    PREOVER             BRANCH YES - ERROR                   58800017
         OI    CKFLAG2,CKEOV       SET EOV FLAG                         60900017
         MVC   PRESV(LXCTLST),PREDSDR   SET UP XCTL PARM LIST           61600018
         MVI   PRESV4,CHAR2                                             62300018
         B     PREOUT              GO TO ISSUE XCTL                     63000018
PREOVER  EQU   *                                                        63700017
         MVI   CKRETCD1,CKPGMERR   INDICATE PROGRAMMER ERROR            64400018
         LA    RA,CKERIO7                                               65100017
         STH   RA,CKMSGCOD         PUT ERROR CODE IN WORK AREA          65800017
PREMVER  EQU   *                                                        66500017
         MVC   PRESV(LXCTLST),PREIORE   MOVE IORESUME'S NAME TO XCTLIST 66600018
*                                                                     * 66700018
*********************************************************************** 66800018
*                                                                     * 66900018
*        I/O ERROR AND SYNAD RTN. WHEN AN I/O ERROR OCCURS PRESERVE'S * 67000018
*        SYNAD RTN GETS CONTROL FROM DCB SYNAD EXIT AND CKRETCOD FIELD* 67100018
*        IN CHKWA IS SET TO INDICATE I/O ERROR CCCURED. CONTROL IS RE-* 67200018
*        TURNED FROM SYNAD RTN. AFTER WRITE IS CHECK'D CKRETCOD IS    * 67300018
*        TESTED FOR I/O ERROR,IN WHICH CASE CONTROL IS TRANSFERED TO  * 67400018
*        IGC0N06C TO RESTORE I/O AND EXIT                             * 67500018
*                                                                     * 67600018
*********************************************************************** 67700018
*                                                                     * 67800018
         B     PREOUT              GO TO XCTL                           67900017
PREERXIT EQU   *                                                        68600017
         LA    RA,CKERIO3          I/O ERROR WRITING CHKPT DATA SET     69300017
         STH   RA,CKMSGCOD         PUT IN WORK AREA                     70000017
         B     PREMVER             BRANCH TO SET UP FOR EXIT            70700017
PRESYNAD EQU   *                                                        71400017
         MVI   CKRETCD1,CKIOERR    MOVE RETURN CODE TO WORK AREA        72100018
         BR    RE        RETURN                                         72800018
CKERIO3  EQU   X'0317'             WRITE UNSUCCESSFUL                   73500017
CKERIO7  EQU   X'031B'             INVALID EOV                          74200017
DEBNMEXT EQU   16                                                       74500017
CHRLN    EQU   400       LENGTH OF CHR                                  74600018
LNWORD   EQU   4         WORD LENGTH                                    74700018
LNADDR   EQU   3         ADDRESS LENGTH                                 74800018
LXCTLST  EQU   8         LENGTH OF XCTL PARM LST                        74900018
BYTE     EQU   1         LENGTH OF BYTE (NO. EXTENTS IN DEB)            75000018
ZERO     EQU   0         USED FOR ADDRESSING                            75100018
CHAR2    EQU   C'2'      CHARACTER NEEDED TO ALTER MODULE NAME TO 206C  75200018
DSDRLN   DC    F'400'              LENGTH OF DSDRS AND CHR              75600017
*        MODULE NAMES USED IN XCTL PARMLST                            * 75900018
PREDSDR  DC    C'IGC0D06C'         PRESERVE 2(NORMAL FLOW)              76400018
PREIORE  DC    C'IGC0N06C'         RESUME I/O (I/O ERROR)               77000018
CKCHR    EQU   128                                                      77700017
*        MAPPING OF DEB TO GET VOLUME SEQUENCE NO                       77800018
DEBSECT  DSECT                                                          77900018
INITIAL  DS    9F        INITIAL SECTION OF DEB                         78000018
VOLSEQNO DS    1F        VOLUME SEQUENCE NO  FOR TAPE                   78100018
         IEEVCHWA                                                       78400017
CKTSTEOV EQU   CKUNIT                                                   79100017
CKEOVCMR EQU   CKUNIT+4                                                 79800017
         IEFJFCBN                                                       80500017
         ORG   INFMJFCB                                                 81200017
         IEFASIOT                                                       81900017
PRESV    DS    1F        XCTL PARM LIST - MODULE NAME                   82200018
PRESV4   DS    1C                                                       82500018
PRESV5   DS    CL3                                                      82800018
PRESV8   DS    1F        POINTER TO PARMLST                             83100018
PRENXB   DS    1F        ADDR OF BUFFER                                 83400018
PRENOB   DS    1F        LENGTH OF BUFFER                               83700018
*        OUTPUT BUFFER HANDLER'S PARAMETERS                             84000018
PREAD    DS    0F        WORK AREA FOR ADDRESSES                        84300018
         DS    1C                                                       84600018
PREAD2   DS    3C                                                       84900018
*        INFO FOR TEST OF EOV CONDITION                               * 85200018
PREADEOV DS    1F        ADDRESS OF TEST FOR EOV CONDITION              85500018
PRNEOV   DS    1F        VALUE USED IN TEST FOR EOV CONDITION           85800018
PRESAVE  DS    12F       SAVE AREA                                      86100018
PRELNGTH EQU   *                                                        87500017
         IHBABCTL                                                       88200017
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               88900017
*        ADDRESSING BYTES WITHIN WORD                                   89000018
DCBSYN1  EQU   DCBSYNAD+1     DCB SYNAD ADDRESS                         89100018
CKRETCD1 EQU   CKRETCOD+1     RETURN CODE FIELD IN CHKWA                89200018
         END                                                            89600017
