AD0A     TITLE 'IEAQAD0A / ABDUMP LOAD 10 (RESIDENT LOAD) / IGC0A05A'   00020021
IGC0A05A CSECT                                                          00040021
*3025112200-112600                                                 0430 00044021
*THE FOLLOWING LINE REFERS TO STATEMENTS THAT WERE DELETED FROM THIS    00048021
*MODULE BECAUSE OF THE CREATION OF A NEW MODULE (IEAQAD0C).             00052021
*3025103000-103200,120200-120400,135490-135550                          00056021
*   THE FOLLOWING IS THE 10TH (NON-TRANSIENT) LOAD OF ABDUMP            00060021
*STATUS CHANGE LEVEL=0                                                  00080021
*   ROUTINE NAME-                                                       00100021
*        IEAQAD0A                                                       00120021
*   FUNCTION-                                                           00140021
*        IEAQAD0A CONSISTS OF REENTRANT ROUTINES AS FOLLOWS-            00160021
*        A) OUTPUT ROUTINE                                              00180021
*        B) TWO DIFFERENT FORMAT ROUTINES                               00200021
*        C) WHERE TO GO ROUTINE                                         00220021
*        D) UNPACK ROUTINE                                              00240021
*        E) TASK SELECT ROUTINE.                                        00260021
*        F) EBCDIC TRANSLATE ROUTINE.                                   00280021
*        EACH OF THE ABOVE IS USED BY ALL MODULES OF ABDUMP TO          00300021
*        PERFORM AN I/O OPERATION, FORMAT A LINE, AND TO DETERMINE      00320021
*        THE SEQUENCE IN WHICH THE MODULES OF ABDUMP SHOULD BE          00340021
*        EXECUTED. THE TASK SELECT ROUTINE IS USED TO SCAN THE          00360021
*        FAMILY OF TASKS.                                               00380021
*   ENTRY POINT NAME-                                                   00400021
*        IGC0A05A                                                       00420021
*   ATTRIBUTES-                                                         00440021
*        SUPERVISOR STATE,REENTRANT,NON-TRANSIENT                       00460021
*   APPLICABILITY-                                                      00480021
*        OPTION IV.                                                     00500021
*   EXTERNAL REFERENCES--NONE                                           00520021
*   SVC USAGE-                                                          00540021
*             1) XCTL                                                   00560021
*             FREEMAIN SP 253                                           00580021
*             3) DEQ                                                    00600021
*             4) DELETE                                                 00620021
*             5) EXIT                                                   00640021
*   INPUT-                                                              00660021
*        SEE REGISTERS UNDER 'ENTRY POINTS'.                            00680021
*   OUTPUT-                                                             00700021
*        IEAQAD0A PRODUCES PRINTABLE HEX-FORMATTED RECORDS AND          00720021
*        OUTPUTS THEM ON THE USER'S DATA SET.                           00740021
*   ENTRY POINTS-                                                       00760021
*        1) PSW                                                         00780021
*             A) ENABLED                                                00800021
*             B) UNDER SUPERVISOR PROTECTION KEY                        00820021
*             C) IN SUPERVISOR MODE                                     00840021
*        2) REGISTERS-                                                  00860021
*             A) REG 4-ADDRESS OF THE TCB BEING DUMPED                  00880021
*             B) REG 13-ADDRESS OF ABDUMP'S WORK AREA                   00900021
*        IEAQAD0A IS LOADED BY IEAQAD00 AND IS                          00920021
*        ENTERED BY ALL MODULES OF ABDUMP AT THE FOLLOWING ENTRY POINTS 00940021
*        1) FORMAT - WHENEVER A LABELED FIELD IS TO BE FORMATTED        00960021
*        2) FORMET - WHENEVER AN UNLABELED BLOCK OF CORE IS TO BE       00980021
*        FORMATTED AND WRITTEN                                          01000021
*        3) OUTPUT - WHEN A PRINTABLE RECORD IS TO BE WRITTEN           01020021
*        4) WHERETOG - WHEN A SEQUENCE OF EXECUTION OF ABDUMP'S MODULES 01040021
*        IS TO BE DETERMINED.                                           01060021
*        5) FORMAT20- WHEN A LINE CONSISTING OF 4-BYTE FIELDS IS TO BE  01080021
*        UNPACKED AND FORMATTED.                                        01100021
*        6) SELTASK-TASK SELECT ROUTINE                                 01120021
*        1) UPON ENTRY TO FORMAT, REGISTER 3 POINTS TO THE LAYOUT LINE  01140021
*        WHICH DETERMINES THE LAYOUT OF LABELS AND FIELDS WITHIN A 120- 01160021
*        BYTE LINE. REGISTER 2 CONTAINS THE ADDRESS OF THE FIELD TO BE  01180021
*        FORMATTED.                                                     01200021
*        2) UPON ENTRY TO FORMET-                                       01220021
*        A) REG 0 CONTAINS STARTING ADDRESS OF THE BLOCK OF CORE TO BE  01240021
*        FORMATTED AND WRITTEN.                                         01260021
*        B) REG 1 CONTAINS THE SIZE (IN BYTES) OF THE BLOCK             01280021
*        3) UPON ENTRY TO OUTPUT-                                       01300021
*        A) REG 13 CONTAINS THE ADDRESS OF ABDUMP'S WORK AREA. THE DECB 01320021
*        AND POINTERS/COUNTERS USED BY THIS ROUTINE ARE ADDRESSABLE BY  01340021
*        MEANS OF A DSECT STATEMENT                                     01360021
*        4) UPON ENTRY TO FORMAT20-                                     01380021
*        A) REG 3 POINTS TO THE LAYOUT LINE WHICH DETERMINES THE        01400021
*        DISTANCE BETWEEN THE 4-BYTE FIELDS                             01420021
*        B) REG 2 CONTAINS THE ADDRESS OF THE FIRST FIELD TO BE         01440021
*        UNPACKED INTO THE OUTPUT LINE (ABDLINE)                        01460021
*   EXIT-                                                               01480021
*        1) RETURNS TO THE CALLER VIA A BRANCH INSTRUCTION              01500021
*        2) UPON COMPLETION OF ABDUMP'S OPERATION,RETURNS TO SUPER-     01520021
*        VISOR VIA SVC 3                                                01540021
*   ERROR MESSAGES-                                                     01560021
*        NONE                                                           01580021
*   TABLE AND CONTROL BLOCKS REFERENCED-                                01600021
*        NONE                                                           01620021
*   LIST ORIGINS,TABLES,CONTROL BLOCKS INCLUDED-                        01640021
*        THE FORMAT OF ABDUMP'S WORK AREA IS DESCRIBED BY THE DSECT     01660021
*        NAMED ABDAREA WHICH IS ASSEMBLED AS PART OF EACH MODULE        01680021
*   OPERATION-                                                          01700021
*        1) FORMAT. THIS FORMAT ROUTINE IS USED WHENEVER A LABELED      01720021
*        FIELD IS TO BE FORMATTED. THIS IS DONE BY MEANS OF THE LAYOUT  01740021
*        LINES. THE FIRST BYTE OF EACH LAYOUT LINE, CALLED INDENTATION  01760021
*        FACTOR, DETERMINES HOW MANY BYTES FROM THE BEGINNING OF A      01780021
*        LINE (ABDLINE)  A PARTICULAR LABELED FIELD SHOULD START. EACH  01800021
*        LABEL IS PRECEEDED WITH THE FOLLOWING 2 BYTES OF INFORMATION-  01820021
*        X'ABCD', WHERE A = LENGTH OF THE LABEL MINUS ONE B = LENGTH OF 01840021
*        THE FIELD MINUS ONE C = THE NUMBER OF BYTES TO BE ADDED TO     01860021
*        REG 4 TO POINT TO THE RIGHT FIELD D = NUMBER OF BYTES WHICH    01880021
*        SEPARATE A LABEL FROM THE FIELD WHICH FOLLOWS. TO ENSURE       01900021
*        APPROPIATE OPERATION OF THIS ROUTINE REG 3 AND REG 4 MUST      01920021
*        POINT TO THE LAYOUT LINE AND THE FIELD TO BE FORMATTED         01940021
*        RESPECTIVELY. HEX X'FF' INDICATES THE END OF THE LINE AND IS   01960021
*        USED AS A DELIMITER.                                           01980021
*        2) FORMET. THIS FORMAT ROUTINE IS USED WHENEVER A BLOCK OF     02000021
*        CORE IS TO FORMATTED AND WRITTEN. UPON ENTRY THE SIZE OF A     02020021
*        BLOCK IS ROUNDED DOWN TO THE MULTIPLE 032 AND THEN DIVIDED BY  02040021
*        32 TO OBTAINED A NUMBER OF COMPLETE (32-BYTE) LINES, AND       02060021
*        THE NUMBER OF BYTES IN AN INCOMPLETE LINE. FOR LOOP CONTROL    02080021
*        PURPOSES THE FIRST VALUE IS KEPT IN REG 10. AFTER REG 10 HAS   02100021
*        BEEN REDUCED TO ZERO, AND AN INCOMPLETE LINE (IF ANY) HAS BEEN 02120021
*        FORMATTED AND WRITTEN, CONTROL IS RETURNED TO THE CALLER. TO   02140021
*        DETERMINE THE DISPLACEMENT BETWEEN TWO CONSECUTIVE WORDS A     02160021
*        LAYOUT LINE CONSISTING OF 2 BYTES OF INFORMATION IS USED AS    02180021
*        FOLLOWS-                                                       02200021
*        A) 1ST BYTE = DISPLACEMENT FROM THE BEGINNING OF A LINE        02220021
*        B) 2ND BYTE = NUMBER OF BLANKS BETWEEN 2 CONSECUTIVE FIELDS.   02240021
*        HEX X'FF' IS USED TO RETURN TEMPORARILY TO THE MAIN ROUTINE    02260021
*        AND TO SIGNIFY AN END OF LINE.                                 02280021
*        IF CORE BLOCKS ARE BEING FORMATTED AND PRINTED, AN EBCDIC      02300021
*        TRANSLATION IS PERFORMED TO ALLOW THE USER TO EASILY LOCATE    02320021
*        VARIOUS FIELDS IN THE DUMP.                                    02340021
*   OUTPUT                                                              02360021
*        OUTPUT ROUTINE USES WRITE AND CHECK MACROS TO PRINT A LINE IF  02380021
*        THE DEVICE IS A PRINTER OR TO WRITE A BLOCK OF CORE IF THE     02400021
*        DEVICE IS A TAPE OR A DIRECT ACCESS DEVICE AND A CONDITIONAL   02420021
*        GETMAIN REQUESTING CORE FOR BLOCKING WAS SATISFIED.            02440021
*        THIS ROUTINE ALLOWS 56 LINES PER PAGE AND EJECTS TO A NEW PAGE 02460021
*        WHEN THIS NUMBER HAS BEEN EXCEEDED.                            02480021
*   WHERETOG                                                            02500021
*        THIS ROUTINE XCTL'S TO A LOAD MODULE WHICH CAN SATISFY A       02520021
*        REQUEST SPECIFIED BY THE PARAMETER LIST. AFTER ALL REQUESTED   02540021
*        FUNCTIONS HAVE BEEN PERFORMED, CLEAN-UP CODE IS EXECUTED       02560021
*        AS FOLLOWS-                                                    02580021
*        A) PRINTS END OF DUMP MESSAGE                                  02600021
*        B) FREEMAIN ALL AREAS OBTAINED IN THE FIRST MODULE OF ABDUMP   02620021
*        C) DEQ-REMOVE A QEL GENERATED BY ENQ                           02640021
*        D) DELETES ITSELF BY MOVING 3 INSTRUCTIONS INTO ABDUMP'S SVRB  02660021
*        EXTENDED SAVE AREA                                             02680021
*        E) EXECUTES DELETE AND SVC 3                                   02700021
*   SELTASK                                                             02720021
*        THIS ROUTINE TRACES THE FAMILY OF TASKS AND RETURNS THE        02740021
*        ADDRESS OF THE TCB TO THE CALLER.                              02760021
*NOTE-THIS MODULE IS CHARACTER CODE DEPENDENT(EBCDIC)                   02780021
         EJECT                                                          02800021
         USING *,R6                                                     02820021
         USING ABDAREA,RD                                               02840021
         USING PARDSECT,PARREG                                          02860021
