IGC0J05A CSECT                                                          00200021
*STATUS CHANGE LEVEL=0                                                  00400021
*   ROUTINE NAME-                                                       00600021
*        IEAQAD0J                                                       00800021
*   FUNCTION-                                                           01000021
*        THIS MODULE OUTPUTS THE GTF TRACE TABLE                        01200021
*   ENTRY POINT NAME-                                                   01400021
*        IGC0J05A                                                       01600021
*   ATTRIBUTES-                                                         01800021
*        TYPE IV SVC,SUPERVISOR STATE,REENTRANT                         02000021
*   APPLICABILITY-                                                      02200021
*        OPTION IV                                                      02400021
*   EXTERNAL REFERENCES-                                                02600021
*        THIS ROUTINE BALRS TO THE FORMAT AND OUTPUT ROUTINES           02800021
*        IN IEAQAD0A                                                    03000021
*   SVC USAGE--NONE                                                     03200021
*   INPUT-                                                              03400021
*        1) POINTER TO THE TCB BEING DUMPED- REG 4                      03600021
*        2) POINTER TO THE ABDUMP WORK AREA- REG 13                     03800021
*   OUTPUT-                                                             04000021
*        GTF TRACE TABLE DUMPED                                         04200021
*   ENTRY POINTS-                                                       04400021
*        1) PSW                                                         04600021
*             A) ENABLED                                                04800021
*             B) UNDER SUPERVISOR PROTECTION KEY                        05000021
*             C) IN SUPERVISOR MODE                                     05200021
*        2) REGISTERS                                                   05400021
*             A) REG 4-POINTER TO TCB BEING DUMPED                      05600021
*             B) REG 13-POINTER TO ABDUMP'S WORK AREA                   05800021
*   EXIT-                                                               06000021
*        TO THE WHERE-TO-GO ROUTINE IN IEAQAD0A.                        06200021
*   TABLE AND CONTROL BLOCK REFERENCED-                                 06400021
*        IEAQAD0J REFERENCES THE FOLLOWING CONTROL BLOCKS-              06600021
*        1) CVT                                                         06800021
*              CVTGTF-GTF FLAGS AND CMT ADDR                            07000021
*        2) CMT (CLASS MASK TABLE)                                      07200021
*              CMTHCT- HCT ADDR                                         07400021
*        3) HCT (HOOK CONTROL TABLE)                                    07600021
*              HCTTCUR- ADDR CURRENT GTF TRACE BUFFER                   07800021
*              HCTFLG2- FLAGS                                           08000021
*              HCTFLG3- FLAGS                                           08200021
*        4) BFX (BUFFER PREFIX AND CONTROL)                             08400021
*              BPXFLGS- FLAGS                                           08600021
*              BPXLINK- ADDR NEXT BPX                                   08800021
*              BPXBUFF- ADDR BUFFER                                     09000021
*        5) TCB                                                         09200021
*              TCBGTOFF- GTF-FREEZE FLAG                                09400021
*                                                                       09600021
** REGISTER EQUATES                                                     09800021
*                                                                       10000021
BASEREG  EQU   12             ROUTINE BASE REG                          10200021
WKREGA   EQU   11             WORK REG FOR CVT,CMT,HCT                  10400021
WKREGB   EQU   9              WORK REG                                  10600021
R5       EQU   5              BALR TO OUTPUT ROUTINE                    10800021
WKREG7   EQU   7                                              AC  M0805 10850021
R6       EQU   6              BASE FOR IEAQAD0A REENTRANT RTNS & ADDR  X11000021
                                                OF  THE OLDEST BUFFER   11050021
