IGC0H05A CSECT                                                          00200020
*  THE FOLLOWING IS THE 8TH TSO LOAD OF ABDUMP.  IT IS IMPLEMENTED      00400020
*  FOR RELEASE 20.                                                      00600020
*                                                                       00800020
*STATUS -- CHANGE LEVEL=0                                               01000020
*                                                                       01200020
*   LIBRARY NAME - IEAQAD0H                                             01400020
*   MODULE NAME  - IGC0H05A                                             01600020
*                                                                       01800020
*FUNCTION -- ABDUMPH PROVIDES FOR THE FORMATTING OF THE FOLLOWING       02000020
*   TIME SHARING OPTION (TSO) CONTROL BLOCKS IN ABEND OR SNAP           02200020
*   DUMP REQUESTS FOR TIME SHARING TASKS.                               02400020
*                                                                       02600020
*      1. DSE  (DATA SET EXTENT)                                        02800020
*      2. PSCB (PROTECTED STORAGE CONTROL BLOCK)                        03000020
*      3. UPT  (USER PROFILE TABLE)                                     03200020
*                                                                       03400020
*ENTRY POINT -- IGC0H05A                                                03600020
*                                                                       03800020
*INPUT --                                                               04000020
*   REGISTERS                                                           04200020
*        REG  4- ADDRESS OF TCB FOR TASK BEING DUMPED                   04400020
*        REG 13- ADDRESS OF ABDUMP'S WORKAREA                           04600020
*                                                                       04800020
*   PSW                                                                 05000020
*        ENABLED                                                        05200020
*        UNDER SUPERVISOR PROTECTION KEY                                05400020
*        IN SUPERVISOR MODE                                             05600020
*                                                                       05800020
*                                                                       06000020
*OUTPUT --     TO NEXT LOAD OF ABDUMP ( IEAQAD0I )                      06200020
*        REG  4- ADDRESS OF TCB FOR TASK BEING DUMPED                   06400020
*        REG 13- ADDRESS OF ABDUMP'S WORKAREA                           06600020
*                                                                       06800020
*                                                                       07000020
*ATTRIBUTES --                                                          07200020
*   TYPE IV SVC,SUPERVISOR STATE,RE-ENTRANT                             07400020
*                                                                       07600020
*                                                                       07800020
*APPLICABILITY --                                                       08000020
*   OPTION IV SYSTEMS                                                   08200020
*                                                                       08400020
*                                                                       08600020
*EXTERNAL REFERENCES -- NONE                                            08800020
*                                                                       09000020
*                                                                       09200020
*SVC USAGE -- XCTL (SVC 7)                                              09400020
*                                                                       09600020
*                                                                       09800020
*TABLES AND CONTROL BLOCKS REFERENCED --                                10000020
*   1) CVT                                                              10200020
*   2) TSCVT                                                            10400020
*   3) JSCB        -JOB STEP CONTROL BLOCK                              10600020
*   4) PSCB        -PROTECTED STORAGE CONTROL BLOCK                     10800020
*   5) TAXE        -TERMINAL ATTENTION EXIT ELEMENT                     11000020
*   6) TJB         -TERMINAL JOB BLOCK                                  11200020
*   7) TJBX        -TERMINAL JOB BLOCK EXTENSION                        11400020
*                                                                       11600020
*                                                                       11800020
*LIST ORIGINS,TABLES,CONTROL BLOCKS INCLUDED                            12000020
*   THE FORMAT OF ABDUMP'S WORK AREA IS DESCRIBED BY THE DSECT          12200020
*   NAMED ABDAREA WHICH IS ASSEMBLED AS APRT OF EACH MODULE.            12400020
*                                                                       12600020
*                                                                       12800020
*OPERATION --                                                           13000020
*    A TEST IS MADE TO DETERMINE IT THE TIME SHARING OPTION IS ACTIVE.  13200020
*    IF TSO IS ACTIVE THEN REGISTER 3 IS LOADED WITH THE ADDRESS OF     13400020
*    THE LAYOUT LINE FOR THE CONTROL BLOCK LINE TO BE FORMATTED AND     13600020
*    REGISTER 2 IS LOADED WITH THE ADDRESS OF THE CONTROL BLOCK TO      13800020
*    BE FORMATTED AND THEN A BRANCH AND LINK IS MADE TO THE RESIDENT    14000020
*    FORMAT ROUTINE FOR THE LINE TO BE FORMATTED AND OUTPUT.  WHEN      14200020
*    THE PSCB,UPT AND ALL THE DSE'S HAVE BEEN OUTPUT CONTROL IS         14400020
*    PASSED TO THE NEXT LOAD OF ABDUMP ( IEAQAD0I ) VIA XCTL.           14600020
*                                                                       14800020
*                                                                       15000020
*                                                                       15200020
*NOTE - THIS MODULE IS CHARACTER CODE DEPENDENT (EBCDIC).               15400020
*                                                                       15600020
         EJECT                                                          15800020
