         TITLE 'IGC0105B (IHJARS00) RESTART HOUSEKEEPING RTN 1 SVC 52'  00500021
IGC0105B CSECT                                                          00700018
*ROUTINE NAME    IGC0105B     RESTART HOUSEKEEPING ROUTINE              00900021
*STATUS - CHANGE LEVEL 000                                              01200018
*                                                                A35696 01220020
*                                                                A36350 01240020
*        RELEASE 21 DELETIONS                                           01260020
*0000450000                                                     SA51163 01270021
*0000339000,546000-552000                                        S21940 01272421
*        RELEASE 21.7 DELETIONS                                         01274421
*0000                                                           SA62489 01276421
*0000                                                           SA62811 01278421
*        RELEASE 21.8 DELETIONS                                         01280021
*0000012800-014000,449715-450980,451180-451220,451380,451460    SA69185 01285021
*0000003000-005000,009000                                        S21940 01290021
*                                                                       01400021
*FUNCTION/OPERATION - 1.)  GET A WORK AREA OF THE SAME SIZE AND         01500018
*                        LOCATION AS THE CHKPT WORK AREA.               01800017
*                                                                       02100017
*                     2.)  INITIALIZE THE RESTART WORK AREA WITH        02400017
*                        INFORMATION PASSED FROM DSDR PROCESSING.       02700017
*                                                                       03000017
*                     3.)  FOR PCP, MOVE THE TIOT AND RESTART'S         03300017
*                        SVRB TO THE RESTART WORK AREA.                 03600017
*                                                                       03900017
*                     4.)  CONSTRUCT A DCB FOR THE CHKPT DATA SETS.     04200017
*                                                                       04500017
*                     5.)  OPEN THE CHKPT DATA SET.                     04800017
*                                                                       05100017
*ENTRY POINTS                                                           05400018
*    IGC0105B VIA XCTL FROM IGC0005B (MICROFICHE IEFVSMBR),             05500021
*    WHICH WAS ENTERED VIA SVC 52 FROM IEFRSTRT.                        05600021
*INPUT - ADDRESS OF THE FOLLOWING PARAMETER LIST WILL BE PASSED IN      05700018
*        REGISTER 1.                                                    06000018
*A(RSCIRTTR)             TTR OF FIRST CIR                               06300017
*CL8(RSDDNAME)           DDNAME OF CHKPT DATA SET TO BE USED BY RESTART 06600017
*A(RSPPM)               LOW ORDER ADDRESS OF PP CORE.                   06900017
*A(RSPPE)               HIGH ORDER ADDRESS OF PP CORE.                  07200017
*AL2(RSBLKSZE)           BLOCKSIZE OF RECORDS IN CHKPT DATA SET.        07500017
*AL2(RSTIOTLN)           LENGTH OF CHKPT TIOT.                          07800017
*AL1(RSFLAGS)            BITS 2-7 RESERVED                              08100017
*                        BIT  6      0-DA                               08400017
*                                    1-TAPE                             08700017
*                        BIT  7      0-BSAM                             09000017
*                                    1-BPAM                             09300017
*AL3(RSCHKWAL)           LENGTH OF CHKPT WORK AREA                      09600017
*AL3(RSCKSVRB)           FOR SSS, THIS WILL CONTAIN A POINTER TO THE    09900017
*                        CHKPT SVRB. FOR MVT, THIS FIELD WILL BE ZERO.  10200017
*A(RSCHKWAD)             ADDRESS OF CHKPT W.A.                          10500017
*OUTPUT - ADDRESS OF RESTART WORK AREA WILL BE IN REGISTER 1.           10800018
*EXTERNAL ROUTINES - NONE.                                              11100018
*SVCS USED - GETMAIN                                                    11400018
*            FREEMAIN                                                   11700017
*            XCTL                                                       12000017
*            OPEN                                                       12300017
*EXITS-NORMAL  XCTL TO IGC0205B WITH ADDR OF RSTRT W.A. IN        MFTCR 12600018
*             REGISTER 1.                                               12900017
*TABLES/WORK AREAS-  RSTWA IS THE FIRST PART OF THE RESTART WORK AREA.  13200018
*                  THIS ROUTINE FILLS IN RSTWA WITH INFORMATION THAT IS 13500017
*                  USED BY OTHER RESTART ROUTINES.                      13800017
*ATTRIBUTES - REENTRANT, SUPERVISOR STATE, TYPE 4 SVC ROUTINE.          14100018
*RESTRICTIONS ON USE OF ROUTINE - MAY NOT BE USED IN OS/MFT.            14400018
*NOTES - NONE.                                                          14700018
         EJECT                                                          14900021
         BALR  RB,ZERO             SET UP MODULE ADDRESSABILITY         15000018
         USING *,RB                                                     15300018
         USING TCBSECT,R4          ADDRESS TCB.                         15900017
         USING RSTSECT,R5          ADDRESS RESTART WORK AREA.           16200017
         SSM   RSTMASK             ALLOW INTERRUPTS.                    16500017
         L     R1,0(0,R1)          GET ADDR OF PARM FIELD.              16800017
         ST    R1,RSTPARM          SAVE ADDR OF PARM FIELD.             17100017
