         TITLE 'IHJACP30 / PCP CHKMAIN / IGC0F06C'                      00300017
*                                                                       00330021
*          RELEASE 22 DELETIONS                                         00360021
*          RELEASE 21 DELETIONS                                         00390021
*                                                                A38478 00420021
*          RELEASE 20 DELETIONS                                         00450021
*397200                                                          A32493 00520021
* STATUS- CHANGE LEVEL 002                                         I250 00600019
* IHJACP30, PCP CHKMAIN, WRITES CORE IMAGE RECORDS (CIR)                00800017
*2166512000-522000,542000-546000,550000                          A38515 00900021
* STATUS CHANGE LEVEL 002                                               01000021
*                               DATA SET.                               01200017
*                                                                       01400017
*   ROUTINE NAME ... CHKMAIN                                            01600017
*                                                                       01800017
*   MODULE NAME ... IHJACP30                                            02000017
*                                                                       02200017
*   CHART ID ...                                                        02400017
*                                                                       02600017
*   FUNCTION / OPERATION ...                                            02800017
*   ..   CHKMAIN USES DATA CONTAINED IN THE CHKPT W.A. TO CALCULATE ALL 03000017
*        CONTROLS TO IMPLEMENT THE WRITING OUT OF PROBLEM PROGRAM CORE  03200017
*        ONTO THE CHKPT DATA SET.                                       03400017
*   ..   SETS UP CONTROLS TO IMPLEMENT SINGLE OR MULTIPLE BUFFERING     03600017
*        SCHEME (DEPENDING ON DCBNCP VALUE IN CHKPT DCB) TO WRITE OUT   03800017
*        PROBLEM PROGRAM CORE IMAGE RECORDS (CIR) ONTO THE CHKPT DATA   04000017
*        SET.                                                           04200017
*   ..   GENERATES A SUPERVISOR RECORD (SUR) IN THE O/P BUFFER AREA.ITS 04400017
*        OFFSET FROM THE START OF THE CHKPT W.A. IS IN THE CKBFOFST     04600017
*        FIELD IN THE CHKPT W.A. THE FOLLOWING DATA IS INSERTED INTO    04800017
*        THE SUR RECORD -                                               05000017
*        ***** THE FOLLOWING TCB FIELDS -                               05200017
*                                                                       05400017
*              TCBRBP                                                   05600017
*              TCBPIE                                                   05800017
*              TCBDEB                                                   06000017
*              TCBTIO                                                   06200017
*              TCBCMP                                                   06400017
*              TCBTRN                                                   06600017
*              TCBMSS                                                   06800017
*              TCBPKF                                                   07000017
*              TCBFLGS                                                  07200017
*              TCBLMP                                                   07400017
*              TCBDSP                                                   07600017
*              TCBLLS                                                   07800017
*              TCBJLB                                                   08000017
*              TCBJSE                                                   08200017
*              TCBIDF                                                   08400017
*              TCBFSA                                                   08600017
*              TCBNSTAE                                                 08660017
*              TCBUSER                                                  08720017
*                                                                       08800017
*        ***** THE FOLLOWING MISCELLANEOUS FIELDS -                     09000017
*                                                                       09200017
*              ADDRESS OF THE CHKPT DATA SET DCB                        09400017
*              ADDRESS OF THE FIRST FQE IN THE PP AREA                  09600017
*              FOUR BYTE CODE - 00000001 - FL. PT. REGS. EXIST          09800017
*                             - 00000002 - FL. PT. REGS. DO NOT EXIST   10000017
*              CONTENTS OF THE FL. PT. REGS. IF THEY EXIST.             10200017
*                                                                       10400017
*   ..   WRITES OUT THE SUR RECORD ONTO THE CHKPT DATA SET, AND         10600017
*        TRANSFERS CONTROL TO THE NEXT LOAD OF CHECKPOINT.              10800017
*                                                                       11000017
*   ENTRY POINTS ...                                                    11200017
*                                                                       11400017
*        CHKMAIN IS ENTERED VIA A TRANSFER CONTROL FROM THE PREVIOUS    11600017
*        CHECKPOINT LOAD AT ENTRY POINT IGC0F06C                        11800017
*                                                                       12000017
*   INPUT ...                                                           12200017
*                                                                       12400017
*   ..   DATA SET UP BY PREVIOUS LOADS OF CHECKPOINT AND MADE AVAILABLE 12600017
*        TO CHKMAIN IN THE CHKPT WORK AREA (W.A.).                      12800017
*   ..   THE ADDRESS OF THE CHKPT W.A. IS PASSED IN GENERAL REGISTER 1  13000017
*        BY THE PREVIOUS LOAD OF CHECKPOINT.                            13200017
*   ..   THE FOLLOWING DATA, RESIDING IN THE CHKPT W.A. IS USED BY THE  13400017
*        CHKMAIN ROUTINE.                                               13600017
*              CKWAOFST - OFFSET TO BEGINNING OF CHKMAIN W.A.           13800017
*              CKBFOFST - OFFSET TO BEGINNING OF CHKMAIN O/P BUFFER     14000017
*              CKDCBAD  - POINTER TO CHKPT DATA SET DCB                 14200017
*              CKWACL   - LENGTH OF CHKPT W.A.                          14400017
*              CKBUFL   - LENGTH OF CHKPT BUFFER                        14600017
*              CKTCBAD  - POINTER TO PP TCB                             14800017
*              CKPPM    - POINTER TO FIRST BYTE IN PP AREA              15000017
*              CKPPE    - POINTER TO LAST BYTE IN PP AREA               15200017
*              CKDECB1  - POINTER TO DECB FOR WRITE 1                   15400017
*              CKDECB2  - POINTER TO DECB FOR WRITE 2                   15600017
*                                                                       15800017
*   OUTPUT ...                                                          16000017
*                                                                       16200017
*   ..   OUTPUT CONSISTS OF CORE IMAGE RECORDS (CIR), AND SUPERVISOR    16400017
*        RECORDS (SUR) WHICH ARE WRITTEN ON THE CHKPT DATA SET.         16600017
*   ..   UPON RECEIPT OF AN I/O ERROR, CHKMAIN PLACES A CODE OF X'10'   16800017
*        IN GENERAL REGISTER 2 BEFORE TRANSFERRING CONTROL TO THE NEXT  17000017
*        LOAD OF CHECKPOINT. THE ERROR CODE IS ALSO MOVED TO THE        17200017
*        CKRETCOD FIELD OF THE CHKPT W.A.                               17400017
*                                                                       17600017
*   EXTERNAL ROUTINES ... NA                                            17800017
*                                                                       18000017
*   EXITS - NORMAL ...                                                  18200017
*                                                                       18400017
*   ..   CHKMAIN TRANSFERS CONTROL TO THE NEXT LOAD OF CHECKPOINT, AND  18600017
*        PASSES THE ADDRESS OF THE CHKPT W.A. IN GENERAL REGISTER 1.    18800017
*                                                                       19000017
*                                                                       19200017
*         - ERROR  ...                                                  19400017
*                                                                       19600017
*   ..   UPON RECEIPT OF AN I/O ERROR, CHKMAIN PLACES A CODE OF X'10'   19800017
*        IN GENERAL REGISTER 2 BEFORE TRANSFERRING CONTROL TO THE NEXT  20000017
*        LOAD OF CHECKPOINT. THE ERROR CODE IS ALSO MOVED TO THE        20200017
*        CKRETCOD FIELD OF THE CHKPT W.A.                               20400017
*   TABLES / WORK AREAS ...                                             20600017
*                                                                       20800017
*   ..   CHKMAIN USES THE FOLLOWING WORK AREAS WHICH ARE BUILT BY THE   21000017
*        FIRST LOAD OF CHECKPOINT.                                      21200017
*                                                                       21400017
*              CHKWA - CHKPT W.A. BUILT BY CHKPT CONTAINING DATA TO BE  21600017
*                      UTILIZED BY SUBSEQUENT LOADS OF CHECKPOINT.      21800017
*              CHWA  - WORK AREA ALLOCATED BY CHKPT FOR USE BY THE      22000017
*                      CHKDCB AND CHKMAIN ROUTINES.                     22200017
*                                                                       22400017
*   ATTRIBUTES ... REENTRANT                                            22600017
*                                                                       22800017
*   NOTES-                                                            * 23000017
*   B = SIZE OF BUFFER IN BYTES                                       * 23200017
*   E2 = HIGH ORDER ADDRESS OF CHKPT'S WORK AREA                      * 23400017
*   M2 = LOW  ORDER ADDRESS OF CHKPT'S WORK AREA                      * 23600017
*   F.O. = FIRST OFFSET                                               * 23800017
*   S.O. = SECOND OFFSET                                              * 24000017
*   K1 = NUMBER OF CIR'S BEFORE CHKPT'S W.A.                          * 24200017
*   K3 = NUMBER OF CIR'S AFTER CHKPT'S W.A.                           * 24400017
*   M = LOW  ORDER ADDRESS OF P.P. CORE                               * 24600017
*   E = HIGH ORDER ADDRESS OF P.P. CORE                               * 24800017
*   P = POINTER TO BEG. OF CORE ABOUT TO BE WRITTEN OUT OR READ IN    * 25000017
*   K2 = REMAINDER OF AERA/BUFFER FOR FIRST SECTION                   * 25200018
*   K4 = REMAINDER OF AERA/BUFFER FOR SECOND SECTION                    25400018
         EJECT                                                          25600017
