         TITLE '   TTIMER AND STIMER FOR OPTION 4 SYSTEMS'              00100017
IGC046   START 0                                                        00200017
*...THIS MODULE CONTAINS CODE FOR TTIMER AND STIMER SVC'S USING OPTION  00300017
*   6B. A FEW ADCONS ARE SHARE BY THE RTNS, AND REGISTER AND OFFSET     00400017
*   SYMBOLISM IS SHARED BETWEEN THE TWO RTNS.                           00500017
         SPACE                                                          00600017
CVTSECT  DSECT                                                          00700017
         CVT                                                            00800017
         EJECT                                                          00900017
         IEAQFX 65,MCH,M65MP                                            01000017
         EJECT                                                          01100017
IGC046   CSECT                                                          01200017
         ENTRY IGC046A0                                             MCH 01250019
         ENTRY IGC046A1                                             MCH 01300019
IGC046A0 EQU   *                                                    MCH 01350019
*OWNERSHIP - 19472                                                  MCH 01450019
*495000-500000                                                   A26059 01550019
* A24887                                                                01560019
*...REGISTERS USED BY TTIMER AND STIMER CODE...                         01700017
XDQ      EQU   2        .RETURN REG FROM DEQUEUE RTN.                   01800017
XCVT     EQU   3        .ADDR OF CVT.                                   01900017
XTCB     EQU   4        .ADDR OF CURRENT TCB.                           02000017
XRB      EQU   5        .ADDR OF CURRENT RB.                            02100017
XRETRN   EQU   14       .RETURN ADDR.                                   02200017
         SPACE                                                          02300017
*...OFFSETS USED BY TTIMER AND STIMER CODE...                           02400017
VSHPC    EQU   0        .OFFSET FROM PSEUDO CLOCK PTR OF SHPC           02500017
VT4PC    EQU   4        .OFFSET FROM PSEUDO CLOCK PTR OF T4PC           02600017
VLTPC    EQU   8        .OFFSET FROM PSEUDO CLOCK PTR OF LTPC           02700017
SAVDISP  EQU   72                  .DISPLACEMENT FOR SAVING REG 10 REFR 02800017
         SPACE                                                          02900017
TQEFLGS  EQU   0        .TIMER ELM FLAGS.                               03000017
TQETCB   EQU   1        .TIMER ELM TCB.                                 03100017
TQEFLNK  EQU   4        .FORWARD LINK ADDR.                             03200017
TQEBLNK  EQU   8        .BACKWARD LINK ADDR.                            03300017
TQEVAL   EQU   12       .INTERVAL VALUE.                                03400017
TQEPSW   EQU   16       .PSW.                                           03500017
TQESAADR EQU   24            .S/A ADDR.                                 03600017
TQEEXIT  EQU   28       .ASYNCH. EXIT ADDR.                             03700017
TQEECB   EQU   96       .ECB AT END OF TQE.                             03800017
         SPACE                                                          03900017
*...RB OFFSETS...                                                       04000017
RBSIZE   EQU   8        .RB SIZE.                                       04100017
RBSTAB   EQU   10       .RB STAB.                                       04200017
RBOPSW   EQU   16       .RB OLD PSW.                                    04300017
RBLINK   EQU   28       .RB LINK FIELD.                                 04400017
RBGRSAV  EQU   32       .1ST WORD OF RB REGISTER SAVE AREA (REG 0).     04500017
RBEXTSAV EQU   96       .1ST WORD OF RB EXTEND SAVE AREA.               04600017
         SPACE                                                          04700017
RBFDYN   EQU   X'02'    .DYNAMIC MASK.                                  04800017
         SPACE                                                          04900017
*...MISC EQUATES...                                                     05000017
TCBTME   EQU   120      .TQE ADDR IN TCB.                               05100017
         TITLE '        TTIMER FOR OPTION 4 SYSTEMS'                    05200017
*...COMMENTARY FOR TTIMER...                                            05300017
         SPACE                                                          05400017
* ROUTINE NAME- IGC046,TTIMER SVC SERVICE ROUTINE.                      05500017
         SPACE                                                          05600017
* FUNCTION-    THIS CODE CALCULATES THE REMAINING TIME IN A TASK'S      05700017
*              INTERVAL AND LOADS THIS VALUE INTO REGISTER 0.           05760017
*              IF THE INTERVAL HAS NOT EXPIRED,REGISTER 1 IS LOADED     05860017
*              WITH EXIT ADDRESS (IF PRESENT) AND THE OPTION FLAGS.     06000017
*              WITH THE INFORMATION THUS PROVIDED, THE INTERVAL MAY BE  06100017
*              REESTABLISHED AFTER A 'TTIMER CANCEL' REQUEST.           06200017
*              THE OPTION FLAG RETURNED IS ALTERED TO INDICATE THE      06300017
*              'TUINTVL' OPTION TO CORRESPOND TO THE TIME UNITS         06400017
*              RETURNED IN REGISTER 1.                                  06500017
*              BEFORE A STIMER MACRO CAN BE GIVEN, THE TIME VALUE IN    06600017
*              REGISTER 1 MUST BE STORED INTO STORAGE AND THE ADDRESS   06700017
*              OF THE STORAGE LOCATION MUST BE PLACED INTO REGISTER 1.  06800017
         SPACE                                                          06900017
