*                                                                       00030020
         GBLC  &LIB                     DEFINE GLOBAL CHARACTER         00060020
*                                       * VARIABLE.                     00090020
&LIB     SETC  'LIB1'                   SET VALUE FOR &LIB              00120020
*                                                                       00150020
         TITLE 'IGC0Q06C - CHKPT EXIT ROUTINE (IHJACP50)'               00300018
IGC0Q06C CSECT                                                          00400018
*        RELEASE 23 DELETIONS/CHANGES                                   00410021
*        RELEASE 22 DELETIONS/CHANGES                                   00420021
*        RELEASE 21.8 DELETIONS/CHANGES                                 00421021
*0000189000,226000-250000,356600-357000,672000-674000,710760    SA69185 00422021
*0000002000,126400-126500                                        S21940 00423021
*        RELEASE 21 DELETIONS/CHANGES                                   00430021
*    232000,342000-346000                                       SA51163 00432021
*        RELEASE 20 DELETIONS/CHANGES                                   00440021
*0535181700-183200                                               A32184 00450020
*STATUS CHANGE LEVEL 002                                                00520020
*FUNCTION/OPERATION - FOR NORMAL PROCESSING THIS ROUTINE WILL DO        00600018
*                   THE FOLLOWING                                       00700018
*                                                                       01200017
*                     1.)  ISSUE A STOW MACRO ON THE CHECKID IF THE     01400017
*                        CHKPT DATA SET IS A PARTIONED DATA SET.        01600017
*                                                                       01800017
*                     2.)  UPDATE THE JCT AND WRITE IT OUT TO THE       02100017
*                     3.)  FREEMAIN FOR THE CHKPT WORK AREA             02400017
*                     4.)  XCTL TO MESSAGE MODULE                       02700017
*                                                                       03100017
*                     FOR ERROR PROCESSING THIS ROUTINE WILL DO THE     03200017
*                     FOLLOWING                                         03300017
*                                                                       03400017
*                     1.)  FREEMAIN FOR CHKPT WORK AREA IF CHKPT HOUSE- 03600017
*                        KEEPING GOT CORE FOR IT                        03800017
*                                                                       03900017
*                     2.)  IF THE CHR WAS WRITTEN, WRITE THE JCT WITH   04000017
*                        ONLY THE JCTCKIDT UPDATED                      04100017
*                                                                       04200017
*                     3.)  XCTL TO MESSAGE MODULE IGC0S06C              04800017
*                     FOR PROCESSING A CANCEL REQUEST THIS ROUTINE WILL 05400017
*                   DO THE FOLLOWING                                    05600018
*                     1.)  ZERO OUT THOSE FIELDS IN THE JCT THAT ARE    05800017
*                        MAINTAINED BY CHKPT (I.E. JCTDEVT, JCTCKTTR,   06000017
*                        JCTCKIDL, JCTCKIDT).                           06200017
*                     2.)  WRITE OUT THE JCT TO THE JOB QUEUE.          06400017
*                     3.)  FREEMAIN FOR THE WORK AREA.                  06600017
*                     4.)  PUT X'00' RETURN CODE IN REGISTER 15.        06800017
*                     5.)  RETURN CONTROL TO THE USER.                  06900017
*                                                                       07000017
*ENTRY POINT  IHJACP50                                                  07050017
*INPUT   ADDRESS OF THE CHKPT WORK AREA IN REGISTER 1.                  07100017
*        IF REGISTER 1 IS ZERO UPON ENTRY, CORE WAS NOT OBTAINED FOR    07150017
*        THE WORK AREA.  IN THIS CASE REGISTER 5 WILL CONTAIN THE       07200017
*        ADDRESS OF CHKPT'S SVRB.  BYTES 0-3 OF THE EXTENDED SAVE AREA  07250017
*        WILL CONTAIN THE RETURN CODE AND MESSAGE CODE, BYTES 33-35 THE 07300017
*        TIOT ADDRESS AND BYTES 37-39 THE DCB ADDRESS OR ZERO (IF A BAD 07350017
*        PARAMETER LIST WAS PASSED).  BIT 3 (HKPCLOSE) OF BYTE 32       07400017
*        (HKPFLAG) WILL BE 1 IF CHKPT HOUSEKEEPING OPENED THE CHKPT     07450017
*        DATA SET.                                                      07500017
*OUTPUT  CANCEL REQUEST                                                 07560018
*              RETURN CODE IN REGISTER 15                               07620018
*        NON CANCEL REQUEST                                             07680018
*              1.) ADDRESS OF SVRB IN REGISTER 1                        07750017
*              2.) RETURN CODE AND MESSAGE CODE IN FIRST 4 BYTES OF THE 07800017
*                  SVRB EXTENDED SAVE AREA                              07850017
*              3.) IF ERROR OCCURRED BEFORE CHR WAS WRITTEN             07900017
*                    BYTES IN SVRB        CONTENTS                      07950017
*                        16-23               JOBNAME                    08000017
*                        24-31               DDNAME (OR 0 IF ERROR CODE 08050017
*                                                       IS 01)          08100017
*                        36-39               DCB ADDRESS                08120017
*              4.) IF ERROR OCCURRED AFTER CHR WAS WRITTEN, OR NO ERROR 08150017
*                  OCCURRED                                             08200017
*                    A.) BYTES IN SVRB    CONTENTS                      08300017
*                             16-31               CHECKID               08400017
*                        32-35               TIOT ADDRESS               08440017
*                        36-39               DCB ADDRESS (HIGH ORDER    08480017
*                                                BYTE=X'80' IF CHKPT    08520017
*                                                OPENED THE DATA SET    08560017
*EXTERNAL ROUTINES  NONE                                                08600017
*SVC USED  FREEMAIN,XCTL,EXIT                                           08650017
*EXITS-NORMAL 1.) FOR CANCEL-RETURN CONTROL TO USER WITH RETURN CODE    08700017
*                                 IN REGISTER 15                        08750017
*             2.) IF NOT CANCEL-XCTL TO CHKPT MESSAGE MODULE IGC0S06C   08800017
*     -ERROR NONE                                                       08850017
*TABLES/WORK AREAS-CREATED-CERSECT (CONTAIN INFO FOR MESSAGE MODULE)    08900017
*                  -REFERENCED- TCB,TIOT,JCT,UCB,CHKWA,DCB              08950017
*ATTRIBUTES - REENTRANT, SUPERVISOR STATE, TYPE 4 SVC ROUTINE.          09050018
*RESTRICTIONS ON USE OF ROUTINE - NONE.                                 09150018
*NOTES - NONE.                                                          09250018
         EJECT                                                          09400021
         USING CHKWA,RC                                                 09600017
         BALR  RB,ZERO             SET UP MODULE ADDRESSABILITY         09800018
         USING *,RB                                                     10000017
         LTR   R1,R1              IS THERE A CHKPT WA                   10200017
         BZ    CERERCHK            NO-CHECK TO DETERMINE ACTION         10400017
         LR    RC,R1              SET UP CHKPT WA ADDRESSABILITY        10600017
         LA    RD,CKREGSAV         INITIALIZE SAVE AREA REG.            11200017
         LA    R3,DXECB            GET ECB ADDR.                        11400017
         LA    R7,INJMJCT          GET ADDR OF JCT WRITE-OUT AREA.      11600017
         L     R5,CVTPTR(ZERO)     GET CVT ADDR.                        11800018
         USING CVTSECT,R5          ADDRESS CVT                          12000017
         L     R5,CVTJOB           GET ADDR OF JOB Q DCB.               12200017
         DROP  R5                                                       12400017
         L     R4,CKTCBAD          GET THE TCB ADDRESS                  12410017
         USING TCBSECT,R4                                               12420017
         L     R9,TCBRBP           GET ADDRESS OF CHECKPOINTS SVRB      12430017
         USING CERSECT,R9                                               12440017
         MVC   CERRETCD(CERMSGMD-CERRETCD),CKRETCOD                     12450018
