IEAQRORI START                                                          00050015
*3152198500,955500                                                 LCS1 00060017
*3152003000,130723,217600,298680-298710,298820,462160,482670       MO0A 00070017
*    488100-489000,494500,514500,758100,760100                     MO0A 00080017
*3152799500,800500                                                 MP1A 00090017
*                                                                       00100015
* THE FOLLOWING CODE IS THE ROLLOUT/ ROLLIN MODULE.                     00150015
   TITLE 'IEAQRORI - ROLLOUT/ROLLIN'                                    00200020
*                                                                       00250015
*                                                                       00260017
*STATUS CHANGE LEVEL =1 IN RELEASE 17                                   00270017
*                                                                       00280017
*RELEASE 17 FLAGS                                                       00290017
*                                                                       00300017
*                  MODULE OWNERSHIP=MO0A                                00310017
*                  LCS SUPPORT     =LCS1                                00320017
*                  MULTIPROCESSING =MP1A                                00330017
*                                                                       00333018
* RELEASE 18 FLAGS                                                 MO18 00336018
*                  MODULE OWNERSHIP=MO18                           MO18 00339018
*                  MESSAGE ROUTING =MCS                            MO18 00342018
*                  RECOVERY MANAG. =MP2K                           MO18 00345018
*                                                                       00350015
* ROUTINE NAME - ROLLOUT/ROLLIN                                         00400015
*                                                                       00450015
* THE ROUTINES CONTAINED IN THIS MODULE ARE-                            00500015
*              ROLLOUT CRITERION                                        00550015
*              ROLLIN  CRITERION                                        00600015
*              ROLLOUT/ROLLIN  I/O                                      00650015
*              DEQUEUE                                                  00700015
* FUNCTION -                                                            00750015
*        THREE TYPES OF PROCESSING ARE PERFORMED IN THIS MODULE-        00800015
*                                                                       00850015
*        A. ROLLOUT                                                     00900015
*3110,216000                                                      9153  00920019
*              ROLLOUT IS SCHEDULED WHEN AN UNCONDITIONAL GETMAIN       00950015
*              CANNOT BE SATISFIED FROM THE JOB STEP'S REGION.          01000015
*              ROLLOUT EITHER -                                         01050015
*                                                                       01100015
*                   1. SATISFIES THE REQUEST FROM FREE SPACE, IF IT     01150015
*                   IS AVAILABLE,BY ISSUING A CONDITIONAL GETPART.      01200015
*                                                                       01250015
*                   2. SATISFIES THE REQUEST FROM SPACE ALLOCATED TO    01300015
*                   ANOTHER JOB STEP BY SUSPENDING THE EXECUTION OF     01350015
*                   THE OTHER JOB STEP, SAVING ITS STATUS ON A DIRECT   01400015
*                   ACCESS DEVICE, THEN TEMPORARILY ALLOCATING ONE      01450015
*                   OF THE SAVED REGIONS TO THE REQUESTING JOB STEP.    01500015
*                                                                       01550015
*                   3. PLACES THE REQUESTOR'S IQE'S ON THE ROLLOUT      01600015
*                   QUEUE UNTIL THE REQUEST CAN BE SATISFIED.           01650015
*                                                                       01700015
*                                                                       01750015
*        B. ROLLIN                                                      01800015
*              ROLLIN  IS SCHEDULED WHEN ALL  OF  THE                   01850015
*              SPACE WITHIN A TEMPORARILY  ALLOCATED                    01900015
*              (BORROWED) REGION IS FREE.   THE PQE ASSOCIATED          01950015
*              WITH THE BORROWED REGION  HAS BEEN DEQUEUED FROM THE     02000015
*              BORROWING TCB.     IF THE REGION WAS ACQUIRED FROM       02050015
*              FREE SPACE, THE MAIN STORAGE HAS BEEN RETURNED TO        02100015
*              GOVRFLB.  ROLLIN PERFORMS AS FOLLOWS-                    02150015
*                                                                       02200015
*                   1. IF THE TCB POINTER IN THE BORROWED PQE IS        02250015
*                   ZERO (THE REGION WAS ALLOCATED FROM FREE SPACE),    02300015
*                   THE BORROWED PQE IS FREED AND ANY IQE'S QUEUED      02350015
*                   FOR ROLLOUT ARE DEQUEUED AND RESCHEDULED.           02400015
*                                                                       02450015
*                                                                       02500015
*                   2. IF THE TCB POINTER IS NOT ZERO (THE REGION WAS   02550015
*                   BORROWED FROM ANOTHER JOB STEP), THE PQE ON THE     02600015
*                   OWNING TCB IS RESET.  THEN THE PQE'S                02650015
*                   ALLOCATED TO THE ROLLED-OUT STEP ARE TESTED         02700015
*                   TO DETERMINE IF ANY OF THE REGIONS ARE IN           02750015
*                   USE OR BORROWED BY ANOTHER STEP.  IF ANY            02800015
*                   REGION IS STILL BORROWED (THE USE BIT IS            02850015
*                   SET IN PQE) THE TEMPORARY PQE IS FREED AND QUEUED   02900015
*                   IQE'S ARE RESCHEDULED.  BUT IF NO OTHER REGIONS     02950015
*                   THAT ARE ALLOCATED TO THIS JOB STEP ARE IN USE      03000015
*                   BY OTHER JOB STEPS, ANY REGION THAT IS              03050015
*                   ROLLED-OUT IS RESTORED (FROM THE DIRECT ACCESS      03100015
*                   DEVICE) TO ITS PREVIOUS STATUS AND THE              03150015
*                   JOB STEP IS RESUMED.  THEN THE BORROWED PQE         03200015
*                   IS FREED AND ANY IQE'S QUEUED FOR ROLLOUT ARE       03250015
*                   DEQUEUED AND RESCHEDULED.                           03300015
*                                                                       03350015
*                                                                       03400015
*        C. DEQUEUE                                                     03450015
*              DEQUEUE IS SCHEDULED EITHER WHEN A FREEPART IS ISSUED,   03500015
*              WHEN A DEQ IS ISSUED THAT RESULTS IN THE NON-ROLLOUTABLE 03550015
*              COUNT BEING DECREMENTED TO ZERO, OR WHEN A BORROWED      03600015
*              REGION IS RETURNED IN ROLLIN.  DEQUEUE PERFORMS AS       03650015
*              FOLLOWS-                                                 03700015
*                                                                       03750015
*                   1. DEQUEUES AND RESCHEDULES (VIA STAGE II OF THE    03800015
*                   EXIT EFFECTOR) EACH IQE ON THE ROLLOUT QUEUE.       03850015
*                                                                       03900015
*                                                                       03950015
*                                                                       04000015
*                                                                       04050015
* ENTRY POINT  . IEAQRORI                                               04100015
* NAMES                                                                 04150015
*                                                                       04200015
* CONTAINED    . IEAQRORI                                               04250015
* IN MODULE                                                             04300015
*                                                                       04350015
* ATTRIBUTES-  RESIDENT, SERIALLY REUSABLE, SUPERVISOR STATE,           04400015
*              PARTIALLY DISABLED.                                      04450015
*                                                                       04500015
* APPLICABILITY-  OPTION 4 SYSTEMS ONLY                                 04550015
*                                                                       04600015
* EXTERNAL     IEAQAPG1  COINCIDENT ROLLOUT APPENDAGE                   04650015
* REFERENCES   IEAQAPG2  HIGH PRIORITY PASS APPENDAGE                   04700015
*              IEAQAPG3  ABEND APPENDAGE                                04750015
*              IEAQAPG4  CRITERION SELECTION APPENDAGE                  04800015
*              IEAMSTCB  ADDRESS OF MASTER TCB                          04850015
*              IEA0AB00  ENTRY POINT TO ABTERM ROUTINE                  04900015
*              GOVRFLB   MSS CONSTANTS                                  04950015
*              IECPCNVT  TTR CONVERT ROUTINE                            05000015
*              RODEB     ROLLOUT DEB                                    05050015
*                                                                       05100015
*                                                                       05150015
* SVC USAGE -                                                           05200015
*                                                                       05250015
*                                                                       05300015
* INPUT -      REGISTER 1 IS THE INPUT REGISTER TO THE ROLLOUT/ROLLIN   05350015
*              MODULE AND DETERMINES WHICH OF THE THREE FUNCTIONS OF    05400015
*              THE ROLLOUT/ROLLIN TASK IS TO BE PERFORMED.              05450015
*                                                                       05500015
*              1. DEQUEUE - IF REG 1 IS ZERO, A DEQUEUE IS REQUESTED.   05550015
*                                                                       05600015
*              2. ROLLOUT - IF REG 1 IS POSITIVE, A ROLLOUT IS          05650015
*                           REQUESTED.  REG 1 CONTAINS THE ADDRESS      05700015
*                           OF THE ROLLOUT PARAMETER LIST.              05750015
*                                                                       05800015
*                             ROLLOUT PARAMETER LIST                    05850015
*                        **************************************         05900015
*                        *RESERVED *   REQUESTING  TCB        *         05950015
*                        **************************************         06000015
*                        *HIERARCHY* REGION  SIZE REQUESTED   *         06050015
*                        **************************************         06100015
*                                                                       06150015
*              3. ROLLIN  - IF REG 1 IS NEGATIVE, A ROLLIN IS           06200015
*                           REQUESTED.  REG 1 CONTAINS THE COMPLEMENT   06250015
*                           OF THE ADDRESS OF THE ROLLIN PARAMETER      06300015
*                           LIST.                                       06350015
*                                                                       06400015
*                                                                       06450015
*                             ROLLIN PARAMETER LIST                     06500015
*                        **************************************         06550015
*                        *RESERVED *  BORROWING TCB ADDR      *         06600015
*                        **************************************         06650015
*                        *   0     * ADDR OF BORROWED PQE     *         06700015
*                        **************************************         06750015
*                                                                       06800015
*                                                                       06850015
*              THE FOLLOWING ENVIRONMENTAL REGISTERS ARE SET UPON ENTRY 06900015
*                                                                       06950015
*              REGISTER 3 = ADDRESS OF CVT                              07000015
*              REGISTER 4 = ADDRESS OF ROLLOUT TCB                      07050015
*              REGISTER 5 = ADDRESS OF ROLLOUT IRB                      07100015
*                                                                       07150015
*                                                                       07200015
* OUTPUT -     .NONE                                                    07250015
*                                                                       07300015
* ENTRY POINTS .IEAQRORI - THE TYPE OF REQUEST IS DETERMINED BY         07350015
*                          PARAMETER REGISTER 1 WHERE                   07400015
*                                  POSITIVE= ROLLOUT                    07450015
*                                  NEGATIVE= ROLLIN                     07500015
*                                  ZERO    = DEQUEUE                    07550015
*                                                                       07600015
* EXIT POINTS -.SVC EXIT                                                07650015
*                                                                       07700015
* ERROR EXIT   .NONE                                                    07750015
*                                                                       07800015
* TABLES AND   .TCB                                                     07850015
* CONTROL BLKS .IRB                                                     07900015
* REFERENCED   .IQE                                                     07950015
*              .PQE                                                     08000015
*              .FBQE                                                    08050015
          SPACE 2                                                       08060020
*   NOTES :                                                             08070020
*            APARS FIXED IN RELE 20: 32013, 33277, 33335                08080020
         SPACE 3                                                        08100015
         MPCVT                                                          08120017
CVTSECT  DSECT                                                          08150015
         CVT                                                            08200015
UCMSECT  DSECT                                                          08210018
         IEECUCM                                                        08220018
         SPACE 3                                                        08250015
         IHBROCTL                                                       08300015
*                                                                       08350015
RQESECT  DSECT                                                          08400015
RQERQE   DS    CL4                      ADDRESS OF NEXT RQE ON QUEUE    08450015
RQEID    DS    CL2                      REPLY IDENTIFICATION NUMBER     08500015
RQEXA    DS    CL2                      FLAGS-PURGE,VALCHK,ROLLOUT      08550015
RQETCB   DS    CL4                      ADDRESS OF ISSUING TCB          08600015
RQEWQE   DS    CL4                     ADDRESS OF RQE              MCS  08650018
RQELNTH  DS    CL1                      MAXIMUM LENGTH OF REPLY         08700015
RQERPTR  DS    CL3                      ADDRESS OF USER'S BUFFER        08750015
RQEECB   DS    CL4                      ADDRESS OF USER'S ECB           08800015
*                                                                       08850015
XPQEFPQE EQU   8                        FORWARD PQE POINTER             08900015
XPQEBPQE EQU   12                       BACKWARD PQE POINTER            08950015
XPQETCB  EQU   16                       TCB ADDR IN PQE                 09000015
XPQEREGN EQU   24                       ADDR OF FIRST BYTE OF REGION    09050015
XPQEHRID EQU   29                       HIERARCHY IDENTIFICATION NUMBER 09100015
*                                                                       09150015
RIQERIQE EQU   0                        ADDRESS OF NEXT RIQE ON QUEUE   09200015
RIQEJSTC EQU   4                        ADDRESS OF JOBSTEP TCB.         09250015
RIQETCB  EQU   8                        ADDRESS OF 'PURGED' TCB         09300015
RIQEIOB  EQU   12                       ORIGIN FOR CHAIN OF IOBS        09350015
*                                                                       09400015
OFF      EQU   X'7F'                    RESET HIGH PRIORITY PASS SW     09450015
SET      EQU   X'80'                    SET HIGH PRIORITY PASS SW       09500015
TWOK     EQU   2048                     CONSTANT USED IN SETKEYS        09550015
*                                                                       09600015
RQEPURGE EQU   X'80'                    PURGE FLAG IN RQEXA FIELD       09650015
RQERO    EQU   X'20'                    ROLLOUT FLAG IN RQEXA FIELD     09700015
PQEIOERR EQU   X'10'                    ROLLIN I/O ERROR INDICATOR      09800015
*                                                                       09810017
*                                                                       09820017
MP65FLAG EQU   X'04'              INDICATES MULTIPROCESSING        MP1A 09830017
PQEFLAGS EQU   28                       RORI FLAGS IN PQE          MP2K 09833018
DPQEPTR  EQU   X'98'                    DUMMY PQE PTR              MP2K 09836018
PREFIX2  EQU   X'02B0'                  DISP OF POINTER TO OTHER PSA    09840017
TCBTCPP  EQU   X'08'               QTAM POST PENDING TCB FLAG     20002 09841020
PPCOMP   EQU   X'F7'               COMPLEMENT OF TCBTCPP          20002 09842020
QPOSTPTR EQU   12                  DISP IN AVT TO QTAM POST ADDR  20002 09843020
RPLABND  EQU   RPLTCB              IF TASK REQUESTING           SA66075 09845021
RPLABNDS EQU   X'80'               ROLLOUT CANCELLED            SA66075 09847021
         SPACE 3                                                        09850015
*   REGISTER ASSIGNMENTS-                                               09900015
         SPACE 2                                                        09950015
PMREG0   EQU   0                        PARAMETER REGISTER 0            10000015
CMPREG   EQU   0                        LOWER LIMIT OF GETSTEP SEARCH   10050015
PQEREG   EQU   3                        ADDR OF PQE                     10100015
TCBREG   EQU   4                        ADDR OF ROLLOUT TCB- ENVIRONMT. 10150015
IRBREG   EQU   5                        ROLLOUT IRB - ENVIRONMENTAL     10200015
JSTREG   EQU   6                        ADDR OF JOB STEP TCB            10250015
GETREG   EQU   9                        SAVES LOWEST JOB STEP TCB       10300015
LSTREG   EQU   WKREG3                   LAST TCB FOUND BY GETSTEP       10350015
CVTREG   EQU   WKREG1                                                   10400015
SELREG   EQU   WKREG2                   INPUT REG TO TASK SELECT        10450015
LASTRG   EQU   WKREG3                   USED AS WORK REG IN TASK SELECT 10500015
REGREG   EQU   WKREG3                   REGION START REG.               10550015
IQEREG   EQU   WKREG3                   IQE DSECT REGISTER              10600015
RTNREG   EQU   15                       REUTRN CODE REGISTER            10650015
STPREG   EQU   WKREG1                   JOBSTEP TCB ADDRESS             10700015
RQEREG   EQU   WKREG3                   ADDRESS OF REPLY QUEUE ELEMENT  10750015
PTR      EQU   WKREG0                   POINTER FOR FBQE RECONSTRUCTION 10800015
TCB      EQU   WKREG1                   TCB ADDR IN FBQE RECONSTRUCTION 10850015
SPQE     EQU   WKREG2                   SPQE ADR IN FBQE RECONSTRUCTION 10900015
DQE      EQU   WKREG3                   DQE ADDR IN FBQE RECONSTRUCTION 10950015
WORK     EQU   WKREG1                   WORKREG FOR FBQE RECONSTRUCTION 11000015
MRBASE   EQU   8                        BASE REGISTER FOR MRELEASE RTN  11050015
QGM2BAS  EQU   3                           QGM'S SEC BASE         20002 11060020
MRPQE    EQU   2                        PQE ADDRESS FOR MRELEASE        11100015
MRSIZE   EQU   15                       BLOCK SIZE FOR MRELEASE         11150015
MRADDR   EQU   14                       BLOCK ADDRESS FOR MRELEASE      11200015
MRBRCH   EQU   1                        ENTRY ADDRESS OF MRELEASE       11250015
MRETRN   EQU   9                        RETURN ADDRESS FOR MRELEASE     11300015
RIQEREG  EQU   9                        ADDRESS OF ROLLOUT I/O QUEUE EL 11350015
PRIREG   EQU   11                       PREVIOUS RIQE ADDRESS           11400015
CURRTCB  EQU   10                       CURRENT TCB ADDRESS FOR RESTORE 11450015
TASKREG  EQU   10                       SELECTED TCB ADDRESS FOR RESTOR 11500015
TASKSAVE EQU   14                       ADDRESS OF SAVE AREA FOR RESTOR 11550015
SWREG    EQU   11                       ENTRY TO TASK SWITCHING RTN     11600015
SWRET    EQU   14                       RETURN FROM TASK SWITCHING RTN  11650015
IOBREG   EQU   11                       IOB CHAIN ADDRESS IN RIQE       11700015
JOBREG   EQU   7                                                        11750015
LNKRG1   EQU   1                                                        11770015
N1       EQU   1                                                        11777017
N4       EQU   4                                                        11784017
N140     EQU   140                                                 MCS  11787018
R15      EQU   15                                                       11791017
UCMREG   EQU   1                                                        11795018
ZERO      EQU    0                                               A33277 11797020
TMERET   EQU   14                  RETURN ADDR FROM WAIT CHK    SA64957 11797421
TMEGOTO  EQU   15                  ADDR OF WAIT CHECK RTN       SA64957 11797821
TQEFLGS  EQU   0                   DISP IN TQE TO FLAG BYTE     SA64957 11798221
TQEREAL  EQU   X'03'               FLG TO INDICATE REAL TQE     SA64957 11798621
RBWAIT   EQU   X'08'               TURNED ON BY WAIT TO SHOW    SA64957 11799021
*                                  ECB POST REQUIRED            SA64957 11799421
         SPACE 3                                                        11800015
IEAQRORI CSECT                                                          11850015
*2551,948000,959800                                               0626  11870017
*0114,130715-130704,130760,130780,217800,968082,968083,968500      MO18 11876018
*0114,298831,462165,482675,620000,628000,867000                    MCS  11882018
*0114,460000-461000,462180                                         MP2K 11888018
*0114,126700,652500,747000                                         2650 11894018
         SPACE 2                                                        11900015
         EXTRN IEAQAPG1,IEAQAPG2,IEAQAPG3,IEAQAPG4                      11950015
         EXTRN IEAMSTCB                 ADDR OF MASTER TCB              12000015
         EXTRN IEA0AB00                 ADDRESS OF ABTERM ROUTINE       12050015
         EXTRN IEAQPRT0                 ADDRESS OF QPR MODULE    A62695 12060021
         EXTRN DISPINIT                 ADDRESS OF DISPINIT      A62695 12070021
         EXTRN IEARCTRS                                                 12100015
         EXTRN IEAROICT                                                 12150015
         EXTRN IEAROQCT                                                 12200015
         EXTRN IEAROQUE                                                 12250015
         EXTRN IEAROPRM                                                 12300015
         EXTRN MSSBASE                  BASE ADDRESS FOR MRELEASE RTN   12350015
         EXTRN MRELEASE                 ADDRESS OF MRELEASE RTN         12400015
         EXTRN IEATCBP                  ADDRESS OF 'NEW'                12450015
         EXTRN IEA0DS02                 ADDRESS OF TASK SWITCHING RTN   12500015
         EXTRN IEAHEAD                  ADDRESS OF HEAD OF TCB QUEUE    12550015
         EXTRN IEA0DS                   ADDRESS OF DISPATCHER           12600015
         EXTRN IEAROTCB                 ADDRESS OF ROLLOUT TCB          12650015
         SPACE 2                                                        12700015
         USING RPLSECT,PMREG2                                           12750015
         USING IRBSECT,IRBREG                                           12800015
         SPACE 2                                                        12850015
         BALR  BASREG,0                                                 12900015
*                                  BIT IS ON IN IQE             SA66075 12910021
STARTUP  EQU   *                                                SA66075 12920021
         USING *,BASREG                                                 12950015
         SPACE 2                                                        13000015
         LA    SAVREG,SAVAREA           LOAD ADDR OF 18 WORD SAVE AREA  13050015
         USING SAVEAREA,SAVREG                                  SA66075 13050521
         EJECT                                                          13051015
*********************************************************************** 13055015
*********************************************************************** 13056015
*********************************************************************** 13057015
*                                                                       13058015
*                                                                       13059015
*  THIS ROUTINE , USING A WTOR , OFFERS THE USER THE OPTION TO SUPPRESS 13060015
*                                                                       13061015
*  THE ROLLOUT/ROLLIN WTO MESSAGES.                                     13062015
*                                                                       13063015
*                                                                       13064015
         BC    15,ASKIT                                                 13065015
ASKIT    EQU   *                                                        13066015
         STM   0,15,SAVAREA            SAVE REGISTERS                   13067015
         OC    FRSTSW(1),FRSTSW        IS FIRST TIME SWITCH ZERO        13068015
         BC    4,EOASKIT               NO. BRANCH AROND MESSAGE         13069015
         MVI   FRSTSW,X'FF'            SET FIRST TIME SWITCH OFF        13070015
ASKWTR   SSM   ENABLE                                                   13071015
         L     WKREG1,WTOR1             ADDR OF WTOR CSECT         MO18 13072018
         BALR  WKREG2,WKREG1            GO TO WTOR CSECT           MO18 13073018
         SSM   DISABLE                                                  13075015
         L     WKREG2,REPLYRA                                      MO18 13075518
         CLI   0(WKREG2),X'E8'          IS ANSWER YES              MO18 13076218
         BC    8,EOASKIT               IF SO DO NOT TURN OFF WTO        13077015
         CLI   0(WKREG2),X'D5'          IS ANSWER NO               MO18 13078018
         BC    7,ASKWTR                IF NOT REPEAT MESSAGE            13079015
         MVC   ROLLOWTO+2(2),ADDRPTR1                                   13080015
         MVC   STLROWT-2(2),ADDRPTR2                                    13081015
         MVC   STLRIWT-2(2),ADDRPTR3                                    13082015
         MVC   ROLLIWTR-2(2),ADDRPTR4                                   13083015
