         TITLE '   TTIMER AND STIMER FOR OPTION 4 SYSTEMS'              00020000
IGC046   START 0                                                        00040000
*...THIS MODULE CONTAINS CODE FOR TTIMER AND STIMER SVC'S USING OPTION  00060000
*   6B. A FEW ADCONS ARE SHARE BY THE RTNS, AND REGISTER AND OFFSET     00080000
*   SYMBOLISM IS SHARED BETWEEN THE TWO RTNS.                           00100000
         SPACE                                                          00120000
CVTSECT  DSECT                                                          00140000
         CVT                                                            00160000
         SPACE                                                          00180000
IGC046   CSECT                                                          00200000
         ENTRY IGC046A0                                             MCH 00202019
         ENTRY IGC046A1                                             MCH 00204019
IGC046A0 EQU   *                                                    MCH 00206019
*OWNERSHIP - 19472                                                  MCH 00213019
* A24887                                                                00214019
         SPACE                                                          00220000
*...REGISTERS USED BY TTIMER AND STIMER CODE...                         00240000
XDQ      EQU   2        .RETURN REG FROM DEQUEUE RTN.                   00260000
XCVT     EQU   3        .ADDR OF CVT.                                   00280000
XTCB     EQU   4        .ADDR OF CURRENT TCB.                           00300000
XRB      EQU   5        .ADDR OF CURRENT RB.                            00320000
XRETRN   EQU   14       .RETURN ADDR.                                   00340000
         SPACE                                                          00360000
*...OFFSETS USED BY TTIMER AND STIMER CODE...                           00380000
VSHPC    EQU   0        .OFFSET FROM PSEUDO CLOCK PTR OF SHPC           00400000
VT4PC    EQU   4        .OFFSET FROM PSEUDO CLOCK PTR OF T4PC           00420000
VLTPC    EQU   8        .OFFSET FROM PSEUDO CLOCK PTR OF LTPC           00440000
SAVDISP  EQU   72                  .DISPLACEMENT FOR SAVING REG 10 REFR 00450017
         SPACE                                                          00460000
TQEFLGS  EQU   0        .TIMER ELM FLAGS.                               00480000
TQETCB   EQU   1        .TIMER ELM TCB.                                 00500000
TQEFLNK  EQU   4        .FORWARD LINK ADDR.                             00520000
TQEBLNK  EQU   8        .BACKWARD LINK ADDR.                            00540000
TQEVAL   EQU   12       .INTERVAL VALUE.                                00560000
TQEPSW   EQU   16       .PSW.                                           00580000
TQESAADR EQU   24            .S/A ADDR.                                 00600000
TQEEXIT  EQU   28       .ASYNCH. EXIT ADDR.                             00620000
TQEECB   EQU   96       .ECB AT END OF TQE.                             00640000
         SPACE                                                          00660000
*...RB OFFSETS...                                                       00680000
RBSIZE   EQU   8        .RB SIZE.                                       00700000
RBSTAB   EQU   10       .RB STAB.                                       00720000
RBOPSW   EQU   16       .RB OLD PSW.                                    00740000
RBLINK   EQU   28       .RB LINK FIELD.                                 00760000
RBGRSAV  EQU   32       .1ST WORD OF RB REGISTER SAVE AREA (REG 0).     00780000
RBEXTSAV EQU   96       .1ST WORD OF RB EXTEND SAVE AREA.               00800000
         SPACE                                                          00820000
RBFDYN   EQU   X'02'    .DYNAMIC MASK.                                  00840000
         SPACE                                                          00860000
*...MISC EQUATES...                                                     00880000
TIMER    EQU   80       .HARDWARE TIMER.                                00900000
TCBTME   EQU   120      .TQE ADDR IN TCB.                               00920000
         TITLE '        TTIMER FOR OPTION 4 SYSTEMS'                    00940000
*...COMMENTARY FOR TTIMER...                                            00960000
         SPACE                                                          00980000
* ROUTINE NAME- IGC046,TTIMER SVC SERVICE ROUTINE.                      01000000
         SPACE                                                          01020000
* FUNCTION-    THIS CODE CALCULATES THE REMAINING TIME IN A TASK'S      01040000
*              INTERVAL AND LOADS THIS VALUE INTO REGISTER 0.           01050017
*              IF THE INTERVAL HAS NOT EXPIRED,REGISTER 1 IS LOADED     01070017
*              WITH EXIT ADDRESS (IF PRESENT) AND THE OPTION FLAGS.     01100000
*              WITH THE INFORMATION THUS PROVIDED, THE INTERVAL MAY BE  01120000
*              REESTABLISHED AFTER A 'TTIMER CANCEL' REQUEST.           01140000
*              THE OPTION FLAG RETURNED IS ALTERED TO INDICATE THE      01160000
*              'TUINTVL' OPTION TO CORRESPOND TO THE TIME UNITS         01180000
*              RETURNED IN REGISTER 1.                                  01200000
*              BEFORE A STIMER MACRO CAN BE GIVEN, THE TIME VALUE IN    01220000
*              REGISTER 1 MUST BE STORED INTO STORAGE AND THE ADDRESS   01240000
*              OF THE STORAGE LOCATION MUST BE PLACED INTO REGISTER 1.  01260000
         SPACE                                                          01280000
