IGC079   CSECT                                                          00200015
*0441424000,556000,670000                                          65MP 00300017
*028000-032000,040000,046000-048000,056000,144000,242000,266000- A28404 00310019
*268000,276800,282000-294000,302000-320000,380100-380200,380450, A28404 00320019
*380700,386000-390000,420000,434000,484000,522000,568600-569200, A28404 00330019
*580000-582000,638000-642000,684000,690000,694000,702000         A28404 00340019
*452000                                                          A31374 00350019
*454000                                                           M2966 00360019
*   TITLE: SET STATUS SVC 79                                            00400015
*   FUNCTION: THIS ROUTINE IS A TYPE 1 SVC AVAILABLE TO SUPERVISOR MODE 00600015
*     ROUTINES TO CHANGE THE STATUS OF A TASK.  THE ROUTINE CAN BE USED 00800015
*     TO:                                                               01000015
*      1. SET A JOB STEP NON-ROLLOUTABLE.                               01200015
*      2. PUT A TASK INTO MUST COMPLETE STATUS.                         01400015
*      3. MAKE A SET OF TASKS NON-DISPATCHABLE.                         01600015
*      4. RESET ANY OF THE ABOVE CONDITIONS.                            01800015
*      5. SET A SUB-TASK OR GROUP OF SUB-TASKS STOP NON-DISPATCHABLE    01810020
*         IF A SUPERVISOR ROUTINE IS NOT RUNNING.                       01820020
*      6. INDICATE TO EXIT TO MAKE A TASK NON-DISPATCHABLE WHEN IT IS   01830020
*         NO LONGER RUNNING A SUPERVISOR ROUTINE.                       01840020
*      7. RESET A SUB-TASK OR GROUP OF SUBTASKS START-DISPATCHABLE AND  01850020
*         IF NO SECONDARY NON-DISPATCHABILITY BITS ARE SET, TO SET THE  01860020
*         TCB PRIMARY NON-DISPATCHABILITY BIT AT DISPLACEMENT (33.7).   01870020
*      8. INCREMENTS START/STOP COUNT IF STOP SPECIFIED.                01880020
*      9. DECREMENTS START/STOP COUNT IF START SPECIFIED.               01890020
*                                                                       01900020
*                                                                       01910020
*NOTE -                                                                 01920020
*      FUNCTIONS 5 THRU 9 APPLY ONLY TO THE START-STOP    SERVICING AND 01930020
*      ARE AVAILABLE TO NON-SUPERVISOR PROGRAMS.                        01940020
*                                                                       01950020
*                                                                       01960020
*   APPLICABILITY: OPTION 4                                             02000015
*                                                                       02100020
*   EXTERNAL REFERENCES                                                 02200015
*      1. IEAMSTCB-MASTER SCHEDULER TCB                                 02400015
*      2. IEA0AB01-BRANCH ENTRY TO ABTERM FOR TYPE 1 SVC'S              02600015
*      3. IEAROICT-NUMBER OF QUEUED ROLLOUT REQUESTS                    03000019
*      4. GETIQE-ROUTINE TO OBTAIN AN IQE                               03200019
*      5. IEA0EX00-TYPE 1 EXIT USED BY ABTERM                    A37037 03250020
*   ENTRY POINTS:  THIS ROUTINE HAS TWO ENTRY POINTS.  THEY ARE:        03400015
*      1. IGC079-ENTRY POINT FOR ENTRY DIRECT FROM EXECUTION OF THE SET 03600015
*         STATUS MACRO WHICH ISSUES AN SVC 79 INSTRUCTION.              03800015
*      2. IGC07902-DIRECT BRANCH ENTRY FROM SUPERVISOR ROUTINES.  THIS  04000019
*         MAY BE DONE AS ILLUSTRATED BELOW:                             04200015
*                                                                       04400015
*              L     REG15,ADCON                                        04600020
*              BALR  REG14,REG15                                        04800019
*               .                                                       05000015
*               .                                                       05200015
*               .                                                       05400015
*        ADCON DC   A(IGC07902)                                         05600020
*   INPUT: THE INPUT TO THIS ROUTINE IS PASSED IN REGISTERS 0 AND 1.    05800015
*      AND IN REGISTER 4 WHEN MUST COMPLETE IS SPECIFIED.               05900015
*      REGISTER ZERO CONTAINS THE NON-DISPATCHABLE MASK AND A CODE      06000015
*      INDICATING THE TYPE OF REQUEST.  THE MASK IS IN THE HIGH ORDER   06200015
*      TWO BYTES OF THE REGISTER.  IT INDICATES THE SPECIFIED BITS IF   06400015
*      NON-DISPATCHABLE IS SPECIFIED.  THE MASK CORRESPONDS DIRECTLY TO 06600015
*      THE NON-DISPATCHABLE BITS IN THE TCB.  THE CODE IS IN THE LOW    06800015
*      ORDER TWO BYTE AND HAS THE FOLLOWING VALUES:                     07000015
*      WHEN PROCESSING A MUST COMPLETE, THE TCB ADDRESS IS PASSED IN    07060015
*      REGISTER 4.                                                      07120015
*                                                                       07200015
*      0-NON ROLLOUTABLE                                                07400015
*      1-MUST COMPLETE,STEP                                             07600015
*      2-MUST COMPLETE,SYSTEM                                           07800015
*      3-NON-DISPATCHABLE,STEP                                          08000015
*      4-NON-DISPATCHABLE,SYSTEM                                        08200015
*      5-NON-DISPATCHABLE,TCB ADDRESS                                   08400015
*      6-STOP NON-DISPATCHABLE                                    20021 08460020
*      7-START DISPATCHABLE                                       20021 08520020
*      REGISTER ONE CONTAINS A TCB ADDRESS IF SPECIFIED AND AN          08600015
*      INDICATION OF SET OR RESET.  THE HIGH ORDER BIT OF THE REGISTER  08800015
*      IS ZERO IF SS IS SPECIFIED AND IS ONE IF RS IS SPECIFIED.  THE   09000015
*      TCB ADDRESS IF SPECIFIED IS IN THE LOW ORDER THREE BYTES.  IF NO 09200015
*      TCB ADDRESS IS SPECIFIED,THE THREE LOW ORDER BYTES ARE ZERO.     09400015
*      THE INPUT REGISTERS ARE FORMATTED AS SHOWN BELOW.                09600015
*      IF START OR STOP ARE SPECIFIED THE HIGH ORDER BYTE OF REGISTER   09640020
*      0 IS IRRELEVANT.                                                 09680020
*       REGISTER 14 CONTAINS THE RETURN ADDRESS.                        09720020
*                                                                       09760020
*         REGISTER 0                                                    09800015
*              ******************************************               10000015
*              *        NON        *  CODE INDICATING   *               10200020
*              *    DISPATCHABLE   *     THE TYPE       *               10400020
*              *        MASK       *    OF REQUEST      *               10600020
*              ******************************************               10800015
*                                                                       11000015
*         REGISTER 1                                                    11200015
*              *****************************************                11400015
*              *  BIT 1  *                             *                11600015
*              *INDICATES*   TCB ADDRESS IF SPECIFIED  *                11800015
*              *SET/RESET*                             *                12000015
*              *****************************************                12200015
*   OUTPUT: NONE                                                        12400015
*   EXTERNAL ROUTINES: SET STATUS USES THREE EXTERNAL ROUTINES:         12600015
*      1. EXIT EFFECTOR STAGE TWO-USED TO SCHEDULE THE ROLLOUT TASK     12800015
*         WHEN EVER THE COUNT IN THE NON-ROLLOUTABLE BYTE GOES TO ZERO  13000015
*         AND ROLLOUT REQUEST ARE QUEUED.                               13200015
*      2. ABTERM ROUTINE-USED TO SCHEDULE AN ABNORMAL TERMINATION WHEN  13400015
*         ENTRY IS FROM A ROUTINE NOT IN SUPERVISOR MODE                13600015
*      3. GETIQE-USED TO OBTAIN AN IQE WHEN SCHEDULING  OF THE ROLLOUT  13800015
*         TASK IS NECESSARY.                                            14000015
*       4. IEA0EX00-ADDRESS OF TYPE 1 EXIT USED BY ABTERM        A37037 14050020
*   EXITS:                                                              14200015
*      NORMAL-A NORMAL EXIT IS A BRANCH ON REGISTER 14.  THIS EXIT      14400019
*      IS TAKEN UPON SUCCESSFUL SETTING OR RESETTING OF THE PROPER BITS 14600015
*      ERROR-WHEN ENTRY IS FROM A ROUTINE NOT IN SUPERVISOR MODE,       14800015
*   AN ERROR CODE OF 330 IS RETURNED.                                   15000015
*      ABTERM IS ENTERED TO SCHEDULE AN ABNORMAL TERMINATION.           15200015
*   TABLES AND CONTROL BLOCKS                                           15400015
*      1. TASK CONTROL BLOCK                                            15600015
*         A. FLAG BYTE 30-USED TO PUT TASK IN MUST COMPLETE STATE       15800015
*         B. FLAG BYTE 33-USED TO SET TASK NON-DISPATCHABLE BECAUSE     16000015
*            COME TASK IS IN MUST COMPLETE STATE                        16200015
*         C. NON-ROLLOUTABLE BYTE 24-USED TO INDICATE TASK NON-ROLLOUT- 16400015
*            ABLE                                                       16600015
*         D. TCBJSTCB-USED TO FIND JOB STEP TCB                         16800015
*         E. TCBNTC-USED TO FIND SISTER TCB                             17000015
*         F. TCBLTC-USED TO FIND DESCENDENT TCB                         17200015
*         G. TCBOTC-USED TO FIND MOTHER TCB                             17400015
*      2. BRANCH TABLE USED TO DETERMINE WHICH FUNCTION IS TO BE        17600015
*         PERFORMED.                                                    17800015
*      3. COMMUNICATION VECTOR TABLE                                    18000015
*         A.  SECOND WORD-ADDRESS OF STAGE TWO EXIT EFFECTOR            18200015
*         B.  FOURTHTEENTH WORD-ADDRESS OF ABTERM                       18400015
*   ATTRIBUTES-DISABLED,SERIALLY REUSABLE                               18600015
*   NOTES-NONE                                                          18800015
         SPACE 2                                                        19000015