IGC0F06C CSECT                                                          25700017
         BALR  RB,N0          ESTABLISH ADDRESSABILITY                  25800017
         USING *,RB                                                     26000017
         USING CHKWA,RC       ADDRESS CHKPT W.A.                        26200017
         USING IHADCB,R2      ADDRESS CHKPT DCB.                        26400017
         LR    RC,R1          GET ADDR OF CHKPT W.A.                    26600017
         LA    RD,CKREGSAV    GET ADDR OF REG S.A.                      26800017
         L     R2,CKDCBAD     GET CHKPT DCB ADDR                        27000017
         LA    RF,CM2A2       GET ADDR OF CHKMAIN SYNAD ROUTINE         27200017
         ST    RF,CMSYSA                                                27400017
         MVC   DCBSYNAD+N1(N3),CMSYSA+N1     PUT ADDR                   27500017
*                             OF CM2A2 IN SYNAD FIELD                   27600017
         MVI   SWITCH,X00     INITIALIZE SWITCHES                       27700017
         CLI   DCBNCP,X01     Q. IS SINGLE BUFFERING INDICATED          27800017
         BH    CM2E1          NO-MULTIPLE BUFFERING SPECIFIED.          28200017
         OI    SWITCH,CMS1    SET CMS1 ON- SINGLE BUFFERING             28400017
