*                                                                       00010020
         GBLC  &LIB                     DEFINE GLOBAL CHARACTER         00020020
*                                       * VARIABLE.                     00030020
&LIB     SETC  'LIB1'                   SET VALUE FOR &LIB              00040020
*                                                                       00050020
         TITLE 'IGC0D06C (IHJACP25) PRESERVE2 (DSDR)'                   00100018
IGC0D06C CSECT                                                          00400017
*        RELEASE 23 DELETIONS/CHANGES                                   00450021
*        RELEASE 22 DELETIONS/CHANGES                                   00460021
*        RELEASE 21.8 DELETIONS/CHANGES                                 00461021
*0000040000-048000,190800-191000,206000-210000,218000-258000,   SA69185 00462021
*0000272000,643000,660000,671080,724960,725120,725280,725840    SA69185 00463021
*0000198500-199000,218000-220000                                SM00230 00464021
*        RELEASE 21 DELETIONS/CHANGES                                   00470021
*092000,116000,152000,158000,166000-168000,186000-188000,        S21940 00470421
*193200,193380,193560,220100,222400,230000,240600,242000,        S21940 00470821
*368000,414700,414900,424000,466000,488000,512000,               S21940 00471221
*652000-656000,671000,722000-723200,724480                       S21940 00474221
*D220400-221300                                                 SA51163 00480021
*262000                                                           M2192 00500018
*221200                                                          A27257 00550019
*FUNCTION/OPERATION   THE MAIN PURPOSE OF THIS ROUTINE IS TO WRITE OUT  00600017
*                   DATA SET DESCRIPTION RECORDS (DSDRS).FOR EACH DATA  00800017
*                   SET, PRESERVE WILL CONSTRUCT AND WRITE OUT A TYPE 1 01000017
*                   DSDR.A TYPE 1 DSDR CONTAINS THE DATA SET'S JFCB,    01200017
*                   ITS DDNAME, AND THE UCBTYP FIELD FROM ITS UCB. IF   01400017
*                   THERE IS A JFCB EXTENSION BLOCK (JFCBX) ASSOCIATED  01600017
*                   WITH THE DATA SET, PRESERVE WILL WRITE OUT A TYPE 2 01800017
*                   DSDR. A TYPE 2 DSDR CONTAINS JUST THE JFCBX. WHEN   02000017
*                   ALL THE JFCBS AND JFCBXS HAVE BEEN PROCESSED,       02200017
*                   PRESERVE WILL READ IN THE GDG BIAS COUNT TABLE (IF  02400017
*                   THERE IS ONE) AND WILL CONSTRUCT AND WRITE OUT A    02600017
*                   TYPE 3 DSDR.A TYPE 3 DSDR CONTAINS JUST THE GDG     02800017
*                   BIAS COUNT TABLE. WHEN ALL THE DSDRS HAVE BEEN      03000017
*                   WRITTEN OUT, PRESERVE WILL XCTL TO CHKMAIN.         03200017
*                     TO READ RECORDS FROM THE JOB QUEUE, PRESERVE USES 03400017
*                   THE XDAP ECB, IOB, AND CHANNEL PROGRAM CONSTRUCTED  03600017
*                   IN THE WORK AREA BY IGC0206C.                       03800017
*                     THE JFCBMASK+6,X'20' BIT OF THE JFCB IN DSDR      04000021
*                   WILL BE TURNED ON TO INDICATE DEFERRED MOUNTING     04200021
*                   DURING DEFERRED RESTART IF SEQUENTIAL TAPE OR DISK  04400021
*                   DATA SET IS NOT CURRENTLY PROCESSING THE FIRST      04600021
*                   VOLUME AND THUS AVOID INEFFICIENT MOUNTING.         04800021
*ENTRY POINTS:                                                          05000017
*INPUT:  ADDRESS OF CHKPT WORK AREA IN REGISTER 1.                      05200017
*OUTPUT:  ADDRESS OF CHKPT WORK AREA IS IN REGISTER 1.                  05400017
*EXITS-NORMAL: THIS ROUTINE WILL XCTL TO CHKMAIN.                       05600017
*EXITS-ERRORS:  IF A PERMANENT I/O ERROR OCCURED, THIS ROUTINE WILL PUT 05800017
*              THE ADDRESS OF THE CHKPT WORK AREA IN REGISTER 1 AND     06000017
*              XCTL TO IORESUME.                                        06200017
*              THE RETURN CODE IN CHRWA IS SET TO X'OC' AND ONE OF THE  06400017
*              FOLLOWING MESSAGE CODES WILL BE PLACED IN CHKWA:         06600017
*              1.) X'0317'  I/O ERROR WHILE CREATING CHKPT DATA SET     06800017
*              2.) X'0316'  I/O ERROR READING RECORDS FROM JOB QUEUE    07000017
*TABLES/WORK AREAS:  CHKWA DSECT,JCT,JFCB,JFCBX,TCB,UCB,SIOT,DSENQ      07200017
*                  TABLE, GDG BIAS COUNT TABLE.                         07400017
*ATTRIBUTES:  REENTRANT,SUPERVISOR STATE,TYPE 4 SVC ROUTINE.            07600017
*RESTRICTIONS ON USE OF ROUTINE:  MAY NOT BE USED IN OS/MFT.            07800017
*NOTES:  NONE                                                           08000017
         EJECT                                                          08100021
         USING CHKWA,RC            ADDRSSS W.A.                         08200017
         BALR  RB,0                SET UP MODULE ADDRESSABILITY.        08400017
         USING *,RB                                                     08600017
         LR    RC,R1               SET UP CHKPT W.A. ADDRESSABILITY.    08800017