* ENTRY POINT NAME- IGC046                                              07000017
         SPACE                                                          07100017
* CONTAINED IN MODULE- IEAQST00                                         07200017
         SPACE                                                          07300017
* ATTRIBUTES-  RESIDENT,REENTRANT,SUPERVISOR STATE,I/O AND EXTERNAL     07400017
*              DISABLED,TYPE 1 SVC ROUTINE.                             07500017
         SPACE                                                          07600017
* APPLICABILITY- OPTION 4 SYSTEMS USING OPTION 6B.                      07700017
         SPACE                                                          07800017
* EXTERNAL REFERENCES- IEAQTD01, ENTRY POINT TO TIMER DEQUEUE RTN.      07900017
*                    - IEAQTD00, ENTRY POINT TO TIMER CANCEL RTN.       08000017
         SPACE                                                          08100017
* SVC USAGE-   NONE                                                     08200017
         SPACE                                                          08300017
* INPUT-       CANCEL OPTION SPECIFIED BY REG 1 NOT ZERO.               08400017
         SPACE                                                          08500017
* OUTPUT-      REMAINING TIME IN INTERVAL PLACED IN REG 0.              08600017
*              REGISTER 1 CONTAINS OPTION FLAG IN HI ORDER BYTE AND     08700017
*              EXIT ADDRESS IN LOW ORDER THREE BYTES.                   08800017
         SPACE                                                          08900017
* ENTRY POINT- .IGC046. ONLY ENTRY POINT IN CODE-GIVEN CONTROL BY SVC   09000017
*               FLIH.                                                   09100017
*              .THE PSW AT ENTRY MUST BE IN SUPERVISORY MODE & DISABLED 09200017
*               FOR I/O AND EXTERNAL INTERRUPTS AND HAVE SUPERVISORY    09300017
*               PROTECTION KEY.                                         09400017
*              .REG 1 CONTAINS THE CANCEL OPTION INDICATION             09500017
*              .REG 3 CONTAINS THE CVT ADDRESS.                         09600017
*              .REG 4 CONTAINS THE CURRENT TCB ADDRESS.                 09700017
*              .REG 5 CONTAINS THE CURRENT RB ADDRESS.                  09800017
*              .REG 14 CONTAINS THE ADDRESS OF TYPE 1 SVC EXIT.         09900017
*              .REGS 0,2,6-13 AND 15 ARE IRRELEVANT.                    10000017
         SPACE                                                          10100017
* EXIT POINT- .TO TYPE 1 SVC EXIT WHEN RTN IS COMPLETE.                 10200017
*             .THE PSW IS UNCHANGED FROM ENTRY.                         10300017
*              .REG 1 CONTAINS OPTION FLAG IN HI ORDER BYTE AND EXIT    10400017
*              ADDRESS IN LOW ORDER THREE BYTES.                        10500017
*              .REG 0 CONTAINS THE REMAINING TIME.                      10600017
*             .REGISTERS 0-15 ARE VOLATILE.                             10700017
         SPACE                                                          10800017
*             .TO TIMER CANCEL ROUTINE.                                 10900017
*              THE PSW IS UNCHANGED FROM ENTRY.                         11000017
*              REG 1 CONTAINS TQE ADDRESS TO BE DEQUEUED.               11100017
*              REG 2 CONTAINS RETURN ADDRESS.                           11200017
*              REG 15 CONTAINS ADDRESSABILITY FOR CANCEL DEQUEUE RTN.   11300017
         SPACE                                                          11400017
* ERROR EXIT POINTS- NONE                                               11500017
         SPACE                                                          11600017
* TABLES AND CONTROL- .THE TCB OF THE CURRENT TASK TO OBTAIN THE        11700017
*  BLOCKS REFERENCED   TIMER QUEUE ELEMENT ADDRESS.                     11800017
*                     .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDRESS.      11900017
         SPACE                                                          12000017
* LIST ORIGINS,     .NONE                                               12100017
* TABLES, CONTROL                                                       12200017
* BLOCKS INCLUDED                                                       12300017
         SPACE                                                          12400017
* RESTRICTIONS-     .NONE                                               12500017
         SPACE                                                          12600017
* NOTES            IF THE CANCEL OPTION IS SPECIFIED, THE TQE AND       12700017
*                  SAVE AREA WILL BE FREED                              12800017
*                                                                       12900017
         SPACE 3                                                        13000017
*...REGISTERS UNIQUE TO IGC046 CODE...                                  13100017
XGT0     EQU   0        .WORK REG.                                      13200017
XPARA    EQU   1        .CONTAINS INPUT PARAM & REMAINING TIME ON EXIT. 13300017
XTPSEUDO EQU   9        .CONTAINS ADDR OF PSEUDO CLOCK.                 13400017
XELE     EQU   10       .CONTAINS ADDRESS OF TIMER QUEUE ELEMENT.       13500017
XFLAGS   EQU   11       .CONTAINS 1ST WORD OF TQE (IF ANY).             13600017
XWK      EQU   12            .WORK REG.                                 13700017
FLGREG   EQU   13                       INTERNAL FLAG REG               13800017
XTBASE   EQU   15       .BASE REG.                                      13900017
XR9      EQU   9                                                        14000017
XR7      EQU   7                                                        14100017
XR8      EQU   8                                                        14200017
         SPACE                                                          14300017