CM2E1    EQU   *                                                        28600017
         L     RA,CKPPE       CALCULATE LOW AND HIGH BOUNDS OF          29000017
         LTR   RA,RA          Q. DOES THIS PARTITION HAVE H0            29040018
         BNZ   CM2E2          A. YES SKIP CODE FOR W.A. IN H1           29080018
         L     RA,CKPPEL      A. GET HIGH BOUND OF H1                   29120018
CM2E2    EQU   *                                                        29160018
         LR    R9,RC          AREA ABOVE W.A.                           29200017
         A     R9,CKWACL                                                29400017
         BAL   R8,CMINTW      GO TO WRITE OUT CORE ABOVE W.A.           29600017
         LA    RA,CHKWA       GET LOW AND HIGH BOUNDS OF                29800017
         BCTR  RA,N0          DECREMENT COUNTER                         30000017
         L     R9,CKPPM       AREA ABOVE W.A.                           30200017
         LTR   R9,R9          Q. DOES THIS PARTITION HAVE HO            30240018
         BNZ   CM2E3          A. YES SKIP CODE FOR W.A. IN H1           30280018
         L     R9,CKPPML      A. NO GET LO BOUND OF H0                  30320018
CM2E3    EQU   *                                                        30360018
         BAL   R8,CMINTW      GO TO WRITE OUT CORE BELOW W.A.           30400017
         C     RC,CKPPE       Q.  IS WORK AREA IN H0                    30460018
         BNL   CMSKP          A.  NO  H1 ALREADY WRITTEN                30520018
         L     RA,CKPPEL      GET HIGH BOUNDARY OF HIERARCHY ONE.       30600017
         LTR   RA,RA          Q. DOES THIS REGION HAVE A HIERARCHY      30800017
         BZ    CMSKP          NO                                        31000017
         L     R9,CKPPML      GET LOW BOUNDARY OF HIERARCHY ONE.        31200017
         BAL   R8,CMINTW      GO TO WRITE OUT HIERARCHY ONE CORE.       31400017
