         TITLE 'IEAQAD0E / TCAM ABDUMP LOAD 2 / IGC0E05A'               00200020
IGC0E05A CSECT                                                          00400020
* MOST RECENT CHANGES WERE MADE IN RELEASE 21.6               AC A43061 00400421
*                                                                       00402020
* MODULE NAME -                                                         00404020
*                                                                       00406020
*        IEAQAD0E                                                       00408020
*                                                                       00410020
* FUNCTION -                                                            00412020
*                                                                       00414020
*        TO FORMAT AND PRINT THE TERMINAL NAMES AS THEY EXIST IN        00416020
*        THE TERMINAL NAME TABLE (TNT) ALONG WITH THEIR                 00418020
*        ASSOCIATED ENTRIES IN THE TERMINAL TABLE (TRM) - WITH          00420021
*        THE EXCEPTION OF LGB TYPE TERMINAL TABLE ENTRIES.              00420421
*                                                                       00422020
* ATTRIBUTES -                                                          00424020
*                                                                       00426020
*        REENTRANT, REFRESHABLE                                         00428020
*                                                                       00430020
* ENTRY -                                                               00432020
*                                                                       00434020
*        1) ENTRY POINT - IGC0E05A                                      00436020
*                                                                       00438020
*        2) PSW - ENABLED                                               00440020
*               - IN SUPERVISOR STATE                                   00442020
*               - UNDER SUPERVISOR PROTECTION KEY                       00444020
*                                                                       00446020
*        3) REGISTERS -                                                 00448020
*                       4 - TCB ADDR OF TASK BEING DUMPED               00450020
*                       7 - ADDR OF TCAM AVT                            00452020
*                      10 - ADDR OF TCAM TNT                            00454020
*                      13 - ADDR OF ABDUMP'S WORK AREA                  00456020
*                                                                       00458020
* EXTERNAL REFERENCES -                                                 00460020
*                                                                       00462020
*        1) TCAM AVT -                                                  00464020
*                       AVTOPTPT - ADDR OF OPTION TABLE                 00466020
*                                                                       00468020
*        2) TCAM TNT -                                                  00470020
*                       TNTLEN - NUMBER OF TNT ENTRIES                  00472020
*                       TNTENLEN - LENGTH OF TERMINAL NAMES             00474020
*                       ALL TNT TERMINAL ENTRIES                        00476020
*                                                                       00478020
*        3) TCAM TRM -                                                  00480020
*                       ALL FIELDS                                      00482020
*                                                                       00484020
* EXIT -                                                                00486020
*                                                                       00488020
*        TO MODULE IEAQAD0F AT ENTRY POINT IGC0F05A VIA AN XCTL.        00490020
*                                                                       00492020
* ERROR MESSAGES -                                                      00494020
*                                                                       00496020
*        NONE                                                           00498020
*                                                                       00500020
* OPERATION -                                                           00502020
*                                                                       00504020
*        IEAQAD0E FIRST EXAMINES THE 'TNTENLEN' AND 'TNTLEN'            00506020
*        FIELDS OF THE TNT IN ORDER TO DETERMINE THE LENGTH AND         00508020
*        NUMBER OF ENTRIES IN THE TNT.  THEN, THE FIRST TNT             00510020
*        ENTRY IS ACCESSED AND THE TERMINAL NAME IS EXTRACTED           00512020
*        FROM IT ALONG WITH THE ADDRESS OF ITS ASSOCIATED TRM           00514021
*        ENTRY.  IF THIS TRM ENTRY IS AN LGB, FURTHER                   00516021
*        PROCESSING OF THIS ENTRY IS DEFERRED UNTIL THE NEXT            00518021
*        LOAD.  IF, HOWEVER, THIS TRM ENTRY IS NOT AN LGB, IT           00518421
*        IS FORMATTED ALONG WITH THE TERMINAL NAME ASSOCIATED           00518821
*        WITH IT.                                                       00519221
*                                                                       00520020
*        THE FORMATTING OF THE TRM ENTRIES IS HANDLED                   00522020
*        DIFFERENTLY DEPENDING ON WHICH TYPE OF ENTRY IS BEING          00524020
*        FORMATTED AND WHICH OPTIONAL FIELDS ARE PRESENT.  THE          00526020
*        SEQUENCE OF EVENTS IN FORMATTING A TRM ENTRY IS AS             00528020
*        FOLLOWS:                                                       00530020
*             FIRST, THE 'TRMSTATE' FIELD IS CHECKED TO SEE             00532020
*        IF THE TRM ENTRY IS OF THE LIST TYPE.  IF IT IS, THE           00534020
*        TRM ENTRY IS FORMATTED ACCORDINGLY ALONG WITH THE NAMES        00536020
*        OF THE TERMINALS ASSOCIATED WITH THE DISTRIBUTION OR           00538020
*        CASCADE LIST.  THESE NAMES ARE ACCESSED VIA INDICIES TO        00540020
*        THE TNT THAT ARE PRESENT IN THE LIST TYPE TRM ENTRIES.         00542020
*             IF THE TRM ENTRY IS NOT OF THE LIST TYPE, THE             00544020
*        PART OF THE TRM ENTRY CONSISTING OF REQUIRED FIELDS IS         00546020
*        FORMATTED.  THEN, THE 'TRMSTATE' FIELD IS CHECKED TO           00548020
*        SEE IF OPTION FIELDS ARE ASSOCIATED WITH THIS ENTRY.           00550020
*        IF SO, THEY ARE FORMATTED ALONG WITH THEIR ADDRESSES           00552020
*        AND OPTION NAMES.  NOTE THAT THE OPTION FIELDS ARE NOT         00554020
*        ACTUALLY A PART OF THE TRM ENTRY ITSELF BUT ARE LOCATED        00556020
*        IN THE OPTION TABLE AND ARE REFERENCED VIA OFFSETS IN          00558020
*        THE TRM ENTRY.                                                 00560020
*             AFTER THE OPTION FIELDS ARE HANDLED, THE                  00562020
*        'TRMDEVFL' FIELD IS CHECKED TO DETERMINE WHICH, IF ANY,        00564020
*        DEVICE DEPENDENT FIELDS ARE PRESENT.  THOSE WHICH ARE          00566020
*        PRESENT ARE FORMATTED ALONG WITH A LABEL IDENTIFYING           00568020
*        WHICH TYPE OF FIELD IT IS.  NOTE THAT THE DEVICE               00570020
*        DEPENDENT FIELDS ARE ACTUALLY PART OF THE TRM ENTRY            00572020
*        ITSELF.                                                        00574020
*                                                                       00576020
*        AFTER THE FORMATTING OF A TRM ENTRY IS COMPLETED, THE          00578020
*        NEXT TNT ENTRY IS LOCATED AND FORMATTED ALONG WITH ITS         00580020
*        ASSOCIATED TRM ENTRY (IF IT IS NOT AN LGB TYPE ENTRY)          00582021
*        AND THIS PROCESS CONTINUES UNTIL ALL TNT ENTRIES HAVE          00584021
*        BEEN PROCESSED.                                                00584421
*                                                                       00584821
*                                                                       00586020
*        FINALLY, CONTROL IS TRANSFERRED TO MODULE IEAQAD0F AT          00588020
*        ENTRY POINT IGC0F05A VIA AN XCTL.                              00590020
         EJECT                                                          00592020
