AD0C     TITLE 'IEAQAD0C / ABDUMP LOAD 1.5 / IGC0C05A'                  00300018
IGC0C05A CSECT                                                          00600018
*                                                                       00900018
* THIS MODULE WAS ENTERED NEW IN RELEASE 18. IT HAD FORMERLY BEEN A     01200018
* PART OF MODULES IEAQAD00 AND IEAQAD01.                                01500018
*                                                                       01800018
*   STATUS-                                                             02100018
*        CHANGE LEVEL = 0                                               02400018
*   ROUTINE NAME-                                                       02700018
*        IEAQAD0C (ALSO CALLED ABDUMP1.5)                               03000018
*   FUNCTION-                                                           03300018
*        ABDUMP1.5 OUTPUTS THE HEADING, COMPLETION CODE, AND PSW AT     03600018
*        ENTRY TO ABEND(SNAP).                                          03900018
*   ENTRY POINT NAME-                                                   04200018
*        IGC0C05A                                                       04500018
*   ATTRIBUTES-                                                         04800018
*        TYPE IV SVC, SUPERVISOR STATE, REENTRANT                       05100018
*   EXTERNAL REFERENCES-                                                05400018
*        NONE                                                           05700018
*   SVC USAGE-                                                          06000018
*        1) TIME                                                        06300018
*   INPUT-                                                              06600018
*        ABDUMP1.5 IS PASSED 2 POINTERS-                                06900018
*        1) THE ADDRESS OF THE TCB OF THE TASK BEING DUMPED IN REG 4    07200018
*        2) THE ADDRESS OF THE WORK AREA OBTAINED BY ABDUMP1 IN REG 13  07500018
*   OUTPUT-                                                             07800018
*        ABDUMP1.5 PROVIDES THE FOLLOWING INFORMATION IN PRINTABLE      08100018
*        FORMAT.                                                        08400018
*        1) JOB NAME                                                    08700018
*        2) STEP NAME                                                   09000018
*        3) TIME                                                        09300018
*        4) DATE                                                        09600018
*        5) PAGE NUMBER                                                 09900018
*        6) COMPLETION CODE                                             10200018
*        7) PSW AT ENTRY TO ABEND(SNAP)                                 10500018
*   ENTRY POINTS-                                                       10800018
*        1) PSW                                                         11100018
*             A) ENABLED                                                11400018
*             B) UNDER SUPERVISOR PROTECTION KEY                        11700018
*             C) IN SUPERVISOR MODE                                     12000018
*        2) REGISTERS                                                   12300018
*             A) REG 4- ADDRESS OF TCB OF TASK BEING DUMPED             12600018
*             B) REG 13- ADDRESS OF ABDUMP'S WORK AREA                  12900018
*   EXIT-                                                               13200018
*        ABDUMP1.5 BRANCHES TO THE 'WHERE TO GO ROUTINE' IN IEAQAD0A.   13500018
*   ERROR MESSAGES-                                                     13800018
*        NONE                                                           14100018
*   TABLES AND CONTROL BLOCKS REFERENCED-                               14400018
*        ABDUMP1.5 REFERENCES THE FOLLOWING CONTROL BLOCKS-             14700018
*        1) TCB                                                         15000018
*             A) TCBTIOT- ADDRESS OF TIOT                               15300018
*             B) TCBCMP- TASK COMPLETION CODE                           15600018
*        2) TIOT                                                        15900018
*             A) TIOTJOB- JOB NAME                                      16200018
*             B) TIOTSTEP- STEP NAME                                    16500018
*        3) RB                                                          16800018
*             A) RBLINK- ADDRESS OF PREVIOUS RB ON QUEUE                17100018
*             B) RBOPSW- PSW AT ENTRY TO ABEND(SNAP)                    17400018
*   LIST ORIGINS, TABLES, CONTROL BLOCKS INCLUDED-                      17700018
*        THE FORMAT OF ABDUMP'S WORK AREA IS DESCRIBED BY THE DSECT     18000018
*        NAMED ABDAREA WHICH IS ASSEMBLED AS PART OF EACH MODULE.       18300018
*   OPERATION-                                                          18600018
*        ABDUMP1.5 OUTPUTS THE HEADING LINE CONSISTING OF JOBNAME,      18900018
*        STEPNAME, TIME, DATE, ID (IF SPECIFIED), AND PAGE NUMBER. IT   19200018
*        THEN OUTPUTS THE COMPLETION CODE IF ABDUMP IS CALLED BY ABEND. 19500018
*        NEXT, IT OUTPUTS THE PSW AT ENTRY TO ABEND(SNAP). FINALLY, IT  19800018
*        BRANCHES TO THE 'WHERE TO GO ROUTINE' IN IEAQAD0A.             20100018
*   NOTE-                                                               20400018
*        THIS MODULE IS CHARACTER CODE DEPENDENT (EBCDIC).              20700018
         EJECT                                                          21000018