*   REGISTER ASSIGNMENT                                                 19200015
SSPMREG0 EQU   0                        PARAMETER REGISTER              19400015
SSPMREG1 EQU   1                                                        19600015
SSPMREG2 EQU   2                                                        19800015
SSREG2   EQU   2                       USER REGISTER 2            20021 19900020
SSCVTREG EQU   3                        ENVIRONMENTAL REGISTER-CVT      20000015
SSTCBREG EQU   4                        ENVIRONMENTAL REGISTER-TCB      20200015
SSRBREG  EQU   5                        ENVIRONMENTAL REGISTER-RB       20400015
SSLKREG1 EQU   6                        LINK REGISTER                   20600015
SSWKREG1 EQU   7                        WORK REGISTER                   20800015
SSSTOPCT EQU   7    START/STOP COUNT REGISTER                     20021 20900020
SSWKREG2 EQU   8                        WORK REGISTER                   21000015
SSWKREG3 EQU   9                        WORK REGISTER                   21200015
SXRBREG  EQU   9                       FIRST RB ADDR IN QUEUE     20021 21300020
SSWKREG4 EQU   10                       WORK REGISTER                   21400015
SSR11    EQU   11                       BASE FOR GETIQE                 21600015
SSBASREG EQU   12                       BASE REGISTER                   21800015
SSSAVREG EQU   13                       SAVE AREA REGISTER              22000015
SSRETREG EQU   14                       RETURN ADDRESS REGISTER         22200015
SSREG14  EQU   14                      USER REGISTER 14           20021 22300020
SSAPGREG EQU   15                       LINK REGISTER TO SUBROUTINES    22400015
SSRCODE  EQU   15        RETURN CODE REGISTER                     20021 22460020
SSENTRY  EQU   15                      ENTRY ADDRESS REGISTER     20021 22520020
         SPACE 2                                                        22600015
*   DISPLACEMENTS IN TCB                                                22800015
TCBROLL  EQU   24                       NON-ROLLOUTABLE BYTE            23000015
TCBASE   EQU   29                       ASYNCHRONOUS EXITS DISPLACEMENT 23200015
TCBMCFLG EQU   30                       MUST COMPLETE DISPLACEMENT      23400015
TCBDISP  EQU   32                       NON-DISPATCHABLE FLAGS          23600015
TCBDFLGS EQU   33                       NON-DISPATCHABLE DISPLACEMENT   23800015
*                                       FOR MUST COMPLETE               24000015
TCBTCB   EQU   116                      NEXT TCB ON READY QUEUE  A      24200019
TCBJSTCB EQU   124                     JOBSTEP DESPLACEMENT IN TCB      24400015
TCBNTC   EQU   128                      NEXT TCB                        24600015
TCBOTC   EQU   132                     ORIGIN DISPLACEMENT IN TCB       24800015
TCBLTC   EQU   136                      DESCENDENT DISPLACEMENT IN TCB  25000015
TCBTSFLG EQU   X'94'     TS FLAGS                                 20021 25030020
TCBSTPCT EQU   X'95'     COUNT OF NO. SETTASK STARTS WHICH        20021 25060020
*                        BE ISSUED BEFORE A TASK IS MADE DISP.    20021 25090020
TCBSCNDY EQU   173                     SECONDARY NON-DISP.FLAGS   20021 25120020
TCBNDST2 EQU   X'AE'     TIME SHARING SEC.NON-DISP.FLAGS          20021 25150020
         SPACE 2                                                        25200015
*   DISPLACEMENTS IN IQE                                                25400015
IQEPARAM EQU   4                        PARAMETER LIST IN IQE           25600015
IQEIRB   EQU   8                        IRB ADDRESS IN IQE              25800015
IQETCB   EQU   12                       TCB ADDRESS IN IQE              26000015
         SPACE 2                                                        26200015
