  TITLE 'IGC046-TTIMER AND STIMER FOR OPT 4 SYS WITH TODC'              00150020
IGC046   START 0                                                        00200020
*...THIS MODULE CONTAINS CODE FOR TTIMER AND STIMER SVC'S USING OPTION  00300020
*   6B AND THE TOD CLOCK. A FEW ADCONS ARE SHARE BY THE RTNS, AND 20071 00400020
*   REGISTER AND OFFSET                                                 00500020
*   SYMBOLISM IS SHARED BETWEEN THE TWO RTNS.                           00600020
         SPACE                                                          00700020
CVTSECT  DSECT                                                          00800020
         CVT                                                            00900020
         EJECT                                                          01000020
IGC046   CSECT                                                          01100020
         ENTRY IGC046A0                                             MCH 01200020
         ENTRY IGC046A1                                             MCH 01300020
IGC046A0 EQU   *                                                    MCH 01400020
*OWNERSHIP - 19472                                                  MCH 01500020
* A24887                                                                01600020
         SPACE                                                          01700020
*...REGISTERS USED BY TTIMER AND STIMER CODE...                         01800020
XDQ      EQU   2        .RETURN REG FROM DEQUEUE RTN.                   01900020
XCVT     EQU   3        .ADDR OF CVT.                                   02000020
XTCB     EQU   4        .ADDR OF CURRENT TCB.                           02100020
XRB      EQU   5        .ADDR OF CURRENT RB.                            02200020
XRETRN   EQU   14       .RETURN ADDR.                                   02300020
RCALC    EQU   13                                                 20071 02400020
RCALC1   EQU   12                                                 20071 02500020
         SPACE                                                          02600020
*...OFFSETS USED BY TTIMER AND STIMER CODE...                           02700020
VSHPC    EQU   0                FROM PSEUDO CLOCK PTR OF SHPC           02800020
VT4PC    EQU   4        .OFFSET FROM PSEUDO CLOCK PTR OF T4PC           02900020
VLTPC    EQU   8        .OFFSET FROM PSEUDO CLOCK PTR OF LTPC           03000020
SAVDISP  EQU   72                  .DISPLACEMENT FOR SAVING REG 10 REFR 03100020
         SPACE                                                          03200020
TQEFLGS  EQU   0        .TIMER ELM FLAGS.                               03300020
TQETCB   EQU   1        .TIMER ELM TCB.                                 03400020
TQEFLNK  EQU   4        .FORWARD LINK ADDR.                             03500020
TQEBLNK  EQU   8        .BACKWARD LINK ADDR.                            03600020
TQEVAL   EQU   12       .INTERVAL VALUE.                                03700020
TQEPSW   EQU   16       .PSW.                                           03800020
TQESAADR EQU   24            .S/A ADDR.                                 03900020
TQEEXIT  EQU   28       .ASYNCH. EXIT ADDR.                             04000020
TQEECB   EQU   96       .ECB AT END OF TQE.                             04100020
TQEWORK  EQU   X'20'     EXPCTD VAL OF TODC AT EXP OF INTV        20071 04200020
TQESYNC  EQU   X'24'                   SYNC BIT IS BIT 0          20071 04300020
SYNC     EQU   X'80'     IF ON THIS TQE IS SYNCHRONIZED           20071 04400020
S4       EQU   4                   NUMERIC EQUATE                20071  04500020
S7       EQU   7                   NUMERIC EQUATE                20071  04600020
S0       EQU   0                   NUMERIC EQUATE                20071  04700020
S3       EQU   3                   NUMERIC EQUATE                20071  04800020
X00      EQU   X'00'               CLEAR FLAG                    20071  04900020
X03      EQU   X'03'               TASK FLAG                     20071  05000020
         SPACE                                                          05100020
*...RB OFFSETS...                                                       05200020
RBSIZE   EQU   8        .RB SIZE.                                       05300020
RBSTAB   EQU   10       .RB STAB.                                       05400020
RBOPSW   EQU   16       .RB OLD PSW.                                    05500020
RBLINK   EQU   28       .RB LINK FIELD.                                 05600020
RBGRSAV  EQU   32       .1ST WORD OF RB REGISTER SAVE AREA (REG 0).     05700020
RBEXTSAV EQU   96       .1ST WORD OF RB EXTEND SAVE AREA.               05800020
         SPACE                                                          05900020
RBFDYN   EQU   X'02'    .DYNAMIC MASK.                                  06000020
         SPACE                                                          06100020
*...MISC EQUATES...                                                     06200020
TIMER    EQU   80       .HARDWARE TIMER.                                06300020
TCBTME   EQU   120      .TQE ADDR IN TCB.                               06400020
  TITLE 'IGC046- TTIMER FOR OPT 4 SYSTEMS WITH TODC'                    06550020
*...COMMENTARY FOR TTIMER...                                            06600020
         SPACE                                                          06700020
* ROUTINE NAME- IGC046,TTIMER SVC SERVICE ROUTINE.                      06800020
         SPACE                                                          06900020
* FUNCTION-    THIS CODE CALCULATES THE REMAINING TIME IN A TASK'S      07000020
*              INTERVAL AND LOADS THIS VALUE INTO REGISTER 0.           07100020
*              IF THE INTERVAL HAS NOT EXPIRED,REGISTER 1 IS LOADED     07200020
*              WITH EXIT ADDRESS (IF PRESENT) AND THE OPTION FLAGS.     07300020
*              WITH THE INFORMATION THUS PROVIDED, THE INTERVAL MAY BE  07400020
*              REESTABLISHED AFTER A 'TTIMER CANCEL' REQUEST.           07500020
*              THE OPTION FLAG RETURNED IS ALTERED TO INDICATE THE      07600020
*              'TUINTVL' OPTION TO CORRESPOND TO THE TIME UNITS         07700020
*              RETURNED IN REGISTER 1.                                  07800020
*              BEFORE A STIMER MACRO CAN BE GIVEN, THE TIME VALUE IN    07900020
*              REGISTER 1 MUST BE STORED INTO STORAGE AND THE ADDRESS   08000020
*              OF THE STORAGE LOCATION MUST BE PLACED INTO REGISTER 1.  08100020
         SPACE                                                          08200020