CMSKP    EQU   *                                                        31600017
         USING SURSECT,RA     ADDRESS SUR                               31800017
         USING TCBSECT,R8     ADDR TCB.                                 32000017
         LR    RA,RC          GET ADDR OF BUFFER.                       32200017
         A     RA,CKBFOFST                                              32400017
         XC    SURSECT(SURL),SURSECT INTIALIZE SUR.                     32600017
         L     R8,CKTCBAD     GET TCB ADDR                              32800017
         L     R6,TCBMSS      PTR. TO BOUNDARY BOX IN R6.               33000017
         MVC   TCBINFO(N48),TCBRBP      MOVE FIRST 48 BYTES             33300017
*                             OF TCB TO O/P BUFFER                      33400017
         MVC   FSA(N3),TCBFSA+N1    SAVE AREA ADRS IN BUFFER            33500017
         MVC   STAE(N4),TCBNSTAE    SAVE TCB STAE INFORMATION           33530017
         MVC   USER(N4),TCBUSER     SAVE TCB USER FIELD                 33560017
         L     RE,CVTPTR           FETCH CVT PTR                        33562021
         USING CVTSECT,RE                                          I250 33565019
         TM    CVTDCB,X'20'        MFT SYSTEM                     M2915 33568019
         BZ    CM2E4               NO                             M2915 33571019
         TM    CVTOPTA,X'08'       ATTACH SYSTEM                  M2915 33574019
         BZ    CM2E4               NO                             M2915 33577019
         DROP  RE                                                  I250 33580019
         L     RE,TCBPIB                GET POINTER TO PIB         I250 33585019
         MVC   JOBPAK(N4),PIBJPA(RE)    SAVE JOB PACK POINTER      I250 33590019
CM2E4    EQU   *                                                   I250 33595019
         MVC   DCBAD(N4),CKDCBAD    MOVE PTR. TO CHKPT                  33600017
*                             DS DCB TO O/P BUFFER                      33700017
         MVC   FQE1(N4),N0(R6)      MOVE PTR. TO 1ST                    33800017
*                             FQE  TO O/P BUFFER                        33900017
         TM    N0(R6),N1      Q. IS THERE ANY LCS                       34000017
         BZ    CM3D1     NO                                             34400017
         MVC   FQE2(N3),N13(R6)     MOVE 2ND (1ST FQE) TO BUFFER        34600017
CM3D1    EQU   *                                                        34800017
         TM    TCBFLGS+N2,X08     CHECK IF FLT.PT. REG EXIST.           35000017
         BZ    CM3D2              TO SYNAD                              35200017
         MVI   FLPTRFLG,N1    INDICATE FLT. PT. REGS. SAVED             35400017
         STD   R0,FLTR0       SAVE                                      35600017
         STD   R2,FLTR2            FLOATING                             35800017
         STD   R4,FLTR4                     POINT                       36000017
         STD   R6,FLTR6                           REGISTERS.            36200017
CM3D2    EQU   *                                                        36400017
         MVC   SYNAD(N4),CKSYNAD   SAVE CHKPT DCBSYNAD FIELD            36600017
         L     R4,CKPARMAD      GET PARM LIST ADDR.                     36800017
         CLI   N4(R4),XFF     REQUEST TO RETURN GENERATED CHECKID       37000017
         BNE   CM3F1            NO-SKIP CODE TO SAVE CHECKID.           37200017
         MVC   CKIDAD(N4),N4(R4)   SAVE ADDR OF CHECKID RETRN AREA      37400017
         MVC   CKID(N8),CKCHEKID   SAVE GENERATED CHECKID               37600017
CM3F1    EQU   *                                                        37800017
         L     R4,TCBTIO      GET ADDR OF TIOT                          38000017
         LA    R3,SYSOUTF     GET ADDR OF SYSOUT INFO FIELD IN SUR      38200017
         L     R2,TCBDEB      GET ADDR OF FIRST DEB.                    38400017
         USING DEBSECT,R2     ADDRESS DEB.                              38600017
         USING IHADCB,R6    ADDRESS DCB.                                38800017
         USING UCBSECT,R7   ADDR UCB.                                   39000017