* ENTRY POINT NAME- IGC046                                              01300000
         SPACE                                                          01320000
* CONTAINED IN MODULE- IEAQST00                                         01340000
         SPACE                                                          01360000
* ATTRIBUTES-  RESIDENT,REENTRANT,SUPERVISOR STATE,I/O AND EXTERNAL     01380000
*              DISABLED,TYPE 1 SVC ROUTINE.                             01400000
         SPACE                                                          01420000
* APPLICABILITY- OPTION 4 SYSTEMS USING OPTION 6B.                      01440000
         SPACE                                                          01460000
* EXTERNAL REFERENCES- IEAQTD01, ENTRY POINT TO TIMER DEQUEUE RTN.      01480000
*                    - IEAQTD00, ENTRY POINT TO TIMER CANCEL RTN.       01500000
         SPACE                                                          01520000
* SVC USAGE-   NONE                                                     01540000
         SPACE                                                          01560000
* INPUT-       CANCEL OPTION SPECIFIED BY REG 1 NOT ZERO.               01580000
         SPACE                                                          01600000
* OUTPUT-      REMAINING TIME IN INTERVAL PLACED IN REG 0.              01620000
*              REGISTER 1 CONTAINS OPTION FLAG IN HI ORDER BYTE AND     01640000
*              EXIT ADDRESS IN LOW ORDER THREE BYTES.                   01660000
         SPACE                                                          01680000
* ENTRY POINT- .IGC046. ONLY ENTRY POINT IN CODE-GIVEN CONTROL BY SVC   01700000
*               FLIH.                                                   01720000
*              .THE PSW AT ENTRY MUST BE IN SUPERVISORY MODE & DISABLED 01740000
*               FOR I/O AND EXTERNAL INTERRUPTS AND HAVE SUPERVISORY    01760000
*               PROTECTION KEY.                                         01780000
*              .REG 1 CONTAINS THE CANCEL OPTION INDICATION             01800000
*              .REG 3 CONTAINS THE CVT ADDRESS.                         01820000
*              .REG 4 CONTAINS THE CURRENT TCB ADDRESS.                 01840000
*              .REG 5 CONTAINS THE CURRENT RB ADDRESS.                  01860000
*              .REG 14 CONTAINS THE ADDRESS OF TYPE 1 SVC EXIT.         01880000
*              .REGS 0,2,6-13 AND 15 ARE IRRELEVANT.                    01900000
         SPACE                                                          01920000
* EXIT POINT- .TO TYPE 1 SVC EXIT WHEN RTN IS COMPLETE.                 01940000
*             .THE PSW IS UNCHANGED FROM ENTRY.                         01960000
*              .REG 1 CONTAINS OPTION FLAG IN HI ORDER BYTE AND EXIT    01980017
*              ADDRESS IN LOW ORDER THREE BYTES.                        02000000
*              .REG 0 CONTAINS REMAINING TIME                           02020017
*             .REGISTERS 0-15 ARE VOLATILE.                             02040000
         SPACE                                                          02060000
*             .TO TIMER CANCEL ROUTINE.                                 02080000
*              THE PSW IS UNCHANGED FROM ENTRY.                         02100000
*              REG 1 CONTAINS TQE ADDRESS TO BE DEQUEUED.               02120000
*              REG 2 CONTAINS RETURN ADDRESS.                           02140000
*              REG 15 CONTAINS ADDRESSABILITY FOR CANCEL DEQUEUE RTN.   02160000
         SPACE                                                          02180000
* ERROR EXIT POINTS- NONE                                               02200000
         SPACE                                                          02220000
* TABLES AND CONTROL- .THE TCB OF THE CURRENT TASK TO OBTAIN THE        02240000
*  BLOCKS REFERENCED   TIMER QUEUE ELEMENT ADDRESS.                     02260000
*                     .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDRESS.      02280000
         SPACE                                                          02300000
* LIST ORIGINS,     .NONE                                               02320000
* TABLES, CONTROL                                                       02340000
* BLOCKS INCLUDED                                                       02360000
         SPACE                                                          02380000
* RESTRICTIONS-     .NONE                                               02400000
         SPACE                                                          02420000
* NOTES            IF THE CANCEL OPTION IS SPECIFIED, THE TQE AND       02440000
*                  SAVE AREA WILL BE FREED                              02460000
*                                                                       02480000
         SPACE 3                                                        02500000