*                                                                     * 17170018
*********************************************************************** 17240018
*                                                                     * 17310018
*        THIS SECTION WILL GET CORE FOR THE RESTART WORK AREA. IT     * 17400017
*     WILL USE THE SAME AREA OF CORE FOR A WORK AREA AS CHKPT DID.    * 17700017
*     SINCE ONE CANNOT ISSUE A GETMAIN FOR A PARTICULAR AREA OF CORE, * 18000017
*     THIS ROUTINE WILL ISSUE A GETMAIN FOR ALL OF CORE AND THEN USE  * 18300017
*                                                                     * 18370018
*********************************************************************** 18440018
*                                                                     * 18510018
*     ONLY THE SAME AREA THAT CHKPT USED FOR A WORK AREA.             * 18600017
         USING PARMSECT,R1         ADDRESS PARM FIELD.                  18900017
         TM    RSFLAGS,RSMVT       IS THIS AN MVT SYSTEM                19200017
         BO    RSTMVT1             YES-GO TO FREE SUBPOOL 251.          19500017
RSTRTN   EQU   *                                                        19600017
         MVC   RSTGMLLW(RSTMASK-RSGMLL),RSGMLL                          19700018
*                                  MOVE GETMAIN PARLST IN SVRB WA       19800018
         LA    R1,RSTGMLLW         SET UP GETMAIN PARM LIST IN SVRB WA. 20100017
         ST    R1,RSTGMLIS                                              20400017
         LA    R1,RSPSD                                                 20700017
         ST    R1,RSTGMLS4                                              21000018
         MVC   RSTGMLS8(LMODESUB),MODESUB    MOVE MODE BYTE AND SUBPOOL 21300018
*                                            NUMBER TO PARAMETER LIST.  21600018
RSTRET1  EQU   *                                                        21900017
         GETMAIN MF=(E,RSTGMLIS)   ISSUE CONDITIONAL GETMAIN.           22200017
         B     *+4(RF)             BRANCH ON RETURN CODE                22400018
*                                                                     * 22600018
         B     RSTRET1             SUCCESSFUL GETMAIN-CONTINUE ISSUING  22670018
*                                  GETMAIN FOR REST OF P/P CORE         22740018
*                                                                     * 22810018
*        UNSUCCESSFUL GETMAIN - ALL P/P CORE GOTTEN - CONTINUE        * 22880018
*        PROCESSING                                                     22950018
*                                                                     * 23020018
RSTCONT  EQU   *                                                        23100017
*                                                                     * 23170018
*********************************************************************** 23240018
*                                                                     * 23310018
*        THIS SECTION WILL INITIALIZE THE RESTART WORK AREA WITH      * 23400017
*     INFORMATION THAT WILL BE USED BY SUBSEQUENT LOADS OF RESTART.   * 23700017
*                                                                     * 23770018
*********************************************************************** 23840018
*                                                                     * 23910018
         L     R3,RSTPARM          GET ADDR OF PARM LIST.               24000017
         USING PARMSECT,R3         ADDRESS PARM LIST.                   24300017
         MVC   RSTAD(RSCKSVRB-RSCHKWAD),RSCHKWAD                        24500018
*                                  CHKPT WA ADDR TO FULL WD BND.        24700018
         L     RC,RSTAD                                                 24900017
         LA    RC,ZERO(RC)                CLEAR HIGH ORDER BYTE         25000018
         USING RSTWA,RC            ADDRESS RESTART W.A.                 25200017
         LA    RD,RSREGSAV         INITIALIZE SAVE AREA REGISTER.       25500017
         XC    RSTWA(RSL),(RSTWA)  ZERO OUT WORK AREA.                  25800017
*        INITIALIZE W.A. WITH INFORMATION PASSED IN PARM FIELD          26000018
         MVC   RSPPM(RSPPML-RSPPM),RSTPPM                               26200018
         MVC   RSPPML(RSTIOTO-RSPPML),RSCKPPML                          26400018
         MVC   RSBUFL2(RSDCBFLG-RSBUFL2),RSBLKSZE                       26600018
         MVC   RSTIOTO2(RSTIOTAD-RSTIOTO2),RSTIOTLN                     26800018
         MVC   RSWACL1(RSBUFL-RSWACL1),RSCHKWAL                         27000018
         MVC   RSSVRB(RSBDCB-RSSVRB),RSCKSVRB                           27200018
         MVC   RSFLAG1(LFLAGS),RSFLAGS    MOVE FLAGS TO W.A.            27400018
         MVC   RSTIOTL2(LTIOT),RSTIOTLN   FOR MVT-MOVE IN LENGTH OF     27600018