*                                       CODES FOR MESSAGE MODULE        12460018
         MVC   CERFLAG(LFLAG),CKFLAG1   MOVE FLAG FOR COMMON ADDRESSING 12470018
         TM    CKFLAG1,CKCANCEL    WAS CANCEL REQUESTED                 12480017
         BO    CERCANC             BRANCH TO PROCESS IF YES             12490017
         L     R8,CKDCBAD          GET ADDRESS OF CHEKPT DCB            12500017
         LA    R8,0(R8)            CLEAR HIGH ORDER BYTE                12503017
         ST    R8,CERDCBAD         SAVE ADDRESS FOR MSG. MODULE         12506017
         USING IHADCB,R8                                                12510017
         L     R2,TCBTIO           GET TIOT ADDRESS                     12520017
         USING TIOTSECT,R2                                              12530017
         TM    CKFLAG2,CKCHR       WAS THE CHR WRITTEN                  12540017
         BO    CERGETID            BRANCH IF YES                        12550017
*                                                                     * 12552018
*********************************************************************** 12554018
*                                                                     * 12556018
*   SET UP PARAMETER LIST FOR THE MESSAGE MODULE.  SINCE THE CHR WAS    12560017
*   NOT WRITTEN, ONLY THE JOBNAME AND DDNAME ARE REQUIRED FOR THE MSG.  12570017
*                                                                     * 12572018
*********************************************************************** 12574018
*                                                                     * 12576018
         MVC   CERJOBNM(LJOBNM),TIOCNJOB     MOVE IN JOBNAME FROM TIOT. 12583018
         AH    R2,DCBTIOT          POINT AT DD ENTRY IN TIOT            12590017
         USING TIOELNGH,R2                                              12600017
         MVC   CERDDNM(CERTIOAD-CERDDNM),TIOEDDNM                       12606018
*                                  MOVE DDNAME TO MSG MOD PARMLST       12612018
         B     CERSYNR             BRANCH TO FREEMAIN AND CLOSE         12620017
*                                                                     * 12621018
*********************************************************************** 12622018
*                                                                     * 12623018
*   SET UP PARAMETER LIST FOR THE MESSAGE MODULE.  SINCE THE CHR WAS  * 12623221
*   WRITTEN, THE CHECKID, TIOT ADDRESS, AND THE DCB ADDRESS ARE       * 12623421
*   PASSED TO THE MSG MODULE.                                         * 12623621
*                                                                     * 12624018
*********************************************************************** 12625018
*                                                                     * 12626018
CERGETID EQU   *                                                        12630017
         MVI   CERCHKID,SPACE                BLANK OUT THE CHECKID      12660018
         MVC   CERCKID1(LCHKID),CERCHKID     FIELD IN THE PARAM AREA.   12670018
         ST    R2,CERTIOAD         SAVE TIOT ADDRESS FOR MSG. MOD.      12700017
         TM    CKFLAG2,CKUSPCHD    DID USER SUPPLY THE CHECKID          12720017
         BZ    CERGETGN            BRANCH IF NO TO GET GENERATED ONE    12730017
         L     R6,CKPARMAD         GET ADDRESS OF PARAMETER LIST        12740017
         USING CHKPTPML,R6         MAPPING CHKPT PARM                   12746018
         L     R4,IDADDR           GET ADDR OF THE CHECKID              12752018
         XR    R2,R2               CLEAR REGISTER 2 FOR INSERT          12760017
         IC    R2,LUSERID          GET LENGTH OF CHECKID                12770018
         BCTR  R2,ZERO             SUBTRACT ONE FOR EXECUTE             12780018
         B     CERMOVE             GO TO MOVE CHECKID TO PARMLST        12790018