*...REGISTERS UNIQUE TO IGC046 CODE...                                  02520000
XGT0     EQU   0        .WORK REG.                                      02540000
XPARA    EQU   1        .CONTAINS INPUT PARAM & REMAINING TIME ON EXIT. 02560000
XTPSEUDO EQU   9        .CONTAINS ADDR OF PSEUDO CLOCK.                 02580000
XELE     EQU   10       .CONTAINS ADDRESS OF TIMER QUEUE ELEMENT.       02600000
XFLAGS   EQU   11       .CONTAINS 1ST WORD OF TQE (IF ANY).             02620000
XWK      EQU   12            .WORK REG.                                 02640000
FLGREG   EQU   13                       INTERNAL FLAG REG               02660000
XTBASE   EQU   15       .BASE REG.                                      02680000
XR9      EQU   9                                                        02700000
XR7      EQU   7                                                        02720000
XR8      EQU   8                                                        02740000
         SPACE                                                          02760000
*...MISC...                                                             02780000
KEXP     EQU   X'88'                                                    02800000
TTIMSAV  EQU   X'4C'                                               REFR 02810017
         SPACE 2                                                        02820000
         BALR  XTBASE,0                                                 02840000
         USING *,XTBASE                                                 02860000
TTBASE   DS    0H                      LABEL FOR ADDRESSABILITY         02880000
         USING CVTSECT,XCVT                                        REFR 02885017
         L     XTPSEUDO,CVTTPC     .ADDRESS OF PSEUDO CLOCKS       REFR 02890017
         ST    XRETRN,TTIMSAV(XTPSEUDO) .SAVE RETURN REG IN TPC    REFR 02895017
         L     XELE,TCBTME(0,XTCB)     .GET TQE ADDR FROM TCB.          02900000
         LTR   XELE,XELE          .IS THERE AN ELEMENT.                 02920000
         BC    6,TESTEXP          .BR IF YES.                           02940000
TSET0   SR    X1,X1                   .CLEAR FLAG REG.                  02960000
         SR    XGT0,XGT0               .CLEAR REMAINING TIME REG.       02980000
TEXIT2   L     XTPSEUDO,CVTTPC     .ADDRESS OF PSEUDO CLOCKS       REFR 02986017
         L     XRETRN,TTIMSAV(XTPSEUDO) .RESTORE RETURN REG        REFR 02993017
        BR    XRETRN                  .RETURN.                          03000000
         DROP  XCVT                                                REFR 03010017
         SPACE                                                          03020000
TESTEXP  IC    XFLAGS,TQEFLGS(0,XELE)  .PICK UP TQE 1ST WORD.           03040000
         TM    TQEFLGS(XELE),KEXP      .HAS INTERVAL EXPIRED.           03060000
         BC    14,TSET2                 BR IF NO                        03080000
         SR    FLGREG,FLGREG            CLEAR FOR LATER TEST            03100000
         ST    FLGREG,TCBTME(0,XTCB)    ZERO TQE POINTER                03120000
         LR    XR9,XTBASE               SET R 9 FOR ADDRESSABILITY      03140000
         LA    FLGREG,TSET0             SET PROPER EXIT FLAG            03160000
         BC    15,TSET1                 SKIP INTERVAL CODE              03180000
TSET2    EQU   *                                                        03200000
         SPACE                                                          03220000
*...DEVELOP REMAINING TIME IN INTERVAL...                               03240000
*...    = TOX - (SHPC - TIMER)                                          03260000
         USING CVTSECT,XCVT                                             03280000
         L     XTPSEUDO,CVTTPC    .GET ADDR OF PSEUDO CLOCKS.           03300000
         L     XWK,TIMER               .GET TIMER VALUE.                03340000
         SRA   XWK,1                   .DEV 26 USEC UNITS.              03360000
         LCR   XWK,XWK                 .-TIMER                          03380000
         AL    XWK,VSHPC(0,XTPSEUDO)   .(SHPC-TIMER)                    03400000
         LR    XR9,XTBASE          .LOAD REG FOR NEW BASE          REFR 03410017
         LCR   XWK,XWK                 .-(SHPC-TIMER)                   03420000
         AL    XWK,TQEVAL(0,XELE)      .TOX-(SHPC-TIMER)                03440000
         BC    3,*+6              .BR IF INTVL NOT PAST DUE.            03460000
         SR    XWK,XWK                 .SET REMAINING TIME TO ZERO.     03480000
         LTR   XPARA,XPARA        .TEST FOR CANCEL OPTION.              03500000
         BC    8,TEXITX           .BR IF CANCEL NOT SPECIFIED.          03520000
         SPACE                                                          03540000
*...CANCEL INTERVAL...                                                  03560000
         SR    XGT0,XGT0                                                03580000
         ST    XGT0,TCBTME(0,XTCB)     ZERO TQE FIELD IN TCB            03600000
         LR    XPARA,XELE         .SET ELM ADDR IN REG FOR DEQUEUE.     03660000
         L     XDQ,ADQSPCL        .GET SPECIAL ENTRY TO DEQUEUE.        03680000
         L     XTPSEUDO,CVTTPC     .GET BASE FOR PSEUDO CLOCKS     REFR 03682017
         ST    XELE,SAVDISP(XTPSEUDO) .SAVE REG 10 IN TPC          REFR 03685017
         LR    XELE,XTPSEUDO       .BASE FOR PSEUDO CLOCKS         REFR 03690017
         LR    XR9,XTBASE          .LOAD REG FOR NEW BASE          REFR 03695017
         L     XTBASE,DQBASE      .SET DQ ADDRESSABILITY.               03700000
         BALR  XDQ,XDQ            .TO DEQUEUE RTN.                      03720000
         DROP  XTBASE                                                   03740000
         USING TTBASE,XR9                                               03760000
         LR    XELE,XPARA          RESTORE TQE ADDR            @SA63917 03780021
         LA    FLGREG,TEXITX            SET RETURN REG                  03800000