*********************************************************************** 16000020
*                                                                     * 16200020
*                       REGISTER EQUATES                              * 16400020
*                                                                     * 16600020
*********************************************************************** 16800020
TCBREG   EQU   4                       TCB REGISTER                     17000020
RBREG    EQU   3                       RB REGISTER                      17200020
BASEREG  EQU   12                      BASE REGISTER                    17400020
ABDSECT  EQU   13                      ABDAREA DSECT REGISTER           17600020
PARREG   EQU   15                      PARAM. LIST DSECT REG.           17800020
PSCBREG  EQU   2                       ADDRESS OF PSCB TO FORMAT        18000020
R0       EQU   0                       REGISTER                         18200020
R1       EQU   1                       REGISTER                         18400020
R2       EQU   2                       REGISTER                         18600020
R3       EQU   3                       REGISTER                         18800020
R4       EQU   4                       REGISTER                         19000020
R5       EQU   5                       REGISTER                         19200020
R6       EQU   6                       REGISTER                         19400020
R7       EQU   7                       REGISTER                         19600020
R8       EQU   8                       REGISTER                         19800020
R9       EQU   9                       REGISTER                         20000020
RA       EQU   10                      REGISTER                         20200020
RB       EQU   11                      REGISTER                         20400020
RC       EQU   12                      REGISTER                         20600020
*                                                                       20800020
RE       EQU   14                      REGISTER                         21000020
RF       EQU   15                      REGISTER                         21200020
*                                                                       21400020
         SPACE 2                                                        21600020
*                                                                       21800020
*MISC.                                                                  22000020
DBLCC    EQU   C'0'                    CARR CTL FOR DOUBLE SPACE        22200020
         EJECT                                                          22400020
         BALR  BASEREG,0               ESTABLISH                        22600020
         USING *,BASEREG                   ADDRESSABILITY               22800020
         USING ABDAREA,ABDSECT         SET UP COMMON AREA DSECT         23000020
         USING TSCVT,R5                                                 23200020
         USING LDDSECT,R6              SET UP REENTRANT CODE DSECT      23400020
         USING TCB,TCBREG              SET UP TCB DSECT                 23600020
         USING CVTSECT,R3              SET UP CVT DSECT                 23800020
         USING PARDSECT,PARREG         SET UP PARAMETER LIST DSECT      24000020
         SPACE 2                                                        24200020
         L     R3,CVTPTR               GET CVT ADDRESS                  24400020
         L     PARREG,ABDPARA          GET ADDRESS OF PARM LIST         24600020
         TM    CVTTSFLG,CVTTSRDY       IS TIME SHARING ACTIVE           24800020
         BZ    EXIT                    NO - BYPASS FORMAT PROCESSING    25000020
         SPACE 2                                                        25200020
*********************************************************************** 25400020
*                                                                     * 25600020
*             THIS SECTION OF CODE LOCATES AND FORMATS THE            * 25800020
*               PROCTECTED STORAGE CONTROL BLOCK ( PSCB )             * 26000020
*                                                                     * 26200020
*********************************************************************** 26400020
         SPACE 2                                                        26600020
         MVI   ABDCC,DBLCC             SET CARR CTRL CHARACTER          26800020
         L     R7,TCBJSCB              GET ADDRESS OF JSCB              27000020
         LTR   R7,R7                   Q IS THERE A JSCB ?              27200020
         BZ    EXIT                    NO - EXIT                        27400020
         USING IEZJSCB,R7                                               27600020
         L     R9,JSCBPSCB             GET ADDR. OF PSCB TO BE          27800020