*  NOTE-  R6 IS THE BASE REGISTER. LINKAGE WILL OCCUR BY LOADING R6     02880021
*         WITH PTR TO PROGRAM AND   BALR  R5,R6                         02900021
*        REGISTERS                                                      02920021
R0       EQU   0         ACCUMULATOR                                    02940021
R1       EQU   1         PTR TO PARAMETER LIST                          02960021
TCBREG   EQU   4                                                        02980021
LINKREG  EQU   5             INTERNAL LINK REG                          03000021
PARREG   EQU   14                                                       03020021
R2       EQU   4                                                        03040021
R3       EQU   3         RB PTR                                         03060021
R4       EQU   2                                                        03080021
R5       EQU   5         INTERNAL LINKAGE REGISTER                      03100021
R6       EQU   6         PTR TO CONSTANTS,...                           03120021
R7       EQU   7         PTR TO OUTPUT LINE                             03140021
R8       EQU   8         PTR TO INFO TO BE FORMATTED                    03160021
R9       EQU   9         PTR TO BLOCKING BUFFER                         03180021
TTCTRSW  EQU   9                                                        03200021
RA       EQU   10        WORK REGISTER                                  03220021
XCTLREG  EQU   10        TEMPORARY XCTL EP NAME PARAMETER POINTER 21014 03224021
CVTREG   EQU   10        TEMPORARY CVT DSECT BASE REGISTER        21014 03224821
RB       EQU   11        WORK REGISTER                                  03225621
RC       EQU   12        BASE REGISTER                                  03225721
RD       EQU   13        POINTER TO AREA OBTAINED VIA GETMAIN           03225821
RE       EQU   14                                                       03225921
RF       EQU   15        RETURN CODE REGISTER                           03226021
*                                                                       03230021
SCVTTASW EQU   X'28'                                                    03230821
TTFLGON  EQU   X'80'               FLAG TO SEE IF TT BEING FORMATTED    03231621
FROMFORM EQU   X'40'               FLAG SET IF OUTPUT WAS ENTERED BY FO 03231721
FROMRES  EQU   255-X'40'           BIT TO RESET 'FROMFORM' SETTING      03231821
SKIPRND  EQU   X'20'               FLAG SET IF ROUNDING NOT NECESSARY   03231921
* ABOVE FLAG WAS USED IN AD03-NOT USED NOW-LEFT IN 'LOAD'-NO EXTRA COST 03232021
INDFLG   EQU   X'10'               AD03 - SET IF DEB OR TIOT PROCESSING 03236021
STORFLG  EQU   X'08'    SET IF FORMET REQUEST LT 32 BYTES ON 1 LINE     03240021
TCBRBP   EQU   0                                                        03260021
TCBFLGS  EQU   30                                                       03280021
TCBJSTCB EQU   124                                                      03300021
TCBNTC   EQU   128                                                      03320021
TCBOTC   EQU   132                                                      03340021
TCBLTC   EQU   136                                                      03360021
TCBFX    EQU   X'01'               PREVENT ASYNCHR. EXIT INDICATOR      03380021
TCBADUMP EQU   X'80'         ABDUMP NON-DISP FLAG                       03400021
FINALESZ EQU   6                   SIZE IN BYTES OF INSTRUCTIONS TO EXS 03420021
EXTSA    EQU   96                  DISPLACEMENT TO EXTENDED SAVE AREA   03440021
TTADDR   EQU   84                                                       03460021
CUR      EQU   4                                                        03480021
SS       EQU   6                  INDENTATION FACTOR                    03500021
FLAGS    EQU   0         DISPLACEMENT FROM BEGIN OF PARA.LIST TO FLAGS  03520021
MESG     EQU   X'01'     MASK TO TEST IF MESSAGE TO BE PUT OUT          03540021
DVTYPE   EQU   17        DCB DISPLACEMENT TO DEVICE TYPE                03560021
OFLGS    EQU   48        DCB DISPLACEMENT TO OPEN FLAGS                 03580021
IOBSYNAD EQU   56        DCB DISPLACEMENT TO IOB LENGTH, SYNAD          03600021
OPEN     EQU   X'10'     MASK TO TEST OPEN FLAG                         03620021
SNAPSHOT EQU   X'02'     MASK TO TEST FOR SNAPSHOT REQUEST              03640021
DUMPTCAM EQU   X'80'     MASK TO TEST IF TCAM INFO WANTED         20002 03660021
DUMPTSO  EQU   X'40'     MASK TO TEST IF TSO INFO WANTED          20021 03680021
XFF      EQU   X'FF'                                              20021 03700021
HEX0     EQU   X'00'              ZERO TO INIT FLAG               21014 03720021
HEX07    EQU   X'07'               MASK FOR MAXIMUM OF 7 BLANKS   21014 03740021
* EXTENDED ASA CARRIAGE CONTROL CHARACTERS FOR                          03760021
HDCC     EQU   C'0'                     HEADING LINE                    03780021
COMPCC   EQU   C'0'                     COMPLETION CODE LINE            03800021
PSWCC    EQU   C'0'                     PSW LINE                        03820021
MSGCC    EQU   C'0'                     MESSAGE LINE                    03840021
ZERO     EQU   0                                                        03860021
EIGHT    EQU   8                                                        03880021
SAVEPTR  EQU   92                                                       03900021
LINEPTR  EQU   12                                                       03904021
FOUR     EQU   4                                                        03908021
**********************************************************************  03912021
*        F O R M A T  R O U T I N E                                     03912821
**********************************************************************  03913621
FORMAT   LA    R8,ABDLINE          GET ADDR OF OUTPUT BUFFER            03913721
         SR    R1,R1                                                    03913821
         IC    R1,0(R3)            GET INDENTATION FACTOR               03913921
         AR    R8,R1               UPDATE POINTER                       03914021
         LA    R3,1(R3)                                                 03914821