TSET1    EQU   *                                                        03820000
         L     XGT0,SP250              SET UP TO FREE TQE SAVE AREA     03860000
         L     XPARA,TQESAADR(0,XELE)  SP = 250, LN = 72 BYTES          03880000
         L     XR8,ARMBRNCH            BRANCH ENTRY TO FREEMAIN         03900000
         BALR  XRETRN,XR8                                               03920000
         L     XGT0,SP243              SET UP TO FREE TQE         20021 03940020
         LR    XPARA,XELE              SP = 243, LN = 112 BYTES   20021 03960020
         L     XR8,ARMBRNCH            BRANCH ENTRY TO FREEMAIN         03980000
         BALR  XRETRN,XR8                                               04000000
         LR    XTBASE,XR9          RESTORE BASE REG                REFR 04010017
         BCR   15,FLGREG                RETURN                          04040000
TEXITX   LR    XGT0,XWK                .SET INTVL IN REG.               04060000
         LA    X1,X'43'           .SET MASK.                            04080000
         NR    XFLAGS,X1         .SET FLAG TO INDICATE 'TUINTVL'.       04100000
         SLL   XFLAGS,24               .SHIFT FLAGS TO HI ORDER BYTE.   04120000
         O     XFLAGS,TQEEXIT(0,XELE)  .PLACE EXIT ADDR IN LO 3 BYTES.  04140000
         LR    X1,XFLAGS          .SET FLAG AND EXIT INFO IN REG 1.     04160000
         L     XCVT,CVTPTR         .GET ADDRESS OF CVT             REFR 04170017
         B     TEXIT2              .BRANCH TO EXIT                 REFR 04180017
         DROP  XCVT                                                     04190017
         DROP  XR9                                                      04340000
         TITLE '        STIMER FOR OPTION 4 SYSTEMS'                    04360000
*...COMMENTARY FOR STIMER...                                            04380000
         SPACE                                                          04400000
* ROUTINE NAME .IGC047- STIMER SVC SERVICE ROUTINE.                     04420000
         SPACE                                                          04440000
* FUNCTION-    .INITIALIZES AND QUEUES TIMER QUEUE ELEMENT (TQE) FOR    04460000
*               THE PURPOSE OF TIMING REQUESTED INTERVALS.              04480000
*              .PERFORMS CONVERSION TO TU'S WHEN INPUT TIME VALUE IS    04500000
*               IN BIN OR DEC UNITS.                                    04520000
*              .CHECKS WHETHER  TQE IS BEING USED AS IRB FOR PREVIOUSLY 04540000
*               SPECIFIED INTERVAL. IF SO, STIMER REQUEST IS IGNORED.   04560000
*              .CHECKS WHETHER TQE IS CURRENT IN USE. IF SO, EXISTING   04580000
*               INTERVAL IS CANCELLED AND NEW INTERVAL INSTATED.        04600000
         SPACE                                                          04620000
* ENTRY POINT NAME  .IGC047                                             04640000
         SPACE                                                          04660000
* CONTAINED IN MODULE- IEAQST00                                         04680000
         SPACE                                                          04700000
* ATTRIBUTES   .TYPE 2 SVC RTN.,RESIDENT,REENTRANT,SUPERVISOR STATE,    04720000
*               I/O AND EXTERNAL DISABLED.                              04740000
         SPACE                                                          04760000
* APPLICABILITY- OPTION 4 SYSTEMS USING OPTION 6B.                      04780000
         SPACE                                                          04800000
* EXTERNAL REFERENCES-  .IEAQTD01, ENTRY POINT TO TIMER DEQUEUE RTN.    04820000
*                       .IEAQTD00, CANCEL DEQUEUE ENTRY POINT           04840000
         SPACE                                                          04860000
* SVC USAGE    .WAIT- ECB IN TQEECB.                                    04880000
*              .GETMAIN- SUBPOOL 250.                                   04900000
*              .GETMAIN- SUBPOOL 253.                                   04920000
         SPACE                                                          04940000
* INPUT        .REG 0 CONTAINS OPTION FLAGS IN HI ORDER BYTE AND EXIT   04960000
*               ADDR. IN LOW ORDER 3 BYTES.                             04980000
*              .REG 1 CONTAINS THE ADDRESS OF THE TIME VALUE.           05000000
*              .THE LEFT HALF OF THE PSW STORED IN THE SVRB (RBOPSW)    05020000
*               OF THE STIMER CODE.                                     05040000
         SPACE                                                          05060000
* OUTPUT       .AN INITIALIZED AND QUEUED TQE.                          05080000
         SPACE                                                          05100000