EOASKIT  EQU   *                                                        13084015
         LM    0,15,SAVAREA            RESTORE REGISTERS                13085015
*                                                                       13086015
*                                                                       13087015
*********************************************************************** 13088015
*********************************************************************** 13089015
*********************************************************************** 13093015
*********************************************************************** 13094015
         EJECT                                                          13095015
         L     WKREG1,ROPARAM           ADDRESS OF IEAROPRM             13100015
         ST    PMREG1,0(WKREG1)         STORE ADDRESS OF PARAMETER LIST 13150015
*   THE FOLLOWING CODE INITIALIZES  TCBREG AND IRBREG TO THE ADDRESS    13200015
*   OF THE ROLLOUT  TCB AND IRB RESPECTIVELY.                           13250015
         SPACE 1                                                        13300015
         L     CVTREG,CVTPTR            LOAD POINTER TO CVT             13350015
         USING CVTSECT,CVTREG                                           13400015
         L     WKREG2,CVTTCBP           LOAD POINTER TO NEW AND OLD     13450015
         L     TCBREG,4(WKREG2)         LOAD ADDR OF CURR. TCB- ROLLOUT 13500015
         DROP  CVTREG                                                   13550015
         USING TCBSECT,TCBREG                                           13600015
         L     IRBREG,TCBRBP            LOAD ADDR OF CURRENT RB-ROLLOUT 13650015
         DROP  TCBREG                                                   13700015
         LTR   PMREG2,PMREG1            LOAD AND TEST PARAMETER REG.    13750015
         BC    8,DEQUEUE                IF ZERO, BR TO DEQUEUE ROUTINE  13800015
         BC    4,ROLLIN                 IF NEGATIVE, BR TO ROLLIN CRIT. 13850015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  ROLLOUT CRITERION'           13900015
**********************************************************************  13950015
**********************      ROLLOUT  CRITERION       ****************** 14000015
**********************************************************************  14050015
*                                                                       14100015
*                                                                       14150015
         USING TCBSECT,JSTREG                                           14200015
         TM    RPLABND,RPLABNDS    IF TASK ABENDING,            SA66075 14210021
         BO    RETEXIT             IGNORE REQUEST               SA66075 14220021
         SPACE 1                                                        14250015
         L     JSTREG,RPLTCB            LOAD ADDR OF REQUESTING TCB     14300015
         L     JSTREG,TCBJSTCB          LOAD ADDR OF REQUESTING JSTCB   14350015
         L     WKREG1,ROICTR            PTR TO ROLLOUT INVOKED COUNTER  14400015
         CLC   0(2,WKREG1),K1           COMPARE NO OF ROLLOUTS TO ONE   14450015
         BC    4,RR003                  IF COUNT LESS THAN 1, BR TO     14500015
*                                       TRY TO GETPART                  14550015
         BC    2,RR001                  IF COUNT MORE THAN 1 BR TO TEST 14600015
         TM    TCBFLGS+2,TCBFRI         CURRENT JSTCB INVOKED ROLLOUT?  14650015
         BC    7,RR003                  YES, BR TO TRY GETPART          14700015
RR001    EQU   *                                                        14750015
         DROP  JSTREG                                                   14800015
         USING TCBSECT,WKREG1                                           14850015
         LR    WKREG1,TCBREG            LOAD ADDR OF ROLLOUT TCB        14900015
RR0012   EQU   *                                                        14950015
         L     WKREG1,TCBTCB            LOAD NEXT TCB ON READY QUEUE    15000015
         LTR   WKREG1,WKREG1            END OF READY QUEUE              15050015
         BC    8,RR003                  YES, BR TO GETPART              15100015
         TM    TCBFLGS+2,TCBFRI         HAS TCB INVOKED ROLLOUT         15150015
         BC    8,RR0012                 NO, BR TO GET NEXT TCB          15200015
         C     JSTREG,X'7C'(WKREG1)    SAME JSTCB AS REQUESTOR          15250015
         BC    8,RR0012                 YES, BR TO CHECK NEXT TCB       15300015
         DROP  WKREG1                                                   15350015
         SPACE 1                                                        15400015
*                                                                       15450015
*   IEAQAPG1   COINCIDENT ROLLOUT APPENDAGE INTERFACE                   15500015
*                                                                       15550015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE COINCIDENT ROLLOUT     15600015
*   APPENDAGE WHICH IS ENTERED WHEN A ROLLOUT IS REQUESTED FOR A        15650015
*   STEP BUT A ROLLOUT IS ALREADY IN EFFECT FOR ANOTHER JOB STEP.       15700015
*   THE APPENDAGE CAN REQUEST THAT AN IMMEDIATE ROLLOUT BE ATTEMPTED    15750015
*   ANYWAY, OR THAT THE ROLLOUT REQUEST BE QUEUED.                      15800015
*                                                                       15850015
*   INPUT -    REG  0 (PMREG0)  ADDR OF ROLLOUT COUNTERS                15900015
*              REG  1 (PMREG1)  ADDR OF TCB REQUESTING SPACE            15950015
*              REG 13 (SAVREG)  ADDR OF 18 WORD SAVE AREA               16000015
*              REG 14 (RETREG)  RETURN ADDRESS                          16050015
*              REG 15 (APGREG)  BASE ADDRESS OF APPENDAGE               16100015
*                                                                       16150015
*   RETURN-    REG  1 (PMREG1)  UNCHANGED = IMMEDIATE ROLLOUT IS NOT    16200015
*                                           DESIRED.                    16250015
*                               COMPLEMENT= IMMEDIATE ROLLOUT IS        16300015
*                                           DESIRED.                    16350015
*                                                                       16400015
*   NOTE  -    THE IBM-SUPPLIED APPENDAGE (IEAQAPG1) WILL NOT           16450015
*              REQUEST AN IMMEDIATE ROLLOUT.  IF MORE THAN ONE STEP     16500015
*              IS ALLOWED TO CAUSE ROLLOUT AT THE SAME TIME, THE        16550015
*              SITUATION MUST BE CAREFULLY CONTROLLED IN ORDER TO       16600015
*              PREVENT POTENTIAL INTERLOCKS  (IE. TWO STEPS REQUIRE     16650015
*              TWO-THIRDS OF THE MACHINE AT THE SAME TIME.)             16700015
         SPACE 2                                                        16750015
         L     APGREG,RRAPG1            LOAD ADDRESS OF APPENDAGE       16800015
         L     PMREG0,RORICTRS          LOAD ADDR OF ROLLOUT COUNTERS   16850015
         L     PMREG1,RPLTCB            LOAD ADDR OF REQUESTING TCB     16900015
         BALR  RETREG,APGREG            BR TO COINCIDENT ROLLOUT APPEND 16950015
         TM    RPLABND,RPLABNDS    IF TASK ABENDING,            SA66075 16960021
         BO    RETEXIT             IGNORE REQUEST               SA66075 16970021
         LTR   PMREG1,PMREG1            Q. ROLLOUT ANYWAY               17000015
         BC    4,RR003                  YES, BR TO TEST GETPART         17050015
         SPACE 1                                                        17100015
*   DEQUEUE THE CURRENT IQE FROM THE ROLLOUT IRB AND PLACE IT ON THE    17150015
*   ROLLOUT REQUEST QUEUE.                                              17200015
         SPACE 1                                                        17250015
         USING IQESECT,IQEREG                                           17300015
RR002    EQU   *                                                        17350015
         L     IQEREG,RBIQE-1           LOAD ADDR OF IQE                17400015
         LA    IQEREG,0(IQEREG)         CLEAR OUT COUNT BYTE     A35024 17410020
         MVC   RBIQE(3),IQELNK+1        DEQUEUE IQE FROM IRB            17450015
         USING TCBSECT,WKREG1                                           17500015
         L     WKREG1,IQETCB+4          LOAD TCB ADDRESS OF NEW IQE     17550020
         LR    WKREG2,WKREG1            SAVE TCB ADDRESS                17650015
         L     LKREG1,RORIQUE           LOAD ADCON OF IEAROQUE          17750015
         L     WKREG1,0(LKREG1)         LOAD ADDRESS OF FIRST IQE       17850015
         LTR   WKREG1,WKREG1            HAVE ANY IQE'S BEEN STORED      17950015
         BC    7,RRIQ02                 YES.  CHECK PRIORITY            18050015
         BC    15,RRIQ01                NO. INSERT IN QUEUE             18150015
RRIQ02   L     TCBREG,16(WKREG1)        GET TCB ADDRESS                 18250015
         CLC   35(1,TCBREG),35(WKREG2) CHECK PRIORITY                   18350015
         BC    4,RRIQ01                INSERT IF HIGHER PRIORITY        18450015
         LR    LKREG1,WKREG1            SAVE PREVIOUS                   18550015
         L     WKREG1,0(WKREG1)         GET NEXT IQE                    18650015
         LTR   WKREG1,WKREG1            WAS IT LAST ON QUEUE            18750015
         BC    7,RRIQ02                 NO.TEST NEXT                    18850015
RRIQ01   MVC   1(3,IQEREG),1(LKREG1)    LINK OLD TO NEW                 18950015
         ST    IQEREG,0(LKREG1)         LINK NEW TO OLD                 19050015
         DROP  WKREG1                                                   19250015
*                                                                       19300015
RRIQ05   EQU   *                                                        19350015
         L     WKREG2,ROQCTR            PTR TO ROLLOUT QUEUE COUNT      19400015
         LH    WKREG1,0(WKREG2)         LOAD ROLLOUT COUNT              19450015
         LA    WKREG1,1(WKREG1)         INCREMENT COUNTER BY ONE        19500015
         STH   WKREG1,0(WKREG2)         STORE INCREMENTED COUNT         19550015
         BC    15,EXIT2                                                 19600015
         DROP  IQEREG                                                   19650015
         SPACE 1                                                        19700015
RR003    EQU   *                                                        19750015
         LA    PMREG1,GETPARM           LOAD ADDR OF GETMAIN LIST       19800015
         MVC   GETHI(N1),RPLHRID       SET HIARCHY REQUEST         LCS1 19820017
         MVC   GETPARM(N4),RPLHRID     MOVE REQ'D SIZE AND HIACHY  LCS1 19840017
*                                      ID INTO ROLLOUT PARM FIELD  LCS1 19860017
         GETMAIN MF=(E,(1))             ISSUE CONDITIONAL GETPART       19900015
         LTR   RTNREG,RTNREG            Q. WAS A PQE RETURNED           19950015
         BC    7,RR01                   NO, BR TO TEST FOR ROLLOUT      20000015
         USING PQESECT,PQEREG                                           20050015
         L     PQEREG,GETPQE            YES, LOAD ADDR OF PQE ACQUIRED  20100015
         L     WKREG3,PQETCB            TCB ADDRESS OF PQE              20150015
         ST    RTNREG,PQETCB           STORE ZERO IN TCB ADDR OF PQE    21150015
         B     RR0B4               GO QUEUE PQE                 SA66075 21160021
         EJECT                                                          21180015
*********************************************************************** 21300015
*********************************************************************** 21330015
*********************************************************************** 21360015
*                                                                       21390015
*                                                                       21420015
STLROWT0 EQU   *                                                SA66075 21430021
         BC    15,STLROWT                                               21450015
STLROWT  EQU   *                                                        21480015
         USING TCBSECT,JSTREG                                           21510015
         L     WKREG2,TCBTIO                                            21540015
         DROP  JSTREG                                                   21570015
         L     WKREG1,WTO2              ADDR OF WTO CSECT          MO18 21580018
         MVC   LROWTOST(8,WKREG1),8(WKREG2)                        MO18 21590018
         MVC   LROWTOJB(8,WKREG1),0(WKREG2)                      A29153 21600019
         MVC   TESTSAVE(4),PQESIZE     MOVE PQESIZE TO WORK AREA        21610015
         UNPK  TESTSAVE(8),TESTSAVE(5)                                  21620015
         TR    TESTSAVE+1(6),DSCS-240                                   21630015
         MVC   LROWTOSZ(6,WKREG1),TESTSAVE+1                       MO18 21640018
         MVC   TESTSAVE(4),PQEREGN     MOVE REGION ADDR TO WORK AREA    21650015
         UNPK  TESTSAVE(8),TESTSAVE(5)                                  21660015
         TR    TESTSAVE+1(6),DSCS-240                                   21670015
         MVC   LROWTORG(6,WKREG1),TESTSAVE+1                       MO18 21690018
         SSM   ENABLE                                                   21720015
         CNOP  0,4                                                MO0A  21750017
LROWTR   EQU   *                                                   MO18 21770018
         BALR  WKREG2,WKREG1            GO TO WTO CSECT            MO18 21790018
         SSM   DISABLE                                                  21810015
         B     RR0065A             CLEAN UP                     SA66075 21820021
*                                                                       21840015
*                                                                       21870015
*********************************************************************** 21900015
*********************************************************************** 21930015
*********************************************************************** 22020015
*********************************************************************** 22050015
         EJECT                                                          22080015
RR0B4    EQU   *                                                        22400015
         L     WKREG2,ROICTR            PTR TO ROLLOUTS INVOKED         22450015
         LH    WKREG1,0(WKREG2)         GET NO INVOKED                  22500015
         LA    WKREG1,1(WKREG1)         INCREMENT COUNT BY ONE          22550015
         STH   WKREG1,0(WKREG2)                                         22600015
         MVI   PQERFLGS,PQEBOR          SET BORROW BIT IN NEW PQE       22650015
         TM    RPLABND,RPLABNDS    IF TASK ABENDING,            SA66075 22652021
         BZ    RR0B4A              REVERSE ROLLOUT              SA66075 22654021
*                                                               SA66075 22656021
** CONVERT THE ROLLOUT REQUEST TO A ROLLIN REQUEST              SA66075 22658021
** THIS ALLOWS RORI TO RECOVER FROM A TASK WHICH                SA66075 22660021
** REQUESTS ROLLOUT BEING CANCELLED.  NOTE THAT THE             SA66075 22662021
** GETMAIN REQUEST MUST HAVE CAUSED ROLLOUT SINCE               SA66075 22664021
** RORI HAS NOT BEEN ENABLED SINCE ISSUING THE                  SA66075 22666021
** SUCCESSFUL GETMAIN FOR UNUSED CORE.                          SA66075 22668021
*                                                               SA66075 22670021
         L     WKREG1,RBIQE-1      POINT TO IQE                 SA66075 22672021
         LNR   PMREG1,PMREG2       MAKE PARM NEGATIVE           SA66075 22674021
         ST    PMREG1,IQEPARAM-IQESECT(,WKREG1)  (SHOW ROLLIN)  SA66075 22676021
         ST    PQEREG,RPLSZPQE-1   ADDRESS OF PQE TO FREE       SA66075 22678021
         BR    BASREG              RE-TRY                       SA66075 22680021
*                                                               SA66075 22682021
RR0B4A   EQU   *                                                SA66075 22684021
         SPACE 2                                                        22700015
*   THE FOLLOWING CODE ENQUEUES THE BORROWED PQE ON THE PQE CHAIN OF    22760015
*   THE STEP REQUESTING ROLLOUT                                         22820015
         SPACE 2                                                        22900015
         USING TCBSECT,JSTREG                                           22950015
         L     WKREG1,TCBPQE            LOAD ADDR OF DUMMY PQE OF       23000015
*                                       STEP REQUESTING ROLLOUT         23050015
         DROP  JSTREG                                                   23100015
         L     WKREG1,XPQEFPQE(WKREG1)  LOAD NEXT PQE ON CHAIN          23250015
RR006    EQU   *                                                        23260015
         L     WKREG2,XPQEBPQE(WKREG1) LOAD PTR ADDR OF CURR PQE        23270015
         CLC   PQEREGN(4),XPQEREGN(WKREG1) COMPARE REGION START ADDR    23300015
         BC    2,RR0HI                      HI TEST FOR END OF CHAIN    23350015
         LTR   WKREG2,WKREG2                Q,IS HOST FIRST PQE         23400015
         BC    8,RRN01                      YES,SET NEW PQE AS NEW 1ST  23450015
         STM   WKREG1,WKREG2,PQEFPQE   STORE FWD AND BACK PQE PTRS      23500015
         ST    PQEREG,XPQEFPQE(WKREG2) STORE FWD PQE PTR IN PREVIOUS    23530015
         ST    PQEREG,XPQEBPQE(WKREG1) STORE BACK PTR IN NEXT           23560015
         BC    15,RR0065                                                23600015
*                                                                       23650015
RRN01    EQU   *                                                        23700015
*                                                                       23750015
* TO SET UP BORROWED PQE AS FIRST IN THE CHAIN                          23800015
*                                                                       23850015
*               ...STORE ADDRESS OF NEW AS BACK PTR IN HOST             23900015
*               ...STORE ADDRESS OF HOST AS FWD PTR IN NEW              23950015
*               ...STORE ZERO AS BACK PTR IN NEW                        24000015
*               ...STORE ADDRESS OF NEW AS FIRST IN DUMMY PQE           24050015
*                                                                       24100015
         ST    PQEREG,XPQEBPQE(WKREG1)     ADDR OF NEW AS HOST BACK PTR 24150015
         STM   WKREG1,WKREG2,PQEFPQE       ADDR OF HOST AS NEW FWD PTR  24200015
*                                          AND ZERO AS NEW BACK PTR     24250015
         USING TCBSECT,JSTREG          ADDRESSABILITY TO HOST JSTCB     24320015
         L     WKREG2,TCBPQE               LOAD ADDR OF HOST DUMMY PQE  24400015
         DROP JSTREG                                                    24450015
         ST    PQEREG,XPQEFPQE(WKREG2)     STORE ADDR OF NEW AS NEW 1ST 24500015
         BC    15,RR0065                                                24550015
*                                                                       24600015
RR0HI    EQU   *                                                        24650015
*                                                                       24700015
         LR    WKREG2,WKREG1           SAVE CURRENT PQE ADDRESS         24710015
         L     WKREG1,XPQEFPQE(WKREG1) LOAD NEXT PGE ON CHAIN           24720015
         LTR   WKREG1,WKREG1                Q.IS HOST LAST PQE          24750015
         BC    7,RR006                      NO,GET NEXT PQE IN CHAIN    24800015
*                                                                       24850015
* TO SET UP BORROWED PQE AS LAST IN CHAIN                               24900015
*                                                                       24950015
*               ...STORE ADDR OF NEW AS FWD PTR IN HOST                 25000015
*               ...STORE ADDR OF HOST AS BACK PTR IN NEW                25050015
*               ...STORE ZERO AS FWD PTR IN NEW                         25100015
*               ...STORE ADDR OF NEW AS LAST IN DUMMY PQE               25150015
*                                                                       25200015
         ST    PQEREG,XPQEFPQE(WKREG2)      ADDR OF NEW AS HOST FWD PTR 25250015
         STM   WKREG1,WKREG2,PQEFPQE        ZERO AS NEW FWD PTR AND     25300015
*                                           ADDR OF HOST AS NEW BACK PT 25350015
         USING TCBSECT,JSTREG          ADDRESSABILITY TO HOST JSTCB     25420015
         L     WKREG1,TCBPQE                LOAD ADDR OF HOST DUMMY PQE 25500015
         DROP  JSTREG                                                   25550015
         ST    PQEREG,XPQEBPQE(WKREG1)      STORE ADDR OF NEW AS LAST   25600015
RR0065   EQU   *                                                        25700015
         L     WKREG1,PQETCB       IF PQETCB = 0                SA66075 25710021
         LTR   WKREG1,WKREG1       REGION FROM FREECORE         SA66075 25720021
         BZ    STLROWT0            TELL OPERATOR                SA66075 25730021
RR0065A  EQU   *                                                SA66075 25740021
         USING TCBSECT,WKREG1                                           25760015
         L     WKREG1,RPLTCB           LOAD ADDR OF REQ TCB             25820015
         OI    TCBFLGS+2,TCBFRI        SET RO INVOKED FLAG              25880015
RR008    EQU   *                                                        25940015
         L     WKREG1,RPLTCB           LOAD ADDR OF REQ TCB IF ABTERM   26000015
DOGFOX   EQU   X'DF'                 MASK TO RESET NONDISP FLG   A33335 26050020
F4       EQU   4                                                 A33335 26100020
         NI    TCBFLGS+F4,DOGFOX     RESET CORE WAIT NONDISP FLG A33335 26150020
         BC    15,RETEXIT               BR TO RETURN IQE AND EXIT       26200015
         DROP  WKREG1                                                   26250015
         SPACE 2                                                        26300015
RR01     EQU   *                                                        26350015
         SPACE 2                                                        26400015
*   GETSTEP INTERFACE                                                   26450015
         SPACE 1                                                        26500015
*                                                                       26550015
*        LKREG2     NO REGION FOUND TO SATISFY REQUEST                  26600015
*        LKREG2+4   REGION FOUND, PQE ADDR IN REG 0 (PMREG0)            26650015
         SPACE 2                                                        26700015
         LR    PMREG1,JSTREG            LOAD REQ. JSTCB FOR GETSTEP     26750015
         BAL   LKREG1,GETSTEP           LINK TO GETSTEP SUBROUTINE      26800015
         BC    15,RR08                  NO PQE FOUND, BR TO CHECK       26850015
*                                       ABEND APPENDAGE                 26900015
         LR    PQEREG,PMREG0            LOAD PQE INTO PQEREG            26950015
         L     PMREG1,PQETCB           LOAD JSTTCB OF PQE BEING         27000015
*                                       ROLLED OUT                      27050015
         TM    PQERFLGS,PQERO           IS PQE ALREADY ROLLED OUT ?     27100015
         BC    7,RR03                   YES, SKIP ROLLING OUT AGAIN     27150015
         USING TCBSECT,PMREG1                                           27200015
         TM    TCBFLGS+4,TCBFRO         HAS STEP ALREADY BEEN           27250015
*                                       ROLLED OUT                      27300015
         BC    7,RR02                   YES, SKIP SET STATUS + PURGING  27350015
         DROP  PMREG1                                                   27420015
         SPACE 1                                                        27500015
         STATUS SET,ND,(1),(12)         SET THE TCBFRO IN EACH TCB      27550015
*                                       IN THE STEP TO BE ROLLED OUT    27600015
         L     PMREG1,PQETCB       GET ADDR OF JS TCB         BL A43015 27610021
         L     LKREG9,TIMDEQ       GET ADDR TIMER DEQ RTN     BL A43015 27620021
         BALR  LKREG1,LKREG9       GO TO DEQUE TIMER ELEMENTS BL A43015 27630021
         SPACE 1                                                        27650015
         SPACE 2                                                        27700015
*   PRGIO      PURGE I/O INTERFACE                                      27750015
*                                                                       27800015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE ROLLOUT PURGE I/O      27850015
*   ROUTINE WHICH QUIESCES I/O FOR EACH TCB IN THE STEP TO BE ROLLED    27900015
*   OUT.                                                                27950015
*                                                                       28000015
*   INPUT -    REG  1 (PMREG1)  ADDR OF JOB STEP TCB TO BE ROLLED OUT   28050015
*              REG  8 (LKREG1)  RETURN ADDRESS                          28100015
         SPACE 3                                                        28150015
         L     PMREG1,PQETCB            LOAD ADDR OF STEP TO ROLL OUT   28200015
         BAL   LKREG1,PRGIO             LINK TO PURGE I/O ROUTINE       28250015
         SPACE 2                                                        28300015