*   DISPLACEMENT IN PSW                                                 26400015
KEY      EQU   33                       PROTECT KEY DISPLACEMENT IN SVC 26600019
*                                       OLD PSW                  A28404 26800019
         SPACE 2                                                        27000015
*   DISPLACEMENTS IN CVT                                                27200015
STAGE2   EQU   4                        ADDRESS OF STAGE I EXIT         27400015
*                                       EFFECTOR IN CVT                 27600015
CVTDCB   EQU   X'74'                   .SYS-ENVIR FLAGS            65MP 27620017
CVTMPCVT EQU   X'C0'                   .PTR TO MP65 SECONDARY CVT  65MP 27625017
CVTTKRM  EQU   12                      .MP65 TASK RMVL PTR OFFSET  65MP 27630017
CVTTCBP  EQU   0                       .PTR TO NEW,OLD             65MP 27635017
         SPACE 2                                                        27640017
*   OTHER 'EQU' DEFINITIONS.                                            27660017
OLD      EQU   4                       .DISP TO OLD TCB          A28404 27661019
CVTPTR   EQU   X'10'                   .POINTER TO CVT                  27670019
FLGM65MP EQU   X'14'                   .CVTDCB FLAG FOR M65MP           27700017
SMCVSRMC EQU   X'80'                   .0 FOR SMC, 1 FOR RMC.           27720017
PROTKY   EQU   X'F0'                   .PROTECTION KEY FLAG      A28404 27730019
C0       EQU   X'00'                   .ZERO DISPLACEMENT.              27740017
START    EQU   7                        START CODE                20021 27742020
STOP     EQU   6                        STOP  CODE                20021 27744020
STRTMSK  EQU   X'01'                    START DISP MASK           20021 27746020
STOPMSK  EQU   X'01'                    STOP DISP MASK            20021 27748020
STRTFLG  EQU   X'01'                    START FLAG                20021 27750020
STOPFLG  EQU   X'02'                    STOP FLAG                 20021 27752020
SUPRTN   EQU   X'20'     CONSTANT INDICATE SUPVR RTN RUNNING      20021 27754020
SPRIDISP EQU   X'01'     CONSTANT TO SET PRIMARY NON-DISP. BIT    20021 27756020
PRIMDISP EQU   X'FE'     CONSTANT TO RESET PRIMARY DISP. BIT      20021 27758020
TCBSTPT  EQU   X'40'     TASK NON-DISPATCHABLE BECAUSE STOPPED    20021 27760020
*              BY SETTASK                                         20021 27762020
TCBSTPPR EQU   X'40'     INDICATES MAKE TASK STOP NON-DISP.       20021 27764020
*                        WHEN SUPVR ROUTINE COMPLETES             20021 27766020
TCBATT   EQU   X'20'     INDICATES SUPVR ROUTINE RUNNING          20021 27768020
RSVRB    EQU   X'C0'                   RES. SVRB MASK             20021 27770020
TSVRB    EQU   X'10'                   TRANS. SVRB MASK           20021 27772020
LASTRB   EQU   X'80'                   INDICATES RB POINTS        20021 27774020
*                                      TO TCB                     20021 27776020
RBSTAB   EQU   10                      DISP TO RB STATUS BYTE     20021 27778020
RBSTAB2  EQU   11                                                 20021 27780020
RBLINK   EQU   28                      DISP TO NEXT RB PTR        20021 27782020
THREE    EQU   3                                                  20021 27784020
FOUR     EQU   4                       INVALID TCB RETURN CODE    20021 27786020
ZERO     EQU   0                       VALID TCB RETURN CODE      20021 27790020
SWITCHST EQU   X'01'               MASK FOR SETTING SWITCH        M3862 27792020
R7       EQU  7                                                   M4543 27792420
REGDOG   EQU  13                                                  M4543 27792820
REGBAKER EQU  11                                                  M4543 27793220
         EJECT                                                          27794020
         SPACE 2                                                        27800015
*********************************************************************** 27850020
*   ENTRY POINT TO SET STATUS VIA SVC ENTRY                           * 28000020
*   SVC FLIH BRANCHES TO ROUTINE ON REG 6(SSLKREG1)              A28404 28050020
         USING *,SSLKREG1                                        A28404 28210019
         ST    SSRETREG,SAVER14         SAVE RETURN ADDRESS      A28404 28410019
         B     SUPVTEST                                          A28404 28420019
*********************************************************************** 28422020
IGC07902 EQU   *                        BRANCH ENTRY POINT       A28404 28430019
         USING *,SSAPGREG                                        A28404 28431019
         STM   SSPMREG0,SSAPGREG,SETSAVE SAVE REGS               A28404 28440019
         OI    BRCHSWTH,X'01'       SET BRANCH ENTRY SWITCH       M5156 28450020
         L     SSCVTREG,CVTPTR          LOCATE CVT               A28404 28451019
         L     SSTCBREG,CVTTCBP(SSCVTREG) LOCATE NEW-OLD         A28404 28452019
         L     SSTCBREG,OLD(SSTCBREG)   LOCATE CURRENT TCB       A28404 28453019
SUPVTEST EQU   *                                                 A28404 28454019
         BALR  SSBASREG,SSPMREG0        ESTABLISH ADDRESSABILITY A28404 28460019
         USING *,SSBASREG                                        A28404 28470019
         ST    SSPMREG1,MASK2                                     M2195 28520020
         ST    SSPMREG0,MASK1           SAVE PARAMETERS           M2195 28522020
         SLL   SSPMREG0,16             CLEAR OUT MASK WHICH       M2195 28524020
         SRL   SSPMREG0,16             MAY BE PASSED IN REG.0     M2195 28526020
         LA    SSWKREG1,STOP           STOP CODE FOR COMPARE      20021 28530020
         CR    SSPMREG0,SSWKREG1       STOP OR START SPECIFIED?   20021 28670020
         BNL   OFFSWTH                 YES. DON'T TEST KEY        M5156 28672020
         TM    BRCHSWTH,X'01'          BRANCH ENTRY?              M5156 28674020
         BO    OFFSWTH                 YES. DON'T TEST KEY        M5156 28676020
         TM    KEY,PROTKY              IS PROTECT KEY ZERO        M5156 28770020
         BZ    PROCEED                 YES. DON'T ABEND USER      M3862 29070020
         LA    SSPMREG1,X'14F'         LOAD ERROR CODE           A40769 29600021
         L     SSAPGREG,ABTERM         ADDRESS OF ABTERM                29800020
*********************************************************************** 29850020
*        REGISTER 14 MUST CONTAIN THE ADDRESS OF TYPE ONE EXIT   A37037 29900020
*        IN CASE OF A BRANCH ENTRY TO IEAQSETS.                  A37037 29950020
*********************************************************************** 30002020
         L     SSRETREG,TYP1EXIT        ADDR OF TYPE 1 EXIT      A37037 30010020
         BR    SSAPGREG                 GO TO ABTERM             A37037 30012020
         SPACE 2                                                        30014020
         EJECT                                                          30024020