* ENTRY POINTS .IGC047, ENTRY FROM SVC FLIH.                            05120000
*              .REG 0 CONTAINS OPTION FLAG AND EXIT ADDRESS.            05140000
*              .REG 1 CONTAINS ADDR OF TIME VALUE.                      05160000
*              .REG 3 CONTAINS CVT ADDR                                 05180000
*              .REG 4 CONTAINS CURRENT TCB ADDR.                        05200000
*              .REG 5 CONTAINS CURRENT RB ADDR.                         05220000
*              .REGS 2,6-13, & 15 ARE IRRELEVANT.                       05240000
*              .REG 14 CONTAINS ADDR OF SVC 3 (TYPE 2 EXIT)             05260000
*              .THE PSW IS IN SUPERVISOR STATE AND IS I/O AND EXTERNAL  05280000
*               DISABLED AND HAS SUPERVISOR PROTECTION KEY.             05300000
         SPACE                                                          05320000
* EXIT POINTS  .TO TYPE 2 EXIT VIA BR 14                                05340000
*              .THE PSW STATUS IS UNCHANGED                             05360000
*              .REG 14 CONTAINS THE EXITING ADDR. OTHER REGS ARE        05380000
*               MEANINGLESS.                                            05400000
*              REGS 0-13, & 15 ARE VOLATILE OVER STIMER.                05420000
*              REG 14 IS TRANSPARENT.                                   05440000
         SPACE                                                          05460000
* ERROR EXIT POINTS .NONE                                               05480000
         SPACE                                                          05500000
* TABLES & CONTROL  .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDR AND        05520000
* BLOCKS REFERENCED  TIMER DEQUEUE AN TIMER ENQUEUE RTNS.               05540000
*                   .THE CURRENT TCB TO OBTAIN THE TQE ADDR.            05560000
*                   .THE CURRENT RB TO REFERENCE INPUT REGS 0 & 1 WHICH 05580000
*                    ARE SAVED IN THE RBGRSAV AREA AND THE PSW IN       05600000
*                    EFFECT WHEN THE SVC WAS ISSUED. ALSO, AN EXTENDED  05620000
*                    SAVE AREA APPENDED TO THE SVRB IS USED FOR AN ECB. 05640000
*                    A WORK AREA FOR A PACK INSTRUCTION, AND AS TEMP.   05660000
*                    REGISTER STORAGE OVER THE TIMER DEQUEUE RTN.       05680000
*                   .THE TQE IS REFERENCED AND INITIALIZED FOR THE NEW  05700000
*                    INTERVAL.                                          05720000
         SPACE                                                          05740000
* LIST ORIGINS,TABLES    .A CONVERSION TABLE TMTABLE FOR CONVERTING     05760000
* & CONTROL BLOCKS        DEC DIGITS TO BIN UNITS.                      05780000
* INCLUDED                                                              05800000
         SPACE                                                          05820000
         SPACE                                                          05840000
* NOTES        NOTE CVB INSTRUCTION DEPENDS UPON RBEXTSAV+0 TO BE ON A  05860000
*              DOUBLE WORD BOUNDARY.                                    05880000
         SPACE 3                                                        05900000
*...REGISTERS UNIQUE TO STIMER CODE...                                  05920000
XPARA0   EQU   0                                                        05940000
X1       EQU   1                                                        05960000
XTIME    EQU   1                                                        05980000
XNQPTR   EQU   1                                                        06000000
XECB     EQU   1                                                        06020000
XBASE    EQU   2                                                        06040000
XNQ      EQU   2                                                        06060000
XLPCTL   EQU   9                                                        06080000
XPSEUDO  EQU   9                                                        06100000
XGR2     EQU   10                                                       06120000
XINCR    EQU   10                                                       06140000
XGR3     EQU   11                                                       06160000
XCMPR    EQU   XINCR+1                                                  06180000
XPRD     EQU   12                                                       06200000
XELM     EQU   12                                                       06220000
XCAND    EQU   XPRD+1                                                   06240000
XGR1     EQU   13                                                       06260000
XEXIT    EQU   13                                                       06280000
XTMPTR   EQU   15                                                       06300000
         SPACE                                                          06320000
*...MASKS FOR TESTING FLAGS...                                          06340000
*   INPUT FLAGS                                                         06360000
DINTVL   EQU   X'30'         .DECIMAL OPTION                            06380000
TOD      EQU   X'40'         .TOD OPTION                                06400000
         SPACE                                                          06420000
*   TQE FLAGS                                                           06440000
EXIT     EQU   X'04'    .EXIT MASK                                      06460000
OFFQ     EQU   X'80'    .OFF QUEUE MASK                                 06480000
WAIT     EQU   X'01'    .WAIT OPTION MASK                               06500000
COMPLETE EQU   X'88'    .COMPLETION MASK                                06520000
         SPACE                                                          06540000