* ENTRY POINT NAME- IGC046                                              08300020
         SPACE                                                          08400020
* CONTAINED IN MODULE- IEAQST00                                         08500020
         SPACE                                                          08600020
* ATTRIBUTES-  RESIDENT,REENTRANT,SUPERVISOR STATE,I/O AND EXTERNAL     08700020
*              DISABLED,TYPE 1 SVC ROUTINE.                             08800020
         SPACE                                                          08900020
* APPLICABILITY- OPTION 4 SYSTEMS USING OPTION 6B AND TOD CLOCK.  20071 09000020
         SPACE                                                          09100020
* EXTERNAL REFERENCES- IEAQTD01, ENTRY POINT TO TIMER DEQUEUE RTN.      09200020
*                    - IEAQTD00, ENTRY POINT TO TIMER CANCEL RTN.       09300020
         SPACE                                                          09400020
* SVC USAGE-   NONE                                                     09500020
         SPACE                                                          09600020
* INPUT-       CANCEL OPTION SPECIFIED BY REG 1 NOT ZERO.               09700020
         SPACE                                                          09800020
* OUTPUT-      REMAINING TIME IN INTERVAL PLACED IN REG 0.              09900020
*              REGISTER 1 CONTAINS OPTION FLAG IN HI ORDER BYTE AND     10000020
*              EXIT ADDRESS IN LOW ORDER THREE BYTES.                   10100020
         SPACE                                                          10200020
* ENTRY POINT- .IGC046. ONLY ENTRY POINT IN CODE-GIVEN CONTROL BY SVC   10300020
*               FLIH.                                                   10400020
*              .THE PSW AT ENTRY MUST BE IN SUPERVISORY MODE & DISABLED 10500020
*               FOR I/O AND EXTERNAL INTERRUPTS AND HAVE SUPERVISORY    10600020
*               PROTECTION KEY.                                         10700020
*              .REG 1 CONTAINS THE CANCEL OPTION INDICATION             10800020
*              .REG 3 CONTAINS THE CVT ADDRESS.                         10900020
*              .REG 4 CONTAINS THE CURRENT TCB ADDRESS.                 11000020
*              .REG 5 CONTAINS THE CURRENT RB ADDRESS.                  11100020
*              .REG 14 CONTAINS THE ADDRESS OF TYPE 1 SVC EXIT.         11200020
*              .REGS 0,2,6-13 AND 15 ARE IRRELEVANT.                    11300020
         SPACE                                                          11400020
* EXIT POINT- .TO TYPE 1 SVC EXIT WHEN RTN IS COMPLETE.                 11500020
*             .THE PSW IS UNCHANGED FROM ENTRY.                         11600020
*              .REG 1 CONTAINS OPTION FLAG IN HI ORDER BYTE AND EXIT    11700020
*              ADDRESS IN LOW ORDER THREE BYTES.                        11800020
*              .REG 0 CONTAINS REMAINING TIME                           11900020
*             .REGISTERS 0-15 ARE VOLATILE.                             12000020
         SPACE                                                          12100020
*             .TO TIMER CANCEL ROUTINE.                                 12200020
*              THE PSW IS UNCHANGED FROM ENTRY.                         12300020
*              REG 1 CONTAINS TQE ADDRESS TO BE DEQUEUED.               12400020
*              REG 2 CONTAINS RETURN ADDRESS.                           12500020
*              REG 15 CONTAINS ADDRESSABILITY FOR CANCEL DEQUEUE RTN.   12600020
         SPACE                                                          12700020
* ERROR EXIT POINTS- NONE                                               12800020
         SPACE                                                          12900020
* TABLES AND CONTROL- .THE TCB OF THE CURRENT TASK TO OBTAIN THE        13000020
*  BLOCKS REFERENCED   TIMER QUEUE ELEMENT ADDRESS.                     13100020
*                     .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDRESS.      13200020
         SPACE                                                          13300020
* LIST ORIGINS,     .NONE                                               13400020
* TABLES, CONTROL                                                       13500020
* BLOCKS INCLUDED                                                       13600020
         SPACE                                                          13700020
* RESTRICTIONS-     .NONE                                               13800020
         SPACE                                                          13900020
* NOTES            IF THE CANCEL OPTION IS SPECIFIED, THE TQE AND       14000020
*                  SAVE AREA WILL BE FREED                              14100020
*                 THE FIRST WORD OF THE MIDNIGHT TQE              20071 14200020
*                 CONTAINS A POINTER TO X'20' BEFORE              20071 14300020
*                 AN EXTENSION TO THE TQE.  THIS EXTENSION        20071 14400020
*                 CONTAINS TWO WORDS.......                       20071 14500020
*                 THE FIRST IS USED TO CONTAIN THE MNIGHT VALUE   20071 14600020
*                 (THE EXPECTED VALUE OF THE HI-ORDER 32 BITS OF  20071 14700020
*                  THE TOD CLOCK AT THE NEXT MIDNIGHT)            20071 14800020
*                 THE SECOND IS USED TO CONTAIN THE SYNC BIT      20071 14900020
*                 (BIT ZERO OF THE FIRST BYTE)                    20071 15000020
*                 THE EXTRN FOR IEACLOCK IS A REFERENCE TO A      20071 15100020
*                 DOUBLE WORD IN THE PSEUDO CLOCK AREA USED       20071 15200020
*                 TO STORE THE TOD CLOCK VALUE WHEN NEEDED        20071 15300020
*                                                                       15400020
         SPACE 3                                                        15500020