*                                         TIOT SA.                      27800018
         ST    R4,RSTCBAD          SAVE TCB ADDR IN W.A.                28200017
         TM    RSTAD,RSSPBKSZ      DID CHECKPOINT SUPPLY BLOCKSIZE      28240017
         BZ    RSTTSMVT            BRANCH IF NO                         28280017
         OI    RSFLAG2,RSSPBKSZ    SET FLAG TO HAVE RESTART EXIT        28320017
*                                  ROUTINE RESET BLOCKSIZE FIELD IN     28360017
*                                  USER'S DCB TO ZERO                   28400017
RSTTSMVT EQU   *                                                        28440017
         TM    RSFLAG1,RSMVT  IS THIS AN MVT SYSTEM                     28500017
         BO    RSTMVT2             YES-GO TO FIND OFFSET TO COMMON W.A. 28800017
RSTPCP1  EQU   *                                                        29100017
*                                                                     * 29170018
*********************************************************************** 29240018
*                                                                     * 29310018
*        FOR PCP, THIS SECTION WILL MOVE THE TIOT AND RESTART'S SVRB  * 29400017
*     TO THE RESTART WORK AREA AND UPDATE POINTERS TO THEM.           * 29700017
*                                                                     * 29770018
*********************************************************************** 29840018
*                                                                     * 29910018
         L     R9,TCBTIO           GET ADDR OF TIOT.                    30000017
         USING TIOT1,R9            ADDRESS TIOT.                        30300017
         LA    RA,TIOELNGH         GET ADDR OF FIRST DD ENTRY IN TIOT.  30600017
         LA    R7,TIOLEN           INITIALIZE TIOT-LENGTH ACCUMLATOR.   30900017
         XR    R6,R6                                                    31200017
RSTETI   EQU   *                                                        31500017
         USING TIOELNGH,RA         ADDRESS DD ENTRY                     31800017
         NC   TIOELNGH(TIOEDDNM-TIOELNGH),TIOELNGH                      32000018
*                                  IS THIS THE END OF THE TIOT          32200018
         BNZ   RSTTIL                       NO                          32400018
         ST    R7,RSTIOTL          SAVE LENGTH OF TIOT.                 32700017
         LA    R8,RSTIOT                                                33000017
         LR    RF,R8               SAVE ADDR OF TIOT-MOVE-IN AREA.      33300017
RSTRET3  EQU   *                                                        33600017
         CH    R7,RSTK256          ARE THERE MORE THAN 256       S21940 33900021
*                                  BYTES LEFT TO MOVE-           S21940 33960021
         BH    RSTMOV2             YES-GO TO MOVE 256 BYTES TO W.A.     34200017
RSTGONC  EQU   *                                                        34500017
         BCTR  R7,ZERO                DECREMENT NO-OF-BYTES-LEFT  COUNT 34800018
         EX    R7,RSTMVC1          MOVE REMAINING BYTES TO W.A.         35100017
         ST    RF,TCBTIO           UPDATE TIOT POINTER IN TCB.          35400017
         LA    R9,EIGHT(R8,R7)     COMPUTE ADDR OF SVRB READ IN  A35696 35500020
*                                       AREA -                   A35696 35600020
         SRL   R9,3                  FORCE DW BOUND --           A35696 35700020
         SLL   R9,3                  DIVIDE BY 8 THEN MULT BY 8  A35696 35800020
         MVC   ZERO(SVRBL,R9),RSTSVRB   MOVE SVRB INTO WORK AREA        36000018
         ST    R9,TCBRBP           UPDATE TCB POINTER TO SVRB.          36300017
         SR    R9,RC               COMPUTE OFFSET TO REPDCB'S W.A.      36600017
         ST    R9,RSWAOFST         SAVE OFFSET IN W.A.                  36900017
         LA    R8,SVRBL(R9)        COMPUTE OFFSET TO PRB MOVE-IN  MFTCR 37000018
*                                  AREA                           MFTCR 37100018
         LA    R2,PRBL(R8)         COMPUTE OFFSET TO REPMAIN'S WA MFTCR 37200018
         ST    R2,RSMWOFST         SAVE OFFSET IN W.A.                  37500017
         AR    R2,RC               GET ADDRESS OF W.A.                  37800017
         USING RSECT,R2            ADDRESS IGC0105BS W.A.         MFTCR 38100018
RSTRET2  EQU   *                                                        38400017
         MVC   RSCIRTTR(RSSVRBN-RSCIRTTR),RSCIRAD                       38500018