FORMAT01 CLI   0(R3),X'FF'         IS THIS A DELIMETER                  03915621
         BC    8,FORMAT3           YES,BRANCH                           03915721
         SR    RE,RE                                                    03915821
         SR    RF,RF                                                    03915921
         SR    R0,R0                                                    03916021
         SR    R1,R1                                                    03920021
         IC    RE,0(R3)            GET FIRST CONTROL BYTE               03940021
         IC    R0,1(R3)            GET SECOND CONTROL BYTE              03960021
         SRDL  RE,4                RE=SIZE OF LABEL-1                   03980021
         SRL   RF,28               RF=SIZE OF FIELD -1                  04000021
         SRDL  R0,4                R0=NO. OF BYTES TO BE ADDED TO R4    04020021
         SRL   R1,28               R1=DIST BETWEEN LABEL AND FIELD      04040021
         AR    R4,R0               BUMP POINTER                         04060021
         EX    RE,MOVE1                                                 04080021
         AR    R1,RE                                                    04100021
         LA    R8,1(R1,R8)         UPDATE POINTER                       04120021
         EX    RF,MOVE2                                                 04140021
         UNPK  ABDWORK4(9),ABDWORK4(5)                                  04160021
         TR    ABDWORK4(8),TBL-240                                      04180021
         LA    RF,1(RF,RF)   RF=SIZE OF UNPACKED FIELD                  04200021
         EX    RF,MOVE3                                                 04220021
         B     PATCHGTF            GO CHECK FOR BLANK CHANGE      21014 04240021
RETNPAT  LA    R3,3(RE,R3)         UP POINTER                     21014 04260021
         BC    15,FORMAT01         FORMAT NEXT FIELD                    04280021
FORMAT3  LA    R3,1(R3)                                                 04300021
         B     RETURN              GO TO RETURN ROUTINE                 04320021
MOVE1    MVC   0(1,R8),2(R3)       MOVE LABEL TO OUTPUT BUFFER          04340021
MOVE2    MVC   ABDWORK4(1),0(R4)   MOVE PACKED FIELD TO WORK AREA       04360021
MOVE3    MVC   0(1,R8),ABDWORK4    MOVE UNPACKED FIELD TO OUTPUT BUFFER 04380021
         EJECT                                                          04400021
*********************************************************************   04420021
*        F O R M A T  R O U T I N E                                     04440021
*********************************************************************   04460021
FORMET   ST    R5,ABDWORK2         SAVE LINK REG                        04480021
         ST    R0,ABDSTAD          SAVE STARTING ADDR                   04500021
         NI    ABDSTAD+3,X'FC'     ROUND STARTING ADDR DOWN TO 4 BYTES  04520021
         S     R0,ABDSTAD          GET DIFF BETWEEN ACTUAL AND ROUNDED  04540021
         AR    R1,R0               ADD DIFFERENCE TO LENGTH             04560021
         L     R0,ABDSTAD          INSERT ADDR AGAIN                    04580021
         LA    R1,3(R1)            BEGIN ROUNDING SIZE UP TO 4 BYTES    04600021
         ST    R1,ABDSIZE          SAVE SIZE OF BLOCK                   04620021
         NI    ABDSIZE+3,X'FC'     COMPLETE ROUNDING SIZE UP TO 4 BYTES 04640021
         XC    ABDIND(4),ABDIND    SET ABDIND=0,ABDIDENT=0              04660021
         LR    R1,R0               GET STARTING ADDRESS                 04680021
         N     R0,MASK             ROUND DOWN TO MULT OF 32             04700021
         CR    R0,R1               IS INDENTATION REQUIRED              04720021
         BC    8,FORMAT02          NO,BRANCH                            04740021
         SR    R1,R0               YES,COMPUTE INDENTATION FACTOR       04760021
         STH   R1,ABDIND           SAVE INDENTATION FACTOR              04780021
FORMAT02 L     R1,ABDSIZE          GET SIZE OF BLOCK                    04800021
         AH    R1,ABDIND                                                04820021
         SR    R0,R0                                                    04840021
         D     R0,=F'32'           32 BYTES / LINE                      04860021
         STH   R0,ABDINCPL         R0=NO. OF BYTES IN INCOMPL LINE      04880021
         LTR   R1,R1               ANY COMPL LINES TO BE FORMATTED      04900021
         BC    7,FORMAT05          YES,BRANCH                           04920021
FORMAT03 EQU  *                                                         04940021
         LH    R1,ABDINCPL         NO,GET INCOMPLETE LINE SIZE   A26963 04960021
         LTR   R1,R1               SIZE OF INCOMPLETE LINE=0     A26963 04980021
         BC    7,FORMAT04          NO,BRANCH                            05000021
EXIT     L     R5,ABDWORK2         RESTORE LINK REG                     05020021
RETURN   L     R6,ABDSAVE6         RESTORE LINKAGE REG 6                05040021
         BCR   15,R5               RETURN                               05060021
*                                                                       05080021
*   HANDLE INCOMPLETE LINE                                              05100021
*                                                                       05120021
*                                                                       05140021
FORMAT04 LA    R4,ABDSTAD+1        GET ADDR OF LOC CTR                  05160021
         BAL   RB,FORMAT20         LINK TO UNPACK ROUTINE               05180021
         L     R4,ABDSTAD          GET ADDR OF INCOMPL LINE             05200021
         LA    R3,INCLINE          GET ADDR OF LAYOUT LINE              05220021
         LH    RA,ABDINCPL         GET NO. OF BYTES IN INCOMPL LINE     05240021
         SH    RA,ABDIND                ADD INDENT IF FIRST LINE  19472 05260021
         SRL   RA,2                GET NO. OF WORDS IN INCOMPL LINE     05280021
         BAL   RB,FORMAT22         LINK TO UNPACK ROUTINE               05284021
         BCT   RA,*-4            LOOP                                   05288021
         OI    ABDFORM,FROMFORM    TELL OUTPUT I'M ENTERING             05288821
         BAL   R5,OUTPUT           OUTPUT A LINE                        05289621
         NI    ABDFORM,FROMRES     RESET FOR OTHERS USE                 05289721
         BC    15,EXIT                                                  05289821
FORMAT05 LR    RA,R1               GET NO. OF COMPL LINES FOR LOOP CTRL 05289921
FORMAT06 L     R1,ABDSTAD          GET LINE ADDRESS                     05290021
         SH    R1,ABDIND           ROUND DOWN TO MULT OF 32             05294021