CERGETGN EQU   *                                                        12800017
         LA    R4,CKCHEKID         GET ADDRESS OF GENERATED CHKID       12810017
         LA    R2,LENGTH1          LENGTH-1 FOR EXECUTE                 12820018
CERMOVE  EX    R2,CERMOVID         MOVE CHECKID TO PARAM AREA           12830017
         DROP  R4,R2,R6                                                 12840018
*                                                                     * 12850018
*********************************************************************** 12860018
*                                                                     * 12870018
*        FOR BPAM CHECKPOINT DATA SET, WHEN NO ERRORS HAVE BEEN       * 12880018
*        ENCOUNTERED(EXCEPT OUTSTANDING ENQUEUES) STOW CHKPT ENTRY    * 12890018
*        UNDER CHECKID AS MEMBER                                      * 12900018
*                                                                     * 12910018
*********************************************************************** 12920018
*                                                                     * 12930018
CERCKCD  EQU   *                                                        12940017
         CLI   CKRETCD1,CKPSBERR   DOES RETURN CODE INDICATE ONLY       13040018
*                                  A POSSIBLE ERROR.                    13200017
         BE    CERSKP1             YES-SKIP ERROR CHECK.                13400017
         CLI   CKRETCD1,HEXZERO    HAVE ANY ERRORS BEEN ENCOUNTERED     13600018
         BNZ   CERSKP2             YES-SKIP CODE TO STOW CHKPT ENTRY    13800018
CERSKP1  TM    CKFLAG1,CKBPAM      WAS CHKPT DATA SET OPENED FOR BPAM   14000017
         BZ    CERSKP2             NO-DO NOT STOW ENTRY                 14200017
         L     R1,CKDCBAD               SET UP                          14400017
         LA    R0,CERSTOW               PARAMETERS                      14600017
         MVC   CERSTOW(IDL),CERCHKID    FOR STOW MACRO                  14800017
         MVC   CERSTOW8(LTTR),CKTTR     TTR FOR STOW MACRO              15000018
         STOW  (1),(0),R                                                15200017
         B     *+4(RF)             BRANCH TABLE DETERMINES PROCESSING   15300018
*                                  TO BE DONE DEPENDING UPON THE RETURN 15400018
*                                  CODE FROM STOW                       15500018
         B     CERSKP2             OK-CONTINUE                          15600018
         B     CER10               I/O ERROR-GO TO MOVE ERRCODE TO WA   15800018
         B     CERSKP2             OK-CONTINUE                          16000018
         B     CER0C               NOT ENOUGH ROOM IN DIRECTORY-GO TO   16100018
*                                  INDICATE PROGRAMMER ERROR            16200018
         B     CER10               I/O ERROR-GO TO MOVE ERRCODE TO WA   16240018
*                                                                     * 16280018
*********************************************************************** 16320018
*                                                                     * 16360018
*        DETERMINE IF CHKPT DATA SET ON DATA CELL AND GET UCB ADDR    * 16400018
*        IN ORDER TO PUT DEVICE TYPE INTO JCT FIELD - JCTDEVT         * 16440018
*                                                                     * 16480018
*********************************************************************** 16520018
*                                                                     * 16560018
CERSKP2  EQU   *                                                        16600017
         L     R6,CKTCBAD          GET THE TCB ADDRESS                  16630017
         USING TCBSECT,R6                                               16660017
         L     RE,TCBTIO                                                16690017
         AH    RE,DCBTIOT                                               16720017
         USING TIOELNGH,RE                                              16750017
         L     R6,TIOTUCB          GET THE UCB ADDRESS FROM TIOT        16760018
         USING UCBSECT,R6                                               16770018
         CLI   UCBID,MAINUCB       IS THIS A MAIN UCB                   16780018
         USING DATACELL,R6                                              16790018
         BE    CERFD               BRANCH IF YES                        16840017
*   THIS IS NOT A MAIN UCB--THEREFORE IT IS A SUB-UCB OF A DATA CELL    16870017
         LA    R6,ZERO(R6)         CLEAR HIGH ORDER BYTE                16890018
         LH    RA,DCELBBNR         GET THE BIN NUMBER                   16910018
         SLL   RA,PERSUB           MULTIPLY BY 16 FOR EACH SUB-UCB      16930018
*                                  PRECEDING THIS SUB-UCB IN CALCULATI  16950018
*                                  ING DISPLACEMENT TO MAIN UCB         16970018
         LA    RA,SRTEUSER-SRTEJBNR(RA)                                 16990018
*                                  INCREMENT BY LENGTH OF MAIN UCB      17010018
         SR    R6,RA               SUBTRACT FROM SUB-UCB ADDRESS TO     17050017