CMSYSG   EQU   *                                                        39200017
         LTR   R2,R2        Q.END OF DEB CHAIN                          39400017
         BZ    CMWSUR       YES                                         39600017
         CLI   DEBEXSCL,N0    Q.  ISTHIS A DUMMY DEB              25118 39660018
         BE    CMNXDB         A.  YES GET NEXT DEB               A32493 39720020
         L     R6,DEBDCB    GET DCB ADDR.                               39800017
         LH    R7,DCBTIOT   GET OFFSET TO TIOT ENTRY.                   40000017
         L     R7,N16(R4,R7)  GET ADDR OF UCB                           40200017
         TM    UCBWGT,SYSOUT  Q. SYSOUT DATA SET                        40400017
         BZ    CMNXDB         NO-GO TO GET NEXT DEB.                    40600017
         CLI   UCBTYP+N2,X80      Q. IS SYSOUT DATA SET ON TAPE         40800017
         BNE   CMNXDB         NO-GO TO GET NEXT DEB.                    41000017
         MVC   N0(N2,R3),SRTEFSEQ  SAVE INFO FOR                        41100017
*                             SYSOUT TAPE DATA SET                      41200017
         MVC   N2(N3,R3),DEBDCB+N1                                      41300017
         LA    R3,N5(R3)      GET PTR TO NEXT SYSOUT INFO S.A.          41400017
CMNXDB   EQU   *                                                        41800017
         L     R2,DEBLINK     GET PTR TO NEXT DEB.                      42000017
         LA    R2,N0(R2)      CLEAR HIGH ORDER BYTE                     42200017
         B     CMSYSG         GO TO PROCESS NEXT DEB.                   42400017
CMWSUR   EQU   *                                                        42600017
         L     RE,TCBRBP      GET ADDR OF CHKPT SVRB.                   42800017
CMNXRB   EQU   *                                                        43000017
         USING RBSECT,RE      ADDRESS RB'S.                             43200017
         L     RE,RBLINK-N1   GET ADDR OF NEXT RB                       43400017
         TM    RBSTAB+N1,X80       Q.  LAST  RB                         43600017
         BO    CMWRSR         YES                                       43800017
         TM    RBSTAB,SVRB    IS THIS RB AN SVRB                        44000017
         BNO   CMNXRB         NO  GET POINTER TO NEXT RB           I250 44200019
         L     RF,RBOPSW+N4   GET NSI  ADDR.                            44400017
         LA    RF,N0(RF)      COMPUTE RELATIVE OFFSET FROM ENTRY        44600017
         L     R1,RBEP        POINT TO INSTRUCTION ADDR IN PSW.         44800017
         LA    R1,N0(R1)                                                45000017
         SR    RF,R1                                                    45200017
         ST    RF,CKOFFST     SAVE RELATIVE OFFST                       45400017
CMWRSR   EQU   *                                                        45600017
         TM    SWITCH,CMS2  Q.HAS LAST WRITE 1 BEEN CHECKED.            45800017
         BZ    CMWOS        YES-SKIP CODE TO CHECK WRITE 1.             46000017
         BAL   R5,CMCHK1    GO TO CHECK LAST WRITE.                     46200017
         BAL   R5,CMEOV       CHECK FOR EOV                             46300017
CMWOS    EQU   *                                                        46400017
         LA    R6,SURL      GET LENGTH OF SUR.                          46600017
         BAL   R5,CMWRT1    GO TO WRITE OUT SUR.                        46800017
         BAL   R5,CMCHK1    GO TO CHECK WRITE OF SUR.                   47000017
         BAL   R5,CMEOV     GO TO SEE IF EOV OCCURRED.                  47200017
CMEXCTL  EQU   *                                                        47400017
         MVC   CKMXLIST(N8),CKMN40    SET UP XCTL PARM LIST             47600017
CMXCTL   EQU   *                                                        47800017
         LR    R1,RC          LOAD PARM REG WITH ADDR OF W.A.           48000017
         LA    RF,CKMXLIST                                              48200017
         ST    RF,CKMN40AD                                              48400017
         LA    RF,CKMN40AD                                              48600017
         XCTL  SF=(E,(15))   XCTL TO NEXT LOAD                          49000017
