AD06     TITLE 'IEAQAD06 / ABDUMP LOAD 7 / IGC0605A'                    00020000
IGC0605A CSECT                                                          00040000
*3529034400-034600,038000                                          1646 00050018
*   THE FOLLOWING IS THE 7TH LOAD OF ABDUMP                             00060000
*STATUS CHANGE LEVEL=0                                                  00080000
*   ROUTINE NAME                                                        00100000
*        IEAQAD06 (ALSO CALLED ABDUMP 7)                                00120000
*   FUNCTION                                                            00140000
*        ABDUMP7 OUTPUTS THE FOLLOWING INFORMATION-                     00160000
*        1) NUCLEUS                                                     00180000
*        2) USER'S REGISTERS                                            00200000
*        3) BLOCKS OF CORE IF STORAGE PARA. IN THE SNAP MACRO           00220000
*        WAS SPECIFIED.                                                 00240000
*   ENTRY POINT NAME-                                                   00260000
*        IGC0605A                                                       00280000
*   ATTRIBUTES-                                                         00300000
*        TYPE IV SVC,SUPERVISOR STATE,REENTRANT                         00320000
*   APPLICABILITY-                                                      00340000
*        OPTION IV.                                                     00360000
*   EXTERNAL REFERENCES--NONE                                           00380000
*   SVC USAGE-                                                          00400000
*        NONE                                                           00420000
*   INPUT                                                               00440000
*        ABDUMP7 IS PASSED TWO POINTERS-                                00460000
*        1) POINTER TO TCB OF THE TASK BEING DUMPED-IN REG 4            00480000
*        2) POINTER TO THE WORK AREA OBTAINED IN ABDUMP1-IN REG 13      00500000
*   OUTPUT                                                              00520000
*        SEE FUNCTION                                                   00540000
*   ENTRY POINTS-                                                       00560000
*        1) PSW                                                         00580000
*             A) ENABLED                                                00600000
*             B) UNDER SUPERVISOR PROTECTION KEY                        00620000
*             C) IN SUPERVISOR MODE                                     00640000
*        2) REGISTERS-                                                  00660000
*             A) REG 4-ADDRESS OF THE TCB BEING DUMPED                  00680000
*             B) REG 13-ADDRESS OF ABDUMP'S WORK AREA                   00700000
*   EXITS-                                                              00720000
*        TO THE WHERE-TO-GO ROUTINE IN IEAQAD0A.                        00740000
*   ERROR MESSAGES-                                                     00760000
*        NONE                                                           00780000
*   TABLE AND CONTROL BLOCKS REFERENCED-                                00800000
*        ABDUMP7 REFERENCES THE FOLLOWING ENTRIES IN THE TCB AND RB     00820000
*        1)TCB                                                          00840000
*        TCBRBP-POINTER TO ACTIVE RB                                    00860000
*        TCBPKF-PROTECTION KEY                                          00880000
*        2)RB .                                                         00900000
*        RBLINK-POINTER TO NEXT RB                                      00920000
*        RBGRSAVE-REGISTER SAVE AREA                                    00940000
*   LIST ORIGINS,TABLES,CONTROL BLOCKS INCLUDED-                        00960000
*        THE FORMAT OF ABDUMP'S WORK AREA IS DESCRIBED BY THE DSECT     00980000
*        NAMED ABDAREA WHICH IS ASSEMBLED AS PART OF EACH MODULE        01000000
*   OPERATION-                                                          01020000
*        ABDUMP7 OUTPUTS THE NUCLEUS IF THE CORRESPONDING               01040000
*         OPTION FLAGS IS SET.THEN THE USER'S REGISTERS ARE             01060000
*        WRITTEN AND A SNAPSHOT FLAG IS TESTED. IF SNAPSHOT IS          01080000
*        REQUESTED I.E. THE STORAGE KEYWORD PARAMETER IS SPECIFIED IN   01100000
*        THE SNAP MACRO INSTRUCTION, THE CORRESPONDING AREAS OF STORAGE 01120000
*        WILL BE WRITTEN. UPON COMPLETION, ABDUMP7 BRANCHES TO THE      01140000
*        WHERE-TO-GO ROUTINE IN IEAQAD0A.                               01160000
*NOTE-THIS MODULE IS CHARACTER CODE DEPENDENT(EBCDIC)                   01180000
         EJECT                                                          01200000