*                                  SAVE TTR OF CIR                      38600018
*                                                                     * 38700018
*********************************************************************** 38800018
*                                                                     * 38900018
*        CONSTRUCT A BSAM DCB. THIS DCB WILL BE USED BY REPMAIN TO    * 39000017
*     READ THE CHKPT DATA SET.                                        * 39300017
*                                                                     * 39320018
*********************************************************************** 39340018
*********************************************************************** 39360018
         MVC   RHRCHKID(RHRXLST-RHRCHKID),RSTCHKID                      39440018
*                                  SAVE CHECKID FOR NEXT MODULE         39520018
         LA    R6,RSBDCB           GET ADDR OF DCB MOVE-IN AREA.        39600017
         USING IHADCB,R6           ADDRESS AREA WHERE DCB WILL BE BUILT 39900017
         MVC   IHADCB21(LDCB),RSTDCBD        MOVE PRE-BUILT DCB TO W.A. 40200018
         MVC   DCBDDNAM(DDL),RSDDNAME INSERT DDNAME IN DCB.             40500017
         MVC   DCBBLKSI(LBLKSZE),RSBUFL2     MOVE BLOCKSIZE INTO DCB.   40700018
         TM    RSFLAG1,RSTRKOV      CHKPT D.S. SPECIFY TRACK OVERFLOW   40900017
         BZ    RSTRESM              NO-SKIP CODE TO SET DCBRECFM FIELD  41000017
         OI    DCBRECFM,TRKOV       SET TRACK OVERFLOW BIT IN CHKPT DCB 41100017
RSTRESM  EQU   *                                                        41400017
         TM    RSFLAG1,RSTAPE      CHKPT D.S. ON TAPE?          SA62811 41450021
         BZ    RSTCKDA             NO-SKIP CODE TO MODIFY MACRF SA62811 41500021
         NI    DCBMACR1,X'FF'-DCBMRPT1                          SA62811 41550021
*                                  TURN OFF POINT BIT FOR TAPE  SA62811 41600021
RSTCKDA  EQU   *                                                SA62811 41650021
         ST    R6,RSDCBAD1    INITIALIZE DECBS WITH ADDR OF DCB.        41700017
         ST    R6,RSDCBAD2                                              42000017
*                                                                 MFTCR 42030018
******************************************************************MFTCR 42060018
*        SAVE IEFRSTRT'S PRB IN RESTART WORKAREA AND UPDATE POINTERS    42090018
*        TO IT SO THAT IT WILL NOT BE OVERLAYED WHEN RESTART FREEMAINS  42120018
*        ALL OF P/P CORE                                                42150018
******************************************************************MFTCR 42180018
*                                                                 MFTCR 42210018
         TM    RSFLAG1,RSMVT       MVT SYSTEM                     MFTCR 42240018
         BO    RSTSKP              YES-SKIP CODE TO MOVE PRB      MFTCR 42270018
         L     R9,TCBRBP           GET RB ADDR                    MFTCR 42300018
         USING RBSECT,R9                                          MFTCR 42330018
         L     RA,RBLINK-1         GET ADDR OF PRB(IEFRSTRT)      MFTCR 42360018
         AR    R8,RC               COMPUTE PRB ADDR IN WA         MFTCR 42390018
         ST    R8,RSTOPEN          SAVE NEW ADDR OF PRB           MFTCR 42420018
         MVC   0(32,R8),0(RA)      SAVE PRB IN WA SO C695 315  5  4OC3  42450018
*                                  FREED FOR OPENING CHKPT DS     MFTCR 42480018
         MVC   RBLINK(3),RSTOPEN+1   UPDATE LINK POINTER IN       MFTCR 42510018
*                                  RESTART SVRB TO POINT TO MOVED MFTCR 42540018
*                                  PRB                            MFTCR 42570018
RSTSKP   EQU   *                                                  MFTCR 42600018
         L     R1,RSPPM            GET LOW BOUNDARY OF PP CORE          42700017
         LTR   R1,R1               DOES H0 EXIST                  MFTCR 42704018
         BNZ   RSTADD4K            BRANCH IF YES                  MFTCR 42708018
         L     R1,RSPPML           LOAD LOW ADDRESS OF H1 CORE    MFTCR 42712018