CM2A2    EQU   *                                                        49400017
         MVI   CKRETCOD+N1,CKIOERR    MOVE ERROR CODE INTO              49500017
*                             WORK AREA                                 49600017
         RETURN                                                         49800017
CMEOV    EQU   *                                                        50000017
         TM    CKFLAG1,CKTAPE   Q. CHKPT DATA SET ON TAPE               50200017
         BZ    CMEOVDA        NO - TEST FOR EOV ON DA DEVICE            50400018
         L     RF,CKTSTEOV                                              50600017
         CLC   N0(N4,RF),CKEOVCMR     DID EOV OCCUR                     50800017
         BE    N0(R5)         NO- CONTINUE PROCESSING                   51000017
         MVI   CKRETCOD+N1,X'14'   YES - SET EOV ERR CODE - 14   A38515 51300021
         LA    RA,CKTPEOV     SET UP FOR TAPE ERR                A38515 51600021
         B     CMEOVER             GO TO EXIT ROUTINE            A38515 51900021
CMEOVDA  EQU   *                                                        52400017
         L     RF,CKDCBAD    GET ADR. OF CHKPT DCB                      52600017
         USING IHADCB,RF                                                52800017
         LA    RF,N0(RF)      CLEAR HIGH ORDER BYTE                     53000018
         L     RF,DCBDEBAD   GET ADR. OF CHKPT DEB                      53200017
         DROP  RF                                                       53400017
         LA    RF,N0(RF)      CLEAR HIGH ORDER BYTE                     53500017
         CLC   DEBNMEXT(N1,RF),CKTSTEOV                                 53600017
*                             Q.  DID  EOV OCCUR ON DA DEV              53700017
         BE    N0(R5)         NO - CONTINUE PROCESSING                  53800017
         MVI   CKRETCOD+N1,CKPGMERR SET RETURN CODE TO 8         A38515 54000021
         LA    RA,CKEOVERR    INDICATE DISK ERROR                A38515 54200021
CMEOVER  EQU   *                                                 A38515 54400021
         STH   RA,CKMSGCOD         STORE IN MESSAGE AREA                54800017
         B     CMEXCTL        XCTL INTERFACE TO IGC0N06C                55200018
CMSMBUF  EQU   *                                                        55400017
         TM    SWITCH,CMS1    Q. SINGLE BUFFERING                       55600017
         BO    CMSBUF         YES                                       55800017
         STH   R6,CKLNGTH2    PUT LENGTH OF CIR IN DECB.                56000017
         WRITE CKDECB2,SF,,(RA),,MF=E   WRITE A CIR.                    56200017
         BAL   R5,CMCHK1      GO TO CHECK WRITE 1.                      56400017
         CHECK CKDECB2                                                  56600017
         CLI   CKRETCOD+N1,CKIOERR    Q.  I/O ERROR                     56800017
         BE    CMEXCTL        XCTL INTERFACE TO IGC0N06C                57000018
         XI    SWITCH,CMS2    TURN OFF SWITCH INDICATING THAT           57200017
*                             LAST WRITE USED DECB1.                    57400017
         BAL   R5,CMEOV       GO TO SEE IF EOV OCCURRED.                57600017
         BR    R3            RETURN TO CMCOM OR CMWAGN                  57800018
CMSBUF   EQU   *                                                        58000017
         BAL   R5,CMCHK1      GO TO CHECK WRITE 1.                      58200017
         BAL   R5,CMEOV       GO TO SEE IF EOV OCCURRED.                58400017
         B     CMCOMW         GO TO WRITE OUT A CIR.                    58600017
CMWRTO   EQU   *                                                        58800017
         TM    SWITCH,CMS2 Q. DID LAST WRITE USE DECB1                  59000017
         BO    CMSMBUF        YES                                       59200017
CMCOMW   EQU   *                                                        59400017
         BAL   R5,CMWRT1      DO WRITE 1                                59600018
         OI    SWITCH,CMS2    TURN ON INDICATION THAT LAST WRITE        59800017
*                             USED DECB1.                               60000017
         BR    R3            RETURN TO CMCOM OR CMWAGN                  60200018
