AD00     TITLE 'IEAQAD00 / ABDUMP LOAD 1 / IGC0L05A'              20048 00020021
IGC0L05A CSECT                                                    20048 00040021
*0018091400-0922                                                        00044021
*3523051800                                                        1646 00048021
*042400                                                           20048 00048821
*THE FOLLOWING LINE REFERS TO STATEMENTS THAT WERE DELETED FROM THIS    00049621
*MODULE AND PLACED IN A NEW MODULE (IEAQAD0C).                          00049721
*3523082000-096800,097400-098400,103400-107200                          00049821
*   THE FOLLOWING IS THE FIRST LOAD OF ABDUMP                           00049921
*STATUS CHANGE LEVEL=0                                                  00050021
*   ROUTINE NAME-                                                       00050821
*        IEAQAD00 (ALSO CALLED ABDUMP1)                                 00051621
*   FUNCTION-                                                           00051721
*        ABDUMP1 PERFORMS THE FOLLOWING FUNCTIONS--                     00051821
*        1) IF THE DCB IS NOT OPENED-ERROR EXIT                         00051921
*        2) IF THE DUMP OF TASK OTHER THAN CURRENT IS REQUESTED         00052021
*           AND AN INVALID TCB ADDRESS WAS SPECIFIED-ERROR EXIT         00052821
*        3) IF THE DUMP OF TASK OTHER THAN CURRENT IS REQUESTED         00052921
*          -SET THE JOBSTEP (EXCEPT CURRENT TASK) NON-DISPATCHABLE.     00053021
*        4) IF ABDUMP IS ENTERED VIA SNAP MACRO-ENQ ON THE DCB ADDRESS  00053821
*           (OTHERWISE ENQ/DEQ IS PERFORMED BY ABEND).                  00053921
*        5) GETMAIN FOR ABDUMP'S WORK AREA.                             00054021
*        6) LOAD IEAQAD0A MODULE INTO CORE                              00054821
*   ENTRY POINT NAME-                                                   00055621
*        IGC0005A                                                       00055721
*   ATTRIBUTES-                                                         00055821
*        TYPE IV SVC,SUPERVISOR STATE,REENTRANT                         00055921
*   APPLICABILITY-                                                      00056021
*        OPTION IV.                                                     00056821
*   EXTERNAL REFERENCES--NONE                                           00057621
*   SVC USAGE-                                                          00057721
*             1) SVC 3 (EXIT)                                           00057821
*             2) GETMAIN (SP 0)                                         00057921
*             3) LOAD                                                   00058021
*             4) ENQ                                                    00058821
*             5) GETMAIN (SP 253)                                       00059621
*             6) XCTL                                                   00059721
*   INPUT-                                                              00059821
*        ABDUMP1 IS PASSED IN REG 1 A POINTER TO THE PARAMETER LIST     00059921
*        CONSISTING OF 1) FLAG BYTES 2) POINTER TO DCB (OPEN'ED FOR     00060021
*        BSAM) 3) POINTER TO TCB (OTHER THAN CURRENT) 4) POINTER TO     00080021
*        THE STORAGE LIST (IF ABDUMP IS ENTERED VIA SNAP MACRO AND      00100021
*        STORAGE KEYWORD PARAMETER WAS SPECIFIED).                      00120021
*   OUTPUT-                                                             00140021
*        NONE                                                           00160021
*   ENTRY POINTS-                                                       00180021
*        1) PSW                                                         00200021
*             A) DISABLE FOR ALL MASKABLE INTERRUPTS EXCEPT MACH CHECK  00220021
*             B) UNDER SUPERVISOR PROTECTION KEY                        00240021
*             C) IN SUPERVISOR MODE                                     00260021
*        2) REGISTERS-                                                  00280021
*             A) REG 3-ADDRESS OF THE CVT.                              00300021
*             B) REG 4-ADDRESS OF THE CURRENT TCB                       00320021
*             C) REG 5-ADDRESS OF ABDUMP'S SVRB                         00340021
*             D) REG 1-POINTER TO THE PARAMETER LIST                    00360021
*   EXIT-                                                               00380021
*       A) IF ABDUMP'S REQUIREMENTS HAVE BEEN MET, ABDUMP1 TRANSFERS    00400021
*       CONTROL VIA AN XCTL TO ABDUMP1.5 (IEAQAD0C).  B) IF ABDUMP'S    00420021
*        REQUIREMENTS HAVE NOT BEEN MET, ABDUMP1 EXITS (SVC 3) WITH     00440021
*        REG 15 CONTAINING- 1) RETURN CODE OF 4 IF THE DCB HAS NOT BEEN 00460021
*        OPEN'ED 2) RETURN CODE - 8 IF AN INVALID TCB ADDRESS IS GIVEN  00480021
*   TABLE AND CONTROL BLOCKS REFERENCED-                                00500021
*        ABDUMP1 REFERENCES THE FOLLOWING CONTROL BLOCKS-               00520021
*        1)TCB                                                          00540021
*        TCBJST-POINTER TO TCB OF THE JOB STEP TASK                     00560021
*        TCBPKF-TASK PROTECTION KEY                                     00580021
*        4)DCB                                                          00600021
*        OFLAGS-FLAG BYTE                                               00620021
*        DVTYPE-A BYTE INDICATING THE DEVICE TYPE                       00640021
*        IOBSYSNAD-A WORD CONTAINING IOB LENGTH AND SYNAD EXIT.         00660021
*   LIST ORIGINS,TABLES,CONTROL BLOCKS INCLUDED-                        00680021
*        ABDUMP1 OBTAINS A WORK AREA VIA                                00700021
*        GETMAIN AND MAINTAINS THE POINTER TO THE AREA IN REG 13.  THE  00720021
*        AREA IS USED BY EACH TRANSIENT LOAD OF ABDUMP, AND IS ASSIGNED 00740021
*        AS FOLLOWS:                                                    00760021
*        A) REGISTER SAVE AREA - 72 BYTES                               00780021
*        B) DECB USED BY BSAM ROUTINES - 20 BYTES                       00800021
*        C) LINE 1 PAGE CTRS - 4 BYTES                                  00820021
*        D) POINTER TO THE PARAMETER LIST - 4BYTES                      00840021
*        E) WORK AREA - 24 BYTES                                        00860021
*        F) SAVE AREA FOR THE POINTERS USED BY THE OUTPUT ROUTINE - 12  00880021
*        BYTES                                                          00900021
*        G) AREA USED TO SAVE INTERNAL LINKAGE REGISTER - 4 BYTES       00920021
*        H) OUTPUT BUFFER - 129 BYTES                                   00940021
*        I) RESERVED-1 BYTE.                                            00960021
*        J) INTERNAL CONTROL FLAGS - 1 BYTE                             00980021
*        K) POINTERS TO MOVED TRACE TABLE - 12 BYTES                    01000021
*        L) ADDRESS OF THE SAVE AREA FOR IEAQAD09-4 BYTES               01020021
*        M) REGISTER SAVE AREA WHEN BRANCHING TO IEAQAD09-4 BYTES       01040021
*        N) ENTRY POINT ADDRESS OF IEAQAD09-4 BUTES                     01060021
*        O) WHERE TO GO FLAGS-2 BYTES                                   01080021
*        P) CURRENT TCB ADDRESS-4 BYTES                                 01100021
*        Q) ABDUMP'S SVRB ADDRESS-4 BYTES                               01120021
*   OPERATION                                                           01140021
*        UPON RECEIVING CONTROL, IN SUPERVISOR MODE AND WITH I/O AND    01160021
*        EXTERNAL INTERRUPTS DISABLED, ABDUMP1 PICKS UP A POINTER TO A  01180021
*        BSAM DCB AND DETERMINES IF THE DCB IS OPEN. IF THE DCB IS NOT  01200021
*        OPEN, A RETURN CODE OF 4 IS RETURNED IN REG 15 TO THE CALLER   01220021
*        OF ABDUMP.  IF THE DCB IS OPEN, IT IS FURTHER CHECKED TO       01240021
*        INSURE THAT THE PROPER ATTRIBUTES ARE PRESENT IN THE DCB,      01260021
*        I.E., DSORG=PS, MACRF=W, RECFM=VBA, LRECL=125,                 01280021
*        AND BLKSIZE=1632.  IF THESE ATTRIBUTES ARE NOT PRESENT IN THE  01380021
*        DCB PASSED TO ABDUMP, A RETURN CODE = C IS PLACED IN REG 15.   01400021
*        IF THE DUMP OF A TASK OTHER THAN THE CURRENT IS REQUES-        01420021
*        TED,THE TCB ADDRESS IS VALIDITY CHECKED AND AN ERROR CODE      01440021
*        OF 8 IS RETURNED TO THE CALLER IF THE ADDRESS IS INVALID.      01460021
*        TO PREVENT ANY DYNAMIC MODIFICATION OF SUPERVISOR QUEUES       01480021
*        THE CURRENT JOB STEP (EXCEPT CURR. TASK) IS SET NON-DISPATCHA- 01500021
*        BLE IF A DUMP OF TASK OTHER THAN CURRENT IS REQUESTED.         01520021
*        AN R-TYPE OF GETMAIN IS NEXT ISSUED TO OBTAIN A WORK AREA      01540021
*        FOR ALL ABDUMP'S MODULES. NON-TRANSIENT MODULE-IEAQAD0A        01560021
*        IS LOAD'ED INTO CORE.ABDUMP1 ENQ'S USING 'SYSIEA01'            01580021
*        AND DCB ADDRESS AS MAJOR AND MINOR QCB NAMES RESPECTIVELY.     01600021
*        IF THE TRACE TBL. IS TO BE WRITTEN A CONDITIONAL               01620021
*        GETMAIN IS ISSUED IN ORDER TO PRESERVE THE STATUS OF THE TRACE 01640021
*        TABLE,AND IF THE DEVICE IS NOT A PRINTER,AN ADDITIONAL         01660021
*        CONDITIONAL GETMAIN IS ISSUED TO ALLOW BLOCKING OF THE LOGICAL 01680021
*        RECORDS. THE BSAM DECB AND ABDUMP'S OUTPUT AREA ARE            01700021
*        INITIALIZED. EXTERNAL AND I/O INTERRUPTS ARE ENABLED. FINALLY, 01720021
*        CONTROL IS TRANSFERRED VIA AN XCTL TO ABDUMP1.5 (IEAQAD0C).    01740021
*NOTE-THIS MODULE IS CHARACTER CODE DEPENDENT(EBCDIC)                   01760021
         EJECT                                                          01780021