*...MISC...                                                             14400017
KEXP     EQU   X'88'                                                    14500017
TTIMSAV  EQU   X'4C'                                               REFR 14600017
         SPACE 2                                                        14700017
         BALR  XTBASE,0                                                 14800017
         USING *,XTBASE                                                 14900017
TTBASE   DS    0H                      LABEL FOR ADDRESSABILITY         15000017
         USING CVTSECT,XCVT                                             15100017
         L     XTPSEUDO,CVTTPC     .LOAD BASE FOR CLOCKS           REFR 15200017
         ST    XRETRN,TTIMSAV(XTPSEUDO) .SAVE RETURN REG           REFR 15300017
         L     XELE,TCBTME(0,XTCB)     .GET TQE ADDR FROM TCB.          15400017
         LTR   XELE,XELE          .IS THERE AN ELEMENT.                 15500017
         BC    6,TESTEXP          .BR IF YES.                           15600017
TSET0   SR    X1,X1                   .CLEAR FLAG REG.                  15700017
         SR    XGT0,XGT0               .CLEAR REMAINING TIME REG.       15800017
TEXIT2   L     XTPSEUDO,CVTTPC     .LOAD BASE FOR CLOCKS           REFR 15900017
         L     XRETRN,TTIMSAV(XTPSEUDO) .RESTORE RETURN REG        REFR 16000017
        BR    XRETRN                  .RETURN.                          16100017
         DROP  XCVT                                                REFR 16200017
         SPACE                                                          16300017
TESTEXP  IC    XFLAGS,TQEFLGS(0,XELE)  .PICK UP TQE 1ST WORD.           16400017
         TM    TQEFLGS(XELE),KEXP      .HAS INTERVAL EXPIRED.           16500017
         BC    14,TSET2                 BR IF NO                        16600017
         SR    FLGREG,FLGREG            CLEAR FOR LATER TEST            16700017
         ST    FLGREG,TCBTME(0,XTCB)    ZERO TQE POINTER                16800017
         LR    XR9,XTBASE               SET R 9 FOR ADDRESSABILITY      16900017
         LA    FLGREG,TSET0             SET PROPER EXIT FLAG            17000017
         BC    15,TSET1                 SKIP INTERVAL CODE              17100017
TSET2    EQU   *                                                        17200017
         SPACE                                                          17300017
*...DEVELOP REMAINING TIME IN INTERVAL...                               17400017
*...    = TOX - (SHPC - TIMER)                                          17500017
         USING CVTSECT,XCVT                                             17600017
         L     XTPSEUDO,CVTTPC    .GET ADDR OF PSEUDO CLOCKS.           17700017
         L     XWK,PREFTMRA        .GET VALUE OF                   65MP 17900017
         L     XWK,TIMER-IEAQFX00(XWK) .ACTIVE TIMER               65MP 18000017
         SRA   XWK,1                   .DEV 26 USEC UNITS.              18100017
         LCR   XWK,XWK                 .-TIMER                          18200017
         AL    XWK,VSHPC(0,XTPSEUDO)   .(SHPC-TIMER)                    18300017
         LCR   XWK,XWK                 .-(SHPC-TIMER)                   18400017
         AL    XWK,TQEVAL(0,XELE)      .TOX-(SHPC-TIMER)                18500017
         LR    XR9,XTBASE          .SAVE BASE OF THIS ROUTINE      REFR 18550017
         BC    3,*+6              .BR IF INTVL NOT PAST DUE.            18600017
         SR    XWK,XWK                 .SET REMAINING TIME TO ZERO.     18700017
         LTR   XPARA,XPARA        .TEST FOR CANCEL OPTION.              18800017
         BC    8,TEXITX           .BR IF CANCEL NOT SPECIFIED.          18900017
         SPACE                                                          19000017
*...CANCEL INTERVAL...                                                  19100017
         SR    XGT0,XGT0                                                19200017
         ST    XGT0,TCBTME(0,XTCB)     ZERO TQE FIELD IN TCB            19300017
         LR    XGT0,XTCB               SAVE TCB ADDR ACROSS DEQUEUE     19400017
         LR    XPARA,XELE         .SET ELM ADDR IN REG FOR DEQUEUE.     19500017
         L     XDQ,ADQSPCL        .GET SPECIAL ENTRY TO DEQUEUE.        19600017
         L     XTPSEUDO,CVTTPC     .GET BASE FOR CLOCKS            REFR 19650017
         ST    XELE,SAVDISP(XTPSEUDO) .SAVE REG 10                 REFR 19700017
         LR    XELE,XTPSEUDO       .SET DQ CLOCK BASE              REFR 19800017
         LR    XR9,XTBASE          .LOAD REG FOR NEW BASE          REFR 19900017
         L     XTBASE,DQBASE      .SET DQ ADDRESSABILITY.               20000017
         BALR  XDQ,XDQ            .TO DEQUEUE RTN.                      20100017
         DROP  XTBASE                                                   20200017
         USING TTBASE,XR9                                               20300017
         LR    XTCB,XGT0               RESTORE TCB ADDR                 20400017
         LA    FLGREG,TEXITX            SET RETURN REG                  20500017
