         TITLE 'IHLMCIHF -- MONITOR CALL INTERRUPT HANDLER  (MFT)'      00200021
*********************************************************************** 00400021
*                                                                     * 00600021
* ROUTINE NAME --                                                     * 00800021
*    IHLMCIHF -- MONITOR CALL INTERRUPT HANDLER (MFT)                 * 01000021
*                                                                     * 01200021
* STATUS --                                                           * 01400021
*    CHANGE LEVEL = 0                                                 * 01600021
*                                                                     * 01800021
* FUNCTION --                                                         * 02000021
*    THIS MODULE RECEIVES CONTROL FROM PFLIH ON ALL PROGRAM           * 02200021
*    INTERRUPTS AND ON ALL BRANCH TYPE HOOKS.                         * 02400021
*                                                                     * 02600021
*    FOR PROGRAM INTERRUPTS, IT FIRST DETERMINES IF THIS INTERRUPT    * 02800021
*    HAS OCCURRED DURING THE PROCESSING OF A HOOK BY EXAMINING THE    * 03000021
*    MONITOR IN CONTROL FLAG (CVTSTATE).  IF ON, THE MODULE SEARCHES  * 03200021
*    THE HCT QUEUE TO FIND THE HCT THAT WAS IN CONTROL WHEN THE       * 03400021
*    INTERRUPT OCCURRED.  THE ERROR RECOVERY MONITOR ASSOCIATED WITH  * 03600021
*    THAT HCT IS CALLED (LOCATED BY HCTRCOV FIELD).  THE ERROR        * 03800021
*    RECOVERY MONITOR WILL EVENTUALLY RETURN TO THE HOOK PROCESSING   * 04000021
*    THAT WAS INTERRUPTED.                                            * 04200021
*                                                                     * 04400021
*    IF THE MONITOR WAS NOT IN CONTROL, THIS ROUTINE DETERMINES WHAT  * 04600021
*    TYPE OF PROGRAM INTERRUPT HAS OCCURRED.  THERE ARE FOUR          * 04800021
*    POSSIBILITIES: REAL MC, EX-NOP, MC-NOP, AND OTHER PROGRAM        * 05000021
*    INTERRUPT.  THEY ARE IDENTIFIED BY THE FOLLOWING                 * 05200021
*    CHARACTERISTICS:                                                 * 05400021
*         REAL MC -- INTERRUPT CODE IN PIOPSW IS X'4000'.             * 05600021
*         EX-NOP -- INSTRUCTION LENGTH CODE IS 4 BYTES.               * 05800021
*              INTERRUPT CODE IS ILLEGAL OP CODE (X'0001').           * 06000021
*              INTERRUPTED INSTRUCTION IS EX OP CODE (X'44') WITH     * 06200021
*                  R1, X2, AND B2 FIELDS ZERO.                        * 06400021
*              TARGET OF EXECUTE IS MC OP CODE (X'AF').               * 06600021
*              EXECUTE IS FOLLOWED BY NOP (X'470XXXXX').              * 06800021
*         MC-NOP -- INSTRUCTION LENGTH CODE IS 4 BYTES.               * 07000021
*              INTERRUPT CODE IS ILLEGAL OP CODE (X'0001').           * 07200021
*              INTERRUPTED INSTRUCTION IS MC OP CODE (X'AF').         * 07400021
*              INTERRUPTED INSTRUCTION IS FOLLOWED                    * 07600021
*                  BY NOP (X'470XXXXX').                              * 07800021
*              THE LOW ORDER THREE BYTES OF THE MC INSTRUCTION ARE    * 08000021
*                  EQUAL TO THE LOW ORDER THREE BYTES OF THE NOP.     * 08200021
*         OTHER PROGRAM INTERRUPT -- NOT ONE OF THE ABOVE.            * 08400021
*                                                                     * 08600021
*    IF AN MC-NOP CONDITION IS DETECTED, THE CLASS DIGIT IS OBTAINED  * 08800021
*    FROM THE MC INSTRUCTION, MULTIPLIED BY 2, AND ADDED TO THE       * 09000021
*    SIMULATED CLASS MASK ADDRESS (CMTCMSK).  THIS IS THE ADDRESS     * 09200021
*    OF THE SIMULATED CLASS FOR THIS HOOK.  THIS VALUE IS THEN        * 09400021
*    STORED IN THE SECOND HALF OF THE MC INSTRUCTION AND THE FIRST    * 09600021
*    HALF IS CHANGED TO AN EXECUTE (X'4400').  IF THE ADDRESSED       * 09800021
*    CLASS WAS NOT ON IN THE CMT (I.E. IT CONTAINED A NOPR (X'0700'), * 10000021
*    EXIT IS TAKEN  FROM THIS ROUTINE (SEE BELOW).                    * 10200021
*                                                                     * 10400021
*    IF EITHER A REAL MC, AN EX-NOP OR AN MC-NOP WITH THE CLASS ON,   * 10600021
*    THE HCT QUEUE IS SEARCHED.  FOR EACH ACTIVE HCT (HIGH ORDER BIT  * 10800021
*    OF CHAIN FIELD THAT CONTAINS ITS ADDRESS IS ZERO), THE           * 11000021
*    CORRESPONDING ROUTER IS CALLED.  THIS IS LOCATED BY THE HCTROUT  * 11200021
*    FIELD OF THE HCT.                                                * 11400021
*                                                                     * 11600021
*    AFTER ALL ACTIVE HCT'S HAVE BEEN SEARCHED AND CALLED, RETURN     * 11800021
*    PROCESSING IS DONE.  IF THE CALLER IS NOT TOTALLY ENABLED,       * 12000021
*    RETURN IS MADE DIRECTLY BY A LPSW OF THE PIOPSW.  IF THE         * 12200021
*    PSEUDO-DISABLED SWITCH IS ON, RETURN IS MADE DIRECTLY.  IF THE   * 12400021
*    NEW-OLD WORDS POINTED TO BY THE CVT ARE NOT EQUAL, A TASK        * 12600021
*    SWITCH IS REQUIRED AND EXIT IS MADE THROUGH THE DISPATCHER       * 12800021
*    (IEA0DS).  OTHERWISE, CONTROL IS RETURNED DIRECTLY AS ABOVE.     * 13000021
*                                                                     * 13200021
*    IF A HOOK INTERRUPT HAD NOT OCCURRED, RETURN IS MADE TO PFLIH.   * 13400021
*                                                                     * 13600021
*    WHEN A BRANCH TYPE HOOK OCCURS, THE OTHER ENTRY POINT IS GIVEN   * 13800021
*    CONTROL.  THE HCT QUEUE IS SEARCHED AND FOR EACH ACTIVE HCT, THE * 14000021
*    ROUTER ENTRY TO HANDLE BRANCH TYPE HOOKS IS CALLED.  THIS IS     * 14200021
*    LOCATED BY THE HCTROUTB FIELD.  WHEN CONTROL IS RETURNED FROM    * 14400021
*    THE ROUTER, THE RETURN CODE IS CHECKED.  A ZERO RETURN CODE      * 14600021
*    INDICATES THAT THE CLASS OF THE HOOK IS ON AND SO THE SEARCH     * 14800021
*    OF THE HCT QUEUE CONTINUES UNTIL THE END.  A CODE OF FOUR        * 15000021
*    INDICATES THAT THE CLASS WAS OFF AND SO THE SEARCHING IS         * 15200021
*    STOPPED AT THIS POINT AND RETURN IS MADE TO THE INSTRUCTION      * 15400021
*    FOLLOWING THE BRANCH HOOK.                                       * 15600021
*                                                                     * 15800021
* ENTRY POINTS --                                                     * 16000021
*         IHLMCIH -- PROGRAM INTERRUPT ENTRY POINT                    * 16200021
*                  PARAMETERS RECEIVED:                               * 16400021
*                      NONE                                           * 16600021
*                                                                     * 16800021
*         IHLBHOOK -- BRANCH TYPE HOOK ENTRY POINT                    * 17000021
*                  PARAMETERS RECEIVED:                               * 17200021
*                      R1 = ADDRESS OF NOP THAT CONTAINS HOOK ID.     * 17400021
*                           NOP HAS FORMAT X'470C0DDD' WHERE HOOK     * 17600021
*                           VALUE IS CDDD                             * 17800021
*                                                                     * 18000021
* INPUT --                                                            * 18200021
*    NONE                                                             * 18400021
*                                                                     * 18600021
* OUTPUT --                                                           * 18800021
*    NONE                                                             * 19000021
*                                                                     * 19200021
* EXTERNAL REFERENCES --                                              * 19400021
*         IHLROUTI -- HOOK INTERRUPT ENTRY POINT LOCATED BY           * 19600021
*              HCTROUT FIELD.                                         * 19800021
*                  PARAMETERS PASSED:                                 * 20000021
*                      R0  = ROUTER PARAMETER LIST ADDRESS            * 20200021
*                      R1  = HCT ADDRESS                              * 20400021
*                      R14 = RETURN ADDRESS                           * 20600021
*                                                                     * 20800021
*         IHLROUTB -- BRANCH HOOK ENTRY POINT LOCATED BY              * 21000021
*              HCTROUTB FIELD.                                        * 21200021
*                  PARAMETERS PASSED:                                 * 21400021
*                      R0  = HCT ADDRESS                              * 21600021
*                      R1  = ADDRESS OF NOP OF BRANCH TYPE HOOK       * 21800021
*                      R14 = RETURN ADDRESS                           * 22000021
*                                                                     * 22200021
*         IHLRCOV -- ERROR RECOVERY MONITOR LOCATED BY HCTRCOV        * 22400021
*              FIELD IN CURRENT HCT                                   * 22600021
*                  PARAMETERS PASSED:                                 * 22800021
*                      R1  = HCT ADDRESS                              * 23000021
*                                                                     * 23200021
*         IEA0DS -- DISPATCHER                                        * 23400021
*                  PARAMETERS PASSED:                                 * 23600021
*                      R0-R15 -- RESTORED TO VALUES AT INTERRUPT      * 23800021
*                                                                     * 24000021
* EXITS, NORMAL --                                                    * 24200021
*    FOR IHLMCIH:                                                     * 24400021
*         IF NO TASK SWITCH IS REQUIRED, RETURN TO INSTRUCTION AFTER  * 24600021
*              INTERRUPT.                                             * 24800021
*         IF TASK SWITCH IS REQUIRED, EXIT THROUGH DISPATCHER.        * 25000021
*                                                                     * 25200021
*    FOR IHLBHOOK:                                                    * 25400021
*         RETURN TO INSTRUCTION FOLLOWING BRANCH HOOK.                * 25600021
*                                                                     * 25800021
* EXITS, ERROR --                                                     * 26000021
*    NONE                                                             * 26200021
*                                                                     * 26400021
* TABLES / WORK AREAS --                                              * 26600021
*         ROUTER PARAMETER LIST                                       * 26800021
*              ****************************************************** * 27000021
*         +0   *   ADDRESS OF BRANCH ENTRY TO TIME RTN.  (IGC011A0) * * 27200021
*              ****************************************************** * 27400021
*         +4   *   ADDRESS OF SVC REGISTER SAVE AREA IN LOW CORE    * * 27600021
*              ****************************************************** * 27800021
*         +8   *   ADDRESS OF PI REGISTER SAVE AREA IN LOW CORE     * * 28000021
*              ****************************************************** * 28200021
*         +C   *   ADDRESS OF THE CVT                               * * 28250021
*              ****************************************************** * 28300021
*                                                                     * 28400021
*    LOW CORE FIELDS:                                                 * 28600021
*         PIOPSW -- USED TO DETERMINE TYPE AND ADDRESS OF INTERRUPT   * 28800021
*         IEA0IO02 -- PSEUDO-DISABLED SWITCH                          * 29000021
*                                                                     * 29200021
*    CVT FIELDS:                                                      * 29400021
*         CVTSTATE -- USED TO DETERMINE IF MONITOR IS IN CONTROL      * 29600021
*         CVTGTF -- USED TO FIND CMT                                  * 29800021
*         CVTTCBP -- USED TO FIND NEW-OLD WORDS FOR TASK SWITCH TEST  * 30000021
*                                                                     * 30200021
*    CMT FIELDS:                                                      * 30400021
*         CMTCMSK -- USED TO CALCULATE CLASS ADDRESS FOR CHANGING     * 30600021
*              AF TO 44 (MC-NOP TO EX-NOP)                            * 30800021
*         CMTHCT -- USED TO FIND FIRST HCT ON QUEUE                   * 31000021
*         CMTHCTDA -- USED TO TEST IF FIRST HCT IS ACTIVE             * 31200021
*                                                                     * 31400021
*    HCT FIELDS:                                                      * 31600021
*         HCTNHCT -- USED TO FIND NEXT HCT ON QUEUE                   * 31800021
*         HCTNDAC -- USED TO TEST IF NEXT HCT IS ACTIVE               * 32000021
*         HCTROUT -- USED TO FIND IHLROUTI                            * 32200021
*         HCTROUTB -- USED TO FIND IHLROUTB                           * 32400021
*         HCTRCOV -- USED TO FIND IHLRCOV                             * 32600021
*         HCTINCTL -- USED TO TEST IF HCT IS IN CONTROL               * 32800021
*                                                                     * 33000021
* ATTRIBUTES --                                                       * 33200021
*    REFRESHABLE, DISABLED, PRIVILEGED, SERIALLY-REUSEABLE            * 33400021
*                                                                     * 33600021
* CHARACTER CODE DEPENDENCY --                                        * 33800021
*    NONE                                                             * 34000021
*                                                                     * 34200021
* NOTES --                                                            * 34400021
*    THIS MODULE IS FOR MFT ONLY.                                     * 34600021
*                                                                     * 34800021
*********************************************************************** 35600021
         EJECT                                                          35800021
*********************************************************************** 36000021
*        MODULE THAT HANDLES REAL, SIMULATED AND BRANCH HOOKS (MFT)   * 36200021
*********************************************************************** 36400021
IHLMCIHF CSECT                                                          36600021
*A000000-999999                                                  S21014 36650021
*D902500                                                          M1329 36700021
*A896500                                                          M1329 36750021
*********************************************************************** 36800021
*        CVT MAPPING                                                  * 37000021
*********************************************************************** 37200021
CVTSECT  DSECT                                                          37400021
         CVT                                                            37600021
         EJECT                                                          37800021
*********************************************************************** 38000021
*        HOOK CONTROL TABLE MAPPING  (HCT)                            * 38200021
*********************************************************************** 38400021
         HCT                                                            38600021
         EJECT                                                          38800021
*********************************************************************** 39000021
*        CLASS MASK TABLE MAPPING  (CMT)                              * 39200021
*********************************************************************** 39400021
         CMT                                                            39600021
         EJECT                                                          39800021
*********************************************************************** 40000021
*        LOW CORE MAPPING                                             * 40200021
*********************************************************************** 40400021
         IEAQFX  65,SERP,0                                              40600021
         EJECT                                                          40800021
*********************************************************************** 41000021
*        ENTRY POINT FOR ALL PROGRAM INTERRUPTS                       * 41200021
*********************************************************************** 41400021
IHLMCIHF CSECT                                                          41600021
         ENTRY IHLMCIH                  NORMAL HOOK EP (REAL & SIMULTD) 41800021
         ENTRY IHLBHOOK                 BRANCH TYPE HOOK EP             42000021
TCBGRS   EQU   48                       TCB REGISTER SAVE AREA          42200021
RBOPSW   EQU   16                       PGM OLD PSW SAVED IN RB         42400021
TCBRBP   EQU   0                        ADDRESS OF CURRENT RB IN TCB    42600021
IHLPARM  EQU   0                        PARAMETER FIELD ADDRESS.        42800021
IHLHCTR  EQU   1                        HOOK CONTROL TABLE              43000021
IHLCMTR  EQU   1                        CMT ADDR                        43200021
IHLNHK   EQU   2                        NOT HOOK ADDR                   43400021
IHLCVT   EQU   3                        CVT ADDR                        43600021
IHLWK1   EQU   4                        WORK REG                        43800021
IHLWK2   EQU   5                        WORK REG                        44000021
IHLWK3   EQU   6                        WORK REG                        44200021
IHLSAVE  EQU   7                        REG TO SAVE PFLIH RETURN ADDR   44400021
IHLBASE  EQU   8                        BASE REG FOR THIS PROGRAM       44600021
IHLSREG  EQU   9                        PFLIH SAVE AREA                 44800021
IHLRE    EQU   14                       LINKAGE REG RETURN              45000021
IHLRF    EQU   15                       LINKAGE REG BRANCH              45200021
IHLR0    EQU   0                        LINKAGE REG FOR BRANCH HOOK     45400021
IHLR1    EQU   1                        LINKAGE REG FOR BRANCH HOOK     45600021
IHLILINT EQU   X'01'                    ILLEGAL OP INTERRUPT CODE       45800021
IHLMCINT EQU   X'40'                    MONITOR CALL INTERRUPT CODE     46000021
IHLMCOP  EQU   X'AF'                    MONITOR CALL OP-CODE            46200021
IHLEXOP  EQU   X'44'                    EXECUTE OP-CODE                 46400021
IHLNOPOP EQU   X'47'                    NOP OP-CODE, IF ZERO MASK       46600021
IHLZBASE EQU   X'F0'                    TM MASK FOR ZERO BASE TEST      46800021
IHLZMASK EQU   X'F0'                    TM MASK FOR ZERO MASK TEST      47000021
IHLPILC1 EQU   X'80'                    ICL BIT 1 IN PIOPSW             47200021
IHLPILC2 EQU   X'40'                    ILC BIT 2 IN PIOPSW             47400021
ENABLED  EQU   X'FF'                    TOTALLY ENABLED MASK            47600021
IHLPIILC EQU   X'C0'                    INSTRUCTION LENGTH IN PIPSW     47650021
         EJECT                                                          47800021
*********************************************************************** 48000021
*        ENTRY FOR NORMAL HOOKS OR RECURSION                          * 48200021
*********************************************************************** 48400021
IHLMCIH  EQU   *                        NORMAL HOOK ENTRY POINT         48600021
         LR    IHLBASE,IHLRF            ADDRESSIBILITY                  48800021
         USING IHLMCIH,IHLBASE                                          49000021
         LR    IHLSAVE,IHLRE            SAVE PFLIH RETURN ADDR          49200021
         L     IHLCVT,CVTCON            CVT ADDR                        49400021
         USING CVTSECT,IHLCVT           CVT ADDRESSIBILITY              49600021
         L     IHLCMTR,CVTGTF           GET CMT ADDR                    49800021
         SPACE                                                          50000021
*********************************************************************** 50200021
*        CHECK FOR PGM CHECK DURING HOOK PROCESSING                   * 50400021
*********************************************************************** 50600021
         TM    CVTGTFST,CVTSTATE        IS THIS PGMCHK DURING HOOK      50800021
         BZ    IHLNOTRE                 NO, CONTINUE NORMALLY           51000021
         EJECT                                                          51200021
*********************************************************************** 51400021
*        RECURSION INTO PFLIH DURING HOOK PROCESSING                  * 51600021
*********************************************************************** 51800021
*        LR    IHLHCTR,IHLCMTR          MAKE CMTHCT LOOK LIKE HCTNHCT   52000021
IHLRCTST EQU   *                        LOOK AT HCT ADDR                52200021
         USING HCT,IHLHCTR              ADDRESSIBILITY FOR HCT          52400021
         L     IHLHCTR,HCTNHCT          GET NEXT HCT ADDR               52600021
         LTR   IHLHCTR,IHLHCTR          IS THIS HCT ACTIVE              52800021
         BM    IHLRCTST                 NO TRY NEXT HCT                 53000021
         TM    HCTFLG1,HCTINCTL         IS THIS HCT IN CONTROL          53200021
         BZ    IHLRCTST                 NO, TRY NEXT HCT                53400021
         L     IHLRF,HCTRCOV            GET ERROR RECOVERY ADDR         53600021
         BR    IHLRF                    GO TO ERROR RECOVERY MONTR      53800021
         DROP  IHLHCTR                                                  54000021
         EJECT                                                          54200021
*********************************************************************** 54400021
*        POTENTIAL HOOK MUST BE CHECKED TO SEE IF REALLY HOOK         * 54600021
*        FOUR CASES: REAL MC INTERRUPT, EX-NOP, AF-NOP, OTHER PGMCHK  * 54800021
*********************************************************************** 55000021
         USING CMT,IHLCMTR                                              55200021
IHLNOTRE EQU   *                        NOT RECURSION DURING HOOK       55400021
         L     IHLSREG,IHLCON1          GET POINTER TO PFLIH REGS       55600021
*********************************************************************** 55800021
*        CHECK FOR REAL MC INTERRUPT                                  * 56000021
*********************************************************************** 56200021
         LA    IHLNHK,IHLNOHOK          ADDR OF BRANCH IF NOT HOOK      56250021
         TM    PIOPSW+3,IHLMCINT        IS REAL MC INTERRUPT            56400021
         BZ    IHLNOTMC                 NO, CHECK FOR SIMULATED MC      56700021
         TM    PIOPSW+4,IHLPIILC        MAYBE, CHECK FOR ZERO LENGTH    56750021
         BC    7,IHLCALLR               NONZERO LEN, REAL MC            56760021
         BR    IHLNHK                   ZERO LEN, IMPRECISE INTERRUPT   56770021
         SPACE                                                          56800021
*********************************************************************** 57000021
*        CHECK FOR EX-NOP AND AF-NOP                                  * 57200021
*********************************************************************** 57400021
IHLNOTMC EQU   *                        INTERRUPT IS NOT A REAL MC      57450021
         TM    PIOPSW+4,IHLPILC1        IS ILC=2 OR 3                   57800021
         BCR   8,IHLNHK                 NO, NOT HOOK                    58000021
         TM    PIOPSW+4,IHLPILC2        IS ILC=2                        58200021
         BCR   1,IHLNHK                 NO, NOT HOOK                    58400021
         CLI   PIOPSW+3,IHLILINT        IS IT ILLEGAL OP                58600021
         BCR   7,IHLNHK                 NO, NOT HOOK                    58800021
         L     IHLWK1,PIOPSW+4          ADDR FROM PI OPSW               59000021
         SL    IHLWK1,IHLC4             YIELDS ADDR OF EX OR MC         59200021
         CLC   0(2,IHLWK1),IHLEX00      DOES IT POINT TO EXECUTE        59400021
         BE    IHLEXNOP                 YES, CHECK VALID EX             59600021
         SPACE                                                          59800021
*********************************************************************** 60000021
*        CHECK FOR AF-NOP, AND IF SO, CHANGE TO EX-NOP                * 60200021
*********************************************************************** 60400021
         CLI   0(IHLWK1),IHLMCOP        IS IT AF OP-CODE                60600021
         BCR   7,IHLNHK                 NO, NOT HOOK                    60800021
         CLI   4(IHLWK1),IHLNOPOP       FOLLOWED BY POTENTIAL NOP       61000021
         BCR   7,IHLNHK                 NO, NOT HOOK                    61200021
         TM    5(IHLWK1),IHLZMASK       IS PTENTIAL NOP REAL NOP        61400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    61600021
         CLC   1(3,IHLWK1),5(IHLWK1)    AF HOOKID EQUAL NOP HOOKID      61800021
         BCR   7,IHLNHK                 NOT EQUAL. NOT A HOOK.          62000021
         SR    IHLWK2,IHLWK2            ZERO WORK REG                   62200021
         IC    IHLWK2,1(IHLWK1)         GET CLASS OF HOOK               62400021
         SLA   IHLWK2,1                 MULTIPLY CLASS BY 2             62600021
         LA    IHLWK2,CMTCMSK(IHLWK2)   CALCULATE CLASSMASK ADDR        62800021
         MVC   0(2,IHLWK1),IHLEX00      SET UP FIRST HALF OF EX INST    63000021
         STH   IHLWK2,2(IHLWK1)         PUT CLASSMASK ADDR IN EX        63200021
         CLI   0(IHLWK2),IHLMCOP        IS CLASS ON                     63400021
         BNE   IHLRETRN                 NO GO TO RETURN                 63600021
         B     IHLCALLR                 YES,GO TO CALL ROUTER           63800021
         SPACE                                                          64000021
*********************************************************************** 64200021
*        CHECK FOR EX-NOP                                             * 64400021
*********************************************************************** 64600021
IHLEXNOP EQU   *                        POTENTIAL EX-NOP                64800021
         TM    2(IHLWK1),IHLZBASE       IS BASE ZERO                    65000021
         BCR   7,IHLNHK                 NO, NOT HOOK                    65200021
         LH    IHLWK2,2(IHLWK1)         GET TARGET OF EXECUTE           65400021
         CLI   0(IHLWK2),IHLMCOP        IS IT AF OP-CODE                65600021
         BCR   7,IHLNHK                 NO, NOT HOOK                    65800021
         CLI   4(IHLWK1),IHLNOPOP       FOLLOWED BY POTENTIAL NOP       66000021
         BCR   7,IHLNHK                 NO, NOT HOOK                    66200021
         TM    5(IHLWK1),IHLZMASK       IS POTENTIAL NOP REAL NOP       66400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    66600021
         EJECT                                                          66800021
*********************************************************************** 67000021
*        ALL HOOKS WILL CALL ROUTER ADDR OF ALL ACTIVE HCT'S          * 67200021
*********************************************************************** 67400021
         DROP  IHLCMTR                                                  67600021
IHLCALLR EQU   *                        SEARCH HCT CHAIN                67800021
*        LR    IHLHCTR,IHLCMTR          MAKE CMTHCT LOOK LIKE HCTNHCT   68000021
IHLTESTH EQU   *                        LOOK DOWN HCT CHAIN             68200021
         USING HCT,IHLHCTR              ADDRESSIBILITY FOR HCT          68400021
         L     IHLHCTR,HCTNHCT          GET NEXT HCT ADDR               68600021
         LTR   IHLHCTR,IHLHCTR          CHECK HCT ADDR                  68800021
         BZ    IHLRETRN                 ZERO, NO MORE HCT'S             69000021
         BM    IHLTESTH                 NEG, INACTIVE HCT TRY NEXT      69200021
         SPACE                                                          69400021
*********************************************************************** 69600021
*        ROUTER IS TO BE CALLED FOR AN HCT                            * 69800021
*********************************************************************** 70000021
         LA    IHLPARM,IHLPLIST         SET PARAMETER LIST POINTER.     70200021
         L     IHLRF,HCTROUT            GET ROUTER ADDR                 70400021
         BALR  IHLRE,IHLRF              GO TO PROCESS HOOK              70600021
         B     IHLTESTH                 GO TO CHECK NEXT HCT            70800021
         DROP  IHLHCTR                                                  71000021
         EJECT                                                          71200021
*********************************************************************** 71400021
*        RETURN AFTER HOOK DIRECTLY IF CALLER DISABLED,               * 71600021
*        CHECK FOR TASK SWITCH IF CALLER TOTALLY ENABLED              * 71800021
*********************************************************************** 72000021
IHLRETRN EQU   *                        HOOK PROCESSING FINISHED        72200021
         CLI   PIOPSW,ENABLED           IS PSW TOTALLY ENABLED          72400021
         BNE   IHLDIRCT                 NO, RETURN DIRECTLY TO PGM      72600021
         L     IHLWK1,IHLCON3           GET PSEUDO-DISABLED SWITCH ADD  72800021
         TM    1(IHLWK1),X'F0'          IS IT ON                        73000021
         BO    IHLDIRCT                 YES, RETURN DIRCTLY             73200021
         L     IHLWK3,CVTTCBP           POINTER TO TASK CTL DBL WORD    73400021
         L     IHLWK1,4(IHLWK3)         DETERMINE IF A TASK SWITCH      73600021
         C     IHLWK1,0(IHLWK3)         IS REQUIRED                     73800021
         BNE   IHLTSWCH                 YES, BRANCH                     74000021
         SPACE                                                          74200021
*********************************************************************** 74400021
*        DIRECT RETURN WHEN NO TASK SWITCH IS REQUIRED                * 74600021
*********************************************************************** 74800021
IHLDIRCT EQU   *                        RETURN WHEN NO TASK SWITCH      75000021
         LM    10,9,0(IHLSREG)          RESTORE REGS FROM LOW CORE      75200021
         LPSW  PIOPSW                   RETURN AFTER HOOK               75400021
         SPACE                                                          75600021
*********************************************************************** 75800021
*        EXIT THROUGH DISPATCHER IF TASK SWITCH IS REQUIRED           * 76000021
*********************************************************************** 76200021
IHLTSWCH EQU   *                        DISP MUST BE CALLED             76400021
         L     IHLWK2,TCBRBP(0,IHLWK1)  GET CURRENT TCB                 76600021
         MVC   RBOPSW(8,IHLWK2),PIOPSW  MOVE PGM OLD PSW INTO RB        76800021
         MVC   TCBGRS(64,IHLWK1),0(IHLSREG)  SAVE REGS IN TCB           77000021
         LM    10,9,0(IHLSREG)          RESTORE REGS FROM LOW CORE      77200021
         BALR  14,0                     RE-ESTABLISH                    77400021
         USING *,14                     ADDRESSIBILITY                  77600021
         L     IHLRF,IHLCON2            GET DISPATCHER ADDRESS          77800021
         BR    IHLRF                    GO TO DISPATCHER                78000021
         DROP  14                                                       78200021
         DROP  IHLCVT                                                   78400021
         SPACE                                                          78600021
*********************************************************************** 78800021
*        NOT A HOOK, SO RETURN TO PFLIH AFTER RESTORING REGS          * 79000021
*********************************************************************** 79200021
IHLNOHOK EQU   *                        NOT A HOOK INTERRUPT            79400021
         LR    IHLRE,IHLSAVE            RESTORE PFLIH RETURN ADDR       79600021
         LM    0,9,24(IHLSREG)         RESTORE REGS THAT WERE USED. MFT 79800021
         BR    IHLRE                    RETURN TO PFLIH                 80000021
         EJECT                                                          80200021
*********************************************************************** 80400021
*        THIS SECTION HANDLES BRANCH HOOKS AND MUST NOT CHANGE        * 80600021
*        REGISTERS 2-13.  REGS 0,14,15 ARE VOLITLE AND REG 1 IS       * 80800021
*        THE RETURN ADDR (ALSO THE NOP ADDR THAT CARRIES HOOK ID)     * 81000021
*********************************************************************** 81200021
IHLBHOOK EQU   *                        BRANCH HOOK BRANCHES HERE       81400021
         BALR  IHLRE,0                  SET UP ADDRESSIBILITY           81600021
         USING *,IHLRE                                                  81800021
         L     IHLRF,CVTCON             CVT BASE ADDR                   82000021
         USING CVTSECT,IHLRF            ADDRESSIBILITY FOR CVT          82200021
         L     IHLRF,CVTGTF             GET CMT ADDR                    82400021
         USING CMT,IHLRF                ADDRESSIBILITY FOR CMT          82600021
*        LR    IHLRF,IHLRF              MAKE CMTHCT LOOK LIKE HCTNHCT   82800021
IHLBRTST EQU   *                        LOOK AT HCT                     83000021
         USING HCT,IHLRF                ADDRESSIBILITY FOR HCT          83200021
         L     IHLRF,HCTNHCT            GET NEXT HCT ADDR               83400021
         LTR   IHLRF,IHLRF              TEST HCT ADDR                   83600021
         BCR   8,IHLR1                  IF ZERO, NO MONITOR             83800021
         BM    IHLBRTST                 IF NEGITIVE, INACTIVE HCT       84000021
         SPACE                                                          84200021
*********************************************************************** 84400021
*        ROUTER (BRANCH ENTRY) IS TO BE CALLED FOR THIS HCT           * 84600021
*********************************************************************** 84800021
         LR    IHLR0,IHLRF              SAVE HCT ADDR FOR ROUTER        85000021
         L     IHLRF,HCTROUTB           ROUTER ADDR FOR BRANCH MC       85200021
         DROP  IHLRF                                                    85400021
IHLBCALL EQU   *                                                        85600021
         BALR  IHLRE,IHLRF              GO TO ROUTER BRANCH EP          85800021
         LTR   IHLRF,IHLRF              WAS CLASS OFF                   86000021
         BCR   7,IHLR1                  YES, RETURN- DONT SEARCH MORE   86200021
         LA    IHLRF,IHLBCALL-IHLBHOOK  NO, RESTORE                     86400021
         SR    IHLRE,IHLRF              ADDRESSIBILITY                  86600021
         LR    IHLRF,IHLR0              RESTORE HCT ADDR                86800021
         USING HCT,IHLRF                REESTABLISH HCT ADDRESSIBILITY  87000021
         B     IHLBRTST                 CONTINUE SEARCH                 87200021
         DROP  IHLRF                                                    87400021
         EJECT                                                          87600021
*********************************************************************** 87800021
*        CONSTANTS AND PARM LIST FOR ROUTER                           * 88000021
*********************************************************************** 88200021
IHLEX00  DC    X'4400'                  1ST HALF OF EXECUTE INSTR       88400021
IHLC4    DC    F'4'                     CONSTANT 4                      88600021
         SPACE                                                          88800021
IHLPLIST DS    0XL16                    PARM LIST TO ROUTER             89000021
IHLTIMBR DC    V(IGC011A0)              TIME ROUTINE BRANCH ADDR        89200021
         DC    V(SVCSAV)                SVC SAVE AREA IN LOW CORE       89400021
IHLCON1  DC    V(PISAV)                 PI SAVE AREA IN LOW CORE        89600021
CVTCON   DC    V(IEACVT)                CVT ADDRESS               M1329 89650021
         SPACE                                                          89800021
IHLCON2  DC    V(IEA0DS)                DISPATCHER ADDRESS              90000021
IHLCON3  DC    V(IEA0IO02)              PSEUDO-DISABLE SWITCH           90200021
         END                                                            90400021