NOTTT    ST    R1,ABDWORK          STORE LOC CTR IN WORK AREA           05298021
         LA    R4,ABDWORK+1        GET ADDR OF LOC CTR                  05298821
         BAL   RB,FORMAT20         LINK TO UNPACK RTN                   05299621
RETFORM  LH    R1,ABDIND           GET INDENTATION FACTOR               05299721
         SRL   R1,1                                                     05299821
         AR    R3,R1               UPDATE POINTER WITHIN LAYOUT LINE    05299921
         L     R4,ABDSTAD          GET ADDR TO UNPACK FROM              05300021
         BAL   RB,FORMAT22         LINK TO UNPACK ROUTINE               05304021
         ST    R4,ABDSTAD          SAVE UPDATED ADDRESS OF NEXT LINE    05308021
         OI    ABDFORM,FROMFORM    TELL OUTPUT I'M ENTERING             05308821
         BAL   R5,OUTPUT           OUTPUT INCOMPLETE LINE               05309621
         NI    ABDFORM,FROMRES     RESET FOR OTHERS USE                 05309721
         LH    R1,ABDIND           GET INDENTATION FACTOR               05309821
         LTR   R1,R1               WAS LAST LINE INDENTED               05309921
        BC    7,FORMAT08          YES,BRANCH                            05310021
         USING CVTDSECT,R1                                              05330021
FORMAT07 EQU   *                                                 A26963 05334021
         NOP   *         PADDING                                 A26963 05338021
         LA    R1,1                HAS THE LAST COMPLETE LINE    A26963 05338821
         CR    R1,RA                BEEN PROCESSED               A26963 05339621
         BNL   FORMAT10      YES,BRANCH-AVOID PROGRAM CHECK             05339721
         LR    R1,R4                                                    05339821
         S     R1,=F'32'           GET ADDR OF LAST LINE                05339921
         CLC   0(32,R1),0(R4)      IS CURRENT LINE SAME AS LAST ONE     05340021
         BC    7,FORMAT10          NO,BRANCH                            05360021
         LH    R1,ABDIDENT         YES,BUMP IDENT LINE CTR              05380021
         LA    R1,1(R1)                                                 05400021
         STH   R1,ABDIDENT                                              05420021
         LA    R4,32(R4)           BUMP THE POINTER TO NEXT LINE        05440021
         ST    R4,ABDSTAD          SAVE ADDR OF NEXT LINE               05460021
         BCT   RA,FORMAT07         COMPARE NEXT LINE                    05480021
         BC    15,FORMAT00                                              05500021
FORMAT08 SR    R1,R1                                                    05520021
         STH   R1,ABDIND           SET INDENTATION FACTOR TO ZERO       05540021
FORMAT09 BCT   RA,FORMAT06         PROCESS  NEXT LINE                   05560021
         BC    15,FORMAT03         ALL COMPL LINE HAVE BEEN PROCESSED   05580021
FORMAT10 LH    R1,ABDIDENT         GET IDENTICAL LINE CTR               05600021
         LTR   R1,R1               ANY IDENTICAL LINES                  05620021
         BC    8,FORMAT09          NO,BRANCH                            05640021
*                                                                       05660021
*   PRINT IDENTICAL LINE(S) MESSAGE                                     05680021
*                                                                       05700021
*   XXXXXX=ABDSTAD-I*32                                                 05720021
*   YYYYYY=ABDSTAD-32                                                   05740021
FORMAT00 L     R1,ABDSTAD          COMPUTE XXXXXX ADDRESS               05760021
         LH    R0,ABDIDENT                                              05780021
         SLL   R0,5                                                     05800021
         SR    R1,R0                                                    05820021
         ST    R1,ABDWORK          STORE XXXXXX ADDR IN WORK AREA       05840021
         LA    R4,ABDWORK+1        GET ADDRESS OF XXXXXX                05860021
         LH    R1,ABDIDENT         GET NO. OF IDENTICAL LINES           05880021
         BCTR  R1,0                                                     05900021
         LTR   R1,R1               ONE IDENTICAL LINE                   05920021
         BC    7,FORMAT12          NO,BRANCH                            05940021
*   PRINT ONE IDENTICAL LINE MESSAGE                                    05960021
         MVC   ABDLINE+SS(4),MESS1                                      05980021
         LA    R3,MSGL1            GET ADDR OF LAYOUT LINE              06000021
         BAL   RB,FORMAT22         LINK TO UNPACK ROUTINE               06020021
         MVC   ABDLINE+SS+11(14),MESS1+5                                06040021
FORMAT11 OI    ABDFORM,FROMFORM    TELL OUTPUT I'M ENTERING             06060021
         BAL   R5,OUTPUT           OUTPUT A LINE                        06080021
         NI    ABDFORM,FROMRES     RESET FOR OTHERS USE                 06100021
         XC    ABDIDENT(2),ABDIDENT  SET IDENT LINE CTR TO ZERO         06120021
         LTR   RA,RA               ALL COMPL LINES PROCESSED            06124021
         BC    8,FORMAT03          YES,BRANCH                           06128021
         BC    15,FORMAT09         NO,BRANCH                            06128821
*   PRINT IDENTICAL LINES MESSAGE                                       06129621
FORMAT12 MVC   ABDLINE+SS(5),MESS1                                      06129721
         LA    R3,MSGL2            GET ADDR OF LAYOUT LINE              06129821
         BAL   RB,FORMAT22         LINK TO UNPACK ROUTINE               06129921
         MVI   ABDLINE+18,C'-'     SEPERATE XXXXXX FROM YYYYYY          06130021
         L     R1,ABDSTAD          COMPUTE YYYYYY ADDRESS               06134021
         S     R1,=F'32'                                                06138021
         ST    R1,ABDWORK          STORE YYYYYYY ADDR IN WORK AREA      06138821
         LA    R4,ABDWORK+1        GET ADDR OF YYYYYY                   06139621
         LA    R3,MSGL3            GET ADDR OF LAYOUT LINE              06139721
         BAL   RB,FORMAT22         LINK TO UNPACK ROUTINE               06139821
         MVC   ABDLINE+SS+19(14),MESS1+5                                06139921
         BC    15,FORMAT11                                              06140021
*********************************************************************   06144021
*   UNPACK ROUTINE                                                      06148021
*********************************************************************   06148821
FORMAT20 LA    R3,LAYOUT           GET ADDR OF LAYOUT LINE              06149621
         B     EBCDIC              GO TO EBCDIC TRANSLATE ROUTINE       06149721
FORMAT22 LA    R8,ABDLINE          GET ADDR OF OUTPUT BUFFER            06149821
FORMAT21 CLI   0(R3),X'FF'         IS THIS A DELIMETER                  06149921
         BC    8,FORMAT23          YES,BRANCH                           06150021
         SR    R0,R0               NO,GET CONTROL BYTES                 06154021
         IC    R0,0(R3)            R0=DISPL FROM BEGIN. OF THE LINE     06158021
         SR    R1,R1                                                    06158821
         IC    R1,1(R3)            R1=SIZE OF FIELD-1                   06159621
         AR    R8,R0               GET ADDR OF FIELD WITHIN A LINE      06159721
         EX    R1,MOVE4            MOVE FIELD TO WORK AREA              06159821
         UNPK  ABDWORK(9),ABDWORK(5)                                    06159921
         TR    ABDWORK(8),TBL-240                                       06160021
         LA    R1,1(R1,R1)   R1=SIZE OF UNPACKED FIELD                  06180021
         EX    R1,MOVE5            MOVE UNPACKED FIELD TO OUTPUT BUFFER 06200021
         LA    R3,2(R3)            BUMP THE POINTERS                    06220021
         LA    R4,4(R4)                                                 06240021
         B     FORMAT22            GO TO UNPACK ROUTINE                 06260021
FORMAT23 LA    R3,1(R3)           BUMP THE PTR                          06280021
         BR    RB                  RETURN                               06300021
**********************************************************************  06320021
*        CONSTANTS                                                      06340021
**********************************************************************  06360021
         DS    0F                                                       06380021