TSET1    EQU   *                                                        20600017
         L     XGT0,SP250              SET UP TO FREE TQE SAVE AREA     20700017
         L     XPARA,TQESAADR(0,XELE)  SP = 250, LN = 72 BYTES          20800017
         L     XR8,ARMBRNCH            BRANCH ENTRY TO FREEMAIN         20900017
         BALR  XRETRN,XR8                                               21000017
         L     XGT0,SP243              SET UP TO FREE TQE         21008 21100021
         LR    XPARA,XELE              SP = 243, LN = 112 BYTES   21008 21200021
         L     XR8,ARMBRNCH            BRANCH ENTRY TO FREEMAIN         21300017
         BALR  XRETRN,XR8                                               21400017
         LR    XTBASE,XR9          .RESTORE REG 15 AS BASE         REFR 21500017
         BCR   15,FLGREG                RETURN                          21600017
TEXITX   LR    XGT0,XWK                .SET INTVL IN REG.               21700017
         LA    X1,X'43'           .SET MASK.                            21800017
         NR    XFLAGS,X1         .SET FLAG TO INDICATE 'TUINTVL'.       21900017
         SLL   XFLAGS,24               .SHIFT FLAGS TO HI ORDER BYTE.   22000017
         O     XFLAGS,TQEEXIT(0,XELE)  .PLACE EXIT ADDR IN LO 3 BYTES.  22100017
         LR    X1,XFLAGS          .SET FLAG AND EXIT INFO IN REG 1.     22200017
         L     XCVT,CVTPTR         .GET ADDRESS OF CVT             REFR 22250017
         B     TEXIT2              .BRANCH TO EXIT                      22320017
         DROP  XCVT                                                     22360017
         DROP  XR9                                                      23100017
         TITLE '        STIMER FOR OPTION 4 SYSTEMS'                    23200017
*...COMMENTARY FOR STIMER...                                            23300017
         SPACE                                                          23400017
* ROUTINE NAME .IGC047- STIMER SVC SERVICE ROUTINE.                     23500017
         SPACE                                                          23600017
* FUNCTION-    .INITIALIZES AND QUEUES TIMER QUEUE ELEMENT (TQE) FOR    23700017
*               THE PURPOSE OF TIMING REQUESTED INTERVALS.              23800017
*              .PERFORMS CONVERSION TO TU'S WHEN INPUT TIME VALUE IS    23900017
*               IN BIN OR DEC UNITS.                                    24000017
*              .CHECKS WHETHER  TQE IS BEING USED AS IRB FOR PREVIOUSLY 24100017
*               SPECIFIED INTERVAL. IF SO, STIMER REQUEST IS IGNORED.   24200017
*              .CHECKS WHETHER TQE IS CURRENT IN USE. IF SO, EXISTING   24300017
*               INTERVAL IS CANCELLED AND NEW INTERVAL INSTATED.        24400017
         SPACE                                                          24500017
* ENTRY POINT NAME  .IGC047                                             24600017
         SPACE                                                          24700017
* CONTAINED IN MODULE- IEAQST00                                         24800017
         SPACE                                                          24900017
* ATTRIBUTES   .TYPE 2 SVC RTN.,RESIDENT,REENTRANT,SUPERVISOR STATE,    25000017
*               I/O AND EXTERNAL DISABLED.                              25100017
         SPACE                                                          25200017
* APPLICABILITY- OPTION 4 SYSTEMS USING OPTION 6B.                      25300017
         SPACE                                                          25400017
* EXTERNAL REFERENCES-  .IEAQTD01, ENTRY POINT TO TIMER DEQUEUE RTN.    25500017
*                       .IEAQTD00, CANCEL DEQUEUE ENTRY POINT           25600017
         SPACE                                                          25700017
* SVC USAGE    .WAIT- ECB IN TQEECB.                                    25800017
*              .GETMAIN- SUBPOOL 250.                                   25900017
*              .GETMAIN- SUBPOOL 253.                                   26000017
         SPACE                                                          26100017
* INPUT        .REG 0 CONTAINS OPTION FLAGS IN HI ORDER BYTE AND EXIT   26200017
*               ADDR. IN LOW ORDER 3 BYTES.                             26300017
*              .REG 1 CONTAINS THE ADDRESS OF THE TIME VALUE.           26400017
*              .THE LEFT HALF OF THE PSW STORED IN THE SVRB (RBOPSW)    26500017
*               OF THE STIMER CODE.                                     26600017
         SPACE                                                          26700017
* OUTPUT       .AN INITIALIZED AND QUEUED TQE.                          26800017
         SPACE                                                          26900017