*********************************************************************** 30026020
*        THE FOLLOWING SECTION OF CODE VALIDITY CHECKS THE TCB        * 30026420
*        ADDRESS PASSED IN REGISTER 1 FOR USE IN THE STOP/START       * 30026820
*        FUNCTION.  IF NONE WAS PASSED IN REGISTER 1 THEN THE         * 30027220
*        CURRENTT TCB IS USED.                                        * 30027620
*********************************************************************** 30028020
OFFSWTH  EQU   *                                                  M5156 30030020
         NI    BRCHSWTH,X'FE'      TURN BRANCH ENTRY SWTH OFF     M5156 30032020
PROCEED  EQU   *                                                 A28404 30040020
         CR    SSPMREG0,SSWKREG1       Q STOP OR START SPECIFIED  20021 32414020
         BL    NOTSTP                  NO - BRANCH                20021 32421020
         LA    SSRCODE,ZERO            SET UP TCB FOUND RTN CODE  20021 32423020
         LTR   SSPMREG1,SSPMREG1       Q ALL SUBTASKS AFFECTED?   20021 32428020
         BZ    ALLTSK                  YES - BRANCH               20021 32442020
         LR    SSWKREG4,SSTCBREG       BEGIN SEARCH AT CUR. TCB   20021 32449020
SEARCH   EQU   *                                                  20021 32456020
         LR    SSWKREG3,SSWKREG4                                  20021 32463020
         L     SSWKREG4,TCBLTC(SSWKREG3) ADDRESS OF DESCENDANT    20021 32470020
SRCH1    LTR   SSWKREG4,SSWKREG4       Q WAS DESCENDANT FOUND?    20021 32477020
         BNZ   TCBFOUND                IF SO GO TEST TCB          20021 32484020
         L     SSWKREG4,TCBNTC(SSWKREG3) IF NOT GET SISTER        20021 32491020
         CR    SSWKREG3,SSTCBREG       ALL DESCENDANTS CHECKED    20021 32498020
         BE    BADTCB                  YES - INVALID TCB ADDRESS  20021 32505020
         L     SSWKREG3,TCBOTC(SSWKREG3)                          20021 32512020
         B     SRCH1                   NO - CONTINUE SEARCH       20021 32519020
TCBFOUND EQU   *                                                  20021 32526020
         CR    SSPMREG1,SSWKREG4       Q SPECIFIED TCB FOUND?     20021 32533020
         BE    NOTSTP                  YES - BRANCH               20021 32540020
         B     SEARCH                  NO - GET NEXT TCB          20021 32547020
BADTCB   EQU   *                                                  20021 32554020
         LA    SSRCODE,FOUR            RETURN CODE - INVALID TCB  20021 32561020
         B     EXIT                    RETURN TO CALLER           20021 32568020
ALLTSK   EQU   *                                                  20021 32575020
         LR    SSPMREG1,SSTCBREG       SET UP SCAN FM CUR. TCB    20021 32582020
NOTSTP   EQU   *                                                  20021 32589020
         LA    SSWKREG1,4               MULTIPLY CODE TO DETERMINE      32600015
         MH    SSWKREG1,MASK1+2         INDEX TO BRANCH TABLE           32800015
         B     *+4(SSWKREG1)            USE MULTIPLIED VALUE TO OBTAIN  33000015
*                                       ENTRY TO BRANCH TABLE           33200015
*********************************************************************** 33450020
*   BRANCH TABLE TO DETERMINE WHICH ROUTINE TO ENTER                  * 33600020
*********************************************************************** 33650020
         B     NONROLL                  NON-ROLLOUTABLE INDICATED       33800015
         B     MCSTEP                   MUST COMPLETE STEP INDICATED    34000015
         B     MCSYSTEM                 MUST COMPLETE SYSTEM INDICATED  34200015
         B     NDSTEP                   NON-DISPATCHABLE STEP           34400015
         B     NDSYSTEM                 NON-DISPATCHABLE SYSTEM         34600015
         B     NDTCB                    NON-DISPATCHABLE TCB ADDRESS    34800015
         B     STOPSTSK                 STOP SPECIFIED            20021 34860020
         B     STRTSTSK                 START SPECIFIED           20021 34920020
         EJECT                                                          34960020
         SPACE 2                                                        35000015
*********************************************************************** 35050020
*   THIS CODE IS ENTERED WHEN MUST COMPLETE SYSTEM IS SPECIFIED         35200015
*********************************************************************** 35250020
MCSYSTEM TM    MASK2,X'80'              SET OR RESET                    35400015
         BO    RESETSYS                 GO TO RESET ROUTINE             35600015
*   IF WE FALL THROUGH, SET STATUS WAS INDICATED                        35800015
         OI    TCBMCFLG(SSTCBREG),X'10' SET MUST COMPLETE FLAG          36000015
         OI    TCBASE(SSTCBREG),X'01'   PROHIBIT ASYNCHRONOUS EXITS     36200015
         MVC   MASK3(2),SETMCFLG        SET SYS. M. C. FLAGS      M3329 36250020
         B     GETFST                   GO TO ROUTINE TO SET FLAGS      36800015
RESETSYS NI    TCBMCFLG(SSTCBREG),X'EF' RESET MUST COMPLETE FLAG        37000015
         NI    TCBASE(SSTCBREG),X'FE'   ALLOW ASYNCHRONOUS EXITS        37200015
         MVC   MASK3(2),RSTMCFLG        RESET SYS. M. C. FLAGS    M3329 37250020
         B     GETFST                   GO SET BIT(S)                   37800015
CHECK    EQU   *                                                 A28404 38010019
         TM    CVTDCB(SSCVTREG),FLGM65MP    . M65MP OR NOT.      A28404 38020019
         BNO   EXIT                    .B IF NOT M65MP             65MP 38030017
         LR    SSWKREG3,SSRCODE         SAVE RETURN CODE TEMP.    21008 38032021
*   PRE-EXIT BRANCH ON SMC-OR-RMC                                * 65MP 38040017
         L     SSAPGREG,CVTMPCVT(,SSCVTREG) MP65 SCNDRY CVT ADDR A28404 38045019
         TM    MASK2,SMCVSRMC          .(M65MP) Q SMC OR RMC       65MP 38050019
         BZ    CHECK2                  .B IF SMC.                  65MP 38060017
         L     SSWKREG1,CVTTCBP(,SSCVTREG)  .(RMC)               A28404 38070019
         SR    SSWKREG2,SSWKREG2       . SET OWN 'NEW'             65MP 38080017
         ST    SSWKREG2,C0(SSWKREG1)        . TO ZERO.             65MP 38090017
CHECK2   L     SSAPGREG,CVTTKRM(,SSAPGREG)  .(EITHER RMC OR SMC)   65MP 38100017
         BALR  SSRETREG,SSAPGREG       .EXEC TASK-REMOVAL SUBRTE.  65MP 38110017
         LR    SSRCODE,SSWKREG3         RESTORE RETURN CODE.      21008 38160021