MOVE4    MVC   ABDWORK(1),0(R4)                                         06400021
MOVE5    MVC  0(1,R8),ABDWORK                                           06420021
MASK     DC    X'FFFFFFE0'                                              06440021
MSGL1    DC    X'0B02'                                                  06460021
         DC    X'FF'                                                    06480021
MSGL2    DC    X'0C02'                                                  06500021
         DC    X'FF'                                                    06520021
MSGL3    DC    X'1302'                                                  06540021
         DC    X'FF'                                                    06560021
MESS1    DC    C'LINES SAME AS ABOVE'                                   06580021
*                                                                       06600021
LAYOUT   DC    X'0002'                                                  06620021
         DC    X'FF'                                                    06640021
         DC    X'0903'                                                  06660021
         DC    X'1203'                                                  06680021
         DC    X'1B03'                                                  06700021
         DC    X'2403'                                                  06720021
         DC    X'3003'                                                  06740021
         DC    X'3903'                                                  06760021
         DC    X'4203'                                                  06780021
         DC    X'4B03'                                                  06800021
         DC    X'FF'                                                    06820021
INCLINE  DC    X'0903'                                                  06840021
         DC    X'FF'                                                    06860021
         DC    X'1203'                                                  06880021
         DC    X'FF'                                                    06900021
         DC    X'1B03'                                                  06920021
         DC    X'FF'                                                    06940021
         DC    X'2403'                                                  06960021
         DC    X'FF'                                                    06980021
         DC    X'3003'                                                  07000021
         DC    X'FF'                                                    07020021
         DC    X'3903'                                                  07040021
         DC    X'FF'                                                    07060021
         DC    X'4203'                                                  07080021
         DC    X'FF'                                                    07100021
**********************************************************************  07120021
* OUTPUT ROUTINE                                                        07140021
*      THIS ROUTINE IS USED BY EACH LOAD OF ABDUMP TO WRITE A           07160021
*      PRINTABLE RECORD.  IT IS ASSEMBLED WITH ABDUMP1, BUT IS MOVED    07180021
*      TO AN AREA WITHIN ABDUMP'S WORK AREA(POINTED TO BY REGISTER 13). 07200021
*      WHEN THE ROUTINE GETS CONTROL, A PRINTABLE RECORD IS IN THE AREA 07220021
*      RESERVED FOR AN OUTPUT LINE.                                     07240021
*      IF THE RECORDS ARE NOT TO BE BLOCKED ,I.E.  OUTPUT DEVICE IS A   07260021
*      PRINTER OR NO BUFFER IS AVAILABLE FOR BLOCKING, THE RECORD IN    07280021
*      THE OUTPUT LINE IS WRITTEN.                                      07300021
*      IF THE RECORDS ARE TO BE BLOCKED, THE RECORD IN THE OUTPUT LINE  07320021
*      IS MOVED TO THE BUFFER.  WHEN THERE REMAINS LESS THAN 125 BYTES  07340021
*      IN THE BUFFER, THE BLOCK IS WRITTEN.                             07360021
*      PAGINATION IS CONTROLLED BY THE ROUTINE, BASED UPON 56 LINES     07380021
*      PER PAGE.                                                        07400021
*      THE ROUTINE RETURNS CONTROL VIA 'BR R5'.                         07420021
         SPACE 2                                                        07440021
OUTPUT   LM    RE,R0,ABDPTRS       LOAD 3 BUFFER PTRS                   07460021
* RE = PTR TO BUFFER                                                    07480021
* RF = PTR TO NEXT AVAILABLE SLOT IN BUFFER                             07500021
* R0 = END OF BUFFER (RE + SIZE)                                        07520021
         LTR   RE,RE               ARE RECORDS TO BE BLOCKED            07540021
         BZ    OUTPUT2             NO, SKIP BLOCKING                    07560021
         MVC   0(125,RF),ABDLOG    MOVE LOGICAL RECORD CT, CC CHAR,     07580021
*                                   AND 120 LINE TO BUFFER              07600021
         LA    RF,125(RF)          INCREMENT PTR TO NEXT BUFFER SLOT    07620021
         ST    RF,ABDPTRS+4        STORE VALUE                          07640021
         LA    R1,125(RF)          CHECK FOR END OF BUFFER              07660021
         CR    R1,R0               IS THERE ROOM FOR MORE RECORDS       07680021
         BNH   OUTPUT3             YES, SKIP FILLED BLOCK PROCESSING    07700021
OUTPUT1  SR    RF,RE               MOVE PHYSICAL RECORD LENGTH, AND     07720021
         STH   RF,ABDPHY            SYSTEM RESERVED CHARACTERS          07740021
         MVC   0(4,RE),ABDPHY       TO BUFFER.                          07760021
         LA    RF,4(RE)            RESET PTR TO NEXT                    07780021
         ST    RF,ABDPTRS+4         SLOT AVAILABLE IN BUFFER            07800021
OUTPUT2  B     DOSYNCH              BRANCH TO SYNCH RTN          A40891 07820021
DOWRITE  EQU   *                                                 A40891 07840021
         WRITE (1),SF,MF=E                                              07860021
         L     R1,ZERO(R7)          LOAD ADDRESS OF DECB      AB A40891 07880021
         CHECK (1)                                                      07900021
         SVC   3                   DEQUEUE PRB                AB A40891 07920021
OUTPUT3  EQU   *                                                        07940021
         BCR   0,0                 FILLER FOR TWO BYTES       AB A40891 07960021
         B     BUMPIT                                         AB A40891 07980021
BUMPED   EQU   *                                                        08000021
         CLI   ABDCC,C'-'                                               08020021
         BL    INCBYONE            BR IF SPACE 1, ABDCC = X'40'         08040021
         BH    INCBYTWO            BR IF SPACE 2, OR EJECT, 'F0-'F1'    08060021
         AR    R0,R1               SPACE 3, ABDCC = X'60'               08080021
INCBYTWO AR    R0,R1               *** NOTE- IF EJECT, LINE CT=-1+2=1   08100021
INCBYONE AR    R0,R1                                                    08120021
         MVI   ABDCC,C' '          SET ABDCC + ABDLINE                  08140021
         MVC   ABDLINE(120),ABDCC   TO BLANKS                           08160021
         LA    R1,56               SET UP CONSTANT                      08180021
         CR    R0,R1               IS LINE CT GT OR EQ TO 56            08200021
         BNL   OUTPUT4             YES, GO TO NEW LINE PROCESSING       08220021
         STH   R0,ABDCTR1                                               08240021
         TM    ABDFORM,FROMFORM    IS CALLER THE FORMET ROUTINE         08260021
         BCR   1,R5                YES, RETURN TO FORMET                08280021
         B     RETURN              NO, GO TO RESTORE R6 AND BACK        08300021
OUTPUT4  LH    R1,ABDCTR2          NEW PAGE,                            08320021
         LA    R1,1(R1)             BUMP CT BY 1,                       08340021
         STH   R1,ABDCTR2           STORE IT                            08360021
         MVI   ABDCC,C'1'          SET ABDCC TO EJECT                   08380021
         MVC   ABDCC+109(4),PAGE   MOVE INTO LINE 'PAGE'                08400021
         CVD   R1,ABDWORK1         CONVERT PAGE NO. TO DECIMAL          08420021
         UNPK  ABDCC+114(4),ABDWORK1+4(4)                               08440021
         OI    ABDCC+117,X'F0'     GET RID OF SIGN                      08460021
         MVC   ABDCTR1(2),MINUSONE RESET LINE CTR                       08480021
         B     OUTPUT                                                   08500021
*                                                                       08520021
OUTPUT5  LM    RE,R0,ABDPTRS       LAST TIME ENTRY,SET UP BUFF PTRS     08540021
         LTR   RE,RE               WAS BUFFER USED                      08560021
         BCR   8,R5                NO BUFFER USED, RETURN               08580021
         LA    R1,4(RE)            YES BUFFER USED                      08600021
         CR    R1,RF                                                    08620021
         BCR   8,R5                LAST WRITE EMPTIED BUFFER, EXIT      08640021
         B     OUTPUT1                  INFO REMAINS TO BE WRITTEN.     08660021