*   MISC                                                                06560000
ACTIRB   EQU   X'40'                                                    06580000
         SPACE                                                          06600000
         SPACE                                                          06620000
         ENTRY IGC047                                                   06640000
         EXTRN IEAQTD00,IEAQTD01                                        06660000
         SPACE                                                          06680000
IGC047   DS    0D                                                       06700000
         BALR  XBASE,0                                                  06720000
         USING *,XBASE                                                  06740000
*...NOTE THAT INPUT PARAMETER REGS 0 & 1 ARE SAVED IN THE SVRB SAVE     06760000
*   AREA AT SVRB+32 & SVRB+36 RESPECTIVELY.                             06780000
         TM    RBGRSAV+0(XRB),DINTVL .TEST FOR DECIMAL OPTION.          06800000
         BC    12,TLDTIME         .BR IF NOT DECIMAL OPTION.            06820000
         SPACE                                                          06840000
*...CONVERT DEC. VALUE TO BIN UNITS...                                  06860000
         LR    XTMPTR,XTIME       .LOAD REG WITH ADDR OF TIME VALUE     06880000
         SR    XLPCTL,XLPCTL      .INITIALIZE CONVERSION LOOP.          06900000
         SR    XTIME,XTIME                                              06920000
         LA    XINCR,4                                                  06940000
         LA    XCMPR,16                                                 06960000
TMDECLP  BXH   XLPCTL,XINCR,TMCNVTU .LOOP 4 TIMES BEFORE BRANCHING.     06980000
         PACK  RBEXTSAV+0(8,XRB),0(2,XTMPTR) .PACK 2 DEC DIGITS.        07000000
         OI    RBEXTSAV+7(XRB),X'0F'   .INSURE THAT SIGN IS PRESENT.    07020000
         CVB   XCAND,RBEXTSAV+0(XRB) .CONVERT 2 DIGITS TO BINARY UNITS. 07040000
         M     XPRD,TMTABLE-4(XLPCTL) .EXPAND TO BIN UNITS.             07060000
         ALR   XTIME,XCAND        .ACCUM BIN TIME UNITS.                07080000
         LA    XTMPTR,2(XTMPTR)   .REF NEXT TWO DIGITS.                 07100000
         B     TMDECLP                                                  07120000
         SPACE                                                          07140000
*...TUINTVL OR BINTVL OPTIONS...                                        07160000
TLDTIME  L     XTIME,0(XTIME)     .GET TIME VALUE.                      07180000
         BZ    TLOCTST            .BR IF TUINTVL OPTION.                07200000
         SPACE                                                          07220000
*...CONVERT BIN UNITS TO TU'S...                                        07240000
TMCNVTU  CL    XTIME,TBINMAX     CHECK FOR EXCESSIVE BIN VALUE   A31487 07270020
         BNH   *+8                                                      07280000
         L     XTIME,TBINMAX      .USE MAX BIN VALUE.                   07300000
         M     XPARA0,TMTUCNV     .CONVERT TO 52 USEC UNITS.            07320000
         D     XPARA0,TM10E7                                            07340000
         ALR   XTIME,XTIME        .DOUBLE TO OBTAIN 26 USEC UNITS.      07360000
*...TU TIME VALUE NOW IN XTIME...                                       07380000
         SPACE                                                          07400000
         SPACE                                                          07460000
*...CONVERT TO ABS INTERVAL BASED ON 6 HR TOD                           07480000
         USING CVTSECT,XCVT                                             07500000
TLOCTST  L     XPSEUDO,CVTTPC      .GET ADDR OF PSEUDO CLOCKS      REFR 07520017
         DROP  XCVT                                                     07540000
         TM    RBGRSAV+0(XRB),TOD  .TEST FOR TOD OPTION            REFR 07546017
         BZ    TCHKMAX            .BR IF NOT TOD OPTION.                07552017
*        ABS INT = NEW TIME-(T4PC+LTPC+SHPC-TIMER)                      07560000
         L     XGR1,TIMER         .GET TIMER VALUE.                     07580000
         SRA   XGR1,1             .DEV 26 USEC UNITS.                   07600000
         LCR   XGR1,XGR1          .-TIMER.                              07620000
         AL    XGR1,VSHPC(XPSEUDO) .SHPC-TIMER.                         07640000
         AL    XGR1,VT4PC(XPSEUDO) .T4PC+SHPC-TIMER.                    07660000
         AL    XGR1,VLTPC(XPSEUDO) .LTPC+T4PC+SHPC-TIMER.               07680000
         L     XGR2,TM24          .SET UP COMPARAND OF 24 HRS.          07700000
         BC    12,*+8             .DID OVERFLOW OCCUR.                  07720000
         B     *+10               .BR IF YES.                           07740000
         CLR   XGR1,XGR2          .IS VALUE LESS THAN 24 HRS.           07760000
         BL    *+6                .BR IF YES.                           07780000
         SLR   XGR1,XGR2          .SUBTRACT 24 HR ADJUSTMENT.           07800000
         SLR   XTIME,XGR1         .NEW LTOD - CURRENT LTOD.             07820000
         BC    3,*+6              .BR IF NO UNDERFLOW OCCURRED.         07840000
         ALR   XTIME,XGR2         .ADD 24 HR ADJUSTMENT.                07860000
         SPACE                                                          07880000