*...REGISTERS UNIQUE TO IGC046 CODE...                                  15600020
XGT0     EQU   0        .WORK REG.                                      15700020
XPARA    EQU   1        .CONTAINS INPUT PARAM & REMAINING TIME ON EXIT. 15800020
XTPSEUDO EQU   9        .CONTAINS ADDR OF PSEUDO CLOCK.                 15900020
XELE     EQU   10       .CONTAINS ADDRESS OF TIMER QUEUE ELEMENT.       16000020
XFLAGS   EQU   11       .CONTAINS 1ST WORD OF TQE (IF ANY).             16100020
XWK      EQU   12            .WORK REG.                                 16200020
FLGREG   EQU   13                       INTERNAL FLAG REG               16300020
XTBASE   EQU   15       .BASE REG.                                      16400020
XR9      EQU   9                                                        16500020
XR7      EQU   7                                                        16600020
XR8      EQU   8                                                        16700020
XRC      EQU   12                                                 20071 16800020
         SPACE                                                          16900020
*...MISC...                                                             17000020
KEXP     EQU   X'88'                                                    17100020
TTIMSAV  EQU   X'4C'                                              20071 17200020
X0       EQU   0                                                  20071 17300020
         SPACE 1                                                        17400020
         EXTRN IEACLOCK                                           20071 17500020
         SPACE 1                                                        17600020
         BALR  XTBASE,0                                                 17700020
         USING *,XTBASE                                                 17800020
TTBASE   DS    0H                      LABEL FOR ADDRESSABILITY         17900020
         USING CVTSECT,XCVT                                        REFR 18000020
         L     XTPSEUDO,CVTTPC     .ADDRESS OF PSEUDO CLOCKS       REFR 18100020
         ST    XRETRN,TTIMSAV(XTPSEUDO)      SAVE RET REG IN TPC        18200020
         ICM   XELE,15,TCBTME(XTCB)   GET TQE ADRS FROM TCB       20071 18300020
         BC    S7,TESTEXP  BRANCH IF THERE IS A TQE               20071 18400020
TSET0   SR    X1,X1                   .CLEAR FLAG REG.                  18500020
         SR    XGT0,XGT0               .CLEAR REMAINING TIME REG.       18600020
TEXIT2   L     XTPSEUDO,CVTTPC     .ADDRESS OF PSEUDO CLOCKS       REFR 18700020
         L     XRETRN,TTIMSAV(XTPSEUDO)      .RESTORE RETURN REG        18800020
         BR    XRETRN                  .RETURN.                         18900020
         DROP  XCVT                                                REFR 19000020
         SPACE                                                          19100020
TESTEXP  IC    XFLAGS,TQEFLGS(0,XELE)  .PICK UP TQE 1ST WORD.           19200020
         TM    TQEFLGS(XELE),KEXP      .HAS INTERVAL EXPIRED.           19300020
         BC    14,TSET2                 BR IF NO                        19400020
         SR    FLGREG,FLGREG            CLEAR FOR LATER TEST            19500020
         ST    FLGREG,TCBTME(0,XTCB)    ZERO TQE POINTER                19600020
         LR    XR9,XTBASE               SET R 9 FOR ADDRESSABILITY      19700020
         LA    FLGREG,TSET0             SET PROPER EXIT FLAG            19800020
         BC    15,TSET1                 SKIP INTERVAL CODE              19900020
TSET2    EQU   *                                                        20000020
         SPACE                                                          20100020
*...DEVELOP REMAINING TIME IN INTERVAL...                               20200020
*...    = TOX - (SHPC - TIMER)                                          20300020
*...IF THE SYNC BIT IS SET TO ONE THE REMAINING INTERVAL          20071 20400020
*...IS CALCULATED AS FOLLOWS                                      20071 20500020
*...    TQEWORK - TODC                                            20071 20600020
         SPACE                                                          20700020
         USING CVTSECT,XCVT                                             20800020
         L     XTPSEUDO,CVTTPC    .GET ADDR OF PSEUDO CLOCKS.           20900020
         TM    TQESYNC(XELE),SYNC      IS SYNC BIT SET            20071 21000020
         BZ    TNORM                   NO - HANDLE AS NORMAL      20071 21100020
         L     XRC,CLOCKAD             GET ADRS OF STCK WORK AREA 20071 21200020
         STCK  0(XRC)                  GET CURRENT VALUE OF TODC  20071 21300020
         L     RCALC,TQEWORK(S0,XELE)  GET TQEWORK VALUE          20071 21400020
         SL    RCALC,X0(XRC)           CALCULATE TO 32 BITS       20071 21500020
*                                      TQEWORK-TODC               20071 21600020
         BC    S4,SYNCOVR              NO CARRY - INTVL PAST DUE  20071 21700020
         M     RCALC1,FOURTYTH         CONVERT TO 26 MS TU        20071 21800020
         LR    RCALC1,RCALC            PUT IN CORRECT REG         20071 21900020
         B     TCAN                    GO TEST FOR CANCEL OPTN    20071 22000020
TNORM    L     XWK,TIMER               .GET TIMER VALUE.          20071 22100020
         SRA   XWK,1                   .DEV 26 USEC UNITS.              22200020
         LCR   XWK,XWK                 .-TIMER                          22300020
         AL    XWK,VSHPC(0,XTPSEUDO)   .(SHPC-TIMER)                    22400020
         LCR   XWK,XWK                 .-(SHPC-TIMER)                   22500020
         AL    XWK,TQEVAL(0,XELE)      .TOX-(SHPC-TIMER)                22600020
         BC    3,*+6              .BR IF INTVL NOT PAST DUE.            22700020
SYNCOVR  SR    XWK,XWK             .SET REMAINING TIME TO ZERO.   20071 22800020
TCAN     LR    XR9,XTBASE          .LOAD REG FOR NEW BASE          REFR 22900020
         LTR   XPARA,XPARA        .TEST FOR CANCEL OPTION.        20071 23000020
         BC    8,TEXITX           .BR IF CANCEL NOT SPECIFIED.          23100020
         SPACE                                                          23200020