*        REGISTERS                                                      01800021
R0       EQU   0         ACCUMULATOR                                    01820021
R1       EQU   1         PTR TO PARAMETER LIST                          01840021
R2       EQU   4                   PTR TO TCB                           01860021
R3       EQU   3         RB PTR                                         01880021
R4       EQU   2                   PTR TO PARAMETER LIST,RB PTR         01900021
PARREG   EQU   2                   PTR TO PARAMETER LIST                01920021
LINKREG  EQU   5             INTERNAL LINK REG                          01940021
R5       EQU   5         INTERNAL LINKAGE REGISTER                      01960021
R6       EQU   6         PTR TO CONSTANTS,...                           01980021
R7       EQU   7         PTR TO OUTPUT LINE                             02000021
R8       EQU   8         PTR TO INFO TO BE FORMATTED                    02020021
R9       EQU   9         PTR TO BLOCKING BUFFER                         02040021
RA       EQU   10        WORK REGISTER                                  02060021
RB       EQU   11        WORK REGISTER                                  02080021
RC       EQU   12        BASE REGISTER                                  02100021
RD       EQU   13        POINTER TO AREA OBTAINED VIA GETMAIN           02120021
RE       EQU   14                                                       02140021
RF       EQU   15        RETURN CODE REGISTER                           02160021
*                                                                       02180021
*  ERROR RETURN CODES                                                   02200021
BADDCB   EQU   4                   INVALID DCB ADDR I.E. DCB NOT OPENED 02220021
BADTCB   EQU   8                   INVALID TCB ADDR                     02240021
SICKDCB  EQU   12                  INCORRECT DCB TYPE RETURN CODE (0C). 02260021
*                                                                       02280021
FORMFLAG EQU   X'00'               INITIALIZE FLAG FOR FORMAT RTNE21014 02300021
*                                                                       02320021
TCBFX    EQU   X'01'          PREVENT ASYNCHRONOUS EXIT INDICATOR       02340021
TCBADUMP EQU   X'80'                   ABDUMP NON-DISPATCH. BIT         02360021
TTFLGOFF EQU   X'00'               FLAG THAT TT NOT BEING PROCESSED     02380021
SCVTRPTR EQU   X'40'         DISPLACEMENT TO TR TBL POINTERS            02400021
VBA      EQU   X'54'               PROPER RECFM FIELD                   02420021
NOTPS    EQU   X'BF'               NOT PSORG MASK IN DCB                02440021
CUR      EQU   4                                                        02460021
EXIT     EQU   3                                                        02480021
MESG     EQU   X'01'     MASK TO TEST IF MESSAGE TO BE PUT OUT          02500021
DVTYPE   EQU   17        DCB DISPLACEMENT TO DEVICE TYPE                02520021
OFLGS    EQU   48        DCB DISPLACEMENT TO OPEN FLAGS                 02540021
IOBSYNAD EQU   56        DCB DISPLACEMENT TO IOB LENGTH, SYNAD          02560021
ESA      EQU   96                  EXT SAVE AREA                        02580021
OPEN     EQU   X'10'     MASK TO TEST OPEN FLAG                         02600021
ZERO     EQU   0                                                  20002 02620021
DUMPTCAM EQU   X'80'               MASK FOR TCAM INFO             20002 02640021
DUMPTSO  EQU   X'40'               MASK FOR TSO INFO              20021 02660021
TSOTASK  EQU   X'80'               MASK TO TEST FOR TSO TASK      20021 02680021
XFF      EQU   X'FF'                                              20002 02700021
AVTCVTPT EQU   240                 OFFSET TO AVT PTR IN CVT       20002 02720021
AVTTCB   EQU   X'170'              OFFSET TO TCB ADDR IN AVT      20002 02740021
* DISPLACEMENTS FROM BEGINNING OF TIOT TO                               02760021
TIOTJOB  EQU   0         JOB NAME                                       02780021
TIOTSTEP EQU   8         STEP NAME                                      02800021
* DISPLACEMENTS FROM BEGINNING OF TCB TO                                02820021
TCBRBP   EQU   0         PTR TO ACTIVE RB CHAIN                         02840021
TCBPIE   EQU   4         PTR TO PROG INTERRUPT ELEMENT                  02860021
TCBTIOT  EQU   12        PTR TO TIOT                                    02880021
TCBCMP   EQU   16        TASK COMPLETION CODE                           02900021
TCBPKF   EQU   28                  PROTECT KEY FIELD                    02920021
TCBFLG1  EQU   29                  TCB FLAGS FIELD                21014 02940021
TCBGTOFM EQU   X'10'               MASK FOR GTF TRACE DISABLED    21014 02960021
TCBFLGS  EQU   30                      DISPACHABILITY FLAGS             02980021
TCBLL    EQU   36        PTR TO LIST OF LOADED PROGRAMS                 03000021
TCBJST   EQU   124                 JOB STEP TCB ADDR                    03020021
TCBNTC   EQU   128                 ADDRESS OF THE NEXT TCB OF SUBTASK Q 03040021
TCBOTC   EQU   132                 ADDRESS OF THE ORIGINATING TCB       03060021
TCBLTC   EQU   136                 ADDRESS OF DAUGHTER TCB              03080021
TCBTSFLG EQU   148                 TSO FLAG BYTE                  20021 03100021
* DISPLACEMENTS FROM BEGINNING OF RB TO                                 03120021
RBSIZE   EQU   8         SIZE OF RB/PROG                                03124021
RBSTAB   EQU   10        RB STATUS AND ATTRIBUTE BITS                   03128021
RBOPSW   EQU   16        PSW SAVE AREA                                  03128821
RBLINK   EQU   28        RB CHAIN ADDR                                  03129621
RBREG    EQU   32                                                       03129721
* EXTENDED ASA CARRIAGE CONTROL CHARACTERS FOR                          03129821
HDCC     EQU   C'0'                     HEADING LINE                    03129921
COMPCC   EQU   C'0'                     COMPLETION CODE LINE            03130021
PSWCC    EQU   C'0'                     PSW LINE                        03134021
MSGCC    EQU   C'0'                     MESSAGE LINE                    03138021
TWENTY   EQU   20                                                       03138821
FOUR     EQU   4                                                        03139621
**********************************************************              03139721
* INITIALIZATION                                                        03139821
*       1)  DETERMINE IF ABDUMP REQUIREMENTS HAVE BEEN MET (OPENED      03139921
*           DCB AND SUFFICIENT CORE AVAILABLE).                         03140021
*       2)  ENABLE FOR I/O AND EXTERNAL INTERRUPTS.                     03160021
*       3)  INITIALIZE OUTPUT AREA.                                     03180021
*                                                                       03200021
ENTRY   BALR  RC,0                     ESTABLISH ADDRESSABILITY         03220021
         USING *,RC                                                     03240021
         USING PARDSECT,PARREG     SET UP PARAMETER DSECT               03260021
         USING CVTDSECT,R3                                              03280021