*                                                                       01210020
*        GENERAL REGISTER EQUATES                                       01212020
*                                                                       01214020
R0       EQU   0                                                        01220000
R1       EQU   1                                                        01240000
R2       EQU   4                                                        01260000
R3       EQU   3                                                        01280000
R4       EQU   2                                                        01300000
TCBREG   EQU   4                                                        01320000
R5       EQU   5                                                        01340000
R6       EQU   6                                                        01360000
R7       EQU   7                                                        01380000
R8       EQU   8                                                        01400000
R9       EQU   9                                                        01420000
RA       EQU   10                                                       01440000
RB       EQU   11                                                       01460000
RC       EQU   12                                                       01480000
RE       EQU   14                                                       01500000
RF       EQU   15                                                       01520000
*                                                                       01540000
STARTREG EQU   0                   INPUT REG TO FORMAT ROUT- START ADDR 01560000
FMLNREG  EQU   0                   FREEMAIN SUBPOOL LENGTH REGISTER     01580000
FMADREG  EQU   1                   FREEMAIN ADDRESS REGISTER            01600000
LENREG   EQU   1                   INPUT REG TO FORMAT ROUT- LENGTH     01620000
LNREG    EQU   1                   FOR FORMAT RTN                       01640000
VALIDREG EQU   1                   REG WITH TEST ADDR FOR VALIDITY RTN  01660000
TT1STREG EQU   1                   FIRST TT PTR REG                     01680000
RETREG   EQU   5                   RETURN REG FROM FORMAT ROUTINE       01700000
OUTREG   EQU   5                   RETURN REG FROM OUTPUT ROUTINE       01720000
TTAREG   EQU   6                   TRACE TABLE REG                      01740000
ENDNUCRG EQU   7                   ADDR OF END OF NUC REG               01760000
TTCTRSW  EQU   9                   TT LINE CTR AND SWITCH               01780000
LISTREG  EQU   9                                                        01800000
VRTNREG  EQU   10                  PTR TO VALIDITY CHECK RTN            01820000
VRETREG  EQU   12                  RETURN REG FROM VALIDITY CHECK RTN   01840000
THREE    EQU   3                                                        01850021
NINE     EQU   9                                                        01852021
*                                                                       01854020
*  IF VRETREG IS 12, REESTABLISH ADDRESSABILITY                         01860000
*                                                                       01870020
BASEREG  EQU   12                                                       01880000
RD       EQU   13                                                       01900000
PARREG   EQU   14                  PARAMETER LIST REGISTER              01920000
CVTREG   EQU   15                                                       01940000
*                                                                       01960000
*        FLT POINT REGS DISPLACEMENTS                                   01980000
*                                                                       01990020
TCBFRS0  EQU   0                                                        02000000
TCBFRS2  EQU   8                                                        02020000
TCBFRS4  EQU   16                                                       02040000
TCBFRS6  EQU   24                                                       02060000
TCBGRS   EQU   48                                                       02080000
*                                                                       02082020
*        GENERAL EQUATES                                                02090020
*                                                                       02090420
ZERO     EQU   0                                                 A31207 02090820
TCBRBP   EQU   0                                                        02100000
FOUR     EQU   4                                                        02110021
PQEREGN  EQU   24                                                       02112021
PQESIZE  EQU   20                                                       02114021
PQEPTR   EQU   8                                                        02116021
DPQEPTR  EQU   152                                                      02118021
TCBPKF   EQU   28                                                       02120000
RBLINK   EQU   28                                                       02140000
RBGRSAVE EQU   32                                                       02160000
TSOTCBID EQU   148                 OFFSET OF TSO FLAG INTO TCB    20A72 02170020
DPQEOFST EQU   152                 DUMMY PQE OFFSET INTO TCB      20A72 02172020
EXIT     EQU   3                                                        02180000
BADSNAP  EQU   12                  INVALID SNAPSHOT ADDR OR LENGTH      02200000
NUCSTART EQU   0                   STARTING ADDR OF NUCLEUS             02220000
SCVTRPTR EQU   X'40'               DISP. TO TT POINTERS          A33745 02240020
DBLSP    EQU   C'0'                DOUBLE SPACE CHAR.                   02260000
SS       EQU   6                   INDENTATION FACTOR                   02280000
TTFLGON  EQU   X'80'               INDICATE THAT TT BEING PROCESSED     02300000
TCBJST   EQU   X'7C'                                                    02310021
TTFLGRES EQU   X'7F'              USED TO RESET TT FLAG                 02320000
*                                                                       02340000
*        EXECUTABLE CODE                                                02350020
*                                                                       02352020
         BALR  BASEREG,0           ESTABLISH                            02360000
         USING *,BASEREG           *ADDRESSABILITY                      02380000
         USING ABDAREA,RD          SET UP COMMON AREA DSECT             02400000
         USING CVTDSECT,CVTREG     SET UP CVT DSECT                     02420000
         USING PARDSECT,PARREG     SET UP DSECT FOR PARAMETER LIST      02440000
         L     PARREG,ABDPARA      LOAD PTR TO PARAM LIST               02460000
         TM    PFLAGS,PFNUC        IS NUCLEUS TO BE PRINTED             02480000
         BC    8,NOMORE      NO,BRANCH                                  02500000
         MVC   ABDCC(L'NUCMSS),NUCMSS   MOVE IN 'NUCLEUS' TITLE         02520000
         BAL   OUTREG,ABDOUT       PRINT IT                             02540000
         L     CVTREG,CVTPTR       LOAD PTR TO CVT                      02560000
         L     PARREG,ABDPARA      LOAD PTR TO PARAM LIST               02580000
         TM    ABDCP,TTSWIT        IS TRACE TABLE TO BE PRINTED         02600000
         L     TTAREG,CVTABEND     GET ABEND'S CVT ADDRESS       A33745 02620020
         L     TTAREG,SCVTRPTR(TTAREG) GET ADDR OF TT POINTERS   A33745 02630020
         BZ    RELATEST            YES, GO AROUND TT AVAILABLE TESTING  02640000
         LTR   TTAREG,TTAREG       NO, THEN IS TRACE TABLE AVAILABLE    02660000
         BNE   RELATEST            YES, GO AROUND PRINT-NUC-AND-RETURN  02680000
         LA    RETREG,LSQSCHK      SET UP RETN FROM 2 LEVELS  AB A49830 02700021
*                                  OF BRANCHES                          02710021
         B     NUCPRINT            FORMAT AND PRINT NUCLEUS             02720000
         USING TTDSECT,TTAREG      SET UP TRACE TABLE DSECT             02740000
RELATEST L     TT1STREG,FPDISP     LOAD FIRST TT PTR                    02760000
         L     ENDNUCRG,CVTNUCB    LOAD LENGTH+1 OF NUCLEUS             02780000
         LA    RETREG,TTTEST       SET UP RET. FROM 2 LEVELS OF BRANCH  02800000
         CR    TT1STREG,ENDNUCRG   IS TT COMPLETELY ABOVE NUCLEUS       02820000
         BNL   NUCPRINT            YES,FORMAT AND PRINT NUCLEUS         02840000
         LA    STARTREG,NUCSTART   LOAD STARTING ADDR OF NUCLEUS        02860000
         TM    CVTDCB,CVTDCBMP     IS THIS AN M65MP?               MP0C 02862017
CVTDCBMP EQU   X'04'               MASK 00000100                   MP0C 02864017
         BZ    NOMP                NO, SKIP NUC START ADJUSTMENT   MP0C 02866017
         AH    STARTREG,CH4096     YES, START NUC ABOVE PSA        MP0C 02868017
         SR    TT1STREG,STARTREG       REDUCE SIZE OF NUC BY PSA S MPOC 02872017
NOMP     EQU   *                                                   MPOC 02875017
         MVI   ABDCC,DBLSP         DOUBLE SPACE                         02880000
         BAL   RETREG,FORMAT       GO PRINT NUCLEUS ONLY UP TO ORIG. TT 02900000
TTTEST   EQU   *                                                        02920000
         C     ENDNUCRG,LPDISP     IS TT AT END OF NUCLEUS              02940000
         BNH   LSQSCHK             YES, SKIP PRINT NUC CONT       20A72 02960020
         MVC   ABDCC(L'NUCMSS+L'CONTMSS),NUCMSS  MOVE NUC CONT TITLE    02980000
         BAL   OUTREG,ABDOUT       PRINT IT                             03000000
         LR    LENREG,ENDNUCRG     CALCULATE LENGTH OF NUC CONT=        03020000
         S     LENREG,LPDISP       *(ENDNUC+1)-(ENDTRACE+1)             03040000
         L     STARTREG,LPDISP     NUC CONT. STARTING ADDR              03060000
         MVI   ABDCC,DBLSP         DOUBLE SPACE                         03080000
         BAL   RETREG,FORMAT       FORMAT REST OF NUCLEUS               03100000
LSQSCHK  EQU   *                                                  20A72 03110020
         TM    TSOTCBID(TCBREG),X'80'   Q. TSO TASK               20A72 03112020
         BZ    NOMORE               NO. CONTINUE NORMAL PROC      20A72 03114020
         MVC   ABDCC(L'LSQSMSG),LSQSMSG  YES. PRINT LSQS HEADING  20A72 03116020
         BAL   OUTREG,ABDOUT        TO OUT PUT ROUTINE            20A72 03118020
         L     LENREG,DPQEOFST(TCBREG)  GET DUMMY PQE PTR         20A72 03118420
         L     STARTREG,0(LENREG)   GET START OF LOCAL SQS        20A72 03118820
         L     LENREG,4(LENREG)     GET LENGTH OF LOCAL SQS       20A72 03119220
         BAL   RETREG,FORMAT        FORMAT AND OUTPUT LOCAL SQS   20A72 03119620
NOMORE   EQU   *                                                        03120000
*                                                                       03140000
*   REGS AT ENTRY TO ABEND/SNAP                                         03160000
*                                                                       03180000
         L     PARREG,ABDPARA      LOAD PTR TO PARAM LIST               03200000
         TM    PFLAGS+1,PFREGS     ARE REGS AT ENTRY TO (-) WANTED      03220000
         BZ    ENDREGS             NO, SKIP 'REGS' CODE                 03240000
         MVC   ABDCC(L'MESS2),MESS2                                     03260000
         TM    PFLAGS,PFABEND      ... AT ENTRY TO ABEND                03280000
         BZ    PRINTMES            YES, SKIP 'ABEND' TO 'ABDUMP' CHANGE 03300000
         MVC   ABDLINE+17(L'MESS2A),MESS2A  CHANGE 'ABEND' TO 'ABDUMP'  03320000
PRINTMES BAL   R5,ABDOUT           PRINT MESSAGE                        03340000
         MVI   ABDCC,C'0'          RESET CARR CTRL CHAR                 03360000
         MVC   ABDLINE+5(L'MESS5),MESS5                                 03380000
         LR    R1,TCBREG           GET FLT POINT REGS ADDRESS           03400000
         S     R1,FORMAT32                                              03420000
         TM    ABDWTG,PFTCB   IS TCB ADDR GIVEN                    1646 03450018
         BC    1,GTCB              YES,BRANCH                           03480000
*********************************************************************   03500000
* THE FOLLOWING  IS FLOATING POINT STORE                                03520000
*********************************************************************   03540000
         STD   0,TCBFRS0(R1)                                            03560000
         STD   2,TCBFRS2(R1)                                            03580000
         STD   4,TCBFRS4(R1)                                            03600000
         STD   6,TCBFRS6(R1)                                            03620000
GTCB     EQU   *                                                        03640000
         LA    R3,FLPLINE          GET LAYOUT LINE ADDRESS              03660000
         LA    R4,TCBFRS0(R1)      GET FLT POINT REGS ADDRESS           03680000
         BAL   RB,UNPACK     FORMAT FLT POINT REGS                      03700000
OUT      BAL   R5,ABDOUT           OUTPUT FLT POINT REGS                03720000
         MVI   ABDCC,C'0'                                               03740000
         MVC   ABDLINE+5(L'MESS3),MESS3                                 03760000
         L     PARREG,ABDPARA      GET ADDRESS OF THE PARAM. LIST       03780000
         TM    ABDWTG,PFTCB        IS TCB ADDR GIVEN               1646 03800018
         BC    8,CURRTCB           NO,CURRENT TCB                       03820000
         LA    R4,TCBGRS(TCBREG)   YES,GET REG SAVE AREA ADDRESS        03840000
         B     REGS1                                                    03860000
CURRTCB  EQU   *                                                        03880000
         L     R1,ABDCRB           GET ABDUMP'S SVRB ADDRESS            03900000
         TM    PFLAGS,PFABEND      ABEND'S OR ABDUMP'S SVRB             03920000
         BO    DUMPSVRB            ABDUMP'S SVRB - SKIP NEXT INST       03940000
         L     R1,RBLINK(R1)       GET ADDR OF ABEND'S SVRB             03960000
DUMPSVRB LA    R1,0(R1)            ZERO HIGH BYTE                       03980000
         LA    R4,RBGRSAVE(R1)     GET ADDR OF SVRB'S REG SAVE AREA     04000000
REGS1    LA    R3,LAYOUT           GET LAYOUT LINE ADDRESS              04020000
         BAL   RB,UNPACK                                                04040000
         L     R6,ABDSAVE6                                              04060000
         BAL   R5,ABDOUT           OUTPUT 1ST 8 REGS                    04080000
         MVC   ABDLINE+5(L'MESS4),MESS4                                 04100000
         LA    R3,LAYOUT           GET ADDR OF LAYOUT LINE              04120000
         BAL   RB,UNPACK                                                04140000
         L     R6,ABDSAVE6                                              04160000
         BAL   R5,ABDOUT           OUTPUT 2ND 8 REGS                    04180000
ENDREGS  EQU   *                                                        04200000
         L     PARREG,ABDPARA      LOAD PTR TO PARAM LIST               04220000
         TM    PFLAGS,PFSNAP       IS SNAP LIST PRESENT                 04240000
         L     LISTREG,PSNAPPTR   LOAD PTR TO SNAPSHOT LIST             04260000
         BZ    ENDSNAP             NO, SKIP CODE                        04280000
*                                                                       04300000
*  SNAPSHOT CODE                                                        04320000
*                                                                       04340000
         MVC   ABDCC(L'SNAPMESS),SNAPMESS                               04360000
         BAL   OUTREG,ABDOUT       PRINT HEADING                        04380000
         MVI   ABDCC,C'0'          DOUBLE SPACE                         04400000
SNAPLOOP L     LNREG,0(LISTREG)   LOAD 1ST OR NEXT STARTING ADDR        04420000
         BAL   RETREG,VALRTN      VALIDITY CHECK STARTING ADDR          04440000
         L     STARTREG,0(LISTREG)     INIT STARTING REGISTER      7480 04460017
         L     LNREG,4(LISTREG)   LOAD CORRESPONDING ENDING ADDR        04480000
         LA    LNREG,0(LNREG)     ZERO HIGH BYTE                        04500000
         BAL   RETREG,VALRTN      VALIDITY CHECK ENDING ADR             04520000
         L     LNREG,4(LISTREG)        RESTORE LENGTH REGISTER     7480 04530017
         LA    LNREG,0(LNREG)                                      7480 04535017
         S     LNREG,0(LISTREG)   GET LENGTH-1                          04540000
         BL    NEXTTEST           STARTING ADDR GT ENDING ADDR          04560000
         LA    LNREG,1(LNREG)     PLUS 1 = LENGTH                       04580000
         BAL   RETREG,FORMAT      FORMAT USER REQUEST                   04600000
NEXTTEST TM    4(LISTREG),X'80'   WAS LAST PAIR FINAL PAIR              04620000
         LA    LISTREG,8(LISTREG)  INITIALIZE FOR NEXT PAIR             04640000
         MVI   ABDCC,C'0'          DOUBLE SPACE FOR NEXT SNAPSHOT       04660000
         BZ    SNAPLOOP            NO, CONTINUE                         04680000
ENDSNAP  EQU   *                                                        04700000
         USING LDDSECT,R6          SET UP REENTRANT CODE DSECT          04720000
         L     R6,ABDLDADD         LOAD ADDR OF REENTRANT CODE          04740000
         B     LDWTG               GO TO 'WHERE TO GO '                 04760000
NUCPRINT LA    STARTREG,NUCSTART   LOAD STARTING ADDR OF NUCLEUS        04780000
         L     LENREG,CVTNUCB      LOAD LENGTH+1 OF NUCLEUS             04800000
         TM    CVTDCB,CVTDCBMP     IS THIS AN M65MP?               MP0C 04803017
         BZ    NOM65MP             NO, SKIP NUC START ADJUSTMENT   MP0C 04806017
         AH    STARTREG,CH4096     YES, START NUC ABOVE PSA        MP0C 04809017
         SR    LENREG,STARTREG         REDUCE SIZE OF NUC BY PSA   MPOC 04812017
NOM65MP  EQU   *                                                   MPOC 04815017
         MVI   ABDCC,DBLSP         DOUBLE SPACE                         04820000
         B     FORMAT              FORMAT NUCLEUS                       04840000
VALRTN   L     CVTREG,CVTPTR      LOAD PTR TO CVT                       04860000
         L     CVTREG,CVTMZ00     LOAD MAX MACHINE SIZE                 04880000
         CR    LNREG,CVTREG       IS ADDR GT MAXIMUM                    04900000
         BH    NEXTTEST           YES, GO TO NEXT TEST                  04920000
         CLI   TCBPKF(R2),0       IS PROTECT KEY OF REQUESTOR = 0       04940000
         BCR   8,RETREG           YES,RETURN                            04960000
         SR    RE,RE              ZERO A WORK REG                       04980000
         C     LNREG,ZERO(LISTREG)  IS THIS START ADDR           A31207 04981020
         BNH   STARTADR           YES,DO NOT SUBTRACT ONE        A31207 04982020
         BCTR  LNREG,ZERO         ALLOW SNAP TO END OF 2K BLOCK  A31207 04983020
STARTADR EQU   *                                                 A31207 04984020
         L     RE,TCBJST(R2)       GET JOBSTEP TCB            AB A46234 05034021
         L     RE,DPQEPTR(RE)      GET DPQE POINTER           AB A46234 05084021
DOWNPQE  EQU  *                                               AB  M2090 05130021
         L     RE,PQEPTR(RE)       GET PQE POINTER            AB A46234 05134021
         L     R7,PQESIZE(RE)      GET SIZE OF REGION         AB  M2090 05136021
         L     RF,PQEREGN(RE)      GET ADDR OF REGION         AB A46234 05138021
         LA    R7,ZERO(R7)         CLEAR HI BYTE              AB  M2090 05138421
         LA    RF,ZERO(RF)         CLEAR HIGH BYTE            AB A46234 05138821
         AR    R7,RF               COMPUTE END OF REGION      AB  M2090 05139221
         LA    LENREG,ZERO(LENREG) CLEAR HI BYTE              AB A46234 05139621
* THE FOLLOWING CODE TESTS THE ADDRESSES PASSED TO SEE IF THEY ARE      05139721
* IN THE BOUNDS OF THE USERS PARTITION                                  05139821
         CR    LENREG,RF           IS ADDR BELOW PARTITION    AB A46234 05139921
         BNL   ENDIT               NO. CONTINUE TEST          AB A46234 05146621
         B     NEXTPQE             YES. TEST FOR MORE         AB  M2090 05148621
ENDIT    EQU   *                                              AB A46234 05150621
         CR    LENREG,R7           OUT OF USERS REGION        AB  M2090 05152621
         BCR   12,RETREG           NO.                        AB  M2090 05153021
NEXTPQE  EQU   *                                              AB  M2090 05153121
         NC   NINE(THREE,RE),NINE(RE)      LAST PQE?          AB  M2090 05153221
         BNZ  DOWNPQE                    NO.                  AB  M2090 05163321
         B    NEXTTEST                   YES. GO TO NEXT TEST AB  M2090 05165321
*********************************************************************   05166621
         USING LDDSECT,R6          SET UP REENTRANT CODE DSECT          05173321
FORMAT   ST    R6,ABDSAVE6         SAVE LINKAGE REGISTER 6              05180000
         L     R6,ABDLDADD         LOAD ADDR TO REENTRANT CODE          05200000
         B     LDFORMET            GO TO FORMET RTN                     05220000
FORMAT1  L     R6,ABDLDADD         GET ADDRESS OF IEAQAD0A MODULE       05240000
         B     LDFORMAT            BRANCH TO FORMAT ROUTINE             05260000
UNPACK   ST    R6,ABDSAVE6         SAVE LINKAGE REG 6                   05280000
         L     R6,ABDLDADD         LOAD ADDR TO REENTRANT CODE          05300000
         B     LDUNPACK+8          GO TO UNPACK ROUTINE                 05320000
ABDOUT   ST    R6,ABDSAVE6         SAVE LINKAGE REGISTER 6              05340000
         L     R6,ABDLDADD         LOAD ADDR TO REENTRANT CODE          05360000
         B     LDOUTPUT            GO TO OUTPUT RTN                     05380000
**********************************************************************  05400000
*        CONSTANTS                                                      05420000
**********************************************************************  05440000
         DS    0F                                                       05460000
MASK     DC    X'FFFFFFF0'         MASK TO TURN OFF LO ORDER 4 BITS 149 05480000
SPTRACE  DC    X'FD000000'         SUBPOOL NUMBER OF MOVED TRACE TABLE  05500000
CH4096   DC    H'4096'             SIZE OF M65MP'S PSA             MP0C 05510017
FORMAT32 DC    F'32'                                                    05520000
LNLENGTH EQU   FORMAT32            LENGTH OF LINE IN TRACE TABLE        05540000
MESS2    DC    C'-REGS AT ENTRY TO ABEND'                               05560000
MESS2A   DC    C'SNAP '                                                 05580000
MESS3    DC    C'REGS 0-7'                                              05600000
MESS4    DC    C'REGS 8-15'                                             05620000
MESS5    DC    C'FLTR 0-6'                                              05640000
NUCMSS   DC    C'-NUCLEUS'                                              05660000
CONTMSS  DC    C' CONT.'                                                05680000
TRACEMSS DC    C'-TRACE TABLE'                                          05700000
NOTTCORE DC    C'-NO CORE AVAIL. FOR MOVING'                            05720000
NOTT2    DC    C'TRACE TABLE'                                           05740000
SNAPMESS DC    C'-STORAGE'                                              05760000
LSQSMSG  DC    C'-LOCAL SQS'                                      20A72 05770020
LAYOUT   DC    X'1303'                                                  05780000
         DC    X'1E03'                                                  05800000
         DC    X'2903'                                                  05820000
         DC    X'3403'                                                  05840000
         DC    X'4703'                                                  05860000
         DC    X'5203'                                                  05880000
         DC    X'5D03'                                                  05900000
         DC    X'6803'                                                  05920000
         DC    X'FF'                                                    05940000
FLPLINE  DC    X'1303'                                                  05960000
         DC    X'1B03'                                                  05980000
         DC    X'2903'                                                  06000000
         DC    X'3103'                                                  06020000
         DC    X'4703'                                                  06040000
         DC    X'4F03'                                                  06060000
         DC    X'5D03'                                                  06080000
         DC    X'6503'                                                  06100000
         DC    X'FF'                                                    06120000
*                                                                       06140000
**********************************************************************  06160000
*        DSECTS                                                         06180000
**********************************************************************  06200000
TTDSECT  DSECT                                                          06220000
TTSWIT   EQU   X'80'               SWITCH IF SET MEANS DONT PRINT TT    06240000
CPDISP   DS    1F                  DISP FROM PTR2PTRS TO CURRENT PTR    06260000
FPDISP   DS    1F                  DISP FROM PTR2PTRS TO FIRST PTR      06280000
LPDISP   DS    1F                  DISP FROM PTR2PTRS TLAST PTR         06300000
*                                                                       06320000
         IHBDMPA                                                        06340000
CVTDSECT DSECT                                                          06360000
         CVT   SYS=VMS                                                  06380000
         END                                                            06400000