*                                                                       08680021
PAGE     DC    C'PAGE'                                                  08700021
MINUSONE DC    X'FFFF'                                                  08720021
* SYNCHRONOUS EXIT ROUTINE - ENTERED ONLY IF DEVICE IS A PRINTER.       08740021
SYNCH    BR    14                  RETURN                               08760021
*                                                                       08780021
LAST     EQU   *    THIS SYMBOL USED TO DETERMINE SIZE OF OUTPUT RTN.   08800021
TBL      DC    C'0123456789ABCDEF'                                      08820021
*                                                                       08840021
WHERETOG TM    ABDWTG,PFSUPDAT     IS SUP DATA REQUESTED                08860021
         BO    MOD2                YES,BRANCH                           08880021
         TM    ABDWTG,PFQCB        IS QCB TRACE REQUESTED               08900021
         BC    1,MOD5              YES,BRANCH                           08920021
         TM    ABDWTG+1,PFSAVE     IS SAVE AREA TRACE REQUESTED         08940021
* DELETED INSTRUCTION...                                           MPOC 08960021
*        BC    1,MOD5,                                             MPOC 08980021
* HAS BEEN REMOVED TO 'PATCH' FOLLOWED BY MP CODE, WHICH           MPOC 09000021
* LOGICALLY BELONGS HERE, SO AS TO AVOID DISPLACING ANY OF         MPOC 09020021
* THE ENTRY POINTS (ACCESSED VIA LDDSECT) WHICH FOLLOW.            MPOC 09040021
*                                                                  MPOC 09060021
         B     PATCH                                               MPOC 09080021
*                                                                  MPOC 09100021
WHERETG2 EQU   *                                                   MPOC 09120021
         TM    ABDWTG,PFNUC+PFSNAP      IS NUC OR SNAPSHOT REQUESTED    09140021
         BC    5,MOD7                  YES,BRANCH                       09160021
         TM    ABDWTG+1,PFREGS         ARE REGS REQUESTED               09180021
         BC    1,MOD7              YES,BRANCH                           09200021
         TM    ABDWTG+1,PFJPA+PFLPA  IS LPA/JPA WANTED                  09220021
         BC    5,MOD8                  YES,BRANCH                       09240021
         TM    ABDWTG,PFTRACE           IS TRACE TABLE WANTED           09260021
         BO    MODJ                YES , CHECK IF GTF IS ACTIVE   21014 09280021
GMSTTEST EQU   *                                                  21014 09300021
         TM    ABDWTG+1,PFSPALL    IS GOTTEN STORAGE WANTED             09320021
         BC    1,MOD9              YES,BRANCH                           09340021
*                                                                       09360021
*   CLEANUP                                                             09380021
*                                                                       09400021
FINISH   EQU   *                                                        09420021
*                                                                       09440021
*  IF A DUMP OF A TASK OTHER THAN CURRENT REQUESTED,ABDUMP1 SETS        09460021
*  THE TASKS IN QUESTION NON-DISPATCHABLE.TO ALLOW THESE TASKS TO       09480021
*  CONTINUE,THE FOLLOWING CODE RESETS THE NON-DISPATCHABILITY BITS      09500021
*  IN ALL TCB'S                                                         09520021
*                                                                       09540021
         L     RE,TCBJSTCB(TCBREG) GET JOBSTEP TCB                      09560021
         LCR   RE,RE               INDICATE FIRST TIME ENTRY            09580021
RESET1   EQU   *                                                        09600021
         BAL   LINKREG,SELTASK  WAS TASK SELECTED                       09620021
         B     RESET2              YES,BRANCH                           09640021
         B     RESET3              NO.MORE TASKS,BRANCH                 09660021
RESET2   NI    TCBFLGS+2(RE),255-TCBADUMP  RESET ND                     09680021
*                                                                       09700021
*   GO TO TASK SWITCHING ROUTINE                                        09720021
*                                                                       09740021
*  INPUT-RA=SUBJECT TASK'S TCB ADDRESS                                  09760021
*        RB=ENTRY POINT TO TASK SW ROUTINE                              09780021
*        RE=RETURN REG                                                  09800021
*  TRANSPARENT REGS--0-9,12,13,15                                       09820021
*                                                                       09840021
         L     R1,CVTPTR     GET CVT ADDRESS                            09860021
         L     RB,CVTABEND   GET ABEND'S CVT ADDRESS                    09880021
         L     RB,SCVTTASW(RB)  GET ENTRY POINT ADDRESS                 09900021
         LR    R8,RE         SAVE                                       09920021
         LR    RA,RE         GET OBJECT TCB ADDRESS                     09940021
*                                                                  0430 09960021
*THE FOLLOWING BRANCH TO PATCH2 IS TAKEN SO THAT ADDITIONAL CODE   0430 09980021
*CAN BE ADDED WITHOUT DISPLACING ANY OF THE ENTRY POINTS (ACCESSED 0430 10000021
*VIA LDDSECT) WHICH FOLLOW.                                        0430 10020021
*                                                                  0430 10040021
         B     PATCH2                                              0430 10060021
         NOP   RESET1        FILL UP SPACE                         0430 10080021