R13      EQU   13             BASE FOR ABDUMP WORK AREA                 11200021
TCBREG   EQU   4              ADDR OF TCB CAUSING DUMP                  11400021
R10      EQU   10             REMAINING BUFFER LENGTH, XCTL             11600021
R15      EQU   15             WORK                                      11800021
R7       EQU   7              PTR TO RECORD IN BUFFER                   12000021
WK2      EQU   2                                                        12200021
R3       EQU   3                                                        12400021
R0       EQU   0                   WORK REG                             12600021
R1       EQU   1                   WORK REG                             12800021
R8       EQU   8                                                        13000021
SPACE2CC EQU   X'F0'               2 SPACE CARRIAGE CONTROL             13600021
FF       EQU   X'FF'               TOTAL FLAG BITS MASK                 14400021
F0       EQU   X'F0'               MASK FOR 2ND BYTE SIO EID            14600021
**  GTF RECORD EQUATES                                                  14800021
PFXLENG  EQU   0                   RECORD LENGTH DISPLACEMENT           15000021
PFXAID   EQU   4                   AID DISPLACEMENT                     15200021
PFXFID   EQU   5                   FID DISPLACEMENT                     15400021
PFXTOD   EQU   6                   TOD DISPLACEMENT                     15600021
PFXNOTOD EQU   10                  TIMER UNITS DISPLACEMENT             15800021
CNTRLREC EQU   X'00'               CONTROL RECORD AID MASK              16000021
TIMESTAM EQU   X'04'               TIMESTAMP CNTRL REC FID              16200021
LOSTCNT  EQU   X'06'               LOST EVENT CONTRL REC FID            16400021
TCBFLG1  EQU   X'1D'               TCB FLG FLC DISP           AC  M0805 16450021
FLG4BLNK EQU   X'84'               MASK FOR FORMAT FLAG AND BLNK CNT    16650021
OFFBLANK EQU   X'00'               MASK OFF FORMAT FLAG AND BLNK CNT    16700021
ZONE     EQU   X'F0'              ZONE FOR DECIMAL DIGITS               16730021
DOT      EQU   C'.'          PERIOD FOR LABEL                           16760021
** NUMBER EQUATES                                                       16800021
ZERO     EQU   0              NUMBER 0                                  17000021
ONE      EQU   1              NUMBER 1                                  17200021
TWO      EQU   2              NUMBER 2                                  17400021
THREE    EQU   3              NUMBER 3                                  17600021
FOUR     EQU   4              NUMBER 4                                  17800021
FIVE     EQU   5              NUMBER 5                                  18000021
SIX      EQU   6               NUMBER 6                                 18200021
SEVEN    EQU   7              NUMBER 7                                  18400021
EIGHT    EQU   8              NUMBER 8                                  18600021
NINE     EQU   9              NUMBER 9                                  18800021
TEN      EQU   10             NUMBER 10                                 19000021
TWELV    EQU   12             NUMBER 12                                 19200021
SIXTN    EQU   16             NUMBER 16                                 19600021
SEVNTN   EQU   17            NUMBER 17                                  19800021
TWENTY   EQU   20             NUMBER 20                                 20000021
FORT3    EQU   43             NUMBER 43                                 20800021
SEVENT3  EQU   73             NUMBER 73                                 22000021
EIGHT3   EQU   83             NUMBER 83                                 22200021
NINT5    EQU   95             NUMBER 95                                 22400021
ONE05    EQU   105            NUMBER 105                                22600021
ABDMP000 BALR  BASEREG,0           GET ADDRESSABILITY                   23000021
         USING *,BASEREG           FOR ROUTINE                          23200021
         LTR   R8,R8              IS ENTRY FROM 2ND LOAD-IEAQADOM       23400021
         BNZ   ABDMP100                                                 23600021
         USING ABDAREA,R13         SET UP DSECT FOR ABDUMP WORK AREA    23800021
         USING CVTSECT,WKREGA     SET UP DSECT FOR CVT                  24000021
*** GET ADDRESSABILITY TO HCT; CVT->CMT->HCT                            24200021
         L     WKREGA,CVTPTR       GET CVT PTR                          24400021
         L     WKREGA,CVTGTF       GET CMT ADDR                         24600021
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        24800021
         USING CMTDSECT,WKREGA     SET UP CMT DSECT                     25000021
         L     WKREGA,CMTHCT       GET HCT ADDR                         25200021
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        25400021
         USING HCTDSECT,WKREGA     SET UP HCT DSECT                     25600021
*** GET ADDRESSABILITY TO REENTRANT ROUTINES IN IEAQAD0A                25800021
         USING LDDSECT,R6          SET UP DSECT FOR REENTRANT ROUTINES  26200021