*...CANCEL INTERVAL...                                                  23300020
         SR    XGT0,XGT0                                                23400020
         ST    XGT0,TCBTME(0,XTCB)     ZERO TQE FIELD IN TCB            23500020
         LR    XPARA,XELE         .SET ELM ADDR IN REG FOR DEQUEUE.     23700020
         L     XDQ,ADQSPCL        .GET SPECIAL ENTRY TO DEQUEUE.        23800020
         L     XTPSEUDO,CVTTPC     .GET BASE FOR PSEUDO CLOCKS     REFR 23900020
         ST    XELE,SAVDISP(XTPSEUDO) .SAVE REG 10 IN TPC          REFR 24000020
         LR    XELE,XTPSEUDO       .BASE FOR PSEUDO CLOCKS         REFR 24100020
         LR    XR9,XTBASE          .LOAD REG FOR NEW BASE          REFR 24200020
         L     XTBASE,DQBASE      .SET DQ ADDRESSABILITY.               24300020
         BALR  XDQ,XDQ            .TO DEQUEUE RTN.                      24400020
         DROP  XTBASE                                                   24500020
         USING TTBASE,XR9                                               24600020
         LR    XELE,XPARA          RESTORE TQE ADDR            @SA63917 24700021
         LA    FLGREG,TEXITX            SET RETURN REG                  24800020
TSET1    EQU   *                                                        24900020
         L     XGT0,SP250              SET UP TO FREE TQE SAVE AREA     25000020
         L     XPARA,TQESAADR(0,XELE)  SP = 250, LN = 72 BYTES          25100020
         L     XR8,ARMBRNCH            BRANCH ENTRY TO FREEMAIN         25200020
         BALR  XRETRN,XR8                                               25300020
         L     XGT0,SP243              SET UP TO FREE TQE        20021  25400020
         LR    XPARA,XELE              SP = 243, LN = 112 BYTES   20021 25500020
         L     XR8,ARMBRNCH            BRANCH ENTRY TO FREEMAIN         25600020
         BALR  XRETRN,XR8                                               25700020
         LR    XTBASE,XR9              RESTORE BASE REG            REFR 25800020
         BCR   15,FLGREG               RETURN                           25900020
TEXITX   LR    XGT0,XWK               .SET INTVL IN REG.                26000020
         LA    X1,X'43'           .SET MASK.                            26100020
         NR    XFLAGS,X1         .SET FLAG TO INDICATE 'TUINTVL'.       26200020
         SLL   XFLAGS,24               .SHIFT FLAGS TO HI ORDER BYTE.   26300020
         ICM   XFLAGS,7,TQEEXIT+1(XELE)   SET EXIT ADRS           20071 26400020
         LR    X1,XFLAGS          .SET FLAG AND EXIT INFO IN REG 1.     26500020
         L     XCVT,CVTPTR         .GET ADDRESS OF CVT             REFR 26600020
         B     TEXIT2              .BRANCH TO EXIT                 REFR 26700020
         DROP  XCVT                                                     26800020
SECTU    DC    F'40265'                TU IN 1.04 SEC             20071 27600020
         DROP  XR9                                                      27700020
  TITLE 'IGC046- STIMER FOR OPT 4 SYSTEMS WITH TODC'                    27850020
*...COMMENTARY FOR STIMER...                                            27900020
         SPACE                                                          28000020
* ROUTINE NAME .IGC047- STIMER SVC SERVICE ROUTINE.                     28100020
         SPACE                                                          28200020
* FUNCTION-    .INITIALIZES AND QUEUES TIMER QUEUE ELEMENT (TQE) FOR    28300020
*               THE PURPOSE OF TIMING REQUESTED INTERVALS.              28400020
*              .PERFORMS CONVERSION TO TU'S WHEN INPUT TIME VALUE IS    28500020
*               IN BIN OR DEC UNITS.                                    28600020
*              .CHECKS WHETHER  TQE IS BEING USED AS IRB FOR PREVIOUSLY 28700020
*               SPECIFIED INTERVAL. IF SO, STIMER REQUEST IS IGNORED.   28800020
*              .CHECKS WHETHER TQE IS CURRENT IN USE. IF SO, EXISTING   28900020
*               INTERVAL IS CANCELLED AND NEW INTERVAL INSTATED.        29000020
         SPACE                                                          29100020
* ENTRY POINT NAME  .IGC047                                             29200020
         SPACE                                                          29300020
* CONTAINED IN MODULE- IEAQST00                                         29400020
         SPACE                                                          29500020
* ATTRIBUTES   .TYPE 2 SVC RTN.,RESIDENT,REENTRANT,SUPERVISOR STATE,    29600020
*               I/O AND EXTERNAL DISABLED.                              29700020
         SPACE                                                          29800020
* APPLICABILITY- OPTION 4 SYSTEMS USING OPTION 6B WITH TOD CLOCK. 20071 29900020
         SPACE                                                          30000020
* EXTERNAL REFERENCES-  .IEAQTD01, ENTRY POINT TO TIMER DEQUEUE RTN.    30100020
*                       .IEAQTD00, CANCEL DEQUEUE ENTRY POINT           30200020
         SPACE                                                          30300020
* SVC USAGE    .WAIT- ECB IN TQEECB.                                    30400020
*              .GETMAIN- SUBPOOL 250.                                   30500020
*              .GETMAIN- SUBPOOL 253.                                   30600020
         SPACE                                                          30700020
* INPUT        .REG 0 CONTAINS OPTION FLAGS IN HI ORDER BYTE AND EXIT   30800020
*               ADDR. IN LOW ORDER 3 BYTES.                             30900020
*              .REG 1 CONTAINS THE ADDRESS OF THE TIME VALUE.           31000020
*              .THE LEFT HALF OF THE PSW STORED IN THE SVRB (RBOPSW)    31100020
*               OF THE STIMER CODE.                                     31200020
         SPACE                                                          31300020
* OUTPUT       .AN INITIALIZED AND QUEUED TQE.                          31400020
         SPACE                                                          31500020