EXIT     EQU   *                        SET EXIT INTERFACE       A28404 38620019
         LM    SSPMREG0,SSRETREG,SETSAVE RESTORE CALLERS REGS     M1190 38630020
         BR    SSRETREG                 RETURN                   A28404 38640019
         EJECT                                                          38840020
         SPACE 2                                                        39200015
*********************************************************************** 39250020
*   THIS CODE IS ENTERED WHEN MUST COMPLETE STEP IS INDICATED         * 39400020
*   IT FIRST DETERMINES IF SET OR RESET AND THEN SETS THE CURRENT TCB.* 39600015
*   THEN IT MAKES ALL TASKS IN THE STEP NON-DISPATCHABLE IF STEP IS   * 39800015
*   INDICATED AND ALL TASKS IN THE SYSTEM NON-DISPATCHABLE IF SYSTEM  * 40000015
*   IS SPECIFIED. MAJOR SYSTEM TASKS ARE NOT MARKED.                  * 40200020
*********************************************************************** 40250020
MCSTEP   TM    MASK2,X'80'              SET OR RESET                    40400015
         BO    RESETSTP                 GO TO RESET ROUTINE             40600015
*********************************************************************** 40650020
*   IF WE FALL THROUGH,THERE'S AT LEAST ONE MORE TCB WHOSE STATUS     * 40800020
*   HAS TO BE MARKED                                                  * 40850020
*********************************************************************** 40900020
         OI    TCBMCFLG(SSTCBREG),X'08' SET MUST COMPLETE FLAG          41000015
         OI    TCBASE(SSTCBREG),X'01'   PROHIBIT ASYNCHRONOUS EXITS     41200015
MAIN1    C     SSTCBREG,MASTER          IS CURRENT TCB MASTER           41400015
         BNE   MAIN2                    NO-NORMAL PROCESSING            41600015
         LR    SSWKREG3,SSTCBREG        SAVE JOB STEP TCB               41800015
         L     SSWKREG1,TCBTCB(SSTCBREG) GET NEXT ON QUEUE              42000019
MAIN12   LTR   SSWKREG1,SSWKREG1        END OF QUEUE                    42200015
         BZ    CHECK                   .YES GO TO PRE-EXIT TESTS.  65MP 42400017
         LA    REGDOG,MAIN13      WHERE TO GO INCASE TCB BAD      M4543 42460020
         BAL   REGBAKER,CHKATERM  GO CHECK TCB FOR ABEND OR TERM  M4543 42520020
CHKCURR  CR    SSTCBREG,SSWKREG1        IS THIS CURRENT TCB       M3329 42600020
         BE    MAIN13                   YES-GO GET NEXT                 42800015
         C     SSWKREG3,TCBJSTCB(SSWKREG1) COMPARE JOB STEP TCB'S       43000015
         BE    MAIN14                   SAME-SET TASK NON-DISPATCHABLE  43200015
MAIN13   L     SSWKREG1,TCBTCB(SSWKREG1) GET NEXT ON READY QUEUE        43400019
         B     MAIN12                   GO TEST FOR END OF QUEUE        43600015
MAIN14   TM    MASK2,X'80'              SET OR RESET                    43800015
         BO    MAIN16                   GO RESET FLAGS                  44000015
         OI    TCBDFLGS(SSWKREG1),X'04' SET NON-DISPATCHABLE            44200015
         B     MAIN13                   GET NEXT ON QUEUE               44400015
MAIN16   NI    TCBDFLGS(SSWKREG1),X'FB' RESET NON-DISPATCHABLE          44600015
         LR    SSWKREG4,SSWKREG1       SET UP LINKAGE              2921 44660018
         BALR  SSRETREG,SSAPGREG       BRANCH TO TASK SWITCHING    2921 44720018
         B     MAIN13                   GET NEXT ON QUEUE               44800015
MAIN2    L     SSWKREG3,TCBJSTCB(SSTCBREG) GET JOB STEP TCB             45000015
         CLC   TCBOTC(4,SSWKREG3),MASTER IS MASTER ORIGIN        A31374 45200019
         BE    LDJOBSTP                 INITALIZE WITH JOBSTEP    M2966 45400019
         L     SSWKREG1,TCBOTC(SSWKREG3) GET INITIATOR                  45600015
         B     MAIN14                   GO SET FLAGS                    45800015
LDJOBSTP LR    SSWKREG1,SSWKREG3        GET JOB STEP TCB          M2966 45801019
         B     MAIN12                   GO SET FLAGS              M2966 45810019
RESETSTP NI    TCBMCFLG(SSTCBREG),X'F7' RESET MUST COMPLETE             46000015
         NI    TCBASE(SSTCBREG),X'FE'   ALLOW ASYNCHRONOUS EXITS        46200015
         L     SSAPGREG,TASKSWCH       LOAD ADDRESS OF IEAODS02    2921 46300018
         B     MAIN1                    RETURN TO MAINLINE CODE         46400015
         EJECT                                                          46500020
         SPACE 2                                                        46600015
*********************************************************************** 46650020
*   THIS CODE IS ENTERED WHEN NON-DISPATCHABLE STEP IS SPECIFIED      * 46800020
*   IT OBTAINS THE JOB STEP TCB AND SETS ALL DESCENDENTS EXCEPT THE   * 47000015
*   CURRENT TASK NON-DISPATCHABLE                                     * 47200015
*********************************************************************** 47250020
NDSTEP   L     SSWKREG2,TCBJSTCB(SSTCBREG) GET JOB STEP TCB             47400015
         MVC   MASK3(2),MASK1           MOVE ND MASK                    47600015
         LR    SSWKREG4,SSWKREG2        INITIALIZE INPUT FOR SCAN       47800015
         CR    SSWKREG2,SSTCBREG        IS CURRENT JOB STEP TCB         48000015
         BE    GETNEXT                  IF YES DON'T SET FLAGS GET NEXT 48200015
         SPACE 2                                                        48600015
*********************************************************************** 48650020
*   THIS SECTION OF CODE IS ENTERED FROM NON DISPATCHABLE STEP OR     * 48800020
*   NON DISPATCHABLE TCB ADDRESS.  IT FINDS ALL DESCENDENTS OF THE    * 49000020
*   TOP TCB AND SETS THE PROPER FLAGS                                 * 49200020
*********************************************************************** 49210020
LOOP     TM     MASK2,X'80'            Q  RESET SPECIFIED?        20021 49220020
         BO    LOOPRSET                YES - TAKE BRANCH          20021 49240020
         TM    MASK2,X'03'             Q SET SPECIFIED ?          20021 49260020
         BZ    LOOPSET                 YES -  TAKE BRANCH         20021 49280020
         EJECT                                                          49300020