RESET3   NI    TCBFLGS-1(TCBREG),255-TCBFX  ZERO TCBFX BIT              10100021
         MVC   ABDCC(L'MESS4),MESS4                                     10120021
         MVC   ABDSAVE6(4),ABDLDADD     RETAIN ADDRESSABILITY FOR LOAD  10140021
         BAL   R5,OUTPUT           PRINT 'END OF DUMP'                  10160021
         BAL   R5,OUTPUT5          CHECK FOR PARTIALLY FILLED BUFFER    10180021
         LM   R7,R9,ABDPTRS     PTRS USED BY OUTPUT RTN                 10200021
         LTR   R7,R7          DID BLOCKING OCCUR                        10220021
         BC    8,DQE         NO,SKIP FREEMAIN                           10240021
         SR   R9,R7         GET SIZE                                    10260021
         FREEMAIN R,LV=(R9),SP=250,A=(R7)                     AB A40891 10280021
DQE      EQU   *                                                        10300021
         B     FREESAVE            FREE SAVE AREA             AB A40891 10320021
FREEBACK EQU   *                                              AB A40891 10340021
         TM    PFLAGS,PFABEND  IS ABEND THE CALLER                      10360021
         BC    8,NODQE       YES,BYPASS DQE CODE                        10380021
         LA    R1,ABDWORK          GET DEQ PARAM LIST ADDRESS           10384021
         XC    0(12,R1),0(R1)      CLEAR                                10388021
         LA    14,MAJ              GET ADDR OF MAJ QCB                  10392021
         L     15,ABDPARA          GET ABDUMP'S PARAM LIST ADDRESS      10396021
         LA    15,4(15)            GET ADDR OF MINOR QCB NAME(DCB)      10400021
         LA    3,4                 GET LENGTH OF THE NAME               10404021
         MVI   0(R1),X'FF'         LAST ENTRY INDICATOR                 10408021
         DEQ   ((14),(15),(3),),MF=(E,(1))                              10412021
NODQE    EQU   *                                                        10416021
         L     RA,ABDCRB     SAVE ABDUMP'S SVRB ADDRESS                 10420021
         L     R0,WORKSIZE   GET SIZE OF WORK AREA                      10440021
*                                                                       10460021
         FREEMAIN  R,LV=(0),A=(13)                                      10480021
*                                                                       10500021
         LA    R0,LOADNAME   GET NAME                                   10520021
         MVC   EXTSA(6,RA),DELETE  MOVE DELETE CODE TO EXT SAVE AREA    10540021
**********************************************************************  10544021
         B     EXTSA(RA)     DELETE AND EXIT                            10548021
*********************************************************************   10548821
DELETE   DELETE  EPLOC=(0)                                              10549621
         SR    RF,RF               ZERO REG 15, RETURN REG              10549721
         SVC   3                   RETURN                               10549821
MOD2     NI    ABDWTG,255-PFSUPDAT                                      10549921
         LA    RA,NAM2             GET NAME OF NEXT LOAD                10550021
         B     XCTLCODE            BRANCH                               10554021
MOD7     NI    ABDWTG,255-PFNUC-PFSNAP                                  10558021
         NI    ABDWTG+1,255-PFREGS                                      10558821
         LA    RA,NAM7             LA NAME OF MODULE                    10559621
         B     XCTLCODE                                                 10559721
MOD8     NI    ABDWTG+1,255-PFLPA-PFJPA                                 10559821
         LA    RA,NAM8             GET NAME ADDRESS                     10559921
         B     XCTLCODE                                                 10560021
MOD9     NI    ABDWTG+1,255-PFSPALL                                     10580021
         NI    ABDWTG,255-PFTRACE                                       10600021
         LA    RA,NAM9             GET NAME ADDRESS                     10620021
XCTLCODE EQU   *                                                        10640021
         LA    RF,ABDWORK                                               10660021
         XCTL  EPLOC=(RA),SF=(E,(15))                                   10680021
*********************************************************************   10700021
*        TASK SELECT ROUTINE                                            10720021
*********************************************************************   10740021
SELTASK  LTR   RE,RE               IS THIS FIRST TIME ENTRY             10760021
         BC    10,SELTASK1         NO,BRANCH                            10780021
         LCR   RE,RE               YES,RETURN JOB-STEP TCB ADDRESS      10800021
         BCR   15,LINKREG                                               10820021
SELTASK1 LR    RF,RE               SAVE GIVEN TCB ADDRESS               10840021
         L     RE,TCBLTC(RF)       GET DAUGHTER                         10860021
SELTASK2  LTR  RE,RE               IS DAUGHTER NON-ZERO                 10880021
         BCR   7,LINKREG               YES,RETURN  DAUGHTER'S ADDRESS   10900021
         L     RE,TCBNTC(RF)       GET SISTER                           10920021
         C     RF,TCBJSTCB(RF)     IS SCAN COMPLETED                    10940021
         BC    8,4(LINKREG)            YES,RETURN                       10960021
         L     RF,TCBOTC(RF)       NO,GET MOTHER                        10980021
         B     SELTASK2            TRY NEXT TASK                        11000021
MESS4    DC    C'0END OF DUMP'                                          11020021
NAM2     DC    CL8'IGC0105A'                                            11040021
NAM5     DC    CL8'IGC0405A'                                            11060021
NAM7     DC    CL8'IGC0605A'                                            11080021
NAM8     DC    CL8'IGC0705A'                                            11100021
NAM9     DC    CL8'IGC0805A'                                            11120021
LOADNAME DC    CL8'IGC0A05A'                                            11140021
WORKSIZE DS    0F                                                       11160021
         DC    AL1(253)           SUB POOL NO.                          11180021
         DC    AL3(317)            ABDUMP WORK AREA SIZE          21014 11200021
MAJ      DC    C'SYSIEA01'         MAJOR QCB NAME                       11204021
EBCDIC   LA    8,ABDLINE           GET ADDRESS OF OUTPUT LINE           11208021
         USING PRNTAREA,R7                                              11208821
         STM   R7,RA,ABDLINE+3     SAVE ABDUMP REGISTERS                11209621
         LR    R7,R8               MOVE REGISTERS FOR PROPER BXLE       11209721
         L     RA,ABDSTAD          GET ADDRESS OF A BLOCK OF STORAGE    11209821
         SRL   RA,5                STRIP LOW 5 BITS FROM STARTING       11209921
         SLL   RA,5                ADDRESS (FOR INDENT PURPOSES)        11210021
         MVC   COREBLOK,0(RA)      MOVE STORAGE BLOCK TO PRINT AREA     11214021
         LA    R8,31(R7)           PLACE UPPER LIMIT OF BXLE IN REG     11218021
         LA    R9,31(R7)           PLACE UPPER BXLE LIMIT IN REG        11218821
         LA    R8,1                PLACE INCREMENT FACTOR IN REG        11219621
         SPACE 2                                                        11219721
         MVI   DELIMITA,X'5C'      DELIMIT EBCDIC FIELD IN DUMP         11219821
         MVI   DELIMITB,X'5C'      DELIMIT EBCDIC FIELD IN DUMP         11219921
         SPACE 2                                                        11220021
LOOP     TM    COREBLOK,X'C0'      SEE IF CHARACTER IS ABOVE C0 HEX     11224021
         BO    ALRIGHT             IF YES, MODIFY BYTE FOR TRANSLATE    11228021
         CLI   COREBLOK,X'40'      ELSE, SEE IF CHARACTER IS A BLANK    11228821
         BE    EXITR               IF YES, NO MODIFY                    11229621
         MVI   COREBLOK,X'0F'      UNPRINTABLE CHAR PRINTS AS A '.'     11229721
ALRIGHT  NI    COREBLOK,X'3F'      STRIP HIGH ORDER 2 BITS.             11229821
EXITR    BXLE  R7,R8,LOOP          DECREMENT POINTER AND LOOP           11229921
         TR    EBCBLOCK,XLATE      TRANSLATE INTO PRINTABLE ENGLISH     11230021
         DROP  R7                                                       11234021
         LM    R7,RA,ABDLINE+3     RESTORE ABDUMP REGISTERS             11238021
         MVC   ABDLINE+3(20),ABDLINE+2  CLEAN PRINT AREA                11238821
         B     FORMAT22            RETURN TO FORMAT ROUTINE             11239621
XLATE    DC    C'.ABCDEFGHI......'                                      11239721
         DC    C'.JKLMNOPQR......'                                      11239821
         DC    C'..STUVWXYZ......'                                      11239921
         DC    C'0123456789......'                                      11240021
         DC    C' '                                                     11244021
PATCH    BC    CC01,MOD5           YES,BRANCH                      MP0C 11248021
CC01     EQU   1                   M FIELD FOR ABOVE BC                 11248821
         TM    ABDWTG2,DUMPTCAM         IS TCAM INFO WANTED       20002 11249621
         BZ    SKIPTCAM                 NO,BRANCH                 20002 11249721
         NI    ABDWTG2,XFF-DUMPTCAM     TURN OFF TCAM BIT         20002 11249821
         LA    RA,NAMTCAM               GET NAME 1ST TCAM LOAD    20002 11249921
         B     XCTLCODE                 XCTL TO IT                20002 11250021
NAMTCAM  DC    C'IGC0D05A'              NAME OF 1ST TCAM LOAD     20002 11254021
SKIPTCAM EQU   *                                                  20002 11258021
         TM    ABDWTG2,DUMPTSO          IS TSO INFO WANTED        20021 11258821
         BZ    SKIPTSO                  NO,BRANCH                 20021 11259621
         NI    ABDWTG2,XFF-DUMPTSO      TURN OFF TSO BIT          20021 11259721
         LA    RA,NAMTSO                GET NAME OF TSO LOAD      20021 11259821
         B     XCTLCODE                 XCTL TO IT                20021 11259921
NAMTSO   DC    C'IGC0H05A'              NAME OF 1ST TSO LOAD      20021 11260021
SKIPTSO  EQU   *                                                  20021 11264021
         L     RA,CVTPTR           ADDRESS THE CVT                 MP0C 11268021
         USING CVTDSECT,RA                                         MPOC 11268821
         TM    CVTDCB,CVTDCBMP     IS THIS AN M65MP?               MP0C 11269621
CVTDCBMP EQU   X'04'               MASK 00000100                   MP0C 11269721
         DROP  RA                                                  MPOC 11269821
         BNO   WHERETG2                NO                          MPOC 11269921
         TM    ABDWTG,PFTRACE      YES... IS TRACE TABLE WANTED?  21014 11270021
         BO    MODK                YES. GO XCTL TO IEAQAD0K       21014 11274021
SKIPTT   TM    ABDWTG,PFNUC        NO... IS NUCLEUS WANTED?       21014 11278021
         BNO   WHERETG2            IF NOT, GO TO WHERETOGO ROUTINE21014 11278821
MODB     NI    ABDWTG,ALL1-PFNUC   TURN OFF NUCLEUS REQUESTED FLG 21014 11279621
         NI    ABDWTG+1,ALL1-PFREGS TURN OFF REGS FLAG            21014 11279721
ALL1     EQU   X'FF'               MASK 11111111                   MP0C 11279821
         LA    RA,NAM0B05A         ADDR OF XCTL PARAMETER          MP0C 11279921
         B     XCTLCODE            GO TO XCTL TO IEAQAD0B          MP0C 11280021
         LTORG                                                          11300021
NAM0B05A DC    C'IGC0B05A'         XCTL PARAMETER                  MP0C 11320021
MOD5     LA    RA,NAM5             GET ADDR OF MODULE NAME              11340021
         B     XCTLCODE            BRANCH TO XCTL RTN                   11360021
PATCH2   SSM   DISABLE             INHIBIT INTERRUPTS              0430 11380021
         BALR  RE,RB               BRANCH TO TASK SWITCH RTN       0430 11400021
         SSM   ENABLE              PERMIT INTERRUPTS               0430 11420021
         LR    RE,R8               RESTORE REG E                   0430 11440021
         B     RESET1              SELECT NEXT TASK                0430 11460021
MODK     NI    ABDWTG,ALL1-PFTRACE TURN OFF TRACE TAB REQUESTD FLG21014 11480021
         L     CVTREG,CVTPTR       GET BASE FOR CVT DSECT         21014 11500021
         USING CVTDSECT,CVTREG                                    21014 11520021
         TM    CVTGTFST,CVTGTFS    IS GTF ACTIVE ?                21014 11540021
         BNO   MODP                NO...GO LOAD ADDR.OF IEAQAD0P  21014 11560021
         TM    CVTGTFST,CVTFORM    YES...IS TRACE TO BE FORMATTED 21014 11580021
         DROP  CVTREG                                             21014 11600021
         BNO   SKIPTT              NO ... THEN CHECK FOR NUC REQ  21014 11620021
         LA    XCTLREG,NAMK        GET XCTL ENTRY POINT PARM ADDR 21014 11640021
         SR    R8,R8               CLEAR REG 8 FOR USE BY _D0K    21014 11660021
         B     XCTLCODE            GO CHECK FOR GTF ACTIVE        21014 11680021
MODJ     L     CVTREG,CVTPTR       GET BASE FOR CVT DSECT         21014 11700021
         NI    ABDWTG,ALL1-PFTRACE TURN OFF TRACE TABLE REQD FLAG 21014 11720021
         USING CVTDSECT,CVTREG                                    21014 11740021
         TM    CVTGTFST,CVTGTFS    IS GTF ACTIVE                  21014 11760021
         BNO   MODN                NO...GO XCTL TO IEAQAD0N       21014 11780021
         TM    CVTGTFST,CVTFORM    IS TRACE TABLE TO BE FORMATTED 21014 11800021
         DROP  CVTREG                                             21014 11820021
         BNO   GMSTTEST            NO... GO BACK INTO WHERETOGO   21014 11840021
         SR    R8,R8               CLEAR REG 8 FOR USE BY _D0J-   21014 11860021
         LA    XCTLREG,NAMJ        GET XCTL ENTRY POINT PARM ADDR 21014 11880021
         B     XCTLCODE            GO XCTL TO IEAQADOJ            21014 11900021
MODN     LA    XCTLREG,NAMN        GET XCTL ENTRY POINT PARM ADDR 21014 11920021
         B     XCTLCODE            GO XCTL TO IEAQAD0N            21014 11940021
MODP     LA    XCTLREG,NAMP        GET XCTL ENTRY POINT PARM ADDR 21014 11960021
         B     XCTLCODE            GO XCTL TO IEAQAD0P            21014 11980021
PATCHGTF TM    ABDBLNKS,ABDBLNKF   IS IT NORMAL 3 BLANKS PAD      21014 12000021
         BO    CHANGFM             NO                      D      21014 12020021
         LA    R8,4(RF,R8)         UPDATE NEXT LABEL PTR          21014 12040021
         B     RETNPAT             GO FINISH FORMAT               21014 12060021
CHANGFM  MVI   ABDFMTSV,HEX0      ZERO OUT FIRST BYTE FOR WORK    21014 12080021
         MVC   ABDFMTSV+1(1),ABDBLNKS MOVE IN BLANKS CNT          21014 12100021
         NI    ABDFMTSV+1,HEX07    ZERO  HIGH 5 BITS FOR ADD      21014 12120021
         AH    R8,ABDFMTSV         ADD BLANK CNT                  21014 12140021
         LA    R8,1(RF,R8)         POINT TO NEXT LABEL            21014 12160021
         B     RETNPAT             GO FINISH FORMATBEL            21014 12180021
DOSYNCH  EQU   *                                                 A40891 12200021
         ST    R7,EIGHT(RD)        SAVE REG 7 ACROSS SYNCH    AB A40891 12220021
         L     R1,ZERO(RD)         LOAD ADDR OF DECB          AB A40891 12240021
         NC    ABDPTRS(4),ABDPTRS  IS BLOCKING NEEDED         AB A40891 12260021
         BNZ   BLOCKING            YES. BLOCKING NEEDED       AB A40891 12280021
         LA    R7,SAVEPTR(R1)      PUT ADDR OF ABDPHY IN 7    AB A40891 12300021
         ST    R7,LINEPTR(R1)      STORE ADDR OF ABDPHY IN DECB  A40891 12320021
         MVC   0(130,R7),ABDPHY    MOVE OUTPUT LINE TO BUFFER AB A40891 12340021
BLOCKING EQU   *                                              AB A40891 12360021
         LR    R7,RD               SAVE REG 13 ACROSS SYNCH   AB A40891 12380021
         L     RD,FOUR(RD)         LOAD ADDR OF SAVE AREA     AB A40891 12400021
         LA    15,DOWRITE          LOAD ADDR OF WRITE RTN        A40891 12420021
         SYNCH (15)                EXECUTE SYNCH                 A40891 12440021
         LR    RD,R7               RESTOTRE REG 13            AB A40891 12460021
         L     R7,8(RD)            RESTORE REG 7              AB A40891 12480021
         B     OUTPUT3             RETURN TO MAIN LINE           A40891 12500021
FREESAVE EQU   *                                              AB A40891 12520021
         L     R1,0(RD)            LOAD ADDR OF DECB          AB A40891 12540021
         L     R0,SAVESIZE         LOAD LENGTH OF SAVE AREA   AB A40891 12560021
         FREEMAIN  R,LV=(0),A=(R1)  FREE SAVE AREA            AC A40891 12580021
         L     PARREG,ABDPARA      GET PARM LIST ADDR         AB A40891 12600021
         B     FREEBACK            BACK TO MAIN LINE          AB A40891 12620021
BUMPIT   EQU  *                                               AB A40891 12640021
         LA   R1,1                 AMOUNT FOR LINE CTR        AB A40891 12660021
         LH   R0,ABDCTR1           INITIALIZE COUNTER         AB A40891 12680021
         B    BUMPED               BACK TO MAIN LINE          AB A40891 12700021
         DS    0F                                             AB A40891 12800021
SAVESIZE DC    AL1(250)                                       AB A40891 12820021
         DC    AL3(224)                                       AB A40891 12840021
NAMJ     DC    CL8'IGC0J05A'       ENTRY POINT NAME FOR IEAQAD0J  21014 12860021
NAMK     DC    CL8'IGC0K05A'       ENTRY POINT NAME FOR IEAQAD0K  21014 12880021
NAMN     DC    CL8'IGC0N05A'       ENTRY POINT NAME FOR IEAQAD0N  21014 12900021
NAMP     DC    CL8'IGC0P05A'       ENTRY POINT NAME FOR IEAQAD0P  21014 12920021
DISABLE  DC    X'00'                                                    12940021
ENABLE   DC    X'FF'                                                    12960021
         EJECT                                                          12980021
********************************************************************    13000021
**********************************************************              13020021
*********************************************************************   13040021
*        DSECTS                                                         13060021
*********************************************************************   13080021
         IHBDMPA                                                        13100021
*                                                                       13120021
CVTDSECT DSECT                                                          13140021
         CVT   SYS=VMS                                                  13160021
PRNTAREA DSECT                                                          13180021
         DS    CL55                                                     13200021
EBCBLOCK DS    0CL32               LOCATION OF EBCDIC FIELD FOR XLATE   13220021
         DS    CL31                                                     13240021
DELIMITA DS    CL1                 LOCATION OF LOWER DELIMIT ASTERISK   13260021
COREBLOK DS    CL32                                                     13280021
DELIMITB DS    CL1                 LOCATION OF UPPER DELIMIT ASTERISK   13300021
         END                                                            13320021