* REGISTERS                                                             21300018
*                                                                       21600018
R0       EQU   0                                                        21900018
R1       EQU   1                                                        22200018
R2       EQU   4                                                        22500018
R3       EQU   3                                                        22800018
R4       EQU   2                                                        23100018
R5       EQU   5                                                        23400018
R6       EQU   6                                                        23700018
R7       EQU   7                                                        24000018
R8       EQU   8                                                        24300018
R9       EQU   9                                                        24600018
RA       EQU   10                                                       24900018
RB       EQU   11                                                       25200018
RC       EQU   12                                                       25500018
RD       EQU   13                                                       25800018
RE       EQU   14                                                       26100018
RF       EQU   15                                                       26400018
PARREG   EQU   15                                                       26700018
*                                                                       27000018
* DISPLACEMENTS FROM BEGINNING OF TCB TO                                27300018
*                                                                       27600018
TCBTIOT  EQU   12                      ADDR OF TIOT                     27900018
TCBCMP   EQU   16                      TASK COMPLETION CODE             28200018
*                                                                       28500018
* DISPLACEMENTS FROM BEGINNING OF TIOT TO                               28800018
*                                                                       29100018
TIOTJOB  EQU   0                       JOB NAME                         29400018
TIOTSTEP EQU   8                       STEP NAME                        29700018
*                                                                       30000018
* DISPLACEMENTS FROM BEGINNING OF RB TO                                 30300018
*                                                                       30600018
RBOPSW   EQU   16                      OLD PSW                          30900018
RBLINK   EQU   28                      PTR TO NEXT RB                   31200018
*                                                                       31500018
* DISPLACEMENTS FROM BEGINNING OF OUTPUT LINE TO                        31800018
*                                                                       32100018
JOBLABEL EQU   0                       LABEL PRECEEDING JOB NAME        32400018
JOBNAME  EQU   4                       JOB NAME                         32700018
STEPLABL EQU   21                      LABEL PRECEEDING STEP NAME       33000018
STEPNAME EQU   26                      STEP NAME                        33300018
DATE5    EQU   66                      DATE FIELD + 5                   33600018
IDLABEL  EQU   70                      LABEL PRECEEDING ID NUMBER       33900018
ID       EQU   75                      ID NUMBER                        34200018
IDSIGN   EQU   77                      SIGN BYTE OF ID NUMBER           34500018
PAGENUM  EQU   109                     LABEL PRECEEDING PAGE NUMBER     34800018
SYSCMP3  EQU   33                      SYSTEM COMPLETION CODE FIELD + 3 35100018
USERCMP1 EQU   27                      USER COMPLETION CODE FIELD - 1   35400018
USERCMP4 EQU   32                      USER COMPLETION CODE FIELD + 4   35700018
PSWMSG16 EQU   16                      PSW MSG FIELD + 16               36000018
*                                                                       36300018
* OTHER EQUATES                                                         36600018
*                                                                       36900018
XF0      EQU   X'F0'                                                    37200018
BLANK    EQU   C' '                                                     37500018
IDLEN    EQU   3                                                        37800018
NAMELEN  EQU   8                                                        38100018
SHIFTOUT EQU   8                                                        38400018
SHIFTIN  EQU   12                                                       38700018
SHIFTRT  EQU   20                                                       39000018
SHIFTLFT EQU   12                                                       39200018
SYSCODE  EQU   1                                                        39400018
USERCODE EQU   5                                                        39600018
BYTE2    EQU   1                                                        39900018
ZERO     EQU   0                                                        40200018
TWO      EQU   2                                                        40500018
SIX      EQU   6                                                        40800018
TWELVE   EQU   12                                                       41100018
         EJECT                                                          41400018