*                                                                       03300021
         LR    R7,R2               SAVE CURRENT TCB ADDRESS             03320021
         LR    R8,R5         SAVE ABDUMP'S SVRB ADDRESS                 03340021
         L     R6,4(PARREG)        GET PTR TO DCB                 20048 03360021
         TM    OFLGS(R6),OPEN      IS DCB OPEN                          03380021
         BNE   GOGM                YES, IT'S OPEN, SKIP ERROR RETURN    03400021
         LA    RF,BADDCB           NO, ERROR RETURN                     03420021
         SVC   EXIT                RETURN                               03420821
         EJECT                                                          03421621
*********************************************************************** 03421721
*        THE FOLLOWING CODE INSURES THAT THE ABDUMP OUTPUT ROUTINE    * 03421821
*        WILL USE A VALID DCB WITH THE FOLLOWING ATTRIBUTES-          * 03421921
*                                                                     * 03422021
*              DSORG=   PS                                            * 03422821
*              MACRF=   W (BSAM)                                      * 03423621
*              RECFM=   VBA                                           * 03423721
*              LRECL=   125                                           * 03423821
*              BLKSIZE= 1632                                          * 03423921
*                   OR 882                                              03424021
* NOTE-- ALLOWING BLKSIZE OF 882 WAS ADDED TO ALLOW COMPATABILITY WITH  03424821
*       MFT2 WHICH REQUIRES 882 FOR SNAP OR ABEND DUMP TO SUPPORT       03425621
*        THE 10K OUTPUT WRITER.                                         03425721
*                                                                     * 03425821
*        IF THE DCB DOES NOT MEET THESE REQUIREMENTS, A RETURN CODE   * 03425921
*        OF 0C IS RETURNED IN REGISTER 15.                            * 03426021
*                                                                     * 03426821
*********************************************************************** 03427621
         SPACE 2                                                        03427721
         USING IHADCB,R6                                                03427821