*                                  GET THE ADDRESS OF THE MAIN UCB      17080017
*                                                                     * 17100018
*********************************************************************** 17120018
*                                                                     * 17140018
*        IF CHR WAS NOT WRITTEN DO NOT UPDATE JCT OR WRITE JCT TO JOB * 17160018
*        QUEUE, OTHERWISE, MOVE CHECKID TO JCT                        * 17180018
*        IF AN ERROR OCCURRED OTHER THAN OUTSTANDING ENQUEUES OR      * 17200018
*        IMMEDIATE RESTARTS SUPPRESSED BRANCH TO WRITE JCT TO JOB Q   * 17220018
*                                                                     * 17240018
*********************************************************************** 17260018
*                                                                     * 17280018
CERFD    EQU   *                                                        17320017
         USING UCBSECT,R6          ADDRESS UCB                          17370017
         TM    CKFLAG2,CKCHR       WAS CHR WRITTEN                      18000017
         BZ    CERSYNR             BRANCH TO FREEMAIN AND CLOSE         18100017
         CLI   CERRETC1,CKPSBERR   RETURN CODE INDICATE POSSIBLE ERROR  18360018
*                                  A POSSIBLE ERROR                     18400017
         BE    CERAFER             YES-UPDATE JCT                       18440018
         CLI   CERRETC1,HEXZERO    HAS AN ERROR OCCURED                 18490018
         BNE   CERJCT1             BRANCH IF YES--SKIP UPDATING THE JCT 18540017
CERAFER  EQU   *                                                        18600017
         TM    JCTRSW2,JCTNORST    ARE IMMEDIATE RESTARTS SUPPRESSED    18800017
         BO    CERJCT1             BRANCH IF YES                        18860017
         MVI   JCTCKIDT,SPACE          BLANK OUT CHK ID IN JCT   A32184 18861020
         MVC   JCTCKID1(CKL),JCTCKIDT                            A32184 18862020
         EX    R2,CERMVID              EX MOVE OF CHK ID TO JCT  A32184 18863020
*                                                                     * 18865018
*********************************************************************** 18870018
*                                                                     * 18875018
*        UPDATE THE FOLLOWING FIELDS IN JCT:                          * 18880018
*            JCTRSW1 - SWITCH - CHKPT TAKEN                           * 18885018
*            JCTDEVT - DEVICE TYPE CHKPT D.S.                         * 18890018
*            JCTRSW2 - SWITCH - SYSCHK                                * 18895018
*                                                                     * 18905018
*********************************************************************** 18910018
*                                                                     * 18915018
CERSKP4  EQU   *                                                        18920017
         MVC   JCTCKTTR(CKTTRL),TIOEJFCB                                20800017
         OI    JCTRSW1,JCTCKFT     TURN ON CHKPT TAKEN BIT.             21600017
         MVC   JCTDEVT(DEVTL),UCBTYP MOVE DEVICE TYPE INFO TO JCT.      22400017
         NI    JCTRSW2,X'7F'       TURN OFF POSSIBLE SYSCHK BIT         22500017
*                                                                       22600021
CERJCT1  EQU   *                                                        25200017
         LA    R7,INJMJCT          LOAD ADDR OF WRITE OUT AREA.         25400017
         MVC   DXDAADDR(CKREGSAV-CKJCTMB),CKJCTMB                       25440018
*                                  MOVE JCT MBBCCHHR ADDR TO IOB        25480018
*                                                                     * 25520018
*********************************************************************** 25560018
*                                                                     * 25600018
*        WRITE JCT TO JOB QUEUE                                       * 25640018
*                                                                     * 25680018
*********************************************************************** 25720018
*                                                                     * 25760018
CERJCTW  EQU   *                                                        25800017
         BAL   RA,CERQW            GO TO WRITE OUT JCT.                 26000017
*                                                                     * 26200018
*********************************************************************** 26400018
*                                                                     * 26600018
*        RESTORE CHKPT DCB SYNAD ADDR EXCECT FOR CHKPT CANCEL REQUEST * 26800018
*                                                                     * 27000018
*********************************************************************** 27200018
*                                                                     * 27400018
CERSYNR  EQU   *                                                        27600017
         TM    CKFLAG1,CKCANCEL    WAS CANCEL REQUESTED.                27800017
         BO    CERTURN             YES-SKIP CODE TO RESTORE SYNAD ADDR. 28000017
         L     R8,CKDCBAD          GET ADDR OF CHKPT DCB.               28200017
         USING IHADCB,R8           ADDRESS CHKPT DCB.                   28400017
         MVC   SYNAD1(CKPARMAD-CKSYNAD1),CKSYNAD1                       28440018
*                                  RESTORE SYNAD ADDR IN CHKPT DCB      28480018
*                                                                     * 28520018
*********************************************************************** 28560018
*                                                                     * 28600018
*        RESTORE CHKPT DCBBLKSIZE IF CHKPT SUPPLIED BLKSIZE           * 28640018
*                                                                     * 28680018
*********************************************************************** 28720018
*                                                                     * 28760018
CERTURN  EQU   *                                                        28800017
CERCON2  EQU   *                                                        29340017
         L     R8,CKDCBAD          ADDRESS CHKPT DCB                    29343017
         L     R2,CKTCBAD          ADDR TCB                             29350017
*                                                                     * 29350218
*********************************************************************** 29350418
*                                                                     * 29350618
*        FREEMAIN CHKPT WORK AREA (SUBPOOL 250)                       * 29350818
*                                                                     * 29351018
*********************************************************************** 29351218
*                                                                     * 29351418
         TM    CKFLAG2,CKSPBKSZ    DID CHECKPOINT SUPPLY BLKSIZE        29352017
         BZ    CERFREWA            BRANCH IF NO                         29354017
         XC    DCBBLKSI(LBLKSIZ),DCBBLKSI  RESET BLKSIZE IN DCB TO ZERO 29356018