* ENTRY POINTS .IGC047, ENTRY FROM SVC FLIH.                            27000017
*              .REG 0 CONTAINS OPTION FLAG AND EXIT ADDRESS.            27100017
*              .REG 1 CONTAINS ADDR OF TIME VALUE.                      27200017
*              .REG 3 CONTAINS CVT ADDR                                 27300017
*              .REG 4 CONTAINS CURRENT TCB ADDR.                        27400017
*              .REG 5 CONTAINS CURRENT RB ADDR.                         27500017
*              .REGS 2,6-13, & 15 ARE IRRELEVANT.                       27600017
*              .REG 14 CONTAINS ADDR OF SVC 3 (TYPE 2 EXIT)             27700017
*              .THE PSW IS IN SUPERVISOR STATE AND IS I/O AND EXTERNAL  27800017
*               DISABLED AND HAS SUPERVISOR PROTECTION KEY.             27900017
         SPACE                                                          28000017
* EXIT POINTS  .TO TYPE 2 EXIT VIA BR 14                                28100017
*              .THE PSW STATUS IS UNCHANGED                             28200017
*              .REG 14 CONTAINS THE EXITING ADDR. OTHER REGS ARE        28300017
*               MEANINGLESS.                                            28400017
*              REGS 0-13, & 15 ARE VOLATILE OVER STIMER.                28500017
*              REG 14 IS TRANSPARENT.                                   28600017
         SPACE                                                          28700017
* ERROR EXIT POINTS .NONE                                               28800017
         SPACE                                                          28900017
* TABLES & CONTROL  .THE CVT TO OBTAIN THE PSEUDO CLOCK ADDR AND        29000017
* BLOCKS REFERENCED  TIMER DEQUEUE AN TIMER ENQUEUE RTNS.               29100017
*                   .THE CURRENT TCB TO OBTAIN THE TQE ADDR.            29200017
*                   .THE CURRENT RB TO REFERENCE INPUT REGS 0 & 1 WHICH 29300017
*                    ARE SAVED IN THE RBGRSAV AREA AND THE PSW IN       29400017
*                    EFFECT WHEN THE SVC WAS ISSUED. ALSO, AN EXTENDED  29500017
*                    SAVE AREA APPENDED TO THE SVRB IS USED FOR AN ECB. 29600017
*                    A WORK AREA FOR A PACK INSTRUCTION, AND AS TEMP.   29700017
*                    REGISTER STORAGE OVER THE TIMER DEQUEUE RTN.       29800017
*                   .THE TQE IS REFERENCED AND INITIALIZED FOR THE NEW  29900017
*                    INTERVAL.                                          30000017
         SPACE                                                          30100017
* LIST ORIGINS,TABLES    .A CONVERSION TABLE TMTABLE FOR CONVERTING     30200017
* & CONTROL BLOCKS        DEC DIGITS TO BIN UNITS.                      30300017
* INCLUDED                                                              30400017
         SPACE                                                          30500017
         SPACE                                                          30600017
* NOTES        NOTE CVB INSTRUCTION DEPENDS UPON RBEXTSAV+0 TO BE ON A  30700017
*              DOUBLE WORD BOUNDARY.                                    30800017
         SPACE 3                                                        30900017
*...REGISTERS UNIQUE TO STIMER CODE...                                  31000017
XPARA0   EQU   0                                                        31100017
X1       EQU   1                                                        31200017
XTIME    EQU   1                                                        31300017
XNQPTR   EQU   1                                                        31400017
XECB     EQU   1                                                        31500017
XBASE    EQU   2                                                        31600017
XNQ      EQU   2                                                        31700017
XLPCTL   EQU   9                                                        31800017
XPSEUDO  EQU   9                                                        31900017
XGR2     EQU   10                                                       32000017
XINCR    EQU   10                                                       32100017
XGR3     EQU   11                                                       32200017
XCMPR    EQU   XINCR+1                                                  32300017
XPRD     EQU   12                                                       32400017
XELM     EQU   12                                                       32500017
XCAND    EQU   XPRD+1                                                   32600017
XGR1     EQU   13                                                       32700017
XEXIT    EQU   13                                                       32800017
XTMPTR   EQU   15                                                       32900017
         SPACE                                                          33000017
*...MASKS FOR TESTING FLAGS...                                          33100017
*   INPUT FLAGS                                                         33200017
DINTVL   EQU   X'30'         .DECIMAL OPTION                            33300017
TOD      EQU   X'40'         .TOD OPTION                                33400017
         SPACE                                                          33500017
*   TQE FLAGS                                                           33600017
EXIT     EQU   X'04'    .EXIT MASK                                      33700017
OFFQ     EQU   X'80'    .OFF QUEUE MASK                                 33800017
WAIT     EQU   X'01'    .WAIT OPTION MASK                               33900017
COMPLETE EQU   X'88'    .COMPLETION MASK                                34000017
         SPACE                                                          34100017
*   MISC                                                                34200017
ACTIRB   EQU   X'40'                                                    34300017
         SPACE                                                          34400017
         SPACE                                                          34500017
         ENTRY IGC047                                                   34600017
         EXTRN IEAQTD00,IEAQTD01                                        34700017
         SPACE                                                          34800017
IGC047   DS    0D                                                       34900017
         BALR  XBASE,0                                                  35000017
         USING *,XBASE                                                  35100017