GOGM     TM    DCBDSORG,NOTPS      SEE IF DSORG IS NOT PS               03427921
         BM    WRONGDCB            IF NOT PS, RETURN ERROR CODE         03428021
         CLI   DCBRECFM,VBA        SEE IF RECFM = VBA                   03428821
         BNE   WRONGDCB            IF NOT VBA, RETURN ERROR CODE        03429621
         CLC   DCBLRECL,PHYLOG+4   SEE IF LRECL = 125                   03429721
         BNE   WRONGDCB            IF NOT 125, RETURN ERROR CODE        03429821
         CLC   DCBBLKSI,MINMAX+6   SEE IF BLKSIZE = 1632                03429921
         LA    RB,MINMAX               SAVE SIZE FOR LATER GETMAIN BLKB 03430021
         BE    BLKOK                   IS 1632,BRANCH              BLKB 03430821
         CLC   DCBBLKSI,MINMAX2+6      IS BLKSIZE=882              BLKB 03431621
         BNE   WRONGDCB                NO,BRANCHTO RETURN ERR CODE BLKB 03431721
         LA    RB,MINMAX2              SAVE SIZE FOR LATER GETMAIN BLKB 03431821
BLKOK    EQU   *                                                        03431921
         CLC   DCBMACRF,=H'32'     SEE IF MACRF = W (BSAM)              03432021
         BE    GOODDCB             IF SO, CONTINUE WITH ABDUMP          03432821
WRONGDCB LA    RF,SICKDCB          ELSE, PLACE RETURN CODE = 0C IN      03433621
*                                  REGISTER 15- - -                     03433721
         SVC   EXIT                AND RETURN                           03433821
         LTORG                                                          03433921
         DROP  R6                                                       03434021
         EJECT                                                          03438021
GOODDCB  DS    0H                                                       03438821
         TM    PFLAGS,PFTCB        IS TCB ADDR GIVEN                    03439621
         BC    8,CURRTCB      NO,ASSUME CURRENT TCB                     03439721