CMWRT1   EQU   *                                                        60400017
         STH   R6,CKLNGTH1    PUT LENGTH OF CIR IN DECB1.               60600017
         WRITE CKDECB1,SF,,(RA),,MF=E   WRITE A CIR.                    60800017
         BR    R5             RETURN                                    61000017
CMCHK1   EQU   *                                                        61200017
         CHECK CKDECB1                                                  61400017
         CLI   CKRETCOD+N1,CKIOERR    Q.  I/O ERROR                     61600017
         BCR   N7,R5          BRANCH IF NO                              61800017
         LA    RA,CKIOERMG         I/O ERROR MESSAGE CODE               62000017
         STH   RA,CKMSGCOD         STORE IN WORK AREA                   62200017
         B     CMEXCTL       XCTL INTERFACE                             62400017
         EJECT                                                          62410018
*                                                                       62420018
*        CIR BUFFER HANDLER  CIR WRITE INTERFACE                        62430018
*                                                                       62440018
*        ENTRY POINT    CMINTW                                          62450018
*                                                                       62460018
*        REGISTER INPUT                                                 62470018
*              R8   RETURN REGISTER                                     62480018
*              R9   LOW BOUND OF AREA TO BE WRITTEN                     62490018
*              RA   UPPER BOUND OF AREA TO BE WRITTEN                   62500018
*                                                                       62510018
*                                                                       62520018
CMLSWT   EQU   *                                                        62600017
         CH    R7,NOISE    Q. WOULD CIR BE MISTAKEN FOR NOISE           62800017
         BL    CMNOISE     YES                                          63000017
         LR    R6,R7          GET LENGTH OF CIR.                        63200017
CMCOM    EQU   *                                                        63400017
         LR    RA,R9          GET ADDR OF BEGINNING OF CIR.             63600017
         BAL   R3,CMWRTO      GO TO WRITE LAST CIR FOR THIS AREA.       63800017
         B     N0(R8)         DECREMENT COUNTER                         64000017
CMNOISE  EQU   *                                                        64200017
         LH    R6,NOISE       INSURE CIR IS AT LEAST MINIMUM LENGTH.    64400017
         B     CMCOM          GO TO GET ADDR OF BEGINNING OF CIR.       64600017
CMINTW   EQU   *                                                        64800017
         LA    RA,N1(N0,RA)   INCREMENT HIGH BOUND PTR.                 65000017
         LR    R7,RA          CALCULATE LENGTH OF AREA                  65200017
         SR    R7,R9          TO BE WRITTEN OUT.                        65400017
         L     R6,CKBUFL      GET BLKSIZE                               65600017
CMWAGN   EQU   *                                                        65800017
         LTR   R7,R7          Q. ANY MORE TO BE WRITTEN OUT.            66000017
         BZ    N0(R8)         NO-RETURN                                 66200017
         CR    R7,R6          Q. LENGTH TO BE WRITTEN LESS THAN BLKSIZE 66400017
         BNH   CMLSWT         YES- WRITE OUT SHORT BLOCK                66600017
         SR    RA,R6          GET ADDR OF BEGINNING OF CIR.             66800017
         SR    R7,R6          COMPUTE LENGTH OF AREA THAT WILL BE LEFT. 67000017
         BAL   R3,CMWRTO      GO TO WRITE A CIR.                        67200017
         B     CMWAGN         LOOP TO COMPLETE WRITING CIR'S            67300018
         EJECT                                                          67360018