*                                      FORMATTED                        28000020
         LTR   R9,R9                   Q ARE THERE ANY PSCB'S ?         28200020
         BZ    FINDDSE                 NO - BYPASS PSCB AND UPT PROCESS 28400020
         USING PSCB,R9                                                  28600020
         LR    R2,R9                   PARAMETER FOR FORMAT RTN         28800020
         ST    R2,ABDWORK1             PUT PSCB ADDR IN WORK AREA       29000020
         LA    R2,ABDWORK1+1           GET ADDR OF FIELD TO BE          29200020
*                                      FORMATTED                        29400020
         LA    R3,PSCBLN1              GET ADDR. OF FIRST LINE          29600020
         BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           29800020
         MVC   ABDLINE+USERDSP(L'USERMSG),USERMSG                       30000020
*                                      MOVE USER LABEL INTO LINE        30200020
         MVC   ABDLINE+USERNM(NAMLNG),PSCBUSER                          30400020
*                                      MOVE USER NAME INTO LINE         30600020
         LR    R2,R9                   RESTORE PARAMETER                30800020
         BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           31000020
         MVC   ABDLINE+GPNDSP(L'GPNMSG),GPNMSG                          31200020
*                                      MOVE GPN LABEL INTO LINE         31400020
         MVC   ABDLINE+GPNAM(GPNLNG),PSCBGPNM                           31600020
*                                      MOVE GROUP NAME INTO LINE        31800020
         BAL   R7,FORMOUT              FORMAT AND OUTPUT LINE 1         32000020
         LA    R3,PSCBLN2              GET ADDR. OF LINE 2              32200020
         BAL   R7,FORMOUT              FORMAT AND OUTPUT LINE 2         32400020
         LA    R3,PSCBLN3              GET ADDR. OF LINE 3              32600020
         BAL   R7,FORMOUT              FORMAT AND OUTPUT LINE 3         32800020
         EJECT                                                          33000020
*********************************************************************** 33200020
*                                                                     * 33400020
*              THIS SECTION OF CODE LOCATES AND FORMATS THE           * 33600020
*                      USER PROFILE TABLE   ( UPT )                   * 33800020
*                                                                     * 34000020
*********************************************************************** 34200020
FINDUPT  EQU   *                                                        34400020
         L     R9,PSCBUPT              GET ADDR. OF USER PROFILE TABLE  34600020
         LTR   R9,R9                   Q ARE THERE ANY UPT'S ?          34800020
         BZ    FINDDSE                 NO - BRANCH                      35000020
FORMUPT  MVI   ABDCC,DBLCC             SET CARR. CTRL CHARACTER         35200020
         LR    R2,R9                   UPT ADDR. FOR FORMAT RTN         35400020
         ST    R2,ABDWORK1             STORE ADDR. OF UPT IN WORKAREA   35600020
         LA    R2,ABDWORK1+1           GET ADDR. OF FIELD TO BE         35800020
*                                      FORMATTED                        36000020
         LA    R3,UPTLN1               GET ADDRESS OF FIRST LINE        36200020
         BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           36400020
         LR    R2,R9                   RESTORE PARAMETER                36600020
         BAL   R7,FORMOUT              FORMAT AND OUTPUT LINE 1         36800020
*********************************************************************** 37000020
*                                                                     * 37200020
*       THIS SECTION LOCATES THE FIRST DATA SET EXTENSION (DSE)       * 37400020
*                         TO BE FORMATTED                             * 37600020
*                                                                     * 37800020
*********************************************************************** 38000020
FINDDSE  L     R7,TCBJSCB              GET ADDRESS OF JSCB              38200020
         LH    R8,JSCBTJID             GET TJID FOR THIS TASK           38400020
         L     R3,CVTPTR               GET ADDRESS OF CVT               38600020
         L     R9,CVTTSCVT             GET ADDRESS OF TSO CVT           38800020
         USING TSCVT,R9                ADDRESSABILITY FOR TSCVT         39000020
         MH    R8,TSCVTSZU             COMPUTE DISPLACEMENT IN          39200020
*                                      TJB LIST                         39400020
         L     R9,TSCVTTJB             GET ADDRESS OF TJB LIST          39600020
         AR    R9,R8                   GET ADDRESS OF TJB FOR           39800020
*                                      THIS TASK                        40000020
         DROP  R9                                                       40200020
         USING TJB,R9                                                   40400020
         L     RA,TJBRCB               GET ADDRESS OF RCB FOR           40600020
*                                      THIS TJID                        40800020
         DROP  R9                                                       41000020
         USING RCB,RA                                                   41200020
         L     R7,RCBEXTNT             GET ADDRESS OF TJBX              41400020
         USING TJBX,R7                                                  41600020
         L     R9,TJBXDSE              GET ADDRESS OF DSE TO BE         41800020
*                                      FORMATTED                        42000020
         LTR   R9,R9                   Q ARE THERE ANY DSE'S ?          42200020
         BZ    NXTLOAD                 NO - BRANCH                      42400020
         DROP  R7                                                       42600020
         USING DSE,R9                                                   42800020
         EJECT                                                          43000020
*********************************************************************** 43200020
*                                                                     * 43400020
*        AT THIS POINT THE DATA SET EXTENSION (DSE) TO BE             * 43600020
*                   FORMATTED HAS BEEN FOUND                          * 43800020
*                                                                     * 44000020
*********************************************************************** 44200020
FORMDSE  EQU   *                                                        44400020
         MVI   ABDCC,DBLCC             SET CARR. CTRL CHARACTER         44600020
         LR    R2,R9                   DSE ADDR. FOR FORMAT RTN         44800020
         ST    R2,ABDWORK1             STORE ADDR. OF DSE IN WORKAREA   45000020
         LA    R2,ABDWORK1+1           GET ADDR. OF FIELD TO BE         45200020
*                                      FORMATTED                        45400020
         LA    R3,DSELN1               GET ADDR. OF FIRST LINE          45600020
         BAL   R5,FORMAT               LINK TO FORMAT LINE 1            45800020
         LR    R2,R9                   RELOAD PARAMETER REGISTER        46000020
         BAL   R5,FORMAT               CONTINUE FORMATTING FIRST LINE   46200020
*                                      OF DSE                           46400020
         MVC   ABDLINE+DDNAMDSP(L'DDNAMMSG),DDNAMMSG                    46600020
*                                      MOVE DDNAM LABEL INTO LINE       46800020
         MVC   ABDLINE+DDNAME(DDNMLNG),DSEDDNAM                         47000020
*                                      MOVE DD NAME INTO LINE           47200020
         BAL   R7,FORMOUT              FORMAT AND OUTPUT LINE           47400020
         LA    R3,DSELN2               GET ADDRESS OF LINE 2            47600020
         BAL   R5,FORMAT               FORMAT LINE 2                    47800020
         SR    RA,RA                   ZERO REG. FOR DS NAME LENGTH     48000020
         IC    RA,DSEDSLNG             GET LENGTH OF DSNAME IN BYTES    48200020
         LTR   RA,RA                   DSNAME LENGTH = ZERO ?           48400020
         BZ    SKIPNAM                 YES - TAKE BRANCH                48600020
         MVC   ABDLINE+DSNAMDSP(L'DSNAMMSG),DSNAMMSG                    48800020
*                                      MOVE DSNAME LABEL INTO LINE      49000020
         LA    RB,ABDLINE+DSNAMLOC     LOCATION IN LINE TO MOVE DSNAME  49200020
         LA    R8,DSEDSNAM             LOCATION IN DSE FROM WHICH       49400020
*                                      DSNAME IS TO BE MOVED            49600020
MVNAM    EQU   *                       BEGIN MOVE OF DSNAME             49800020
         MVC   ZERO(ONE,RB),ZERO(R8)   MOVE DSNAME ONE BYTE AT A TIME   50000020
*                                      INTO ITS LINE POSITION           50200020
         LA    R2,ONE(R2)                                               50400020
         LA    RB,ONE(RB)              INCREMENT TO NEXT BYTE IN LINE   50600020
         LA    R8,ONE(R8)              INCREMENT TO NEXT BYTE OF DSNAME 50800020
         BCT   RA,MVNAM                FALL THROUGH WHEN MOVE OF DSNAME 51000020
*                                      TO OUTPUT LINE IS COMPLETE       51200020
SKIPNAM  BAL   R5,ABDOUT               OUTPUT LINE 3                    51400020
         TM    DSEDSORG,DSEPO          Q PARTITIONED ORGANIZATION ?     51600020
         BZ    NXTDSE                  YES- BRANCH TO GET NEXT DSE      51800020
         MVC   ABDLINE+MEMBRDSP(L'MEMBRMSG),MEMBRMSG                    52000020
*                                      MOVE MEMBR LABEL INTO LINE       52200020
         MVC   ABDLINE+MEMBRNAM(EIGHT),ZERO(R8)                         52400020
*                                      MOVE MEMBR NAME INTO LINE        52600020
         BAL   R5,ABDOUT               OUTPUT LINE 3                    52800020
NXTDSE   L     R7,DSEFORWD             GET ADDRESS OF NEXT DSE          53000020
         LTR   R9,R7                   Q ANY MORE DSE'S ?               53200020
         BNZ   FORMDSE                 YES - TAKE BRANCH                53400020
NXTLOAD  LA    RA,NAMEI                EPLOC OF NEXT LOAD               53600020
         LA    RF,ABDWORK                                               53800020
         XCTL  EPLOC=(RA),SF=(E,(15))                                   54000020
NAMEI    DC    CL8'IGC0I05A'                                            54200020
EXIT     EQU   *                                                        54400020
         L     R6,ABDLDADD             LOAD ADDR. OF REENTRANT CODE     54600020
         B     LDWTG                   GO TO WHERE TO GO                54800020
         EJECT                                                          55000020
*********************************************************************** 55200020
*                                                                     * 55400020
*        THE FOLLOWING CODE PERFORMS THE LINKAGE TO THE               * 55600020
*              FORMAT AND OUT PUT ROUTINES                            * 55800020
*                                                                     * 56000020
*********************************************************************** 56200020
FORMOUT  BAL   R5,FORMAT               LINK TO FORMAT ROUTINE           56400020
         BAL   R5,ABDOUT               LINK TO OUTPUT ROUTINE           56600020
         BR    R7                      RETURN TO CALLER                 56800020
FORMAT   ST    R6,ABDSAVE6             SAVE LINKAGE REGISTER 6          57000020
         L     R6,ABDLDADD             LOAD ADDR TO REENTRANT CODE      57200020
         B     LDFORMAT                GO TO FORMAT ROUTINE             57400020
ABDOUT   ST    R6,ABDSAVE6             SAVE LINKAGE REGISTER 6          57600020
         L     R6,ABDLDADD             LOAD ADDR TO REENTRANT CODE      57800020
         B     LDOUTPUT                GO TO OUTPUT ROUTINE             58000020
*******************************************************************     58200020
*                                                                 *     58400020
*                        LINE FORMAT CONSTANTS                    *     58600020
*                                                                 *     58800020
*******************************************************************     59000020
         SPACE 2                                                        59200020
PSCBLN1  DC    X'00'                   INDENTATION                      59400020
         DC    X'3201'                 DESCRIPTOR BYTES                 59600020
*DESCRIPTOR BYTES FORMAT  DC  X'ABCD'  WHERE                            59800020
*        A=    LABEL LENGTH MINUS 1                                     60000020
*        B=    LENGTH OF FIELD TO BE FORMATTED MINUS 1                  60200020
*        C=    VALUE TO BE ADDED TO REG. 4 TO POINT TO RIGHT FIELD      60400020
*        D=    NUMBER OF BYTES SEPARATING LABEL AND FIELD               60600020
         DC    C'PSCB'                 LABEL                            60800020
         DC    X'FF'                   LINE DELIMITER                   61000020
         DC    AL1(30)                 INDENTATION                      61200020
         DC    X'4072'                 DESCRIPTOR BYTES                 61400020
         DC    C'USERL'                LABEL                            61600020
         DC    X'FF'                   LINE DELIMITER                   61800020
         DC    AL1(58)                 INDENTATION                      62000020
         DC    X'8392'                 DESCRIPTRO BYTES                 62200020
         DC    C'ATR1-ATR2'            LABEL                            62400020
         DC    X'2342'                 DESCRIPTOR BYTES                 62600020
         DC    C'CPU'                  LABEL                            62800020
         DC    X'2342'                 DESCRIPTOR BYTES                 63000020
         DC    C'SWP'                  LABEL                            63200020
         DC    X'FF'                   LINE DELIMITER                   63400020
PSCBLN2  DC    AL1(13)                 INDENTATION                      63600020
         DC    X'3342'                 DESCRIPTOR BYTES                 63800020
         DC    C'LTIM'                 LABEL                            64000020
         DC    X'3342'                 DESCRIPTOR                       64200020
         DC    C'TCPU'                 LABEL                            64400020
         DC    X'3345'                 DESCRIPTOR BYTES                 64600020
         DC    C'TSWP'                 LABEL                            64800020
         DC    X'3342'                 DESCRIPTOR BYTES                 65000020
         DC    C'TCON'                 LABEL                            65200020
         DC    X'3343'                 DESCRIPTOR BYTES                 65400020
         DC    C'TCO1'                 LABEL                            65600020
         DC    X'FF'                   LINE DELIMITER                   65800020
PSCBLN3  DC    AL1(13)                 INDENTATION FACTOR               66000020
         DC    X'3342'                 DESCRIPTOR BYTES                 66200020
         DC    C'RLGB'                 LABEL                            66400020
         DC    X'2343'                 DESCRIPTOR BYTES                 66600020
         DC    C'UPT'                  LABEL                            66800020
         DC    X'6342'                 DESCRIPTOR BYTES                 67000020
         DC    C'UPT-RES'              LABEL                            67200020
         DC    X'2343'                 DESCRIPTOR BYTES                 67400020
         DC    C'RES'                  LABEL                            67600020
         DC    X'4342'                 DESCRIPTOR BYTES       AB A53955 67800021
         DC    C'PSCBU'                LABEL                            68000020
         DC    X'0340'                                                  68200020
         DC    C' '                                                     68400020
         DC    X'FF'                   LINE DELIMITER                   68600020
DSELN1   DC    X'00'                   INDENTATION                      68800020
         DC    X'2202'                 DESCRIPTOR BYTES                 69000020
         DC    C'DSE'                  LABEL                            69200020
         DC    X'FF'                   LINE DELIMITER                   69400020
         DC    AL1(13)                 INDENTATION                      69600020
         DC    X'4302'                 DESCRIPTOR BYTES                 69800020
         DC    C'FORWD'                LABEL                            70000020
         DC    X'4342'                 DESCRIPTOR BYTES                 70200020
         DC    C'BCKWD'                LABEL                            70400020
         DC    X'D342'                 DESCRIPTOR BYTES                 70600020
         DC    C'BLKSZ-RES-CNTR'       LABEL                            70800020
         DC    X'FF'                   LINE DELIMITER                   71000020
         DC    AL1(96)                 INDENTATION                      71200020
         DC    X'43C2'                 DESCRIPTOR BYTES                 71400020
         DC    C'TCBAD'                LABEL                            71600020
         DC    X'FF'                   LINE DELIMITER                   71800020
DSELN2   DC    AL1(13)                 INDENTATION                      72000020
         DC    X'4342'                 DESCRIPTOR BYTES                 72200020
         DC    C'TTRPW'                LABEL                            72400020
         DC    X'F342'                 DESCRIPTOR BYTES   ?????????     72600020
         DC    C'N/DISP-DSORG/LNG'     LABEL                            72800020
         DC    X'FF'                   LINE DELIMITER                   73000020
UPTLN1   DC    X'00'                   INDENTATION                      73200020
         DC    X'2202'                 DESCRIPTOR BYTES                 73400020
         DC    C'UPT'                  LABEL                            73600020
         DC    X'FF'                   LINE DELIMITER                   73800020
         DC    AL1(13)                 INDENTATION                      74000020
         DC    X'2102'                 DESCRIPTER BYTES                 74200020
         DC    C'RES'                  LABEL                            74400020
         DC    X'3322'                 DESCRIPTER BYTES                 74600020
         DC    C'USER'                 LABEL                            74800020
         DC    X'0340'                                                  75000020
         DC    C' '                                                     75200020
         DC    X'0140'                                            M4823 75400020
         DC    C' '                                                     75600020
         DC    X'2022'                 DESCRIPTER BYTES           M4823 75800020
         DC    C'SWS'                  LABEL                            76000020
         DC    X'3012'                 DESCRIPTER BYTES                 76200020
         DC    C'CDEL'                 LABEL                            76400020
         DC    X'3012'                 DESCRIPTER BYTES                 76600020
         DC    C'LDEL'                 LABEL                            76800020
         DC    X'2012'                 DESCRIPTER BYTES                 77000020
         DC    C'RES'                  LABEL                            77200020
         DC    X'FF'                                                    77400020
         EJECT                                                          77600020
*********************************************************************** 77800020
*                                                                     * 78000020
*              LABEL CONSTANTS AND GENERAL EQUATES                    * 78200020
*                                                                     * 78400020
*********************************************************************** 78600020
USERMSG  DC    C'USER'                 USER LABEL                       78800020
GPNMSG   DC    C'GPN'                  GPN LABEL (GROUP NAME)           79000020
DDNAMMSG DC    C'DDNAM'                DDNAME LABEL                     79200020
DSNAMMSG DC    C'DSNAME'               DSNAME LABEL                     79400020
MEMBRMSG DC    C'MEMBR'                MEMBR LABEL                      79600020
ZERO     EQU   0                                                        79800020
ONE      EQU   1                                                        80000020
NAMLNG   EQU   7                       LENGTH OF USER NAME              80200020
EIGHT    EQU   8                                                        80400020
GPNLNG   EQU   8                       LENGTH OF GROUP NAME             80600020
USERDSP  EQU   13                      DISP. IN LINE FOR USER LABEL     80800020
USERNM   EQU   19                      DISP. IN LINE FOR USER NAME      81000020
GPNDSP   EQU   42                      DISP. IN LINE FOR GPN LABEL      81200020
GPNAM    EQU   47                      DISP. IN LINE FOR GP NAME        81400020
DSNAMDSP EQU   59                      DISP. IN LINE FOR DSNAME LABEL   81600020
DSNAMLOC EQU   67                      DISP. IN LINE FOR DSNAME         81800020
DDNAMDSP EQU   77                      DISP. IN LINE FOR DDNAM LABEL    82000020
DDNAME   EQU   84                      DISP. IN LINE FOR DDNAME         82200020
DDNMLNG  EQU   8                       LENGTH OF DDNAME                 82400020
MEMBRDSP EQU   14                      DISP. IN LINE FOR MEMBR LABEL    82600020
MEMBRNAM EQU   21                      DISP. IN LINE FOR MEMBR NAME     82800020
         EJECT                                                          83000020
*********************************************************************** 83200020
*                                                                     * 83400020
*                            DSECTS                                   * 83600020
*                                                                     * 83800020
*********************************************************************** 84000020
CVTSECT  DSECT                                                          84200020
         CVT   SYS=MVT                                                  84400020
         EJECT                                                          84600020
         IHBDMPA                                                        84800020
         EJECT                                                          85000020
         IKJTSCVT                                                       85200020
         EJECT                                                          85400020
         IEZJSCB                                                        85600020
         EJECT                                                          85800020
         IKJRCB                                                         86000020
         EJECT                                                          86200020
         IKJTJB                                                         86400020
         EJECT                                                          86600020
         IKJTJBX                                                        86800020
         EJECT                                                          87000020
         IKJTCB                                                         87200020
         EJECT                                                          87400020
         IKJDSE                                                         87600020
         EJECT                                                          87800020
*         THE CALL FOR IKJUPT WAS REMOVED FOR REL 21.7                  87850021
         EJECT                                                          88200020
         IKJPSCB                                                        88400020
         END                                                            88600020