*                                                                       03439821
* VALIDITY CHECK GIVEN TCB ADDRESS                                      03439921
*                                                                       03440021
         L     R2,PTCBPTR     LOAD GIVEN TCB ADDRESS                    03460021
         LTR   R2,R2          IS TCB ADDRESS ZERO                       03480021
         BZ    CURRTCB        YES,ASSUME DUMP IS FOR CURRENT TASK  1646 03500021
         CLI   TCBPKF(R7),0   IS ABDUMP CALLED BY SUPERV. ROUTINE       03520021
         BC    7,PPRTN        NO,BRANCH                                 03540021
         OI    TCBFLGS+2(R2),TCBADUMP SET TASK NON-DISPATCHABLE         03560021
*     MORE MULTIPROCESSOR TASK REMOVAL                             MP0C 03580021
         TM    CVTDCB,CVTDCBMP     IS THIS AN M65MP?               MP0C 03600021
CVTDCBMP EQU   X'04'               MASK 00000100                   MP0C 03604021
         BZ    AROUND                  NO                          MP0C 03604821
         L     RF,CVTMPCVT    GET MULTIPROCESSOR SECONDARY         MP0C 03605621
*                             CVT ADDRESS                          MP0C 03605721
         USING IEAMPCVT,RF                                         MP0C 03605821
         L     RF,CVTTKRM     GET ADDRESS OF TASK REMOVER          MP0C 03605921
         DROP  RF                                                  MP0C 03606021
         BALR  RE,RF          EXECUTE TESTDSP                      MP0C 03610021
AROUND   EQU   *                                                   MP0C 03610821
         B     GETM                                                     03611621
PPRTN    CLC   TCBJST(4,R2),TCBJST(R7) IS GIVEN TCB IN CURR JOBSTEP     03611721
         BC    8,GETM        YES,BRANCH                                 03611821
MALTCB   LA    RF,BADTCB      NO,GET ERROR CODE                         03611921
         SVC   EXIT           RETURN                                    03612021
CURRTCB  EQU   *    PREVENT ASYNCHRONOUS EXITS FOR CURR TASK            03616021
         OI    TCBFLGS-1(R7),TCBFX                                      03620021
GETM     EQU   *                                                        03640021
* GETMAIN FOR OUTPUT AREA, SAVE AREA, DECB, WORK AREA, SPACE FOR        03660021
* OUTPUT ROUTINE, PRINT LINE                                            03680021
         L     R0,WORKSIZE        NO. OF BYTES FOR WORK AREA            03700021
         GETMAIN   R,LV=(0)                                             03720021
* POINTER TO AREA ALLOCATED IS RETURNED IN REGISTER 1.                  03724021
         LR    RD,R1                                                    03728021
         L     R0,SAVESIZE         LENGTH FOR SAVE AREA       AB A40891 03728821
         GETMAIN R,LV=(0)                                     AB A40891 03729621
*         POINTER TO ALLOCATED AREA IS IS REG ONE(1)                    03729721
         ST    R1,ZERO(RD)          SAVE ADDR OF DECB         AB A40891 03729821
         LA    R1,TWENTY(R1)       BUMP POINTER TO SAVE AREA  AB A40891 03729921
         ST    R1,FOUR(RD)         SAVE ADDR OF SAVE AREA     AB A40891 03730021
         USING ABDAREA,RD                                               03734021
         USING LDDSECT,R6                                               03738021
         MVI   ABDBLNKS,FORMFLAG   INIT FORMAT ROUTINE FLAG       21014 03738821
         ST    RB,ABDWORK              SAVE ADDR OF CORE REQ       BLKB 03739621
*                                      FOR GETMAIN FOR BUFFER           03739721
         ST    R7,ABDCTCB          SAVE CURRENT TCB ADDRESSS            03739821
         ST    R8,ABDCRB     SAVE ABDUMP'S SVRB ADDRESS                 03739921
         MVC   ABDWTG(2),2(R4)     SAVE OPTION FLAGS                    03740021
         LA    R0,LOADNAME         LA OF NAME OF REENTRABLE PGM         03760021
         L     R1,CVTSVDCB         GET SVC LIB DCB ADDRESS              03780021
         LOAD  EPLOC=(0),DCB=(1)                                        03800021
         ST    R0,ABDLDADD         SAVE ENTRY POINT ADDR                03820021
         TM    PFLAGS,PFABEND      IS ABEND THE CALLER        AB  M0805 04144021
         BC    8,NOENQ             YES.  BYPASS ENDQUE        AB  M0805 04148021
*                                                                       04160021
*  ENQ ON SYSABEND DATA SET                                             04180021
*                                                                       04200021
         LA    R1,ESA(R8)     GET ABDUMP'S EXT SAVE AREA ADDRESS        04220021
         XC    0(12,R1),0(R1)      CLEAR ENQ PARAM LIST                 04224021
         MVC   12(8,R1),MAJ        MOVE MAJ NAME OUTSIDE TRANS AREA     04228021
         LA    14,12(R1)           GET ADDR OF MAJOR NAME               04228821
         LA    15,4(R4)            GET MINOR QCB NAME(DCB ADDRESS)      04229621
         LA    3,4                 GET LENGTH OF MINOR QCB NAME         04229721
         MVI   0(R1),X'FF'         LAST ENTRY INDICATOR                 04229821
*                                                                       04229921
         ENQ   ((14),(15),E,(3),),MF=(E,(1))                            04230021