*********************************************************************** 49320020
*   THE FOLLOWING CODE IS                                             * 49360020
*   ENTERED ONLY IF THE  STATUS MACRO WITH THE START OR STOP OPTION   * 49390020
*   IS SPECIFIED.  THIS CODE SETS OR RESETS THE START/STOP            * 49420020
*   SECONDARY NON-DISPATCHABILITY BIT.  IF NO SECONDARY NON-          * 49450020
*   DISPATCHABILITY BITS ARE SET THE PRIMARY NON-DISPATCHABILITY      * 49480020
*   BIT IS RESET.  THE TCB START/STOP COUNT IS ALSO MAINTAINED        * 49510020
*********************************************************************** 49570020
STRTSTOP EQU   *                                                  20021 49630020
         TM    MASK2,STOPFLG            Q  STOP SPECIFIED?        20021 49660020
         BO    STPCNT                   YES - TAKE BRANCH         20021 49690020
*********************************************************************** 49730020
*    IF START WAS SPECIFIED FALL THROUGH TO START PROCESSING      20021 49750020
*********************************************************************** 49760020
STRTCNT  EQU   *                                                  20021 49780020
         OC    TCBSTPCT(1,SSWKREG4),TCBSTPCT(SSWKREG4)            20021 49810020
*                                      Q ANY STOPS OUTSTANDING?   20021 49840020
         BZ    RSETSTP                  NO- BYPASS COUNT PROCESS  20021 49870020
         SR    SSWKREG1,SSWKREG1        ZERO REGISTER FOR IC      20021 49900020
         IC    SSSTOPCT,TCBSTPCT(SSWKREG4)   GET START/STOP CNT   20021 49930020
         BCT   SSSTOPCT,STRCNTV         WHEN CNT=0 RESET TCBSTPT  20021 49960020
         STC   SSSTOPCT,TCBSTPCT(SSWKREG4) UPDATE START/STOP CNT  20021 49970020
RSETSTP  EQU   *                                                  20021 49980020
         NI    TCBTSFLG(SSWKREG4),255-TCBSTPPR .  TURNS OFF FLAG  M0112 49983020
*                                        INDICATING SPV ACTIVE    M0112 49986020
         NI    TCBNDST2(SSWKREG4),255-TCBSTPT RESET START/STOP    20021 49990020
*                                      NON-DISPATCHABILITY FLAG   20021 50000020
         NC    TCBSCNDY(THREE,SSWKREG4),TCBSCNDY(SSWKREG4)        20021 50010020
*                                      Q ANY SEC. NON-DISP. SET?  20021 50020020
         BZ    RSETND                   NO SECONDARY FLAGS -BR    20021 50030020
CKALTSK  EQU   *                                                  20021 50040020
         LA    SSRCODE,ZERO       RESET RETURN CODE OF ZERO       21072 50042021
         CR    SSPMREG1,SSTCBREG        Q  ALL SUBTASKS AFFECTED  20021 50050020
         BE    GETNEXT                  YES -TAKE BRANCH          20021 50060020
         B     CHECK                                              21008 50070021
STRCNTV  EQU   *                                                  20021 50080020
         STC   SSSTOPCT,TCBSTPCT(SSWKREG4) UPDATE START/STOP CNT  20021 50110020
         B     CKALTSK                                            20021 50140020
RSETND   EQU   *                                                  20021 50170020
         NI    TCBDFLGS(SSWKREG4),PRIMDISP   RESET PRIMARY        20021 50200020
*                                      NON-DISPATCHABILITY FLG    20021 50230020
         L     SSAPGREG,TASKSWCH     ADDR OF TASK SWITCH         A39954 50240020
         BALR  SSRETREG,SSAPGREG     GO TO TASK SWITCH           A39954 50250020
         B     CKALTSK                                            20021 50260020
ONETCB   EQU   *                                                  20021 50290020
         CR    SSPMREG1,SSTCBREG        Q  ALL SUBTASKS AFFECTED  20021 50320020
         LR    SSWKREG2,SSTCBREG       INITIALIZE REG. FOR SCAN   20021 50340020
         LR    SSWKREG4,SSTCBREG       INITIALIZE REG. FOR SCAN   20021 50360020
         BE    GETNEXT                                            20021 50380020
FINDTCB  EQU   *                                                  20021 50400020
         BAL   SSRETREG,TREESCAN        GO TO SCAN ROUTINE        20021 50420020
         CR    SSPMREG1,SSWKREG4        Q  SPECIFIED TCB FOUND    20021 50440020
         BE    STRTSTOP                 YES - TAKE BRANCH         20021 50460020
         B     FINDTCB                  CONTINUE SEARCH FOR TCB   20021 50480020
STPCNT   EQU   *                                                  20021 50500020
         L     SXRBREG,0(SSWKREG4)     GET ADDR OF FIRST RB       20021 50510020
         SR    SSWKREG1,SSWKREG1       ZERO REGISTER FOR IC       20021 50520020
         IC    SSSTOPCT,TCBSTPCT(SSWKREG4)   GET START/STOP CNT   20021 50530020
         LA    SSSTOPCT,1(SSSTOPCT)    INCREMENT START/STOP CNT   20021 50540020
TESTRB   EQU   *                                                  20021 50550020
         TM    TCBTSFLG(SSWKREG4),TCBATT .     IS SUPV REQ        M0112 50560020
         BO    SETWCPLT                YES - TAKE BRANCH          20021 50570020
         STC   SSSTOPCT,TCBSTPCT(SSWKREG4) UPDATE START/STOP CNT  20021 50640020
         OI    TCBNDST2(SSWKREG4),TCBSTPT  SET STOP NON-DISP BIT  20021 50650020
         OI    TCBDFLGS(SSWKREG4),SPRIDISP   SET PRIMARY          20021 50660020
*                                      NON-DISPATCHABILITY BIT    20021 50690020
         B     CKALTSK                                            20021 50720020
SETWCPLT EQU   *                                                  20021 50750020
         STC   SSSTOPCT,TCBSTPCT(SSWKREG4) UPDATE START/STOP CNT  20021 50780020
         OI    TCBTSFLG(SSWKREG4),TCBSTPPR  INDICATE EXIT TO SET  20021 50810020
*                             STOP NON-DISP. WHEN SVRB COMPLETES  20021 50840020
         B     CKALTSK                                            20021 50900020
STOPSTSK EQU   *                                                  20021 50930020
         MVI   MASK2,STOPFLG            STOP INDICATOR            20021 50960020
         MVI   MASK1+1,STOPMSK          STOP NON-DISP. MASK       20021 50990020
         B     ONETCB                                             20021 51020020
STRTSTSK EQU   *                                                  20021 51050020
         MVI   MASK2,STRTFLG            START INDICATOR           20021 51080020
         MVI   MASK1+1,STRTMSK         START DISP MASK            20021 51110020
         B     ONETCB                                             20021 51150020
*********************************************************************** 51200020
*        SET STATUS INDICATED                                         * 51230020
*********************************************************************** 51240020
LOOPSET  EQU   *                                                  20021 51250020
         OC    TCBDISP(2,SSWKREG4),MASK3 SET PROPER BIT(S)              51270020