* ENTRY POINTS .IGC047, ENTRY FROM SVC FLIH.                            31600020
*              .REG 0 CONTAINS OPTION FLAG AND EXIT ADDRESS.            31700020
*              .REG 1 CONTAINS ADDR OF TIME VALUE.                      31800020
*              .REG 3 CONTAINS CVT ADDR                                 31900020
*              .REG 4 CONTAINS CURRENT TCB ADDR.                        32000020
*              .REG 5 CONTAINS CURRENT RB ADDR.                         32100020
*              .REGS 2,6-13, & 15 ARE IRRELEVANT.                       32200020
*              .REG 14 CONTAINS ADDR OF SVC 3 (TYPE 2 EXIT)             32300020
*              .THE PSW IS IN SUPERVISOR STATE AND IS I/O AND EXTERNAL  32400020
*               DISABLED AND HAS SUPERVISOR PROTECTION KEY.             32500020
         SPACE                                                          32600020
* EXIT POINTS  .TO TYPE 2 EXIT VIA BR 14                                32700020
*              .THE PSW STATUS IS UNCHANGED                             32800020
*              .REG 14 CONTAINS THE EXITING ADDR. OTHER REGS ARE        32900020
*               MEANINGLESS.                                            33000020
*              REGS 0-13, & 15 ARE VOLATILE OVER STIMER.                33100020
*              REG 14 IS TRANSPARENT.                                   33200020
         SPACE                                                          33300020
* ERROR EXIT POINTS .NONE                                               33400020
         SPACE                                                          33500020
* TABLES & CONTROL  .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDR AND        33600020
* BLOCKS REFERENCED  TIMER DEQUEUE AN TIMER ENQUEUE RTNS.               33700020
*                   .THE CURRENT TCB TO OBTAIN THE TQE ADDR.            33800020
*                   .THE CURRENT RB TO REFERENCE INPUT REGS 0 & 1 WHICH 33900020
*                    ARE SAVED IN THE RBGRSAV AREA AND THE PSW IN       34000020
*                    EFFECT WHEN THE SVC WAS ISSUED. ALSO, AN EXTENDED  34100020
*                    SAVE AREA APPENDED TO THE SVRB IS USED FOR AN ECB. 34200020
*                    A WORK AREA FOR A PACK INSTRUCTION, AND AS TEMP.   34300020
*                    REGISTER STORAGE OVER THE TIMER DEQUEUE RTN.       34400020
*                   .THE TQE IS REFERENCED AND INITIALIZED FOR THE NEW  34500020
*                    INTERVAL.                                          34600020
         SPACE                                                          34700020
* LIST ORIGINS,TABLES    .A CONVERSION TABLE TMTABLE FOR CONVERTING     34800020
* & CONTROL BLOCKS        DEC DIGITS TO BIN UNITS.                      34900020
* INCLUDED                                                              35000020
         SPACE                                                          35100020
         SPACE                                                          35200020
* NOTES        NOTE CVB INSTRUCTION DEPENDS UPON RBEXTSAV+0 TO BE ON A  35300020
*              DOUBLE WORD BOUNDARY.                                    35400020
*                 THE FIRST WORD OF THE MIDNIGHT TQE              20071 35500020
*                 CONTAINS A POINTER TO X'20' BEFORE              20071 35600020
*                 AN EXTENSION TO THE TQE.  THIS EXTENSION        20071 35700020
*                 CONTAINS TWO WORDS.......                       20071 35800020
*                 THE FIRST IS USED TO CONTAIN THE MNIGHT VALUE   20071 35900020
*                 (THE EXPECTED VALUE OF THE HI-ORDER 32 BITS OF  20071 36000020
*                  THE TOD CLOCK AT THE NEXT MIDNIGHT)            20071 36100020
*                 THE SECOND IS USED TO CONTAIN THE SYNC BIT      20071 36200020
*                 (BIT ZERO OF THE FIRST BYTE)                    20071 36300020
*                 THE EXTERN FOR IEACLOCK IS A REFERENCE TO A     20071 36400020
*                 DOUBLE WORD IN THE PSEUDO CLOCK AREA USED       20071 36500020
*                 TO STORE THE TOD CLOCK VALUE WHEN NEEDED        20071 36600020
         SPACE 3                                                        36700020
*...REGISTERS UNIQUE TO STIMER CODE...                                  36800020
XPARA0   EQU   0                                                        36900020
X1       EQU   1                                                        37000020
XTIME    EQU   1                                                        37100020
XNQPTR   EQU   1                                                        37200020
XECB     EQU   1                                                        37300020
XBASE    EQU   2                                                        37400020
XNQ      EQU   2                                                        37500020
XLPCTL   EQU   9                                                        37600020
XPSEUDO  EQU   9                                                        37700020
XGR2     EQU   10                                                       37800020
XINCR    EQU   10                                                       37900020
XGR3     EQU   11                                                       38000020
XCMPR    EQU   XINCR+1                                                  38100020
XPRD     EQU   12                                                       38200020
XELM     EQU   12                                                       38300020
XCAND    EQU   XPRD+1                                                   38400020
XGR1     EQU   13                                                       38500020
XEXIT    EQU   13                                                       38600020
XTMPTR   EQU   15                                                       38700020
REG      EQU   7                   REGISTER EQUATE                20071 38800020
REGP1    EQU   REG-1               REGISTER EQUATE                20071 38900020
XTIMEP1  EQU   XTIME-1             REGISTER EQUATE                20071 39000020
SAV      EQU   6                   REGISTER EQUATE                20071 39100020
XRA      EQU   10                  REGISTER EQUATE                20071 39200020
SAVTIM   EQU   13                  REGISTER EQUATE                20071 39300020
         SPACE                                                          39400020
*...MASKS FOR TESTING FLAGS...                                          39500020
*   INPUT FLAGS                                                         39600020
DINTVL   EQU   X'30'         .DECIMAL OPTION                            39700020
TOD      EQU   X'40'         .TOD OPTION                                39800020
         SPACE                                                          39900020
*   TQE FLAGS                                                           40000020
EXIT     EQU   X'04'    .EXIT MASK                                      40100020
OFFQ     EQU   X'80'    .OFF QUEUE MASK                                 40200020
WAIT     EQU   X'01'    .WAIT OPTION MASK                               40300020
COMPLETE EQU   X'88'    .COMPLETION MASK                                40400020
         SPACE                                                          40500020