*   PRGRQE     PURGE REPLY QUEUE ELEMENTS INTERFACE                     28350015
*                                                                       28400015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE REPLY PURGE ROUTINE    28450015
*   WHICH SETS THE ROLLOUT BIT IN EACH REPLY QUEUE ELEMENT (RQE)        28500015
*   THAT IS OUTSTANDING FOR THE JOB STEP TO BE ROLLED OUT.  THIS BIT    28550015
*   CAN BE TESTED WHEN A REPLY TO A WTOR IS RECEIVED, AND IF SET, THE   28600015
*   MESSAGE AND ECB CAN BE SAVED UNTIL THE STEP IS ROLLED IN.           28650015
*                                                                       28700015
*   INPUT      REG  1 (PMREG1)  ADDR OF JOB STEP TCB TO BE ROLLED OUT   28750015
*              REG  8 (LKREG1)  RETURN ADDRESS                          28800015
         SPACE 2                                                        28850015
         L     PMREG1,PQETCB            LOAD ADDR OF STEP TO ROLL OUT   28900015
         BAL   LKREG1,PRGRQE            LINK TO HANDLE RQE'S FOR STEP   28950015
         SPACE 3                                                        29000015
*   STARTIO    ROLLOUT I/O INTERFACE                                    29050015
*                                                                       29100015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE ROLLOUT I/O ROUTINE    29150015
*   WHICH SAVES THE CONTENTS OF THE REGION DESCRIBED BY THE INPUT       29200015
*   PQE ON THE ROLLOUT DATA SET.                                        29250015
*                                                                       29300015
*   INPUT-     REG  1 (PMREG1)          ADDR OF PQE TO BE ROLLED OUT    29350015
*              REG  8 (LKREG1)          RETURN ADDRESS                  29400015
*                                                                       29450015
*   RETURN     LKREG1                                                   29520015
*                                                                       29600015
         SPACE 2                                                        29650015
RR02     EQU   *                                                        29700015
         LR    PMREG1,PQEREG            LOAD ADDR OF PQE                29750015
         BAL   LKREG1,STARTIO           LINK TO ROLLOUT I/O ROUTINE     29800015
         EJECT                                                          29851015
*********************************************************************** 29855015
*********************************************************************** 29856015
*********************************************************************** 29857015
*                                                                       29858015
*                                                                       29859015
*  THIS ROUTINE WRITES A MESSAGE TO THE OPERATOR IN THE FORMAT          29860015
*     'IEA123I,JOBNAME,STEPNAME R/O OFJOBNAME,STEPNAME'                 29861015
*                                                                       29862015
*  AT THE COMPLETION OF A PHYSICAL ROLLOUT.                             29863015
*                                                                       29864015
*                                                                       29865015
ROLLOWTO EQU   *                                                        29866015
         BC    15,STRLLOWT                                              29867015
STRLLOWT EQU   *                                                  MO0A  29868017
         L     WKREG2,ADDRPTR1         GET ADDR OF OWNING JSTCB   MO0A  29869017
         USING TCBSECT,WKREG2                                           29872015
         L     WKREG2,TCBTIO           GET TIOT ADDRESS                 29873015
         L     WKREG1,WT03 .            ADDR OF WTO CSECT        21472  29873521
         DROP  WKREG2                                                   29874015
         MVC   ROLLEEJB(8,WKREG1),0(WKREG2) .MOVE JOBNAME        21472  29875021
         MVC   ROLLEEST(8,WKREG1),8(WKREG2) .MOVE STEPNAME       21472  29876021
         USING TCBSECT,JSTREG                                           29877015
         L     WKREG2,TCBTIO                                            29878015
         DROP  JSTREG                                                   29879015
         MVC   ROLLERJB(8,WKREG1),0(WKREG2) .MOVE JOBNAME        21472  29880021
         MVC   ROLLERST(8,WKREG1),8(WKREG2) .MOVE STEPNAME       21472  29881021
         BALR  WKREG2,WKREG1 .          WTO CSECT                21472  29882021
         CNOP  0,4                                                21472 29883021
EORLLOWT EQU   *                                                        29884015
*                                                                       29885015
*                                                                       29886015
*********************************************************************** 29887015
*********************************************************************** 29888015
*********************************************************************** 29892015
*********************************************************************** 29893015
         EJECT                                                          29894015
         SSM   DISABLE                  DISABLE                         29900015
RR03     EQU   *                                                        29950015
         OI    PQERFLGS,PQERO+PQEUSE    SET ROLLED OUT AND IN USE BITS  30000015
         SPACE 2                                                        30050015
BUILDPQE EQU   *                                                        30100015
         SPACE 1                                                        30150015
*   THIS ROUTINE BUILDS A PQE DESCRIBING THE BORROWED                   30200015
*   REGION.  THE LAST FOUR WORDS OF THE PQE (TCB,SIZE,START OF          30250015
*   REGION,FLAGS) ARE COPIED FROM THE PQE FOR THE ROLLED OUT REGION.    30300015
*   THE NEW PQE POINTS TO AN FBQE WHICH DESCRIBES THE ENTIRE            30350015
*   REGION AS FREE.  THE DUPLICATE PQE WILL SUBSEQUENTLY BE             30400015
*   ENQUEUED ON THE PQE CHAIN OF THE STEP WHICH CAUSED ROLLOUT.         30450015
         SPACE 3                                                        30500015
         GETMAIN R,LV=32,SP=255         GET SPACE FOR A PQE             30550015
         MVC   XPQETCB(16,PMREG1),PQETCB  MOVE LAST 4 WORDS OF ROLLED   30600015
*                                       OUT PQE TO NEW PQE.             30650015
         LR    PQEREG,PMREG1            LOAD PQE ADDR INTO PQE REG      30700015
         L     PMREG1,PQEREGN           LOAD ADDR OF PQE                30750015
         ST    PMREG1,PQEFFBQE          STORE FORWARD FBQE INTO PQE     30800015
         ST    PMREG1,PQEBFBQE          STORE BACKWARD FBQE INTO PQE    30850015
         USING FBQESECT,PMREG1                                          30900015
         MVC   FBQESIZE+1(3),PQESIZE+1  PUT PQE SIZE IN THE FBQE        30950015
         MVI   FBQESIZE,X'00'           CLEAR HIGH ORDER BYTE           31000015
         ST    PQEREG,FBQEFWDP          STORE PQE ADDR IN FBQE FORWARD  31050015
         ST    PQEREG,FBQEBCKP          STORE PQE ADDR IN BACKWARD FBQE 31100015
         DROP  PMREG1                                                   31150015
         SPACE 1                                                        31200015
         SR    PMREG0,PMREG0            SET STORAGE KEY REG TO ZERO     31250015
         LR    PMREG1,PQEREG            LOAD PQE TO BE SET              31300015
         BAL   LKREG1,SETKEYS1          LINK TO SET BORROWED REGION     31350015
*                                       TO STORAGE KEY ZERO             31400015
         BC    15,RR0B4                                                 31450015
         SPACE 2                                                        31500015
RR08     EQU   *                                                        31550015
         NI    PRIORSW,OFF              TURN OFF PRIORITY PASS SWITCH   31600015
*                                                                       31650015
*                                                                       31700015
*   IEAQAPG3   ABEND APPENDAGE INTERFACE                                31750015
*                                                                       31800015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE ABEND APPENDAGE        31850015
*   WHICH IS ENTERED WHEN A ROLLOUT IS REQUESTED BUT CAN NOT BE         31900015
*   IMMEDIATELY SATISFIED FROM EITHER FREE SPACE OR BY ROLLING OUT      31950015
*   ANOTHER STEP.  THE APPENDAGE CAN SELECT A JOB STEP TO BE            32000015
*   ABENDED (INCLUDING THE STEP REQUESTING SPACE).                      32050015
*                                                                       32100015
*   INPUT -    REG  0 (PMREG0)  ADDR OF ROLLOUT COUNTERS                32150015
*              REG  1 (PMREG1)  ADDR OF TCB REQUESTING SPACE            32200015
*              REG 13 (SAVREG)  ADDR OF 18 WORD SAVE AREA               32250015
*              REG 14 (RETREG)  RETURN ADDRESS                          32300015
*              REG 15 (APGREG)  BASE ADDRESS OF APPENDAGE               32350015
*                                                                       32400015
*   RETURN-    REG  1 (PMREG1)  ZERO    = NO ABEND DESIRED              32450015
*                               NON-ZERO= ABEND JOB STEP SPECIFIED BY   32500015
*                                         REG 1.                        32550015
         SPACE 3                                                        32600015
         L     PMREG0,RORICTRS          LOAD ADDR OF ROLLOUT CTR        32650015
         L     PMREG1,RPLTCB            LOAD ADDR OF REQUESTING TCB     32700015
         L     APGREG,RRAPG3            LOAD ADDR OF ABEND APPENDAGE    32750015
          BALR RETREG,APGREG            BR TO THE ABEND APPENDAGE       32800015
         TM    RPLABND,RPLABNDS    IF TASK ABENDING,            SA66075 32810021
         BO    RETEXIT             IGNORE REQUEST               SA66075 32820021
         LTR   PMREG1,PMREG1            IS AN ABEND REQUESTED           32850015
         BC    8,RR002                  NO, BR TO QUEUE THE IQE         32900015
         LA    PMREG1,0(PMREG1)         CLEAR HIGH ORDER BYTE           32950015
         CR    PMREG1,JSTREG            Q. ABEND THE REQUESTING STEP    33000015
         LA    RETREG,RR008             LOAD ADDR OF ABTERM RETURN      33050015
*                                       IN ORDER TO SET THE ABTERMED    33100015
*                                       STEP DISPATCHABLE               33150015
         BC    8,RR083                  BR TO ABTERM THE STEP           33200015
         LR    WKREG3,TCBREG            LOAD ROLLOUT TCB AS BEGIN       33250015
         USING TCBSECT,WKREG3                                           33300015
RR081    EQU   *                                                        33350015
         L     WKREG3,TCBTCB            LOAD NEXT TCB ON READY QUEUE    33400015
         LTR   WKREG3,WKREG3            Q. LAST TCB ON QUEUE            33450015
         BC    8,RR002                  YES, SKIP ABTERM + QUEUE IQE    33500015
         CR    WKREG3,PMREG1            Q. FIND TCB ON READY QUEUE      33550015
         BC    7,RR081                  NO, BR TO GET NEXT TCB          33600015
         L     WKREG2,TCBJSTCB          LOAD ADDR OF JOB STEP TCB       33650015
         CR    WKREG2,WKREG3            DOES IT POINT TO SELF           33700015
         BC    7,RR002                  NO, SKIP ABTERM AND QUEUE IQE   33750015
         CLC   TCBOTC+1(3),MASTER+1     IS MASTER THE ORIGIN TCB        33800015
         BC    8,RR002                  YES, NOT JSTCB- SKIP ABTERM     33850015
         TM    29(PMREG1),X'C0'   IS TASK ABENDING                      33860015
         BC    5,RR002            YES. QUEUE IQE, SKIP ABTERM           33870015
         LA    RETREG,RR002             LOAD RTN ADDR FROM ABTERM- IE.  33900015
*                                       IN ORDER TO QUEUE ROLLOUT REQ.  33950015
         DROP  WKREG3                                                   34000015
RR083    EQU   *                                                        34050015
         LR    PMREG0,PMREG1      ADDR OF TCB TO BE ABTERMED            34110015
         L     PMREG1,ABENDCOD    ABEND CODE                            34170015
         L     APGREG,ABTERMAD          LOAD ENTRY POINT OF ABTERM      34250015
         BCR   15,APGREG                BR TO ABTERM                    34300015
         DROP  PQEREG                                                   34350015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  GETSTEP'                     34400015
*********************************************************************** 34450015
*   GETSTEP                                                             34500015
*                                                                       34550015
*   THE GETSTEP ROUTINE SEARCHES THE TCB READY QUEUE FOR THE LOWEST     34600015
*   PRIORITY JOB STEP THAT CAN BE ROLLED OUT AND WOULD SATISFY THE      34650015
*   ORIGINAL GETMAIN REQUEST.                                           34700015
*                                                                       34750015
*   REGISTER USAGE IN GETSTEP IS AS FOLLOWS -                           34800015
*                                                                       34850015
*              GETREG -  SAVE REG FOR TCB THAT SATISFIES REQUEST        34900015
*              LSTREG -  LAST TCB FOUND BY GETSTEP - IE. LOWER LIMIT    34950015
*                        REGISTER                                       35000015
*              CMPREG -  REG DETERMINES THE END OF SEARCH - LOWER LIMIT 35050015
*                        IF NORMAL SEARCH, CONTAINS REQUESTING JSTCB    35100015
*                        IF HIGH PRIORITY PASS, CONTAINS ZERO.          35150015
*              WKREG2 -  TCB REG USED IN READY QUEUE SEARCH             35200015
*                                                                       35250015
*                                                                       35300015
*                                                                       35350015
*   GETSTEP INPUT -                                                     35400015
*                   PMREG1 -  ADDR OF JSTCB INVOKING ROLLOUT            35450015
*                   PMREG2 -  PARAMETER LIST ADDRESS                    35500015
*                   LKREG1 -  RETURN ADDR                               35550015
*                                                                       35600015
*   GETSTEP RETURN- LKREG1 -  ERROR RETURN - REGION NOT FOUND           35650015
*                   LKREG1+4  NORMAL RETURN - PQE FOUND                 35700015
*                             PMREG0 = ADDR OF PQE TO BE ROLLED OUT     35750015
         SPACE 3                                                        35800015
GETSTEP  EQU   *                                                        35850015
         USING TCBSECT,JSTREG                                           35900015
         USING PQESECT,WKREG3                                           35950015
         NI    PRIORSW,X'7F'           TURN PRIORITY PASS SWITCH OFF    35970015
         TM    TCBFLGS+2,TCBFRI        HAS JOBSTEP INVOKED ROLLOUT      36000015
         BC    8,G03                    NO, BR TO SEARCH READY QUEUE    36050015
         SPACE 2                                                        36100015
*   THE FOLLOWING CODE CHECKS EACH PQE ATTACHED TO THE TCB THAT         36150015
*   REQUESTED ROLLOUT IN ORDER TO DETERMINE WHETHER THE CURRENT         36200015
*   REQUEST CAN BE SATISFIED FROM A REGION ALLOCATED TO A STEP THAT     36250015
*   HAS ALREADY BEEN ROLLED OUT BY THE REQUESTING STEP.                 36300015
         SPACE 2                                                        36350015
         L     WKREG3,TCBPQE            LOAD DUMMY PQE OF REQUESTOR     36400015
         DROP  JSTREG                                                   36450015
G01      EQU   *                                                        36500015
         L     WKREG3,PQEFPQE           LOAD NEXT PQE                   36550015
         LTR   WKREG3,WKREG3            Q. IS IT LAST PQE               36600015
         BC    8,G03                    YES, BR TO SEARCH READY QUEUE   36650015
         TM    PQERFLGS,PQEBOR          IS PQE BORROWED                 36700015
         BC    8,G01                    NO, BR TO GET NEXT PQE          36750015
G0101    EQU   *                                                        36800015
         SPACE 2                                                        36850015
*   TESTSTEP INTERFACE                                                  36900015
*                                                                       36950015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE TESTSTEP ROUTINE       37000015
*   WHICH DETERMINES WHETHER THE GIVEN STEP IS ROLLOUTABLE AND HAS A    37050015
*   REGION THAT SATISFIES THE REQUEST.  IF A SATISFACTORY REGION        37100015
*   IS FOUND, ITS PQE ADDRESS IS RETURNED.                              37150015
*                                                                       37200015
*   INPUT -    REG  1 (PMREG1)  ADDR OF JOB STEP TCB TO BE TESTED       37250015
*              REG  2 (PMREG2)  ADDR OF THE ROLLOUT PARAMETER LIST      37300015
*              REG  7 (LKREG2)  RETURN ADDRESS                          37350015
*   RETURN-    REG  0 (PMREG0)  ADDR OF PQE IF ONE IS FOUND             37400015
*              LKREG2           UNSUCCESSFUL RETURN - PQE NOT FOUND     37450015
*              LKREG2+4         SUCCESSFUL RETURN - PQE IN PMREG0       37500015
*                                                                       37550015
         SPACE 2                                                        37600015
         L     PMREG1,PQETCB            LOAD ADDR OF TCB THAT OWNS PQE  37650015
         LTR   PMREG1,PMREG1            Q. IS TCB ADDR IN PQE ZERO      37700015
         BC    8,G01                    YES, BORROWED FROM FREE, BR     37750015
*                                       TO GET NEXT PQE                 37800015
         BAL   LKREG2,TESTSTEP          LINK TO TESTSTEP TO GET PQE     37850015
         BC    15,G01                   NO PQE RETURNED, BR TO CHECK    37900015
*                                       NEXT PQE                        37950015
         BC    7,4(LKREG1)              YES, RETURN NORMALLY TO CALLER  38000015
*                                       WITH ADDR OF PQE IN PMREG0      38050015
         DROP  WKREG3                                                   38100015
G03      EQU   *                                                        38150015
         USING TCBSECT,WKREG2                                           38200015
         SR    LSTREG,LSTREG            INITIALIZE LAST TCB TO 0        38250015
G0301    EQU   *                                                        38300015
         SR    GETREG,GETREG            ZERO THE TCB SAVE REG           38350015
         SR    CMPREG,CMPREG            INIT LOWER LIMIT TO ZERO        38400015
         LR    WKREG2,JSTREG            INIT READY Q REG WITH JSTCB     38450015
         TM    PRIORSW,SET              IS HIGH PRIORITY PASS SW SET    38500015
         BC    8,G04                    NO, BR TO LOOK AT READY QUEUE   38550015
         LR    CMPREG,JSTREG            INIT LOWER LIMIT TO JSTCB       38600015
         L     WKREG2,MASTER                                            38650015
G04      EQU   *                                                        38700015
         L     WKREG2,TCBTCB            LOAD NEXT TCB IN READY QUEUE    38750015
         CR    WKREG2,CMPREG            REACHED LOWER LIMIT OF READY Q. 38800015
         BC    8,G05                    YES, BR TO TEST IF STEP FOUND   38850015
         C     WKREG2,TCBJSTCB          DOES JSTCB FIELD POINT TO SELF  38900015
         BC    7,G04                    NO, BR TO GET NEXT TCB ON READY 38950015
         CLC   TCBOTC+1(3),MASTER+1     Q. IS MASTER THE ORIGIN TCB     39000015
         BC    8,G04                    YES, BR TO GET NEXT TCB         39050015
         CR    WKREG2,LSTREG            SAME TCB AS LAST PROCESSED      39100015
         BC    8,G05                    YES, BR TO TEST IF STEP FOUND   39150015
         LR    GETREG,WKREG2            SAVE JSTCB ADDR IN GET REG      39200015
         BC    15,G04                   BR TO GET NEXT TCB ON READY Q.  39250015
G05      EQU   *                                                        39300015
         LTR   GETREG,GETREG            WAS A JSTCB FOUND               39350015
         BC    7,G07                    YES, BR TO TEST THE STEP        39400015
         TM    PRIORSW,SET              IS HIGH PRIORITY PASS SW SET    39450015
         BCR   7,LKREG1                 YES, RETURN TO CALLER AT ERROR  39500015
         DROP  WKREG2                                                   39550015
         SPACE 2                                                        39600015
*   IEAQAPG2   HIGH PRIORITY PASS APPENDAGE                             39650015
*                                                                       39700015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE HIGH PRIORITY PASS     39750015
*   APPENDAGE WHICH IS ENTERED WHEN A ROLLOUT IS REQUESTED BUT A        39800015
*   STEP OF LOWER PRIORITY THAN THE STEP REQUESTING ROLLOUT IS NOT      39850015
*   AVAILABLE FOR ROLLOUT.  THE APPENDAGE CAN REQUEST THAT ROLLOUT      39900015
*   SEARCH FOR A HIGHER PRIORITY STEP TO ROLLOUT.                       39950015
         SPACE 2                                                        40000015
*   INPUT -    REG  0 (PMREG0)  ADDR OF ROLLOUT ENVIRONMENT             40050015
*              REG  1 (PMREG1)  ADDR OF TCB REQUESTING ROLLOUT          40100015
*              REG 13 (SAVREG)  ADDR OF 18 WORD SAVE AREA               40150015
*              REG 14 (RETREG)  RETURN ADDRESS                          40200015
*              REG 15 (APGREG)  BASE ADDR OF APPENDAGE                  40250015
*                                                                       40300015
*   RETURN     REG  1 (PMREG1)  TRUE FROM = HIGH PRIORITY PASS NOT      40350015
*   INFO -                                  DESIRED                     40400015
*                               COMPLEMENT= HIGH PRIORITY PASS DESIRED  40450015
         SPACE 2                                                        40500015
         L     PMREG0,RORICTRS          LOAD ADDR OF ROLLOUT CTR        40550015
         L     PMREG1,RPLTCB            LOAD ADDR OF REQUESTING TCB     40600015
         L     APGREG,RRAPG2            LOAD ADDR OF THE APPENDAGE      40650015
         BALR  RETREG,APGREG            BR TO HIGH PRIORITY PASS        40700015
*                                       APPENDAGE                       40750015
         TM    RPLABND,RPLABNDS    IF TASK ABENDING,            SA66075 40760021
         BO    RETEXIT             IGNORE REQUEST               SA66075 40770021
         LTR   PMREG1,PMREG1            HIGH PRIORITY PASS DESIRED      40800015
         BCR   10,LKREG1                NO, RETURN TO CALLER AT         40850015
*                                       ERROR RETURN                    40900015
         OI    PRIORSW,SET              SET PRIORITY SWITCH             40950015
         BC    15,G0301                 BR TO SEARCH FOR ANOTHER STEP   41000015
G07      EQU   *                                                        41050015
         LR    LSTREG,GETREG            UPDATE LAST REG TO NEW TCB      41100015
         SPACE 2                                                        41150015
*   TESTSTEP INTERFACE                                                  41200015
         SPACE 2                                                        41250015
         LR    PMREG1,GETREG            LOAD ADDR OF JSTCB TO BE TESTED 41300015
         BAL   LKREG2,TESTSTEP          LINK TO THE TEST STEP SUBROUT.  41350015
         BC    15,G0301                 BR TO SEARCH FOR ANOTHER STEP   41400015
         BC    15,4(LKREG1)             PQE RETURNED, RETURN TO CALLER  41450015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  TESTSTEP'                    41500015