*                                                                       00600020
* REGISTER EQUATES                                                      00800020
*                                                                       01000020
ENDLINE  EQU   0                   PTR TO STOP ADDR IN LINE             01200020
ENTRYLEN EQU   1                   LENGTH OF TNT ENTRY                  01400020
OPTPTR   EQU   1                   PTR TO OPTION FIELD OFFSET           01600020
LOOKUP   EQU   1                   PTR TO OPTION LOOK-UP TABLE          01800020
BYTECTR  EQU   1                   COUNT OF BYTES IN GROUPING           02000020
FORMREG  EQU   2                   PTR TO FLD BEING FORMATTED           02200020
LAYOUT   EQU   3                   PTR TO LAYOUT LINE                   02400020
LABLREG  EQU   3                   PTR TO LABEL TABLE                   02600020
OPTABLE  EQU   3                   PTR TO OPTION TABLE                  02800020
TNTENTRY EQU   3                   PTR TO TNT ENTRY           CI  22024 02850021
TCB      EQU   4                   PTR TO TCB                           03000020
LINKREG  EQU   5                   LINK REG USED IN BAL                 03200020
LDREG    EQU   6                   BASE REG OF RESIDENT LOAD            03400020
MASKREG  EQU   6                   MASK TO TEST TRMDEVFL FIELD          03600020
OPTCTR   EQU   6                   COUNT OF OPTION ENTRIES              03800020
LISTCTR  EQU   6                   COUNT OF LIST ENTRIES                04000020
AVT      EQU   7                   PTR TO AVT                           04200020
OUTAREA  EQU   8                   PTR TO OUTPUT LINE                   04400020
NAMELEN  EQU   8                   LENGTH OF TNT NAME FIELD             04600020
TRM      EQU   9                   PTR TO TRM                           05000020
TNT      EQU   10                  PTR TO BEGINNING OF TNT              05200020
SWITCH   EQU   10                  SWITCH PASSED TO LOAD 3    CI  22024 05250021
NAMECTR  EQU   11                  COUNT OF TNT TERMINAL NAMES          05400020
BASE     EQU   12                  BASE REG USED BY ABDUMP              05600020
WORKAREA EQU   13                  PTR TO ABDUMP'S WORK AREA            05800020
FORMLINK EQU   14                  LINK REG USED BY FORMFLD RTN         06000020
NMNXTLD  EQU   14                  PTR TO NAME NEXT ABDUMP LOAD         06200020
MULTREG  EQU   14                  REG USED WHEN MULTIPLYING            06400020
PRODUCT  EQU   15                  PRODUCT AFTER MULTIPLICATION         06600020
WORKREG  EQU   15                  WORK REGISTER                        06800020
XCTLREG  EQU   15                  REG USED WHEN XCTL'ING               07000020
TNTINDEX EQU   15                  INDEX TO TNT ENTRY                   07200020
LABLEN   EQU   15                  LENGTH OF LABEL                      07400020
FLDLEN   EQU   15                  LENGTH OF DEV DEPENDENT FIELD        07600020
*                                                                       07800020
* OTHER EQUATES                                                         08000020
*                                                                       08200020
DBLSPACE EQU   C'0'                CARRIAGE CONTROL CHAR-SPACE 2        08400020
DIST     EQU   X'40'               MASK FOR DISTRIBUTION ENTRY          08600020
TSINGLE  EQU   X'E0'               MASK FOR SINGLE TYPE ENTRY CI  22024 08650021
TLINE    EQU   X'80'               MASK FOR LINE ENTRY        CI  22024 08700021
T3705    EQU   X'08'               MASK FOR 3705 ENTRY        AB  22024 08750021
UNUSED   EQU   X'FF'               INDICATES NO OPTION OFFSET           09000020
TNTNMIND EQU   5                   INDENT FACTOR-TNT NAME               09200020
LSTNMIND EQU   15                  INDENT FACTOR-LIST NAME              09400020
LISTIND  EQU   13                  INDENT FACTOR-LIST HEADING           09600020
LABLIND  EQU   13                  INDENT FACTOR-LABTABL NAMES          09800020
FLDIND   EQU   29                  IDENT FACTOR-OPTION FIELD            10000020
OPNMIND  EQU   13                  INDENT FACTOR-OPTION NAME            10200020
OPADIND  EQU   22                  INDENT FACTOR-OPTION ADDR            10400020
LGBAIND  EQU   13                  INDENT FACTOR-LGBA LABEL   CI  22024 10450021
RSIDIND  EQU   36                  INDENT FACTOR-RSID LABEL   CI  22024 10500021
SCBAIND  EQU   79                  INDENT FACTOR-SCBA LABEL   CI  22024 10550021
STATIND  EQU   95                  INDENT FACTOR-STAT LABEL   CI  22024 10560021
NOMORE   EQU   8                                                        10600020
CHAR0    EQU   C'0'                                                     10800020
BLANK    EQU   C' '                                                     11000020
ZERO     EQU   0                                                        11200020
ONE      EQU   1                                                        11400020
TWO      EQU   2                                                        11600020
THREE    EQU   3                                                        11800020
FOUR     EQU   4                                                        12000020
SIX      EQU   6                                                        12200020
SEVEN    EQU   7                                                        12400020
EIGHT    EQU   8                                                        12600020
SIXTEEN  EQU   16                                             CI  22024 12650021
STOPADDR EQU   101                                                      12800020
         EJECT                                                          13000020
         BALR  BASE,ZERO               ESTABLISH ADDRESSABILITY         13200020
         USING *,BASE                                                   13400020
         USING ABDAREA,WORKAREA                                         13600020
         USING LDDSECT,LDREG                                            13800020
         USING IEDQAVTD,AVT                                             14000020
         USING IEDQTNTD,TNT                                             14200020
         USING IEDQTRM,TRM                                              14400020