*   MISC                                                                40600020
ACTIRB   EQU   X'40'                                                    40700020
MNIGHT   EQU   X'20'                                              20071 40800020
MIDELM   EQU   X'28'                                              20071 40900020
         SPACE                                                          41000020
         SPACE                                                          41100020
         ENTRY IGC047                                                   41200020
         EXTRN IEAQTD00,IEAQTD01                                        41300020
         SPACE                                                          41400020
IGC047   DS    0D                                                       41500020
         BALR  XBASE,0                                                  41600020
         USING *,XBASE                                                  41700020
*...NOTE THAT INPUT PARAMETER REGS 0 & 1 ARE SAVED IN THE SVRB SAVE     41800020
*   AREA AT SVRB+32 & SVRB+36 RESPECTIVELY.                             41900020
         TM    RBGRSAV+0(XRB),DINTVL .TEST FOR DECIMAL OPTION.          42000020
         BC    12,TLDTIME         .BR IF NOT DECIMAL OPTION.            42100020
         SPACE                                                          42200020
*...CONVERT DEC. VALUE TO BIN UNITS...                                  42300020
         LR    XTMPTR,XTIME       .LOAD REG WITH ADDR OF TIME VALUE     42400020
         SR    XLPCTL,XLPCTL      .INITIALIZE CONVERSION LOOP.          42500020
         SR    XTIME,XTIME                                              42600020
         LA    XINCR,4                                                  42700020
         LA    XCMPR,16                                                 42800020
TMDECLP  BXH   XLPCTL,XINCR,TMCNVTU .LOOP 4 TIMES BEFORE BRANCHING.     42900020
         PACK  RBEXTSAV+0(8,XRB),0(2,XTMPTR) .PACK 2 DEC DIGITS.        43000020
         OI    RBEXTSAV+7(XRB),X'0F'   .INSURE THAT SIGN IS PRESENT.    43100020
         CVB   XCAND,RBEXTSAV+0(XRB) .CONVERT 2 DIGITS TO BINARY UNITS. 43200020
         M     XPRD,TMTABLE-4(XLPCTL) .EXPAND TO BIN UNITS.             43300020
         ALR   XTIME,XCAND        .ACCUM BIN TIME UNITS.                43400020
         LA    XTMPTR,2(XTMPTR)   .REF NEXT TWO DIGITS.                 43500020
         B     TMDECLP                                                  43600020
         SPACE                                                          43700020
*...TUINTVL OR BINTVL OPTIONS...                                        43800020
TLDTIME  L     XTIME,0(XTIME)     .GET TIME VALUE.                      43900020
         BZ    TLOCTST            .BR IF TUINTVL OPTION.                44000020
         SPACE                                                          44100020
*...CONVERT BIN UNITS TO TU'S...                                        44200020
TMCNVTU  CL    XTIME,TBINMAX       CHECK FOR EXCESSIVE BIN VALUE        44300020
         BNH   *+8                                                      44400020
         L     XTIME,TBINMAX      .USE MAX BIN VALUE.                   44500020
         M     XPARA0,TMTUCNV     .CONVERT TO 52 USEC UNITS.            44600020
         D     XPARA0,TM10E7                                            44700020
         ALR   XTIME,XTIME        .DOUBLE TO OBTAIN 26 USEC UNITS.      44800020
*...TU TIME VALUE NOW IN XTIME...                                       44900020
         SPACE                                                          45000020
         SPACE                                                          45100020
*...CONVERT TO ABS INTERVAL BASED ON 6 HR TOD                           45200020
         USING CVTSECT,XCVT                                             45300020
TLOCTST  L     XPSEUDO,CVTTPC      .GET ADDR OF PSEUDO CLOCKS      REFR 45400020
         DROP  XCVT                                                     45500020
         TM    RBGRSAV+0(XRB),TOD  .TEST FOR TOD OPTION            REFR 45600020
         BZ    TCHKMAX            .BR IF NOT TOD OPTION.                45700020
*  HAVE TU REQUESTED IN REG 1                                     20071 45800020
*  TO GET AN ABSOLUTE INTERVAL MUST CALCULATE                     20071 45900020
*  TAM - TOD                                                      20071 46000020
*  TAM = REQUESTED TU PAST LAST MIDNIGHT                          20071 46100020
*  TOD = ACTUAL TU ALREADY EXPIRED SINCE LAST MIDNIGHT            20071 46200020
         SPACE 2                                                        46300020
         L     XR8,CLOCKAD             GET ADRS OF STCK WORK AREA 20071 46400020
*        THE FIRST WORD OF THE MIDNIGHT ELEMENT POINTS TO         20071 46500020
*        X'20' BEFORE AN EXTENSION WHICH CONTAINS THE MNIGHT      20071 46600020
*        FIELD AND THE SYNC BIT                                   20071 46700020
         L     XRA,MIDELM(XPSEUDO)     GET ADRS TO DUMMY ELEM     20071 46800020
         STCK  0(XR8)                  GET THE VALUE OF THE TODC  20071 46900020
         L     REG,MNIGHT(XRA)         GET MNIGHT VALUE           20071 47000020
         LR    SAV,REG                 SAVE VALUE                 20071 47100020
REDO     SL    REG,X0(XR8)             CALC MNIGHT-TODC           20071 47200020
         BC    S3,TOK                  IF CARRY, OK - BRANCH      20071 47300020
         AL    SAV,TWNT4HRS            RESULT NEG - ADD 1 DAY     20071 47400020
*                                      TO MNIGHT VAL              20071 47500020
         LR    REG,SAV                 *                          20071 47600020
         B     REDO                    DO CALC AGAIN              20071 47700020
TOK      LCR   REG,REG                 -(MNIGHT-CLOCK)            20071 47800020
         A     REG,TWNT4HRS            82397-(MNIGHT-CLOCK)       20071 47900020
         M     REGP1,FOURTYTH        (82397-(MNIGHT-CLOCK))*40265 20071 48000020