*********************************************************************** 08820018
*                                                                     * 08840018
*        INITIALIZE CONTROL BLOCKS FOR WRITING DSDR'S                 * 08860018
*                                                                     * 08880018
*********************************************************************** 08900018
*                                                                     * 08920018
         L     R8,CVTPTR           GET CVT ADDR.                        09000017
         USING CVT,R8              ADDRESS CVT.                  S21940 09200021
         USING IHADCB,R2      ADDRESS CHKPT DCB                         09400017
         LA    RD,CKREGSAV         INITIALIZE SAVE AREA REG.            09600017
         L     R2,CKDCBAD          GET DCB ADDR                         09800017
         LA    R3,DXECB            GET ADDR OF ECB.                     10000017
         L     R5,CVTJOB           GET ADDR OF JOB Q DCB.               10200017
         USING QJOB,R5             ADDRESS JOB Q DCB.                   10400017
         LA    R4,SCADEB           GET ADDR OF JOB Q DEB.               10600017
         LA    R9,PRESYNAD         MODIFY DCBSYNAD SO THAT              10800017
         ST    R9,PREAD            PRESERVE SYNAD ROUTINE WILL          11000017
         MVC   DCBSYND(LNADDR),PREAD3   GET CONTROL IF I/O ERROR OCCURS 11200018
         DROP  R5                                                       11400017
         USING TCB,R6              ADDRESS TCB.                  S21940 11600021
         L     R6,CKTCBAD          GET ADDR OF TCB.                     11800017
         L     R6,TCBTIO           GET ADDR OF TIOT.                    12000017
         USING TIOT1,R6            ADDRESS TIOT.                        12200017
         LA    R6,TIOELNGH         GET ADDR OF DD ENTRY.                12400017
         DROP  R6                                                       12600017
         USING TIOELNGH,R6         ADDR DD ENTRY IN TIOT.               12800017
*                                                                     * 12820018
*********************************************************************** 12840018
*        BET JFCB TTR FROM TIOT ENTRY - READ IN JFCB                  * 12860018
*        FOR SUBALLOCATE REQUEST A SIOT IS READ FROM JOB QUEUE, JFCB  * 12880018
*        TTR EXTRACTED FROM SIOT AND THEN JFCB READ INTO CORE         * 12900018
*                                                                     * 12920018
*********************************************************************** 12940018
*                                                                     * 12960018
PREXL    EQU   *                                                        13000017
PREAG3   L     R0,TIOEJFCB         GET JFCB TTR.                        13200017
         IC    R0,PREZERO          FILL IN CONCATENATION NUMBER.        13400017
         BAL   RA,PRECONV          GO TO CONVERT TTRN TO MBBCCHHR.      13600017
         LA    R7,INFMJFCB         LOAD READ IN ADDRESS                 13800017
         BAL   RA,PREQR            READ IN RECORD.                      14000017
PRESEQCK EQU   *                                                        14600017
         DROP  R2                                                       14800017
         L     R9,CKTCBAD          GET TCB ADDRESS                      15000017
         USING TCB,R9                                            S21940 15200021
         L     RF,TCBTIO           GET TIOT ADDRESS                     15400017
         L     R9,TCBDEB           GET DEB QUEUE ADDRESS                15600017
         USING DEBBASIC,R9                                       S21940 15800021
*                                                                     * 15820018
*********************************************************************** 15840018
*                                                                     * 15860018
*        SEARCH THROUGH DEB CHAIN TO FIND ASSOCIATEDDCB WITH JFCB JUST* 15880018
*        READ         IN ORDER TO GET UCB ADDR FOR THE D.S.           * 15900018
*                                                                     * 15920018
*********************************************************************** 15940018
*                                                                     * 15960018
PRENXTDB EQU   *                                                        16000017
         LTR   R9,R9               IS THERE ANOTHER DEB                 16200017
         BZ    PREBK               BRANCH IF NO                         16400017
         L     RA,DEBDCBAD         GET ADDRESS OF DCB ASSOCIATED S21940 16600021
*                                  WITH THIS DEB                 S21940 16800021
         USING IHADCB,RA                                                17000017
         LH    R0,DCBTIOT          GET INCREMENT TO TIOT DD ENTRY       17200017
         AR    R0,RF               GET ADDRESS OF TIOT DD ENTRY BY      17400017
*                                  ADDING DCB INCREMENT TO TIOT         17600017
*                                  ADDRESS                              17800017
         CR    R0,R6               IS THIS DEB ASSOCIATED WITH THE      18000017
*                                  TIOT ENTRY CURRENTLY BEING PROCESSED 18200017
         BE    PREDCB              BRANCH IF YES                        18400017
         L     R9,DEBDEBAD         GET POINTER TO NEXT DEB       S21940 18600021
         LA    R9,DEBTCBAD         CLEAR HIGH ORDER BYTE OF DEB  S21940 18800021