*********************************************************************** 41550015
*   TESTSTEP                                                            41600015
*                                                                       41650015
*   TESTSTEP SEARCHES THE INPUTTED JOBSTEP TCB PQE QUEUE FOR A PQE      41700015
*   THAT FULFILLS THE REQUEST AND IS ROLLOUTABLE.  IF A PQE IS FOUND,   41750015
*   ITS ADDRESS IS RETURNED IN REGISTER 0.                              41800015
*                                                                       41850015
*   INPUT -    REG  1 (PMREG1)  ADDR OF JOB STEP TO BE TESTED           41900015
*              REG  2 (PMREG2)  ADDR OF ROLLOUT PARAMETER LIST          41950015
*              REG  7 (LKREG2)  RETURN REGISTER                         42000015
*                                                                       42050015
*   RETURN-    REG  0 (PMREG0)  ADDR OF PQE TO BE ROLLED OUT, IF ONE    42100015
*                               WAS FOUND                               42150015
*              LKREG2           UNSUCCESSFUL RETURN - PQE NOT FOUND     42200015
*              LKREG2+4         SUCCESSFUL RETURN - PQE ADDR IN PMREG0  42250015
*                                                                       42300015
*   NOTE -     TESTSTEP WILL NOT ALTER WKREG3 - REG 11                  42350015
*                                                                       42400015
*                                                                       42450015
*                                                                       42500015
*                                                                       42550015
TESTSTEP EQU   *                                                        42600015
         USING PQESECT,WKREG1                                           42650015
         USING TCBSECT,WKREG2                                           42700015
         STM   JSTREG,WKREG3,TESTSAV    SAVE TESTSTEP ENVIRONMT. REGS-  42750015
*                                       USED TO CONTINUE SEARCH IF      42800015
*                                       AN I/O ERROR ON ROLLOUT         42850015
         LR    WKREG2,PMREG1            SAVE ADDR OF JOB STEP TCB       42900015
         ST    PMREG1,ADDRPTR1         STR ADDR OF JSTCB FOR MSGE MO0A  42920017
         TM    TCBFLGS+2,TCBFRI         HAS STEP INVOKED ROLLOUT        42950015
         BCR   7,LKREG2                 YES, ERROR RETURN TO CALLER     43000015
         CLI   TCBNROC,X'00'            IS NON-ROLLOUTABLE COUNT = 0?   43050015
         BCR   7,LKREG2                 NO, ERROR RETURN TO CALLER      43100015
         TM    TCBFLGS+1,X'04'         IS ABEND OPEN                    43110015
         BCR   7,LKREG2                YES,ERROR RETURN TO CALLER       43130015
         L     WKREG1,TCBPQE            LOAD ADDR OF DUMMY PQE          43150015
         DROP  WKREG2                                                   43200015
RRT1     EQU   *                                                        43250015
         L     WKREG1,PQEFPQE           LOAD NEXT PQE TO BE TESTED      43300015
         LTR   WKREG1,WKREG1            Q. LAST PQE ON TCB              43350015
         BCR   8,LKREG2                 YES, ERROR RETURN TO CALLER     43400015
         CLC   PQESIZE+1(3),RPLSZPQE    PQE REGION SIZE SUFFICIENT?     43450015
         BC    4,RRT1                   NO, BR TO GET NEXT PQE          43500015
         TM    PQERFLGS,PQEUSE          IS PQE IN USE BY A BORROWER?    43550015
         BC    7,RRT1                   YES, BR TO GET NEXT PQE         43600015
         CLI   RPLHRID,X'00'            IS HIERARCHY ZERO REQUESTED     43650015
         BC    8,RRT4                   YES, BR TO LINK TO APPENDAGE    43700015
         CLC   PQEHRID(1),RPLHRID       Q. SAME HIERARCHY AS REQUESTED  43750015
         BC    7,RRT1                   NO, BR TO GET NEXT PQE          43800015
         DROP  WKREG1                                                   43850015
RRT4     EQU   *                                                        43900015
         SPACE 2                                                        43950015
*   IEAQAPG4  - CRITERION SELECTION APPENDAGE INTERFACE                 44000015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE CRITERION SELECTION    44050015
*   APPENDAGE WHICH DETERMINES WHETHER THE PQE PASSED IN REGISTER 1     44100015
*   FULFILLS THE REQUEST AND CAN BE ROLLED OUT.                         44150015
*                                                                       44200015
*                                                                       44250015
*   INPUT -    REG  0 (PMREG0)  ADDR OF ROLLOUT COUNTERS                44300015
*              REG  1 (PMREG1)  ADDR OF PQE TO BE TESTED                44350015
*              REG 13 (SAVREG)  ADDR OF 18 WORD SAVE AREA               44400015
*              REG 14 (RETREG)  RETURN ADDR.                            44450015
*              REG 15 (APGREG)  BASE ADDR OF APPENDAGE                  44500015
*                                                                       44550015
*   RETURN -   REG  1 (PMREG1)  UNCHANGED = PASSES USER CRITERIA        44600015
*                               CLEARED   = DOES NOT PASS USER CRITERIA 44650015
         SPACE 2                                                        44700015
         L     PMREG0,RORICTRS          LOAD ADDR OF ROLLOUT CTR        44750015
         LR    PMREG1,WKREG1            LOAD ADDR OF PQE TO TEST        44800015
         L     APGREG,RRAPG4            LOAD ADDR OF CRITERION APPEND.  44850015
         BALR  RETREG,APGREG            LINK TO CRITERION APPENDAGE     44900015
         TM    RPLABND,RPLABNDS    IF TASK ABENDING,            SA66075 44910021
         BO    RETEXIT             IGNORE REQUEST               SA66075 44920021
         LR    PMREG0,WKREG1            LOAD ADDR OF SELECT PQE         44950015
         LTR   PMREG1,PMREG1            DO STEP AND PQE PASS            45000015
         BC    7,RRT5                  YES STORE PQE ADDR               45050015
         BC    15,RRT1                  BR TO TEST NEXT PQE             45100015
RRT5     ST    WKREG1,TESTSAV+12       STORE PQE ADDR IN TESTSAV AREA   45110015
         BC    15,4(LKREG2)            RETURN TO CALLER                 45120015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  ROLLIN CRITERION'            45150015
**********************************************************************  45200015
*************************      ROLLIN  CRITERION     *****************  45250015
**********************************************************************  45300015
         SPACE 2                                                        45350015
*   ROLLIN IS SCHEDULED WHEN ALL OF THE SPACE WITHIN A TEMPORARILY      45400015
*   ALLOCATED (BORROWED) REGION IS FREE.  THE PQE ASSOCIATED WITH       45450015
*   THE BORROWED REGION HAS BEEN DEQUEUED FROM THE BORROWING TCB.       45500015
*   IF THE REGION WAS ACQUIRED FROM FREE SPACE, THE SPACE HAS BEEN      45550015
*   RETURNED TO GOVRFLB.                                                45600015
         SPACE 2                                                        45650015
ROLLIN   EQU   *                                                        45700015
         USING PQESECT,PQEREG                                           45750015
         USING TCBSECT,JSTREG                                           45800015
         LCR   PMREG2,PMREG1            PUT PARAMETER LIST ADDR IN TRUE 45850015
         L     WKREG1,ROPARAM           GET PTR TO IEAROPRM             45900015
         ST    PMREG2,0(WKREG1)         STORE ADDR OF PARAMETER LIST    45950015
         L     PQEREG,RPLSZPQE-1        LOAD ADDR OF FREED PQE     MP2K 45960018
         L     REGREG,PQEREGN           LOAD ADDR OF BEG OF REGION MP2K 45970018
         L     JSTREG,PQETCB            LOAD ADDR OF OWNING TCB    MP2K 45980018
         LTR   JSTREG,JSTREG                                       MP2K 45990018
         BZ    EORISET                  BYPASS TEST IF ZERO      A63882 46000021
         L     WKREG2,DPQEPTR(JSTREG)   GET PTR TO DUMMY PQE       MP2K 46010018
         L     WKREG2,XPQEFPQE(WKREG2)  GET PQE PTR                MP2K 46020018
         TM    PQEFLAGS(WKREG2),X'10'   TEST NON-ROLLINABLE FLAG   MP2K 46030018
         BNO   ROLLIWTO                 BRANCH IF NOT ON           MP2K 46040018
         IC    WKREG2,24(JSTREG)        GET NON-ROLLINABLE COUNT   MP2K 46050018
         LA    WKREG2,1(WKREG2)         INCREMENT COUNT BY ONE     MP2K 46060018
         STC   WKREG2,24(JSTREG)        STORE COUNT IN TCB         MP2K 46070018
         B     EORISET                  BRANCH AROUND NEXT SECTION MP2K 46080018
XXCONTIN EQU   *                                                   MP2K 46090018
         EJECT                                                          46101015
*********************************************************************** 46105015
*********************************************************************** 46106015
*********************************************************************** 46107015
*                                                                       46108015
*                                                                       46109015
* THIS ROUTINE WILL PREPARE THE ROLLIN MSG BUFFER IN THE FORMAT         46110015
*                                                                       46111015
*    'IEA124I JOBNAME,STEPNAME ROLLIN'                                  46112015
*                                                                       46113015
ROLLIWTO EQU   *                                                 A62204 46115021
         L     WKREG2,TCBTIO .                                   A35609 46115321
         L     PMREG1,TCBOTC                                     A62204 46115621
         LTR   PMREG1,PMREG1 .         THE TCB ZERO              A35609 46115921
         BNZ   MOVNAME .               NO - ACCEPT TCB           A35609 46116221
         C     PMREG1,MASTER .         EQUAL TO M/S TCB          A35609 46116521
         BNE   MOVNAME .               NO - ACCEPT TCB           A35609 46116821
         L     WKREG2,TCBLTC           YES. STEP TO NEXT TCB      M3869 46117420
         L     WKREG2,12(WKREG2)       LOAD TIOT ADDR             MO0A  46117517
MOVNAME  EQU   *                                                  MO0A  46117617
         L     WKREG1,WT05 .            ADDR OF WTO CSECT        21472  46118221
         MVC   ROLLINJB(8,WKREG1),0(WKREG2) .MOVE JOBNAME        21472  46118821
         MVC   ROLLINST(8,WKREG1),8(WKREG2) .MOVE STEPNAME       21472  46119421
EORISET  EQU   *                                                        46120015
*                                                                       46121015
*                                                                       46122015
*********************************************************************** 46123015
*********************************************************************** 46124015
*********************************************************************** 46128015
*********************************************************************** 46129015
         EJECT                                                          46130015
         LR    PMREG1,PQEREG            LOAD ADDR OF PQE INTO PARAM.    46150015
         FREEMAIN R,LV=32,SP=255,A=(1)  FREE BORROWED PQE               46200015
         EJECT                                                          46201015
*********************************************************************** 46205015
*********************************************************************** 46206015
*********************************************************************** 46207015
*                                                                       46208015
*                                                                       46209015
         BC    15,STLRIWT                                               46210015
STLRIWT  EQU   *                                                        46211015
         LTR   JSTREG,JSTREG                                            46212015
         BC    7,NOTLOG                                                 46212215
         MVC   TESTSAVE(4),PQEREGN     MOVE REGION ADDR TO WORK AREA    46212715
         UNPK  TESTSAVE(8),TESTSAVE(5)                                  46213215
         TR    TESTSAVE+1(6),DSCS-240                                   46213715
         L     WKREG1,WT04 .            ADDR OF WTO CSECT        21472  46214121
         MVC   LRIWTRG(6,WKREG1),TESTSAVE+1 .MOVE REGION ADDR    21472  46214521
         SSM   ENABLE                                                   46215015
         BALR  WKREG2,WKREG1 .          WTO CSECT                21472  46216021
         SSM   DISABLE                                                  46217015
NOTLOG   EQU   *                                                        46218015
         LTR   JSTREG,JSTREG                                       MP2K 46218118
         BZ    XCONTIN                  BYPASS TEST IF ZERO        MP2K 46218218
         L     WKREG2,DPQEPTR(JSTREG)   GET PTR TO DUMMY PQE       MP2K 46218318
         L     WKREG2,XPQEFPQE(WKREG2)  GET PQE PTR                MP2K 46218418
         TM    PQEFLAGS(WKREG2),X'10'   TEST NON-ROLLINABLE FLAG   MP2K 46218518
         BO    RIN06                    BRANCH IF NON-ROLLINABLE   MP2K 46218618
XCONTIN  EQU   *                                                   MP2K 46218718
*                                                                       46219015
*                                                                       46220015
*********************************************************************** 46221015
*********************************************************************** 46222015
*********************************************************************** 46225015
*********************************************************************** 46226015
         EJECT                                                          46227015
         LTR   JSTREG,JSTREG            IS TCB ADDR IN PQE EQUAL TO 0?  46250015
         BC    7,RIN01                  NO, DO ROLLIN            A62695 46300021
         L     REGREG,ADPART            LOAD BASE FOR GET/FREE   A62695 46305021
*                                       PART MODULE                     46310021
         L     WKREG1,ADDISP            LOADUP DISPINIT ROUTINE  A62695 46315021
         BALR  WKREG1,WKREG1            GO SEE IF ANY TASK IS    A62695 46320021
*                                       NON-DISPATCHABLE FOR     A62695 46325021
*                                       LACK OF CORE             A62695 46330021
         B     RIN08                                             A62695 46335021
RIN01    EQU   *                                                 A62695 46340021
         SR    WKREG0,WKREG0            CLEAR IN USE STATUS REG         46350015
         L     PQEREG,TCBPQE            LOAD ADDR OF FIRST PQE OF OWNER 46400015
RIN02    EQU   *                                                        46450015
         L     PQEREG,PQEFPQE           LOAD NEXT PQE ON QUEUE          46500015
         LTR   PQEREG,PQEREG            Q. LAST PQE ON QUEUE            46550015
         BC    8,RIN023                 YES, BR TO CHECK FOR ROLLIN     46600015
         C     REGREG,PQEREGN           PQE FOR SAME REGION             46650015
         BC    7,RIN021                 NO, SKIP RESETTING USE COUNT    46700015
         NI    PQERFLGS,255-PQEUSE      RESET IN USE BIT IN OWNER'S PQE 46750015
RIN021   EQU   *                                                        46800015
         TM    PQERFLGS,PQEUSE          IS PQE IN USE                   46850015
         BC    8,RIN02                  NO, SKIP SETTING USE STATUS     46900015
         LR    WKREG0,BASREG            YES, SET USE STATUS REG NON- 0  46950015
         BC    15,RIN02                 BR TO GET NEXT PQE              47000015
RIN023   EQU   *                                                        47050015
         LTR   WKREG0,WKREG0            ANY PQE OF THIS TCB IN USE      47100015
         BC    7,RIN08                  YES, BR TO SKIP ROLLIN          47150015
         L     PQEREG,TCBPQE            LOAD ADDR OF FIRST PQE          47200015
RIN04    EQU   *                                                        47250015
         L     WKREG0,PQETCB           LOAD JSTCB ADDR                  47270015
         L     PQEREG,PQEFPQE           LOAD NEXT PQE                   47300015
         LTR   PQEREG,PQEREG            ANY PQE ON CHAIN ?              47350015
         BC    8,RIN05                  NO, BR TO RESTORE THE STEP      47400015
         TM    PQERFLGS,PQERO           IS PQE'S REGION ROLLED OUT      47450015
         BC    8,RIN04                  NO, BR TO GET NEXT PQE          47500015
         LR    PMREG1,PQEREG            LOAD ADDR OF PQE TO BE SET      47550015
         IC    PMREG0,TCBPKF            INSERT PROTECTION KEY OF STEP   47600015
         BAL   LKREG1,SETKEYS1          LINK TO RESET BORROWED REGION   47700015
*                                       TO OWNER'S KEY                  47750015
         SPACE 2                                                        47800015
*   STARTIO    ROLLIN I/O INTERFACE                                     47850015
*                                                                       47900015
*   THE FOLLOWING CODE SETS THE INTERFACE TO THE ROLLIN I/O ROUTINE     47950015
*   WHICH RESTORES THE CONTENTS OF THE REGION DESCRIBED BY THE INPUT    48000015
*   PQE FROM THE ROLLOUT DATA SET.                                      48050015
         SPACE 2                                                        48100015
         LCR   PMREG1,PQEREG            LOAD COMPLEMENT OF PQE TO BE    48150015
*                                       ROLLED IN.                      48200015
         BAL   LKREG1,STARTIO           LINK TO ROLLIN I/O ROUTINE      48250015
         EJECT                                                          48251015
*********************************************************************** 48255015
*********************************************************************** 48256015
*********************************************************************** 48257015
*                                                                       48258015
*                                                                       48259015
*                                                                       48260015
* THIS ROUTINE  TESTS FOR I/O ERROR IN ROLLIN.IF NO ERROR WRITES        48261015
* ROLLIN MESSAGE                                                        48262015
         BC    15,ROLLIWTR                                              48263015
ROLLIWTR EQU   *                                                        48264015
         TM    PQERFLGS,PQEIOERR                                        48265015
         BC    5,EORIWTR                                                48266015
         L     WKREG1,WT05 .            ADDR OF WTO CSECT        21472  48266621
         BALR  WKREG2,WKREG1 .          WTO CSECT                21472  48267221
EORIWTR  EQU   *                                                        48268015
*                                                                       48269015
*                                                                       48270015
*********************************************************************** 48271015
*********************************************************************** 48272015
*********************************************************************** 48276015
         EJECT                                                          48277015
         SSM   DISABLE                  DISABLE INTERRUPTS              48300015
         TM    PQERFLGS,PQEIOERR        DID I/O ERROR OCCUR DURING R/I  48350015
         BZ    RIN044                   NO, BYPASS FBQE RECONSTRUCTION  48400015
         ST    PQEREG,PQEFFBQE          REINITIALIZE FORWARD FBQE PTR   48450015
         ST    PQEREG,PQEBFBQE          REINITIALIZE BACKWARD FBQE PTR  48500015
         L     PTR,PQEREGN              INITIALIZE PTR TO REGION START  48550015
FBQE1    L     TCB,AIEAHEAD             GET ADDRESS OF PTR TO 'HEAD'    48600015
FBQE2    LTR   TCB,TCB                  END OF TCB QUEUE ATTAINED       48650015
         BZ    FBQE8                    YES, THIS BLOCK NOT ALLOCATED   48700015
         USING TCBSECT,TCB                                              48750015
         L     SPQE,X'98'(TCB)          GET ADDRESS OF PQE              48780015
         LTR   SPQE,SPQE          IS D-PQE PTR 0?                A37054 48786021
         BZ    FBQE5              YES, GET NEXT TCB              A37054 48792021
FBQE2A   C     PQEREG,8(SPQE)          IS THIS PQE FOR CURR TCB   MO0A  48800017
         BE    FBQE2B                  YES, ACCESS FIRST SPQE     MO0A  48820017
         L     SPQE,8(SPQE)            GET NEXT PQE FOR TCB       MO0A  48840017
         LTR   SPQE,SPQE                    LAST ON CHAIN         MO0A  48860017
         BZ    FBQE5                        YES, IGNORE TCB       MO0A  48880017
         B     FBQE2A                                             MO0A  48900017
FBQE2B   L     SPQE,TCBMSS-1           ACCESS FIRST SPQE FOR TCB  MO0A  48920017
FBQE3    LA    SPQE,0(SPQE)             CLEAR HIGH-ORDER BYTE           49000015
         LTR   SPQE,SPQE                IS IT ZERO                      49050015
         BZ    FBQE5                    YES, GET ANOTHER TCB            49100015
         TM    0(SPQE),X'80'      IS SUBPOOL OWNED?              A37054 49150021
         BO    FBQE6B             YES, GET OWNING SPQE           A37054 49200021
         L     DQE,4(SPQE)              ACCESS DQE POINTER              49250015
FBQE4    LA    DQE,0(DQE)               CLEAR HIGH-ORDER BYTE           49300015
         LTR   DQE,DQE                  IS IT ZERO                      49350015
         BZ    FBQE6                    YES, GO GET NEXT SPQE           49400015
         L     WORK,8(DQE)             LOAD DQE PTR               MO0A  49420017
         LA    WORK,ZERO(,WORK)           ELIMINATE HIARCHY CODE A32013 49450020
         CR    PTR,WORK             CORE DESCRIBED BY THIS DQE    MO0A  49460017
         BNE   FBQE7                    NO, IGNORE AND GET NEXT DQE     49500015
         A     PTR,12(DQE)              ADD ALLOCATED SIZE TO PTR       49550015
         B     FBQE9                    GO SEE IF FINISHED              49600015
FBQE5    L     TCB,TCBTCB               ACCESS NEXT TCB ON TCB QUEUE    49650015
         B     FBQE2                    BRANCH TO TEST                  49700015
         DROP  TCB                                                      49720015
FBQE6    L     SPQE,0(SPQE)             ACCESS NEXT SPQE ON QUEUE       49750015
         B     FBQE3                    BRANCH TO TEST                  49800015
FBQE6B   EQU   *                                                 A37054 49810021
         L     DQE,4(SPQE)        GET ADDR OF OWNING SPQE        A37054 49820021
         L     DQE,4(DQE)         GET ADDR OF DQE FOR SP         A37054 49830021
         B     FBQE4              CHECK THE DQE CHAIN            A37054 49840021
FBQE7    L     DQE,4(DQE)               ACCESS NEXT DQE ON QUEUE        49850015
         B     FBQE4                    BRANCH TO TEST                  49900015
FBQE8    STM   14,12,12(SAVREG)         SAVE ROLLIN'S REGISTERS         49950015
         LR    MRPQE,PQEREG             PROVIDE PQE ADDRESS             50000015
         LA    MRSIZE,2048              PROVIDE BLOCK SIZE              50050015
         LR    MRADDR,PTR               PROVIDE BLOCK ADDRESS           50100015
         L     MRBASE,AMSSBASE          PROVIDE BASE ADDRESS            50150015
         LR    QGM2BAS,MRBASE           GET  QGM'S 2ND BASE       20002 50160020
         A     QGM2BAS,A4096            INIT QGM 2ND BASE         20002 50170020
         L     MRBRCH,ARELEASE          GET ADDRESS OF MRELEASE ROUTINE 50200015
         BALR  MRETRN,MRBRCH            BUILD AND REORDER FBQES         50250015
         LM    14,12,12(SAVREG)         RESTORE ROLLIN'S REGISTERS      50300015
         LA    WORK,2048                GET SIZE OF UNALLOCATED BLOCK   50350015
         AR    PTR,WORK                 ADD UNALLOCATED SIZE TO PTR     50400015
FBQE9    L     WORK,PQEREGN             GET REGION START ADDRESS        50450015
         A     WORK,PQESIZE             ADD REGION SIZE IN BYTES        50500015
         CR    PTR,WORK                 IS PTR EQUAL TO END OF REGION+1 50550015
         BNE   FBQE1                    NO, CONTINUE RECONSTRUCTION     50600015
RIN044   NI    PQERFLGS,255-PQERO       RESET ROLLOUT FLAG IN PQE       50650015
         SR    PMREG0,PMREG0            CLEAR STORAGE KEY REG- ZERO KEY 50700015
         L     WKREG3,PQEFFBQE          LOAD ADDR OF FIRST FBQE         50750015
         DROP  PQEREG                                                   50800015
         USING FBQESECT,WKREG3                                          50850015
RIN045   EQU   *                                                        50900015
         CR    PQEREG,WKREG3            Q. LAST FBQE                    50950015
         BC    8,RIN04                  YES, BR TO GET NEXT PQE         51000015
         LR    WKREG1,WKREG3            ESTABLISH BEGINNING OF REGION   51050015
         L     WKREG2,FBQESIZE          LOAD SIZE OF REGION             51100015
         BAL   LKREG1,SETKEYS           LINK TO SET KEY OF FREE AREAS   51150015
*                                       TO ZERO                         51200015
         L     WKREG3,FBQEFWDP          LOAD NEXT FBQE                  51250015
         DROP  WKREG3                                                   51300015
         BC    15,RIN045                BR TO CHECK NEXT FBQE           51350015