GETNEXT  BAL   SSRETREG,TREESCAN       GO TO SCAN ROUTINE               51310020
         CR    SSWKREG4,SSTCBREG       IS THIS THE CURRENT TCB          51350020
         BE    GETNEXT                 IF SO DONT'T SET FLAGS           51390020
         B     LOOP                    GO SET FLAGS                     51430020
*********************************************************************** 51440020
*  THE NEXT 3 INSTRUCTIONS RESET THE STATUS OF THE SPECIFIED TCB  M3329 51470020
*********************************************************************** 51480020
LOOPRSET EQU   *                                                  M3329 51510020
         MVC   MASK4(2),ORMASK     SET XC MASK                    M3329 51520020
         XC    MASK4(2),MASK3      SET INVERSE MASK FOR RESET     M3329 51530020
         NC    TCBDISP(2,SSWKREG4),MASK4  RESET DISP. BITS        M3329 51540020
         B     GETNEXT                                                  51550020
         EJECT                                                          51570020
         SPACE 1                                                        51600020
*********************************************************************** 51650020
*   THIS CODE IS ENTERED WHEN NON-DISPATCHABLE TCB ADDRESS IS SPECIFIED 51800015
*   IT SETS ALL DESCENDENTS OF THE SPECIFIED TCB NON-DISPATCHABLE     * 52000015
*********************************************************************** 52002020
NDTCB    EQU   *                                                 A28404 52010019
         LA    SSPMREG1,C0(SSPMREG1)    CLEAR HIGH ORDER BYTE    A28404 52200019
         LR    SSWKREG2,SSPMREG1                                        52400015
         LR    SSWKREG4,SSPMREG1        INITIALIZE INPUT FOR SCAN       52600015
         MVC   MASK3(2),MASK1           SET APPROPIATE MASK BITS        52800015
         LR    SSWKREG1,SSPMREG1  SET UP TCB ADDR. FOR CHK. RTN.  M4543 52850020
         LA    REGDOG,GETNEXT     WHERE TO GO IF TCB IS ABEND/TRM M4543 52900020
         BAL   REGBAKER,CHKATERM  GO CHECK TCB FOR ABEND OR TERM  M4543 52950020
         B     LOOP                     GO TO ROUTINE TO SET FLAGS      53000015
*********************************************************************** 53250020
*   THIS CODE IS ENTERED WHEN NON-DISPATCHABLE SYSTEM IS SPECIFIED      53400015
*   IT OBTAINS THE ADDRESS OF THE LAST SPECIAL SYSTEM TASK TCB AND    * 53600015
*   SETS ALL TASKS BELOW THIS NON-DISPATCHABLE EXCEPT THE CURRENT TCB * 53800015
*********************************************************************** 53850020
NDSYSTEM MVC   MASK3(2),MASK1           INITIALIZE INPUT FOR SCAN     * 54000020
         SPACE 1                                                        54050020
*********************************************************************** 54250020
*   THIS PORTION OF NDSYSTEM IS USED BY MCSYSTEM TO OBTAIN A TCB AND  * 54400020
*   SET THE PROPER INDICATORS                                         * 54600020
*********************************************************************** 54650020
GETFST   L     SSWKREG1,MASTER          GET ADDRESS OF MASTER TASK      54800015
         L     SSAPGREG,TASKSWCH            LOAD ADDRESS OF IEA0DS02    55000015
GETNXT   L     SSWKREG1,TCBTCB(SSWKREG1)   NEXT ON READY QUEUE          55200019
         LTR   SSWKREG1,SSWKREG1        IS THIS LAST ON READY QUEUE?    55400015
         BZ    CHECK                   .YES GO TO PRE-EXIT TESTS.  65MP 55600017
         CR    SSWKREG1,SSTCBREG        IS THIS CURRENT TCB             55800015
         BE    GETNXT                   IF SO DON'T SET BUT GET NEXT    56000015
         LA    REGDOG,GETNXT      WHERE TO GO INCASE TCB BAD      M4543 56060020
         BAL   REGBAKER,CHKATERM  GO CHECK TCB FOR ABEND OR TERM  M4543 56120020
         TM    MASK2,X'80'              SET OR RESET                    56200015
         BO    RESET2                   GO TO RESET ROUTINE             56400015
*********************************************************************** 56450020
*       IF WE FALL THROUGH, SET STATUS WAS INDICATED                  * 56600020
*********************************************************************** 56650020
         OC    TCBDISP(2,SSWKREG1),MASK3 SET PROPER BITS                56800015
         B     GETNXT                   GO GET NEXT                     57000015
RESET2   EQU   *                                                  M3892 57050020
         MVC   MASK4(2),ORMASK        USED FOR INVERT MASK        M3892 57100020
         XC    MASK4(2),MASK3         SET INVERSE MASK FOR RESET  M3892 57150020
         NC    TCBDISP(2,SSWKREG1),MASK4   RESET PROPER BITS      M3892 57200020
         LR    SSWKREG4,SSWKREG1            SET UP LINKAGE              57260015
         BALR  SSRETREG,SSAPGREG            BRANCH TO TASK SWITCHING    57320015
         B     GETNXT                   GO GET NEXT ON QUEUE            57400015
         EJECT                                                          57500020
         SPACE 2                                                        57600015
*********************************************************************** 57650020
*   THIS CODE IS ENTERED WHEN NON-ROLLOUTABLE IS INDICATED            * 57800020
*********************************************************************** 57850020
NONROLL  EQU   *                                                 A28404 58000019
         LA    SSWKREG1,C0(SSPMREG1)    CLEAR HIGH ORDER BYTE    A28404 58010019
         LA    SSWKREG2,1                                               58400015
         SR    SSWKREG3,SSWKREG3                                        58600015
         LTR   SSWKREG1,SSWKREG1        WAS TCB ADDRESS SPECIFIED?      58800015
         BNZ   SKIP                                                     59000020
*********************************************************************** 59250020
*   IF WE FALL THROUGH, NO TCB ADDRESS WAS SPECIFIED SO WE USE THE    * 59400020
*   CURRENT TCB                                                       * 59600020
*********************************************************************** 59650020
         LR    SSWKREG1,SSTCBREG  SET REG 7 WITH CURR. TCB.       M4543 59730020
SKIP     EQU   *                                                  M4543 59810020
         L     SSWKREG1,TCBJSTCB(SSWKREG1)                        M4543 59890020
         IC    SSWKREG3,TCBROLL(SSWKREG1) GET ROLLOUT BYTE              59990020
         TM    MASK2,X'80'                                              60200015
         BO    RESET3                   GO TO RESET ROUTINE             60400015
*********************************************************************** 60450020
*   IF WE FALL THROUGH, SET STATUS WAS INDICATED                      * 60600020
*********************************************************************** 60650020
         AR    SSWKREG3,SSWKREG2        INCREMENT COUNT                 60800015
         STC   SSWKREG3,TCBROLL(SSWKREG1) REPLACE COUNT                 61000015
         B     EXIT                                                     61200015