* ESTABLISH ADDRESSABILITY                                              41700018
*                                                                       42000018
         BALR  RC,R0                                                    42300018
         USING *,RC                                                     42600018
         USING ABDAREA,RD                                               42900018
         USING LDDSECT,R6                                               43200018
         USING PARDSECT,PARREG                                          43500018
*                                                                       43800018
* FORMAT AND OUTPUT HEADING LINE CONSISTING OF JOB NAME, STEP NAME,     44100018
* TIME, DATE, ID (IF SPECIFIED), AND PAGE NUMBER                        44400018
*                                                                       44700018
         L     PARREG,ABDPARA          GET PTR TO PARAM LIST            45000018
         TM    PFLAGS,PFID             IS ID PRESENT IN PARAM LIST      45300018
         BZ    NOID                    NO,THERE IS NO ID                45600018
*                                                                       45900018
         MVC   ABDLINE+IDLABEL(L'IDMSG),IDMSG       ID MSG TO HEADING   46200018
         SR    R3,R3                                CLEAR R3            46500018
         IC    R3,PID                               ID FROM PARAM LIST  46800018
         CVD   R3,ABDWORK1                          CONVERT AND STORE   47100018
         UNPK  ABDLINE+ID(IDLEN),ABDWORK1+SIX(TWO)  ID TO HEADING  2658 47400018
         OI    ABDLINE+IDSIGN,XF0                   MAKE SIGN 'F'  2658 47700018
*                                                                       48000018
NOID     EQU   *                                                        48300018
         L     R3,TCBTIOT(R2)                         GET ADDR OF TIOT  48600018
         MVC   ABDCC(L'JOBMSG),JOBMSG                 JOB MSG TO HDING  48900018
         MVC   ABDLINE+JOBNAME(NAMELEN),TIOTJOB(R3)   JOBNAME TO HDING  49200018
         MVC   ABDLINE+STEPLABL(L'STEPMSG),STEPMSG    STEP MSG TO HDING 49500018
         MVC   ABDLINE+STEPNAME(NAMELEN),TIOTSTEP(R3) STEPNAME TO HDING 49800018
         TIME  DEC                                                      50100018
         STM   R0,R1,ABDWORK1                         STORE TIME/DATE   50400018
         LA    R3,TIMELINE                            GET ADDR LAYOUT   50700018
         LA    R4,ABDWORK1                            ADDR OF TIME/DATE 51000018
         BAL   R5,FORMAT                              FORMAT TIME/DATE  51300018
         MVI   ABDLINE+DATE5,BLANK                    BLANK OUT JUNK    51600018
         MVC   ABDLINE+PAGENUM(L'PAGEMSG),PAGEMSG     PAGE MSG TO HDING 51900018
*                                                                       52200018
* ZERO 'ABDFORM' TO INDICATE TO OUTPUT RTN THAT REG 6 MUST BE RESTORED  52500018
*                                                                       52800018
         MVI   ABDFORM,ZERO            ZERO ABDFORM BYTE                53100018
         BAL   R5,OUTPUT               OUTPUT HEADING                   53400018
         L     PARREG,ABDPARA          GET PTR TO PARAM LIST            53700018
         TM    PFLAGS,PFABEND          IS ABEND THE CALLER              54000018
         BO    NOCC                    NO,THERE IS NO COMPLETION CODE   54300018
*                                                                       54600018
* FORMAT TASK COMPLETION CODE - IN HEX IF ASSIGNED BY SYSTEM RTN        54900018
*                               IN DECIMAL IF ASSIGNED BY USER RTN      55200018
*                                                                       55500018
*                ******************************************             55800018
*        TCBCMP  *  BITS 0-7  *  BITS 8-19  *  BITS 20-31 *             56100018
*                * ABEND BYTE * SYSTEM CODE *  USER CODE  *             56400018
*                ******************************************             56700018
*                                                                       57000018
*        NOTE - ONE OF THE CODE FIELDS MUST BE ZERO                     57300018
*                                                                       57600018
         MVC   ABDCC(L'CMPMSG),CMPMSG  MOVE IN COMPLETION CODE MSG      57900018
         SR    RA,RA                   CLEAR REG A                 4029 58200018
         L     RB,TCBCMP(R2)           GET COMP CODE FROM TCB      4029 58500018
         SLL   RB,SHIFTOUT             SHIFT OUT ABEND BYTE        4029 58800018
         SLDL  RA,SHIFTIN              SHIFT SYSTEM CODE INTO RA   4029 59100018
         LTR   RA,RA                   IS THERE A SYSTEM CODE      4029 59400018
         BZ    ABD011                  NO,BRANCH                   4029 59700018
         SLL   RA,SHIFTLFT             RE-ALIGN SYSTEM CODE             59800018
         ST    RA,ABDWORK1             STORE CODE IN WORK AREA          60000018
         LA    R3,CMPLINE1             GET ADDR LAYOUT LINE             60300018
         LA    R4,ABDWORK1+SYSCODE     GET ADDR OF SYSTEM CODE          60600018
         BAL   R5,FORMAT               FORMAT SYSTEM CODE               60900018
         MVI   ABDLINE+SYSCMP3,BLANK   BLANK OUT JUNK                   61200018
         B     ABD012                  BRANCH-THERE IS NO USER CODE     61500018
ABD011   EQU   *                                                        61800018
         SRL   RB,SHIFTRT              RIGHT-ALIGN USER CODE            62100018
         CVD   RB,ABDWORK1             CONVERT USER CODE AND STORE      62400018
         LA    R3,CMPLINE2             GET ADDR LAYOUT LINE             62700018
         LA    R4,ABDWORK1+USERCODE    GET ADDR OF CONVERTED CODE       63000018
         BAL   R5,FORMAT               FORMAT USER CODE                 63300018
         MVI   ABDLINE+USERCMP1,BLANK  BLANK OUT JUNK                   63600018
         MVI   ABDLINE+USERCMP4,BLANK  BLANK OUT JUNK                   63900018
ABD012   BAL   R5,OUTPUT               OUTPUT COMPLETION CODE           64200018
*                                                                       64500018
NOCC     EQU   *                                                        64800018
         L     PARREG,ABDPARA          GET PTR TO PARAM LSIT            65100018
         TM    PFLAGS+BYTE2,PFPSW      IS PSW WANTED                    65400018
         BZ    NOPSW                   NO,BRANCH AROUND PSW CODE        65700018
*                                                                       66000018
* FORMAT PSW AT ENTRY TO ABEND/SNAP                                     66300018
*                                                                       66600018
         MVC   ABDCC(L'PSWMSG),PSWMSG  MOVE PSW MSG INTO OUTPUT LINE    66900018
         L     R8,ABDCRB               GET ADDR OF ABDUMP'S SVRB        67200018
         L     R8,RBLINK(R8)           GET ADDR OF NEXT RB              67500018
         TM    PFLAGS,PFABEND          IS ABEND THE CALLER              67800018
         BO    NOABEND                 NO,BRANCH                        68100018
         L     R8,RBLINK(R8)           GET ADDR OF ABENDING RB          68400018
         MVC   ABDLINE+PSWMSG16(L'ABEND),ABEND  CHANGE 'SNAP' TO 'ABEND 68700018
NOABEND  LA    R4,RBOPSW(R8)           GET PSW ADDR                     69000018
         LA    R3,PSWLINE              GET ADDR LAYOUT LINE             69300018
         BAL   R5,FORMAT               FORMAT LEFT HALF OF PSW          69600018
         BAL   R5,FORMAT               FORMAT RIGHT HALF OF PSW         69800018
         BAL   R5,OUTPUT               OUTPUT PSW LINE                  70000018
*                                                                       70200018
NOPSW    EQU   *                                                        70500018
         L     R6,ABDLDADD             GET ADDR OF RESIDENT MODULE      70800018
         B     LDWTG                   BRANCH TO 'WHERE TO GO' RTN      71100018
*                                                                       71400018
*                                                                       73200018
* FORMAT ROUTINE                                                        73500018
*                                                                       73800018
FORMAT   ST    R6,ABDSAVE6             SAVE REG 6                       74100018
         L     R6,ABDLDADD             GET ADDR OF RESIDENT MODULE      74400018
         B     LDFORMAT                BRANCH TO RESIDENT FORMAT RTN    74700018
*                                                                       75000018
* OUTPUT ROUTINE                                                        75300018
*                                                                       75600018
OUTPUT   ST    R6,ABDSAVE6             SAVE REG 6                       75900018
         L     R6,ABDLDADD             GET ADDR OF RESIDENT MODULE      76200018
         B     LDOUTPUT                BRANCH TO RESIDENT OUTPUT RTN    76500018
         EJECT                                                          76800018
* CONSTANTS                                                             77100018
*                                                                       77400018
JOBMSG   DC    C'1JOB'                 LABEL PRECEEDING JOB NAME        77700018
STEPMSG  DC    C'STEP'                 LABEL PRECEEDING STEP NAME       78000018
PAGEMSG  DC    C'PAGE 0001'            PAGE NUMBER FOR 1ST PAGE OF DUMP 78300018
IDMSG    DC    C'ID ='                 LABEL PRECEEDING ID              78600018
CMPMSG   DC    C'0COMPLETION CODE'     LABEL PRECEEDING COMPLETION CODE 78900018
PSWMSG   DC    C'0PSW AT ENTRY TO SNAP' LABEL PRECEEDING PSW            79200018
ABEND    DC    C'ABEND'                TO CAHNGE 'SNAP' TO 'ABEND'      79500018
TIMELINE DC    X'2A'                   INDENTATION FACTOR               79800018
         DC    X'3201'                 DESCRIPTION OF TIME FIELD        80100018
         DC    C'TIME'                 LABEL PRECEEDING TIME            80400018
         DC    X'3251'                 DESCRIPTION OF DATE FIELD        80700018
         DC    C'DATE'                 LABEL PRECEEDING DATE            81000018
         DC    X'FF'                   DELIMITER                        81300018
CMPLINE1 DC    X'15'                   INDENTATION FACTOR               81600018
         DC    X'7101'                 DESCRIPTION OF SYSTEM CODE FIELD 81900018
         DC    C'SYSTEM ='             LABEL PRECEEDING SYSTEM CODE     82200018
         DC    X'FF'                   DELIMETER                        82500018
CMPLINE2 DC    X'15'                   INDENTATION FACTOR               82800018
         DC    X'5200'                 DESCRIPTION OF USER CODE FIELD   83100018
         DC    C'USER ='               LABEL PRECEEDING USER CODE       83400018
         DC    X'FF'                   DELIMETER                        83700018
PSWLINE  DC    X'16'                   INDENTATION FACTOR               84000018
         DC    X'0300'                 DESCRIPTION OF LEFT PSW FIELD    84300018
         DC    C' '                    DUMMY LABEL                      84600018
         DC    X'FF'                   DELIMETER                        84900018
         DC    X'1F'                   INDENTATION FACTOR               85200018
         DC    X'0340'                 DESCRIPTION OF RIGHT PSW FIELD   85500018
         DC    C' '                    DUMMY LABEL                      85800018
         DC    X'FF'                   DELIMETER                        86100018
         EJECT                                                          86400018
         IHBDMPA                                                        86700018
         END                                                            87000018