*...NOTE THAT INPUT PARAMETER REGS 0 & 1 ARE SAVED IN THE SVRB SAVE     35200017
*   AREA AT SVRB+32 & SVRB+36 RESPECTIVELY.                             35300017
         TM    RBGRSAV+0(XRB),DINTVL .TEST FOR DECIMAL OPTION.          35400017
         BC    12,TLDTIME         .BR IF NOT DECIMAL OPTION.            35500017
         SPACE                                                          35600017
*...CONVERT DEC. VALUE TO BIN UNITS...                                  35700017
         LR    XTMPTR,XTIME       .LOAD REG WITH ADDR OF TIME VALUE     35800017
         SR    XLPCTL,XLPCTL      .INITIALIZE CONVERSION LOOP.          35900017
         SR    XTIME,XTIME                                              36000017
         LA    XINCR,4                                                  36100017
         LA    XCMPR,16                                                 36200017
TMDECLP  BXH   XLPCTL,XINCR,TMCNVTU .LOOP 4 TIMES BEFORE BRANCHING.     36300017
         PACK  RBEXTSAV+0(8,XRB),0(2,XTMPTR) .PACK 2 DEC DIGITS.        36400017
         OI    RBEXTSAV+7(XRB),X'0F'   .INSURE THAT SIGN IS PRESENT.    36500017
         CVB   XCAND,RBEXTSAV+0(XRB) .CONVERT 2 DIGITS TO BINARY UNITS. 36600017
         M     XPRD,TMTABLE-4(XLPCTL) .EXPAND TO BIN UNITS.             36700017
         ALR   XTIME,XCAND        .ACCUM BIN TIME UNITS.                36800017
         LA    XTMPTR,2(XTMPTR)   .REF NEXT TWO DIGITS.                 36900017
         B     TMDECLP                                                  37000017
         SPACE                                                          37100017
*...TUINTVL OR BINTVL OPTIONS...                                        37200017
TLDTIME  L     XTIME,0(XTIME)     .GET TIME VALUE.                      37300017
         BZ    TLOCTST            .BR IF TUINTVL OPTION.                37400017
         SPACE                                                          37500017
TMCNVTU  EQU   *                                                        37600020
         CL    XTIME,TBINMAX       CHECK FOR EXCESSIVE BIN VALUE        37750019
         BNH   *+8                                                      37800017
         L     XTIME,TBINMAX      .USE MAX BIN VALUE.                   37900017
         M     XPARA0,TMTUCNV     .CONVERT TO 52 USEC UNITS.            38000017
         D     XPARA0,TM10E7                                            38100017
         ALR   XTIME,XTIME        .DOUBLE TO OBTAIN 26 USEC UNITS.      38200017
*...TU TIME VALUE NOW IN XTIME...                                       38300017
         SPACE                                                          38400017
         SPACE                                                          38500017
*...CONVERT TO ABS INTERVAL BASED ON 6 HR TOD                           38600017
         USING CVTSECT,XCVT                                             38700017
TLOCTST  L     XPSEUDO,CVTTPC      .GET ADDR OF PSEUDO CLOCKS      REFR 38800017
         DROP  XCVT                                                     38900017
         TM    RBGRSAV+0(XRB),TOD  .TEST FOR TOD OPTION            REFR 39000017
         BZ    TCHKMAX            .BR IF NOT TOD OPTION.                39100017
*        ABS INT = NEW TIME-(T4PC+LTPC+SHPC-TIMER)                      39200017
         L     XGR1,PREFTMRA       .GET VALUE OF                   65MP 39300017
         L     XGR1,TIMER-IEAQFX00(XGR1) .ACTIVE TIMER             65MP 39400017
         SRA   XGR1,1             .DEV 26 USEC UNITS.                   39500017
         LCR   XGR1,XGR1          .-TIMER.                              39600017
         AL    XGR1,VSHPC(XPSEUDO) .SHPC-TIMER.                         39700017
         AL    XGR1,VT4PC(XPSEUDO) .T4PC+SHPC-TIMER.                    39800017
         AL    XGR1,VLTPC(XPSEUDO) .LTPC+T4PC+SHPC-TIMER.               39900017
         L     XGR2,TM24          .SET UP COMPARAND OF 24 HRS.          40000017
         BC    12,*+8             .DID OVERFLOW OCCUR.                  40100017
         B     *+10               .BR IF YES.                           40200017
         CLR   XGR1,XGR2          .IS VALUE LESS THAN 24 HRS.           40300017
         BL    *+6                .BR IF YES.                           40400017
         SLR   XGR1,XGR2          .SUBTRACT 24 HR ADJUSTMENT.           40500017
         SLR   XTIME,XGR1         .NEW LTOD - CURRENT LTOD.             40600017
         BC    3,*+6              .BR IF NO UNDERFLOW OCCURRED.         40700017
         ALR   XTIME,XGR2         .ADD 24 HR ADJUSTMENT.                40800017
         SPACE                                                          40900017
TCHKMAX  CL    XTIME,TMAX         .CHECK FOR MAX VALUE EXCEEDED.        41000017
         BL    *+8                                                      41100017
         L     XTIME,TMAX         .USE MAX VALUE.                       41200017
         SPACE                                                          41300017
