     TITLE  'IEAQAD0K / ABDUMP13 / IGC0K05A'                            00000521
IGC0K05A CSECT                                                          00001021
*STATUS CHANGE LEVEL=0                                                  00001521
*   ROUTINE NAME-                                                       00002021
*        IEAQAD0K                                                       00002521
*   FUNCTION-                                                           00003021
*        THIS MODULE OUTPUTS THE GTF TRACE TABLE FOR MP                 00003521
*   ENTRY POINT NAME-                                                   00004021
*        IGC0K05A                                                       00004521
*   ATTRIBUTES-                                                         00005021
*        TYPE IV SVC,SUPERVISOR STATE,REENTRANT                         00005521
*   APPLICABILITY-                                                      00006021
*        OPTION IV                                                      00006521
*   EXTERNAL REFERENCES-                                                00007021
*        THIS ROUTINE BALRS TO THE FORMAT AND OUTPUT ROUTINES           00007521
*        IN IEAQAD0A                                                    00008021
*   SVC USAGE--NONE                                                     00008521
*   INPUT-                                                              00009021
*        1) POINTER TO THE TCB BEING DUMPED- REG 4                      00009521
*        2) POINTER TO THE ABDUMP WORK AREA- REG 13                     00010021
*   OUTPUT-                                                             00010521
*        GTF TRACE TABLE DUMPED                                         00011021
*   ENTRY POINTS-                                                       00011521
*        1) PSW                                                         00012021
*             A) ENABLED                                                00012521
*             B) UNDER SUPERVISOR PROTECTION KEY                        00013021
*             C) IN SUPERVISOR MODE                                     00013521
*        2) REGISTERS                                                   00014021
*             A) REG 4-POINTER TO TCB BEING DUMPED                      00014521
*             B) REG 13-POINTER TO ABDUMP'S WORK AREA                   00015021
*   EXIT-                                                               00015521
*        TO THE WHERE-TO-GO ROUTINE IN IEAQAD0A.                        00016021
*   TABLE AND CONTROL BLOCK REFERENCED-                                 00016521
*        IEAQAD0K REFERENCES THE FOLLOWING CONTROL BLOCKS-              00017021
*        1) CVT                                                         00017521
*              CVTGTF-GTF FLAGS AND CMT ADDR                            00018021
*        2) CMT (CLASS MASK TABLE)                                      00018521
*              CMTHCT- HCT ADDR                                         00019021
*        3) HCT (HOOK CONTROL TABLE)                                    00019521
*              HCTTCUR- ADDR CURRENT GTF TRACE BUFFER                   00020021
*              HCTFLG2- FLAGS                                           00020521
*              HCTFLG3- FLAGS                                           00021021
*        4) BFX (BUFFER PREFIX AND CONTROL)                             00021521
*              BPXFLGS- FLAGS                                           00022021
*              BPXLINK- ADDR NEXT BPX                                   00022521
*              BPXBUFF- ADDR BUFFER                                     00023021
*        5) TCB                                                         00023521
*              TCBGTOFF- GTF-FREEZE FLAG                                00024021
*                                                                       00024521
** REGISTER EQUATES                                                     00025021
*                                                                       00025521
BASEREG  EQU   12             ROUTINE BASE REG                          00026021
WKREGA   EQU   11             WORK REG FOR CVT,CMT,HCT                  00026521
WKREGB   EQU   9              WORK REG                                  00027021
R5       EQU   5              BALR TO OUTPUT ROUTINE                    00027521
R6       EQU   6              BASE FOR IEAQAD0A REENTRANT RTNS AND     X00028021
                                          ADDR  OF THE OLDEST BUFFER    00028521
R13      EQU   13             BASE FOR ABDUMP WORK AREA                 00029021
TCBREG   EQU   4              ADDR OF TCB CAUSING DUMP                  00029521
R10      EQU   10             REMAINING BUFFER LENGTH, XCTL             00030021
R15      EQU   15             WORK                                      00030521
WKREG7   EQU   7                                              AB  M0805 00030921
R7       EQU   7              PTR TO RECORD IN BUFFER                   00031021
WK2      EQU   2                                                        00031521
R3       EQU   3                                                        00032021
R0       EQU   0                   WORK REG                             00032521
R1       EQU   1                   WORK REG                             00033021
R8       EQU   8                                                        00033521
SPACE2CC EQU   X'F0'               2 SPACE CARRIAGE CONTROL             00034021
FF       EQU   X'FF'               TOTAL FLAG BITS MASK                 00034521
F0       EQU   X'F0'               MASK FOR 2ND BYTE SIO EID            00035021
ZONE     EQU   X'F0'              ZONE FOR DECIMAL DIGITS               00035521
DOT      EQU   C'.'          PERIOD FOR LABEL                           00036021
**  GTF RECORD EQUATES                                                  00036521
PFXLENG  EQU   0                   RECORD LENGTH DISPLACEMENT           00037021
PFXAID   EQU   4                   AID DISPLACEMENT                     00037521
PFXFID   EQU   5                   FID DISPLACEMENT                     00038021
PFXTOD   EQU   6                   TOD DISPLACEMENT                     00038521
PFXNOTOD EQU   10                  TIMER UNITS DISPLACEMENT             00039021
CNTRLREC EQU   X'00'               CONTROL RECORD AID MASK              00039521
TIMESTAM EQU   X'04'               TIMESTAMP CNTRL REC FID              00040021
LOSTCNT  EQU   X'06'               LOST EVENT CONTROL REC FID           00040521
TCBFLG1  EQU   X'1D'                                          AB  M0805 00040921
FLG4BLNK EQU   X'84'               MASK FOR FORMAT FLAG AND BLNK CNT    00067821
FLG2BLNK EQU   X'82'               MASK FOR FORMAT FLAG AND BLNK CNT    00068921
OFFBLANK EQU   X'00'               MASK OFF FORMAT FLAG AND BLNK CNT    00070021
** NUMBER EQUATES                                                       00071121
ZERO     EQU   0              NUMBER 0                                  00072221
ONE      EQU   1              NUMBER 1                                  00073321
TWO      EQU   2              NUMBER 2                                  00074421
THREE    EQU   3              NUMBER 3                                  00075521
FOUR     EQU   4              NUMBER 4                                  00076621
FIVE     EQU   5              NUMBER 5                                  00077721
SIX      EQU   6               NUMBER 6                                 00078821
SEVEN    EQU   7              NUMBER 7                                  00079921
EIGHT    EQU   8              NUMBER 8                                  00081021
TEN      EQU   10             NUMBER 10                                 00082121
TWELV    EQU   12             NUMBER 12                                 00083221
SIXTN    EQU   16             NUMBER 16                                 00084321
SEVNTN   EQU   17            NUMBER 17                                  00085421
TWENT4   EQU   24             NUMBER 24                                 00086521
TWENT8   EQU   28            NUMBER 28                        CH M1547  00087621
FORT3    EQU   43             NUMBER 43                                 00088721
SIXT9    EQU   69             NUMBER 69                                 00089821
SEVENT7  EQU   77             NUMBER 77                                 00090921
EIGHT7   EQU   87             NUMBER 87                                 00092021
ONE04    EQU   104            NUMBER 104                                00093121
ONE12    EQU   112            NUMBER 112                                00094221
ABDMP000 BALR  BASEREG,0           GET ADDRESSABILITY                   00095321
         USING *,BASEREG           FOR ROUTINE                          00096421
         LTR   R8,R8              IS ENTRY FROM 2ND LOAD-IEAQADOM       00097521
         BNZ   ABDMP100            YES                                  00098621
         USING ABDAREA,R13         SET UP DSECT FOR ABDUMP WORK AREA    00099721
         USING CVTSECT,WKREGA     SET UP DSECT FOR CVT                  00100821