CERFREWA EQU   *                                                        29358017
         USING TCBSECT,R2                                               29360017
         L     R2,TCBRBP           ADDR CHKPT SVRB                      29370017
         L     R0,CKWACL           SET UP FREEMAIN                      29400017
         O     R0,SP250            INDICATE SP 250.                     29600017
         LA    R1,CHKWA            PARAMETER REGISTERS                  29800017
         FREEMAIN R,LV=(0),A=(1)   FREE WORK AREA                       30000017
*                                                                     * 30040018
*********************************************************************** 30080018
*                                                                     * 30120018
*        SET FLAG IN PARMLST FOR MSG.MOD. TO CLOSE CHKPT D.S. IF      * 30160018
*        CHKPT OPENED D.S.                                            * 30200018
*********************************************************************** 30240018
*                                                                     * 30280018
*                                                                     * 30320018
         TM    CERFLAG,CKOPEN      DID CHKPT OPEN DATA SET              30400017
         BZ    CERRET              NO-RETURN TO USER                    30800017
CERSTCLS EQU   *                                                        31100017
         OI    CERDCBAD,CERMCLS    SET BIT TO HAVE MSG. MOD. CLOSE      31400017
*                                  CHKPT DATA SET                       31700017
*                                                                     * 31750018
*********************************************************************** 31800018
*                                                                     * 31850018
*        IF CANCEL WAS REQUESTED RETURN TO CALLER VIA SVC 3, ELSE     * 31900018
*        GO TO XCTL TO MSG.MOD.(IHJACP70)                             * 31950018
*                                                                     * 32000018
*********************************************************************** 32050018
*                                                                     * 32100018
CERRET   EQU   *                                                        32200017
         TM    CERFLAG,CKCANCEL    WAS CANCEL REQUESTED                 32300017
         BZ    CERMSGX             BRANCH IF NO TO MSG. MOD EXIT        32400017
         LH    RF,CERRETCD         LOAD RETURN CODE                     32500017
         SVC   3                   RETURN TO CALLING PROGRAM            32600017
CERMSGX  EQU   *                                                        32700017
         MVC   CERMSGMD(LMODNAME),CERMSGID   MOVE MOD.NAME TO XCTL PARM 32800018
         LA    R7,CERMSGMD         ADDRESS OF MODULE NAME               33000017
         ST    R7,CERXCTL          PUT IN PARM LIST FOR XCTL            33100017
         LA    RF,CERXCTL                                               33200017
         LR    R1,R9               PUT ADDRESS OF SVRB IN R1            33300017
         XCTL  SF=(E,(15))         GO TO MESSAGE MODULE                 33400017
*                                                                     * 34610018
*********************************************************************** 34620018
*                                                                     * 34630018
*        SET MSG AND RET CODE IN PARMLST WHEN I/O ERROR OCCURS DURING * 34640018
*        STOW AND THEN CONTINUE PROCESSING                            * 34650018
**                          RETURN CODE  = 0C(HEX)                    * 34660018
*                           MESSAGE CODE = 26(DEC)                    * 34670018
*                                                                     * 34680018
*********************************************************************** 34690018
*                                                                     * 34700018
CER10    EQU   *                                                        34800017
         MVI   CERRETC1,CKIOERR    MOVE IN RETURN CODE                  35000018
         LA    RA,CKERIO5          LOAD MESSAGE CODE                    35200017
         STH   RA,CERMSGCD         PUT IN PAR AREA FOR MSG. MODULE      35400017
         B     CERSKP2             CONTINUE PROCESSING                  35500018
*                                                                     * 35710018
*********************************************************************** 35720018
*                                                                     * 35730018
*        INITIALIZES PARMLST TO MSG.MOD. WHEN ERROR OCCURRED BEFORE   * 35740018
*        CHKPT GETMAIN'D FOR WORKAREA                                 * 35750018
*                                                                     * 35760018
*********************************************************************** 35770018
*                                                                     * 35780018
CERERCHK EQU   *                                                        35800017
         USING HKPSECT,R5                                               35870017
         LR    R9,R5               PUT ADDRESS OF SVRB IN R9            35940017
         MVC   CERFLAG(LFLAG),HKPFLAG   MOVE FLAG TO COMMON AREA        36010018
         L     R4,HKPTIOT          GET TIOT ADDRESS                     36080018
         DROP  RE                                                       36150017
         USING TIOTSECT,R4                                              36220017
         L     R8,HKPDCB           GET DCB ADDRESS                      36270018
         LA    R8,ZERO(R8)         CLEAR HIGH ORDER BYTE                36320018
         ST    R8,CERDCBAD         SAVE DCB ADDRESS FOR MSG. MOD.       36390017
         MVC   CERJOBNM(LJOBNM),TIOCNJOB     MOVE JOBNAME TO MSG. PARMS 36440018
         LTR   R8,R8               Q. IS THERE A DCB ADDRESS            36500017
         BZ    CERMSGX             BRANCH IF NO TO MESSAGE MODULE       36570017
         TM    DCBOFLGS,CKDCBOP    IS THE DCB OPENED                    36640017
         BZ    CERMVDD             BRANCH IF NOT--GET DDNAME FROM DCB   36710017