*                                  POINTER                       S21940 18850021
         B     PRENXTDB            BRANCH TO TEST NEXT DEB              19000017
*                                                                     * 19020018
*********************************************************************** 19040018
*                                                                     * 19060018
*        RESTORE SYSIN/SYSOUT I/O AND ALLOW IT TO COMPLETE, BECAUSE IT* 19080021
*        CANNOT BE RESTARTED TO NEW DATA SETS WITH DEFERRED RESTART.  * 19100021
*                                                                     * 19120018
*********************************************************************** 19140018
PREDCB   EQU   *                                                        19200017
         USING INFMJFCB,R7                                              19206017
         TM    JFCBTSDM,X'20'      IS THIS SYSIN OR SYSOUT              19212017
         BZ    NOPURGE             BRANCH IF NO                         19218017
TESTPRGE EQU   *                                                        19224017
         TM    DEBUSRPG+3,NOTPRGD  DID PURGE TAKE PLACE                 19230017
         BO    NOPURGE             BRANCH IF NO                         19236017
         L     RE,DEBUSRPG         LOAD ADDR OF PURGED IOB              19242017
         LA    RE,0(RE)            CLEAR HIGH ORDER BYTE                19248017
         LTR   RE,RE               DID PURGE TAKE PLACE                 19254017
         BZ    NOPURGE                                                  19260017
         RESTORE   DEBUSRPG        RESTORE PURGED IOBS                  19266017
         L     R1,IOBECBAD(RE)     GET ADDR OF RESTORED IOB             19272017
         WAIT  1,ECB=(1)           WAIT FOR COMPLETION                  19278017
         XC    PURGWD2(4),PURGWD2  ZERO SECOND WORD OF PURGE PARAMS     19284017
         ST    R9,PURGDEB          STORE DEB ADDR IN PURGE PARMS        19290017
         MVI   PURGDEB,PURGEOPT    MOVE IN PURGE OPTIONS                19296017
         LA    RE,DEBUSRPG         WHERE ADDR OF FIRST PURGED IOB IS    19302017
*                                  PUT                                  19308017
         ST    RE,PURGLST          STORE IN PURGE PARMS                 19314017
         L     RE,DEBSUCBA         SAVE UCB ADDRESS              S21940 19320021
         TM    DCBDSORG,INDSEQ     ISAM DATA SET                        19326017
         BZ    PURGE               BRANCH IF NO                         19332017
         MVC   DEBSUCBB,DEBSUCBB+16   RESET UCB ADDR IN DEB      S21940 19338021
PURGE    EQU   *                                                        19344017
         PURGE PURGDEB                                                  19350017
         ST    RE,DEBSUCBA         RESTORE UCB ADDRESS IN DEB    S21940 19356021
         B     TESTPRGE            GO SEE IF PURGE TOOK PLACE           19362017
NOPURGE  EQU   *                                                        19368017
         DROP  R7                                                       19374017
*                                                                       19376021
*********************************************************************** 19378021
*                                                                     * 19380021
*        FOR SEQUENTIAL TAPE AND DISK DATA SETS, IF NOT CURRENTLY     * 19382021
*        PROCESSING THE FIRST VOLUME, SET JFCBMASK+6,X'20' TO         * 19384021
*        INDICATE DEFER MOUNT DURING DEFERRED RESTART SO THAT         * 19386021
*        SCHEDULER DOES NOT WASTE TIME MOUNTING THE FIRST             * 19388021
*        VOLUME WHEN RESTART WILL WANT A DIFFERENT VOLUME.            * 19390021
*                                                                     * 19392021
*********************************************************************** 19394021
*                                                                       19396021
         TM    DCBDSORG,QSAMBSAM   IS DATA SET OPENED FOR QSAM OR BSAM  19400017
*                                  PROCESSING                           19600017
         BZ    PREBK               BRANCH IF NO                         19800017
         L     RF,TIOESTTB         GET ADDRESS OF ASSOCIATED UCB        20000018
         USING UCBSECT,RF                                               20200017
         CLI   UCBID,MAINUCB       IS THIS A MAIN UCB                   20400018
         BE    PREMAINU            BR IF YES, NOT 2321          SA69185 20500021
         USING UCBDCELL,RF         DEFINE BASE TO 2321 SUB UCB  SA69185 20600021
         CLC   UCBDVOLI,JFCBVOLS   IS THIS FIRST VOL SER NO.    SA69185 20700021
         BE    PREBK               BR IF YES                    SA69185 20800021
         B     PRESEQBT            BR NO TO SET DEFER MOUNT     SA69185 20900021
         USING UCBSECT,RF          DEFINE BASE TO MAIN UCB      SA69185 21000021
PREMAINU EQU   *                                                SA69185 21100021
         TM    UCBTBYT3,NOTTAPDA   IS THIS A TAPE OR DIRECT ACCESS      21200017