*** GET ADDRESSABILITY TO HCT; CVT->CMT->HCT                            00101921
         L     WKREGA,CVTPTR       GET CVT PTR                          00103021
         L     WKREGA,CVTGTF       GET CMT ADDR                         00104121
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        00105221
         USING CMTDSECT,WKREGA     SET UP CMT DSECT                     00106321
         L     WKREGA,CMTHCT       GET HCT ADDR                         00107421
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        00108521
         USING HCTDSECT,WKREGA     SET UP HCT DSECT                     00109621
         USING LDDSECT,R6          SET UP DSECT FOR REENTRANT ROUTINES  00110721
*** PRINT HEADER RECORD AND GET OLDEST BUFFER                           00111821
ABDMP010 MVC   ABDCC(L'TRACHEAD),TRACHEAD  SET UP CARR CNTRL,HEADER     00112921
         BAL   R5,GOOUTPUT                 AND GO PRINT                 00114021
         MVI   ABDCC,SPACE2CC      RESET CARR CNTRL TO SPACE 2          00115121
         L     WKREGB,HCTTCUR      GET ADDR CURRENT TRACE BUFFER PREFIX 00116221
         LA    WKREGB,ZERO(WKREGB) CLEAR HI BYTE                        00117321
         USING BPXDSECT,WKREGB     SET UP BPX DSECT                     00118421
         L     WKREGB,BPXLINK      GET OLDEST BUFFER                    00119521
         LA    WKREGB,ZERO(WKREGB)  ZERO HI BYTE                        00120621
         LR    R6,WKREGB          SAVE OLDEST BUFFER                    00121721
         B     ABDMP050           GO TEST BUFFER                        00122821
*** ALL BUFFERS HAVE BEEN FORMATTED. PRINT TRAILER,UNFREEZE GTF,        00123921
***                                  AND EXIT TO WHERE-TO-GO RTN        00125021
          USING TCBSECT,TCBREG     SET UP FOR TCB ADDRESSABILITY        00126121
ABDMP025 L     WKREG7,ABDCTCB      GET CURRENT TCB            AB  M0805 00127121
         TM    TCBFLG1(WKREG7),TCBGTOFM HOOK REISSUED FOR TCB AB  M0805 00127521
         BZ    ABDMP030            NO                                   00128321
         HOOK  EID=IHLMABON        UNFREEZE GTF                         00129421
         NI    TCBFLG1(WKREG7),FF-TCBGTOFM  RESET FREEZE FLAG AB  M0805 00130521
ABDMP030 L     R6,ABDLDADD         GET ADDR IEAQAD0A                    00131621
         B     LDWTG               BRANCH TO WHERE TO GO                00132721
*** CHECK FOR ACTIVE BUFFER, SET UP TOTAL GTF REC LENGTH IN BUFFER      00133821
ABDMP040 L     WKREGB,BPXLINK     GET NEXT BUFFER                       00134921
         LA    WKREGB,ZERO(WKREGB) CLEAR HI BYTE              CH M1547  00136021
         CR    R6,WKREGB          IS OLDEST BUFFER NEXT                 00137121
         BE    ABDMP025           YES,ALL THROUGH                       00138221
ABDMP050 TM    BPXFLGS,BPXFULL+BPXSCED+BPXCURR  IS BUFFER IN USE        00139321
         BZ    ABDMP040            NO GO GET NEXT                       00140421
         L     R10,BPXPRLEN        GET BLOCK DESCRIPTOR WORD            00141521
         SRL   R10,SIXTN           RIGHT ALIGN LENGTH FIELD             00142621
         SH    R10,FOURDC          GET ONLY GTF TOTAL RECORDS LENGTH    00143721
         LA    R7,BPXLRLEN         GET ADDR 1ST REC IN BUFFER           00144821
ABDMP060 LTR   R10,R10             HAVE ALL RECORDS IN BUFFER BEEN DONE 00145921
         BNH   ABDMP040            YES                                  00147021
*** CHECK FOR GTF CONTROL REC                                           00148121
         CLI   PFXAID(R7),CNTRLREC IS THIS A CNTRL REC                  00149221
         BNE   ABDMP200            NO                                   00150321
         LA    R8,FOUR            INIT REG 8 FOR 2ND LOAD-CONTROL REC   00151421
         CLI   PFXFID(R7),TIMESTAM IS IT FOR TIMESTAMP                  00152521
         BE    ABDMP600           YES                                   00153621
         CLI   PFXFID(R7),LOSTCNT  IS IT FOR LOST EVENT CNT             00154721
         BE    ABDMP600           YES                                   00155821
ABDMP075 LA    R8,EIGHT           INIT REG 8 FOR 2ND LOAD-ERROR REC     00156921
       B       ABDMP600           GO XCTL                               00158021
*** TEST FOR VALID EID                                                  00159121
ABDMP200 LA    WK2,SIX(R7)         POINT TO EID- NO TIMESTAMP           00160221
         TM    HCTFLG3,HCTTIME     IS THERE A TIMESTAMP IN RECORD       00161321
         BZ    ABDMP205            NO                                   00162421
         LA    WK2,EIGHT(WK2)      YES UP PTR                           00163521
ABDMP205 LA    R15,EIDTABLE        GET ADDR EID LIST                    00164621
         LA    R0,EIDEND          POINT TO END OF TABLE                 00165721
ABDMP210 CR    R15,R0          IS TABLE END REACHED                     00166821
         BE    ABDMP075            YES, EID INVALID, PRINT ERR MSG      00167921
         CLC   ZERO(TWO,R15),ZERO(WK2)  DO EIDS MATCH                   00169021
         BE    ABDMP220            DO EIDS MATCH                        00170121
         LA    R15,FIVE(R15)       POINT TO NEXT EID                    00171221
         B     ABDMP210            GO CHECK EID                         00172321
*** A VALID EID HAS BEEN FOUND                                          00173421
ABDMP220 LA    WK2,TWO(WK2)        GET ADDR OF DATA IN RECORD           00174521
         ST    R15,ABDWORK2       SAVE ADDR OF EID AND LABEL            00175621
         ST    WK2,ABDWORK1        SAVE BEGIN OF DATA                   00176721
*** CHECK TRACE RECORD FOR ERROR -X'EEEE' IN DATA FIELD                 00177821
         CLC   ZERO(TWO,WK2),EES  IS RECORD BAD                         00178921
         BNE   ABDMP225            NO                                   00180021
         LA    R8,TWELV           SET UP FOR 2ND LOAD- EE REC           00181121
         LR     R5,R15            GET EID/LABEL FOR 2ND LOAD            00182221
         B     ABDMP600           GO XCTL                               00183321
*** REPLACE CHARACTER FIELDS **** OR N/A WITH ZEROS FOR FORMAT          00184421
ABDMP225 LA    R3,GTFLINE          GET ADDR GTF LAYOUT LINE             00185521
*** REGS 2,3,AND 6 HAVE BEEN INITIALIZED FOR FORMAT RTN                 00186621
***  GO FORMAT RECORD                                                   00187721
ABDMP240 MVI   ABDBLNKS,FLG4BLNK   INIT FOR 4 BLANKS AFTER FIELD        00188821
         BAL   R5,GOFORMAT         FORMAT 1ST HALF PSW                  00189921
         BAL   R5,GOFORMAT         FORMAT 2ND HALF PSW AND R15          00191021
         MVI   ABDBLNKS,FLG2BLNK   INIT FOR 2 BLANKS AFTER FIELD        00192121
         BAL   R5,GOFORMAT         FORMAT R0,R1, AND TCBS A&B           00193221
         MVI   ABDBLNKS,OFFBLANK  REINIT BLANKS FIELD                   00194321
         L     R15,ABDWORK2       GET ADDR EID AND LABEL                00195421
         MVC   ABDLINE+THREE(THREE),TWO(R15)  MOVE IN LABEL             00196521
         LA    R5,ABDMP280         GET ADDR FOR GO OUTPUT               00197621
         L     WK2,ABDWORK1        LOAD SAVED DATA ADDR                 00198721
         MVC   ABDLINE(ONE),TWENT8(WK2)  MOVE IN CPUID        CH M1547  00199821
*** CHANGE EID-DEPENDENT LABELS                                         00200921
         CLC   ZERO(TWO,R15),PGMEID IS IT PGM                           00202021
         BCR   EIGHT,R5            YES                                  00203121
         CLC   ZERO(TWO,R15),SVCEID IS IT SVC                           00204221
         BCR   EIGHT,R5            YES                                  00205321
         CLC   ZERO(TWO,R15),DSPEID IS IT DSP                           00206421
         BNE   ABDMP250            NO                                   00207521
         MVC   ABDLINE+TEN(THREE),RESLAB  CHANGE PSW LABEL              00208621
         MVC   ABDLINE+EIGHT7(TWO),NEWLAB CHANGE TCB LABEL FOR A        00209721
         MVC   ABDLINE+ONE04(TWO),NEWLAB CHANGE TCB LABEL FOR B         00210821
         BR    R5                  GO OUTPUT                            00211921
ABDMP250 CLC   ZERO(TWO,R15),EXTEID  IS IT EXTERNAL                     00213021
         BNE   ABDMP260            NO                                   00214121
         MVC   ABDLINE+EIGHT7(FIVE),STMSK  MOVE IN STMSK LABEL          00215221
         CLC   TWENT4(FOUR,WK2),ASTERS  IS TQE  ****                    00216321
         BNE   ABDMP252      NO                                         00217421
         MVC   ABDLINE+ONE12(EIGHT),ASTERS   MOVE ****INTO RECORD       00218521
         B     ABDMP255           GO FINISH RECORD                      00219621
ABDMP252 CLC   TWENT4(FOUR,WK2),NOTAPPL   IS TQE  N/A                   00220721
         BNE   ABDMP255           NO                                    00221821
         MVC    ABDLINE+ONE12(EIGHT),NOTAPPL  MOVE N/A INTO RECORD      00222921
ABDMP255 MVC   ABDLINE+ONE04(SEVEN),TQE   CHANGE TCB LABEL              00224021
         BR    R5                  GO OUTPUT                            00225121
ABDMP260 CLC   SIXTN(FOUR,WK2),ASTERS    IS RQE TCB ****                00226221
         BNE   ABDMP262           NO                                    00227321
         MVC   ABDLINE+SEVENT7(EIGHT),ASTERS   MOVE **** INTO RECORD    00228421
         B     ABDMP265           GO FINISH RECORD                      00229521
ABDMP262 CLC   SIXTN(FOUR,WK2),NOTAPPL   IS RQE TCB N/A                 00230621
         BNE   ABDMP265           NO                                    00231721
         MVC   ABDLINE+SEVENT7(EIGHT),NOTAPPL  MOVE N/A INTO RECORD     00232821
ABDMP265 CLC   ZERO(TWO,R15),PCIEID IS IT PCI                           00233921
         BE    ABDMP270            YES                                  00235021
         TM    ONE(R15),F0         IS IT SIO1                           00236121
         BNO   ABDMP275           NO, I/O EID                           00237221
ABDMP270 MVC   ABDLINE+TEN(TEN),CCDEVCAW  MOVE IN IO INFO               00238321
ABDMP275 MVC   ABDLINE+SIXT9(SEVEN),RQETCB   MOVE IN RQE LABEL          00239421
         MVC   ABDLINE+FORT3(SIX),CSW        MOVE IN CSW LABEL          00240521
ABDMP280 BAL   R5,GOOUTPUT         GO OUTPUT FORMATTED RECORD           00241621
*** PUT OUT TIMESTAMP IF TIME OPTION CHOSEN                             00242721
ABDMP080 TM    HCTFLG3,HCTTIME     DOES TIMESTAMP EXIST FOR EACH RECORD 00243821
         BZ    ABDMP100            NO                                   00244921
* THE TIMESTAMP OUTPUT IS OF THE FORM SSSSS.TTTMMM -SECOND.MICROSEC     00246021
         MVC   ABDLINE(FOUR),TIMEDC     MOVE LABEL TO BUFFER            00247121
         MVC   ABDWORK1(EIGHT),PFXTOD(R7) GET TIME ON FULLWORD BNDRY    00248221
         TM    HCTFLG2,HCTTODCK         Q- TOD CLOCK                    00249321
         BO    ABDMP085                 YES, READY FOR CONVERSION       00250421
         SR    WK2,WK2                  NO, CONVERT TU TO MICROSECONDS  00251521
         L     R3,ABDWORK1+FOUR         GET TIME IN TU                  00252621
         M     WK2,TUCONV               1 TU IS 26.04 MICROSECONDS      00253721
         D     WK2,DECPOINT             CORRECT DECIMAL POINT           00254821
         SR    WK2,WK2                  ZERO OUT REMAINDER              00255921
         M     WK2,ADJUST               AVOID FIXED POINT OVERFLOW      00257021
         B     ABDMP090                GO CONVERT                       00258121
ABDMP085 LM    WK2,R3,ABDWORK1          GET TIME IN TOD CLOCK FORMAT    00259221
         SRDL  WK2,TWELV                SHIFT OUT UNUSED BITS           00260321
ABDMP090 D     WK2,SIXTYMIL            WK2 NOW HAS NUMBER OF SECONDS    00261421
*                                        IN MICROSECONDS AND R3 HAS     00262521
*                                        NUMBER OF MINUTES SINCE EPIC   00263621
         LR    R0,R3                    SAVE MINUTES                    00264721
         LR    R3,WK2                   MOVE SECONDS TO ODD REG         00265821
         LA    R5,ABDMP097              SET ADDRESS TO COME OUT OF LOOP 00266921
         LA    R8,ABDLINE+SEVNTN        ADDRESS OF END OF FIELD         00268021
         LA    R1,SIX                   SET LOOP CONTROL                00269121
ABDMP095 SR    WK2,WK2                  CLEAR EVEN REG FOR DIVIDE       00270221
         D     WK2,TENDC                CONVERT TO DECIMAL              00271321
         STC   WK2,ZERO(R8)             STORE IN BUFFER                 00272421
         OI    ZERO(R8),ZONE            CONVERT TO EBCDIC               00273521
         BCTR  R8,ZERO                  DECREMENT BUFFER POINTER        00274621
        BCT    R1,ABDMP095             LOOP CONTROL                     00275721
         BR    R5                       RETURN TO CALLER                00276821
ABDMP097 MVI   ZERO(R8),DOT             PUT DECIMAL POINT IN BUFFER     00277921
         BCTR  R8,ZERO                  DECREMENT BUFFER POINTER        00279021
         LR    R1,R3                    SAVE SECONDS                    00280121
         SR    WK2,WK2                  CLEAR EVEN REG FOR DIVIDE       00281221
         LR    R3,R0                    GET MINUTES                     00282321
         D     WK2,MINPRDAY             GET MINUTES LEFT IN DAY         00283421
         LR    R3,WK2                   SAVE MINUTES PER DAY            00284521
         SR    WK2,WK2                  CLEAR REG FOR MULTIPLY          00285621
         M     WK2,SIXTYDC              CONVERT TO SECONDS              00286721
         AR    R3,R1                    ADD SECONDS                     00287821
         LA    R1,FIVE                  SET COUNTER FOR LOOP            00288921
         BAL   R5,ABDMP095              CONVERT SECONDS TO EBCDIC       00290021
ABDMP087 BAL   R5,GOOUTPUT         GO OUTPUT TIMESTAMP                  00291121
*** UPDATE POINTER TO NEXT RECORD AND GO GET NEXT RECORD                00292221
ABDMP100 SH    R10,ZERO(R7)        GET REMAINING LENGTH OF RECS IN BUFF 00293321
         AH    R7,ZERO(R7)         POINT TO NEXT RECORD                 00294421
         B     ABDMP060            GO TEST RECORD                       00295521
ABDMP600 LA    R1,LOADOM          POINT TO LOAD NAME                    00296621
         LA    R15,ABDWORK        SET UP FOR XCTL                       00297721
         XCTL  EPLOC=(R1),SF=(E,(R15))    XCTL TO IGC0M05A              00298821
*** GOOUTPUT AND GOFORMAT SAVE REG 6 BEFORE GOING TO IEAQAD0A.          00299921
*** IEAQAD0A UPON RETURN LOADS THE SAVED CONTENTS OF REG 6 AND          00301021
*** RETURNS ON REG 5.                                                   00302121
GOOUTPUT ST    R6,ABDSAVE6        SAVE OLD BUFFER ADDR                  00303221
         L     R6,ABDLDADD         GET ADDR IEAQAD0A                    00304321
         B     LDOUTPUT           GO TO IEAQAD0A'S OUTPUT ROUTINE       00305421
GOFORMAT ST    R6,ABDSAVE6        SAVE OLD BUFFER ADDR                  00306521
         L     R6,ABDLDADD         GET ADDR IEAQAD0A                    00307621
         B     LDFORMAT           GO TO IEAQAD0A'S FORMAT ROUTINE       00308721
***                                                                     00309821
***   G T F   C O N S T A N T S                                         00310921
***                                                                     00312021
SIXTYMIL DC    F'60000000'        DIVIDER FOR MINUTES AND SECONDS       00313121
TENDC    DC    F'10'              DIVIDER FOR HEX TO DECIMAL            00314221
ADJUST   DC    F'100'             CONSTANTS FOR TIMER                   00315321
DECPOINT DC    F'100000000'                 UNIT CONVERSION             00316421
TUCONV   DC    F'26041667'                            TO MICROSECONDS   00317521
MINPRDAY DC    F'1440'                  MINUTES PER DAY                 00318621
SIXTYDC  DC    F'60'              SECONDS PER MINUTE                    00319721
TRACHEAD DC    C'-GTF TRACE TABLE' HEADER FOR GTF TRACE                 00320821
EES      DC    X'EEEE'             INDICATOR OF BAD RECORD              00321921
NEWLAB  DC    C'NU'               NEW LABEL                             00323021
RESLAB   DC    C'RES'        RES LABEL                                  00324121
TQE      DC    C'TQE TCB'              TQE LABEL                        00325221
CCDEVCAW DC    C'CC/DEV/CAW'       IO LABEL                             00326321
RQETCB   DC    C'RQE TCB'          RQETCB LABEL                         00327421
CSW      DC    C'CSW   '              CSW LABEL                         00328521
ASTERS   DC    C'********'         INDICATES ERROR IN GETTING TCB ADDR  00329621
NOTAPPL  DC    C'N/A     '        INDICATES TCB ADDR NOT APPLICABLE     00330721
STMSK    DC    C'STMSK'           EXTERNAL LABEL                        00331821
FOURDC   DC    H'4'                CONSTANT 4                           00332921
LOADOM   DC    C'IGC0M05A'        NAME OF 2ND GTF TRACE FORMAT LOAD     00334021
***                                                                     00335121
***  GTF TRACE TABLE LAYOUT LINE                                        00336221
***                                                                     00337321
***   THE CONTROL BYTES ARE SET UP FOR THE FORMAT ROUTINE AS FOLLOWS:   00338421
***   SIZE OF LABEL-1,SIZE OF FIELD-1,NUMBER OF BYTES TO ADD TO REG 2,  00339521
***   AND DISTANCE BETWEEN LABEL AND FIELD                              00340621
GTFLINE  DC    AL1(10)             DISPLACEMENT TO PSW LABEL            00341721
         DC    X'6305'             CONTROL BYTES FOR FORMAT RTN         00342821
         DC    C'OLD PSW'          1ST LABEL                            00343921
         DC    X'FF'               RETURN,MORE THAN 4 BYTES TO FORMAT   00345021
         DC    AL1(30)             DISPLACEMENT TO 2ND HALF PSW         00346121
         DC    X'0340'             CONTROL BYTES                        00347221
         DC    C' '                BLANK                                00348321
         DC    X'5341'             CONTROL BYTES                        00349421
         DC    C'R15/R0'           2ND LABEL                            00350521
         DC    X'FF'               RETURN, MORE THAN 4 BYTES TO FORMAT  00351621
         DC    AL1(58)             DISPLACEMENT TO R0                   00352721
         DC    X'0340'             CONTROL BYTES                        00353821
         DC    C' '                BLANK                                00354921
         DC    X'1346'             CONTROL BYTES                        00356021
         DC    C'R1'              3RD LABEL                             00357121
         DC    X'2344'             CONTROL BYTES                        00358221
         DC    C'OLA'             4TH LABEL                             00359321
         DC    X'2345'             CONTROL BYTES                        00360421
         DC    C'OLB'             5TH LABEL                             00361521
         DC    X'FF'               END OF GTF TRACE LINE                00362621
***  THESE EIDS AND THEIR LABELS MUST BE KEPT CONTIGUOUS                00363721
EIDTABLE EQU   *                   ADDR EID TABLE                       00364821
PCIEID   DC    X'2FDF'             PCI EID                              00365921
         DC    C'PCI'              PCI LABEL                            00367021
SVCEID   DC    X'3FFF'             SVC EID                              00368121
         DC    C'SVC'              SVC LABEL                            00369221
DSPEID   DC    X'4FE7'             DSP EID                              00370321
         DC    C'DSP'              DSP LABEL                            00371421
IOEID1   DC    X'5FEE'             I/O EID1                             00372521
         DC    C'I/O'              I/O LABEL                            00373621
IOEID2   DC    X'5FEF'             I/O EID2                             00374721
         DC    C'I/O'              I/O LABEL                            00375821
SIOEID1  DC    X'5FF0'             SIO EID1                             00376921
         DC    C'SIO'              SIO LABEL                            00378021
PGMEID   DC    X'DFFD'             PGM EID                              00379121
         DC    C'PGM'              PGM LABEL                            00380221
EXTEID   DC    X'DFFE'             EXT EID                              00381321
         DC    C'EXT'             EXT LABEL                             00382421
***  SSM IS NOT SUPPORTED IN INTERNAL GTF TRACE                         00383521
EIDEND   EQU   *                   END OF TABLE ADDR                    00384621
TIMEDC   DC    C'TIME'             TIME LABEL                           00385721
***                                                                     00386821
          IHBABCTL                                                      00387921
***                                                                     00389021
CMTDSECT CMT                                                            00390121
***                                                                     00391221
HCTDSECT HCT                                                            00392321
***                                                                     00393421
         IHBDMPA                                                        00394521
***                                                                     00395621
BPXDSECT BPX                                                            00396721
       END                                                              00397821
     TITLE  'IEAQAD0K / ABDUMP13 / IGC0K05A'                            00398921
IGC0K05A CSECT                                                          00400021
*STATUS CHANGE LEVEL=0                                                  00600021
*   ROUTINE NAME-                                                       00800021
*        IEAQAD0K                                                       01000021
*   FUNCTION-                                                           01200021
*        THIS MODULE OUTPUTS THE GTF TRACE TABLE FOR MP                 01400021
*   ENTRY POINT NAME-                                                   01600021
*        IGC0K05A                                                       01800021
*   ATTRIBUTES-                                                         02000021
*        TYPE IV SVC,SUPERVISOR STATE,REENTRANT                         02200021
*   APPLICABILITY-                                                      02400021
*        OPTION IV                                                      02600021
*   EXTERNAL REFERENCES-                                                02800021
*        THIS ROUTINE BALRS TO THE FORMAT AND OUTPUT ROUTINES           03000021
*        IN IEAQAD0A                                                    03200021
*   SVC USAGE--NONE                                                     03400021
*   INPUT-                                                              03600021
*        1) POINTER TO THE TCB BEING DUMPED- REG 4                      03800021
*        2) POINTER TO THE ABDUMP WORK AREA- REG 13                     04000021
*   OUTPUT-                                                             04200021
*        GTF TRACE TABLE DUMPED                                         04400021
*   ENTRY POINTS-                                                       04600021
*        1) PSW                                                         04800021
*             A) ENABLED                                                05000021
*             B) UNDER SUPERVISOR PROTECTION KEY                        05200021
*             C) IN SUPERVISOR MODE                                     05400021
*        2) REGISTERS                                                   05600021
*             A) REG 4-POINTER TO TCB BEING DUMPED                      05800021
*             B) REG 13-POINTER TO ABDUMP'S WORK AREA                   06000021
*   EXIT-                                                               06200021
*        TO THE WHERE-TO-GO ROUTINE IN IEAQAD0A.                        06400021
*   TABLE AND CONTROL BLOCK REFERENCED-                                 06600021
*        IEAQAD0K REFERENCES THE FOLLOWING CONTROL BLOCKS-              06800021
*        1) CVT                                                         07000021
*              CVTGTF-GTF FLAGS AND CMT ADDR                            07200021
*        2) CMT (CLASS MASK TABLE)                                      07400021
*              CMTHCT- HCT ADDR                                         07600021
*        3) HCT (HOOK CONTROL TABLE)                                    07800021
*              HCTTCUR- ADDR CURRENT GTF TRACE BUFFER                   08000021
*              HCTFLG2- FLAGS                                           08200021
*              HCTFLG3- FLAGS                                           08400021
*        4) BFX (BUFFER PREFIX AND CONTROL)                             08600021
*              BPXFLGS- FLAGS                                           08800021
*              BPXLINK- ADDR NEXT BPX                                   09000021
*              BPXBUFF- ADDR BUFFER                                     09200021
*        5) TCB                                                         09400021
*              TCBGTOFF- GTF-FREEZE FLAG                                09600021
*                                                                       09800021
** REGISTER EQUATES                                                     10000021
*                                                                       10200021
BASEREG  EQU   12             ROUTINE BASE REG                          10400021
WKREGA   EQU   11             WORK REG FOR CVT,CMT,HCT                  10600021
WKREGB   EQU   9              WORK REG                                  10800021
R5       EQU   5              BALR TO OUTPUT ROUTINE                    11000021
R6       EQU   6              BASE FOR IEAQAD0A REENTRANT RTNS AND     X11200021
                                          ADDR  OF THE OLDEST BUFFER    11400021