*                                                                       04250021
NOENQ    EQU   *                                                        04270021
         TM    PFLAGS,PFTCB  IS CURRENT TASK BEING DUMPED               04274021
         BZ    TESTRACE       YES,BRANCH                          20472 04278021
         LTR   R2,R2          IS GIVEN TCB ADDR ZERO               1646 04278821
         BNZ   SETNDISP       NO,BRANCH                            1646 04279621
         LR    R2,R7          YES,CURRENT TASK IS TO BE DUMPED     1646 04279721
         NI    ABDWTG,X'BF'   INDICATE TCB ADDR NOT GIVEN          1646 04279821
         B     TESTRACE                                           20472 04279921
SETNDISP EQU   *                                                   1646 04280021
*                                                                       04300021
* TO AVOID ANY DYNAMIC MODIFICATION OF SUP Q'S SET CURRENT JOBSTEP      04320021
* NON-DISPATCHABLE(EXCEPT CURRENT TASK).                                04340021
*                                                                       04360021
         L     RE,TCBJST(R7)  GET JOBSTEP TCB ADDRESS                   04380021
         LCR   RE,RE         INDICATE 1ST TIME ENTRY TO TASKSEL         04400021
SEL1     BAL   LINKREG,SELTASK WAS TASK SELECTED                        04420021
         B     SEL2          YES,BRANCH                                 04440021
         B     SEL3          NO MORE TASKS,BRANCH                       04460021
SEL2     OI    TCBFLGS+2(RE),TCBADUMP SET TASK NON-DISP.                04480021
         B     SEL1          SELECT NEXT TASK                           04500021
SEL3     NI    TCBFLGS+2(R7),255-TCBADUMP  MAKE CURRENT TASK DISP.      04520021
*                                                                  MP0C 04540021
*   EXECUTE MULTIPROCESSOR'S TASK REMOVAL LOGIC IN CASE            MP0C 04544021
*   THE TASK ON THE OTHER CPU HAS BEEN SET NON-DISPATCHABLE        MP0C 04548021
*                                                                  MP0C 04552021
         TM    CVTDCB,CVTDCBMP     IS THIS AN M65MP?               MP0C 04556021
         BZ    TESTRACE       NO,BRANCH                           20472 04560021
         L     RF,CVTMPCVT    GET MULTIPROCESSOR SECONDARY         MP0C 04580021
*                             CVT ADDRESS                          MP0C 04600021
         USING IEAMPCVT,RF                                         MP0C 04620021
         L     RF,CVTTKRM     GET ADDRESS OF TASK REMOVER          MP0C 04640021
         DROP  RF                                                  MP0C 04660021
         BALR  RE,RF          EXECUTE TESTDSP                      MP0C 04680021
*                                                                  MP0C 04700021
TESTRACE EQU   *                                                  20472 04724021
         TM    PFLAGS,PFABEND   IS ABEND THE CALLER                     04728021
         BC    8,TSTGT             YES,BYPASS HOOK            AC  M0805 04732021
***  FOR SNAP,ISSUE HOOK TO FREEZE GTF, IF GTF IS ACTIVE AND      21014 04736821
*** THE TRACE TABLE IS REQUESTED                                  21014 04737621
         TM    PFLAGS,PFTRACE      IS TRACE TABLE WANTED ?        21014 04738421
         BZ    BYPASSHK            IF NOT, BYPASS HOOK            21014 04739221
         L     R3,CVTPTR          GET CVT ADDR                    21014 04739321
         TM    CVTGTFST,CVTGTFS+CVTFORM IS GTF ACTIVE AND TO BE   21014 04739421
*                                                FORMATTED        21014 04739521
         BNO   BYPASSHK            IF NOT, BYPASS HOOK            21014 04739621
         TM    TCBFLG1(R7),TCBGTOFM  TRACE BEEN SUSPENDED ?       21014 04739721
         BO    BYPASSHK            IF YES,DONT TRY TO DO IT AGAIN 21014 04739821
         OI    TCBFLG1(R7),TCBGTOFM    NO,SET TRACE SUSPENDED BIT 21014 04739921
         HOOK  EID=IHLMABOF        TURN OFF TRACE                 21014 04745721
BYPASSHK EQU   *                                              AC  M0805 04760821
TSTGT    EQU   *                                              AC  M0805 04760921
         TM    CVTGTFST,CVTGTFS    IS GTF ACTIVE ?                21014 04761421
         BO    ABD03               IF YES SKIP GETMAIN & TT MOVE  21014 04767221
         TM    PFLAGS,PFTRACE      IS TRACE TABLE WANTED                04780021
         BZ    TTNOTAV             NO, SET NOT AVAIL. FLAG              04800021
         L     R3,CVTPTR     GET CVT ADDRESS                            04820021
         L     R8,CVTABEND   GET ABEND'S CVT ADDRESS                    04824021
         L     R8,SCVTRPTR(R8)  GET ADDR OF TR TBL POINTERS             04824821
         LTR   R8,R8               IS TR TBL AVAILABLE                  04824921
         BC    8,TTNOTAV           NOT AVAILABLE,BRANCH                 04825021
         L     R9,8(R8)            AVAILABLE,GET LAST POINTER           04829021
         S     R9,4(R8)            COMPUTE THE SIZE OF TRACE TBL        04829821
         LR    RA,R9                                                    04829921
         ST    R9,ABDWORK2         STORE SIZE OF TT IN WORK             04831021
         MVI   ABDWORK2,X'80'      SET HI BIT TO INDIC ATE LAST LENGTH  04836821
         LA    R1,ABDWORK1         LA OF PARAM LIST AREA                04842621
         GETMAIN  LC,LA=ABDWORK2,A=ABDENDLL,SP=0,MF=(E,(1))             04848421
         LTR   RF,RF               WAS CONDITIONAL REQUEST SATISFIED    04854221
         BC    7,TTNOTAV           NO,BRANCH                            04860021
         L     RA,ABDENDLL         YES, GET ADDR OF AREA FOR TT         04865821
         ST    RA,ABDFP            COMPUTE NEW TR TBL POINTERS          04871621
         LR    RB,RA                                                    04877421
         L     R0,0(R8)            COMPUTE 2ND TT POINTER               04883221
         S     R0,4(R8)                                                 04889021
         AR    RB,R0                                                    04894821
         ST    RB,ABDCP                                                 04900621
         L     R0,8(R8)            COMPUTE 3RD TT POINTER               04906421
         S     R0,4(R8)                                                 04912221
         AR    R0,RA                                                    04918021
         ST    R0,ABDLP                                                 04923821