*** PRINT HEADER RECORD AND GET OLDEST BUFFER                           26800021
ABDMP010 MVC   ABDCC(L'TRACHEAD),TRACHEAD  SET UP CARR CNTRL,HEADER     27000021
         BAL   R5,GOOUTPUT                 AND GO PRINT                 27200021
         MVI   ABDCC,SPACE2CC      RESET CARR CNTRL TO SPACE 2          27400021
         L     WKREGB,HCTTCUR      GET ADDR CURRENT TRACE BUFFER PREFIX 27600021
         LA    WKREGB,ZERO(WKREGB) CLEAR HI BYTE                        27800021
         USING BPXDSECT,WKREGB     SET UP BPX DSECT                     28000021
         L     WKREGB,BPXLINK      GET OLDEST   BUFFER                  28200021
         LA    WKREGB,ZERO(WKREGB)  ZERO HI BYTE                        28400021
         LR    R6,WKREGB          SAVE ADDR OLDEST BUFFER               28450021
         B     ABDMP050           GO CHECK OLDEST BUFFER                28500021
*** ALL BUFFERS HAVE BEEN FORMATTED. REISSUE HOOK TO UNFREEZE GTF.      29000021
*** THEN EXIT TO THE WHERE-TO-GO ROUTINE.                               29050021
          USING TCBSECT,TCBREG     SET UP FOR TCB ADDRESSABILITY        29250021
ABDMP025 L     WKREG7,ABDCTCB          GET CURRENT TCB        AC  M0805 29300021
         TM    TCBFLG1(WKREG7),TCBGTOFM HAS HOOK BEEN REISSUED AC M0805 29400021
         BZ    ABDMP030            YES                                  29800021
         HOOK  EID=IHLMABON        UNFREEZE GTF                         30000021
         NI    TCBFLG1(WKREG7),FF-TCBGTOFM RESET  FREEZE FLG  AC  M0805 30200021
ABDMP030 L     R6,ABDLDADD         GET ADDR OF IEAQAD0A                 30250021
         B     LDWTG               BRANCH TO WHERE TO GO                30400021
*** CHECK FOR ACTIVE BUFFER, SET UP TOTAL GTF REC LENGTH IN BUFFER      30600021
ABDMP040  L    WKREGB,BPXLINK      GET NEXT BUFFER                      30650021
         LA    WKREGB,ZERO(WKREGB)  ZERO HI BYTE                        30700021
         CR    R6,WKREGB           IS OLDEST BUFFER NEXT                30750021
         BE    ABDMP025            YES,ALL RECORDS PRINTED              30760021
ABDMP050 TM    BPXFLGS,BPXFULL+BPXSCED+BPXCURR  IS BUFFER IN USE        30800021
         BZ    ABDMP040            NO GO GET NEXT                       31000021
         L     R10,BPXPRLEN        GET BLOCK DESCRIPTOR WORD            31200021
         SRL   R10,SIXTN           RIGHT ALIGN LENGTH FIELD             31400021
         SH    R10,FOURDC          GET ONLY GTF TOTAL RECORDS LENGTH    31600021
         LA    R7,BPXLRLEN         GET ADDR 1ST REC IN BUFFER           31800021
ABDMP060 LTR   R10,R10             HAVE ALL RECORDS IN BUFFER BEEN DONE 32000021
         BNH   ABDMP040            YES                                  32200021
*** CHECK FOR GTF CONTROL REC                                           32400021
         CLI   PFXAID(R7),CNTRLREC IS THIS A CNTRL REC                  32600021
         BNE   ABDMP200            NO                                   32800021
         LA    R8,FOUR            INIT REG 8 FOR 2ND LOAD-CONTROL REC   32850021
         CLI   PFXFID(R7),TIMESTAM IS IT FOR TIMESTAMP                  33000021
         BE    ABDMP600           YES                                   33050021
         CLI   PFXFID(R7),LOSTCNT  IS IT FOR LOST EVENT CNT             33600021
         BE    ABDMP600           YES                                   33800021
ABDMP075 LA    R8,EIGHT           INIT REG 8 FOR 2ND LOAD-ERROR REC     34000021
       B       ABDMP600           GO XCTL                               34200021
*** TEST FOR VALID EID                                                  34400021
ABDMP200 LA    WK2,SIX(R7)         POINT TO EID- NO TIMESTAMP           34600021
         TM    HCTFLG3,HCTTIME     IS THERE A TIMESTAMP IN RECORD       34800021
         BZ    ABDMP205            NO                                   35000021
         LA    WK2,EIGHT(WK2)      YES UP PTR                           35200021
ABDMP205 LA    R15,EIDTABLE        GET ADDR EID LIST                    35400021
         LA    R0,EIDEND          POINT TO END OF TABLE                 35450021
ABDMP210 CR    R15,R0          IS TABLE END REACHED                     35600021
         BE    ABDMP075            YES, EID INVALID, PRINT ERR MSG      35800021
         CLC   ZERO(TWO,R15),ZERO(WK2)  DO EIDS MATCH                   36000021
         BE    ABDMP220            DO EIDS MATCH                        36200021
         LA    R15,FIVE(R15)       POINT TO NEXT EID                    36400021
         B     ABDMP210            GO CHECK EID                         36600021
*** A VALID EID HAS BEEN FOUND                                          36800021
ABDMP220 LA    WK2,TWO(WK2)        GET ADDR OF DATA IN RECORD           37000021
         ST    R15,ABDWORK2       SAVE ADDR OF EID AND LABEL            37200021
         ST    WK2,ABDWORK1        SAVE BEGIN OF DATA                   37400021
*** CHECK TRACE RECORD FOR ERROR -X'EEEE' IN DATA FIELD                 37600021
         CLC   ZERO(TWO,WK2),EES  IS RECORD BAD                         37800021
         BNE   ABDMP225            NO                                   38000021
         LA    R8,TWELV           SET UP FOR 2ND LOAD- EE REC           38200021
         LR     R5,R15            GET EID/LABEL FOR 2ND LOAD            38250021
         B     ABDMP600           GO XCTL                               38400021
*** REPLACE CHARACTER FIELDS **** OR N/A WITH ZEROS FOR FORMAT          38600021
ABDMP225 LA    R3,GTFLINE          GET ADDR GTF LAYOUT LINE             38800021
*** REGS 2,3,AND 6 HAVE BEEN INITIALIZED FOR FORMAT RTN                 40600021
***  GO FORMAT RECORD                                                   40800021
ABDMP240 MVI   ABDBLNKS,FLG4BLNK   INIT FOR 4 BLANKS AFTER FIELD        40850021
         BAL   R5,GOFORMAT         FORMAT 1ST HALF PSW                  41000021
         BAL   R5,GOFORMAT         FORMAT 2ND HALF PSW AND R15          41200021
         BAL   R5,GOFORMAT         FORMAT R0,R1, AND TCB                41400021
         MVI   ABDBLNKS,OFFBLANK  REINIT BLANKS FIELD                   41450021
         L     R15,ABDWORK2       GET ADDR EID AND LABEL                41600021
         MVC   ABDLINE(THREE),TWO(R15)  MOVE IN LABEL                   41800021
         LA    R5,ABDMP280         GET ADDR FOR GO OUTPUT               42000021
         L     WK2,ABDWORK1        LOAD SAVED DATA ADDR                 42200021
*** CHANGE EID-DEPENDENT LABELS                                         42400021
         CLC   ZERO(TWO,R15),PGMEID IS IT PGM                           42600021
         BCR   EIGHT,R5            YES                                  42800021
         CLC   ZERO(TWO,R15),SVCEID IS IT SVC                           43000021
         BCR   EIGHT,R5            YES                                  43200021
         CLC   ZERO(TWO,R15),DSPEID IS IT DSP                           43400021
         BNE   ABDMP250            NO                                   43600021
         MVC   ABDLINE+TEN(THREE),NEWLAB  CHANGE PSW LABEL              43800021
         MVC   ABDLINE+NINT5(THREE),NEWLAB CHANGE TCB LABEL             44000021
         BR    R5                  GO OUTPUT                            44200021
ABDMP250 CLC   ZERO(TWO,R15),EXTEID  IS IT EXTERNAL                     44250021
         BNE   ABDMP260            NO                                   44800021
         CLC   TWENTY(FOUR,WK2),ASTERS  IS TQE  ****                    44850021
         BNE   ABDMP252      NO                                         44900021
         MVC   ABDLINE+ONE05(EIGHT),ASTERS   MOVE ****INTO RECORD       44950021
         B     ABDMP255           GO FINISH RECORD                      45000021
ABDMP252 CLC   TWENTY(FOUR,WK2),NOTAPPL   IS TQE  N/A                   45010021
         BNE   ABDMP255           NO                                    45100021
         MVC    ABDLINE+ONE05(EIGHT),NOTAPPL  MOVE N/A INTO RECORD      45150021
ABDMP255 MVC   ABDLINE+NINT5(THREE),TQE   CHANGE TCB LABEL              45600021
         BR    R5                  GO OUTPUT                            45800021
ABDMP260 CLC   SIXTN(FOUR,WK2),ASTERS    IS RQE TCB ****                45850021
         BNE   ABDMP262           NO                                    45900021
         MVC   ABDLINE+EIGHT3(EIGHT),ASTERS   MOVE **** INTO RECORD     45950021
         B     ABDMP265           GO FINISH RECORD                      46000021
ABDMP262 CLC   SIXTN(FOUR,WK2),NOTAPPL   IS RQE TCB N/A                 46050021
         BNE   ABDMP265           NO                                    46060021
         MVC   ABDLINE+EIGHT3(EIGHT),NOTAPPL  MOVE N/A INTO RECORD      46150021
ABDMP265 CLC   ZERO(TWO,R15),PCIEID IS IT PCI                           46600021
         BE    ABDMP270            YES                                  46800021
         TM    ONE(R15),F0         IS IT SIO1 OR SIO2                   47000021
         BNO   ABDMP275           NO, I/O EID                           47200021
ABDMP270 MVC   ABDLINE+TEN(TEN),CCDEVCAW  MOVE IN IO INFO               47400021
ABDMP275 MVC   ABDLINE+SEVENT3(SEVEN),RQETCB   MOVE IN RQE LABEL        47600021
         MVC   ABDLINE+FORT3(SIX),CSW        MOVE IN CSW LABEL          47800021
ABDMP280 BAL   R5,GOOUTPUT         GO OUTPUT FORMATTED RECORD           48000021
*** PUT OUT TIMESTAMP IF TIME OPTION CHOSEN                             48200021
ABDMP080 TM    HCTFLG3,HCTTIME     DOES TIMESTAMP EXIST FOR EACH RECORD 48400021
         BZ    ABDMP100            NO                                   48600021
* THE TIMESTAMP OUTPUT IS OF THE FORM SSSSS.TTTMMM -SECOND.MICROSEC     48650021
         MVC   ABDLINE(FOUR),TIMEDC     MOVE LABEL TO BUFFER            48700021
         MVC   ABDWORK1(EIGHT),PFXTOD(R7) GET TIME ON FULLWORD BNDRY    48750021
         TM    HCTFLG2,HCTTODCK         Q- TOD CLOCK                    48800021
         BO    ABDMP085                 YES, READY FOR CONVERSION       48850021
         SR    WK2,WK2                  NO, CONVERT TU TO MICROSECONDS  48900021
         L     R3,ABDWORK1+FOUR         GET TIME IN TU                  48950021
         M     WK2,TUCONV               1 TU IS 26.04 MICROSECONDS      49000021
         D     WK2,DECPOINT             CORRECT DECIMAL POINT           49050021
         SR    WK2,WK2                  ZERO OUT REMAINDER              49100021
         M     WK2,ADJUST               AVOID FIXED POINT OVERFLOW      49150021
         B     ABDMP090                GO CONVERT                       49200021
ABDMP085 LM    WK2,R3,ABDWORK1          GET TIME IN TOD CLOCK FORMAT    49250021
         SRDL  WK2,TWELV                SHIFT OUT UNUSED BITS           49300021
ABDMP090 D     WK2,SIXTYMIL            WK2 NOW HAS NUMBER OF SECONDS    49350021
*                                        IN MICROSECONDS AND R3 HAS     49400021
*                                        NUMBER OF MINUTES SINCE EPIC   49450021
         LR    R0,R3                    SAVE MINUTES                    49500021
         LR    R3,WK2                   MOVE SECONDS TO ODD REG         49550021
         LA    R5,ABDMP097              SET ADDRESS TO COME OUT OF LOOP 49600021
         LA    R8,ABDLINE+SEVNTN        ADDRESS OF END OF FIELD         49650021
         LA    R1,SIX                   SET LOOP CONTROL                49700021
ABDMP095 SR    WK2,WK2                  CLEAR EVEN REG FOR DIVIDE       49750021
         D     WK2,TENDC                CONVERT TO DECIMAL              49800021
         STC   WK2,ZERO(R8)             STORE IN BUFFER                 49850021
         OI    ZERO(R8),ZONE            CONVERT TO EBCDIC               49900021
         BCTR  R8,ZERO                  DECREMENT BUFFER POINTER        49950021
        BCT    R1,ABDMP095             LOOP CONTROL                     50000021
         BR    R5                       RETURN TO CALLER                50050021
ABDMP097 MVI   ZERO(R8),DOT             PUT DECIMAL POINT IN BUFFER     50100021
         BCTR  R8,ZERO                  DECREMENT BUFFER POINTER        50150021
         LR    R1,R3                    SAVE SECONDS                    50200021
         SR    WK2,WK2                  CLEAR EVEN REG FOR DIVIDE       50250021
         LR    R3,R0                    GET MINUTES                     50300021
         D     WK2,MINPRDAY             GET MINUTES LEFT IN DAY         50350021
         LR    R3,WK2                   SAVE MINUTES PER DAY            50400021
         SR    WK2,WK2                  CLEAR REG FOR MULTIPLY          50450021
         M     WK2,SIXTYDC              CONVERT TO SECONDS              50500021
         AR    R3,R1                    ADD SECONDS                     50550021
         LA    R1,FIVE                  SET COUNTER FOR LOOP            50600021
         BAL   R5,ABDMP095              CONVERT SECONDS TO EBCDIC       50650021
ABDMP087 BAL   R5,GOOUTPUT         GO OUTPUT TIMESTAMP                  50800021
*** UPDATE POINTER TO NEXT RECORD AND GO GET NEXT RECORD                51000021
ABDMP100 SH    R10,ZERO(R7)        GET REMAINING LENGTH OF RECS IN BUFF 51200021
         AH    R7,ZERO(R7)         POINT TO NEXT RECORD                 51400021
         B     ABDMP060            GO TEST RECORD                       51600021
ABDMP600 LA    R1,LOADOM          POINT TO LOAD NAME                    60400021
         LA    R15,ABDWORK        SET UP FOR XCTL                       60600021
         XCTL  EPLOC=(R1),SF=(E,(R15))    XCTL TO IGC0M05A              60800021
*** GOOUTPUT AND GOFORMAT SAVE REG 6 BEFORE GOING TO IEAQAD0A.          60850021
*** IEAQAD0A UPON RETURN LOADS THE SAVED CONTENTS INTO REG6 AND         60900021
*** RETURNS ON REG 5.                                                   60950021
GOOUTPUT ST    R6,ABDSAVE6         SAVE THE OLD BUFFER ADDR             60960021
         L     R6,ABDLDADD         GET ADDR OF IEAQAD0A                 60970021
         B     LDOUTPUT            GO TO IEAQAD0A'S OUTPUT RTN          60980021
GOFORMAT ST    R6,ABDSAVE6         SAVE THE OLD BUFFER ADDR             60990021
         L     R6,ABDLDADD         GET ADDR OF IEAQAD0A                 60992021
         B     LDFORMAT            GO TO IEAQAD0A'S FORMAT RTN          60994021
***                                                                     61000021
***   G T F   C O N S T A N T S                                         61200021
***                                                                     61400021
SIXTYMIL DC    F'60000000'        DIVIDER FOR MINUTES AND SECONDS       61420021
TENDC    DC    F'10'              DIVIDER FOR HEX TO DECIMAL            61440021
ADJUST   DC    F'100'             CONSTANTS FOR TIMER                   61460021
DECPOINT DC    F'100000000'                 UNIT CONVERSION             61480021
TUCONV   DC    F'26041667'                            TO MICROSECONDS   61500021
MINPRDAY DC    F'1440'                  MINUTES PER DAY                 61520021
SIXTYDC  DC    F'60'              SECONDS PER MINUTE                    61540021
TRACHEAD DC    C'-GTF TRACE TABLE' HEADER FOR GTF TRACE                 61600021
EES      DC    X'EEEE'             INDICATOR OF BAD RECORD              61800021
NEWLAB  DC    C'NEW'               NEW LABEL                            62000021
TQE      DC    C'TQE'              TQE LABEL                            62200021
CCDEVCAW DC    C'CC/DEV/CAW'       IO LABEL                             62400021
RQETCB   DC    C'RQE TCB'          RQETCB LABEL                         62600021
CSW      DC    C'CSW   '              CSW LABEL                         62800021
ASTERS   DC    C'********'         INDICATES ERROR IN GETTING TCB ADDR  63000021
NOTAPPL  DC    C'N/A     '        INDICATES TCB ADDR NOT APPLICABLE     63200021
FOURDC   DC    H'4'                CONSTANT 4                           63400021
LOADOM   DC    C'IGC0M05A'        NAME OF 2ND GTF TRACE FORMAT LOAD     63600021
***                                                                     65200021
***  GTF TRACE TABLE LAYOUT LINE                                        65400021
***                                                                     65600021
GTFLINE  DC    AL1(10)             DISPLACEMENT TO PSW LABEL            65800021
         DC    X'6305'             CONTROL BYTES FOR FORMAT RTN         66000021
         DC    C'OLD PSW'          1ST LABEL                            66200021
         DC    X'FF'               RETURN,MORE THAN 4 BYTES TO FORMAT   66400021
         DC    AL1(30)             DISPLACEMENT TO 2ND HALF PSW         66600021
         DC    X'0340'             CONTROL BYTES                        66800021
         DC    C' '                BLANK                                67000021
         DC    X'5343'             CONTROL BYTES                        67200021
         DC    C'R15/R0'           2ND LABEL                            67400021
         DC    X'FF'               RETURN, MORE THAN 4 BYTES TO FORMAT  67600021
         DC    AL1(60)             DISPLACEMENT TO R0                   67800021
         DC    X'0340'             CONTROL BYTES                        68000021
         DC    C' '                BLANK                                68200021
         DC    X'1348'             CONTROL BYTES                        68400021
         DC    C'R1'              3RD LABEL                             68600021
         DC    X'6343'             CONTROL BYTES                        68800021
         DC    C'OLD TCB'          4TH LABEL                            69000021
         DC    X'FF'               END OF GTF TRACE LINE                69200021
***  THESE EIDS AND THEIR LABELS MUST BE KEPT CONTIGUOUS                69400021
EIDTABLE EQU   *                   ADDR EID TABLE                       69600021
PCIEID   DC    X'2FDF'             PCI EID                              69800021
         DC    C'PCI'              PCI LABEL                            70000021
SVCEID   DC    X'3FFF'             SVC EID                              70200021
         DC    C'SVC'              SVC LABEL                            70400021
DSPEID   DC    X'4FE7'             DSP EID                              70600021
         DC    C'DSP'              DSP LABEL                            70800021
IOEID1   DC    X'5FEE'             I/O EID1                             71000021
         DC    C'I/O'              I/O LABEL                            71200021
IOEID2   DC    X'5FEF'             I/O EID2                             71400021
         DC    C'I/O'              I/O LABEL                            71600021
SIOEID1  DC    X'5FF0'             SIO EID1                             71800021
         DC    C'SIO'              SIO LABEL                            72000021
PGMEID   DC    X'DFFD'             PGM EID                              72600021
         DC    C'PGM'              PGM LABEL                            72800021
EXTEID   DC    X'DFFE'             EXT EID                              73000021
         DC    C'EXT'              EXT LABEL                            73200021
EIDEND   EQU   *                   END OF TABLE ADDR                    73400021
TIMEDC   DC    C'TIME'             TIME LABEL                           74200021
***                                                                     75250021
          IHBABCTL                                                      75300021
***                                                                     75800021
CMTDSECT CMT                                                            76000021
***                                                                     76200021
HCTDSECT HCT                                                            76400021
***                                                                     76600021
         IHBDMPA                                                        76800021
***                                                                     77000021
BPXDSECT BPX                                                            77200021
       END                                                              77400021