*                                  DEVICE                               21400017
         BNZ   PREBK               BRANCH IF ITS NOT                    21600018
         TM    UCBTBYT3,PRETAPE    IS IT A TAPE                         21800021
         BNE   PREDA               BRANCH IF NO-- ITS D. A.             22000021
         MVC   JFCBFSEQ(1),SRTEFSCT+1 SAVE TAPE PHYSICAL FILE   SA60703 22002021
*                                  SEQUENCE NUMBER              SA60703 22004021
PREDA    EQU   *                                                SA69185 22005021
         CLC   DEBDCBB,CKDCB1      IS THIS CHKPT D.S. DEB        S21940 22010021
         BE    PREBK               BR IF YES, NO DEFER MOUNT    SA69185 22020021
         CLC   UCBVOLI,JFCBVOLS    IS THIS FIRST VOL SER NO.    SA69185 22400021
         BE    PREBK               BR IF YES                    SA69185 22600021
*                                                                       25800021
PRESEQBT EQU   *                                                        26000017
         OI    JFCBMASK+K6,DEFMOUNT    SET BIT TO CAUSE DSDR TO   M2192 26200018
*                                  MARK SIOT FOR THIS DATA SET FOR      26400017
*                                  DEFERRED MOUNTING AT RESTART TIME    26600017
*                                                                       26650021
*********************************************************************** 26700021
*                                                                     * 26750021
*        WRITE DSDR FOR JFCB, JFCBX, GDG                              * 26800021
*                                                                     * 26850021
*********************************************************************** 26900021
*                                                                       26950021
         USING IHADCB,R2                                                27000017
         DROP  RF,R9,RA                                         SA69185 27200021
PREBK    EQU   *                                                        27400017
         XR    R9,R9               LOAD RECORD CODE.                    27600017
         BAL   RA,PREOBH           GO TO OUTPUT BUFFER HANDLER.         27800017
         MVC   PREAD(LNADDR),JFCBEXAD        GET JFCBX TTR              28000018
         L     R0,PREAD                                                 28200017
         IC    R0,PREZERO          SET CONCATENATION NUMBER TO ZERO.    28400017
         LTR   R0,R0               IS THERE A JFCBX                     28600017
         BNZ   PREJFCBX            GO TO READ IN JFCBX.                 28800017
PRENXTI  EQU   *                                                        29000017
         XR    R9,R9                                                    29200017
         IC    R9,TIOELNGH         GET LENGTH OF THIS DD ENTRY.         29400017
         AR    R6,R9               GET ADDR OF NEXT DD ENTRY.           29600017
         NC    TIOELNGH(LNWORD),TIOELNGH     HAVE ALL JFCBS BEEN        29700018
*                                            PROCESSED                  29800018
         BNZ   PREAG3              NO-PROCESS NEXT JFCB.                30000017
         L     R0,JCTBCTDA         GET TTRN OF GDG BIAS COUNT TABLE.    30200017
PRENXGDG EQU   *                                                        30400017
         LTR   R0,R0               IS THERE A GDG.                      30600017
         BZ    PRESKP3             NO-SKIP GDG PROCESSING               30800017
         BAL   RA,PRECONV          GO TO CONVERT TTRN TO MBBCCHHR       31000017
         BAL   RA,PREQR            GO TO READ IN GDG.                   31200017
         LA    R9,COGDG            LOAD RECORD CODE.                    31400017
         BAL   RA,PREOBH           GO TO OUTPUT BUFFER HANDLER.         31600017
         L     R0,GDGTAB           GET TTR OF NEXT GDG TABLE            31800018
         IC    R0,PREZERO          FILL IN CONCATENATION NUMBER.        32000017
         B     PRENXGDG            GO TO PROCESS NEXT GDG TABLE.        32200017
PRESKP3  EQU   *                                                        32400017
PREXIT   EQU   *                                                        32600017
         LA    R9,DSDREND          LOAD END-OF-DSDRS CODE.              32800017
         BAL   RA,PREOBH           GO TO WRITE OUT LAST DSDR.           33000017
         MVC   PRESV(LNMODNAM),PREXMN   MOVE CHKMAIN MOD NAME TO XCTLST 33200018
PREOUT   EQU   *                                                        33400017
         LR    R1,RC               PUT ADDR OF W.A. IN PARM REG.        33600017
         LA    RF,PRESV            SET UP PARAMETER LIST FOR XCTL.      33800017
         ST    RF,PRELSTAD                                              33900018
         LA    RF,PRELSTAD                                              34000018
         XCTL  SF=(E,(15))         TRANSFER CONTROL TO NEXT MODULE.     34400017
PREQR    XDAP  (R3),RI,(R5),(R7),,,,MF=E   READ A RECORD FROM JOB Q.    34600017
         LR    R1,R3               ADDR OF I/O ECB.                     34800017
         WAIT  1,ECB=(1)           WAIT COMPLETION OF I/O.              35000017
         USING ECBSECT,R3                                               35100018
         CLI   CMPCODE,SUREAD      WAS READ SUCCESSFUL                  35200018
         DROP  R3                                                       35300018
         BNE   PREQERRX             NO-GO TO ERROR ROUTINE.             35400017
         BR    RA                  YES-RETURN TO CALLER.                35600017