RESET3   SR    SSWKREG3,SSWKREG2        DECREMENT COUNT                 61400015
         STC   SSWKREG3,TCBROLL(SSWKREG1) REPLACE COUNT                 61600015
         LTR   SSWKREG3,SSWKREG3        IS COUNT ZERO?                  61800015
         BNE   EXIT                     COUNT NOT ZERO EXIT             62000015
         L     SSWKREG2,ROLLOUTQ        ARE THERE QUEUED REQUESTS?      62200015
         LH    SSWKREG2,0(SSWKREG2)                                     62400015
         LTR   SSWKREG2,SSWKREG2                                        62600015
         BZ    EXIT                     NO REQUESTS, EXIT               62800015
         LA    REGDOG,EXIT        WHERE TO GO INCASE TCB BAD      M4543 62860020
         BAL   REGBAKER,CHKATERM  GO CHECK TCB FOR ABEND OR TERM  M4543 62920020
         EJECT                                                          62980020
*********************************************************************** 63050020
*   THIS CODE SCHEDULES THE ROLL OUT TASK WHEN THE COUNT GOES TO ZERO * 63200020
*********************************************************************** 63250020
         L     SSR11,IQE                ADDRESS OF GETIQE               63400015
         BALR  SSWKREG3,SSR11     GO GET IQE                            63600015
         XC    IQEPARAM(4,SSPMREG1),IQEPARAM(SSPMREG1) ZERO PARAMETER   63800019
*********************************************************************** 63850020
* LIST ADDRESS TO INDICATE RETRY OF QUEUED ROLLOUT REQUESTS      A28404 64000019
*********************************************************************** 64050020
         LCR   SSPMREG1,SSPMREG1        COMPLEMENT TO INDICATE IQE      64400015
         L     SSAPGREG,STAGE2(SSCVTREG) ADDRESS OF EXIT EFFECTOR-2     64600015
         BALR  SSRETREG,SSAPGREG                                        64800015
         B     EXIT                                                     65000015
         EJECT                                                          65100020
         SPACE 2                                                        65200015
*********************************************************************** 65250020
*   THIS ROUTINE PASSES BACK IN SSWKREG4 A DESCENDENT OF THE TCB WHOSE* 65400015
*   ADDRESS IS PASSED TO IT IN SSWKREG4                               * 65600015
*********************************************************************** 65650020
TREESCAN LR    SSWKREG3,SSWKREG4                                        65800015
         L     SSWKREG4,TCBLTC(SSWKREG3) ADDRESS OF DESCENDENT          66000015
SCAN1    LTR   SSWKREG4,SSWKREG4        WAS DESCENDENT FOUND?           66200015
         BZ    PICKNXT             GO GET NEXT TCB                M3329 66220020
         LR    SSWKREG1,SSWKREG4     SET UP REG FOR ABEND CHECK   M4543 66260020
         LA    REGDOG,PICKNXT     WHERE TO GO INCASE TCB BAD      M4543 66300020
         BAL   REGBAKER,CHKATERM  GO CHECK TCB FOR ABEND OR TERM  M4543 66340020
         BR    SSRETREG  RETURN TO MAINLINE WITH TCB ADDRESS      M4543 66380020
PICKNXT  EQU   *                                                  M3329 66460020
         L     SSWKREG4,TCBNTC(SSWKREG3) IF NOT GET SISTER TCB          66600015
         CR    SSWKREG3,SSWKREG2        IS THIS TOP TCB?                66800015
         BE    CHECK                    YES GO TO PRE-EXIT TESTS.  65MP 67000020
         L     SSWKREG3,TCBOTC(SSWKREG3)                                67200015
         B     SCAN1                                                    67400015
         EJECT                                                          67402020
*********************************************************************** 67404020
*                                                                 M4543 67406020
*                  TERMINATED/ABENDING CHECK ROUTINE              M4543 67408020
*                                                                 M4543 67410020
*********************************************************************** 67412020
*                           INPUT                                 M4543 67414020
*     THE ADDRESS OF THE TCB TO BE CHECKED IS TO BE IN REG.7      M4543 67416020
*     THE ADDRESS OF WHERE TO GO FOR AN INVALID TCB IS IN REG.13  M4543 67418020
*     THE ADDRESS OF WHERE TO RETURN TO THE MAINLINE IS IN REG.11 M4543 67420020
*                                                                 M4543 67422020
CHKATERM EQU   *                                                  M4543 67424020
         TM    TCBDISP+1(SSWKREG1),X'80'  IS TCB TERM'D?          M4543 67426020
         BCR   1,REGDOG                   YES. RETURN TO MAINLINE M4543 67428020
         TM    TCBDISP+1(SSWKREG1),X'40'  IS TCB TERM BY ABEND?   M4543 67430020
         BCR   8,REGBAKER                 NO. GOOD TCB. RETURN    M4543 67432020
         TM    TCBASE(SSWKREG1),X'80'     IS TCB ABENDING?        M4543 67434020
         BCR   1,REGDOG                   YES. RETURN TO MAINLINE M4543 67436020
         BR    REGBAKER                   TCB IS GOOD. RETURN     M4543 67438020
         EJECT                                                          67440020
*********************************************************************** 67450020
         SPACE 2                                                        67600015
         DS    0F                                                       67800015
TASKSWCH DC    A(IEA0DS02)              TASK SWITCHING ROUTINE          67900020
ROLLOUTQ DC    A(IEAROQCT)              NUMBER OF QUEUED REQUESTS       68000015
IQE      DC    A(GETIQE)                GET IQE ROUTINE                 68200015
MASTER   DC    A(IEAMSTCB)              ADDRESS OF MASTER TCB           68600015
ABTERM   DC    A(IEA0AB01)                                              68800015
TYP1EXIT DC    A(IEA0XE00)              ADDR OF TYPE 1 EXIT      A37037 68810020
ORMASK   DC    X'FFFF'                                            M3329 68850020
SETMCFLG DC    X'0008'                  SET SYS. M. C. FLAGS            68900020
RSTMCFLG DC    X'0008'                                            M4543 68950020
SETSAVE  DS    14F                      REGISTER SAVE AREA       A28404 69400019
SAVER14  DS    2F                                                A28404 69410019
MASK1    DS    1F                       FULL WORD FOR PARAMETERS        69600015
MASK2    DS    1F                       FULL WORD FOR PARAMETERS        69800015
MASK3    DS    1H                       NON-DISPATCHABLE MASK           70000015
MASK4    DS    1H                                                 M3329 70020020
BRCHSWTH DC    1H'0'                                              M5156 70070020
         EXTRN IEA0DS02                                                 70100015
         EXTRN IEAROQCT                                                 70400015
         EXTRN GETIQE                                                   70800015
         EXTRN IEA0AB01                                                 71000015
         EXTRN IEAMSTCB                                                 71200015
         EXTRN IEA0XE00                                          A37037 71250020
         ENTRY IGC07902                                                 71600019
         END                                                            72000015