*                                                                       14600020
* PREPARE TO FORMAT THE TNT ENTRIES                                     14800020
*                                                                       15000020
         LH    NAMECTR,TNTLEN          GET NUMBER OF TNT ENTRIES        15200020
         N     NAMECTR,CLRSIGN         INSURE A POSITIVE SIGN           15400020
         LTR   NAMECTR,NAMECTR         ARE THERE ANY                    15600020
         BZ    EXIT                    NO,BRANCH                        15800020
         LA    TNTENTRY,TNTFIRST       GET ADDR FIRST TNT ENTRY         16000020
         SR    NAMELEN,NAMELEN                                          16200020
         IC    NAMELEN,TNTENLEN        GET LENGTH TERMINAL NAME         16400020
         B     SAVEADDR                BRANCH TO FORMAT NAME            16600020
*                                                                       16800020
* LOCATE NEXT TNT ENTRY                                                 17000020
*                                                                       17200020
FORMNAME SR    NAMELEN,NAMELEN                                          17400020
         IC    NAMELEN,TNTENLEN        GET LENGTH TERMINAL NAME         17600020
         LA    TNTENTRY,THREE(NAMELEN) GET LENGTH TNT ENTRY             17800020
         A     TNTENTRY,ABDWORK2       POINT TO NEXT TNT ENTRY          18000020
SAVEADDR ST    TNTENTRY,ABDWORK2       SAVE ADDR OF TNT ENTRY           18200020
*                                                             CI  22024 18250021
* LOCATE TRM ENTRY ASSOCIATED WITH CURRENT TNT ENTRY          CI  22024 18300021
*                                                             CI  22024 18350021
         LR    FORMREG,TNTENTRY                               CI  22024 18360021
         AR    FORMREG,NAMELEN         POINT TO TRM ADDR      CI  22024 18370021
         MVC   ABDWORK1+ONE(THREE),ZERO(FORMREG)  MOVE ADDR   CI  22024 18380021
*                                                 TO FULLWORD CI  22024 18390021
         L     TRM,ABDWORK1            GET TRM ADDR           CI  22024 18392021
*                                                             CI  22024 18394021
* CHECK IF ENTRY IS AN LGB                                    CI  22024 18394421
*                                                             CI  22024 18394821
         TM    TRMSTATE,TSINGLE        Q. SINGLE OR LGB ENTRY CI  22024 18396021
         BNZ   NOTLGB                  NO,BRANCH              CI  22024 18398021
         TM    TRMDSORG,TRMLGB         Q. LGB TYPE ENTRY      CI  22024 18398421
         BZ    NOTLGB                  NO, BRANCH             CI  22024 18398821
         O     BASE,HIORDER            INDICATE LGB PRESENT   CI  22024 18399221
         B     NEXTTNT                 SKIP LGB'S THIS PASS   CI  22024 18399621