*  NOW HAVE TOD VALUE IN REG                                      20071 48100020
         SLR   XTIME,REG               TAM-TOD                    20071 48200020
         BC    S3,TOK2                 IF CARRY  OK  BRANCH       20071 48300020
         AL    XTIME,TM24         ADD 24 HRS TO GET CORRECT INTV  20071 48400020
TOK2     EQU   *                                                  20071 48500020
         SPACE                                                          48600020
TCHKMAX  CL    XTIME,TMAX         .CHECK FOR MAX VALUE EXCEEDED.        48700020
         BL    *+8                                                      48800020
         L     XTIME,TMAX         .USE MAX VALUE.                       48900020
         SPACE                                                          49000020
*...CHECK CURRENT STATUS OF TIMER ELEMENT...                            49100020
         L     XELM,TCBTME(0,XTCB)     .GET TQE ADDR FROM TCB.          49200020
         LTR   XELM,XELM          .IS THERE A TQE.                      49300020
         BC    8,TGETCORE         .BR IF NOT.                           49400020
         TM    TQEFLGS(XELM),OFFQ .IS TQE OFF QUEUE.                    49500020
         BO    TIRBTST            .BR IF YES.                           49600020
         SPACE                                                          49700020
*...ELM IS IN USE. CANCEL EXISTING INTERVAL.                            49800020
*  .USE SPECIAL ENTRY TO DEQUEUE RTN.                                   49900020
*  .SAVE REGS XTIME,XELM,XBASE,XRB.                                     50000020
*  .SAVE REGS XTIME,XELM,XBASE,XRB,XRETRN.                              50100020
         STM   14,5,RBEXTSAV(XRB) .SAVE REGS IN SVRB EXT SAVE AREA.     50200020
         LR    1,XELM             .SET ELM ADDR FOR DQ RTN.             50400020
         L     15,DQBASE          .EST ADDRESSABILITY FOR CANCEL RTN.   50500020
         L     XDQ,ADQSPCL             .GET ADDR OF CANCEL RTN.         50600020
         BALR  XDQ,XDQ            .TO DQ RTN TO CANCEL INTERVAL.        50900020
         LM    14,5,RBEXTSAV(XRB)  RESTORE REGISTERS           @SA62685 51000021
         B     TSTORTCB                                                 51100020
         SPACE                                                          51200020
TIRBTST  TM    TQEFLGS(XELM),EXIT+COMPLETE  .CHECK FOR EXIT AND COMPLT. 51300020
         BC    12,TSTORTCB+4           .BR IF NOT IN IRB FORMAT.        51400020
         TM    RBSTAB+1(XELM),ACTIRB .IS ELM AN ACTIVE IRB.             51500020
         BC    12,TMVSAADR             .BR IF NOT.                      51600020
         OI    RBSTAB+1(XELM),RBFDYN FLAG RB DYNAMIC               2647 51700020
         SPACE                                                          51800020
*...GET CORE FOR TQE...                                                 51900020
TGETCORE DS    0H                                                       52000020
         LR    XGR1,XTIME                                               52100020
         ST    XRETRN,RBEXTSAV(XRB) SAVE RETURN ADDR             A36393 52150020
         L     XGT0,SP250          SET UP TO GET CORE FOR S/A    A36393 52160020
         BAL   XGR3,GETCORE        GO TO COMMON CORE GETTER RTE  A36393 52200020
         LR    XELM,X1                 SAVE REG SAVE AREA               52300020
         L     XGT0,SP243          SET UP TO GET CORE FOR TQE 36393     52350020
         BAL   XGR3,GETCORE        GO TO COMMON CORE GETTER RTE  36393  52400020
         L     XRETRN,RBEXTSAV(XRB) RESTORE RETURN ADDR          A36393 52450020
         ST    X1,TCBTME(0,XTCB)       STORE TQE ADDR IN TCB            52500020
         ST    XELM,TQESAADR(0,X1)     STORE  SAVE AREA ADDR IN TQE     52600020
         LR    XELM,X1                 SET STD REG TO TQE ADDR          52700020
         SR    X1,X1                   CLEAR RIGHT HALF PSW             52800020
         ST    X1,TQEPSW+4(0,XELM)                                      52900020
         LR    XTIME,XGR1              .RESTORE TIME VALUE.             53000020
         B     TSTORTCB                                                 53100020
*                                                                       53150020
*              COMMON GET CORE ROUTINE        A36393                    53160020
*                                                                       53170020
GETCORE  LR    XPARA,XGT0          INDICATE GETMAIN ENTRY        A36393 53180020
         SVC   10                  GO GET THE CORE             BH 53495 53190021
         BR    XGR3                RETURN TO CALLER              A36393 53194020
*                                                                       53200020
TMVSAADR MVC   TQESAADR+1(3,XELM),TQEFLGS+1(XELM)     .REPLACE S/A ADR. 53300020
         SPACE                                                          53400020
TSTORTCB EQU   *                                                        53500020
         ST    XTCB,TQEFLGS(0,XELM)    .STORE TCB ADDR IN TQE.          53600020
         MVC   TQEFLGS(1,XELM),RBGRSAV+0(XRB)    .MOVE FLAG BYTE TO TQE 53700020
         OI    TQEFLGS(XELM),OFFQ                .FLAG TQE AS OFF QUEUE 53800020
         SPACE                                                          53900020