*                                                                       04929621
* MOVE TRACE TABLE TO AREA OBTAINED VIA GETMAIN                         04935421
*                                                                       04941221
         L     RB,4(R8)            GET ADDR TO MOVE FROM                04947021
         SR    R8,R8                                                    04952821
         D     R8,TWO56                                                 04958621
         LTR   R9,R9               IS SIZE OF TT GT 256                 04964421
         BC    8,ABD02             NO,BRANCH                            04970221
ABD01    MVC   0(256,RA),0(RB)     YES,MOVE 256 BYTES                   04976021
         LA    RA,256(RA)          BUMP POINTERS                        04981821
         LA    RB,256(RB)                                               04987621
         BCT   R9,ABD01            LOOP                                 04993421
ABD02    LTR   R8,R8               WHOLE TT HAS BEEN MOVED              04999221
         BC    8,ABD03             YES,BRANCH                           05005021
         BCTR  R8,0                NO,MOVE THE REST                     05010821
         EX    R8,ABD28                                                 05020021
ABD03    EQU   *                                                        05040021
* INITIALIZE BSAM DECB                                                  05060021
         L     R6,PDCBPTR    GET DCB ADDRESS FROM PARLIST               05080021
         LA    R7,ABDCC-8               PTR TO OUTPUT LINE              05100021
         STM   R6,R7,ABDDCB             BSAM PARAMETERS TO DECB         05120021
         SR    R9,R9                    PTR TO BUFFER SET TO ZERO       05140021
         TM    DVTYPE(R6),X'48'         TEST, BR, IF OUTPUT DEVICE      05160021
         BC    14,ABD004                IS NOT A PRINTER                05180021
* DEVICE IS A PRINTER, ESTABLISH SYNAD.                                 05200021
         LR    RE,R6               SAVE DCB ADDRESS                     05220021
         L     R6,ABDLDADD         LA OF OUTPUT RTN MODULE              05240021
         LA    R1,LDSYNAD          LA OF BR 14 INSTR FOR SYNAD          05240821
         ST    R1,ABDWORK1                                              05240921
         MVC   IOBSYNAD+1(3,RE),ABDWORK1+1  STORE SYNAD ADDR IN DCB     05241021
         B     ABD005                                                   05241821
TTNOTAV  MVI   ABDCP,X'80'         SET TR TBL NOT AVAILABLE SWITCH      05241921
         BC    15,ABD03                                                 05242021
*                                                                       05242821
* A VARIABLE, CONDITIONAL REQUEST IS ISSUED TO OBTAIN A BUFFER FOR      05242921
* BLOCKING.                                                             05243021
ABD004   EQU   *                                                        05243821
         LA    R1,ABDWORK1         LA OF PARAMETER LIST AREA            05243921
         L     RB,ABDWORK              LOAD ADDR OF LIST OF CORE REQ    05244021
*                                      SAVED FROM EARLIER          BLKB 05244821
         GETMAIN VC,LA=(RB),A=ABDPTRS+4,SP=250,MF=(E,(1))     AC A40891 05244921
         LTR   RF,RF                    TEST, BR, IF REQUEST FOR        05245021
         BNE   ABD005              BUFFER NOT SATISFIED                 05245821
         LM    R9,RA,ABDPTRS+4     LOAD PTRS TO BUFFER, SIZE            05245921
         ST    R9,ABDPTR                BUFFER ADDRESS TO DECB          05246021
         LA    RB,0(R9,RA)              END OF BUFFER                   05246821
         LA    RA,4(R9)                 PTR TO NEXT SLOT IN BUFFER      05246921
ABD005   STM   R9,RB,ABDPTRS                                            05247021
*                                                                       05247821
*    ENABLE                                                             05247921
         SSM   SYSMASK                  ENABLE                          05248021