PRECONV  LR    R8,RC               SAVE ADDR OF W.A.                    35800017
         STM   R9,RD,CKREGSAV      SAVE REGISTERS.                      36000017
         LR    R1,R4               LOAD DEB ADDR.                       36200017
         LA    R2,DXDAADDR         ADDR OF MBBCCHHR FIELD IN IOB.       36400017
         L     RF,CVTPTR(0)        GET ADDR OF CVT.                     36600017
         USING CVT,RF              ADDR CVT                      S21940 36800021
         L     RF,CVTPCNVT         GET ADDR OF TTR CONVERT ROUTINE.     37000017
         BALR  RE,RF               GO TO CONVERT ROUTINE.               37200017
         DROP  RC                                                       37400017
         USING CHKWA,R8            ADDRESS W.A.                         37600017
         LM    R9,RD,CKREGSAV      RESTORE REGISTERS.                   37800017
         DROP  8                                                        38000017
         USING CHKWA,RC                                                 38200017
         BR    RA                  RETURN TO CALLER.                    38400017
PREOBH   EQU   *                                                        38600017
         STM   R2,RC,PRESAVE                                            38800017
         L     R2,PRENXB           LOAD ADDR OF NEXT BYTE IN BUFFER     39000017
         L     R8,PRENOB           LOAD NUMBER OF BYTES LEFT IN BUFFER. 39200017
         STH   R9,0(R2)            MOVE CODE TO BUFFER.                 39400017
         B     *+4(R9)             BRANCH TABLE ON RECORD CODE          39600018
         B     PREOJF              GO TO MOVE JFCB AND UCB INFO TO BUF. 39800017
         B     PREJFX              GO TO WRITE OUT JFCBX.               40000017
         B     PREJFX              GO TO WRITE OUT GDG BIAS COUNT TABLE 40200017
         B     PREJFX              GO TO WRITE OUT DSENQ TABLE.         40400017
PRECOM3  EQU   *                                                        40600017
         LA    R1,CKDECB1          GET DECB ADDR.                       40800017
         WRITE (R1),SF,,,,,,MF=E   WRITE OUT A DSDR.                    41000017
         LA    R1,CKDECB1                                               41200017
         CHECK (R1)                                                     41400017
         TM    CKFLAG1,CKTAPE      CHKPT DATA SET ON TAPE               41410017
         BO    PRETAEOV            BRANCH IF YES                        41420017
         L     RF,CKDCBAD          GET DCB ADDRESS FOR CHKPT DATA SET   41430017
         DROP  R2                                                       41440017
         USING IHADCB,RF                                                41450017
         L     RF,DCBDEBAD         GET DEB ADDRESS                      41460017
         DROP  RF                                                       41470017
         USING DEBBASIC,RF         ADDRESS DEB                   S21940 41472021
         USING IHADCB,R2                                                41480017
         CLC   CKTSTEOV(ONE),DEBNMEXT HAS THE NUMBER OF EXTENTS  S21940 41490021
*                                          CHANGED                      41500017
         DROP  RF                  DROP DEB ADDRESSABILITY       S21940 41502021
         BNE   PREOVER             BRANCH IF YES-EOV ON D.A. ERROR      41510017
         B     PREIOCHK            CHECK FOR I/O ERROR                  41520017
PRETAEOV EQU   *                                                        41530017
         L     RF,CKTSTEOV         GET POINTER TO EOV INFO              41600017
         CLC   ZERO(LNWORD,RF),CKEOVCMR      DID END OF VOLUME OCCUR    41800018
         BNE   PREOV               YES                                  42000017
PREIOCHK EQU   *                                                        42100017
         TM    CKRETCD1,CKIOERR    WAS THERE AN I/O ERROR               42200018
         BO    PREQERRW             YES-GO TO I/O ERROR EXIT ROUTINE.   42400017
         STH   R9,CODE(R2)         MOVE RECORD CODE TO BUFFER           42600018
         BR    RA                  RETURN                               42800018
PREOJF   EQU   *                                                        43000017
         CH    R8,PREUPR           IS THERE ROOM FOR ANOTHER RECORD     43200017
         BH    PREMVJ              YES-DO NOT WRITE BUFFER YET          43400017
         BAL   RA,PREWR            NO-GO TO WRITE OUT BUFFER            43600017
PREMVJ   EQU   *                                                        43800017
         MVC   CDL(JFCL,R2),INFMJFCB  MOVE JFCB TO BUFFER               44000017
         MVC   DDNMP(DDL,R2),TIOEDDNM MOVE DDNAME TO BUFFER.            44200017
         L     RF,TIOTUCB          GET ADDR OF UCB                      44300018
         LA    RF,ZERO(RF)         CLEAR HIGH ORDER BYTE                44370018
         LTR   RF,RF               IS THIS A DUMMY DATA SET             44440017
         BNZ   PRENODMY            BRANCH IF NOT                        44460018
         XC    UCBP(TYPL,R2),UCBP(R2)      ZERO DEVTYP BYTES IN DSDR    44480017
         B     PREUPDAT            GO TO UPDATE BUFFER POINTERS         44500018