*...SET INTERVAL AND EXIT ADDRESS...                                    54000020
TSET     NI    TQESYNC(XELM),X00       CLEAR HI BYTE (SYNC BIT)   20071 54100020
         LR    SAVTIM,XTIME       SAVE INTVL VALUE REQUESTED      20071 54200020
         TM    TQEFLGS(XELM),X03       IS THIS A 'TASK' REQST     20071 54300020
         BZ    NOSYNC                  YES - CAN NOT BE SYNC'ED   20071 54400020
         L     XR8,CLOCKAD             GET ADRS OF CLOCK WRKARA   20071 54500020
         STCK  0(XR8)                  GET CURRENT VAL OF TODC    20071 54600020
         SR    XTIMEP1,XTIMEP1         ZERO FOR DIV               20071 54700020
         D     XTIMEP1,FOURTYTH      GET INTRVL IN 1.04 SEC UNITS 20071 54800020
         AL    XTIME,X0(XR8)            ADD AND STORE AS          20071 54900020
         ST    XTIME,TQEWORK(S0,XELM)  TQEWORK                    20071 55000020
         CL    SAVTIM,ONEHR       IS INTVL GT ONE HR              20071 55100020
         BNH   NOSYNC             NO, DO NOT SYNC THE TQE         20071 55200020
         L     SAVTIM,ONEHR       SET INTVL TO ONE HR             20071 55300020
         OI    TQESYNC(XELM),SYNC    TURN ON SYNC BIT             20071 55400020
NOSYNC   EQU   *                                                  20071 55500020
         ST    SAVTIM,TQEVAL(S0,XELM) PUT TIME IN TQE             20071 55600020
         SR    XEXIT,XEXIT         ZERO FOR EXIT ADRS             20071 55700020
         ICM   XEXIT,7,RBGRSAV+1(XRB)  GET EXIT ADRS              20071 55800020
         ST    XEXIT,TQEEXIT(XELM) STORE IN TQE                   20071 55900020
         BZ    TMNQ              IF ZERO  BRANCH                  20071 56000020
         L     XGR2,RBLINK(0,XRB) .GET CALLER'S RB ADDR.                56100020
         MVC   TQEPSW(4,XELM),RBOPSW(XGR2)  .SAVE LH OF CALLER'S PSW.   56200020
         OI    TQEFLGS(XELM),EXIT .FLAG ELM AS HAVING EXIT.             56300020
         SPACE                                                          56400020
*...INTERFACE WITH ENQUEUE RTN...                                       56500020
TMNQ     LR    XNQPTR,XELM        .SET ELM ADDR FOR ENQUEUE RTN.        56600020
         LR    XGR2,XELM          .SAVE TQE ADDR OVER ENQUEUE.          56700020
         LR    XGR3,XRB           .SAVE RB ADDR OVER ENQUEUE.           56800020
         LR    XR7,XTCB                SAVE TCB ADR OVER ENQUEUE   MTS0 56900020
         USING CVTSECT,XCVT                                             57000020
         L     XNQ,CVTQTE00       .GET ADDR OF ENQUEUE RTN.             57100020
         DROP  XCVT                                                     57200020
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 57300020
         BALR  XNQ,XNQ            .TO ENQUEUING RTN.                    57400020
         USING *,XBASE                                                  57500020
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 57600020
         LR    XTCB,XR7                RESTORE TCB ADR             MTS0 57700020
         SPACE                                                          57800020
*...IMPLEMENT WAIT IF INDICATED...                                      57900020
         TM    TQEFLGS(XGR2),X'03'     .IS WAIT INDICATED.              58000020
        BCR   9,XRETRN                .BR IF NOT.                       58100020
         LA    XECB,TQEECB(0,XGR2)     .DEV ECB ADDR.                   58200020
         XC    TQEECB(4,XGR2),TQEECB(XGR2)   .ZERO ECB                  58300020
         WAIT  1,ECB=(1)           ISSUE WAIT                    A31487 58400020
         BR    XRETRN              RETURN                        A31487 58500020
         EJECT                                                          58600020
*...ADDRESSES AND CONSTANTS UNIQUE TO STIMER...                         58700020
         SPACE                                                          58800020
         DS    0F                                                       58900020
TMTUCNV  DC    X'7270E000'    .DECIMAL EQUIV=1,920,000,000.      A24887 59000020
*                                  USED TO DEVELPP 52 USEC UNITS A24887 59100020
*                                  FROM 10 MS (BIN) UNITS.EQUALS A24887 59200020
*                                  100,000 SECONDS/52 TO DEVELOP A24887 59300020
*                                  GREATEST ACCURACY.MUST DIV BY A24887 59400020
*                                  10,000,000                    A24887 59500020
TM10E7   DC    X'00989680'        .EQUALS 10,000,000. USED TO DEVELOP   59600020
*                                  52 USEC UNITS.                       59700020
TBINMAX  DC    X'0083D5FF'        .MAX BIN VALUE.                       59800020
TMAX     EQU   *                                                        59900020
TM24     DC    X'C5C10000'         .24 HR TU VALUE    20071      A24887 60000020
TMTABLE  DC    F'360000'          .CONVERSION FACTORS TO DEV BIN UNITS  60100020
         DC    F'6000'             FROM DECIMAL FORMAT.                 60200020
         DC    F'100'                                                   60300020
         DC    F'1'                                                     60400020
FOURTYTH DC    F'40265'                TU IN 1.04 SEC             20071 60500020
TWNT4HRS DC    F'82397'                1.04 SEC UNITS IN A DAY    20071 60600020
ONEHR    DC    F'138240000'            TU IN ONE HR               20071 60700020
         SPACE                                                          60800020
*...ADCONS SHARED BY TTIMER AND STIMER                                  60900020
ADQSPCL  DC    A(IEAQTD00)   .CANCEL DEQUEUE ROUTINE.                   61000020
DQBASE   DC    A(IEAQTD01+2) .ADDRESSABILITY FOR DEQUEUE RTN.           61100020
CLOCKAD  DC    A(IEACLOCK)             ADDRESS OF STCK WORK AREA  20071 61200020
*                       CONSTANTS USED BY BOTH STIMER AND TTIMER  36393 61250020
*                                                                       61260020
*                                                                       61270020
         DS    0F                                                       61280020
SP250    DC    X'FA000048'        72 BYTES IN SP 250                    61290020
SP243    DC    X'F3000070'        112 BYTES IN SP 243                   61292020
ARMBRNCH DC    V(RMBRANCH)        BRANCH ENTRY TO FREEMAIN              61294020
IGC046A1 EQU   *                                                    MCH 61300020
         END                                                            61400020