R13      EQU   13             BASE FOR ABDUMP WORK AREA                 11600021
TCBREG   EQU   4              ADDR OF TCB CAUSING DUMP                  11800021
R10      EQU   10             REMAINING BUFFER LENGTH, XCTL             12000021
R15      EQU   15             WORK                                      12200021
R7       EQU   7              PTR TO RECORD IN BUFFER                   12400021
WK2      EQU   2                                                        12600021
R3       EQU   3                                                        12800021
R0       EQU   0                   WORK REG                             13000021
R1       EQU   1                   WORK REG                             13200021
R8       EQU   8                                                        13400021
SPACE2CC EQU   X'F0'               2 SPACE CARRIAGE CONTROL             13600021
FF       EQU   X'FF'               TOTAL FLAG BITS MASK                 13800021
F0       EQU   X'F0'               MASK FOR 2ND BYTE SIO EID            14000021
**  GTF RECORD EQUATES                                                  14200021
PFXLENG  EQU   0                   RECORD LENGTH DISPLACEMENT           14400021
PFXAID   EQU   4                   AID DISPLACEMENT                     14600021
PFXFID   EQU   5                   FID DISPLACEMENT                     14800021
PFXTOD   EQU   6                   TOD DISPLACEMENT                     15000021
PFXNOTOD EQU   10                  TIMER UNITS DISPLACEMENT             15200021
CNTRLREC EQU   X'00'               CONTROL RECORD AID MASK              15400021
TIMESTAM EQU   X'04'               TIMESTAMP CNTRL REC FID              15600021
LOSTCNT  EQU   X'06'               LOST EVENT CONTROL REC FID           15800021
FLG4BLNK EQU   X'84'               MASK FOR FORMAT FLAG AND BLNK CNT    16000021
FLG2BLNK EQU   X'82'               MASK FOR FORMAT FLAG AND BLNK CNT    16200021
OFFBLANK EQU   X'00'               MASK OFF FORMAT FLAG AND BLNK CNT    16400021
** NUMBER EQUATES                                                       16600021
ZERO     EQU   0              NUMBER 0                                  16800021
ONE      EQU   1              NUMBER 1                                  17000021
TWO      EQU   2              NUMBER 2                                  17200021
THREE    EQU   3              NUMBER 3                                  17400021
FOUR     EQU   4              NUMBER 4                                  17600021
FIVE     EQU   5              NUMBER 5                                  17800021
SIX      EQU   6               NUMBER 6                                 18000021
SEVEN    EQU   7              NUMBER 7                                  18200021
EIGHT    EQU   8              NUMBER 8                                  18400021
TEN      EQU   10             NUMBER 10                                 18600021
TWELV    EQU   12             NUMBER 12                                 18800021
SIXTN    EQU   16             NUMBER 16                                 19000021
TWENT4   EQU   24             NUMBER 24                                 19200021
TWENT9   EQU   29             NUMBER 29                                 19400021
FORT3    EQU   43             NUMBER 43                                 19600021
SIXT9    EQU   69             NUMBER 69                                 19800021
SEVENT7  EQU   77             NUMBER 77                                 20000021
EIGHT7   EQU   87             NUMBER 87                                 20200021
ONE04    EQU   104            NUMBER 104                                20400021
ONE12    EQU   112            NUMBER 112                                20600021
ABDMP000 BALR  BASEREG,0           GET ADDRESSABILITY                   20800021
         USING *,BASEREG           FOR ROUTINE                          21000021
         LTR   R8,R8              IS ENTRY FROM 2ND LOAD-IEAQADOM       21200021
         BNZ   ABDMP100            YES                                  21400021
         USING ABDAREA,R13         SET UP DSECT FOR ABDUMP WORK AREA    21600021
         USING CVTSECT,WKREGA     SET UP DSECT FOR CVT                  21800021