PRENODMY EQU   *                                                        44520017
         USING UCBSECT,RF                                               44610018
         CLI   UCBID,MAINUCB       IS THIS A MAIN UCB                   44700018
         BE    PREUCB              BRANCH IF YES ELSE DS ON DATA CELL   44800017
         LH    R3,UCBINNO          GET THE BIN NUMBER                   45000018
         SLL   R3,EQUX16           MULTIPLY BY 16(LENGTH OF SUB-UCB)    45200018
         LA    R3,LMAINUCB(R3)     INCREMENT BY LENGTH OF MAIN UCB      45400018
         SR    RF,R3               GET ADDRESS OF MAIN UCB              45600017
PREUCB   EQU   *                                                        45800017
         USING UCBSECT,RF          ADDRESS UCB.                         46000017
         MVC   UCBP(TYPL,R2),UCBTYP MOVE UCB INFO INTO DSDR.            46200017
PREUPDAT EQU   *                                                        46300017
         LA    R2,PREUPJ(R2)       UPDATE BUFFER POINTER.               46400017
         SH    R8,LNGDSDR1         UPDATE NUMBER OF BYTES LEFT   S21940 46600021
*                                  IN BUFFER                     S21940 46615021
PRECOM2  ST    R2,PRENXB           SAVE BUFFER POINTER.                 46800017
         ST    R8,PRENOB           SAVE NUMBER OF BYTES LEFT IN BUF.    47000017
PRERET   EQU   *                                                        47200017
         LM    R2,RC,PRESAVE                                            47400017
         BR    RA                  RETURN TO CALLER.                    47600017
PREWR    EQU   *                                                        47800017
         LA    RF,BLKEND           MOVE END OF BLOCK CODE TO BUFFER.    48000017
         STH   RF,CODE(R2)         PUT END OF BLOCK CODE IN BUFFER      48200018
         LR    R2,RC               COMPUTE                              48400017
         A     R2,CKBFOFST         BUFFER ADDRESS                       48600017
         SH    R2,HALFDSDR         UPDATE POINTER TO NEXT        S21940 48800021
         ST    R2,PRENXB           AVAILABLE BYTE AND SAVE IT    S21940 49000021
         MVC   PRENOB(LNWORD),DSDRLN    UPDATE NO. OF BYTES LEFT IN BUF 49200018
         L     R8,PRENOB           GET NO. OF BYTES LEFT IN BUFFER.     49400017
         B     PRECOM3             GO TO WRITE OUT DSDR                 49600018
PREJFX   EQU   *                                                        49800017
         CH    R8,PREUPX           IS THERE ROOM FOR ANOTHER RECORD     50000017
         BH    PREMVJX             YES-DO NOT WRITE OUT BUFFER YET.     50200017
         BAL   RA,PREWR            NO-GO TO WRITE OUT BUFFER.           50400017
PREMVJX  EQU   *                                                        50600017
         MVC   CDL(JFCL,R2),INFMJFCB  MOVE JFCBX TO BUFFER              50800017
         LA    R2,PREUPZ(R2)       UPDATE BUFFER POINTER                51000018
         SH    R8,LNGDSDR2         UPDATE NUMBER OF BYTES LEFT   S21940 51200021
*                                  IN BUFFER                     S21940 51215021
         B     PRECOM2             GO TO SAVE BUFFER POINTERS AND RET   51400018
PREOV    EQU   *                                                        51600017
         TM    CKFLAG2,CKEOV  Q. HAS EOV OCCURRED BEFORE                51800017
         BO    PREOVER        YES                                       52000017
         OI    CKFLAG2,CKEOV  TURN ON EOV INDICATOR                     52600017
         MVC   PRESV(LNMODNAM),PREXMN   SET UP XCTL PARM LIST           52800018
         MVI   PREWD2,CHAR2        IGC0206C                             53000018
         B     PREOUT              GO TO EXECUTE XCTL                   53200018
PREOVER  EQU   *                                                        53400017
         MVI   CKRETCD1,CKPGMERR   INDICATE PROGRAMMER ERROR            53600018
         LA    RA,CKERIO7          GET EOV ERROR CODE                   53800017
         STH   RA,CKMSGCOD         STORE IN WORK AREA                   54000017
         B     PREQMFG             GO TO TRANSFER CONTROL TO IGC0N06C   54200018
PRESYNAD EQU   *                                                        54300018
         MVI   CKRETCD1,CKIOERR    MOVE ERROR CODE INTO W.A.            54400018
         BR    RE                                                       54600017
PREQERRW EQU   *                                                        56200017
         LA    RA,CKERIO3          I/O ERROR WRITING CHKPT DATA SET     56400017
         STH   RA,CKMSGCOD         STORE ERROR CODE IN WORK AREA        56600017
         B     PREQERR             GO TO GET RETURN CODE                56800018
PREQERRX EQU   *                                                        57000017
         LA    RA,CKERIO4          I/O ERROR READING JOB QUEUE          57200017
         STH   RA,CKMSGCOD         STORE IN WORK AREA                   57400017
PREQERR  EQU   *                                                        57600017
         MVI   CKRETCD1,CKIOERR    MOVE RETURN CODE TO WA               57800018
PREQMFG  EQU   *                                                        58000017
         MVC   PRESV(LNMODNAM),PREIORE  MOVE IORESUME'S NAME TO XCTLST  58200018
         B     PREOUT             GO TO TRANSFER CONTROL                58400017