RIN05    EQU   *                                                        51400015
         LR    WKREG3,WKREG0                                      MO0A  51402017
         L    WKREG3,152(WKREG3)       ADDR OF DUMMY PQE TO COMP  MO0A  51404017
         L     PQEREG,MASTER           ADDRESS OF MASTER TCB      MO0A  51406017
NXTCB    L     PQEREG,116(PQEREG)      ADDR OF NXT LOWER PRIORITY MO0A  51408017
         LTR   PQEREG,PQEREG           ANY TCB ON CHAIN           MO0A  51410017
         BZ    RIN05A                  NO, CHECK FOR I/O ERROR    MO0A  51412017
         C     WKREG3,152(PQEREG)      THIS TCB BELONG TO REGION  MO0A  51414017
*                                            JUST ROLLED-IN       MO0A  51416017
         BNE   NXTCB                   NO, GET NEXT TCB           MO0A  51418017
         DROP  JSTREG                                             MO0A  51420017
         USING TCBSECT,PQEREG                                     MO0A  51422017
*                                      YES, RESET PROTECT KEY     MO0A  51424017
*                                      FOR SP252                  MO0A  51426017
         L     WKREG1,TCBMSS-1         ADDRESS OF SPQE            MO0A  51428017
         DROP  PQEREG                                             MO0A  51430017
         USING TCBSECT,JSTREG                                     MO0A  51432017
SPQECHCK LA    WKREG1,0(WKREG1)        CLEAR HIGH ORDER BYTE      MO0A  51434017
         LTR   WKREG1,WKREG1           IS THIS END OF SPQE CHAIN  MO0A  51436017
         BZ    NXTCB                   YES, ACCESS NEXT TCB       MO0A  51438017
         CLI   4(WKREG1),X'FC'         IS SPQE FOR SUBPOOL 252    MO0A  51440017
         LR    JOBREG,WKREG1                                      MO0A  51442017
         BE    DQECHECK                YES, ACCESS THE DQE CHAIN  MO0A  51444017
         L     WKREG1,0(WKREG1)        GET NEXT SPQE ADDRESS      MO0A  51446017
         B     SPQECHCK                                           MO0A  51448017
DQECHECK L     JOBREG,4(JOBREG)        ADDRESS OF DQE             MO0A  51450017
         LA    JOBREG,0(JOBREG)        CLEAR HIGH ORDER BYTE      MO0A  51452017
         LTR   JOBREG,JOBREG           IS IT LAST DQE IN CHAIN    MO0A  51454017
         BZ    NXTCB                   YES, ACCESS NEXT TCB       MO0A  51456017
         L     WKREG2,12(JOBREG)       SIZE OF DESCRIBED REGION   MO0A  51458017
         L     WKREG1,8(JOBREG)        ADDR OF DESCRIBED REGION   MO0A  51460017
         LA    LKREG1,DQECHECK         RETURN ADDRESS             MO0A  51462017
         SR    PMREG0,PMREG0           PROTECTION KEY TO BE ZERO  MO0A  51464017
         B     SETKEYS                                            MO0A  51466017
RIN05A   TM    RIOERRSW,X'FF'          DID I/O ERROR OCCUR        MO0A  51468017
         MVI   RIOERRSW,X'00'           TURN OFF GENERAL I/O ERROR SW.  51500015
         BO    ERRIN                    YES, ABTERM THE ROLLED-IN STEP  51550015
         SPACE 2                                                        51600015
*   THE RSTRIO(RESTORE I/O) ROUTINE ISSUES A RESTORE MACRO FOR          51650015
*   EACH TCB IN THE JOB STEP IN ORDER TO RE-ACTIVATE THE I/O THAT       51700015
*   WAS QUIESCED PRIOR TO ROLLOUT.                                      51750015
         SPACE 2                                                        51800015
         LR    PMREG1,JSTREG            LOAD ADDR OF JSTCB TO RESTORE   51850015
         BAL   LKREG1,RSTRIO            BR TO RESTORE I/O FOR STEP      51900015
         SPACE 2                                                        51950015
*   THE RSTRQE (RESTQRE RQE) ROUTINE MOVES ANY REPLIES (FROM WTOR'S)    52000015
*   THAT WERE RECEIVED WHILE THE STEP WAS ROLLED OUT TO THE USER'S      52050015
*   REPLY BUFFER WITHIN THE REGION.  THEN THE REPLY QUEUE IS PURGED.    52100015
         SPACE 2                                                        52150015
         LR    PMREG1,JSTREG            LOAD ADDR OF JSTCB TO RESTORE   52200015
         BAL   LKREG1,RSTRQE            LINK TO RESTORE PURGED REPLIES  52250015
         TM    TCBFLGS+3,TCBTCPP   IS QTAM POST PENDING           20002 52260020
         BNO   RIN06               NO, SET TASK DISPATCHABLE      20002 52270020
         L     R15,CVTPTR          LOCATE CVT                     20002 52280020
         USING CVTSECT,R15                                        20002 52290020
         L     R15,CVTAQAVT        LOCATE AVT                     20002 52300020
         LA    R15,0(R15)          CLEAR FLAGS                    20002 52310020
         LTR   R15,R15             IS QTAM DCB OPEN               20002 52320020
         BZ    RIN06               NO, SET TASK DISPATCHABLE      20002 52330020
         LR    WKREG2,TCBREG       SAVE RORI TCB                  20002 52340020
         LR    TCBREG,JSTREG       LOAD TCB ADDR FOR QTAM POST    20002 52341020
         L     R15,QPOSTPTR(R15)   LOCATE QTAM POST ROUTINE       20002 52342020
         BALR  SWRET,R15           PROCESS PENDING QTAM POST      20002 52343020
         LR    TCBREG,WKREG2       RESTORE RORI TCB               20002 52344020
         DROP  R15                                                20002 52345020
RIN06    EQU   *                                                        52350015
*                                                               SA64957 52350221
** CHECK FOR ALL TASKS OF THE JOBSTEP IN AN 0A01 WAIT.          SA64957 52350421
** IF SO,QUEUE THE 30-MIN WIAT TQE TO THE INITIATOR.            SA64957 52350621
** THE ROUTINE TO CHECK THE SUBTASKS AND QUEUE THE              SA64957 52350821
** TQE IS IN WIAT (IGC001).                                     SA64957 52351021
*                                                               SA64957 52351221
         STM   0,15,SAVEAREA       SAVE REGS                    SA64957 52351421
         LA    TMERET,NOWAITQE     RET ADDR OR BYPASS ADDR      SA64957 52351621
         L     TQEREG,TCBTME       TQE OF INITIATOR             SA64957 52351821
         LTR   TQEREG,TQEREG       IS THERE ANY                 SA64957 52352021
         BCR   8,TMERET            NO--SKIP                     SA64957 52352221
         TM    TQEFLGS(TQEREG),TQEREAL  IF REAL TQE, IS         SA64957 52352421
         BCR   1,TMERET            30-MIN TQE LEFT OVER         SA64957 52352621
*                                  SO QUEUE REMAINDER           SA64957 52352821
         L     TCBREG,TCBLTC       POINT TO JOBSTEP TASK (USER) SA64957 52353021
         LTR   TCBREG,TCBREG       ANY                          SA64957 52353221
         BCR   8,TMERET            NO--SKIP                     SA64957 52353421
         DROP  JSTREG                                           SA64957 52353621
         USING TCBSECT,TCBREG      USER JOBSTEP                 SA64957 52353821
         L     TMEGOTO,AQJSTM      ADDR OF RTN IN WAIT          SA64957 52354021
         TM    TCBFLGS+4,X'80'     TASK ENDED--                 SA64957 52354221
         BCR   1,TMERET            DONOT ENQUEUE                SA64957 52354421
         TM    TCBFLGS+0,X'80'     TASK ABENDING --             SA64957 52354621
         BCR   1,TMEGOTO           CHECK OTHER TASKS            SA64957 52354821
         TM    TCBFLGS+2,X'20'     TASK ABTERMED --             SA64957 52355021
         BCR   1,TMEGOTO           CHECK OTHER TASKS            SA64957 52355221
         L     IRBREG,TCBRBP       POINT TO RB TO DISPATCH      SA64957 52355421
         TM    RBSTAB,RBWAIT       IF RB IN 0A01 WAIT,          SA64957 52355621
         BCR   1,TMEGOTO           CHECK OTHER TCBS.            SA64957 52355821
NOWAITQE EQU   *                   30-MIN WAIT TQE IS           SA64957 52356021
*                                  QUEUED IF REQUIRED           SA64957 52356221
         LM    0,15,SAVEAREA-NOWAITQE(TMERET) RELOAD ALL REGS   SA64957 52356421
         USING TCBSECT,JSTREG                                   SA64957 52356621
         DROP  TCBREG                                           SA64957 52356821
         LR    PMREG1,JSTREG       GET JSTCB                 BL  A43015 52360021
         L     LKREG9,TIMENQ       GET TIMER ENQ RTN ADDR    BL  A43015 52370021
         BALR  LKREG1,LKREG9       GO DO TI                  BL  A43015 52380021
         SPACE 1                                                        52400015
         STATUS RESET,ND,(6),(12)      RESET THE TCBFRO BIT IN EACH     52450015
*                                       TCB OF THE JOB STEP             52500015
         SPACE 1                                                        52550015
RIN08    EQU   *                                                        52600015
         L     WKREG2,ROICTR            POINTER TO ROLLOUTS INVOKED     52650015
         LH    WKREG1,0(WKREG2)         INSERT ROLLOUT COUNT            52700015
         BCTR  WKREG1,0                 DECREMENT COUNT BY ONE          52750015
         STH   WKREG1,0(WKREG2)         STORE DECREMENTED COUNT         52800015
         DROP  JSTREG                                                   52850015
         SPACE 1                                                        52900015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  DEQUEUE'                     53900015
**********************************************************************  53950015
*******************************     DEQUEUE        *******************  54000015
**********************************************************************  54050015
*                                                                       54100015
         SPACE 2                                                        54150015
*   DEQUEUE IS SCHEDULED EITHER WHEN A FREEPART IS ISSUED,  WHEN A      54200015
*   DEQ IS ISSUED THAT RESULTS IN THE NON-ROLLOUTABLE COUNT BEING       54250015
*   DECREMENTED TO ZERO, OR WHEN A BORROWED REGION IS RETURNED          54300015
*   IN ROLLIN.                                                          54350015
         SPACE 1                                                        54400015
*   DEQUEUE RESCHEDULES (VIA STAGE II  OF THE EXIT EFFECTOR) EACH IQE   54450015
*   ON THE ROLLOUT QUEUE ,  ZEROES THE ROLLOUT QUEUED COUNTER           54500015
*   (IEAROQCT) AND THE ROLLOUT REQUEST QUEUE (IEAROQUE).                54550015
         SPACE 2                                                        54600015
*                                                                       54650015
DEQUEUE  EQU   *                                                        54700015
         L     WKREG1,RORIQUE          PTR TO QUEUED REQUESTS           54750015
         L     IQEREG,0(WKREG1)        ADDR OF FIRST PQE                54800015
         SR    WKREG0,WKREG0            ZERO WORK REG                   54850015
         ST    WKREG0,0(WKREG1)        CLEAR ROLLOUT REQUEST QUEUE      54900015
         L     WKREG1,ROQCTR            PTR TO QUEUED COUNTER           54950015
         STH   WKREG0,0(WKREG1)                                         55000015
DEQ1     EQU   *                                                        55050015
         LTR   IQEREG,IQEREG            LAST IQE?                       55100015
         BC    8,RETEXIT                YES, BR TO RETURN IQE AND EXIT  55150015
         LCR   PMREG1,IQEREG            LOAD COMPLEMENT OF IQE          55200015
         USING IQESECT,IQEREG                                           55250015
         L     WKREG1,IQETCB           LOAD ADDR OF REQUESTING TCB      55300015
         USING TCBSECT,WKREG1                                           55350015
         NI    TCBFLGS+4,X'FD'         RESET CORE WAIT NONDISP FLAG     55400015
         DROP  WKREG1                                                   55450015
         L     IQEREG,IQELNK            LOAD ADDR OF NEXT IQE           55500015
         DROP  IQEREG                                                   55550015
*                                                                       55600015
* SCHEDIRB SUBROUTINE.                                                  55650015
*                                                                       55700015
         SPACE 2                                                        55750015
*   THE FOLLOWING ROUTINE SCHEDULES THE  QUEUED ROLLOUT REQUESTS        55800015
*   (THE IQE'S) VIA STAGE 2 OF THE EXIT EFFECTOR.                       55850015
*                                                                       55900015
*   INPUT -    REG 10 (WKREG2)  ADDR OF STAGE 2 OF THE EXIT EFFECTOR    55950015
*              REG  1 (PMREG1)  IQE ADDR IN COMPLEMENT FORM             56000015
*              REG 14 (RETREG)  RETURN ADDR                             56050015
*                                                                       56100015
*   NOTE       ALL OTHER REGISTERS ARE ASSUMED TO BE TRANSPARENT.       56150015
         SPACE 2                                                        56200015
         L     CVTREG,CVTPTR            GET ADDRESS OF CVT              56250015
         USING CVTSECT,CVTREG                                           56300015
         L     WKREG2,CVT0EF00          GET ADDRESS OF STAGE 2          56350015
         DROP  CVTREG                                                   56400015
         BALR  RETREG,WKREG2            GO TO STAGE 2 EXIT EFFECTOR     56450015
*                                                                       56500015
         BC    15,DEQ1                  BR TO TEST NEXT IQE             56550015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  I/O ROUTINES'                56600015
**********************************************************************  56650015
***********************     ROLLOUT/ROLLIN  I/O      *****************  56700015
**********************************************************************  56750015
*                                                                       56800015
*                                                                       56850015
*                                                                       56900015
*   START TRANSFER SUBROUTINE.                                          56950015
*   THIS SUBROUTINE, ENTERED FROM THE ROLLOUT CRITERION                 57000015
*   FUNCTION, HAS THE RESPONSIBILITY TO:                                57050015
*   1) INITIALIZE THE CHANNEL PROGRAMS FOR ROLLOUT OR ROLLIN.           57100015
*   2) PERFORM PCI PROCESSING TO KEEP THE CHANNEL PROGRAMS              57150015
*      UPDATED AND RESTARTABLE.                                         57200015
*   3) PERFORM CHANNEL END PROCESSING TO EITHER RESTART THE             57250015
*      DATA TRANSFER OR TERMINATE DATA TRANSFER.                        57300015
*   4) PERFORM END PROCESSING TO TEST FOR ERROR CONDITIONS              57350015
*      OR NORMAL COMPLETION.                                            57400015
*   IN SHORT, ALL I/O OPERATIONS ARE HANDLED IN THIS SUBROUTINE.        57450015
         SPACE 3                                                        57500015
*   ENTERED WITH                                                        57550015
*   REGISTER 'PMREG1'= ADDRESS OF PQE TO ROLLOUT/ROLLIN                 57600015
*             ROLLOUT= ADDRESS IN TRUE FORM                             57650015
*             ROLLIN = ADDRESS IN COMPLEMENT FORM                       57700015
*   REGISTER 'LKREG1'= RETURN REGISTER                                  57750015
         EJECT                                                          57800015
*   GENERAL EQUATES USED IN MAINLINE I/O AND IOS APPENDAGES             57850015
         SPACE 3                                                        57900015
ERROR    EQU   X'20'                    I/O ERROR COMPLETION            57950015
INTCP    EQU   X'44'                    IOB INTERCEPT COMPLETION CODE   58000015
RDSCMD   EQU   X'06'                    READ OP CODE                    58050015
WRTCMD   EQU   X'05'                    WRITE OP CODE                   58100015
SCHID    EQU   X'31'                    SEARCH ID EQUAL OP CODE         58150015
TICCMD   EQU   X'08'                    TIC OP CODE                     58200015
NOPCMD   EQU   X'03'                    NOP OP CODE                     58250015
WKREG4   EQU   4                        WORK REGISTER                   58300015
WKREG5   EQU   5                        WORK REGISTER                   58350015
         SPACE 3                                                        58400015
*   EXTERNALLY DEFINED SYMBOLS REFERRED TO FROM MAINLINE I/O            58450015
         SPACE 1                                                        58500015
         EXTRN GOVRFLB                  MSS CONSTANTS                   58550015
         EXTRN IECPCNVT                 TTR CONVERT ROUTINE             58600015
         SPACE 3                                                        58650015
*   INTERNALLY DEFINED SYMBOLS REFERRED TO BY OTHER PROGRAMS            58700015
         SPACE 1                                                        58750015
         ENTRY IEACONST                 ADDR OF ROLLOUT CONSTANTS       58800015
         ENTRY IEARODCB                 ADDR OF ROLLOUT DCB             58850015
         ENTRY IEAROAPG                 ADDR OF ROLLOUT APPENDAGE TABLE 58900015
         EJECT                                                          58950015
STARTIO  DS    0C                       ENTRY POINT TO MAIN LINE I/O    59000015
         SSM   ENABLE                   ENABLE ALL I/O                  59050015
         BAL   LKREG2,CPINIT            GO INITIALIZE CHANNEL PROGRAMS  59100015
         SPACE 3                                                        59150015
*   START DATA TRANSFER                                                 59200015
         SPACE 1                                                        59250015
GOGO     EXCP  ROIOB                    GO TO IOS                       59300015
         SPACE 3                                                        59350015
*   WAIT FOR COMPLETION OF DATA TRANSFER                                59400015
         SPACE 1                                                        59450015
         WAIT  ECB=ROECB                ISSUE WAIT SVC                  59500015
*   TEST FOR TYPE OF COMPLETION                                         59550015
         SPACE 1                                                        59600015
         TM    ROECB,ERROR              Q, DID PROG. COMPLETE IN ERROR  59650015
         BC    1,0(LKREG1)             NO. RETURN TO CALLER             59700015
         SPACE 2                                                        59750015
*   IF FALL THROUGH PROGRAM COMPLETED WITH ERROR                        59800015
         TM    ROECB,INTCP              Q. WAS IOB INTERCEPTED          59850015
         BC    1,COMMON                 YES, REINITIALIZE AND RESTART   59900015
         L     WKREG2,SAVE1            GET PQE ADDRESS                  59950015
         LTR   WKREG3,WKREG2           Q. WAS IT ROLLOUT OR ROLLIN      60000015
         BC    2,SKIP1                  ROLLOUT, TAKE BRANCH            60050015
         LCR   WKREG2,WKREG3            ROLLIN, PQE ADDR IN TRUE FORM   60100015
         USING PQESECT,WKREG2                                           60150015
         OI    PQERFLGS,PQEIOERR        INDICATE I/O ERROR IN THIS PQE  60200015
         MVI   RIOERRSW,X'FF'           SET GENERAL I/O ERROR SIWTCH    60250015
*                                                                       60450015
* SET REGISTERS TO WRITE RO/RI ERROR MSG                                60550015
*                                                                       60650015
SKIP1    DS    0C                                                       60900015
         USING PQESECT,WKREG2                                           60950015
         L     WKREG2,PQETCB            GET ADDR OF OWNING JSTCB        61000015
         DROP  WKREG2                                                   61050015
         USING TCBSECT,WKREG2                                           61100015
         L     WKREG2,TCBTIO            GET THE TIOT ADDRESS            61150015
         DROP  WKREG2                                                   61200015
         LTR   WKREG3,WKREG3           WAS IT ROLLOUT                   61230015
         BC    2,ROMSG                 YES. GO TO WRITE RO I/O ER MSG   61260015
         SPACE 3                                                        61300015
*   PERMANENT ERROR WAS DETECTED ON ROLLIN                              61350015
*   THIS SUBROUTINE WRITES A MESSAGE TO                                 61400015
*   THE OPERATOR OF THE FORMAT:                                         61450015
*   'IEA100I, JOBNAME, STEPNAME'                                        61500015
*   AND THEN ENTERS THE ABTERM INTERFACE                                61550015
*   WHICH ABNORMALLY TERMINATES THE STEP                                61600015
*   WE ARE ATTEMPTING TO ROLLIN.                                        61650015
         SPACE 1                                                        61700015
RIMSG    MVC   RIJOBNM(8),0(WKREG2)     MOVE JOB NAME TO MSG BUFFER     61750015
         MVC   RISTPNM(8),8(WKREG2)     MOVE STEP NAME TO MSG BUFFER    61800015
         SPACE 1                                                        61850015
*   WRITE THE OUTPUT MESSAGE                                            61900015
         LA    PMREG1,RIMSGBFR          LOAD BUFFER ADDR FOR WTO        61950015
         WTO   MF=(E,(1)),ROUTCDE=(2,10),DESC=6 ISSUE WTO          MCS  62000018
         LCR   PMREG1,WKREG3            RESET PARM REG                  62050015
         BCR   15,LKREG1               GO TERMINATE THIS STEP           62100015
         SPACE 3                                                        62150015
*   PERMANENT ERROR WAS DETECTED ON ROLLOUT                             62200015
*   THIS SUBROUTINE WRITES A MESSAGE TO                                 62250015
*   THE OPERATOR OF THE FORMAT:                                         62300015
*   'IEA100I, JOBNAME, STEPNAME'                                        62350015
*   AND THEN RETURNS TO THE MAINLINE CRITERION                          62400015
*   FUNCTION WHICH WILL ATTEMPT TO FIND                                 62450015
*   ANOTHER STEP TO ROLLOUT.                                            62500015
         SPACE 1                                                        62550015
ROMSG    MVC   ROJOBNM(8),0(WKREG2)     MOVE JOB NAME TO MSG BFR        62600015
         MVC   ROSTPNM(8),8(WKREG2)     MOVE STEP NAME TO MSG BFR       62650015
*   WRITE OUTPUT MESSAGE                                                62700015
         LA    PMREG1,ROMSGBFR          LOAD BUFFER ADDR FOR WTO        62750015
         WTO   MF=(E,(1)),ROUTCDE=(2,10),DESC=6 ISSUE WTO          MCS  62800018
         LR    PMREG1,WKREG3            RESET PARM REG                  62850015
         BC    15,RETRY                 RETURN TO MAINLINE              62900015
         EJECT                                                          62950015
*   IOB WAS INTERCEPTED BY IOS TO HANDLE A DEVICE END                   63000015
*   ERROR ON A PREVIOUS REQUEST.  THE PASSING PARAMETER                 63050015
*   REGISTER CAN BE RESTORED AND THE REQUEST REISSUED.                  63100015
         SPACE 1                                                        63150015
COMMON   LR    PMREG1,WKREG3            SET THE INTERFACE               63200015
         LA    LKREG2,GOGO              SET RETURN ADDRESS              63250015
*        BC    15,CPINIT                AND GO TO INITIALIZATION        63300021
         EJECT                                                          63350015
*   CHANNEL PROGRAM INITIALIZATION SUBROUTINE.                          63400015
CPINIT   DS    0C                                                       63450015
         STM   PMREG1,WKREG5,SAVE1     SAVE    REGS FOR MAINLINE        63500015
         LR    WKREG2,PMREG1            XFR PQE ADDRESS                 63550015
         LTR   WKREG3,PMREG1            Q. ROLLOUT OR ROLLIN REQUEST    63600015
         BC    2,WRITE1                 ROLLOUT                         63650015
         LCR   WKREG2,WKREG3            PQE ADDRESS IN TRUE FORM        63700015