*** GET ADDRESSABILITY TO HCT; CVT->CMT->HCT                            22000021
         L     WKREGA,CVTPTR       GET CVT PTR                          22200021
         L     WKREGA,CVTGTF       GET CMT ADDR                         22400021
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        22600021
         USING CMTDSECT,WKREGA     SET UP CMT DSECT                     22800021
         L     WKREGA,CMTHCT       GET HCT ADDR                         23000021
         LA    WKREGA,ZERO(WKREGA) CLEAR HI BYTE                        23200021
         USING HCTDSECT,WKREGA     SET UP HCT DSECT                     23400021
         USING LDDSECT,R6          SET UP DSECT FOR REENTRANT ROUTINES  23600021
*** PRINT HEADER RECORD AND GET OLDEST BUFFER                           23800021
ABDMP010 MVC   ABDCC(L'TRACHEAD),TRACHEAD  SET UP CARR CNTRL,HEADER     24000021
         BAL   R5,GOOUTPUT                 AND GO PRINT                 24200021
         MVI   ABDCC,SPACE2CC      RESET CARR CNTRL TO SPACE 2          24400021
         L     WKREGB,HCTTCUR      GET ADDR CURRENT TRACE BUFFER PREFIX 24600021
         LA    WKREGB,ZERO(WKREGB) CLEAR HI BYTE                        24800021
         USING BPXDSECT,WKREGB     SET UP BPX DSECT                     25000021
         L     WKREGB,BPXLINK      GET OLDEST BUFFER                    25200021
         LA    WKREGB,ZERO(WKREGB)  ZERO HI BYTE                        25400021
         LR    R6,WKREGB          SAVE OLDEST BUFFER                    25600021
         B     ABDMP050           GO TEST BUFFER                        25800021
*** ALL BUFFERS HAVE BEEN FORMATTED. PRINT TRAILER,UNFREEZE GTF,        26000021
***                                  AND EXIT TO WHERE-TO-GO RTN        26200021
          USING TCBSECT,TCBREG     SET UP FOR TCB ADDRESSABILITY        26400021
ABDMP025 TM    TCBDAR,TCBGTOFM   HAS HOOK BEEN REISSUED FOR TCB         26600021
         BZ    ABDMP030            NO                                   26800021
         HOOK  EID=IHLMABON        UNFREEZE GTF                         27000021
         NI    TCBDAR,FF-TCBGTOFM  RESET TCB FREEZE FLAG                27200021
ABDMP030 L     R6,ABDLDADD         GET ADDR IEAQAD0A                    27400021
         B     LDWTG               BRANCH TO WHERE TO GO                27600021
*** CHECK FOR ACTIVE BUFFER, SET UP TOTAL GTF REC LENGTH IN BUFFER      27800021
ABDMP040 L     WKREGB,BPXLINK     GET NEXT BUFFER                       28000021
         L     WKREGB,ZERO(WKREGB)   CLEAR HI BYTE                      28200021
         CR    R6,WKREGB          IS OLDEST BUFFER NEXT                 28400021
         BE    ABDMP025           YES,ALL THROUGH                       28600021
ABDMP050 TM    BPXFLGS,BPXFULL+BPXSCED+BPXCURR  IS BUFFER IN USE        28800021
         BZ    ABDMP040            NO GO GET NEXT                       29000021
         L     R10,BPXPRLEN        GET BLOCK DESCRIPTOR WORD            29200021
         SRL   R10,SIXTN           RIGHT ALIGN LENGTH FIELD             29400021
         SH    R10,FOURDC          GET ONLY GTF TOTAL RECORDS LENGTH    29600021
         LA    R7,BPXLRLEN         GET ADDR 1ST REC IN BUFFER           29800021
ABDMP060 LTR   R10,R10             HAVE ALL RECORDS IN BUFFER BEEN DONE 30000021
         BNH   ABDMP040            YES                                  30200021
*** CHECK FOR GTF CONTROL REC                                           30400021
         CLI   PFXAID(R7),CNTRLREC IS THIS A CNTRL REC                  30600021
         BNE   ABDMP200            NO                                   30800021
         LA    R8,FOUR            INIT REG 8 FOR 2ND LOAD-CONTROL REC   31000021
         CLI   PFXFID(R7),TIMESTAM IS IT FOR TIMESTAMP                  31200021
         BE    ABDMP600           YES                                   31400021
         CLI   PFXFID(R7),LOSTCNT  IS IT FOR LOST EVENT CNT             31600021
         BE    ABDMP600           YES                                   31800021
ABDMP075 LA    R8,EIGHT           INIT REG 8 FOR 2ND LOAD-ERROR REC     32000021
       B       ABDMP600           GO XCTL                               32200021
*** TEST FOR VALID EID                                                  32400021
ABDMP200 LA    WK2,SIX(R7)         POINT TO EID- NO TIMESTAMP           32600021
         TM    HCTFLG3,HCTTIME     IS THERE A TIMESTAMP IN RECORD       32800021
         BZ    ABDMP205            NO                                   33000021
         LA    WK2,EIGHT(WK2)      YES UP PTR                           33200021
ABDMP205 LA    R15,EIDTABLE        GET ADDR EID LIST                    33400021
         LA    R0,EIDEND          POINT TO END OF TABLE                 33600021
ABDMP210 CR    R15,R0          IS TABLE END REACHED                     33800021
         BE    ABDMP075            YES, EID INVALID, PRINT ERR MSG      34000021
         CLC   ZERO(TWO,R15),ZERO(WK2)  DO EIDS MATCH                   34200021
         BE    ABDMP220            DO EIDS MATCH                        34400021
         LA    R15,FIVE(R15)       POINT TO NEXT EID                    34600021
         B     ABDMP210            GO CHECK EID                         34800021
*** A VALID EID HAS BEEN FOUND                                          35000021
ABDMP220 LA    WK2,TWO(WK2)        GET ADDR OF DATA IN RECORD           35200021
         ST    R15,ABDWORK2       SAVE ADDR OF EID AND LABEL            35400021
         ST    WK2,ABDWORK1        SAVE BEGIN OF DATA                   35600021
*** CHECK TRACE RECORD FOR ERROR -X'EEEE' IN DATA FIELD                 35800021
         CLC   ZERO(TWO,WK2),EES  IS RECORD BAD                         36000021
         BNE   ABDMP225            NO                                   36200021
         LA    R8,TWELV           SET UP FOR 2ND LOAD- EE REC           36400021
         LR     R5,R15            GET EID/LABEL FOR 2ND LOAD            36600021
         B     ABDMP600           GO XCTL                               36800021
*** REPLACE CHARACTER FIELDS **** OR N/A WITH ZEROS FOR FORMAT          37000021
ABDMP225 LA    R3,GTFLINE          GET ADDR GTF LAYOUT LINE             37200021
*** REGS 2,3,AND 6 HAVE BEEN INITIALIZED FOR FORMAT RTN                 37400021
***  GO FORMAT RECORD                                                   37600021
ABDMP240 MVI   ABDBLNKS,FLG4BLNK   INIT FOR 4 BLANKS AFTER FIELD        37800021
         BAL   R5,GOFORMAT         FORMAT 1ST HALF PSW                  38000021
         BAL   R5,GOFORMAT         FORMAT 2ND HALF PSW AND R15          38200021
         MVI   ABDBLNKS,FLG2BLNK   INIT FOR 2 BLANKS AFTER FIELD        38400021
         BAL   R5,GOFORMAT         FORMAT R0,R1, AND TCBS A&B           38600021
         MVI   ABDBLNKS,OFFBLANK  REINIT BLANKS FIELD                   38800021
         L     R15,ABDWORK2       GET ADDR EID AND LABEL                39000021
         MVC   ABDLINE+THREE(THREE),TWO(R15)  MOVE IN LABEL             39200021
         LA    R5,ABDMP280         GET ADDR FOR GO OUTPUT               39400021
         L     WK2,ABDWORK1        LOAD SAVED DATA ADDR                 39600021
         MVC   ABDLINE(ONE),TWENT9(WK2)  MOVE IN CPU ID                 39800021
*** CHANGE EID-DEPENDENT LABELS                                         40000021
         CLC   ZERO(TWO,R15),PGMEID IS IT PGM                           40200021
         BCR   EIGHT,R5            YES                                  40400021
         CLC   ZERO(TWO,R15),SVCEID IS IT SVC                           40600021
         BCR   EIGHT,R5            YES                                  40800021
         CLC   ZERO(TWO,R15),DSPEID IS IT DSP                           41000021
         BNE   ABDMP250            NO                                   41200021
         MVC   ABDLINE+TEN(THREE),RESLAB  CHANGE PSW LABEL              41400021
         MVC   ABDLINE+EIGHT7(TWO),NEWLAB CHANGE TCB LABEL FOR A        41600021
         MVC   ABDLINE+ONE04(TWO),NEWLAB CHANGE TCB LABEL FOR B         41800021
         BR    R5                  GO OUTPUT                            42000021
ABDMP250 CLC   ZERO(TWO,R15),EXTEID  IS IT EXTERNAL                     42200021
         BNE   ABDMP260            NO                                   42400021
         MVC   ABDLINE+EIGHT7(FIVE),STMSK  MOVE IN STMSK LABEL          42600021
         CLC   TWENT4(FOUR,WK2),ASTERS  IS TQE  ****                    42800021
         BNE   ABDMP252      NO                                         43000021
         MVC   ABDLINE+ONE12(EIGHT),ASTERS   MOVE ****INTO RECORD       43200021
         B     ABDMP255           GO FINISH RECORD                      43400021
ABDMP252 CLC   TWENT4(FOUR,WK2),NOTAPPL   IS TQE  N/A                   43600021
         BNE   ABDMP255           NO                                    43800021
         MVC    ABDLINE+ONE12(EIGHT),NOTAPPL  MOVE N/A INTO RECORD      44000021
ABDMP255 MVC   ABDLINE+ONE04(SEVEN),TQE   CHANGE TCB LABEL              44200021
         BR    R5                  GO OUTPUT                            44400021
ABDMP260 CLC   SIXTN(FOUR,WK2),ASTERS    IS RQE TCB ****                44600021
         BNE   ABDMP262           NO                                    44800021
         MVC   ABDLINE+SEVENT7(EIGHT),ASTERS   MOVE **** INTO RECORD    45000021
         B     ABDMP265           GO FINISH RECORD                      45200021
ABDMP262 CLC   SIXTN(FOUR,WK2),NOTAPPL   IS RQE TCB N/A                 45400021
         BNE   ABDMP265           NO                                    45600021
         MVC   ABDLINE+SEVENT7(EIGHT),NOTAPPL  MOVE N/A INTO RECORD     45800021
ABDMP265 CLC   ZERO(TWO,R15),PCIEID IS IT PCI                           46000021
         BE    ABDMP270            YES                                  46200021
         TM    ONE(R15),F0         IS IT SIO1                           46400021
         BNO   ABDMP275           NO, I/O EID                           46600021
ABDMP270 MVC   ABDLINE+TEN(TEN),CCDEVCAW  MOVE IN IO INFO               46800021
ABDMP275 MVC   ABDLINE+SIXT9(SEVEN),RQETCB   MOVE IN RQE LABEL          47000021
         MVC   ABDLINE+FORT3(SIX),CSW        MOVE IN CSW LABEL          47200021
ABDMP280 BAL   R5,GOOUTPUT         GO OUTPUT FORMATTED RECORD           47400021
*** PUT OUT TIMESTAMP IF TIME OPTION CHOSEN                             47600021
ABDMP080 TM    HCTFLG3,HCTTIME     DOES TIMESTAMP EXIST FOR EACH RECORD 47800021
         BZ    ABDMP100            NO                                   48000021
         LA    R3,GTFTIMEL         GET ADDR OF TIME INFO                48200021
         LA    WK2,PFXNOTOD(R7)    INIT REG2 FOR TIMER UNITS DATA ADDR  48400021
         TM    HCTFLG2,HCTTODCK    IS TIMESTAMP FOR TOD                 48600021
         BZ    ABDMP085            NO                                   48800021
         LA    WK2,PFXTOD(R7)      REINIT REG2 TO TOD DATA ADDR         49000021
*** REGS 2,3 AND 6 ARE INITIALIZED FOR THE FORMAT ROUTINE               49200021
ABDMP085 BAL   R5,GOFORMAT         GO FORMAT TIMESTAMP                  49400021
         TM    HCTFLG2,HCTTODCK   IS TIME  TOD                          49600021
         BZ    ABDMP087           NO                                    49800021
         BAL   R5,GOFORMAT        YES, GO FINISH TIMESTAMP              50000021
ABDMP087 BAL   R5,GOOUTPUT         GO OUTPUT TIMESTAMP                  50200021
*** UPDATE POINTER TO NEXT RECORD AND GO GET NEXT RECORD                50400021
ABDMP100 SH    R10,ZERO(R7)        GET REMAINING LENGTH OF RECS IN BUFF 50600021
         AH    R7,ZERO(R7)         POINT TO NEXT RECORD                 50800021
         B     ABDMP060            GO TEST RECORD                       51000021
ABDMP600 LA    R1,LOADOM          POINT TO LOAD NAME                    51200021
         LA    R15,ABDWORK        SET UP FOR XCTL                       51400021
         XCTL  EPLOC=(R1),SF=(E,(R15))    XCTL TO IGC0M05A              51600021
*** GOOUTPUT AND GOFORMAT SAVE REG 6 BEFORE GOING TO IEAQAD0A.          51800021
*** IEAQAD0A UPON RETURN LOADS THE SAVED CONTENTS OF REG 6 AND          52000021
*** RETURNS ON REG 5.                                                   52200021
GOOUTPUT ST    R6,ABDSAVE6        SAVE OLD BUFFER ADDR                  52400021
         L     R6,ABDLDADD         GET ADDR IEAQAD0A                    52600021
         B     LDOUTPUT           GO TO IEAQAD0A'S OUTPUT ROUTINE       52800021
GOFORMAT ST    R6,ABDSAVE6        SAVE OLD BUFFER ADDR                  53000021
         L     R6,ABDLDADD         GET ADDR IEAQAD0A                    53200021
         B     LDFORMAT           GO TO IEAQAD0A'S FORMAT ROUTINE       53400021
***                                                                     53600021
***   G T F   C O N S T A N T S                                         53800021
***                                                                     54000021
TRACHEAD DC    C'-GTF TRACE TABLE' HEADER FOR GTF TRACE                 54200021
EES      DC    X'EEEE'             INDICATOR OF BAD RECORD              54400021
NEWLAB  DC    C'NU'               NEW LABEL                             54600021
RESLAB   DC    C'RES'        RES LABEL                                  54800021
TQE      DC    C'TQE TCB'              TQE LABEL                        55000021
CCDEVCAW DC    C'CC/DEV/CAW'       IO LABEL                             55200021
RQETCB   DC    C'RQE TCB'          RQETCB LABEL                         55400021
CSW      DC    C'CSW   '              CSW LABEL                         55600021
ASTERS   DC    C'********'         INDICATES ERROR IN GETTING TCB ADDR  55800021
NOTAPPL  DC    C'N/A     '        INDICATES TCB ADDR NOT APPLICABLE     56000021
STMSK    DC    C'STMSK'           EXTERNAL LABEL                        56200021
FOURDC   DC    H'4'                CONSTANT 4                           56400021
LOADOM   DC    C'IGC0M05A'        NAME OF 2ND GTF TRACE FORMAT LOAD     56600021
***                                                                     56800021
***  GTF TRACE TABLE LAYOUT LINE                                        57000021
***                                                                     57200021
***   THE CONTROL BYTES ARE SET UP FOR THE FORMAT ROUTINE AS FOLLOWS:   57400021
***   SIZE OF LABEL-1,SIZE OF FIELD-1,NUMBER OF BYTES TO ADD TO REG 2,  57600021
***   AND DISTANCE BETWEEN LABEL AND FIELD                              57800021
GTFLINE  DC    AL1(10)             DISPLACEMENT TO PSW LABEL            58000021
         DC    X'6305'             CONTROL BYTES FOR FORMAT RTN         58200021
         DC    C'OLD PSW'          1ST LABEL                            58400021
         DC    X'FF'               RETURN,MORE THAN 4 BYTES TO FORMAT   58600021
         DC    AL1(30)             DISPLACEMENT TO 2ND HALF PSW         58800021
         DC    X'0340'             CONTROL BYTES                        59000021
         DC    C' '                BLANK                                59200021
         DC    X'5341'             CONTROL BYTES                        59400021
         DC    C'R15/R0'           2ND LABEL                            59600021
         DC    X'FF'               RETURN, MORE THAN 4 BYTES TO FORMAT  59800021
         DC    AL1(58)             DISPLACEMENT TO R0                   60000021
         DC    X'0340'             CONTROL BYTES                        60200021
         DC    C' '                BLANK                                60400021
         DC    X'1346'             CONTROL BYTES                        60600021
         DC    C'R1'              3RD LABEL                             60800021
         DC    X'2344'             CONTROL BYTES                        61000021
         DC    C'OLA'             4TH LABEL                             61200021
         DC    X'2345'             CONTROL BYTES                        61400021
         DC    C'OLB'             5TH LABEL                             61600021
         DC    X'FF'               END OF GTF TRACE LINE                61800021
***  THESE EIDS AND THEIR LABELS MUST BE KEPT CONTIGUOUS                62000021
EIDTABLE EQU   *                   ADDR EID TABLE                       62200021
PCIEID   DC    X'2FDF'             PCI EID                              62400021
         DC    C'PCI'              PCI LABEL                            62600021
SVCEID   DC    X'3FFF'             SVC EID                              62800021
         DC    C'SVC'              SVC LABEL                            63000021
DSPEID   DC    X'4FE7'             DSP EID                              63200021
         DC    C'DSP'              DSP LABEL                            63400021
IOEID1   DC    X'5FEE'             I/O EID1                             63600021
         DC    C'I/O'              I/O LABEL                            63800021
IOEID2   DC    X'5FEF'             I/O EID2                             64000021
         DC    C'I/O'              I/O LABEL                            64200021
SIOEID1  DC    X'5FF0'             SIO EID1                             64400021
         DC    C'SIO'              SIO LABEL                            64600021
PGMEID   DC    X'DFFD'             PGM EID                              64800021
         DC    C'PGM'              PGM LABEL                            65000021
EXTEID   DC    X'DFFE'             EXT EID                              65200021
         DC    C'EXT'             EXT LABEL                             65400021
***  SSM IS NOT SUPPORTED IN INTERNAL GTF TRACE                         65600021
EIDEND   EQU   *                   END OF TABLE ADDR                    65800021
GTFTIMEL DC    AL1(0)              DISPLACEMENT TO TIME LABEL           66000021
TIMECNTR DC    X'3302'             CONTROL BYTES                        66200021
TIMEDC   DC    C'TIME'             TIME LABEL                           66400021
         DC    X'FF'               RETURN,END OF TIME-LINE              66600021
         DC    AL1(14)            LABEL DISP                            66800021
         DC    X'0340'            CONTROL BYTES                         67000021
         DC    C' '               LABEL                                 67200021
         DC    X'FF'              END OF LINE                           67400021
***                                                                     67600021
          IHBABCTL                                                      67800021
***                                                                     68000021
CMTDSECT CMT                                                            68200021
***                                                                     68400021
HCTDSECT HCT                                                            68600021
***                                                                     68800021
         IHBDMPA                                                        69000021
***                                                                     69200021
BPXDSECT BPX                                                            69400021
       END                                                              69600021