*                                  IF YES, GET DDNAME FROM TIOT         36780017
         AH    R4,DCBTIOT          POINT TO TIOT ENTRY                  36850017
         USING TIOELNGH,R4                                              36920017
         MVC   CERDDNM(LDDNM),TIOEDDNM  MOVE DDNAME TO MESG. MOD. PARMS 36990018
         TM    CERFLAG,HKPCLOSE    DID CHECKPOINT OPEN THE DATA SET     37060017
         BO    CERSTCLS            BRANCH TO SET CLOSE BIT FOR MSG. MOD 37130017
         B     CERMSGX             BRANCH TO GO TO MESSAGE MODULE       37200017
CERMVDD  MVC   CERDDNM(LDDNM),DCBDDNAM  MOVE DDNAME TO MESSAGE PARMS.   37270018
         B     CERMSGX             BRANCH TO GO TO MESSAGE MODULE       37340017
         DROP  R4,R5                                                    37410017
*                                                                     * 37420018
*********************************************************************** 37430018
*                                                                     * 37440018
*        CHKPT CANCEL PROCESSING - IF A CHKPT HAS BEEN TAKEN DURING   * 37450018
*        THIS STEP,CHKPT FIELDS IN JCT ARE ZERO'D OUT SO THAT IT WILL * 37460018
*        APPEAR THAT A CHKPT HAS NOT BEEN TAKEN AND AN IMMEDIATE      * 37470018
*        RESTART IS NOT POSSIBLE                                      * 37480018
*                                                                     * 37490018
*********************************************************************** 37500018
*                                                                     * 37510018
CERCANC  EQU   *                                                        37600017
         TM    JCTRSW1,JCTCKFT     HAS A CHKPT BEEN TAKEN IN THIS STEP  37800017
         BZ    CERCON2             NO-GO TO FREE WORK AREA              38000018
CERZERO  EQU   *                                                        38200017
         XC    JCTDEVT(LJCT),JCTDEVT    ZERO OUT JCT FIELDS.            38400018
         XC    JCTCKTTR(CKTTRL),JCTCKTTR                                38600017
         XC    JCTCKIDL(TWO),JCTCKIDL                                   38800018
         MVI   JCTCKIDT,SPACE      BLANK OUT CHECKID FIELD IN JCT.      39000018
         MVC   JCTCKID1(CKL),JCTCKIDT                                   39200018
         XI    JCTRSW1,JCTCKFT     TURN OFF CHKPT TAKEN BIT.            39400017
         B     CERJCTW             GO TO WRITE OUT JCT.                 39600017
*                                                                     * 39610018
*********************************************************************** 39620018
*                                                                     * 39630018
*        SET MESSAGE AND RETURN CODE IN PARMLST FOR MSG.MOD WHEN      * 39640018
*        STOW MACRO FAILED BECAUSE DIRECTORY OF CHKPT BPAM D.S.       * 39650018
*        RAN OUT OF SPACE                                             * 39660018
*                             RETURN CODE  = 08                       * 39670018
*                             MESSAGE CODE = 17(DEC)                  * 39680018
*                                                                     * 39690018
*********************************************************************** 39700018
*                                                                     * 39710018
CER0C    EQU   *                                                        39800017
         MVI   CERRETC1,CKPGMERR   MOVE RETURN CODE TO MSG. PARMS       40000018
         LA    RA,CKERPG17         GET MSG. CODE                        40200017
         STH   RA,CERMSGCD         PUT IN MSG. PARMS                    40400017
         B     CERSKP2             RETURN TO MAIN-LINE CODE AFTER STOW  40440018
*                                                                     * 40480018
*********************************************************************** 40520018
*                                                                     * 40560018
*        SUBROUTINE TO WRITE JCT TO JOB QUEUE AND CHECK FOR SUCCESSFUL* 40600018
*        COMPLETION                                                   * 40640018
*                                                                     * 40680018
*********************************************************************** 40720018
*                                                                     * 40760018
CERQW    EQU   *                                                        40800017
         XDAP  (3),WI,(5),(7),,,,MF=E   WRITE A RECORD TO THE JOB Q.    41000017
CERCOMM  LR    R1,R3               ADDR OF I/O ECB.                     41200017
         WAIT  1,ECB=(1)           WAIT COMPLETION OF I/O.              41400017
         CLI   ZERO(R3),IOCC       WAS I/O SUCCESSFUL                   41600018
         BNE   CERIO               NO-RETURN TO USER WITH ERROR CODE.   41800017
         BR    RA                  RETURN TO CALLER.                    42000017
*                                                                     * 42080018
*********************************************************************** 42160018
*                                                                     * 42240018
*        SETTING MSG AND RET CODES WHEN I/O ERROR OCCURS WRITING JCT- * 42320018
*        IF AN ERROR OCCURRED PREVIOUS TO WRITING TO JOB Q (OTHER THEN* 42400018
*        OUTSTANDING ENQUEUES) THEN USER IS NOTIFIED THROUGH CONSOLE  * 42480018
*        MESSAGE AND RETURN CODE OF PREVIOUS ERROR, OTHERWISE, CODES  * 42560018
*        ARE SET IN PARMLST TO MSG.MOD OF JOB Q I/O ERROR             * 42640018
*                             RETURN CODE  = 0C(HEX)                  * 42720018
*                             MESSAGE CODE = 02                       * 42800018
*                                                                     * 42880018
*********************************************************************** 42960018
*                                                                     * 43040018
CERIO    EQU   *                                                        43200017
         CLI   CERMSGCD,HEXZERO    DID A PREVIOUS ERROR OCCUR           43250018
         BE    CERJCTER            BRANCH IF NO                         43300017
         CLI   CERRETC1,CKPSBERR   WAS THE PREVIOUS ERROR ONLY A        43350018