RSTADD4K EQU   *                                                        42716018
*                                                                     * 42720018
*********************************************************************** 42740018
*                                                                     * 42760017
*        THIS SECTION WILL FREE ENOUGH CORE FOR OPEN TO OPERATE IN.   * 42820017
*     IT FIRST DETERMINES IF THERE ARE 4K BYTES THAT MAY BE FREED     * 42880017
*     BELOW THE WORK AREA. IF THERE ARE THE LOWEST 4K BYTES IN PP CORE* 42940017
*     ARE FREED. OTHERWISE THE 4K BYTES IMMEDIATLY ABOVE THE WORK AREA* 43000017
*     ARE FREED.                                                        43060017
*        IEFDSDRP HAS PASSED THE VOLUME SEQUENCE NUMBER OF THE CURRENT* 43070021
*     CHECKPOINT IN THE SVRB ADDRESS FROM THE CHR RECORD BUILT BY     * 43080021
*     CHECKPOINT.  SINCE IEFDSDRP HAS ALREADY DONE ITS OWN OPEN OF THE* 43090021
*     CHECKPOINT DATA SET, ON AN IMMEDIATE RESTART IT USES THE VOL SEQ* 43100021
*     PASSED IN JCTVOLSQ, AND ON DEFERRED RESTART REQUIRES CORRECT JCL* 43110021
*                                                                     * 43120017
*********************************************************************** 43140018
*                                                                     * 43160018
         AH    R1,C4096            TEST TO SEE IF THERE                 43180017
         CR    R1,RC               ARE 4K BYTES BELOW THE WORK AREA     43240017
         BH    RSTHIGH             NO-GO TO GET ADDRESS ABOVE W.A.      43300018
         SH    R1,C4096                                                 43360017
RSTFRE   EQU   *                                                        43500017
         FREEMAIN R,LV=4096,SP=250,A=(1)                                43900017
*                                                                       44000021
         ST    R6,RSTOPEN          SET UP OPEN'S PARAMETER LIST.        44400017
         MVI   RSTOPEN,INPUTOPN    MOVE OPTION BYTE TO W.A.             44700017
* SET UP RDJFCB PARAMETERS                                              44750021
         LA    R1,RSTRDJ           ADDR OF EXIT LIST            SA51163 44800021
         ST    R1,DCBEXLST         PLACE IN DCB                 SA51163 44850021
         LA    R1,INFMJFCB         ADDR OF JFCB AREA            SA51163 44900021
         ST    R1,RSTRDJ           PLACE IN EXIT LIST ENTRY     SA51163 44950021
         MVI   RSTRDJ,OPENJOPT     SET RDJFCB AND END-OF-LIST   SA51163 44960021
         RDJFCB MF=(E,RSTOPEN)     READ THE JFCB                SA51163 44970021
*                                                               SA51163 44971521
         SR    R1,R1               CLEAR WORK REGISTER          SA51163 45102021
         IC    R1,RSSVRB           LOAD DEBTVLSQ, WHICH WAS     SA51163 45106021
*                                  SAVED AT CHKPT TIME IN THE   SA51163 45110021
*                                  FIRST BYTE OF THE SVRB ADDR  SA51163 45114021
         STH   R1,JFCBVLSQ         STORE IT IN JFCBVLSQ         SA69185 45122021
*                                                               SA51163 45126021
* OPEN THE CHECKPOINT DATA SET USING THE JUST-MODIFIED JFCB.    SA51163 45130021
* NOTE THAT THE MODIFIED JFCB IS NOT WRITTEN BACK TO THE        SA51163 45134021
* JOB QUEUE BY 'OPEN', THUS NOT LOCKING FUTURE CHKPT OPENS      SA69185 45138021
* TO THIS VOLUME.                                               SA69185 45140021
*                                                               SA51163 45142021
         MVI   RSSVRB,X'00'        ZERO VOL SEQ NO. IN SVRB PTR SA62489 45148021
         OI    JFCBTSDM,JFCNWRIT   IND 'DON'T REWRITE JFCB'     SA51163 45150021
*                                                                       45152021
         OPEN  TYPE=J,MF=(E,RSTOPEN)  OPEN CHKPT DATA SET       SA51163 45154021
*                                                               SA51163 45158021
         LR    R1,RC               LOAD PARM REG WITH ADDR OF CHKPT WA. 45300017
         MVC   RHRXLST(LMODNAME),RHRXLIST    MOVE NAME OF NEXT MODULE   45600018
         LA    RF,RHRXLST                    TO XCTL'S PARM LIST IN WA. 45900018
         ST    RF,RHRXPTR                                               46200017
         LA    RF,RHRXPTR                                               46500017
         XCTL  SF=(E,(15))         TRANSFER CONTROL TO 2ND LOAD OF      46800017
*                                  THE RESTART HOUSEKEEPING ROUTINE.    47100017
RSTHIGH  EQU   *                                                        47400017
         LR    R1,RC               COMPUTE ADDR OF FIRST BYTE ABOVE WA. 47700017
         A     R1,RSWACL                                                48000017
         B     RSTFRE              GO TO FREEMAIN FOR 4K BYTES FOR OPEN 48060018