PREJFCBX EQU   *                                                        58500018
         BAL   RA,PRECONV          CONVERT RTN                          58600018
         BAL   RA,PREQR            READ RCD FROM JOB Q                  58700018
         LA    R9,COJFCBX          LOAD RECORD CODE.                    59000017
         BAL   RA,PREOBH           WRITE RCD TO CHKPT D.S.              59200018
         L     R0,INFMJFCB         GET TTR OF NEXT JFCBX                59400017
         IC    R0,PREZERO          FILL IN CONCATENATION NUMBER.        59600017
         LTR   R0,R0               IS THERE ANOTHER JFCBX.              59800017
         BNZ   PREJFCBX            YES-GO TO READ IN NEXT JFCBX.        60000017
         B     PRENXTI             NO-GO TO EXAMINE NEXT JFCB.          60200017
CKERIO3  EQU   X'0317'             WRITE UNSUCCESSFUL                   60400017
CKERIO4  EQU   X'0316'             XDAP UNSUCCESSFUL                    60600017
CKERIO7  EQU   X'031B'             INVALID EOV                          60800017
DSDRL    EQU   400  LENGTH OF CHR AND DSDRS                             61000017
PREUPZ   EQU   178                                                      61400017
DSDRLN   DC    F'400'    LENGTH OF A DSDR                               61600017
*                                                                     * 61650018
*        LENGHTS OF RECORDS USED TO UPDATE BUFFER POINTER             * 61700018
*                                                                     * 61750018
PREUPX   DC    H'180'                                                   61800017
PREUPJ   EQU   190                                                      62000017
LNGDSDR2 DC    H'178'              LENGTH OF A TYPE 2 DSDR       S21940 62015021
LNGDSDR1 DC    H'190'              LENGTH OF A TYPE 1 DSDR       S21940 62030021
PREUPR   DC    H'192'                                                   62200017
HALFDSDR DC    H'200'              HALF THE DSDR BUFFER LENGTH   S21940 62215021
PREZERO  DC    X'00'                                                    62400017
*                                                                       62450018
*        MODULE NAMES USED IN XCTL PARM LIST                            62500018
*                                                                       62550018
PREXMN   DC    C'IGC0F06C'                                              62600017
PREIORE  DC    C'IGC0N06C'                                              62800017
*                                                                S21940 62830021
*********************************************************************** 62845021
*        PATCH AREA DEFINITION                                        * 62860021
*********************************************************************** 62875021
*                                                                S21940 62890021
LNGD06C  EQU   *-IGC0D06C          LENGTH BEFORE PATCH AREA      S21940 62905021
*                                                                S21940 62920021
PATCHLNG EQU   1024-LNGD06C        LENGTH OF PATCH AREA          S21940 62935021
*                                                                S21940 62950021
         DC    (PATCHLNG)X'00'     ZEROED PATCH AREA             S21940 62965021
*                                                                S21940 62980021
         EJECT                                                   S21940 62995021
COJFCBX  EQU   4    CODE FOR JFCBX                                      63000017
COGDG    EQU   8    CODE FOR GDG BIAS COUNT TABLE                       63200017
CODSENQ  EQU   12   CODE FOR DSENQ TABLE                                63400017
DSDREND  EQU   X'10'     CODE TO LAST DSDR.                             63600017
BLKEND   EQU   X'14'     CODE TO INDICATE END OF A DSDR.                63800017
BLKL     EQU   2    LENGTH OF DCBBLKSI FIELD                            64000017
SUBALOC  EQU   130       TIOESTTC FIELD-INDICATES SUBALLOCATE REQUESTED 64200017
SUREAD   EQU   X'7F'     RETURN CODE FOR SUCCESSFUL I/O COMPLETION.     64400017
JFCL     EQU   176       LENGTH OF JFCB TO BE WRITTEN OUT.              64600017
CDL      EQU   2    LENGTH OF CODE FIELD IN DSDR.                       64800017
DDL      EQU   8         LENGTH OF TIOEDDNM FIELD                       65000017
UCBP     EQU   CDL+JFCL+DDL   OFFSET TO UCB INFO IN A DSDR.             65200017
QSAMBSAM EQU   X'40'                                                    65400017
NOTTAPDA EQU   X'5F'                                                    65600017
PRETAPE  EQU   X'80'                                                    65800017
DDNMP    EQU   CDL+JFCL  OFFSET TO DDNAME FIELD IN A DSDR.              66200017
TYPL     EQU   4         LENGTH OF UCBTYP FIELD                         66400017
CKMSG2   EQU   64    INDICATES WTO MSG-INVALID-ERROR WHILE CREATING     66600017
*                   CHKPT D.S.                                          66800017
CKCHR    EQU   128  INDICATES CHR WRITTEN                               67000017
DEBVLSQ  EQU   0         USED TO REFERENCE VOLUME SEQUENCE NO. IN DEB   67104018
DEBVSQ   EQU   1                                                        67112018
CODE     EQU   0         OFFSET INTO BUFFER FOR RECORD CODE             67116018
NOTPRGD  EQU   X'FF'                                                    67120017
IOBECBAD EQU   4                                                        67140017
INDSEQ   EQU   X'80'                                                    67160017
PURGEOPT EQU   X'C0'                                                    67180017
K6       EQU   6                                                  M2192 67190018
         EJECT                                                          67195021
         IEEVCHWA                                                       67200017