*...CHECK CURRENT STATUS OF TIMER ELEMENT...                            41400017
         L     XELM,TCBTME(0,XTCB)     .GET TQE ADDR FROM TCB.          41500017
         LTR   XELM,XELM          .IS THERE A TQE.                      41600017
         BC    8,TGETCORE         .BR IF NOT.                           41700017
         TM    TQEFLGS(XELM),OFFQ .IS TQE OFF QUEUE.                    41800017
         BO    TIRBTST            .BR IF YES.                           41900017
         SPACE                                                          42000017
*...ELM IS IN USE. CANCEL EXISTING INTERVAL.                            42100017
*  .USE SPECIAL ENTRY TO DEQUEUE RTN.                                   42200017
*  .SAVE REGS XTIME,XELM,XBASE,XRB.                                     42300017
*  .SAVE REGS XTIME,XELM,XBASE,XRB,XRETRN.                              42400017
         STM   14,5,RBEXTSAV(XRB) .SAVE REGS IN SVRB EXT SAVE AREA.     42500017
         LR    XGR2,XRB           .SAVE XRB OVER DEQUEUE.               42600017
         LR    1,XELM             .SET ELM ADDR FOR DQ RTN.             42700017
         L     15,DQBASE          .EST ADDRESSABILITY FOR CANCEL RTN.   42800017
         L     XDQ,ADQSPCL             .GET ADDR OF CANCEL RTN.         42900017
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10                  REFR 43000017
         LR    XGR2,XPSEUDO        .SET DQ CLOCK BASE              REFR 43100017
         BALR  XDQ,XDQ            .TO DQ RTN TO CANCEL INTERVAL.        43200017
         LM    14,5,RBEXTSAV(XGR2)     .RESTORE REGISTERS.              43300017
         B     TSTORTCB                                                 43400017
         SPACE                                                          43500017
TIRBTST  TM    TQEFLGS(XELM),EXIT+COMPLETE  .CHECK FOR EXIT AND COMPLT. 43600017
         BC    12,TSTORTCB+4           .BR IF NOT IN IRB FORMAT.        43700017
         TM    RBSTAB+1(XELM),ACTIRB .IS ELM AN ACTIVE IRB.             43800017
         BC    12,TMVSAADR             .BR IF NOT.                      43900017
         OI    RBSTAB+1(XELM),RBFDYN FLAG IRB DYNAMIC              2647 44000018
         SPACE                                                          44100017
*...GET CORE FOR TQE...                                                 44200017
TGETCORE DS    0H                                                       44300017
         LR    XGR1,XTIME                                               44400017
         ST    XRETRN,RBEXTSAV(XRB) SAVE RETURN ADDR             A36393 44410020
         L     XGT0,SP250          SET UP TO GET CORE FOR S/A    A36393 44450020
         BAL   XGR3,GETCORE        GO TO COMMON CORE GETTER RTE  36393  44500020
         LR    XELM,X1                 SAVE REG SAVE AREA               44600017
         L     XGT0,SP243              SET UP TO GET CORE FOR TQE 21008 44650021
         BAL   XGR3,GETCORE        GO TO COMMON CORE GETTER RTE  A36393 44700020
         L     XRETRN,RBEXTSAV(XRB) RESTORE RETURN ADDR          A36393 44750020
         ST    X1,TCBTME(0,XTCB)       STORE TQE ADDR IN TCB            44800017
         ST    XELM,TQESAADR(0,X1)     STORE  SAVE AREA ADDR IN TQE     44900017
         LR    XELM,X1                 SET STD REG TO TQE ADDR          45000017
         SR    X1,X1                   CLEAR RIGHT HALF PSW             45100017
         ST    X1,TQEPSW+4(0,XELM)                                      45200017
         LR    XTIME,XGR1              .RESTORE TIME VALUE.             45300017
         B     TSTORTCB                                                 45400017
*                                                                       45450020
*              COMMON CORE GETTER ROUTINE                      A36393   45500020
*                                                                       45550020
GETCORE  LR    XPARA,XGT0          INDICATE GETMAIN ENTRY        A36393 45560020
         L     XGR2,ARMBRNCH                                            45570020
         BALR  XRETRN,XGR2         GO GET SOME CORE              A36393 45580020
         BR    XGR3                RETURN TO CALLER              A36393 45590020
*                                                                       45599920
TMVSAADR MVC   TQESAADR+1(3,XELM),TQEFLGS+1(XELM) REPLACE S/A ADDR      45650020
         SPACE                                                          45700017
TSTORTCB EQU   *                                                        45800017
         ST    XTCB,TQEFLGS(0,XELM)    .STORE TCB ADDR IN TQE.          45900017
         MVC   TQEFLGS(1,XELM),RBGRSAV+0(XRB)    .MOVE FLAG BYTE TO TQE 46000017
         OI    TQEFLGS(XELM),OFFQ                .FLAG TQE AS OFF QUEUE 46100017
         SPACE                                                          46200017