*                                                                     * 48120018
*********************************************************************** 48180018
*                                                                     * 48240018
*        FOR MVT, ISSUE FREEPOOL FOR SUBPOOL 252 TO FREE CORE OF      * 48300018
*        IEFRSTRT(STEP THAT ISSUED SVC 52)                            * 48360018
*                                                                     * 48420018
*********************************************************************** 48480018
*                                                                     * 48540018
RSTMVT1  EQU   *                                                        48600017
         FREEMAIN R,SP=252                                              48900017
         FREEMAIN R,SP=251              FREE JOB PACK AREA       A36350 49000020
*                                       A3635                    A36350 49100020
         B     RSTRTN              GO TO GETMAIN FOR P/P REGION         49300018
         USING TIOELNGH,RA                                              49800017
RSTTIL   EQU   *                                                        50100017
         IC    R6,TIOELNGH         GET LENGTH OF DD ENTRY               50400017
         AR    R7,R6               UPDATE TIOT-LENGTH ACCUMULATOR.      50700017
         AR    RA,R6               UPDATE DD ENTRY POINTER.             51000017
         B     RSTETI              GO TO EXAMINE NEXT DD ENTRY.         51300017
*                                                                     * 51330018
*********************************************************************** 51360018
*                                                                     * 51390018
*        FOR MVT, COMPUTE OFFSETS WITHIN W.A. BY INCREMENTING BY      * 51420018
*        LENGTH OF TIOT DURING CHKPT(CHKPT TIOT WILL BE MOVED TO W.A. * 51450018
*        DURING REPMAIN WHEN IT READS IN THE SURS).                   * 51480018
*                                                                     * 51510018
*                                                                     * 51540018
RSTMVT2  EQU   *                                                        51600017
         LA    R2,RSTIOT           GET ADDR OF NEXT AVAILABLE BYTE      51900017
         A     R2,RSTIOTO          IN THE W.A. (FOR MVT)                52200017
         SR    R2,RC               COMPUTE OFFSET TO REPDCB'S AND       52500017
         ST    R2,RSWAOFST         REPMAIN'S W.A.                       52800017
         ST    R2,RSMWOFST         SAVE OFFSET IN W.A.                  53100017
         AR    R2,RC               GET ADDRESS OF W.A.                  53400017
         B     RSTRET2             GO TO BUILD RESTART DCB              53500018
*        SUBROUTINE USED IN PCP TO MOVE 256 BYTES BLOCK OF TIOT AT    * 53600018
*        RESTART(LOCATED IN P/P CORE) TO RSTWA                        * 53700018
*                                                                     * 53800018
*                                                                     * 53900018
RSTMOV2  EQU   *                                                        54000017
         MVC   ZERO(DEC256,R8),ZERO(R9)                                 54300018
         AH    R8,RSTK256          POINT TO NEXT AVAILABLE       S21940 54600021
*                                  BUFFER LOCATION               S21940 54660021
         SH    R7,RSTK256          DECREMENT REMAINING LENGTH    S21940 54900021
         AH    R9,RSTK256          POINT TO NEXT SEGMENT TO      S21940 55200021
*                                  BE MOVED                      S21940 55260021
         B     RSTRET3                                                  55500017
RSTMVC1  MVC   ZERO(ONE,R8),ZERO(R9)                                    55800018
RHRXLIST DC    C'IGC0205B'         NEXT LOAD OF HSEKEEPING        MFTCR 56100018
MODESUB  DC    X'E0FA'   INDICATES VC MODE, SP=250 TO GETMAIN           56400017
RSGMLL   DC    A(8)                VARIABLE GETMAIN PARMLST FOR AS MUCH 56700018
RSGMLH   DC    X'00FFFFF8'         CORE AS IS AVAILABLE                 57000018
RSTMASK  DC    X'FF'                                                    57300017
C4096    DC    H'4096'                                                  57400017
RSTK256  DC    H'256'              MAX LNG FOR 'MVC' INSTRUCTION S21940 57412021
         DS    0F                  PUTS DCB ON FULL WORD BOUNDARY       57460017
         DS    C                   ALIGNS ADDRESS TO FULL WORD BOUNDARY 57520017
RSTDCBD  EQU   *                                                        57600017
         DC    AL3(0)    BUFCB                                          57900017
         DC    AL2(0)  BUFL                                             58200017
         DC    BL2'0100000000000000'  DSORG  (BSAM)                     58500017
         DC    A(1)    IOBAD                                            58800017
         DC    AL1(0)  BFTEK,BFALN                                      59100017
         DC    AL3(1)  EODAD                                            59400017
         DC    BL1'11000000'                                            59700017
         DC    AL3(0)  EXLST                                            60000017