TCHKMAX  CL    XTIME,TMAX         .CHECK FOR MAX VALUE EXCEEDED.        07900000
         BL    *+8                                                      07920000
         L     XTIME,TMAX         .USE MAX VALUE.                       07940000
         SPACE                                                          07960000
*...CHECK CURRENT STATUS OF TIMER ELEMENT...                            07980000
         L     XELM,TCBTME(0,XTCB)     .GET TQE ADDR FROM TCB.          08000000
         LTR   XELM,XELM          .IS THERE A TQE.                      08020000
         BC    8,TGETCORE         .BR IF NOT.                           08040000
         TM    TQEFLGS(XELM),OFFQ .IS TQE OFF QUEUE.                    08060000
         BO    TIRBTST            .BR IF YES.                           08080000
         SPACE                                                          08100000
*...ELM IS IN USE. CANCEL EXISTING INTERVAL.                            08120000
*  .USE SPECIAL ENTRY TO DEQUEUE RTN.                                   08140000
*  .SAVE REGS XTIME,XELM,XBASE,XRB.                                     08160000
*  .SAVE REGS XTIME,XELM,XBASE,XRB,XRETRN.                              08180000
         STM   14,5,RBEXTSAV(XRB) .SAVE REGS IN SVRB EXT SAVE AREA.     08200000
         LR    1,XELM             .SET ELM ADDR FOR DQ RTN.             08240000
         L     15,DQBASE          .EST ADDRESSABILITY FOR CANCEL RTN.   08260000
         L     XDQ,ADQSPCL             .GET ADDR OF CANCEL RTN.         08280000
         BALR  XDQ,XDQ            .TO DQ RTN TO CANCEL INTERVAL.        08300000
         LM    14,5,RBEXTSAV(XRB)  RESTORE REGISTERS           @SA62685 08320021
         B     TSTORTCB                                                 08340000
         SPACE                                                          08360000
TIRBTST  TM    TQEFLGS(XELM),EXIT+COMPLETE  .CHECK FOR EXIT AND COMPLT. 08380000
         BC    12,TSTORTCB+4           .BR IF NOT IN IRB FORMAT.        08400000
         TM    RBSTAB+1(XELM),ACTIRB .IS ELM AN ACTIVE IRB.             08420000
         BC    12,TMVSAADR             .BR IF NOT.                      08440000
         OI    RBSTAB+1(XELM),RBFDYN FLAG RB DYNAMIC               2647 08460018
         SPACE                                                          08480000
*...GET CORE FOR TQE...                                                 08500000
TGETCORE DS    0H                                                       08520000
         LR    XGR1,XTIME                                               08540000
         L     XGT0,SP250           SET UP TO GET CORE FOR S/A  36393   08570020
         ST    XRETRN,RBEXTSAV(XRB) SAVE RETURN ADDR             A36393 08572020
         BAL   XGR3,GETCORE        GO TO COMMON CORE RTE         A36393 08574020
         LR    XELM,X1                 SAVE REG SAVE AREA               08580000
         L     XGT0,SP243          SET UP TO CAORE FOR TQE       A36393 08590020
         BAL   XGR3,GETCORE        GO TO COMMON CORE RTE         A36393 08600020
         L     XRETRN,RBEXTSAV(XRB) RESTORE RETURN REG           A36393 08610020
         ST    X1,TCBTME(0,XTCB)       STORE TQE ADDR IN TCB            08620000
         ST    XELM,TQESAADR(0,X1)     STORE  SAVE AREA ADDR IN TQE     08640000
         LR    XELM,X1                 SET STD REG TO TQE ADDR          08660000
         SR    X1,X1                   CLEAR RIGHT HALF PSW             08680000
         ST    X1,TQEPSW+4(0,XELM)                                      08700000
         LR    XTIME,XGR1              .RESTORE TIME VALUE.             08720000
         B     TSTORTCB                                                 08740000
*                                                                       08750020
*             COMMON CORE GETTER ROUTINE                                08752020
*                                                                       08754020
GETCORE  LR    XPARA,XGT0          INDICATE GETMAIN ENTRY        A36393 08756020
         SVC   10 .                                           BH A53495 08758021
         BR    XGR3                RETURN TO CALLER                     08758820
*                                                                       08760000
TMVSAADR MVC   TQESAADR+1(3,XELM),TQEFLGS+1(XELM)     .REPLACE S/A ADR. 08780000
         SPACE                                                          08800000
TSTORTCB EQU   *                                                        08820000
         ST    XTCB,TQEFLGS(0,XELM)    .STORE TCB ADDR IN TQE.          08840000
         MVC   TQEFLGS(1,XELM),RBGRSAV+0(XRB)    .MOVE FLAG BYTE TO TQE 08860000
         OI    TQEFLGS(XELM),OFFQ                .FLAG TQE AS OFF QUEUE 08880000
         SPACE                                                          08900000