*...SET INTERVAL AND EXIT ADDRESS...                                    46300017
TSET     ST    XTIME,TQEVAL(0,XELM)    .STORE INTERVAL VALUE IN TQE.    46400017
         L     XEXIT,RBGRSAV(0,XRB)    .GET EXIT ADDR.                  46500017
         LA    XEXIT,0(0,XEXIT)        .CLEAR HI-ORDER BYTE.            46600017
         ST    XEXIT,TQEEXIT(0,XELM)   .STORE EXIT ADDR IN TQE.         46700017
         LTR   XEXIT,XEXIT        .IS THERE AN EXIT ADDR SPECIFIED.     46800017
         BZ    TMNQ               .BR IF NOT TO ENQUEUE.                46900017
         L     XGR2,RBLINK(0,XRB) .GET CALLER'S RB ADDR.                47000017
         MVC   TQEPSW(4,XELM),RBOPSW(XGR2)  .SAVE LH OF CALLER'S PSW.   47100017
         OI    TQEFLGS(XELM),EXIT .FLAG ELM AS HAVING EXIT.             47200017
         SPACE                                                          47300017
*...INTERFACE WITH ENQUEUE RTN...                                       47400017
TMNQ     LR    XNQPTR,XELM        .SET ELM ADDR FOR ENQUEUE RTN.        47500017
         LR    XGR2,XELM          .SAVE TQE ADDR OVER ENQUEUE.          47600017
         LR    XGR3,XRB           .SAVE RB ADDR OVER ENQUEUE.           47700017
         LR    XR7,XTCB                                                 47800017
         LR    XR7,XTCB                SAVE TCB ADR OVER ENQUEUE   MTS0 47900017
         USING CVTSECT,XCVT                                             48000017
         L     XNQ,CVTQTE00       .GET ADDR OF ENQUEUE RTN.             48100017
         DROP  XCVT                                                     48200017
         ST    XGR2,SAVDISP(XPSEUDO) .SAVE REG 10 IN TPC           REFR 48300017
         BALR  XNQ,XNQ            .TO ENQUEUING RTN.                    48400017
         USING *,XBASE                                                  48500017
         L     XGR2,SAVDISP(XPSEUDO) .RESTORE REG 10               REFR 48600017
         LR    XTCB,XR7                                                 48700017
         LR    XTCB,XR7                RESTORE TCB ADR             MTS0 48800017
         SPACE                                                          48900017
*...IMPLEMENT WAIT IF INDICATED...                                      49000017
         TM    TQEFLGS(XGR2),X'03'     .IS WAIT INDICATED.              49100017
        BCR   9,XRETRN                .BR IF NOT.                       49200017
         LA    XECB,TQEECB(0,XGR2)     .DEV ECB ADDR.                   49300017
         XC    TQEECB(4,XGR2),TQEECB(XGR2)  .ZERO ECB.                  49400017
         WAIT  1,ECB=(1)                                         A26059 49600019
         BR    XRETRN              RETURN TO CALLER              A26059 49800019
*...ADDRESSES AND CONSTANTS UNIQUE TO STIMER...                         50200017
         SPACE                                                          50300017
         DS    0F                                                       50400017
AWAIT    DC    V(IGC001)     .ADDR OF WAIT.                             50500017
TMTUCNV  DC    X'7270E000'    .DECIMAL EQUIV=1,920,000,000.      A24887 50600019
*                                  USED TO DEVELOP 52 USEC UNITS A24887 50610019
*                                  FROM 10 MS (BIN) UNITS.EQUALS A24887 50620019
*                                  100,000 SECONDS/52 TO DEVELOP A24887 50630019
*                                  GREATER ACCURACY.MUST DIVIDE  A24887 50640019
*                                  BY 10,000,000.                A24887 50650019
TM10E7   DC    X'00989680'        .EQUALS 10,000,000. USED TO DEVELOP   51100017
*                                  52 USEC UNITS.                       51200017
TBINMAX  DC    X'0083D5FF'        .MAX BIN VALUE.                       51300017
TMAX     EQU   *                                                        51400017
TM24     DC    X'C5C10000'         .24 HR TU VALUE               A24887 51500019
TMTABLE  DC    F'360000'          .CONVERSION FACTORS TO DEV BIN UNITS  51600017
         DC    F'6000'             FROM DECIMAL FORMAT.                 51700017
         DC    F'100'                                                   51800017
         DC    F'1'                                                     51900017
         SPACE                                                          52000017
*...ADCONS SHARED BY TTIMER AND STIMER                                  52100017
ADQSPCL  DC    A(IEAQTD00)   .CANCEL DEQUEUE ROUTINE.                   52200017
DQBASE   DC    A(IEAQTD01+2) .ADDRESSABILITY FOR DEQUEUE RTN.           52300017
*                                                                       52310020
*               CONSTANTS USED BY BOTH STIMER AND TTIMER       A36393   52320020
*                                                                       52330020
*                                                                       52340020
         DS    0F                                                       52342020
SP250    DC    X'FA000048'         72 BYTES IN SUBPOOL 250       A36393 52344020
SP243    DC    X'F3000070'        112 BYTES IN SP 243             21008 52346021
ARMBRNCH DC    V(RMBRANCH)         BRANCH ENTRY TO GET/FREEMAIN  A36393 52348020
IGC046A1 EQU   *                                                    MCH 52350019
         END                                                            52400017