NOTLGB   EQU   *                                              CI  22024 18399721
*                                                                       18400020
* FORMAT TERMINAL NAME                                                  18600020
*                                                                       18800020
         MVC   ABDCC(L'NAMELABL),NAMELABL  MOVE LABEL TO LINE           19000020
         BCTR  NAMELEN,ZERO                GET NAME LENGTH-1  CI  22024 19400021
         EX    NAMELEN,MVCTNTNM            MOVE TERMINAL NAME CI  22024 19600021
         BAL   LINKREG,ABDOUT              PRINT THE LINE               19800020
*                                                                       20000020
* FORMAT CORRESPONDING TRM ENTRY                                        20200020
*                                                                       20400020
         LA    LAYOUT,$TRMLINE         ADDR TRM LAYOUT LINE   AI  22024 21600021
         BAL   LINKREG,FORMAT          FORMAT TRM ADDR                  21800020
         LR    FORMREG,TRM             PREPARE TO FORMAT TRM            22000020
         TM    TRMSTATE,DIST           IS THIS A DISTRIBUTION OR        22200020
*                                        CASCADE TYPE TRM ENTRY         22400020
         BNO   NOTDIST                 NOT DISTRIBUTION       AC A43061 22450021
         TM    TRMSTATE,X'A0'          TEST AGAIN FOR DIST    AC A43061 22500021
         BZ    DISTEN                  YES, BR TO FORMAT      AC A43061 22510021
NOTDIST  EQU   *                                                        22570021
         BAL   LINKREG,FORMAT          FORMAT PART OF TRM LINE          22800020
         TM    TRMDEVFL+ONE,TRMRNTRM   Q. ENTRY FOR 3705      AB  22024 22850021
         BZ    CHECKOPT                NO, BRANCH             CI  22024 22900021
         TM    TRMSTATE,TLINE          Q. LINE ENTRY          CI  22024 22950021
         BNO   NOTLINE                 NO, BRANCH             CI  22024 22960021
         TM    TRMSTATE,X'E0'-TLINE    Q. LINE ENTRY          CI  22024 22970021
         BNZ   NOTLINE                 NO FOR SURE, BRANCH    CI  22024 22980021
*                                                             CI  22024 22990021
* CHANGE LABELS FOR 3705 LINE ENTRY                           CI  22024 22992021
*                                                             CI  22024 22994021
         MVC   ABDLINE+LGBAIND(L'LGBALABL),LGBALABL           CI  22024 22996021
         MVC   ABDLINE+RSIDIND(L'RSIDLABL),RSIDLABL           CI  22024 22998021
         B     CHECKOPT                CHECK OPTION FIELDS    CI  22024 22998421
NOTLINE  EQU   *                                              CI  22024 22998821
*                                                             CI  22024 22999221
* CHANGE LABELS FOR 3705 TERMINAL ENTRY                       CI  22024 22999621
*                                                             CI  22024 22999721
         MVC   ABDLINE+SCBAIND(L'SCBALABL),SCBALABL           CI  22024 22999821
         MVC   ABDLINE+STATIND(L'STATLABL),STATLABL           CI  22024 22999921
CHECKOPT EQU   *                                              CI  22024 23049921
         LA    FORMREG,TRMCHCIN        POINT TO TRMCHCIN FIELD          23099921
         TM    TRMSTATE,TRMOPTFN       ARE OPTION FIELDS USED           23200020
         BZ    NOOPT                   NO,BRANCH                        23400020
*                                                                       23600020
* PREPARE TO FORMAT THE OPTION FIELDS                                   23800020
*                                                                       24000020
         BAL   LINKREG,FORMAT          FORMAT REST OF TRM LINE          24200020
         BAL   LINKREG,ABDOUT          PRINT TRM LINE                   24400020
         MVI   ABDCC,DBLSPACE          DOUBLE SPACE PRINT LINE          24600020
         MVC   ABDLINE+OPNMIND(L'OPTLABEL),OPTLABEL  MOVE LABEL         24800020
         BAL   LINKREG,ABDOUT                        PRINT IT           25000020
         L     OPTABLE,AVTOPTPT        GET ADDR OF OPTION TABLE         25200020
         SR    OPTCTR,OPTCTR           INITIALIZE COUNTER               25400020
         B     FIRSTOPT                BRANCH TO FORMAT 1ST FLD         25600020
NEXTOPT  LA    OPTCTR,ONE(OPTCTR)      INCREMENT COUNTER                25800020
FIRSTOPT LA    OPTPTR,TRMOPT               GET ADDR OF NEXT             26000020
         LA    OPTPTR,ZERO(OPTPTR,OPTCTR)  OPTION OFFSET                26200020
         EX    OPTCTR,CHKOPNO          ANY MORE OPTION FIELDS           26400020
         BNH   ENDOPT                  NO,BRANCH                        26600020
         CLI   ZERO(OPTPTR),UNUSED     IS OPTION FIELD USED             26800020
         BE    NEXTOPT                 NO,BRANCH                        27000020
         LH    WORKREG,TRMOPTBL        GET 2-BYTE OFFSET                27200020
         N     WORKREG,CLRSIGN         INSURE A POSITIVE SIGN           27400020
         SR    FORMREG,FORMREG                                          27600020
         IC    FORMREG,ZERO(OPTPTR)    GET 1-BYTE OFFSET                27800020
         AR    FORMREG,WORKREG         DETERMINE ADDR OF CURRENT        28000020
         AR    FORMREG,OPTABLE           OPTION FIELD                   28200020
*                                                                       28400020
* FORMAT ADDRESS OF OPTION FIELD                                        28600020
*                                                                       28800020
         ST    FORMREG,ABDWORK1                                         29000020
         MVC   ABDLINE+OPADIND(THREE),ABDWORK1+ONE                      29200020
         UNPK  ABDLINE+OPADIND(SEVEN),ABDLINE+OPADIND(FOUR)             29400020
         TR    ABDLINE+OPADIND(SIX),HEXTAB-CHAR0                        29600020
         MVI   ABDLINE+OPADIND+SIX,BLANK                                29800020
*                                                                       30000020
* LOCATE THE APPROPIATE ENTRY IN THE OPTION LOOK-UP TABLE               30200020
*                                                                       30400020
         L     LOOKUP,FOUR(OPTABLE)    GET ADDR LOOK-UP TABLE           30600020
         LR    WORKREG,OPTCTR          DETERMINE ADDR OF LOOK-UP        30800020
         MH    WORKREG,TABLEN            TABLE ENTRY ASSOCIATED         31000020
         AR    LOOKUP,WORKREG            WITH CURRENT OPTION FLD        31200020
*                                                                       31400020
* FORMAT NAME OF OPTION FIELD                                           31600020
*                                                                       31800020
         MVC   ABDLINE+OPNMIND(EIGHT),TWO(LOOKUP)                       32000020
*                                                                       32200020
* FORMAT THE OPTION FIELD ITSELF                                        32400020
*                                                                       32600020
         SR    FLDLEN,FLDLEN                                            32800020
         IC    FLDLEN,ZERO(LOOKUP)     GET LENGTH OF THE CURRENT        33000020
         LA    FLDLEN,ONE(FLDLEN)        OPTION FIELD                   33200020
         BAL   FORMLINK,FORMFLD        FORMAT THE OPTION FIELD          33400020
         B     NEXTOPT                 PROCESS NEXT FIELD               33600020
ENDOPT   LR    FORMREG,OPTPTR          POINT TO NEXT TRM FIELD          33800020
         B     FORMDEVF                FORMAT DEV DEPENDENT FIELDS      34000020
NOOPT    BAL   LINKREG,ABDOUT          PRINT TRM LINE                   34200020
         LA    FORMREG,ONE(FORMREG)    POINT TO NEXT TRM FIELD          34400020
*                                                                       34600020
* TEST FOR PRESENCE OF DEVICE DEPENDENT FIELDS OF TRM                   34800020
*                                                                       35000020
FORMDEVF EQU   *                                              CI  22024 35200021
         LH    MASKREG,TRMDEVFL        GET DEVICE DEP FLAGS   CI  22024 35250021
         SLL   MASKREG,SIXTEEN         LEFT JUSTIFY THEM      CI  22024 35300021
         N     MASKREG,VALIDBIT        MASK OUT UNUSED BITS   AB  22024 35350021
         LA    LABLREG,LABTABL         GET ADDR OF LABELS               35600020
         MVI   ABDCC,DBLSPACE          DOUBLE SPACE PRINT LINE          35800020
         B     TSTDEVFL                BRANCH TO TEST 1ST FLAG          36000020
NULLFLD  BAL   LINKREG,ABDOUT          PRINT LABEL AND NULL FLD         36100020
NEXTFLAG EQU   *                                              CI  22024 36150021
         SLL   MASKREG,ONE             REMOVE BIT JUST TESTED CI  22024 36200021
         SR    LABLEN,LABLEN                                            36800020
         IC    LABLEN,ZERO(LABLREG)    GET LENGTH-1 CURR LABEL          37000020
         LA    LABLREG,TWO(LABLREG)    DETERMINE ADDR OF NEXT           37200020
         AR    LABLREG,LABLEN            LENGTH BYTE IN LABTABL         37400020
TSTDEVFL EQU   *                                              CI  22024 37600021
         LTR   MASKREG,MASKREG         Q. ANY FIELDS USED     AB  22024 37660021
         BZ    NEXTTNT                 NO. BRANCH             AB  22024 37720021
         BP    NEXTFLAG                YES. BUT NOT THIS ONE  AB  22024 37820021
*                                                                       38000020
* FORMAT DEVICE DEPENDENT FIELDS OF TRM                                 38200020
*                                                                       38400020
         SR    LABLEN,LABLEN                                            38600020
         IC    LABLEN,ZERO(LABLREG)    GET LENGTH-1 CURR LABEL          38800020
         EX    LABLEN,MOVELABL         MOVE LABEL TO OUTPUT LINE        39000020
         SR    FLDLEN,FLDLEN                                            39200020
         IC    FLDLEN,ZERO(FORMREG)    GET LENGTH OF FIELD              39400020
         LA    FORMREG,ONE(FORMREG)    POINT TO BEGINNING OF FLD        39600020
         LTR   FLDLEN,FLDLEN           IS FIELD LENGTH ZERO             39800020
         BZ    NULLFLD                 YES,BRANCH                       40000020
         BAL   FORMLINK,FORMFLD        FORMAT THE FIELD                 40200020
         B     NEXTFLAG                TEST NEXT FLAG                   40400020
*                                                                       40600020
* FORMAT DISTRIBUTION OR CASCADE TYPE TRM ENTRY                         40800020
*                                                                       41000020
DISTEN   LA    LAYOUT,DISTLINE         GET ADDR LAYOUT LINE             41200020
         BAL   LINKREG,FORMAT          FORMAT A TRM LINE                41400020
         BAL   LINKREG,ABDOUT          PRINT IT                         41600020
         LH    LISTCTR,TLISTCNT        GET NUMBER LIST INDICES          41800020
         N     LISTCTR,CLRSIGN         INSURE A POSITIVE SIGN           42000020
         LTR   LISTCTR,LISTCTR         ARE THERE ANY                    42200020
         BZ    NEXTTNT                 NO,BRANCH                        42400020
*                                                                       42600020
* FORMAT THE TERMINAL NAMES ASSOCIATED WITH CURRENT DISTRIBUTION        42800020
* OR CASCADE ENTRY                                                      43000020
*                                                                       43200020
         MVI   ABDCC,DBLSPACE          DOUBLE SPACE PRINT LINE          43400020
         MVC   ABDLINE+LISTIND(L'LISTLABL),LISTLABL  MOVE LABEL         43600020
         BAL   LINKREG,ABDOUT                        PRINT IT           43800020
FORMLIST LA    FORMREG,TWO(FORMREG)    POINT TO NEXT TNT INDEX          44000020
         SR    NAMELEN,NAMELEN                                          44200020
         IC    NAMELEN,TNTENLEN        GET LENGTH TERMINAL NAME         44400020
         LA    ENTRYLEN,THREE(NAMELEN) GET LENGTH OF TNT ENTRY          44600020
         LH    TNTINDEX,ZERO(FORMREG)  GET INDEX TO TNT ENTRY           44800020
         N     TNTINDEX,CLRSIGN        INSURE A POSITIVE SIGN           45000020
         LA    TNTENTRY,TNTFIRST       GET ADDR 1ST TNT ENTRY           45200020
         LR    MULTREG,ENTRYLEN                                         45400020
*                                      ADDR OF TNT ENTRY =              45600020
         MR    MULTREG,MULTREG         (LENGTH OF ENTRY * INDEX)        45800020
         SR    PRODUCT,ENTRYLEN        - LENGTH OF ENTRY                46000020
         AR    TNTENTRY,PRODUCT        + ADDR OF 1ST ENTRY              46200020
         BCTR  NAMELEN,ZERO            GET LENGTH-1 OF NAME             46400020
         EX    NAMELEN,MVCLSTNM        MOVE TERMINAL NAME               46600020
         BAL   LINKREG,ABDOUT          PRINT A LINE                     46800020
         BCT   LISTCTR,FORMLIST        BRANCH IF MORE ENTRIES           47000020
*                                        IN LIST                        47200020
NEXTTNT  BCT   NAMECTR,FORMNAME        BRANCH IF MORE TNT               47400020
*                                        ENTRIES TO FORMAT              47600020
*                                                                       47800020
* XCTL TO NEXT ABDUMP LOAD                                              48000020
*                                                                       48200020
EXIT     EQU   *                                              CI  22024 48250021
         LR    SWITCH,BASE             INITIALIZE SWITCH      CI  22024 48260021
         LTR   BASE,BASE               Q. ANY LGB'S FOUND     CI  22024 48300021
         BL    XCTL                    YES, BRANCH            CI  22024 48350021
         SR    SWITCH,SWITCH           INDICATE NO LGB'S      CI  22024 48360021
XCTL     EQU   *                                              CI  22024 48370021
         LA    NMNXTLD,TCAMLD3         GET NAME OF NEXT LOAD            48400021
         LA    XCTLREG,ABDWORK         POINT TO XCTL PARAM LIST         48600020
         XCTL  EPLOC=(NMNXTLD),SF=(E,(15))                              48800020
TCAMLD3  DC    C'IGC0F05A'             NAME OF NEXT ABDUMP LOAD         48900020
*                                                                       49000020
* BRANCH TO FORMAT ROUTINE                                              49200020
*                                                                       49400020
FORMAT   ST    LDREG,ABDSAVE6          SAVE REG 6                       49600020
         L     LDREG,ABDLDADD          GET ADDR OF RESIDENT LOAD        49800020
         B     LDFORMAT                BRANCH TO FORMAT RTN             50000020
*                                                                       50200020
* BRANCH TO OUTPUT ROUTINE                                              50400020
*                                                                       50600020
ABDOUT   ST    LDREG,ABDSAVE6          SAVE REG 6                       50800020
         L     LDREG,ABDLDADD          GET ADDR OF RESIDENT LOAD        51000020
         B     LDOUTPUT                BRANCH TO OUTPUT RTN             51200020
         EJECT                                                          51300020
*                                                                       51400020
* THE FOLLOWING RTN IS ENTERED VIA A BAL AT ENTRY POINT                 51600020
* 'FORMFLD' IN ORDER TO FORMAT THE OPTION FIELDS AND DEVICE             51800020
* DEPENDENT FIELDS ASSOCIATED WITH A TRM ENTRY.  THESE FIELDS           52000020
* ARE FORMATTED IN 4-BYTE GROUPINGS.                                    52200020
*                                                                       52400020
CHKLINE  CR    OUTAREA,ENDLINE         IS OUTPUT LINE FULL              52600020
         BL    NEXTBYTE                NO,FORMAT NEXT BYTE              52800020
PRINTLN  STM   FORMLINK,FLDLEN,ABDWORK SAVE REGS 14 AND 15              53000020
         BAL   LINKREG,ABDOUT          PRINT A LINE                     53200020
         LM    FORMLINK,FLDLEN,ABDWORK RESTORE REGS 14 AND 15           53400020
         LTR   FLDLEN,FLDLEN           ANY MORE BYTES TO FORMAT         53600020
         BCR   NOMORE,FORMLINK         NO,RETURN TO CALLING RTN         53800020
FORMFLD  LA    OUTAREA,ABDLINE+FLDIND  POINT TO OUTPUT LINE             54000020
         LA    ENDLINE,ABDLINE+STOPADDR  ESTABLISH STOP ADDR            54200020
         LA    BYTECTR,FOUR            SET COUNT OF BYTES/GROUP         54400020
NEXTBYTE MVC   ZERO(ONE,OUTAREA),ZERO(FORMREG)       MOVE 1 BYTE        54600020
         UNPK  ZERO(THREE,OUTAREA),ZERO(TWO,OUTAREA) UNPACK IT          54800020
         TR    ZERO(TWO,OUTAREA),HEXTAB-CHAR0        TRANSLATE          55000020
         MVI   TWO(OUTAREA),BLANK                    CLEAR SIGN         55100020
         LA    FORMREG,ONE(FORMREG)    POINT TO NEXT BYTE IN FLD        55200020
         LA    OUTAREA,TWO(OUTAREA)    BUMP OUTPUT LINE PTR             55400020
         BCT   BYTECTR,CHKFLDLN        BRANCH IF LESS THAN              55600020
*                                        4 BYTES IN GROUPING            55800020
         LA    OUTAREA,ONE(OUTAREA)    SPACE 1 BETWEEN GROUPINGS        56000020
         LA    BYTECTR,FOUR            RESET COUNT                      56200020
CHKFLDLN BCT   FLDLEN,CHKLINE          BRANCH IF MORE BYTES TO          56400020
*                                        BE FORMATTED                   56600020
         B     PRINTLN                 PRINT LAST LINE                  56800020
               EJECT                                                    56810020
*                                                                       57000020
* THE FOLLOWING INSTRUCTIONS ARE REACHED VIA AN EXECUTE                 57200020
*                                                                       57400020
MVCTNTNM MVC   ABDLINE+TNTNMIND(ZERO),ZERO(TNTENTRY)  MOVE TERM         57600020
*                                                     NAME WHEN         57800020
*                                                     FORMATTING        58000020
*                                                     TNT ENTRY         58200020
*                                                                       58400020
MVCLSTNM MVC   ABDLINE+LSTNMIND(ZERO),ZERO(TNTENTRY)  MOVE TERM         58600020
*                                                     NAME WHEN         58800020
*                                                     FORMATTING        59000020
*                                                     DIST LIST         59200020
*                                                                       59400020
MOVELABL MVC   ABDLINE+LABLIND(ZERO),ONE(LABLREG)  MOVE LABEL           59600020
*                                                  DESCRIBING           59800020
*                                                  DEVICE               60000020
*                                                  DEPENDENT FLD        60200020
*                                                                       60400020
CHKOPNO  CLI   TRMOPNO,ZERO            COMPARE NUMBER OF OPTION         60600020
*                                      FIELDS WITH NUMBER               60800020
*                                      ALREADY FORMATTED                61000020
         EJECT                                                          61800020
*                                                                       61820020
* LAYOUT LINES -                                                        61840020
*                                                                       61860020
*        EACH LINE TO BE FORMATTED WITH LABELED FIELDS IS               61880020
*        DESCRIBED BY A SEQUENCE OF CONSTANTS CALLED A LAYOUT           61900020
*        LINE.                                                          61920020
*                                                                       61940020
*        THE FIRST BYTE OF EACH LAYOUT LINE AND THE FIRST BYTE          61960020
*        FOLLOWING A X'FF' DELIMITER CONSISTS OF AN INDENTATION         61980020
*        FACTOR WHICH IS EQUAL TO THE NUMBER OF BYTES THAT THE          62000020
*        NEXT FIELD IS TO BE INDENTED IN THE PRINT LINE.                62020020
*                                                                       62040020
*        EACH LABELED FIELD TO BE FORMATTED IS DESCRIBED BY ITS         62060020
*        APPROPRIATE LABEL AND A SEQUENCE OF 4 HEX DIGITS WHICH         62080020
*        PRECEDE THE LABEL IN THE LAYOUT LINE.  THE 4 HEX               62100020
*        DIGITS, X'ABCD', HAVE THE FOLLOWING SIGNIFICANCE :             62120020
*                                                                       62140020
*             A = SIZE OF THE LABEL - 1                                 62160020
*                                                                       62180020
*             B = SIZE OF FIELD BEING FORMATTED - 1                     62200020
*                                                                       62220020
*             C = NUMBER OF BYTES FORMREG MUST BE INCREMENTED TO        62240020
*                 POINT TO THE FIELD BEING FORMATTED                    62260020
*                                                                       62280020
*             D = NUMBER OF BLANKS TO APPEAR BETWEEN THE LABEL          62300020
*                 AND THE FORMATTED FIELD                               62320020
*                                                                       62340020
*        THE X'FF' CONSTANT THAT APPEARS THROUGHOUT THE LAYOUT          62360020
*        LINES IS USED AS A DELIMITER.  IT INDICATES TO THE             62380020
*        FORMAT ROUTINE THAT IT SHOULD STOP FORMATTING AND              62400020
*        RETURN TO THE CALLING ROUTINE.                                 62420020
*                                                                       62440020
$TRMLINE DC    AL1(0)                                         AI  22024 62600021
         DC    X'2202'                                                  62800020
         DC    C'TRM'                                                   63000020
         DC    X'FF'                                                    63200020
         DC    AL1(13)                                                  63400020
         DC    X'A301'                                                  63600020
         DC    C'STATE/DESTQ'                                           63800020
         DC    X'8341'                                                  64000020
         DC    C'IN/OUTSEQ'                                             64200020
         DC    X'9341'                                                  64400020
         DC    C'ALTD/DEVFL'                                            64600020
         DC    X'3341'                                                  64800020
         DC    C'STAT'                                                  65000020
         DC    X'4041'                                                  65200020
         DC    C'CHCIN'                                                 65400020
         DC    X'FF'                                                    65600020
         DC    AL1(100)                                                 65800020
         DC    X'A301'                                                  66000020
         DC    C'/OPNO/OPTBL'                                           66200020
         DC    X'FF'                                                    66400020
DISTLINE DC    AL1(13)                                                  66600020
         DC    X'A301'                                                  66800020
         DC    C'STATE/DESTQ'                                           67000020
         DC    X'7141'                                                  67200020
         DC    C'TLISTCNT'                                              67400020
         DC    X'FF'                                                    67600020
         EJECT                                                          67610020
*                                                                       67620020
* THE FOLLOWING TABLE CONSISTS OF LABELS DESCRIBING THE VARIOUS         67640020
* DEVICE DEPENDENT FIELDS THAT CAN EXIST IN A TRM ENTRY.  EACH          67660020
* LABEL IS PRECEDED BY ITS LENGTH - 1.  THIS TABLE IS USED TO           67680020
* INSERT THE PROPER LABEL IN THE PRINT LINE WHEN THE DEVICE             67700020
* DEPENDENT FIELDS OF A TRM ENTRY ARE BEING FORMATTED.                  67720020
*                                                                       67740020
LABTABL  EQU   *                                                        67800020
         DC    AL1(L'LABEL1-1)                                          67850021
LABEL1   DC    C'BUFFSIZE'                                              67900021
         DC    AL1(L'LABEL2-1)                                          67950021
LABEL2   DC    C'DIAL DIGITS'                                           68000021
         DC    AL1(L'LABEL3-1)                                          68050021
LABEL3   DC    C'ADDR CHAR'                                             68100021
         DC    AL1(L'LABEL4-1)                                          68150021
LABEL4   DC    C'BLOCK'                                                 68200021
         DC    AL1(L'LABEL5-1)                                          68250021
LABEL5   DC    C'SUBBLOCK'                                              68300021
         DC    AL1(L'LABEL6-1)                                          68450021
LABEL6   DC    C'TRANS BLOCK'                                           68500021
         DC    AL1(L'LABEL7-1)                                          68550021
LABEL7   DC    C'BFDELAY'                                               68600021
         DC    AL1(L'LABEL8-1)                                          68650021
LABEL8   DC    C'TIME SHARING'                                          68700021
         DC    AL1(L'LABEL9-1)                                          68750021
LABEL9   DC    C'CONC'                                                  68800021
         DC    AL1(L'LABEL10-1)                                         68850021
LABEL10  DC    C'LMD/MB'                                                68900021
         DC    AL1(L'LABEL11-1)                                         68950021
LABEL11  DC    C'RETRY COUNT'                                           69000021
         DC    AL1(L'LABEL12-1)                                         69050021
LABEL12  DC    C'3705 FIELD'                                            69100021
         EJECT                                                          71010020
*                                                                       71050020
* CONSTANTS                                                             71100020
*                                                                       71150020
         DS    0F                                                       71200020
HIORDER  DC    X'80000000'             MASK TO SET HI BIT     CI  22024 71250021
CLRSIGN  DC    X'0000FFFF'             MASK TO CLEAR SIGN AFTER         71400020
VALIDBIT DC    X'FFF00000'                                              71402021
*                                        LOADING HALFWORDS              71410020
TABLEN   DC    H'10'                   LENGTH OF LOOK-UP ENTRY          71600020
HEXTAB   DC    C'0123456789ABCDEF'     TRANSLATE TABLE                  72000020
NAMELABL DC    C'0NAME'                LABEL FOR TNT NAME FIELD         72200020
LISTLABL DC    C'LIST ENTRIES'         LABEL FOR TRM LIST FIELD         72400020
OPTLABEL DC    C'NAME      ADDR  OPTION FIELD'  LABEL FOR TRM           72600020
*                                               OPTION FIELDS           72800020
LGBALABL DC    C'LSTAT/LGBA '          LABELS FOR 3705        CI  22024 72850021
RSIDLABL DC    C'RSID/TYPE'              LINE ENTRIES         CI  22024 72900021
*                                                             CI  22024 72950021
SCBALABL DC    C'SCBA'                 LABELS FOR 3705        CI  22024 73000021
STATLABL DC    C'STAT1'                  TERMINAL ENTRIES     CI  22024 73050021
         EJECT                                                          73406721
         TAVTD                                                          73410020
         EJECT                                                          73420020
         TTNTD                                                          73430020
         EJECT                                                          73440020
         TTRMD                                                          73450020
         EJECT                                                          78410020
         IHBDMPA                                                        78600020
         END                                                            78800020