WRITE1   DS    0C                                                       63750015
         USING PQESECT,WKREG2                                           63800015
         L     WKREG1,PQEREGN           GET REGION ADDRESS              63850015
         L     WKREG4,PQESIZE           GET THE SIZE OF THE REGION      63900015
         DROP  WKREG2                                                   63950015
         AR    WKREG4,WKREG1            CALCULATE END OF REGION         64000015
         ST    WKREG4,REGEND            STORE IT FOR APPENDAGES         64050015
         ST    WKREG1,RWCCW1            PUT DATA ADDRESS IN BOTH        64100015
         ST    WKREG1,RWCCW2            READ/WRITE DATA CCW'S           64150015
         LTR   WKREG3,WKREG3            Q. ROLLOUT OR ROLLIN            64200015
         BC    2,WRITE2                 ROLLOUT                         64250015
         MVI   RWCCW1,RDSCMD            SET BOTH READ/WRITE             64300015
         MVI   RWCCW2,RDSCMD            CCW'S TO READ                   64350015
         BC    15,DOBOTH                SKIP TO COMMON PROCESSING       64400015
WRITE2   MVI   RWCCW1,WRTCMD            SET BOTH READ/WRITE             64450015
         MVI   RWCCW2,WRTCMD            CCW'S TO WRITE                  64500015
SCH      EQU   0                   FIRST CCW IN CP                      64580015
RWC      EQU   16                  R/W CCW                              64660015
NTC      EQU   24                  N/T CCW                              64740015
NTC8     EQU   32                  N/T CCW PLUS EIGHT                   64780021
DOBOTH   EQU   *                                                        64820015
         SPACE 2                                                        64900015
         MVI   DTTIC1,NOPCMD            SET BOTH DATA XFR               64950015
         MVI   DTTIC2,NOPCMD            NOP/TIC'S  TO NOP               65000015
         SPACE 2                                                        65050015
*   CALCULATE TTR USING FORMULA ((RB-K1)/RS)/N=TTR                      65100015
         SR    WKREG4,WKREG4           CLEAR FOR DIVISION               65150015
         LR    WKREG5,WKREG1           XFR REGION ADDRESS  (RB)         65200015
         L     WKREG1,GOVRFLBA      GET S.G.S. + 1 ADDRESS         2650 65250018
         C     WKREG5,TOPADDR1         Q. REGION ABOVE MASTER REGION    65300015
         BC    4,SKIPSUBT              NO. SKIP SUBTRACTING MASTER REG  65350015
         S     WKREG5,SIZEREG1         YES, SUBTRACT SIZE OF MASTER     65400015
*                                       SCHEDULER REGION                65450015
SKIPSUBT EQU   *                                                        65500015
         S     WKREG5,SQSBND(WKREG1) .        RB-K1              A41356 65550020
         SRL   WKREG5,10               DIVIDE BY RECORD SIZE (1024)     65600015
*                                       (RB-K1)/RS                      65650015
         D     WKREG4,NUMRECS           ((RB-K1)/RS)/N=TTR              65700015
         SPACE 2                                                        65750015
*   SET INTERFACE FOR TTR CONVERT ROUTINE                               65800015
         SPACE 1                                                        65850015
         LR    WKREG0,WKREG5            XFR TTR                         65900015
         SLL   WKREG0,8                 MAKE IT A TTRN                  65950015
         L     PMREG1,DEBADR            DEB ADDR INTO REG 1             66000015
         L     PMREG2,INIT1        CURRENT CP POINTR                    66010015
         ST    PMREG2,ROIOB+16     SET START ADDR                       66020015
         MVI   SCH(PMREG2),X'31'                                        66023015
         MVI   RWC+4(PMREG2),X'68'                                      66026015
         L     PMREG2,SCH(PMREG2)  GET BUFF ADDR                        66030015
         SL    PMREG2,THREE            POINT TO BEGINNING OF BUFFER     66035015
         LA    WKREG4,1(WKREG4)        CLEAR HIGH BYTE AND ADD ONE      66040015
         AR    WKREG0,WKREG4           ADD AS RECORD NUMBER   TTR       66050015
         SLL   WKREG0,8                MAKE IT TTRN                     66060015
         ST    WKREG0,SVTTR        SAVE TTR                             66070015
         LA    WKREG4,0(BASREG)        SAVE BASE REGISTER               66080015
         L     APGREG,CNVTADR           SET BASE FOR CONVERT ROUTINE    66100015
         BALR  RETREG,APGREG            GO TO CONVERT ROUTINE           66150015
         LA    BASREG,0(WKREG4)        RESTORE BASE REGISTER            66180015
         LA    SAVREG,SAVAREA           RESTORE SAVE AREA ADDRESS       66190015
         LA    SAVREG,SAVEAREA-STARTUP(,BASREG)   SECOND BASE   SA64957 66200021
         MVC   IOBSEEK(8),0(PMREG2)                                     66210015
         LM    PMREG1,WKREG5,SAVE1     RESTORE REGS FOR MAINLINE        66250015
         BCR   15,LKREG2                RETURN                          66300015
SAVEAREA DC    18A(0)              SAVE AREA                    SA64957 66310021
SAVAREA  EQU   SAVEAREA                                         SA64957 66320021
         EJECT                                                          66350015
*   PCI APPENDAGE PROCESSING                                            66400015
*   THE PCI APPENDAGE HAS THE RESPONSIBILITY OF UPDATING THE            66450015
*   CHANNEL PROGRAMS IN AN ATTEMPT TO MAINTAIN DISK SPEED               66500015
*   ON THE DATA TRANSFERS FOR ROLLOUT AND ROLLIN.  ON THE               66550015
*   TRANSFER OF THE LAST RECORD THE PCI APPENDAGE WILL                  66600015
*   ASSURE THAT THE CHANNEL END APPENDAGE GETS CONTROL.                 66650015
*   USING THE INITIALIZATION POINTERS THE PCI APPENDAGE WILL            66700015
*   1. UPDATE THE DATA ADDRESS IN THE NEXT READ/WRITE                   66750015
*      CCW BY ADDING 1024 TO THE CURRENT READ/WRITE CCW.                66800015
*   2. MAKE THE NEXT NOP/TIC CCW A NOP                                  66850015
*   3. UPDATE THE SEARCH ID CCW                                         66900015
*   4. POINT THE RESTART TIC TO NEXT                                    66950015
*   5. MAKE THE CURRENT NOP/TIC CCW A TIC                               67000015
*   6. FLIP/FLOP THE CURRENT AND NEXT INITIALIZATION POINTERS           67050015
*   IF THE LAST RECORD IS TRANSFERRING 1 THROUGH 6 ARE                  67100015
*   NOT DONE AND THE CHANNEL END APPENDAGE WILL GET CONTROL.            67150015
         SPACE 3                                                        67200015
*   GENERAL EQUATES USED ONLY IN APPENDAGES.                            67250015
         SPACE 1                                                        67300015
CURREG   EQU   10                       CURRENT DATA XFR PROGRAM        67350015
NXTREG   EQU   11                       NEXT DATA XFR PROGRAM           67400015
GENRG1   EQU   12                       GENERAL USAGE REGISTER          67450015
GENRG2   EQU   13                       GENERAL USAGE REGISTER          67500015
APGBAS   EQU   15                       IOS APG BASE REGISTER           67550015
DEBREG   EQU   3                   IOS APPENDAGE DEB REG.               67650015
LOC40    EQU   X'40'               POINTS TO CSW LOCATION 40            67700021
         USING *,15                                                     67750015
         SPACE 1                                                        67800015
PCIAPG   DS    0C                                                       67850015
         LM    CURREG,NXTREG,INIT1      LOAD INITIALIZATION POINTERS    67900015
         L     GENRG1,RWC(CURREG)       GET CURRENT R/W CCW             67950015
         AL    GENRG1,RECSZ             ADD RECORD SIZE TO DATA ADDR    68000015
         LA    GENRG2,0(GENRG1)         XFR IT AND CLEAR OP CODE        68050015
         C     GENRG2,REGEND            Q. IS LAST RECORD TRANSFERRING  68100015
         BCR   10,RETREG                YES, DON'T BOTHER UPDATING      68150015
**********************************************************************  68154021
* CODE BELOW IS TO HANDLE EXTRANNEOUS PCI'S CAUSED BY COMMAND RETRY  *  68158021
**********************************************************************  68162021
PCICRTRY LA    GENRG2,NTC(CURREG)  PTR TO CURRENT CHANNEL PROG NOP/TIC  68166021
         MVC   PCIREGSW(4),LOC40(0) FETCH CSW FROM LOC X'40'            68170021
         MVI   PCIREGSW,X'00'      CLEAR IOBFLAG3 I/O ERROR FLAGS       68174021
         C     GENRG2,PCIREGSW     Q. DOES CSW POINT TO NOP/TIC CCW     68178021
         BE    PCICNTNU            YES-EXPECTED PCI. CONTINUE PROCESS.  68182021
         LA    GENRG2,NTC8(CURREG) PTR TO CURR CHAN PGM NOP/TIC PLUS 8  68186021
         C     GENRG2,PCIREGSW     Q. DOES CSW POINT TO NOP/TIC PLUS 8  68190021
         BCR   7,RETREG           NO-EXTRANNEOUS PCI-RETURN TO IOS      68194021
         SPACE 1                                                        68200015
*   IF WE FALL THROUGH THE DATA TRANSFER                                68250015
*   IS NOT COMPLETE AND THE CHANNEL                                     68300015
*   PROGRAMS WILL BE UPDATED ACCORDINGLY.                               68350015
PCICNTNU STM   0,1,REGONESV         SAVE REGS 0,1 TEMPORARILY           68360021
         L     1,APCIREGS         PNTR TO SAVEAREA IN WTO CSECT- PCI    68370021
         STM   2,15,8(1)          SAVE REGS 2-15 IN PCI SAVEAREA        68380021
         MVC   0(8,1),REGONESV    SAVE REGS 0-1 IN PCI SAVEAREA         68390021
         SPACE 1                                                        68400015
         ST    GENRG1,RWC(NXTREG)       PUT NEXT DATA ADDR IN NEXT R/W  68450015
         MVI   NTC(NXTREG),NOPCMD       MAKE NEXT NOP/TIC A NOP         68500015
         L     WKREG0,SVTTR        GET TTR                              68520015
         AL    WKREG0,RECD1            INDEX R BY ONE                   68540015
         ST    WKREG0,SVTTR        STORE NEW TTR                        68560015
         CLC   SVTTR+2(1),NUMRECS+3    CHK END OF TRK                   68580015
         BC    12,PCIAPG01         BR NO END                            68600015
         A     WKREG0,PCIONE       INDEX T BY ONE                       68620015
         ST    WKREG0,SVTTR        SAVE NEW TTR                         68640015
         MVI SVTTR+2,X'01'         NEW TRK  R=1                         68660015
         L     WKREG0,SVTTR                                             68680015
PCIAPG01 LR    PMREG1,DEBREG       GET DEB ADDR                         68700015
         L     PMREG2,SCH(NXTREG)  ADDR FOR MBBCCHHR                    68720015
         SL    PMREG2,THREE            POINT TO BEGINNING OF BUFFER     68730015
         L     APGREG,CNVTADR      ADDR CONVERT RTN                     68740015
         BALR  RETREG,APGREG                                            68760015
         USING *,RETREG            RESTORE ADDRESSABILITY               68780015
         LM    CURREG,NXTREG,INIT1     RE-ESTABLISH POINTERS            68790015
         ST    CURREG,ROIOB+16     RESET CP ADDR FOR RESTART            68800015
         L     GENRG1,SCH(CURREG)   ADDR OF RESTART CCHHR               68820015
         SL    GENRG1,THREE            POINT TO BEGINNING OF BUFFER     68830015
         MVC   IOBSEEK(8),0(GENRG1)    TO IOB                           68840015
         MVI   SCH(NXTREG),X'B1'   SRCH MTM                             68860015
         MVI   RWC+4(NXTREG),X'68'                                      68866015
         MVI   RWC+4(CURREG),X'60'                                      68872015
         MVI   SCH(CURREG),X'31'   SRC FOR POSS RESTART                 68880015
         MVI   NTC(CURREG),TICCMD       MAKE CURRENT NOP/TIC CCW A TIC  68900015
         ST    CURREG,INIT2             FLIP/FLOP THE CURRENT AND       68950015
         ST    NXTREG,INIT1             NEXT INITIALIZATION POINTERS    69000015
         L     1,APCIREGS         PTR TO PCI SAVEAREA IN WTO CSECT      69006021
         LM    0,15,0(1)          RESTORE REGS 0-15 FROM PCI SAVEAREA   69012021
         DROP  RETREG                                                   69020015
         BCR   15,RETREG                RETURN TO IOS                   69050015
         SPACE 3                                                        69100015
*   CHANNEL END APPENDAGE PROCESSING                                    69150015
*   THE CHANNEL END APPENDAGE IS RESPONSIBLE FOR                        69200015
*   1. DETERMINING IF DATA TRANSFER IS COMPLETE                         69250015
*   2. IF IT IS, RETURN TO IOS AND DO NOT RESTART                       69300015
*   3. IF IT IS NOT, RESET IOB FLAGS AND ERROR COUNT                    69350015
*      AND RESTARTING THE CHANNEL PROGRAMS                              69400015
         SPACE 1                                                        69450015
         USING *,15                                                     69500015
         SPACE 1                                                        69550015
CHEAPG   DS    0C                                                       69600015
         LM    CURREG,NXTREG,INIT1      LOAD INITIALIZATION POINTERS    69650015
         L     GENRG1,RWC(CURREG)      GET THE DATA ADDR OF THE JUST    69700015
*                                       COMPLETED READ/WRITE CCW        69750015
         AL    GENRG1,RECSZ             ADD RECORD SIZE TO DATA ADDR    69800015
         LA    GENRG2,0(GENRG1)         XFR IT AND CLEAR OP CODE        69850015
         CL    GENRG2,REGEND            Q. IS TRANSFER COMPLETE         69900015
         BCR   10,RETREG                YES, EXIT DONT RESTART          69950015
         MVI   ROIOB,X'42'              RESET IOB FLAGS I               70000015
         MVI   ROIOB+1,X'00'            CLEAR FLAGS II                  70050015
         XC    ROIOB+30(2),ROIOB+30     CLEAR ERROR COUNT               70100015
         BC    15,8(RETREG)             RETURN AND RESTART REQUEST      70350015
         DROP  15                                                       70400015
         EJECT                                                          70402015
******************THIS IS THE ABNORMAL END APPENDAGE**************      70404015
         SPACE                                                          70406015
         SPACE                                                          70408015
         USING  *,15                                                    70410015
IOBREGI  EQU   2                                                        70412015
CCWREGI  EQU   12                                                       70414015
IOSRET   EQU   14                                                       70416015
ABEAPG   TM    12(IOBREGI),X'02'        IS THIS UNIT CHECK              70418015
         BCR   8,IOSRET                 NO.RETURN TO IOS                70420015
         TM    3(IOBREGI),X'20'         IS THIS END OF CYL.             70422015
         BCR   8,IOSRET                 NO. RETURN TO IOS               70424015
         NI    0(IOBREGI),X'FB'         CLEAR IOB FLAGS                 70426015
         NI    12(IOBREGI),X'FD'        CLEAR UNIT CHECK INDICATOR      70428015
         L     CCWREGI,8(IOBREGI)       GET CCW ADDRESS                 70430015
         SH    CCWREGI,ABEIGHT          BACK UP CCW                     70432015
         ST    CCWREGI,16(IOBREGI)      STORE IN START ADDRESS          70434015
         NI    0(CCWREGI),X'7F'         CLEAR MULT. TRACK BIT           70436015
         L     CCWREGI,0(CCWREGI)       GET ADDRESS OF SEARCH ARG.      70438015
         MVC   35(5,IOBREGI),0(CCWREGI) MOVE IT INTO IOB                70440015
         BC    15,8(IOSRET)             RETURN TO IOS FOR RE-START      70442015
ABEIGHT  DC    H'8'                                                     70444015
         DROP  15                                                       70446015
         EJECT                                                          70450015
         DS    0F                       INSURE FULL WORD ALIGNMENT      70500015
*   ROLLOUT/ROLLIN ECB                                                  70550015
         SPACE 1                                                        70600015
ROECB    DC    1F'0'                    ECB, INITIALLY CLEAR            70650015
         SPACE 2                                                        70700015
*   ROLLOUT/ROLLIN IOB                                                  70750015
         SPACE 1                                                        70800015
ROIOB    DC    X'42'                    COMMAND CHAINING, UNRELATED     70850015
         DC    X'000000'                FLAGS 2 AND SENSE               70900015
         DC    A(ROECB)                 ECB POINTER AND COND. CODE      70950015
         DC    2F'0'                    FLAGS O AND CSW                 71000015
         DC    A(ROCCW)                 SIO COND CODE AND START ADDR    71050015
         DC    A(IEARODCB)              POINTER TO THE ROLLOUT DCB      71100015
         DC    1F'0'                    OP CODE AND RESTART ADDRESS     71150015
         DC    1F'0'                    INCREMENT VALUE AND ERROR COUNT 71200015
IOBSEEK  DC    2F'0'                    IOB SEEK ADDRESS                71250015
         SPACE 1                                                        71300015
IEARODCB EQU   *-44                     SET PROPER ALIGNMENT            71350015
RODCB    EQU   IEARODCB                                                 71400015
DEBADR   DC    X'20'                    FLAG TO BYPASS LOOKASIDE        71450015
         DC    X'000000'                DEB ADDR, INITIALIZED BY NIP    71500015
ROBUFA   DS    2D                       *                               71550015
ROBUF1   EQU   ROBUFA+3                 * ROLLOUT/ROLLIN                71600015
ROBUFB   DS    2D                       * ID BUFFERS                    71650015
ROBUF2   EQU   ROBUFB+3                 *                               71700015
         SPACE 3                                                        71750015
         SPACE 1                                                        71800015
*   THE ROLLOUT APPENDAGE VECTOR TABLE                                  71850015
         SPACE 1                                                        71900015
IEAROAPG DC    A(RETURN)                END OF EXTENT APPENDAGE         71950015
         DC    A(RETURN)                SIO APG                         72000015
         DC    A(PCIAPG)                PCI APG                         72050015
         DC    A(CHEAPG)                CHANNEL END APG                 72100015
         DC    A(ABEAPG)                                                72150015
         SPACE 3                                                        72200015
*   THIS IS THE EOE, SIO, AND AE APPENDAGE                              72250015
         SPACE 1                                                        72300015
RETURN   BCR   15,RETREG                RETURN W/O PROCESSING           72350015
         EJECT                                                          72400015
*   INITIALIZATION POINTERS                                             72450015
*   THE TWO POINTERS FOLLOWING ARE USED TO KEEP TRACK                   72500015
*   OF THE ROLLOUT PROCESSING.  THE MEANINGS OF THE                     72550015
*   TWO POINTERS VARIES, DEPENDING ON THE POINT                         72600015
*   IN TIME THAT THEY ARE ACCESSED.                                     72650015
*   AT PCI TIME:                                                        72700015
*   *    CURRENT CHANNEL PROGRAM        (PROGRAM NOW OPERATING)         72750015
*   *    NEXT CHANNEL PROGRAM           (NEXT PROGRAM TO OPERATE)       72800015
*   AT CHANNEL END TIME:                                                72850015
*   *    NEXT CHANNEL PROGRAM           (NEXT PROGRAM TO START)         72900015
*   *    CURRENT CHANNEL PROGRAM        (PROGRAM JUST COMPLETED)        72950015
*   THE POINTERS ARE INITIALIZED AT CHANNEL PROGRAM INITIALIZATION      73000015
*   TIME AND MODIFIED IN THE PCI APPENDAGE.                             73050015
         SPACE 1                                                        73100015
INIT1    DC    A(DTCCW1)                CURRENT/NEXT POINTER            73150015
INIT2    DC    A(DTCCW2)                NEXT/CURRENT POINTER            73200015
SVTTR    DC    A(0)                TTR SAVE AREA                        73210015
PCIONE   DC    XL4'00010000'                                            73230015
         EJECT                                                          73250015
*   ROLLOUT/ROLLIN CHANNEL PROGRAMS                                     73300015
*   NOTE THAT THE DEFINITIONS BELOW ARE MODIFIED AT                     73350015
*   CHANNEL PROGRAM INITIALIZATION, PCI APPENDAGE,                      73400015
*   AND CHANNEL END APPENDAGE.  FOR EXACT PROCESSING                    73450015
*   REFER TO THE THREE SECTIONS OF CODE SPECIFIED.                      73500015
         SPACE 2                                                        73550015
*              CHANNEL PROGRAM ONE                                      73610015
         SPACE                                                          73670015
ROCCW    EQU   *                                                        73730015
DTCCW1   CCW   X'31',ROBUF1,X'40',5    SRCH ID EQU                      73790015
         CCW   X'08',DTCCW1,X'00',1    TO SRCH TILL EQU                 73850015
RWCCW1   CCW   X'05',TMPADR,X'68',1024 READ / WRITE                     73910015
DTTIC1   CCW   X'03',DTCCW2,X'20',1    NOP/TIC                          73970015
         SPACE                                                          74030015
*              CHANNEL PROGRAM TWO                                      74090015
         SPACE                                                          74150015
DTCCW2   CCW   X'31',ROBUF2,X'40',5    SRCH ID EQU                      74210015
         CCW   X'08',DTCCW2,X'00',1    TO SRCH TILL EQU                 74270015
RWCCW2   CCW   X'05',TMPADR,X'68',1024 READ / WRITE                     74330015
DTTIC2   CCW   X'03',DTCCW1,X'20',1    NOP/TIC                          74390015
         SPACE 2                                                        74450015
TMPADR   EQU   *                                                        74500015
         EJECT                                                          74550015
*   CONSTANTS USED IN MAINLINE I/O                                      74600015
         SPACE 3                                                        74650015
CNVTADR  DC    A(IECPCNVT)              TTR CONVERT  ROUTINE            74750015
IEACONST EQU   *                                                        74800015
NUMRECS  DC    1F'0'                    NUMBER OF RECORDS PER TRACK     74850015
*                                       DEVICE DEPENDENT SET BY NIP     74900015
TOPADDR1 DC    1F'0'                    ADDR OF END OF MASTER SCHEDULER 74950015
*                                       REGION.                         75000015
SIZEREG1 DC    1F'0'                    SIZE OF MASTER SCHEDULER REGION 75050015
*                                       (INCLUDING SYSTEM LINK PACK)    75100015
SAVE1    DS    5F                                                       75150015
*                                       I/O SUBROUTINE FOR MAINLINE     75200015
         SPACE 3                                                        75250015
*   CONSTANTS USED IN THE PCI AND CHANNEL END                           75300015
*   APPENDAGES AND IN MAINLINE I/O.                                     75350015
         SPACE 3                                                        75400015
REGEND   DC    1F'0'                    ADDRESS OF END OF REGION        75450015
RECSZ    DC    1F'1024'                 RECORD SIZE FOR ROLLOUT/ROLLIN  75500015
         SPACE 3                                                        75550015