*                       FOUNDATION BLOCK                                60300017
         DC    CL8'        '   DDNAME                                   60600017
         DC    BL1'00000010'  OFLGS                                     60900017
         DC    BL1'00000000'  IFLG                                      61200017
         DC    BL2'0010010000000000'  MACR                              61500017
*                       BSAM-BPAM-QSAM INTERFACE                        61800017
         DC    BL1'00000000'                                            62100017
         DC    AL3(1)  CHECK, GERR, PERR                                62400017
         DC    A(1)    SYNAD                                            62700017
         DC    H'0'    CIND1, CIND2                                     63000017
         DC    AL2(0) BLKSIZE                                           63300017
         DC    F'0'   WCPO, WCPL, OFFSR, OFFSW                          63600017
         DC    A(1)   IOBA                                              63900017
         DC    AL1(1)    NCP                                            64200017
         DC    AL3(1) EOBR, EOBAD                                       64500017
*                       BSAM-BPAM INTERFACE                             64800017
         DC    A(1)   EOBW                                              65100017
         DC    H'0'   DIRCT                                             65400017
         DC    AL2(0) LRECL                                             65700017
         DC    A(1)   CNTRL, NOTE, POINT                                66000017
*                                                                S21940 66004021
*********************************************************************** 66008021
*        PATCH AREA DEFINITION                                        * 66012021
*********************************************************************** 66016021
*                                                                S21940 66020021
LNG105B  EQU   *-IGC0105B          LENGTH BEFORE PATCH AREA      S21940 66024021
*                                                                S21940 66028021
PATCHLNG EQU   1024-LNG105B        LENGTH OF PATCH AREA          S21940 66032021
*                                                                S21940 66036021
         DC    (PATCHLNG)X'00'     ZEROED PATCH AREA             S21940 66040021
*                                                                S21940 66044021
         EJECT                                                   S21940 66048021
RSECT    DSECT                     IGC0005B'S WORK AREA.                66300017
RHRCHKID DS    4F   CHECKID                                             66400017
RHRXLST  DS    2F   NAME OF MODULE TO RECEIVE CONTROL.                  66600017
RHRXPTR  DS    F    POINTER XCTL PARM LIST.                             66900017
RSTOPEN  DS    F    OPEN PARAMETER LIST.                                67200017
RSTRDJ   DS    A(INFMJFCB)         OPENJ AND RDJFCB EXLST       SA51163 67202021
         IEFJFCBN                  MAP JFCB                     SA51163 67210021
PARMSECT DSECT                                                          67500017
RSLNGTH  DS    CL2       LENGTH OF PARM FIELD                           67800017
RSCIRAD  DS    CL4       TTR OF FIRST CIR                               68100017
RSTCHKID DS    CL16        CHECKID                                      68200017
RSDDNAME DS    CL8       DDNAME OF CHKPT DATA SET TO BE USED BY RESTART 68400017
RSTPPM   DS    CL4       LOW ORDER ADDRESS OF PP CORE.                  68700017
RSTPPE   DS    CL4       HIGH ORDER ADDRESS OF PP CORE.                 69000017
RSBLKSZE DS    CL2       BLOCKSIZE OF RECORDS IN CHKPT DATA SET.        69300017
RSTIOTLN DS    CL2       LENGTH OF CHKPT TIOT                           69600017
RSFLAGS  DS    CL1       RESTART FLAGS                                  69900017
RSCHKWAL DS    CL3       LENGTH OF CHKPT WORK AREA                      70200017
RSCHKWAD DS    CL4       ADDRESS OF CHKPT W.A.                          70500017
RSCKSVRB DS    CL4       FOR PCP, ADDRESS OF CHKPT SVRB.                70800017
RSCKPPML DS    CL4       LOW ORDER ADDR OF LCS CORE                     70870017
RSCKPPEL DS    CL4       HIGH ORDER ADDR OF LCS CORE                    70940017
RSSYNAD  DS    CL4       SYNAD ADDR,SAVED FROM CHKPT DCB                71010017
*                                                                     * 71030018
*        MAPPING OF RESTART SVRB AND EXTENDED SAVE AREA USED BY MODULE* 71050018
*                                                                     * 71070018
RSTSECT  DSECT                                                          71100017
RSTSVRB  DS    24F                                                      71400017
RSPSD    DS    2F   GETMAIN RETURNS ADDR AND LNGTH HERE, BUT            71700017
*                   FIELD IS NEVER REFERENCED                           72000017
RSTPARM  DS    F    ADDR OF PARM FIELD.                                 72300017
RSTFLAG1 DS    F    FLAGS FIELD.                                        72600017
RSTAD    DS    F    WORK AREA USED TO STORE ADDRESSES                   72900018
RCOUNT   DS    F                                                        73200017
RSTSAVE  DS    F    SAVE AREA FOR CIR TTR AND CHKPT DATA SET DDNAME.    73500017
*                                                                     * 73600018
*        GETMAIN PARAMETER LIST                                       * 73700018
*                                                                     * 73800018
RSTGMLIS DS    1F   POINTER TO GETMAIN LIST                             73900018
RSTGMLS4 DS    1F   POINTER TO GETMAIN RETURN ADDRESS                   74000018
RSTGMLS8 DS    H    MODE BYTE AND SUBPOOL NUMBER                        74200018
RSTGMLLW DS    2F    GETMAIN LIST                                       74400018
         IHBABCTL                                                       74700017
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               75000017
         IEFTIOT1                                                       75300017
         IEEVRSWA                                                       75600017