*...SET INTERVAL AND EXIT ADDRESS...                                    08920000
TSET     ST    XTIME,TQEVAL(0,XELM)    .STORE INTERVAL VALUE IN TQE.    08940000
         L     XEXIT,RBGRSAV(0,XRB)    .GET EXIT ADDR.                  08960000
         LA    XEXIT,0(0,XEXIT)        .CLEAR HI-ORDER BYTE.            08980000
         ST    XEXIT,TQEEXIT(0,XELM)   .STORE EXIT ADDR IN TQE.         09000000
         LTR   XEXIT,XEXIT        .IS THERE AN EXIT ADDR SPECIFIED.     09020000
         BZ    TMNQ               .BR IF NOT TO ENQUEUE.                09040000
         L     XGR2,RBLINK(0,XRB) .GET CALLER'S RB ADDR.                09060000
         MVC   TQEPSW(4,XELM),RBOPSW(XGR2)  .SAVE LH OF CALLER'S PSW.   09080000
         OI    TQEFLGS(XELM),EXIT .FLAG ELM AS HAVING EXIT.             09100000
         SPACE                                                          09120000
*...INTERFACE WITH ENQUEUE RTN...                                       09140000
TMNQ     LR    XNQPTR,XELM        .SET ELM ADDR FOR ENQUEUE RTN.        09160000
         LR    XGR2,XELM          .SAVE TQE ADDR OVER ENQUEUE.          09180000
         LR    XGR3,XRB           .SAVE RB ADDR OVER ENQUEUE.           09200000
         LR    XR7,XTCB                SAVE TCB ADR OVER ENQUEUE   MTS0 09210016
         USING CVTSECT,XCVT                                             09220000
         L     XNQ,CVTQTE00       .GET ADDR OF ENQUEUE RTN.             09240000
         DROP  XCVT                                                     09260000
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 09270017
         BALR  XNQ,XNQ            .TO ENQUEUING RTN.                    09280000
         USING *,XBASE                                                  09300000
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 09305017
         LR    XTCB,XR7                RESTORE TCB ADR             MTS0 09310016
         SPACE                                                          09320000
*...IMPLEMENT WAIT IF INDICATED...                                      09340000
         TM    TQEFLGS(XGR2),X'03'     .IS WAIT INDICATED.              09360000
        BCR   9,XRETRN                .BR IF NOT.                       09380000
         LA    XECB,TQEECB(0,XGR2)     .DEV ECB ADDR.                   09400000
         XC    TQEECB(4,XGR2),TQEECB(XGR2)  .ZERO ECB.                  09420000
         WAIT  1,ECB=(1)                                         A31487 09430020
         BR    XRETRN                    EXIT                    A31487 09440020
         SPACE 2                                                        09560000
*...ADDRESSES AND CONSTANTS UNIQUE TO STIMER...                         09580000
         SPACE                                                          09600000
         DS    0F                                                       09620000
AWAIT    DC    V(IGC001)     .ADDR OF WAIT.                             09640000
TMTUCNV  DC    X'7270E000'    .DECIMAL EQUIV=1,920,000,000.      A24887 09660019
*                                  USED TO DEVELPP 52 USEC UNITS A24887 09670019
*                                  FROM 10 MS (BIN) UNITS.EQUALS A24887 09671019
*                                  100,000 SECONDS/52 TO DEVELOP A24887 09672019
*                                  GREATEST ACCURACY.MUST DIV BY A24887 09673019
*                                  10,000,000                    A24887 09674019
TM10E7   DC    X'00989680'        .EQUALS 10,000,000. USED TO DEVELOP   09760000
*                                  52 USEC UNITS.                       09780000
TBINMAX  DC    X'0083D5FF'        .MAX BIN VALUE.                       09800000
TMAX     EQU   *                                                        09820000
TM24     DC    X'C5C10000'         .24 HR TU VALUE               A24887 09840019
TMTABLE  DC    F'360000'          .CONVERSION FACTORS TO DEV BIN UNITS  09860000
         DC    F'6000'             FROM DECIMAL FORMAT.                 09880000
         DC    F'100'                                                   09900000
         DC    F'1'                                                     09920000
         SPACE                                                          09940000
*...ADCONS SHARED BY TTIMER AND STIMER                                  09960000
ADQSPCL  DC    A(IEAQTD00)   .CANCEL DEQUEUE ROUTINE.                   09980000
DQBASE   DC    A(IEAQTD01+2) .ADDRESSABILITY FOR DEQUEUE RTN.           10000000
*                                                                       10002020
*                       CONSTANTS USED BY STIMER AND TTIMER  A36393     10004020
*                                                                       10006020
         DS    0F                                            A36393     10008020
SP250    DC    X'FA000048'        72 BYTES IN SP 250         A36393     10008420
SP243    DC    X'F3000070'        112 BYTES IN SP 243        A36393     10008820
ARMBRNCH DC    V(RMBRANCH)        BRANCH ENTRY TO FREEMAIN   A36393     10009220
IGC046A1 EQU   *                                                    MCH 10010019
         END                                                            10020000