*   THE FOLLOWING TWO BUFFERS ARE THE OUTPUT MESSAGE BUFFERS            75600015
*   USED IN WRITE TO OPERATOR FOR NOTIFICATION OF I/O ERRORS            75650015
*   ON THE DATA TRANSFERS                                               75700015
         SPACE 1                                                        75750015
ROMSGBFR DC    XL4'002A0000'                                            75780015
         DC    CL9'IEA401I, '                                     MO0A  75810017
ROJOBNM  DC    CL10'        , '         JOBNAME                         75850015
ROSTPNM  DC    CL8'        '            STEPNAME                        75900015
         DC    CL11'R/O I/O ERR'                                        75920015
         SPACE 3                                                        75950015
         DS    0F                                                       75970015
RIMSGBFR DC    XL4'002A0000'                                            75980015
         DC    CL9'IEA400I, '                                     MO0A  76010017
RIJOBNM  DC    CL10'        , '         JOBNAME                         76050015
RISTPNM  DC    CL8'        '            STEPNAME                        76100015
         DC    CL11'R/I I/O ERR'                                        76120015
         SPACE 1                                                        76150015
*                                                                       76200015
*                                                                       76250015
         TITLE 'IEAQRORI - ROLLOUT/ROLLIN  SUBROUTINES'                 76300015
**                                                                      76350015
         DS    0F                                                       76370015
ERRPROC  EQU   *                                                        76400015
RETRY    EQU   *                                                        76450015
         SSM   DISABLE             ERROR PATH HOUSEKEEP            MP1A 76470017
         USING PQESECT,PQEREG                                           76500015
         L     LSTREG,PQETCB            LOAD ADDR OF JOB STEP TCB       76550015
         DROP  PQEREG                                                   76600015
         USING TCBSECT,LSTREG                                           76650015
         L     WKREG2,TCBPQE            LOAD ADDR OF DUMMY PQE          76700015
ERR1     EQU   *                                                        76750015
         USING PQESECT,WKREG2                                           76800015
         L     WKREG2,PQEFPQE           LOAD NEXT PQE                   76850015
         LTR   WKREG2,WKREG2            Q. ANY PQE ON CHAIN             76900015
         BC    8,ERR3                   NO, BR TO RESTORE I/O ETC       76950015
         TM    PQERFLGS,PQERO           Q. IS PQE'S REGION ROLLED OUT   77000015
         BC    8,ERR1                   NO, BR TO CHECK NEXT PQE        77050015
         BC    15,ERR5                  YES, SKIP RESTORE               77100015
ERR3     EQU   *                                                        77150015
         DROP  WKREG2                                                   77200015
         LR    PMREG1,LSTREG            LOAD ADDR OF JSTCB TO RESTORE   77250015
         LR    JSTREG,LSTREG           SAVE ADDRESS OF JSTCB            77270015
         BAL   LKREG1,RSTRIO            BR TO RESTORE I/O FOR STEP      77300015
         LR    PMREG1,JSTREG            GET ADDR OF JSTCB FOR RESTORE   77350015
         BAL   LKREG1,RSTRQE            BR TO RESTORE REPLIES FOR STEP  77400015
         LR    PMREG1,JSTREG       GET JSTCB                 BL  A43015 77407021
         L     LKREG9,TIMENQ       GET TIMER ENQ RTN ADDR    BL  A43015 77414021
         BALR  LKREG1,LKREG9       GO DO TI                  BL  A43015 77421021
         L     WKREG2,X'88'(JSTREG)     GET DAUGHTER TCB                77430015
         OI    24(WKREG2),1             MAKE IT NON-ROLLOUTABLE         77460015
         STATUS RESET,ND,(6),(12)      RESET THE TCBFRO BIT IN EACH     77490015
*                                       TCB IN STEP                     77550015
ERR5     EQU   *                                                        77600015
         LM    JSTREG,WKREG3,TESTSAV    LOAD TESTSTEP ENVIRONMT. REGS   77650015
         BC    15,RRT1                  BR TO TESTSTEP TO CONTINUE      77700015
*                                       SEARCH FOR A PQE TO SATISFY     77750015
*                                       THE REQUEST.                    77800015
         DROP  LSTREG                                                   77850015
         SPACE 3                                                        77900015
*   THE FOLLOWING ROUTINE IS ENTERED WHEN A PERMANENT I/O ERROR         77950015
*   HAS BEEN ENCOUNTERED WHILE TRYING TO ROLL IN A REGION.  THE STEP    78000015
*   IS ABTERMED.                                                        78050015
*                                                                       78100015
ERRIN    EQU   *                                                        78150015
         LR    WKREG1,PMREG0            SAVE ADDR OF STEP TO ABTERM     78400015
         USING TCBSECT,WKREG1                                           78410015
         L     PMREG0,TCBLTC            GET DAUGHTER TCB ADDRESS        78420015
         DROP WKREG1                                                    78430015
         L     PMREG1,ABNDCD2           LOAD ROLLIN FAILURE ABEND CODE  78450015
         L     APGREG,ABTERMAD          LOAD ENTRY POINT TO ABTERM      78500015
         BALR  RETREG,APGREG            BR TO ABTERM STEP THAT CAN NOT  78550015
*                                       BE ROLLED IN                    78600015
         USING TCBSECT,WKREG1                                           78700015
         SR    WKREG2,WKREG2            CLEAR REG                       78750015
         IC    WKREG2,TCBNROC           LOAD NON-ROLLOUT COUNT          78800015
         LA    WKREG2,1(WKREG2)         ADD 1 TO NONROLLOUT COUNT       78850015
         STC   WKREG2,TCBNROC           STORE UPDATED COUNT             78900015
         BC    15,RIN06                 BR TO RESET STATUS              78950015
**                                                                      79000015
* RETEXIT/EXIT SUBROUTINES.                                             79050015
*                                                                       79100015
*                                                                       79150015
**                                                                      79200015
RETEXIT  EQU   *                                                        79250015
**                                                                      79300015
*                                                                       79350015
*   THE RETEXIT ROUTINE RETURNS THE CURRENT IQE TO THE AVAILABLE        79400015
*   IQE QUEUE, INDICATES A TASK SWITCH AND EXITS.                       79450015
         SPACE 2                                                        79500015
*                                                                       79550015
         USING IRBSECT,IRBREG                                           79600015
         USING IQESECT,IQEREG                                           79650015
         L     IQEREG,RBIQE-1                                           79660015
         MVC   RBIQE(3),IQELNK+1       UPDATE QUEUE ORIGIN              79670015
         MVC   IQELNK+1(3),RBNEXAV+1    MOVE LINK TO CURRENT IQE        79700015
         LA    IQEREG,0(IQEREG)         CLEAR HI BYTE         AC A54237 79710021
         ST    IQEREG,RBNEXAV           STORE ADDR OF CURR. IQE IN      79750015
*                                      NEXAVL                           79760015
EXIT2    EQU   *                                                        79765015
         OC    RBIQE(3),RBIQE                                           79770015
         BZ    EXIT                                                     79780015
         L     IQEREG,RBIQE-1          LOAD ADDR OF IQE QUEUE           79785015
         L     PMREG1,4(IQEREG)                                         79790015
         BCR   15,BASREG                                                79820015
EXIT     L     CVTREG,CVTPTR            GET ADDRESS OF CVT              79850015
         USING CVTSECT,CVTREG                                           79900015
         L     R15,CVTTCBP              GET ADDRESS OF 'NEW'       MP1A 79950017
         SR    WKREG2,WKREG2            DEVELOP ZEROS                   80000015
         ST    WKREG2,0(R15)            ZERO 'NEW', SHOW TASK SW   MP1A 80020017
         TM    CVTDCB,MP65FLAG    IS THIS MULTIPROCESSING          MP1A 80040017
         BZ    NOMPEXIT                NO                          MP1A 80060017
         L     R15,CVTMPCVT            POINTER TO MPCVT            MP1A 80065017
         USING IEAMPCVT,R15                                        MP1A 80070017
         L     R15,CVTTKRM             POINTER TO TSTDSP           MP1A 80075017
         DROP  R15                                                 MP1A 80080017
         BALR  RETREG,R15              GO TO TASK REMOVAL          MP1A 80085017
NOMPEXIT EQU   *                                                   MP1A 80090017
         SVC   3                        EXIT FROM ROLLOUT/ROLLIN        80100015
*                                                                       80150015
*                                                                       80200015
*                                                                       80250015
*                                                                       80300015
         EJECT                                                          80350015
*********************************************************************   80400015
*                                                                       80450015
* REPLY PURGE.                                                          80500015
*                                                                       80550015
* THE FOLLOWING CODE MARKS REPLY QUEUE ELEMENTS ASSOCIATED WITH THE     80600015
* STEP TO BE ROLLED OUT IN CASE THE REPLIES ARE RECEIVED BEFORE THE     80650015
* STEP IS ROLLED IN.                                                    80700015
*                                                                       80750015
* INPUT - REG 1 (PMREG1)                JOBSTEP TCB ADDRESS             80800015
*         REG 8 (LKREG1)                RETURN ADDRESS OF CALLER        80850015
*                                                                       80900015
* OUTPUT - NONE                                                         80950015
*                                                                       81000015
* REGISTER USAGE - REGS 1,9,10, AND 12 ARE VOLATILE                     81050015
*                                                                       81100015
*                  REGS 0,2,3,4,5,6,7,8,11,13,14,AND 15 ARE TRANSPARENT 81150015
*                                                                       81200015
PRGRQE   EQU   *                                                        81250015
         L     CVTREG,CVTPTR            GET ADDRESS OF CVT              81300015
         USING CVTSECT,CVTREG                                           81350015
         L     RQEREG,CVTCUCB           GET ADDRESS OF UCM FROM CVT     81400015
         DROP  CVTREG                                                   81450015
         USING UCMSECT,RQEREG                                     M0155 81452020
         L     RQEREG,UCMRPYQ           GET REPLY QUEUE ORIGN     M0155 81500020
PRGRQE1  LTR   RQEREG,RQEREG            ANY (MORE) RQES ON QUEUE        81550015
         USING RQESECT,RQEREG                                     M0155 81560020
         BCR   8,LKREG1                 NO, RETURN TO CALLER            81600015
         TM    RQEXA,RQEPURGE+RQERO     RQE TO BE PURGED OR ROLLED OUT  81700015
         BC    7,PRGRQE2                YES, IGNORE                     81750015
         L     STPREG,RQETCB            GET TCB ADDRESS IN THIS RQE     81800015
         USING TCBSECT,STPREG                                           81850015
         TM    TCBFLGS+4,TCBFRO  IS THIS TCB BEING ROLLED OUT           81910015
         BZ    PRGRQE2  NO,IGNORE                                       81970015
         OI    RQEXA,RQERO              SET ROLLED-OUT FLAG IN THIS RQE 82050015
PRGRQE2  L     RQEREG,RQERQE            GET NEXT RQE ON QUEUE           82100015
         BC    15,PRGRQE1                                               82150015
         DROP  RQEREG                                                   82200015
         DROP  STPREG                                                   82250015
*                                                                       82300015
*********************************************************************   82350015
         EJECT                                                          82400015
*********************************************************************   82450015
*                                                                       82500015
* SVC PURGE INTERFACE.                                                  82550015
*                                                                       82600015
* THE FOLLOWING CODE IS THE INTERFACE TO SVC PURGE.  THE PURGE IS       82650015
* ISSUED WITH THE TCB AND QUIESCE OPTIONS FOR EACH TASK OF THE STEP     82700015
* TO BE ROLLED OUT.  AN ECB IS WAITED ON FOLLOWING EACH ISSUANCE OF     82750015
* THE PURGE SVC IN ORDER TO ALLOW ACTIVE REQUESTS AND REQUESTS ON THE   82800015
* SIRB TO QUIESCE.  REQUESTS ON LOGICAL CHANNEL AND SEEK QUEUES HAVE    82850015
* THEIR IOBS ENQUEUED ON A CHAIN WHOSE ORIGIN IS IN THE RIQE FOR THE    82900015
* STEP.                                                                 82950015
*                                                                       83000015
* INPUT - REG 1 (PMREG1)                JOBSTEP TCB ADDRESS             83050015
*         REG 8 (LKREG1)                RETURN ADDRESS OF CALLER        83100015
*                                                                       83150015
* OUTPUT - NONE                                                         83200015
*                                                                       83250015
* REGISTER USAGE - REGS 0,1,7,9,10,11,12, AND 15 ARE VOLATILE           83300015
*                                                                       83350015
*                  REGS 2,3,4,5,6,8,13, AND 14 ARE TRANSPARENT          83400015
*                                                                       83450015
PRGIO    EQU   *                                                        83500015
         LR    JOBREG,PMREG1            SAVE JOBSTEP TCB ADDRESS        83550015
         LR    TASKREG,JOBREG           INITIALIZE TCB ADDRESS          83600015
PRGIO1   GETMAIN R,LV=16,SP=255         GET SPACE FOR RIQE              83650015
         LR    RIQEREG,PMREG1           GET ADDRESS OF GOTTEN RIQE      83700015
         MVC   RIQERIQE(4,RIQEREG),IEAROIOQ  LINK FIRST TO GOTTEN RIQE  83750015
         ST    RIQEREG,IEAROIOQ              MAKE GOTTEN RIQE FIRST     83800015
         ST    JOBREG,RIQEJSTC(RIQEREG) IDENTIFY RIQE BY JOBSTEP TCB    83850015
         XC    RIQEIOB(4,RIQEREG),RIQEIOB(RIQEREG)     ZERO CHAIN FIELD 83900015
PRGIO2   ST    TASKREG,RIQETCB(RIQEREG) IDENTIFY RIQE BY 'PURGED' TCB   83950015
         ST    TASKREG,PURGTCB          IDENTIFY TASK FOR PURGE BY TCB  84000015
         LA    IOBREG,RIQEIOB(RIQEREG)  GET ADDRESS OF IOB CHAIN FIELD  84050015
         ST    IOBREG,PURGIOB           PLACE IN PURGE PARAMETER LIST   84100015
         LA    PMREG1,PURGPARM          GET ADDRESS OF PARAMETER LIST   84150015
         PURGE (1)                      PURGE I/O FOR THIS TASK         84200015
         BAL   LNKRG1,TASKSEL          SELECT A SUBTASK OF STEP         84250015
         B     PRGIO3                   SUBTASK SELECTED                84300015
         L     IOBREG,RIQEIOB(RIQEREG)  SUBTASK NOT SELECTED, FINISH UP 84350015
         LTR   IOBREG,IOBREG            ANY I/O TO BE RESTORED          84400015
         BCR   7,LKREG1                 YES, RETURN TO CALLER           84450015
         MVC   IEAROIOQ(4),RIQERIQE(RIQEREG) REMOVE THIS RIQE FROM QUE  84500015
         FREEMAIN R,LV=16,SP=255,A=(RIQEREG) FREE THIS RIQE             84550015
         BR    LKREG1                   RETURN TO CALLER                84600015
PRGIO3   L     IOBREG,RIQEIOB(RIQEREG)  ACCESS IOB CHAIN FIELD          84650015
         LTR   IOBREG,IOBREG            ANY I/O TO BE RESTORED          84700015
         BC    7,PRGIO1                 YES, GET A NEW RIQE FOR TASK    84750015
         B     PRGIO2                   NO, USE THIS RIQE FOR TASK      84800015
*                                                                       84850015
*********************************************************************   84900015
         EJECT                                                          84950015
*********************************************************************   85000015
*                                                                       85050015
* REPLY RESTORE.                                                        85100015
*                                                                       85150015
* THE FOLLOWING CODE RESTARTS REPLY PROCESSING FOR REPLIES WHICH WERE   85200015
* RECEIVED WHILE THE STEP WAS ROLLED-OUT.                               85250015
*                                                                       85300015
* INPUT - REG 1 (PMREG1)                JOBSTEP TCB ADDRESS             85350015
*         REG 8 (LKREG1)                RETURN ADDRESS OF CALLER        85400015
*                                                                       85450015
* OUTPUT - NONE                                                         85500015
*                                                                       85550015
* REGISTER USAGE - REGS 1,9,10,11, AND 12 ARE VOLATILE                  85600015
*                                                                       85650015
*                  REGS 0,2,3,4,5,6,7,8,13,14, AND 15 ARE TRANSPARENT   85700015
*                                                                       85750015
RSTRQE   EQU   *                                                        85800015
         USING TCBSECT,TASKREG                                          85820015
         LR    TASKREG,PMREG1  SAVE INITIATOR TCB ADDRS                 85840015
         B     RSTRQE1                                           A41734 85860021
         DROP  TASKREG                                                  85880015
NEXTTCB  TM    SWTCBCK,SWITCHON .                                A41734 85882021
         BO    RTNXXX .                 RETURN                   A41734 85884021
         USING TCBSECT,TASKREG .                                 A41734 85886021
         L     TASKREG,TCBLTC .         PICK UP JOB STEP TCB     A41734 85888021
         DROP  TASKREG .                                         A41734 85890021
         OI    SWTCBCK,SWITCHON .       SET SW TO EXIT           A41734 85892021
         B     RSTRQE1 .                RESTORE RQE PTR          A41734 85894021
RTNXXX   NI    SWTCBCK,SWITCHOF .                                A41734 85896021
         BR    LKREG1 .                 RETURN TO CALLER      BL  M1456 85898021
RSTRQE1  L     CVTREG,CVTPTR            GET ADDRESS OF CVT              85900015
         USING CVTSECT,CVTREG                                           85950015
         L     RQEREG,CVTCUCB           GET ADDRESS OF UCM FROM CVT     86000015
         LR    UCMREG,RQEREG      SAVE UCM ADDRESS               A27490 86020019
         DROP  CVTREG                                                   86050015
         USING UCMSECT,RQEREG                                     M0155 86052020
         L     RQEREG,UCMRPYQ           GET REPLY QUEUE ORIGN     M0155 86100020
RSTRQE2  LTR   RQEREG,RQEREG            ANY (MORE) RQES ON QUEUE        86150015
         USING RQESECT,RQEREG                                     M0155 86160020
         BC    8,NEXTTCB .              CHK NEXT TCB             A41734 86180021
         TM    RQEXA,RQERO              RQE BELONG TO A ROLLED-OUT STEP 86300015
         BC    8,RSTRQE3                NO, IGNORE                      86350015
         L     STPREG,RQETCB            GET TCB ADDRESS IN THIS RQE     86400015
         USING TCBSECT,STPREG                                           86450015
         L     STPREG,TCBJSTCB          GET JOB STEP TCB ADDRESS        86500015
         CR    STPREG,TASKREG           RQE BELONG TO THIS STEP         86550015
         BC    7,RSTRQE3                NO, IGNORE                      86600015
         NI    RQEXA,255-RQERO          RESET ROLLOUT FLAG IN THIS RQE  86650015
         USING UCMSECT,UCMREG                                      MCS  86656018
         TM    UCMMODE,UCMMCS     IS MCS IN SYSTEM               A27490 86662019
         DROP  UCMREG                                              MCS  86668018
         BNO   NOMCSRQE                                            MCS  86674018
         L     PMREG1,RQEWQE            GET ASSOCIATED RQE ADDR    MCS  86680018
         L     PMREG1,N140(PMREG1)     GET PURGING MESSAGE ADDR    MCS  86710018
         B     YSMCSRQE                                                 86730018
NOMCSRQE L     PMREG1,RQEWQE            GET PURGING MESSAGE ADD    MCS  86750018
         TM    RQEXA,X'10' .            TEST IF TEMP BUFF         M4525 86760020
         BO    RSTRQE3 .                NO                        M4525 86762020
YSMCSRQE LTR   PMREG1,PMREG1            WAS REPLY RECEIVED         MCS  86770018
         BC    8,RSTRQE3                NO, IGNORE                      86800015
         SR    WKREG0,WKREG0      ZERO REG 1 BEFORE MGCR         A28735 86820019
         MGCR  (PMREG1)                 RESTART REPLY PROCESSING        86850015
         BC    15,RSTRQE1               CHECK FOR MORE RQES ON QUEUE    86900015
RSTRQE3  L     RQEREG,RQERQE            GET NEXT RQE ON QUEUE           86950015
         BC    15,RSTRQE2               TEST AGAIN                      87000015
         DROP  RQEREG                                                   87050015
         DROP  STPREG                                                   87100015
*                                                                       87150015
*********************************************************************   87200015
         EJECT                                                          87250015
*********************************************************************   87300015
*                                                                       87350015
* SVC RESTORE INTERFACE.                                                87400015
*                                                                       87450015
* THE FOLLOWING CODE IS THE INTERFACE TO SVC RESTORE.  THE RESTORE IS   87500015
* ISSUED ONCE FOR THE STEP WHICH IS ROLLED IN.                          87550015
*                                                                       87600015
* INPUT - REG 1 (PMREG1)                JOB STEP TCB ADDRESS            87650015
*         REG 8 (LKREG1)                RETURN ADDRESS OF CALLER        87700015
*                                                                       87750015
* OUTPUT - NONE                                                         87800015
*                                                                       87850015
* REGISTER USAGE - REGS 1,9,10,11, AND 12 ARE VOLATILE                  87900015
*                                                                       87950015
*                  REGS 0,2,3,4,5,6,7,8,13,14, AND 15 ARE TRANSPARENT   88000015
*                                                                       88050015
RSTRIO   EQU   *                                                        88100015
         LR    JOBREG,PMREG1            SAVE JOBSTEP TCB ADDRESS        88150015
RSTRIO1  L     RIQEREG,IEAROIOQ         ACCESS RIQE QUEUE ORIGIN        88200015
         LA    PRIREG,IEAROIOQ          INITIALIZE PREV RIQE ADDRESS    88250015
RSTRIO2  LTR   RIQEREG,RIQEREG          ANY (MORE) RIQES ON QUEUE       88300015
         BZ    RSTRIO5                  NO                              88350015
         C     JOBREG,RIQEJSTC(RIQEREG) IS THIS RIQE FOR THIS STEP      88400015
         BE    RSTRIO3                  YES, PREPARE TO RESTORE I/O     88450015
         LR    PRIREG,RIQEREG           NO, UPDATE PREV RIQE ADDRESS    88500015
         L     RIQEREG,RIQERIQE(RIQEREG)     GET NEXT RIQE ADDRESS      88550015
         B     RSTRIO2                  TRY AGAIN                       88600015