*                                                                       05248821
*  INITIALIZE OUTPUT AREA                                               05248921
*       1)  BSAM PARAMETERS IN DECB ( DCB PTR, AREA ADDRESS ) HAVE      05249021
*           BEEN ESTABLISHED.                                           05249821
*       2)  ESTABLISH RECORD COUNTS PRIOR TO OUTPUT LINE                05249921
*       4)  CLEAR OUTPUT LINE.                                          05254421
*       5) SET LINE COUNT TO 1, PAGE COUNT TO 1.                        05260221
*       6)  STORE POINTER TO PARAMETER LIST IN WORK AREA.               05266021
*                                                                       05271821
* ESTABLISH BSAM RECORD LENGTH FIELDS                                   05277621
         MVC   ABDPHY(8),PHYLOG                                         05283421
         MVI   ABDLINE,C' '                                             05289221
         MVC   ABDLINE+1(119),ABDLINE   CLEAR OUTPUT LINE TO BLANKS     05295021
         MVC   ABDCTR1(L'COUNTS),COUNTS     LINE, PAGE COUNTS           05300821
        ST    R4,ABDPARA               SAVE PTR TO PARAMETER LIST       05306621
*                                                                 20002 05312421
* DETERMINE IF TCAM AND/OR TSO INFO IS TO BE DUMPED               20002 05320021
*                                                                 20002 05340021
         LA    R2,ZERO(R2)              CLEAR HI BYTE OF TCB ADDR 20002 05360021
         NI    ABDWTG2,XFF-DUMPTCAM-DUMPTSO  INITIALIZE TCAM AND  20002 05380021
*                                            TSO 'WHERE TO GO'    20002 05400021
*                                            FLAGS                20002 05420021
         TM    PFLAGS,PFSUPDAT          IS SUP DATA REQUESTED     20002 05440021
         BZ    XCTL                     NO,BRANCH                 20002 05460021
         L     R3,CVTPTR                GET CVT ADDR              20002 05480021
         L     R3,AVTCVTPT(R3)          GET ADDR OF AVT PTR       20002 05500021
         LA    R3,ZERO(R3)         CLEAR TOP BYTE                 M0165 05520021
         LTR   R3,R3               IS TCAM ACTIVE                 M0165 05540021
         BZ    SKIPTCAM            NO,BRANCH                      M0165 05560021
         L     R3,ZERO(R3)              GET AVT ADDR              20002 05560821
         C     R2,AVTTCB(R3)            IS MCP TASK BEING DUMPED  20002 05561621
         BNE   SKIPTCAM                 NO,BRANCH                 20002 05562421
         OI    ABDWTG2,DUMPTCAM         INDICATE DUMP TCAM INFO   20002 05562521
SKIPTCAM EQU   *                                                  20002 05562621
         TM    TCBTSFLG(R2),TSOTASK     IS TSO TASK BEING DUMPED  20021 05562721
         BZ    XCTL                     NO,BRANCH                 20021 05562821
         OI    ABDWTG2,DUMPTSO          INDICATE DUMP TSO INFO    20021 05562921
XCTL     EQU   *                                                  20021 05563021
         LA    RA,NMNXTLD                                               05563821
         LA    RF,ABDWORK                                               05564621
         L     R1,0(RD)            LOAD ADDR OF WORK AREA     AB A40891 05565421
         MVC   ZERO(20,R1),ABDECB   MOVE DCB TO WORK AREA     AB A40891 05565521
         XCTL  EPLOC=(10),SF=(E,(15))                                   05565621
*                                                                       05565721
ABD28    MVC   0(1,RA),0(RB)                                            05565821
SELTASK  ST    R6,ABDSAVE6         SAVE                                 05565921
         L     R6,ABDLDADD         GET ADDRESS OF IEAQAD0A              05566021
         B     LDSEL               BRANCH TO TASK SELECT ROUTINE        05570021
         EJECT                                                          05570821
*                                                                       05571621
*        CONSTANTS                                                      05571721
*                                                                       05571821
         DS    0F                                                       05571921
WORKSIZE DC    AL1(253)           SUB POOL NO.                          05572021
         DC    AL3(317)                                                 05576021
TWO56    EQU   *                                                   BLKB 05580021
MINMAX  DC    A(256)    MINIMUM BUFFER LENGTH FOR BLOCKING              05600021
         DC    A(1632)   MAXIMUM BUFFER LENGTH FOR BLOCKING (13 LINES)  05620021
MINMAX2  EQU   *                                                        05640021
         DC    A(256)      MINIMUM BUFFER LENGTH FOR BLOCKING      BLKB 05660021
         DC    A(882)      ALTERNATE MAXIMUM BUFFER LENGTH         BLKB 05680021
*                          FOR BLOCKING                                 05700021
LOADNAME DC    C'IGC0A05A'                                              05704021
NMNXTLD  DC    C'IGC0C05A'                                              05708021
PHYLOG   DC    H'129'                   PHYSICAL RECORD LENGTH          05708821
         DC    C'  '                    SYSTEM-RESERVED CHARACTER       05709621
         DC    H'125'                                                   05709721
         DC    X'0000'             SYSTEM RESERVED CHARACTER       6900 05709821
SYSMASK  DC    X'FF'                                                    05709921
COUNTS   DC    X'00010001'         LINE/PAGE COUNTER                    05710021
MAJ      DC    C'SYSIEA01'         MAJOR QCB NAME                       05714021
*                                                                       05718021
*                                                                       05718821
**********************************************************              05719621
         DS    0F                                             AB A40891 05719721
SAVESIZE DC    AL1(250)                                       AB A40891 05719821
         DC    AL3(224)                                       AB A40891 05719921
*                                                                       05720021
*       THE FOLLOWING STORAGE IS RESERVED FOR WORKSPACE                 05720121
*                                                                       05720221
         DC    25H'0'                                                   05720321
         IHBDMPA                                                        05720421
         MPCVT                                                          05720521
CVTDSECT DSECT                                                          05720621
         CVT   SYS=VMS                                                  05720721
         EJECT                                                          05720821
         DCBD  DSORG=(PS),DEVD=(PR)                                     05724221
         END                                                            05730021