*                                                                       67420018
*        GENERAL CONSTANTS                                              67480018
*                                                                       67540018
NOISE    DC    H'18'     MINIMUM LENGTH FOR CHKPT RECORD.               67600017
CKMN40   DC    C'IGC0N06C'    XCLT  PARM                                67800017
SURL     EQU   200            LENGTH OF SUR BUFFER                      67860017
DEBNMEXT EQU   16             NUMBER OF EXTENTS FOR THIS DEB            67920017
CKEOVERR EQU   X'031B'                                                  68000017
CKIOERMG EQU   X'0317'                                                  68200017
CKTPEOV  EQU   X'031C'        TAPE EOV ERROR                     A38515 68201021
PIBJPA   EQU   44         DISPLACEMENT FOR PIB JOB PACK POINTER    I250 68203019
MFTATT   EQU   X'22'         CVT INDICATOR FOR MFT ATTACH          I250 68206019
*                                                                       68210017
*        MASKS FOR TESTING AND BRANCHING                                68220017
*                                                                       68230017
X00      EQU   X'00'          TO INITIALIZE SWITCH                      68240017
X01      EQU   X'01'          TEST FOR SINGLE BUFFERING                 68250017
X08      EQU   X'08'          TEST TCBFLGS FOR F.P. REGS                68260017
X80      EQU   X'80'          TEST UCB FOR TAPE OUTPUT                  68270017
XFF      EQU   X'FF'                                                    68280017
SYSOUT   EQU   X'40'          INDICATES SYSOUT DATA SET                 68300017
SVRB     EQU   X'D0'          INDICATES TRANSIENT SVRB                  68310017
*                                                                       68320017
*        DSECT FOR SUPERVISOR RECORDS                                   68330017
*                                                                       68340017
SURSECT  DSECT                                                          68400017
TCBINFO  DS    12F            SAVE AREA                                 68600017
         DS    CL1            ALIGNMENT                                 68800017
FSA      DS    CL3            FIRST SAVE AREA                           69000017
DCBAD    DS    F              DCB ADDR                                  69200017
FQE1     DS    F              FQE 1ST                                   69400017
FLPTRFLG DS    CL1            FLOATING POINT FLAG                       69600017
FQE2     DS    CL3            FQE 2ND                                   69800017
FLTR0    DS    D              FLOATING-                                 70000017
FLTR2    DS    D              POINT-                                    70200017
FLTR4    DS    D              REGISTER-                                 70400017
FLTR6    DS    D              SAVE.                                     70600017
SYNAD    DS    F              SYNAD PARM                                70800017
CKIDAD   DS    F              ID ADDRESS                                71000017
CKID     DS    2F             ID                                        71200017
CKOFFST  DS    F              OFFSET                                    71400017
SYSOUTF  DS    10F            OUTPUT BUFFER                             71600017
STAE     DS    F              TCB STAE INFORMATION                      71650017
USER     DS    F              TCB USER FIELD SAVE AREA                  71700017
JOBPAK   DS    F              ADDRESS OF JOB PACK AREA             I250 71720019
         EJECT                                                          71750017
         IEEVCHWA                                                       71800017
CKTSTEOV EQU CKUNIT                                                     72000017
CKEOVCMR EQU CKUNIT+4                                                   72200017
SWITCH   DS    F              EQU 1 FOR SINGLE BUFFERING                72300018
*                             EQU 2 LAST WRITE WAS WRITE 1              72400018
*                                                                       72500018
CMS1     EQU   1    INDICATES SINGLE BUFFERING.                         72600017
CMS2     EQU   2    INDICATES WRITE 1 WAS LAST WRITE.                   72800017
CMADEOV  DS    F    SAVE AREA FOR INFORMATION NEEDED                    73000017
CMNEOV   DS    F    TO TEST IF EOV OCCURRED.                            73200017
CKMXLIST DS    2F   NAME OF NEXT MODULE TO RECEIVE CONTROL.             73400017
CKMN40AD DS    F              POINTER TO XCTL PARAMETER LIST            73600018
CMSYSA   DS    F              ADDRESS OF CHKMAIN SYNAD ROUTINE          73800018
UCBSECT  DSECT                                                          74000017
         IEFUCBOB                                                       74200017
         IHBABCTL                                                       74400017
TCBPIB   EQU   TCBJSTCB                                            I250 74500019
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               74600017
DEBEXSCL EQU   DEBAPPAD                                                 75500018
*                                                                       76400017
*              GENERAL  DISPLACEMENT EQUATES                            77400017
*                                                                       78400017
N0       EQU   0                                                        79400017
N1       EQU   1                                                        80400017
N2       EQU   2                                                        81400017
N3       EQU   3                                                        82400017
N4       EQU   4                                                        83400017
N5       EQU   5                                                        84400017
N7       EQU   7                                                        85400017
N8       EQU   8                                                        86400017
N13      EQU   13                                                       87400017
N16      EQU   16                                                       89400017
N48      EQU   48                                                       90400017
N255     EQU   255                                                      91400017
C2       EQU   C'2'                                                     97400017
         END                                                            98400017