*                                  POSSIBLE ERROR                       43400017
         BNE   CERSYNR             BRANCH IF NO,TELL CALLER ABOUT       43450017
*                                  PREVIOUS ERROR                       43500017
CERJCTER MVI   CERRETC1,CKIOERR    MOVE IN RETURN CODE                  43550018
         MVI   CERMSGCD,CKERIO6    JCT-WRITE ERROR CODE                 43600017
         B     CERSYNR             BRANCH TO FREEMAIN AND CLOSE         43650017
*                                                                     * 45650018
*        EXECUTED INSTRUCTION                                         * 47650018
*                                                                     * 49650018
CERMVID  MVC   JCTCKIDT(ONE),ZERO(R4)   MOVE CHECKID TO JCT.            51650018
CERMOVID MVC   CERCHKID(ONE),ZERO(R4)   EXECUTED INSTRUCTION            53650018
*                                                                     * 54250018
*        CONSTANTS                                                    * 54850018
*                                                                     * 55450018
CERMSGID DC    CL8'IGC0S06C'       MODULE NAME FOR XCTL PARMLST         56050018
         DS    0F                                                       56800017
SP250    DC    X'FA000000'         SPECIFY SUBPOOL 250 FOR FREEMAIN WA  56880018
*                                                                S21940 56890021
*********************************************************************** 56895021
*        PATCH AREA DEFINITION                                        * 56900021
*********************************************************************** 56905021
*                                                                S21940 56910021
LNGQ06C  EQU   *-IGC0Q06C          LENGTH BEFORE PATCH AREA      S21940 56915021
*                                                                S21940 56920021
PATCHLNG EQU   1024-LNGQ06C        PATCH AREA LENGTH             S21940 56925021
*                                                                S21940 56930021
         DC    (PATCHLNG)X'00'     ZEROED PATCH AREA             S21940 56935021
*                                                                S21940 56940021
         EJECT                                                   S21940 56945021
*                                                                     * 56960018
*        MAPPING OF PARAMETER LIST FOR CHKPT                            57040018
*                                                                     * 57120018
CHKPTPML DSECT                                                          57200018
DCBADDR  DS    0F                                                       57280018
FLAGBYTE DS    CL1       INDICATES USER/SYS-GEN/SSS-GEN AND RETURN ID   57360018
DCBAD    DS    CL3       CHKPT D.S. DCB                                 57440018
IDADDR   DS    0F                                                       57520018
LUSERID  DS    CL1       LENGTH USER CHKID/RETURN SYSTEM-GEN CHKID      57600018
CHKIDADR DS    CL3       ADDR OF CHECKID                                57680018
CKCHR    EQU   128  INDICATES CHKPT WROTE OUT CHR                       57800017
*                                                                       57820018
*        MAPPING OF CHKPT SVRB AND EXTENDED SAVEAREA USED TO PASS       57840018
*        INFORMATION TO EXIT MODULE ON ERROR CONDITIONS.                57860018
*                                                                       57880018
HKPSECT  DSECT                                                          57900017
HKPSVRB  DS    24F       BASIC SECTION OF SVRB                          57980018
HKPGML2  DS    F         SAVE AREA FOR ERROR RETURN AND MESSAGE CODES   58060018
HKPGML   DS    F         N/A                                            58140018
HKPGMLAD DS    2F        N/A                                            58220018
HKPGLIST DS    2F        N/A                                            58300018
         DS    F         N/A                                            58380018
HKPTIOTL DS    H         LENGTH OF TIOT                                 58460018
HKPBUFL  DS    H         N/A                                            58540018
HKPTIOT  DS    0F                                                       58620018
HKPFLAG  DS    1C        FLAG BYTE                                      58700018
HKPCLOSE EQU   X'10'     INDICATES EXIT RTN MUST CLOSE CHKPT D.S.       58780018
HKPTIOAD DS    3C        ADDRESS OF TIOT                                58860018
HKPDCB   DS    0F                                                       58940018
HKPSP    DS    CL1       N/A                                            59020018
HKPDCBAD DS    3C        ADDRESS CHKPT DCB                              59100018
HKPSAVRN DS    F         N/A                                            59180018
*                                                                       59260018
*        ALTERNATE MAPPING OF CHKPT SVRB AND EXTENDED SAVE AREA USED    59340018
*        TO PASS INFORMATION TO MESSAGE MODULE TO BUILD WTO MESSAGE     59420018
*                                                                       59500018
CERSECT  DSECT                                                          59580018
CERSVRB  DS    24F       BASIC SECTION OF SVRB                          59660018
CERRETCD DS    H         RETURN CODE                                    59740018
CERMSGCD DS    H         MESSAGE CODE                                   59820018
CERMSGMD DS    2F        MODULE NAME FOR XCTL PARAMETER LIST            59900018
CERXCTL  DS    F         POINTER TO MODULE NAME FOR XCLL PARMLST        59980018
CERFLAG  EQU   CERXCTL   FLAG BYTE FROM CHKWA 'CKFLAG1' FOR COMMON      60060018
*                        ADDRESSING ON BOTH ERROR AND NORMAL ENTRY      60140018
CERJOBNM DS    2F        JOB NAME            FILLED WHEN ERROR BEFORE   60220018
CERCHKID EQU   CERJOBNM  OTHERWISE CONTAINS CHECKID                     60300018
CERDDNM  DS    2F        CHKPT D.S. DDNAME   CHR WAS WRITTEN            60380018
CERTIOAD DS    F         ADDR OF TIOT                                   60460018
CERDCBAD DS    F         ADDR OF CHKPT DCB                              60540018
CERMCLS  EQU   X'80'                                                    60700017
         IEEVCHWA                                                       60800017
         CNOP  2,4                                                      61000017