PRBL     EQU   32        LENGTH OF IEFRSTRT'S PRB                       75900018
INPUTOPN EQU   128  OPTION BYTE FOR OPEN PARM LIST.                     76200017
OPENJOPT EQU   X'87'          EXLST OPENJ AND LAST ENTRY        SA51163 76250021
RST256   EQU   256                                                      76500017
DDL      EQU   8    LENGTH OF DDNAME FIELD IN DCB.                      76800017
LENL     EQU   32             OFFSET DEBLNGTH FROM BEG OF APPEND. TABLE 77100017
DCBDECBL EQU   128  LENGTH OF RESTART'S DCB AND TWO DECB.               77400017
DIOBL    EQU   80   LENGTH OF DA IOB.                                   77700017
DICBL    EQU   112  LENGTH OF DA ICB.                                   78000017
TICBL    EQU   48   LENGTH OF TAPE ICB                                  78300017
TIOBL    EQU   48   LENGTH OF TAPE IOB                                  78600017
RSDIRACC EQU   2    INDICATES DIRECT ACCESS DEVICE                      78900017
KCVTMVT  EQU   X'10'                                                    79200017
TIOLEN   EQU   28                                                       79500017
RSL      EQU   256  LENGTH OF RSTWA TO BE ZEROED OUT.                   79800017
SVRBL    EQU   144  LENGTH OF RESTART SVRB                              80100017
DSORGBPM EQU   B'01000010'    MASK TO CHANGE BSAM DSORG FIELD TO BPAM.  80400017
DCBL     EQU   88   LENGTH OF BSAM/BPAM DCB.                            80700017
RSTWAL   EQU   RSTIOT-RSTWA   LENGTH OF RESTART W.A.                    81000017
RSTRKOV  EQU   64   INDICATES CHKPT DCB SPECIFIED TRACK OVERFLOW        81100017
TRKOV    EQU   32   TRACK OVERFLOW IN DCBRECFM                          81200017
RSSPBKSZ EQU   X'08'                                                    81250017
R0       EQU   0                                                        81300017
R1       EQU   1                                                        81600017
R2       EQU   2                                                        81900017
R3       EQU   3                                                        82200017
R4       EQU   4                                                        82500017
R5       EQU   5                                                        82800017
R6       EQU   6                                                        83100017
R7       EQU   7                                                        83400017
R8       EQU   8                                                        83700017
R9       EQU   9                                                        84000017
RA       EQU   10                                                       84300017
RB       EQU   11                                                       84600017
RC       EQU   12                                                       84900017
RD       EQU   13                                                       85200017
RE       EQU   14                                                       85500017
RF       EQU   15                                                       85800017
*                                                                       85810018
*       DEFINITION OF CONSTANTS, POSITIONS WITHIN OTHER AREAS,          85820018
*                     AND LENGTHATTRIBUTES                              85830018
ZERO     EQU   0         DECIMAL - 0                                    85840018
ONE      EQU   1         DECIMAL - 1                                    85850018
EIGHT    EQU   8                   DECIMAL - 8                   A35696 85855020
DEC256   EQU   256       DECIMAL - 256                                  85860018
*                                                                       85870018
RSBUFL2  EQU   RSBUFL+2            BUFFER+2                             85880018
RSTIOTO2 EQU   RSTIOTO+2           TIOTO                                85890018
RSWACL1  EQU   RSWACL+1            WORKAREA+1                           85900018
RSTIOTL2 EQU   RSTIOTL+2           TIOTL                                85910018
IHADCB21 EQU   IHADCB+21           WORKAREA                             85920018
*                                                                       85930018
LMODESUB EQU   2                   MODE BYTE AND SUBPOOL                85940018
LBLKSZE  EQU   2                   BLOCK SIZE                           85950018
LTIOT    EQU   2                   TIOT                                 85960018
LFLAGS   EQU   1                   FLAGS                                85970018
LDCB     EQU   67                  DCB                                  85980018
LMODNAME EQU   8                   MODULE NAME                          85990018
     END                                                                86100017