PURGDEB  EQU   CKREGSAV                                                 67250017
PURGWD2  EQU   PURGDEB+4                                                67300017
PURGLST  EQU   PURGWD2+4                                                67350017
CKTSTEOV EQU   CKUNIT                                                   67400017
CKEOVCMR EQU   CKUNIT+4                                                 67600017
         IEFJFCBN                                                       67800017
         ORG   INFMJFCB                                                 68000017
         IEFASIOT                                                       68200017
*                                                                     * 68250018
*        PRESERVE'S WORK AREA                                         * 68300018
*                                                                     * 68350018
PRESV    DS    F         XCTL PARAMETER LIST -                          68400018
PREWD2   DS    F              FIRST 2 WORDS CONTAIN MODULE NAME         68450018
PRELSTAD DS    F              POINTER TO MODULE NAME                    68500018
PRENXB   DS    F                   NEXT BYTE IN BUFFER.                 68600017
PRENOB   DS    F                   NUMBER OF BYTES LEFT IN BUFFER.      68800017
PREAD    DS    0F        SAVE AREA USED FOR ADDRESSES                   68900018
PREAD1   DS    CL1                                                      69000018
PREAD3   DS    CL3                                                      69100018
PREADEOV DS    F    SAVE AREA FOR INFO FOR EOV TEST                     69200017
PRNEOV   DS    F                                                        69400017
PRESAVE  DS    12F  REGISTER SAVE AREA.                                 69600017
PRELNGTH EQU   *    END OF PRESERVE'S W.A.                              69800017
*                                                                     * 69850018
*        WORK AREA USED BY QUEUE MANAGER                              * 69900018
*                                                                     * 69950018
QJOB     DSECT                                                          70000017
SCALADCB DS    13F                                                      70200017
SCADEB   DS    12F                                                      70400017
SCATALLY DS    F                                                        70600017
SCASTRKS DS    H    TT OF FIRST TRACT IN Q.                             70800017
SCALTRKS DS    H    TT OF LAST TRACK IN Q.                              71000017
SCARECPT DS    CL1  NUMBER OF RECORDS PER PHYSICAL TRACK.               71200017
*                                                                     * 71220018
*        MAPPING OF ECB                                               * 71240018
*                                                                     * 71260018
ECBSECT  DSECT                                                          71280018
CMPCODE  DS    CL1            I/O COMPLETION CODE                       71300018
RBADDR   DS    CL3            ADDR OF RB WAITING ON I/O                 71320018
         EJECT                                                          71370021
CVT      DSECT ,                                                 S21940 71380021
         CVT   ,                                                 S21940 71390021
         EJECT                                                          71391021
         IKJTCB ,                                                S21940 71392021
         EJECT                                                          71393021
         IEZDEB ,                                                S21940 71394021
         EJECT                                                          71395021
UCBSECT  DSECT                                                          71400017
         IEFUCBOB                                                       71600017
         EJECT                                                          71700021
TIOTSECT DSECT                                                          71800017
         IEFTIOT1                                                       72000017
         EJECT                                                          72100021
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               72400017
         EJECT                                                          72405021
UCBINNO  EQU   SRTEJBNR       BIN NO IN SUB-UCB                         72408018
CKRETCD1 EQU   CKRETCOD+1     RETURN CODE FIELD IN CHKWA                72416018
GDGTAB   EQU   INFMJFCB+4     TTR OF NEXT GDG TABLE                     72424018
DCBSYND  EQU   DCBSYNAD+1          ADDRESSING SYNAD ADDRESS IN DCB      72432018
TIOTUCB  EQU   TIOEFSRT-1     UCB ADDRESS IN TIOT ENTRY                 72440018
CKDCB1   EQU   CKDCBAD+1      CHKPT DCB ADDR IN CHKWA                   72456018
JFCBVSQ1 EQU   JFCBVLSQ+1     VOLSEQ NO. IN JFCB                        72464018
MAINUCB  EQU   X'FF'          FLAG FOR MAIN UCB                         72472018
LNADDR   EQU   3              LENGTH OF ADDRESS                         72480018
ZERO     EQU   X'00'                                                    72488018
EQUX16   EQU   4              SHIFT NUMBER IN REG LEFT 4=MULTIPLY BY 16 72504018
ONE      EQU   1                                                        72520018
DEFMOUNT EQU   X'20'          DEFERRED MOUNT BIT IN JFCB CAUSES DSDR TO 72536018
*                             MARK SIOT FOR REPIO TO MOUNT CORRECT VOL  72544018
LNWORD   EQU   4              LENGTH OF WORD                            72552018
LNMODNAM EQU   8              LENGTH OF MODULE NAME IN XCTL PARMLST     72560018
LMAINUCB EQU   56             LENGTH OF MAIN UCB                        72568018
CHAR2    EQU   C'2'           CHAR TO ALTER MOD NAME TO IGC0206C        72576018
 END                                                                    72600017