CERSTOW  DS    6H    STOW PARAMETER LIST                                61200017
CERCLOSE DS    F    CLOSE'S PARAMETER LIST                              61400017
CERAD    DS    F                                                        61600017
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               65400017
TIOTSECT DSECT                                                          65600017
         IEFTIOT1                                                       65800017
UCBSECT  DSECT                                                          66000017
         IEFUCBOB                                                       66200017
         IHBABCTL                                                       66400017
NOID     EQU   X'80'     SIGNIFIES LAST WORD IN PARM LIST.              66600017
CLOSEOPT EQU   128  OPTION BYTE FOR CLOSE'S PARM LIST.                  66800017
TAPE     EQU   X'80'     UCBTYP FIELD-INDICATES TAPE                    67000017
TAEXT    EQU   4    LENGTH DEB DEVICE DEPENDENT SECTION FOR TAPE.       67600017
DAEXT    EQU   16   LENGTH DEB DEVICE DEPENDENT SECTION FOR DIR. ACC.   67800017
DEVTL    EQU   4    LENGTH OF UCBTYP FIELD IN UCB.                      68000017
CKTTRL   EQU   3    LENGTH OF JCTCKTTR FIELD IN JCT.                    68200017
PCPSP    EQU   254                                                      68400017
GR       EQU   60   OFFSET TO REG 15 IN SVRB REG SAVE AREA.             68600017
GR15     EQU   62   RBEXSAVE FIELD-OFFSET LOW ORDER 1/2 WORD IN REG 15. 68800017
IOCC     EQU   X'7F' SUCCESSFUL I/O COMPLETION CODE                     69000017
DDL      EQU   8     LENGTH OF TIOEDDNM FIELD                           69200017
IDL      EQU   8    LENGTH OF CHECKID FOR BPAM                          69400017
CKL      EQU   15   LENGTH OF CHKID FIELD IN JCT MINUS ONE              69600017
CKMSG1   EQU   32    INDICATES WTO MSG-NOT TAKEN                        69800017
CKMSG2   EQU   64                                                       70000017
CKERPG17 EQU   X'0311'                                                  70200017
CKERIO5  EQU   X'031A'             I/O ERROR ON STOW,MSG CODE = 26      70400017
CKERIO6  EQU   X'02'                                                    70600017
CKDCBOP  EQU   X'10'                                                    70800017
CKSPBKSZ EQU   8                                                        71000017
*                                                                       71004018
*        DECIMAL CONSTANTS, POSITIONS, LENGTH-CODES                     71008018
*                                                                       71012018
ZERO     EQU   0              DECIMAL - 0                               71016018
ONE      EQU   1                      - 1                               71020018
TWO      EQU   2                      - 2                               71024018
FOUR     EQU   4                      - 4                               71028018
DEC56    EQU   56                     - 56                              71032018
SPACE    EQU   C' '           BLANK                                     71036018
*                                                                       71040018
LENGTH1  EQU   7                                                        71044018
*                                                                       71048018
CERCKID1 EQU   CERCHKID+1                                               71052018
CKRETCD1 EQU   CKRETCOD+1                                               71056018
CERSTOW8 EQU   CERSTOW+8                                                71060018
TIOTUCB  EQU   TIOESTTB            UCB POINTER IN TIOT                  71064018
JCTCKID1 EQU   JCTCKIDT+1                                               71068018
CERRETC1 EQU   CERRETCD+1                                               71072018
SYNAD1   EQU   DCBSYNAD+1                                               71080018
CKSYNAD1 EQU   CKSYNAD+1                                                71084018
TIOTADD  EQU   HKPTIOAD-1                                               71088018
DCBADD   EQU   HKPDCBAD-1                                               71092018
*                                                                       71096018
LCODES   EQU   4         LENGTH OF RETURN AND MESSAGE CODE              71100018
LFLAG    EQU   1                   FLAGS                                71104018
LJOBNM   EQU   8                   JOBNAME                              71108018
LDDNM    EQU   8                   DDNAME                               71112018
LCHKID   EQU   15                  CHECKID                              71116018
LJCTMB   EQU   8                   JCT MBBCCHHR ADDRESS                 71120018
LSYNAD   EQU   3                   SYNAD                                71124018
LBLKSIZ  EQU   2                   BLOCKSIZE                            71128018
LMODNAME EQU   8                   MODULE NAME                          71132018
LJCT     EQU   4                   JCT                                  71136018
PERSUB   EQU   4         CONSTANT USED INSHIFT INSTR(= MULTIPLY BY 16)  71140018
LTTR     EQU   4                   TTR                                  71144018
*                                                                       71148018
*        HEXADECIMAL CONSTANTS (MASKS)                                  71152018
*                                                                       71156018
HEXZERO  EQU   X'00'               HEXADECIMAL - 0                      71160018
HEXONE   EQU   X'01'                           - 1                      71164018
MAINUCB  EQU   X'FF'               UCB ID FOR MAIN UCB                  71168018
 END                                                                    71200017