RSTRIO3  L     CURRTCB,AIEATCBP         GET ADDRESS OF 'NEW'            88650015
         L     CURRTCB,4(CURRTCB)       GET CURRENT TCB FROM 'OLD'      88700015
         USING TCBSECT,CURRTCB                                          88750015
         MVC   TCBRBP+1(3),RBLINK       REMOVE ROLLOUT IRB FROM CURRTCB 88800015
         DROP  CURRTCB                                                  88850015
         L     TASKREG,RIQETCB(RIQEREG) GET TCB ADDRESS FROM RIQE       88900015
         USING TCBSECT,TASKREG                                          88950015
         MVC   RBLINK(3),TCBRBP+1       PLACE ROLLOUT IRB ON SEL TASK   89000015
         ST    IRBREG,TCBRBP            MAKE ROLLOUT IRB TOP ON QUEUE   89050015
         USING IQESECT,IQEREG                                           89100015
         GETMAIN R,LV=72,SP=255         GET CORE TO SAVE TASK STATUS    89200015
         LR    TASKSAVE,PMREG1          GET ADDRESS OF GOTTEN CORE      89250015
         MVC   0(5,TASKSAVE),TCBFLGS    SAVE STATUS & DISPATCHABILITY   89300015
         MVC   8(64,TASKSAVE),TCBGRS    SAVE REGISTERS                  89350015
         OI    TCBFLGS,X'01'            PREVENT ASYNCHRONOUS EXITS      89400015
         XC    TCBFLGS+3(2),TCBFLGS+3   SET TASK DISPATCHABLE           89450015
         STM   0,15,TCBGRS              SET UP REGISTERS FOR REENTRY    89500015
         LA    WKREG1,RSTRIO4           GET ADDRESS OF REENTRY POINT    89550015
         ST    WKREG1,RBOPSW+4          SET UP REENTRY TO ROLLIN        89600015
         MVI   16(IRBREG),X'00'  DISABLE PSW IN RORI IRB                89605015
         L     SWREG,AIEATCBP          LOAD POINTER TO 'NEW'            89610015
         XC    0(4,SWREG),0(SWREG)     ZERO OUT 'NEW'                   89620015
         L     SWREG,ATASW              GET ADDR OF TASK SWITCHING RTN  89650015
         BALR  SWRET,SWREG              LINK TO TASK SWITCHING RTN      89700015
         L     WKREG1,ADISP             GET ADDRESS OF DISPATCHER       89750015
         BR    WKREG1                   GO TO DISPATCHER                89800015
RSTRIO4  LA    PMREG1,RIQEIOB(RIQEREG)  PROVIDE ADDRESS OF CHAIN FIELD  89850015
         RESTORE (1)                    RESTORE I/O FOR SELECTED TASK   89900015
         MVC   0(4,PRIREG),RIQERIQE(RIQEREG) REMOVE THIS RIQE FROM QUE  89950015
         FREEMAIN R,LV=16,SP=255,A=(RIQEREG) FREE THIS RIQE             90000015
         MVC   TCBFLGS(5),0(TASKSAVE)   RESTOR STATUS & DISPATCHABILITY 90050015
         MVC   TCBGRS(64),8(TASKSAVE)   RESTORE REGISTERS               90100015
         FREEMAIN R,LV=72,SP=255,A=(TASKSAVE)   FREE TASK SAVE CORE     90120015
         B     RSTRIO1                  LOOK FOR MORE RIQES ON QUEUE    90150015
RSTRIO5  L     CURRTCB,AIEATCBP         GET ADDRESS OF 'NEW'            90200015
         L     CURRTCB,4(CURRTCB)       GET CURRENT TCB FROM 'OLD'      90250015
         CR    CURRTCB,TCBREG           IS CURRENT TCB ROLLOUT          90300015
         BCR   8,LKREG1                 YES, RETURN TO CALLER           90350015
         MVC   TCBRBP+1(3),RBLINK       REMOVE ROLLOUT IRB FROM CURRTCB 90400015
         L     TASKREG,AROTCB           GET ADDRESS OF ROLLOUT TCB      90450015
         USING TCBSECT,TASKREG                                          90500015
         MVC   RBLINK(3),TCBRBP+1       RETURN IRB TO ROLLOUT TCB       90550015
         ST    IRBREG,TCBRBP            MAKE ROLLOUT IRB TOP ON QUEUE   90600015
         STM   0,15,TCBGRS              SET UP REGISTERS FOR REENTRY    90700015
         LA    WKREG1,RSTRIO6           GET ADDRESS OF REENTRY POINT    90750015
         ST    WKREG1,RBOPSW+4          SET UP REENTRY TO ROLLIN        90800015
         L     SWREG,ATASW              GET ADDR OF TASK SWITCHING RTN  90850015
         BALR  SWRET,SWREG              LINK TO TASK SWITCHING RTN      90900015
         L     CVTREG,CVTPTR            GET ADD OF CVT                  90904017
         USING CVTSECT,CVTREG                                           90908017
         TM    CVTDCB,MP65FLAG          IS THIS MULTI-PROCESSING        90912017
         BZ    NOMPRSTR                 NO                              90916017
         L     SWREG,AIEATCBP           POINTER TO 'NEW ONE'            90920017
         XC    0(4,SWREG),0(SWREG)      ZERO OUT 'NEW ONE'              90924017
         L     WKREG1,PREFIX2           LOAD POINTER TO OTHER CPU PSA   90928017
         LA    SWREG,0(WKREG1,SWREG)    POINTER TO 'NEW TWO'            90932017
         XC    0(4,SWREG),0(SWREG)      ZERO OUT 'NEW TWO'              90936017
NOMPRSTR EQU   *                        MVT BRANCH POINT                90940017
         L     WKREG1,ADISP             GET ADDRESS OF DISPATCHER       90950015
         BR    WKREG1                   GO TO DISPATCHER                91000015
RSTRIO6  BR    LKREG1  RETURN TO CALLER                                 91050015
*                                                                       91100015
*********************************************************************   91150015
         EJECT                                                          91200015
**********************************************************************  91250015
**********************    TASK SELECT ROUTINE    *********************  91300015
**********************************************************************  91350015
         SPACE 2                                                        91400015
*   TASKSEL    TASK SELECT ROUTINE                                      91450015
*                                                                       91500015
*   THE FOLLOWING TASK SELECTION ROUTINE SELECTS EACH SUBTASK OF THE    91550015
*   JOB STEP TCB, FROM THE TOP OF THE STEP TO THE BOTTOM.  THE FIRST    91600015
*   TIME THE ROUTINE IS ENTERED, SELREG SHOULD CONTAIN THE ADDRESS      91650015
*   OF THE JOB STEP TCB.  ON SUBSEQUENT ENTRIES, SELREG SHOULD CONTAIN  91700015
*   THE TCB ADDRESS LAST RETURNED.  IF A TCB IS SELECTED, IT IS         91750015
*   RETURNED IN SELREG AT THE ADDRESS SPECIFIED BY LNKRG1. IF A TCB     91800015
*   IS NOT SELECTED, TASKSEL WILL RETURN TO LNKRG1+4. JOBREG MUST       91850015
*   CONTAIN THE ADDRESS OF THE JOB STEP TCB.                            91900015
         SPACE 2                                                        91950015
TASKSEL  EQU   *                                                        92000015
         USING TCBSECT,LASTRG                                           92050015
         LR    LASTRG,SELREG            INITIALIZE LAST TCB             92100015
         L     SELREG,TCBLTC            LOAD DAUGHTER                   92150015
TASKSEL2 EQU   *                                                        92200015
         LTR   SELREG,SELREG            Q. ANY DAUGHTER                 92250015
         BCR   7,LNKRG1                YES. RETURN SELECTED TASK        92300015
         L     SELREG,TCBNTC            LOAD SISTER                     92350015
         CR    LASTRG,JOBREG           Q. LAST TCB                      92400015
         BC    8,4(LNKRG1)             YES. RETUTN WITHOUT TASK         92450015
         L     LASTRG,TCBOTC            LOAD MOTHER                     92500015
         BC    15,TASKSEL2              BR TO TEST AGAIN                92550015
         DROP  LASTRG                                                   92600015
         EJECT                                                          92650015
**********************************************************************  92700015
***********************   SET STORAGE KEYS    ************************  92750015
**********************************************************************  92800015
         SPACE 2                                                        92850015
*   SETKEYS    SET STORAGE KEYS                                         92900015
*                                                                       92950015
*   THE SET KEYS SUBROUTINE HAS THE FOLLOWING TWO ENTRY POINTS-         93000015
*                                                                       93050015
*   SETKEYS1   IF ENTERED AT SETKEYS1, EACH 2K BLOCK OF THE PQE         93100015
*              PASSED IN REGISTER 1 IS TO BE SET TO THE STORAGE         93150015
*              KEY SPECIFIED BY BITS 24-27 OF REGISTER 0.               93200015
*                                                                       93250015
*              REG  0 (PMREG0)  STORAGE KEY IN BITS 24-27               93300015
*              REG  1 (PMREG1)  ADDRESS OF PQE                          93350015
*              REG  8 (LKREG1)  RETURN ADDRESS                          93400015
*                                                                       93450015
*   SETKEYS    IF ENTERED AT SETKEYS, EACH 2K BLOCK OF THE SPECIFIED    93500015
*              REGION ( WHOSE BEGINNING ADDRESS AND SIZE ARE PASSED IN  93550015
*              REGISTERS) IS TO BE SET TO THE SPECIFIED STORAGE KEY.    93600015
*                                                                       93650015
*              REG  0 (PMREG0)  STORAGE KEY IN BITS 24-27               93700015
*              REG  9 (WKREG1)  ADDRESS OF BEGINNING OF REGION          93750015
*              REG 10 (WKREG2)  SIZE OF REGION                          93800015
*              REG  8 (LKREG1)  RETURN ADDRESS                          93850015
*                                                                       93900015
*   NOTE - ONLY REGISTERS 9 AND 10 (WKREG1 AND WKREG2) ARE ALTERED      93950015
*   BY THIS SUBROUTINE.                                                 94000015
         SPACE 2                                                        94050015
SETKEYS1 EQU   *                                                        94100015
         USING PQESECT,PMREG1                                           94150015
         L     WKREG1,PQEREGN           LOAD BEG. ADDR OF REGION        94200015
         L     WKREG2,PQESIZE           LOAD SIZE OF REGION             94250015
         DROP  PMREG1                                                   94300015
SETKEYS  EQU   *                                                        94350015
         SRL   WKREG2,11               CALCULATE NO OF 2K BLOCKS        94400015
SSKLOOP  EQU   *                                                        94450015
         SSK   PMREG0,WKREG1            SET STORAGE KEY                 94500015
         LA    WKREG1,TWOK(WKREG1)      ADD 2048 TO BEGINNING ADDR.     94550015
         BCT   WKREG2,SSKLOOP           DECREMENT COUNT, BR TO SET NEXT 94600015
         BCR   15,LKREG1                RETURN TO CALLER                94650015
         EJECT                                                          94700015
         DS    0F                                                       94750015
ABENDCOD DC    X'002FF000'              ROLLOUT ABEND CODE        0626  94800017
MASTER   DC    A(IEAMSTCB)              ADDR OF MASTER TCB              94850015
RORICTRS DC    A(IEARCTRS)                                              94900015
ROICTR   DC    A(IEAROICT)              PTR TO NO OF ROLLOUTS INVOKED   94950015
ROQCTR   DC    A(IEAROQCT)              PTR TO NO OF REQUESTS QUEUED    95000015
RORIQUE  DC    A(IEAROQUE)              PTR TO FIRST IQE QUEUED         95050015
ROPARAM  DC    A(IEAROPRM)              PTR TO ADDR OF ROLLOUT/ROLLIN   95100015
*                                       PARAMETER LIST                  95150015
RRAPG1   DC    A(IEAQAPG1)                                              95200015
RRAPG2   DC    A(IEAQAPG2)                                              95250015
RRAPG3   DC    A(IEAQAPG3)                                              95300015
RRAPG4   DC    A(IEAQAPG4)                                              95350015
*                                                                       95400015
ABTERMAD DC    A(IEA0AB00)              ADDRESS OF ABTERM               95450015
ADPART   DC    A(IEAQPRT0+2)       BASE ADDRESS OF GETPART       A62695 95460021
ADDISP   DC    A(DISPINIT)         ADDR OF DISPINIT ROUTINE      A62695 95470021
GETPQE   DC    1F'0'                                                    95500015
GETPARM  GETMAIN EC,A=GETPQE,SP=248,MF=L                           LCS1 95550017
GETHI    EQU   GETPARM+4                                                95570017
ENABLE   DC    X'FF'                    USED TO SET SYSTEM MASK         95600015
DISABLE  DS    0C                       USED TO SET SYSTEM MASK         95650015
K1       DC    H'1'                     CONSTANT OF ONE                 95700015
PRIORSW  DC    X'00'                    HIGH PRIORITY PASS SWITCH       95750015
SWTCBCK  DC    X'00' .                  1ST TIME THRU SW         A41734 95760021
SWITCHON EQU   X'01' .                                           A41734 95770021
SWITCHOF EQU   X'00' .                                           A41734 95780021
TESTSAV  DC    3F'0'                    REG SAVE AREA FOR TESTSTEP      95850015
TESTSAV1 DC    3F'0'                    ENVIRONMT. IN CASE OF I/O       95900015
*                                       ERROR ON ROLLOUT.               95950015
ABNDCD2  DC    X'002FE000'              ROLLIN ABEND CODE         0626  95980017
RECD1    DC    X'00000100'                                              96010015
THREE    DC    X'00000003'                                              96020015
         DS    0F                                                       96050015
IEAROIOQ DC    F'0'                     RIQE QUEUE ORIGIN               96100015
PURGPARM EQU   *                        PARAMETER LIST FOR SVC PURGE    96150015
PURGOPT  DC    X'06'                   TCB AND QUIESCE OPTIONS          96200015
PURGDEB  DC    X'000000'                DEB ADDRESS - NOT USED          96250015
PURGTCB  DS    0F                       INPUT - TCB ADDRESS FOR PURGE   96300015
PURGECB  DC    F'0'                     OUTPUT - ECB TO BE POSTED       96350015
PURGIOB  DC    F'0'                     ADDRESS OF IOB CHAIN FIELD      96400015
A4096    DC    A(4096) .                QGM'S 2ND BASE            20002 96410020
AMSSBASE DC    A(MSSBASE)               BASE ADDRESS FOR MRELEASE RTN   96450015
ARELEASE DC    A(MRELEASE)              ENTRY POINT TO MRELEASE ROUTINE 96500015
AIEATCBP DC    A(IEATCBP)               ADDRESS OF 'NEW'                96550015
ATASW    DC    A(IEA0DS02)              ADDRESS OF TASK SWITCHING RTN   96600015
AIEAHEAD DC    A(IEAHEAD)               ADDRESS OF HEAD OF TCB QUEUE    96650015
ADISP    DC    A(IEA0DS)                ADDRESS OF DISPATCHER           96700015
AROTCB   DC    A(IEAROTCB)              ADDRESS OF ROLLOUT TCB          96750015
APCIREGS DC    A(PCIREGSV)        SAVE AREA FOR PCI APPEND IN WTO       96760021
REGONESV DC   2A(0)               2 WORDS TO HOLD REG 1 BEFORE STM      96770021
PCIREGSW DC    A(0)               WORK WORD TO CONTAIN CURR CCW PNTR    96780021
RIOERRSW DC    X'00'                    ROLLIN GENERAL I/O ERROR SWITCH 96800015
         EJECT                                                          96801015
*********************************************************************** 96805015
*********************************************************************** 96806015
**********************************************************************  96806315
*                                                                       96806615
TESTSAVE EQU   TESTSAV                                                  96806915
*                                                                       96807215
DSCS     DC    C'0123456789ABCDEF'                                      96807515
*                                                                       96807815
FRSTSW   DC    X'00'                                                    96808115
         DS    0F                                                A41734 96808221
ADDRPTR1 DC    S(EORLLOWT)                                              96808415
ADDRPTR2 DC    S(RR0065A)          SKIP WTO                     SA66075 96808521
ADDRPTR3 DC    S(NOTLOG)                                                96808615
ADDRPTR4 DC    S(EORIWTR)                                               96808715
WTOR1    DC    A(WTORA)                                                 96809221
WTO2     DC    A(WTOB)                                                  96809721
WT03     DC    A(WT03CS) .                                       21472  96810221
WT04     DC    A(WT04CS) .                                       21472  96810721
WT05     DC    A(WT05CS) .                                       21472  96811221
ROLLERJB EQU   16 .                                              21472  96811721
ROLLERST EQU   26 .                                              21472  96812221
ROLLEEJB EQU   42 .                                              21472  96812721
ROLLEEST EQU   52 .                                              21472  96813221
*                                                                       96814015
*                                                                       96815015
ROLLINJB EQU   16 .                                              21472  96816021
ROLLINST EQU   26 .                                              21472  96817021
*                                                                       96818015
*                                                                       96819015
LROWTOJB EQU   16                                                  MO18 96820018
LROWTOST EQU   26                                                  MO18 96821018
LROWTOSZ EQU   42                                                  MO18 96822018
LROWTORG EQU   49                                                  MO18 96823018
*                                                                       96824015
*                                                                       96825015
LRIWTRG  EQU   21 .                                              21472  96833021
CINIT    DC    C'INIT'                                            MO0A  96842017
REPLYRA  DC    A(REPLYRO)                                          MO18 96942018
GOVRFLBA DC    V(GOVRFLB)                                          2650 97042018
SQSBND   EQU    24          NEW PTR. TO NIPSQSBD                 A36186 97092020
TIMDEQ   DC    A(IEAROTDQ)                                   BL  A43015 97102021
TIMENQ   DC    A(IEARITEQ)                                   BL  A43015 97112021
         EJECT                                                          97142018
WTOMSGS  CSECT                                                     MO18 97242018
BASE     EQU   9                                                   MO18 97342018
WKREG2C  EQU   10                                                  MO18 97442018
         USING *,BASE                                              MO18 97642018
WTORA    MVI   ECBMSGA,X'00'                                       MO18 97742018
         WTOR  'IEA402A,ROLLOUT/IN MSGS REQUIRED.REPLY Y OR N',    MCS C97842018
               REPLYRO,1,ECBMSGA,ROUTCDE=1                         MCS  97942018
         WAIT  1,ECB=ECBMSGA                                       MO18 98042018
         BR    WKREG2C                                             MO18 98142018
ECBMSGA  DC    F'0'                                                MO18 98162018
REPLYRO  DC    X'00'                                               MO18 98182018
         CNOP  0,4                                                      98202018
         USING *,BASE                                              MO18 98222018
WTOB     WTO   'IEA403I,          ,        LOG R/O       ,      ', MCS C98242018
               ROUTCDE=2,DESC=6                                    MCS  98342018
         BR    WKREG2C                                             MO18 98442018
         CNOP  0,4 .                                             21472  98448021
         USING *,BASE .                                          21472  98454021
WT03CS   WTO   'IEA405I,         ,        RO/OF          ,          ,' C98460021
               ROUTCDE=2,DESC=6 .                                21472  98466021
         BR    WKREG2C .                                         21472  98472021
         CNOP  0,4 .                                             21472  98478021
         USING *,BASE .                                          21472  98484021
WT04CS   WTO   'IEA4041 REGN        LOG ROLLIN',ROUTCDE=2,DESC=6 21472  98490021
         BR    WKREG2C .                                         21472  98496021
         CNOP  0,4 .                                             21472  98502021
         USING *,BASE .                                          21472  98508021
WT05CS   WTO   'IEA406I         ,          ROLLIN',ROUTCDE=2,    21472 C98514021
               DESC=6 .                                          21472  98520021
         BR    WKREG2C .                                         21472  98526021
PCIREGSV DS    16F                 REG SAVE AREA FOR PCI APNDG          98542021
IEAQRORI CSECT                                                          98572021
IEAROTDQ EQU   *                                             BL  A43015 98602021
         USING *,LKREG9                                      BL  A43015 98632021
         L     TIMRGO,ADAQTD01    LOAD ADDR OF TIMER DEQ RTN BL  A43015 98662021
         B     TIMCOMM            GO TO COMMON PORTION       BL  A43015 98692021
IEARITEQ EQU   *                                             BL  A43015 98722021
         USING *,LKREG9                                      BL  A43015 98752021
         L     TIMRGO,ADQTE00     LOAD ADDR OF TIMER ENQ RTN BL  A43015 98782021
TIMCOMM  EQU   *                                             BL  A43015 98812021
         BALR  LKREG9,0          ESTABLISH ADDRESSABILITY    BL  A43015 98842021
         USING *,LKREG9                                      BL  A43015 98872021
TIMCBAS  EQU   *                                             BL  A43015 98902021
         LR    JOBREG,PMREG1       SET UP FOR TASK SELECT    BL  A43015 98932021
         STM   2,15,TIMSAV1      SAVE REGS FOR TIMER         BL  A43015 98962021
         LR    SELREG,PMREG1     SET UP FOR TQE SEARCH       BL  A43015 98992021
TGETNTQE EQU   *                                             BL  A43015 99022021
         L     TQEREG,TCBTME          GET ADDR OF TQE        BL  A43015 99052021
         LTR   TQEREG,TQEREG     IS THERE A TQE?             BL  A43015 99082021
         BZ    TGETNXT           NO, GET NEXT TCB ON Q       BL  A43015 99112021
         TM    TQEFLGS(TQEREG),TQEREAL  SKIP                    SA64957 99122021
         BZ    TGETNXT             ENQ/DEQ FOR TASK TQE         SA64957 99132021
         L     TIMRGO,TMSAVGO    YES, GET ADDR OF TIMER RTN  BL  A43015 99142021
         ST    SELREG,TCBTMSA      SAVE CURRENT TCB PTR      BL  A43015 99172021
         L     SELREG,SIXHRSC      GET 6 HR SUDO CLOCK       BL  A43015 99202021
         BALR  2,TIMRGO         GO TO TIMER TO ENQ OR DEQ TQEBL  A43015 99232021
         DROP  LKREG9           GET TEMP BASE REG            BL  A43015 99262021
         USING *,2              GET TEMP BASE REG            BL  A43015 99292021
         LM    7,13,TIMSAV2        RESTORE BAD REGS             SA64957 99322021
         L     SELREG,TCBTMSA      RESTORE CURR TCB PTR      BL  A43015 99352021
         DROP  2                GET RID OF TEMP BASE         BL  A43015 99382021
         USING TIMCBAS,LKREG9   REESTABLISH BASE REG         BL  A43015 99412021
TGETNXT  BAL   LNKRG1,TASKSEL   GET NEXT TCB ON Q            BL  A43015 99442021
         B     TGETNTQE         IF MORE TCBSENQ OR DEQ TQES  BL  A43015 99472021
         LM    2,15,TIMSAV1     NO MRE TCBS - RESTORE REGS   BL  A43015 99502021
         BR    LKREG1           RETURN                       BL  A43015 99532021
TIMSAV1  DC    5F'0'            SAVE AREA FOR CALLERS REGS   BL  A43015 99562021
TIMSAV2  DC    8F'0'            SAVE ARE FOR TIMER RTN       BL  A43015 99592021
TMSAVGO  DC    1F'0'            ADDR STORED  FOR TIMER RTN   BL  A43015 99622021
TCBTMSA  DC    1F'0'            SAVE AREA FOR CURR TCB       BL  A43015 99652021
LKREG9   EQU   9                REG USED TO LINK TO SUBRTN   BL  A43015 99682021
TIMRGO   EQU   15               REG USED TO GO TO TIMER      BL  A43015 99712021
TQEREG   EQU   1                PARM REG FOR TIMER           BL  A43015 99742021
ADAQTD01 DC    V(IEAQTD01)      SELF EXPLAINITORY            BL  A43015 99772021
ADQTE00  DC    V(IEAQTE00)      SELF EXPLAINITORY            BL  A43015 99802021
SIXHRSC  DC    V(IEATPC)           SIX HOUR SUDO CLOCK       BL  A43015 99832021
AQJSTM   DC    V(IEAQJSTM)         ADDR OF 30-MIN WIAT          SA64957 99842021
*                                  CHECK IN IGC001              SA64957 99852021
         END                                                            99862021
