         TITLE  ' SPIE  *  EXTRACT  '                              STAE 00010017
IGC014   START                                                          00040000
*1024000100,000300,000500,025200,141000-243800                     STAE 00050017
*RELEASE NO.21.6 21372,A50600,A37037                          AC  21372 00052021
         SPACE 2                                                        00060000
*  KEYS FOR COMMENTS                                                    00080000
*        INITIALIZATION                 $                               00100000
*        EXIT-NORMAL                    *                               00120000
*        EXIT-SUBROUTINE                **                              00140000
*        EXIT-ERROR                     ***                             00160000
*        SPECIAL ENTRY POINT            /                               00180000
*        INTEROGATIVE OPERATION         Q.                              00200000
         SPACE 2                                                        00220000
* REGISTER ASSIGNMENTS                                                  00240000
*  ALL ROUTINE                                                          00260000
XRERCODE EQU   1         ERROR CODE IN REGISTER BEFORE GOING TO ABTERM  00280000
XRTESTWD EQU   1         WORD TO BE TESTED FOR VALIDITY                 00300000
XRTSTADR EQU   2         ADDRESS OF VALIDITY CHECK ROUTINE              00320000
XRCVT    EQU   3         ADDRESS OF VECTOR TABLE (SVC HANDLER SETS)     00340000
XROTCB   EQU   4         CONTENT OF 'OLD' (SVC HANDLER SETS)            00360000
XRORB    EQU   5         ADDRESS OF TOP RB OF 'OLD' (SVC HANDLER SETS)  00380000
XRSAVE   EQU   6         SAVE REGISTER 1 CONTENT                        00400000
XRLINK   EQU   12        LINK REGISTER                                  00420000
XRABTERM EQU   13        ABTERM ROUTINE ADDRESS (SVC HANDLER SETS)      00440000
XRRETURN EQU   14        TYPE 1 SVC EXIT ADDRESS (SVC HANDLER SETS)     00460000
XRBASE   EQU   15        BASE REGISTER                                  00480000
         SPACE 1                                                        00500000
*  SPIE ROUTINE                                                         00520000
XRPICADR EQU   1         INPUT PARAMETER REGISTER, ADDRESS OF PICA      00540000
XRGMPIE  EQU   1         REGISTER OF PIE GOTTEN BY GETMAIN              00560000
XRPRIRB  EQU   9        PREVIOUS RB                                8764 00580014
XRPIE    EQU   7         PROGRAM INTERUPT ELEMENT POINTER IN TCB        00600000
XRPICAOL EQU   8        OLD PICA ADR                                    00620000
XRBASE10 EQU   10        BASE REGISTER                                  00640000
XRCCODE  EQU   15        CONDITION CODE REG                             00660000
         SPACE 1                                                        00680000
*  EXTRACT ROUTINE.                                                     00700000
XRPADR   EQU   1         INPUT PARAMETER ADDRESS                        00720000
XRCOUNT  EQU   5         COUNTER FOR FIELDS TO BE EXTRACTED             00740000
XRLIST   EQU   7         UPDATED LIST ADDRESS                           00760000
XRTSTFLD EQU   8         TEST WHAT FIELDS TO BE EXTRACTED               00780000
XRINF    EQU   8         CONTAIN ZERO OR EXTRACTED INFORMATION          00800000
XRFIELD  EQU   9         UPDATED CONTENT OF FIELD TO BE EXTRACTED       00820000
XRETCB   EQU   10        ADDRESS OF TCB WHICH INFORMATION TO BE EXTRACT 00840000
XRSHIFT  EQU   11        WORK BIT TEST REGISTER                         00860000
XRIND    EQU   11        INTERNAL INDICATOR                             00880000
XRTCBTST EQU   11        TCB TO BE TESTED                               00900000
         SPACE 1                                                        00920000
         SPACE 1                                                        01200000
*  STAE ROUTINE.                                                        01220000
XRSEOTE  EQU   1         INPUT SEOTE ADDRESS OR ZERO                    01240000
         SPACE 2                                                        01260000
*  TASK CONTROL BLOCK DISPLACEMENT (TCB)                                01280000
TCBRBP   EQU   0         PTR TO TOP RB                                  01300000
TCBPIE   EQU   4         PTR PROGRAM INTERUPT ELEMENT (PIE)             01320000
TCBDEB   EQU   8         PTR TO DATA ELEMENT BLOCK (DEB)                01340000
TCBTIO   EQU   12        PTR TO TASK I/O TABLE (TIOT)                   01360000
TCBCMP   EQU   16        TCB COMPLETION CODE                            01380000
TCBTRN   EQU   20        TESTRAN FIELD                                  01400000
TCBMSS   EQU   24        PTR TO SUBPOOL QUEUE ELEMENT (SPQE)            01420000
TCBPKF   EQU   28        TASK PROTECT KEY                               01440000
TCBFLG   EQU   29        FLAGS                                          01460000
TCBLMP   EQU   34        TCB'S LIMIT PRIORITY                           01480000
TCBDSP   EQU   35        TCB'S DISPATCHING PRIORITY                     01500000
TCBLLS   EQU   36        PTR TO LOADED PROGRAM LIST ADR                 01520000
TCBJLB   EQU   40        PTR TO JOB LIBRARY DATA CONTROL BLOCK          01540000
TCBJSE   EQU   44        PTR TO JOB STEP INDEX ELEMENT (JSIE)           01560000
TCBGRS   EQU   48        GENERAL REGISTER SAVE AREA                     01580000
TCBTSFLG EQU   X'94'                   DISP TO TIME SHARING FLAGS 20021 01590020
TCBIDF   EQU   112       TCB'S ID                                       01600000
TCBFSA   EQU   113       PTR TO FIRST PROBLEM PROGRAM SAVE AREA         01620000
TCBTCB   EQU   116       PTR TO NEXT TCB ON READY QUEUE                 01640000
TCBTME   EQU   120       PTR TO TIMER ELEMENT                           01660000
TCBITB   EQU   124       PTR TO INITIATOR/TERMINATOR TCB                01680000
TCBSTC   EQU   128       PTR TO SISTER TCB                              01700000
TCBMTC   EQU   132       PTR TO MOTHER TCB                              01720000
TCBDTC   EQU   136       PTR TO DAUGHTER TCB                            01740000
TCBIQE   EQU   140       PTR TO INTERUPT QUEUE ELEMENT (IQE)            01760000
TCBECB   EQU   144       PTR TO EVENT CONTROL BLOCK (ECB)               01780000
TCBSET   EQU   148       PTR TO SELF END OF TASK ROUTINE (SEOTE)        01800000
TCBJSCB  EQU   180                     PTR TO JOB STEP CONTROL BLOCK    01810019
         SPACE 2                                                        01820000
*  REQUEST BLOCK DISPLACEMENT (RB)                                      01840000
RBABOPSW EQU   4         BITS 32-36 OF USER'S PSW                       01860000
RBSIZE   EQU   8         SIZE OF RB IN DOUBLE WORD                      01880000
RBSTAB   EQU   10        STATUS AND ATTRIBUTE BITS (STAB)               01900000
RBCDFLGS EQU   12        CONTENT CONTROL FLAGS                          01920000
RBEP     EQU   12        IRB'S ENTRY POINT ADDRESS                      01940000
RBCDE    EQU   13        PTR TO CONTENT DIRECTORY ENTRY                 01960000
RBOPSW   EQU   16        INTERRUPT OPSW                                 01980000
RBPGMQ   EQU   24        QUEUE FIELD FOR SERIALLY REUSABLE PROGRAM      02000000
RBWCF    EQU   28        WAIT COUNT                                     02020000
RBLINK   EQU   29        PTR TO NEXT RB ON QUEUE, OR TCB IF LAST RB     02040000
NXTRBS   EQU   28       PTR. TO NEXT RB.                                02060000
         SPACE 2                                                        02080000
* GENERAL EQUATES                                                       02100000
FLDSIZE  EQU   10        NUMBERS OF FIELD TO BE EXTRACTED-1   AC A46428 02120021
HEADADR  EQU   160       DISPLACMENT IN VECTOR TABLE TO 'HEAD' POINTER  02140000
IQEPTR   EQU   140       LOGICAL ADR IN TCB TO IQE PTR                  02160000
IRBPTR   EQU   8         LOGICAL ADDR. TO IRB PTR IN IQE                02180000
NEWPTR   EQU   4         DISPLACEMENT TO 'NEW'                          02200000
SEOTEFLG EQU   X'01'     SEOTE FLAG BIT                                 02220000
SEOTEUNF EQU   X'FE'     SEOTE UNFLAG BITS                              02240000
TCBFPS   EQU   32        DISPLACEMENT OF FLOATING POINT REGISTER IN TCB 02260000
ERRXRACT EQU   X'0128'   EXTRACT LIST ADDRESS INVALID                   02280000
ERRXAT2  EQU   X'0228'  INPUT PARA LIST ADDRESS INVALID                 02300000
ERRAXT3  EQU   X'0328'   INVALID SUB-TASK                               02320000
ERRCHAP  EQU   X'012C'   CHAP'S DAUGHTER'S ADDRESS INVALID              02340000
ERRCHP2  EQU   X'022C'  INPUT ADR OF SUBTASK TO BE CHAPPED IS INVALID   02360000
ZERO     EQU   X'00'    ZERO BYTE                                       02380000
PGMZERO  EQU   X'F0'    ZERO PROGRAM MASK                               02400000
SUPORPP  EQU   X'F0'    SUPERVISOR INDICATOR BIT IN PSW                 02420000
         SPACE 2                                                        02440000
* ENTRY AND EXTRN STATEMENTS                                            02460000
         ENTRY IGC040                                                   02480000
         EXTRN IEA0DS02                                                 02540000
         SPACE 2                                                        02541019
* MAPPING MACRO FOR JSCB                                                02542019
         IEZJSCB                                                        02543019
         SPACE 2                                                        02544019
* MAPPING MACRO FOR CSCB                                                02545019
CSCB     DSECT                                                          02546019
         IEECHAIN                                                       02547019
         SPACE 2                                                        02548019
* END OF DUMMY SECTIONS                                                 02549019
IGC014   CSECT                         CONTINUE                         02550019
         EJECT                                                          02560000
*ROUTINE NAME-           IGC014-SPIE SVC SERVICE ROUTINE                02580000
*                                                                       02600000
*FUNCTION -              PROVIDES   THE PROBLEM PROGRAM WITH            02620000
*                        A MEANS OF SPECIFYING AN ERROR EXIT            02640000
*                        ROUTINE IN RESPONSE TO ONE OR MORE             02660000
*                        PROGRAM ERROR INTERRUPTS.                      02680000
*                                                                       02700000
*                        THE PROGRAM MASK IN THE PROGRAM STATUS         02720000
*                        WORD (PSW) IS SET AS SPECIFIED BY THE          02740000
*                        PROGRAM MASK IN THE PICA(PROGRAM INTERRUPT     02760000
*                        CONTROL AREA).                                 02780000
*                                                                       02800000
*ENTRY POINT NAMES-      IGC014- SPIE SVC ENTRY POINT                   02820000
*                                                                       02840000
*CONTAINED IN MODULE-    IEAQTB00- TASK CONTROL BLOCK EFFECTOR          02860000
*                                                                       02880000
*ATTRIBUTES-             RESIDENT,RE-ENTRANT,SUPERVISOR STATE,          02900000
*                        TYPE 2 SVC ROUTINE.                            02920000
*                                                                       02940000
*APPLICABILITY-          OPTION 4 ONLY                                  02960000
*                                                                       02980000
*EXTERNAL REFERENCES-    NONE                                           03000000
*                                                                       03020000
*SVC'S USED              GETMAIN                                        03040000
*                                                                       03060000
*INPUT                   NONE                                           03080000
*                                                                       03100000
* MACRO EXPANSION EXAMPLES                                              03120000
*                                                                       03140000
DUMMY1   DSECT                                                          03160000
         USING *,1                                                      03180000
         SPACE 2                                                        03200000
*  EXAMPLE 1........SPECIFIES THAT IF SIGNIFICANCE AND FLOATING POINT   03220000
*                   DIVIDE INTERRUPTIONS OCCUR CONTROL WILL BE PASSED   03240020
*                   TO LOCATION SPECIFIED BY REGISTER 6.                03260000
         SPACE 2                                                        03280000
         SPIE  (6),(14,15)                                              03300000
         SPACE 2                                                        03320000
*  EXAMPLE 2........SPECIFIES THAT PROGRAM INTERRUPTION TYPES 1         03340000
*                   THROUGH 8,10 THROUGH 12 AND 15 OCCUR CONTROL        03360000
*                   WILL BE PASSED TO LOCATION 'ROUND'.                 03380000
         SPACE 2                                                        03400000
         SPIE  ROUND,((1,8),(10,12),15)                                 03420000
         SPACE 2                                                        03440000
*  EXAMPLE 3........IF A PREVIOUS SPIE MACRO HAD BEEN ISSUED AND        03460000
*                   THE PICA (PROGRAM INTERRUPT CONTROL ELEMENT)        03480000
*                   WAS TO BE RE-USED IT COULD HAVE BEEN SAVED          03500000
*                   IN ANOTHER REGISTER. THE PICA IS RETURNED IN        03520000
*                   REGISTER 1 FOR SUCCEEDING SPIE'S.                   03540000
         SPACE 2                                                        03560000
         SPIE  MF=(E,(5))                                               03580000
         SPACE 2                                                        03600000
*                                                                       03620000
*        THE ABOVE MACRO EXPANSIONS ARE NOT TO BE MISCONSTRUED          03640000
*  AS BEING AN EXECUTABLE PORTION OF THIS SPIE SVC SERVICED ROUTINE.    03660000
*  THESE MACRO EXPANSIONS SERVE ONLY TO ILLUSTRATE WHAT SOME OF         03680000
*  THE VARIOUS FORMS OF THE EXPANSION LOOK LIKE.                        03700000
*OUTPUT                1.PIE  PROGRAM INTERRUPT ELEMENT                 03720000
*                        THE PIE BLOCK IS INITIALIZED TO 0.             03740000
*                        THE PICA ADDRESS IS PLACED INTO THE            03760000
*                        FIRST WORD OF THE PIE.                         03780000
*                                                                       03800000
*                      2.REGISTER 1 IS RETURNED WITH THE ADDRESS        03820000
*                                   OF THE PREVIOUS PICA. THE           03840000
*                                   FIRST TIME THROUGH SPIE'S           03860000
*                                   PICA ADDRESS WILL BE 0.             03880000
*                                                                       03900000
*ENTRY POINTS-         1.IGC014- SPIE ROUTINE ENTRY POINT               03920000
*                        GIVEN CONTROL BY SVC FIRST LEVEL               03940000
*                        INTERRUPT HANDLER(FLIH) VIA LPSW               03960000
*                        IN ORDER TO PERFORM THE SPIE FUNCTION          03980000
*                        REQUESTED BY THE CALLER. AN SVC 14             04000000
*                        IS ISSUED BY THE CALLER.                       04020000
*                                                                       04040000
*                      2.THE PSW MUST BE.                               04060000
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           04080000
*                        EXCEPT FOR MACHINE CHECK,IN SUPERVISOR         04100000
*                        MODE AND HAVE A SUPERVISOR PROTECT KEY OF 0.   04120000
*                                                                       04140000
*                      3.THE REGISTERS CONTAIN.                         04160000
*                        REGISTERS 0-2,6-13 AND 15 CONTAIN              04180000
*                        THE CONTENTS IN THEM AT THE TIME               04200000
*                        SVC 14 WAS GIVEN.                              04220000
*                        REGISTER 3 CONTAINS THE ADDRESS OF             04240000
*                                  THE CVT TABLE.                       04260000
*                        REGISTER 4 CONTAINS THE ADDRESS OF             04280000
*                                   THE CURRENT TCB.                    04300000
*                        REGISTER 5 CONTAINS THE ADDRESS OF THE         04320000
*                                   RB AT THE TOP OF THE RB             04340000
*                                   QUEUE.                              04360000
*                        REGISTER 14 CONTAINS THE ADDRESS OF            04380000
*                                    THE TYPE 1 SVC EXIT                04400000
*                                    HANDLER.                           04420000
*                                                                       04440000
*EXIT POINTS-          1. TO THE TYPE 2 SVC EXIT ROUTINE VIA            04460000
*                        A BRANCH REGISTER 14.                          04480000
*                                                                       04500000
*                      2.THE PSW IS.                                    04520000
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           04540000
*                        EXCEPT MACHINE CHECK,IN SUPERVISOR             04560000
*                        MODE AND HAVE SUPERVISOR PROTECT KEY           04580000
*                        OF 0.                                          04600000
*                                                                       04620000
*                      3.REGISTERS 0,2-5,8,9,11-14 ARE UNALTERED        04640000
*                                  ACROSS THE SPIE ROUTINE              04660000
*                        REGISTER 1 WILL CONTAIN THE ADDRESS            04680000
*                                  OF THE PREVIOUS PICA.                04700000
*                                                                       04720000
*                        REGISTER 15 WILL RETURN A COMPLETION           04740000
*                                   CODE OF 0.                          04760000
*                                                                       04780000
*TABLES AND CONTROL                                                     04800000
*BLOCKS REFERENCED-    1.TCB TASK CONTROL BLOCK                         04820000
*                        THE CONTROLLING BLOCK UNDER WHICH              04840000
*                        THE TASK IS OPERATING.                         04860000
*                                                                       04880000
*                        TCBPIE- POINTER TO THE PROGRAM INTERRUPT       04900000
*                                ELEMENT, SET AND TESTED BY SPIE.       04920000
*                                                                       04940000
*                      2.PICA- PROGRAM INTERRUPT CONTROL AREA           04960000
*                              CONTAINING THE PROGRAM MASK,             04980000
*                              EXIT ROUTINE ADDRESS,AND INTERRUPT       05000000
*                              MASK.                                    05020000
*                                                                       05040000
*                        PSW PROGRAM MASK- IS TESTED BY SPIE            05060000
*                                                                       05080000
*                      3.RB (REQUEST BLOCK)                             05100000
*                              BITS 0-7 MODIFIED BY SPIE.               05120000
*                                                                       05140000
*ERROR EXIT POINTS-      NONE                                           05160000
*                                                                       05180000
*LIST ORIGINS,TABLES                                                    05200000
*AND CONTROL BLOCKS                                                     05220000
*INCLUDED-               NONE                                           05240000
*                                                                       05260000
*RESTRICTIONS ON                                                        05280000
*USE OF ROUTINE-         NONE                                           05300000
*                                                                       05320000
*NOTES-                  NONE                                           05340000
*                                                                       05360000
*                                                                       05380000
         EJECT                                                          05400000
IGC014   CSECT                                                          05420000
* SPIE (SVC 14)  SET PROGRAM INTERRUPT EXIT                             05440000
         SPACE 1                                                        05460000
*      (PICA) PROGRAM INTERRUPTION CONTROL BLOCK                        05480000
* BYTES      0               1      2       3         4     5           05500000
*        XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX      05520000
*        X      X PROG X                         X               X      05540000
*        X      X RAM  X  EXIT ROUTINE ADDRESS   X  INTERRUPTION X      05560000
*        X 0000 X MASK X                         X     MASK      X      05580000
*        XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX      05600000
         SPACE 2                                                        05620000
* FUNCTION                                                              05640000
*        THE SPIE SVC ROUTINE PROVIDES A MEANS BY WHICH A PROBLEM       05660000
*   PROGRAM CAN SPECIFY AN ERROR EXIT ROUTINE. THIS ERROR EXIT          05680000
*   ROUTINE WILL OPERATE IN RESPONSE TO ONE OR MORE PROGRAM ERROR       05700000
*   INTERRUPTIONS.                                                      05720000
*  THE PROGRAM MASK IN THE OPSW , IN THE CALLERS RB,                    05740000
*  WILL BE SET AS SPECIFIED BY THE                                      05760000
         CNOP  0,8                                                      05780000
         BALR  XRBASE10,0                                               05800000
         USING *,XRBASE10               ESTABLISH BASE                  05820000
         L     XRPIE,TCBPIE(XROTCB)     LD PIE POINTER FROM TCB         05840000
         LTR   XRPIE,XRPIE             Q. IS PIE PRESENT                05860000
         BC    7,PIEPRES                YES/BRANCH TO PIEPRES PROCESS   05880000
         SPACE 1                                                        05900000
*   WITH THE PIE ABSENT A PIE WILL BE CONSTRUCTED. THIRTY-TWO BYTES OF  05920000
* CORE FROM SUBPOOL ZERO WILL BE OBTAINED. THE ADDRESS OF THIS NEWLY    05940000
* CREATED PIE WILL BE PLACED INTO THE TCB.                              05960000
         SPACE 1                                                        05980000
         LR    XRSAVE,XRPICADR          SAVE INPUT REGISTER             06000000
         GETMAIN R,LV=32,SP=250        GET CORE TO BUILD PIE            06020000
         ST    XRGMPIE,TCBPIE(XROTCB)   ST NEW PIE ADR IN TCB           06040000
         L     XRPRIRB,NXTRBS(XRORB)       LOAD PREVIOUS RB        8764 06046014
         MVN   TCBPIE(1,XROTCB),RBOPSW+4(XRPRIRB) SAVE OLD PGM MSK 8764 06052014
         XC    0(32,XRGMPIE),0(XRGMPIE) ZERO PIE                        06060000
         LR    XRPIE,XRGMPIE            PLACE PIE ADR. IN WORK REG      06080000
         LR    XRPICADR,XRSAVE          RESTORE PICA INPUT PARAMETER    06100000
         SPACE 2                                                        06120000
*   WITH THE PIE CONSTRUCTED THE CURRENT PICA ADDESS IS EXTRACTED       06140000
* FROM THE PIE AND RETURNED IN REGISTER 1. THE FIRST SPIE SVC           06160000
* ISSUED FOR A ROUTINE WILL RETURN ZERO IN REG 1.                       06180000
         SPACE 1                                                        06200000
PIEPRES  L     XRPICAOL,0(XRPIE)       SAVE OLD PICA ADR OF PIE         06220000
         LA    XRPICADR,0(XRPICADR)     CLEAR HIGH BYTE        AB 69379 06230021
         ST    XRPICADR,0(XRPIE)        ST INPUT PICA ADR IN PIE        06240000
         SPACE 2                                                        06260000
*  THE PROGRAM MASK IN THE OPSW IS CLEARED AND THE PROGRAM              06280000
*  MASK IN THE PICA IS PLACED THERE.                                    06300000
         SPACE 1                                                        06320000
         L     XRPRIRB,NXTRBS(XRORB)   LOAD THE PREVIOUS RB             06340000
         NI    RBOPSW+4(XRPRIRB),PGMZERO  ZERO THE OPSW                 06360000
         LTR   XRPICADR,XRPICADR        CHK FOR INPUT PICA              06380000
         BC    8,RESETINA                                          8764 06400014
         OC    RBOPSW+4(1,XRPRIRB),0(XRPICADR)  SET MASK                06420000
         BC    15,RESETINB                                         8764 06430014
RESETINA MVN   RBOPSW+4(1,XRPRIRB),TCBPIE(XROTCB) RESET OLD MSK    8764 06440014
         L     XRPICADR,TCBPIE(XROTCB) GET ADDR OF PIE        AB A59872 06442021
         LA    XRPICADR,0(XRPICADR)    CLEAR PGM INT MASK     AB A59872 06444021
         L     0,PIESIZE               GET SIZE AND SUBPOOL   AB A59872 06446021
         XC    TCBPIE(4,XROTCB),TCBPIE(XROTCB) ZERO PIE PTR   AB A59872 06448021
         FREEMAIN  R,LV=(0),A=(1)      FREE THE PIE           AB A59872 06448421
RESETINB LR    XRPICADR,XRPICAOL                                   8764 06450014
         BR    XRRETURN               * GO TO TYPE 2 SVC HANDLER        06460000
PIESIZE  DC    X'FA000020'            SIAE AND SUBPOOL FOR PIE   A59872 06470021
         EJECT                                                          06480000
*ROUTINE NAME-           IGC040- EXTRACT SVC ROUTINE                    06500000
*                                                                       06520000
*FUNCTIONS-              TO EXTRACT ONE OR ALL OF SEVEN FIELDS          06540000
*                        WITHIN A TASK CONTROL BLOCK. THE TCB           06560000
*                        FROM WHICH INFORMATION MAY BE EXTRACTED        06580000
*                        MAY BE FROM EITHER THE ISSUER'S OR             06600000
*                        ONE OF IT'S SUBTASKS.                          06620000
*                                                                       06640000
*ENTRY POINT NAMES-      IGC040- EXTRACT SVC ENTRY POINT                06660000
*                                                                       06680000
*CONTAINED IN MODULE-    IEAQTB00- TASK CONTROL BLOCK EFFECTOR          06700000
*                                                                       06720000
*ATTRIBUTES-             RESIDENT,RE-ENTRANT,SUPERVISOR STATE,          06740000
*                        TYPE 1 SVC ROUTINE                             06760000
*                                                                       06780000
*APPLICABILITY-          OPTION 4 ONLY                                  06800000
*                                                                       06820000
*EXTERNAL REFERENCES-    IEATCBP- LOCATION 'NEW' AND'OLD'               06840000
*                        IEABTERM- ABTERM                               06860000
*                        SVCXT- TYPE1 SVC EXIT ROUTINE                  06880000
*                                                                       06900000
*SVC'S USED-             NONE                                           06920000
*                                                                       06940000
*INPUT-                  ADDRESS OF PARAMETER LIST IN REGISTER 1.       06960000
*                                                                       06980000
* MACRO EXPANSION EXAMPLES                                              07000000
*                                                                       07020000
DUMMY2   DSECT                                                          07040000
         USING *,1                                                      07060000
         SPACE 2                                                        07080000
* EXAMPLE  1........ALL SEVEN FIELDS (TCBGRS,TCBFRS,TCBAETX,TCBPRI,     07100020
*                   TCBCMC,TCBTIOT) WILL BE EXTRACTED FROM THE TCB.     07120020
*                   'P255' SPECIFIES THE ADDRESS OF A VARIABLE LENGTH   07140000
*                   LIST OF CONSECUTIVE FULL-WORDS OF MAIN STORAGE.     07160000
         SPACE 2                                                        07180000
         EXTRACT P255,'S',FIELDS=(ALL)                                  07200000
         SPACE 2                                                        07220000
* EXAMPLE 2.........THREE FIELDS WILL BE EXTRACTED FROM THE TCB         07240020
*                   INDICATED BY TCBLOC. THE ADDRESS OF THE GENERAL     07260000
*                   REGISTER SAVE AREA IS STORED INTO THE FIRST         07280000
*                   WORD OF THE FULL WORD AT LOCATION 'P255'.           07300000
         SPACE 2                                                        07320000
         EXTRACT P255,TCBOK,FIELDS=(GRS)                           MTS0 07340016
         SPACE 2                                                        07360000
* EXAMPLE 3.........A PARAMETER LIST WILL BE CREATED AT A LOCATION      07380000
*                   'EXLIST'.  PARAMETER ROUND IS THE ADDRESS OF        07400000
*                   THE LIST WHERE THE EXTRACTED FIELDS WILL BE         07420000
*                   PLACED. THE ISSUER'S TCB WILL BE EXTRACTED FROM.    07440000
         SPACE 2                                                        07460000
EXLIST   EXTRACT ROUND,'S',FIELDS=(ALL)                                 07480000
         SPACE 2                                                        07500000
* EXAMPLE 4.........SPECIFIES AN EXISTING PARAMETER LIST AT LOCATION    07520000
*                   'EXLIST'.  ONLY THE TCB TO BE EXTRACTED FROM        07540000
*                   IS ALTERED IN 'EXLIST' DYNAMICALLY.                 07560000
         SPACE 2                                                        07580000
         EXTRACT ,P255,MF=(E,EXLIST)                                    07600000
         SPACE 2                                                        07620000
* EXAMPLE 5.........WILL CREATE ONLY A PARAMETER LIST AT LOCATION       07640000
*                   ABLE.  ANOTHER MACRO-INSTRUCTION, OF THE 'E'        07660000
*                   FORM COULD LOAD THE LIST.                           07680000
         SPACE 2                                                        07700000
         EXTRACT ,,MF=L                                                 07720000
         SPACE 2                                                        07740000
* EXAMPLE 6........ALL ELEVEN FIELDS THAT CAN BE EXTRACTED WILL BE      07750020
*                  LOCATED USING THE TCB SPECIFIED AND RETURNED IN THE  07752020
*                  11 WORD LIST AT ADDRESS '255'.                       07754020
         SPACE 2                                                        07756020
         EXTRACT  P255,TCBOK,FIELDS=(ALL,COMM,TSO,PSB,TJID)             07756420
*        THE ABOVE MACRO EXPANSIONS ARE NOT TO BE MISCONSTRUED          07760000
*   AS BEING AN EXECUTABLE PORTION OF THIS EXTRACT SVC SERVICE ROUTINE  07780000
*   THESE MACRO EXPANSIONS SERVE ONLY TO ILLUSTRATE WHAT SOME OF        07800000
*   THE VARIOUS FORMS OF THE EXPANSION LOOK LIKE.                       07820000
*OUTPUT-                 EXTRACT LIST- ADDRESS OF LIST IS               07840000
*                        PROVIDED BY THE USER. THIS LIST                07860000
*                        PROVIDES THE INTERMEDIARY BY WHICH EXTRACTED   07880000
*                        INFORMATION FROM THE TCB IS MADE KNOWN         07900000
*                        TO THE PROBLEM PROGRAM.                        07920000
*                                                                       07940000
*ENTRY POINTS-         1.IGC040- EXTRACT SVC ROUTINE ENTRY POINT.       07960000
*                        GIVEN CONTROL BY THE SVC FIRST LEVEL           07980000
*                        INTERRUPT HANDLER (FLIH) VIA AN LPSW,          08000000
*                        IN ORDER TO PERFORM THE EXTRACT FUNCTION       08020000
*                        REQUESTED BY THE CALLER. AN SVC 40             08040000
*                        IS ISSUED BY THE CALLER.                       08060000
*                                                                       08080000
*                      2.THE PSW MUST BE                                08100000
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           08120000
*                        EXCEPT MACHINE CHECK,IN SUPERVISOR             08140000
*                        MODE AND HAVE SUPERVISOR PROTECT KEY.          08160000
*                                                                       08180000
*                      3.THE REGISTERS CONTAIN.                         08200000
*                                                                       08220000
*                        REGISTER 1 CONTAINS THE ADDRESS OF             08240000
*                        THE INPUT PARAMETER LIST.                      08260000
*                                                                       08280000
*                        REGISTERS 0,2,6-12 AND 15 CONTAIN              08300000
*                        THE CONTENTS AT THE TIME SVC 40 WAS            08320000
*                        GIVEN.                                         08340000
*                                                                       08360000
*                        REGISTER 3 CONTAINS THE ADDRESS OF THE         08380000
*                        CVT TABLE.                                     08400000
*                                                                       08420000
*                        REGISTER 4 CONTAINS THE ADDRESS OF THE         08440000
*                        CURRENT TCB.                                   08460000
*                                                                       08480000
*                        REGISTER 5 CONTAINS THE ADDRESS OF THE         08500000
*                        RB AT THE TOP OF THE RB QUEUE.                 08520000
*                                                                       08540000
*                        REGISTER 14 CONTAINS THE RETURN                08560000
*                        ADDRESS OF THE CALLER.IN THE                   08580000
*                        CASE OF THE SVC FLIH BEING THE                 08600000
*                        CALLER REGISTER 14 CONTAINS                    08620000
*                        THE ADDRESS OF THE TYPE 1 SVC                  08640000
*                        EXIT ROUTINE.(SVCXT)                           08660000
*                                                                       08680000
*EXIT POINT-           1.TO THE CALLING ROUTINE VIA                     08700000
*                        A BRANCH REGISTER 14.                          08720000
*                                                                       08740000
*                      2.THE PSW IS.                                    08760000
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           08780000
*                        EXCEPT MACHINE CHECK,IN SUPERVISOR             08800000
*                        MODE AND HAVE SUPERVISOR PROTECT KEY           08820000
*                        OF 0.                                          08840000
*                                                                       08860000
*                      3.REGISTERS 0,1,3-5 AND 14 ARE UNALTERED.        08880000
*                                                                       08900000
*ERROR EXIT POINTS-    1.TO ABTERM IN ORDER TO CAUSE THE ISSUING        08920020
*                        TASK TO BE TERMINATED.                         08940000
*                                                                       08960000
*                      2.THE PSW IS.                                    08980000
*                        DISABLED FOR ALL MASKABLE INTERRUPTS           09000000
*                        EXCEPT FOR MACHINE CHECK, IN SUPERVISOR        09020000
*                        MODE AND HAVE A PROTECT KEY OF 0.              09040000
*                                                                       09060000
*                      3.REGISTER 1 WILL CONTAIN THE ERROR CODE.        09080000
*                                                                       09100000
*                      4.REGISTERS 0,3-5,   AND 14 CONTAIN THE          09120000
*                        INFORMATION IN THEM AT THE TIME SVC            09140000
*                        40 WAS GIVEN.                                  09160000
*                                                                       09180000
*                      5.THE ERROR CODE IS.                             09200000
*                        X'0128' ERROR = 1 THE EXTRACT LISTIS INVALID   09220000
*                       X'0228' ERROR # 2  INPUT ADDRESS OF PARA-       09240000
*                                          METER LIST IS INVALID.       09260000
*                        X'0328' ERROR 3 SPECIFIED SUB TASK INVALID     09280000
*                                                                       09300000
*                      6.REGISTER 13 CONTAINS THE ADDRESS OF THE        09320000
*                        ABTERM ROUTINE.                                09340000
*                                                                       09360000
*                                                                       09380000
*TABLES AND CONTROL                                                     09400000
*BLOCKS REFERENCED-    1.TCB- TASK CONTROL BLOCK                        09420000
*                        THE CONTROLLING BLOCK UNDER WHICH              09440000
*                        THE TASK IS OPERATING.                         09460000
*                                                                       09480000
*                        THE FOLLOWING FIELDS ARE EXTRACTABLE.          09500000
*                                                                       09520000
*                        TCBGRS- ADDRESS OF GENERAL REGISTER            09540000
*                        (GRS)   SAVE AREA. PLACED INTO WORD            09560000
*                                1 OF THE EXTRACT LIST.                 09580000
*                        TCBFRS- ADDRESS OF FLOATING POINT              09600000
*                        (FRS)   SAVE AREA. PLACED INTO WORD            09620000
*                                2 OF THE EXTRACT LIST.                 09640000
*                        RES-    RESERVED, ZEROS PLACED IN WORD         09660020
*                                3 OF EXTRACT LIST                      09670020
*                        TCBAETX- ADDRESS OF THE ENTRY POINT TO         09740000
*                        (AETX)   THE ASYNCHRONOUS TERMINATION          09760000
*                                 ROUTINE. PLACED INTO WORD 4           09780000
*                                 OF THE EXTRACT LIST.                  09800000
*                        TCBLMP-  LIMIT PRIORITY AND                    09820000
*                        TCBDSP   DISPATCHING PRIORITY.                 09840000
*                        (PRI)    PLACED IN TO WORD 5 OF THE            09860000
*                                 EXTRACT LIST.                         09880000
*                        TCBCMP- TASK COMPLETION CODE                   09900000
*                        (CMC)   PLACED INTO WORD 6 OF THE              09920000
*                                EXTRACT LIST                           09940000
*                        TCBTIO- ADDRESS OF TASK INPUT/OUTPUT           09960000
*                        (TIOT)  TABLE.                                 09980000
*                                PLACED IN TO WORD 7 OF THE             10000000
*                                EXTRACT LIST.                          10020000
*                        COMM-   ADDRESS OF COMMUNICATION AREA OF       10050020
*                                CSCB                                   10050420
*                                PLACED INTO WORD 8 OF THE              10052020
*                                EXTRACT LIST                           10054020
*                        TCBTSFLG-TIME SHARING OPTION FLAGS, ADDRESS    10056020
*                        (TSO)   OF THIS FIELD IS RETURNED IN WORD 9    10058020
*                                OF THE EXTRACT ANSWER AREA             10058420
*                        JSCBPSCB-ADDRESS OF THE PROTECTED STORAGE      10058820
*                        (PSB)    CONTROL BLOCK IS RETURNED IN WORD 10  10059620
*                                 OF THE EXTRACT ANSWER AREA            10059720
*                        JSCBTJID-TSO TERMINAL JOB IDENTIFIER FOR THIS  10059820
*                        (TJID)   TASK IS RETURNED IN WORD 11 OF THE    10059920
*                                 EXTRACT ANSWER AREA                   10066620
*                      2.IRB INTERRUPT REQUEST BLOCK                    10073320
*                        THE CONTROLLING BLOCK UNDER WHICH              10080000
*                        THE INTERRUPT ROUTINE OPERATES.                10100000
*                                                                       10120000
*                        RBEP- ADDRESS OF AETX ROUTINE.                 10140000
*                              EXTRACTED BY EXTRACT ROUTINE             10160000
*                              AND PLACED INTO EXTRACT LIST.            10180000
*                                                                       10200000
*                      3.IEATCBP-POINTER TO LOCATION 'OLD'              10220000
*                                FROM WHICH THE EXTRACT                 10240000
*                                ROUTINE OBTAINS THE CURRENT            10260000
*                                TCB.                                   10280000
*                                                                       10300000
*LIST ORIGINS,TABLES                                                    10320000
*AND CONTROL BLOCKS-     NONE                                           10340000
*                                                                       10360000
*RESTRICTIONS ON                                                        10380000
*USE OF ROUTINE-         NONE                                           10400000
*                                                                       10420000
*NOTES-                  THE ASYNCHRONOUS EXIT ENTRY POINT              10440000
*                        SPECIFIED BY THE ETXR ROUTINE IN ATTACH IS     10460000
*                        IN REALITY STORED INTO AN IRB.                 10480000
*                        IT IS ONLY THROUGH THE USE OF THE              10500000
*                        TCB'S IQE THAT THE IRB CAN BE                  10520000
*                        REFERENCED TO OBTAIN THIS ADDRESS              10540000
*                        DURING EXTRACT.                                10560000
*                                                                       10580000
*                          IF A SUPERVISOR ROUTINE IS AWARE             10600000
*                        THAT IT IS REFERENCING DATA WHO'S              10620000
*                        STORAGE KEY IS VALID BUT WILL NOT              10640000
*                        PASS THE VALIDITY CHECK ROUTINE                10660000
*                        EMPLOYED BY THIS ROUTINE ,A BRANCH             10680000
*                        ENTRY SHOULD BE USED.  THAT IS                 10700000
*                        THIS ROUTINES ADDRESS + 8.                     10720000
         EJECT                                                          10740000
IGC014   CSECT                                                          10760000
* EXTRACT (SVC 40)                                                      10780000
         SPACE 1                                                        10800000
* INPUT PARAMETER                                                       10820000
**********************                                                  10840000
*       *  LIST ADR  *                                                  10860000
**********************                                                  10880000
*      * TCB LOC ADR *                                                  10900000
**********************                                                  10920000
* EXTRACT FIELD      *                                                  10940000
**********************                                                  10960000
         SPACE 2                                                        10980000
*  BIT MEANING IN FIELD. ON (1) MEANS EXTRACT INFORMATION               11000000
*  0 BIT (GRS)  ADDRESS OF TCB GENERAL REGISTER LOCATION                11020000
*  1 BIT (FRS)  ADDRESS OF TCB FLOATING REGISTER LOCATION               11040000
*  2 BIT (RES)  RESERVED                                                11060020
*  3 BIT (AETX) ADDRESS OF TCB ASYNCHRONUS TERMINATE ROUTINE            11080000
*  4 BIT (PRI)  TCB LIMIT AND DISPATCHING PRIORITY                      11100000
*  5 BIT (CMC)  TCB COMPLETION CODE                                     11120000
*  6 BIT (TIOT) ADDRESS OF TASK I/O TABLE                               11140000
*  7 BIT (COMM) ADDRESS OF COMMUNICATION AREA IN CSCB                   11150019
*  8 BIT (TSO) ADDRESS OF TIME SHARING TCB FLAGS                  20021 11152020
*  9 BIT (PSB) ADDRESS OF PROTECTED STORAGE CONTROL BLOCK         20021 11154020
* 10 BIT (TJID) TIME SHARING TERMINAL ID                          20021 11156020
         SPACE 2                                                        11160000
*  EXTRACT ROUTINE                                                      11180000
*        THIS ROUTINE EXTRACTS INFORMATION FROM REQUESTING TCB OR FROM  11200020
* IT'S DAUGHTER TCB, THE TCB ADDRESS WILL BE IN THE SECOND WORD OF      11220000
* INPUT LIST SPECIFIED BY INPUT REGISTER (1). NO TCB VALIDITY CHECK IS  11240000
* MADE.                                                                 11260000
*        THE LIST ADDRESS (LOCATION WHERE EXTRACTED INFORMATION         11280000
*  IS TO BE STORED) IS CHECKED FOR CORRECT PROTECT KEY.                 11300000
*        THE INFORMATION TO BE EXTRACTED IS FLAGGED IN THE FIELD BYTE   11320000
*  OF THE INPUT PARAMETER.                                              11340000
         SPACE 2                                                        11360000
         CNOP  0,8                                                      11380000
IGC040   BALR  XRBASE,0                                                 11400000
         USING *,XRBASE                                                 11420000
         SR    XRIND,XRIND             SET SVC INDICATOR                11440000
         B     VALCHECK                                                 11460000
         BALR  XRIND,0                 SET BRANCH ENTRY IND.            11480000
         B     SVCENTRY                                                 11500000
         SPACE 1                                                        11520000
*  TEST INPUT LIST TO FIND IF REQUESTING TCB OR DAUGHTER TCB            11540000
*  INFORMATION SHOULD BE EXTRACTED.                                     11560000
         SPACE 2                                                        11580000
         SPACE 2                                                        11600000
VALCHECK TM    33(0),X'F0'             Q. IS ENTRY VIA SUP. TASK        11620000
         BZ    SVCENTRY                YES,TAKE BRANCH                  11640000
         L     XRABTERM,ABTERM         LOAD ABTERM'S ADDRESS            11660000
         LR    XRSAVE,XRPADR           SAVE INPUT REGISTER              11680000
         L     XRTSTADR,CHECK          LOAD ADDRESS OF VAL. CHECK       11700000
         BAL   XRLINK,4(XRTSTADR)      Q. IS INPUT LIST VALID           11720000
         BNE   ERROR3                  NO, TAKE BRANCH                  11740000
         LR    XRPADR,XRSAVE           RESTORE INPUT PARAMETER ADDR     11760000
SVCENTRY EQU   *                                                   2144 11768018
         L     XRABTERM,ABTERM          GET ABTERMS ADDR IN        2144 11776018
*                                       CASE USER IN SUP STATE     2144 11784018
         L     XRTSTADR,CHECK           LOAD ADDR OF VAL. CK  AC  M4905 11786021
         L     XRLIST,0(XRPADR)         LOAD LIST ADDRESS          2144 11792018
         L     XRFIELD,8(XRPADR)       LOAD FIELD CONTENT               11800000
         L     XRETCB,4(,XRPADR)       LOAD TCB FIELD         AC  M4905 11820021
         LTR   XRETCB,XRETCB           SUB-TASK OR OWN TCB              11840000
         BNZ   LOADLIST                SUB-TASK, BRANCH       AC A50600 11860021
         LR    XRETCB,XROTCB           LOAD OWN TCB                     11880000
         TM    33(0),X'F0'             Q. IS ENTRY VIA SUP. TASK        11900000
         BZ    GOFIRST                 YES, TAKE BRANCH                 11920000
         B     TCBOK                                                    11940000
LOADLIST EQU   *                                              AC A50600 11960021
         LR    XRTESTWD,XRETCB         LD ADDR OF TCB LOC WD  AC A50600 11970021
         BAL   XRLINK,4(,XRTSTADR)     Q. LOC WD ADDR VALID   AC A50600 11972021
         BNE   ERROR5                  NO, TAKE BRANCH        AC A50600 11974021
         LA    XRETCB,0(XRETCB)         GET TCB ADDR          AB A66120 11980021
         CLR   XRETCB,XROTCB          Q.EXTRACTING FROM A SUB-TASK      12000000
         BC    8,TCBOK                 NO TAKE BRANCH                   12020000
         SPACE 2                                                        12040000
*  SEARCH THE IMMEDIATE FAMILY FOR THE SUB-TASK.  IF NOT                12060000
*  PRESENT ABTERM THE REQUESTOR.                                        12080000
         SPACE 2                                                        12100000
         L     XRTCBTST,TCBDTC(XROTCB)      GET NEXT TCB IN FAMILY      12120000
TRYAGAIN LTR   XRTCBTST,XRTCBTST       Q. IS SUB-TASK PRESENT           12140000
         BC    8,ERROR5                NO SUB TASK                      12160000
TRY      CR    XRTCBTST,XRETCB     WAS TCB FOUND                   296  12180000
         BC    8,TCBOK                 YES TAKE BRANCH                  12200000
         L     XRTCBTST,TCBSTC(XRTCBTST)  GET 1ST. SISTER TCB           12220000
         LTR   XRTCBTST,XRTCBTST     Q. IS SISTER PRESENT               12240000
         BZ    ERROR5                  NO SUBTASK                       12260000
         B     TRY                     GO TO TEST TCB                   12280000
         SPACE 2                                                        12300000
*  IF ENTRY IS BY SUPERVISER, SKIP THIS SECTION. IF NOT, TEST  AC 21372 12320021
*  IF LIST ADDRESS WHERE EXTRACTED INFORMATION IS TO BE STORED AC 21372 12340021
*  IS IN THE CORRECT PROTECT KEY. IF WRONG PROTECT KEY, ABTERM AC 21372 12360021
         SPACE 2                                                        12380000
TCBOK    LR    XRTESTWD,XRLIST         $ LOAD ADDRESS OF LIST           12400000
         BAL   XRLINK,4(XRTSTADR)      Q. EXTRACT LIST VALID            12420000
         BNE   ERROR1                ***NO BRANCH                       12440000
         LA    XRCOUNT,FLDSIZE         $LOAD FIELD SIZE MINUS 1         12460000
         LA    XRSHIFT,1(XRCOUNT)       LD FIELD SIZE                   12480000
         LR    XRTSTFLD,XRFIELD         LD FIELD CONTENT                12500000
LOOP2    ALR   XRTSTFLD,XRTSTFLD       Q.FIELD TO BE EXTRACTED          12520000
         BC    3,SHIFTCTR               YES BRANCH                      12540000
         BCT   XRCOUNT,SHIFTCTR         DECREMENT FIELD COUNTER         12560000
SHIFTCTR BCT   XRSHIFT,LOOP2           Q.DECREMENT SHIFT CTR (NOT 0 BR) 12580000
         SLL   XRCOUNT,2               ADJUST FROM BYTES TO WORDS       12600000
         LA    XRTESTWD,0(XRCOUNT,XRLIST) LD LAST LIST ADR              12620000
         L     XRTSTADR,CHECK          LOAD ADDRESS OF VAL. CHECK       12640000
         BAL   XRLINK,4(XRTSTADR)      Q. LAST ENTRY VALID              12660000
         BNE   ERROR1                ***NO BRANCH                       12680000
GOFIRST  LA    XRLINK,BITS              LD ADR OF FIRST TEST            12700000
         B     SHIFT                                                    12720000
         SPACE 1                                                        12740000
*  TEST REGISTER. Q. INDICATE SOMETHING TO STORE IN LIST. IF YES        12760000
*  STORE REGISTER CONTENT AND UPDATE LIST ADDRESS, NOTHING TO STORE GO  12780000
*  TO NEXT SECTION.                                                     12800000
         SPACE 2                                                        12820000
QSTORE   BC    12,SHIFT                Q.EXTRACT INFORMATION (NO BR)    12840000
         ST    XRINF,0(XRLIST)          ST EXTRACTED INFO IN LIST       12860000
         LA    XRLIST,4(XRLIST)         UPDATE LIST ADR                 12880000
         SPACE 2                                                        12900000
*  SHIFT FIELD CONTENT LEFT 1 TO SET CONDITON CODE. IF INFORMATION TO   12920000
* BE EXTRACTED, CONDITION CODE WILL BE CARRY.                           12940000
         SPACE 1                                                        12960000
SHIFT    ALR   XRFIELD,XRFIELD          SHIFT FIELD LEFT 1              12980000
         BR    XRLINK                                                   13000000
         SPACE 1                                                        13020000
*  (GRS) LOAD LOAD EXTRACT TCB'S GENERAL REGISTER SAVE AREA ADDRESS.    13040000
         SPACE 1                                                        13060000
BITS     LA    XRINF,TCBGRS(XRETCB)     LD ADR OF GENERAL REGISTER SAVE 13080000
         BAL   XRLINK,QSTORE          **                                13100000
         SPACE 2                                                        13120000
*  (FRS) LOAD EXTRACT TCB'S FLOATING POINT REGISTER SAVE AREA ADDRESS.  13140000
         SPACE 1                                                        13160000
         BC    12,EX1                  Q.FRS BIT ON (NO BR)             13180000
         LA    XRINF,TCBFPS             LD FLOATING POINT DISPLACEMENT  13200000
         LNR   XRINF,XRINF              MAKE DISPLACEMENT NEGATIVE      13220000
         AR    XRINF,XRETCB             ADD EXTRACT TCB'S ADR           13240000
EX1      BAL   XRLINK,QSTORE          **                                13260000
         SPACE 2                                                        13280000
*    (RES) THIRD WORD OF LIST RESERVED                                  13300020
         SPACE 1                                                        13320000
         LA    XRINF,0                  LOAD ZEROES               M2973 13340020
         BAL   XRLINK,QSTORE          **                                13360000
         SPACE 2                                                        13380000
* (AETX) LOAD ASNCHRONUS TERMINATE ROUTINE ADDRESS.                     13400000
         SPACE 1                                                        13420000
         BC    12,EX2                 Q. ETXR BIT SET                   13440000
         L     XRINF,IQEPTR(XRETCB)    GET IQE ADDRESS                  13460000
         LTR   XRINF,XRINF            Q. ETXR ADDRESS PRESENT           13480000
         BC    8,EX3                   ZERO TAKE BRANCH                 13500000
         L     XRINF,IRBPTR(XRINF)     GET IRB ADDRESS                  13520000
         L     XRINF,RBEP(XRINF)        LD ASYNCHRONUS TERMINATE ADR    13540000
EX3      LTR   XROTCB,XROTCB           RE-SET CONDIYION CODE            13560000
EX2      BAL   XRLINK,QSTORE           **                               13580000
         SPACE 2                                                        13600000
* (PRI) LOAD LIMIT AND DISP PRIORITY IN LOWER HALF OF REG.              13620000
         SPACE 1                                                        13640000
         MVC   HALF0+2(2),TCBLMP(XRETCB) PROPAGATE L AND D PRIORITY     13660000
         L     XRINF,HALF0              LD LIMIT AND DISPATCH PRIORITY  13680000
         BAL   XRLINK,QSTORE          **                                13700000
         SPACE 2                                                        13720000
*  (CMC) LOAD COMPLETION CODE OF TCB.                                   13740000
         SPACE 1                                                        13760000
         L     XRINF,TCBCMP(XRETCB)     LD COMPLETION CODE              13780000
         BAL   XRLINK,QSTORE          **                                13800000
         SPACE 2                                                        13820000
*  (TIOT) LOAD TASK INPUT OUTPUT TABLE ADDRESS.                         13840000
         SPACE 1                                                        13860000
         L     XRINF,TCBTIO(XRETCB)     LD TASK I/O ADR                 13880000
         BAL   XRLINK,QSTORE           **                               13881019
         SPACE                                                          13882019
* (COMM) LOAD COMMUNICATION AREA ADDRESS.                               13883019
         SPACE                                                          13884019
         L     XRINF,TCBJSCB(XRETCB)   LOAD JSCB ADDR                   13885019
         BC    12,EX8                  COMM BIT ON (NO BR)    AC  21372 13885421
         LTR   XRINF,XRINF             Q. JSCB PTR ZERO       AC  21372 13885821
         BZ    EX9                     YES BRANCH             AC  21372 13885921
         USING IEZJSCB,XRINF           JSCB ADDRESSABILITY              13886019
         L     XRINF,JSCBCSCB          LOAD CSCB ADDR                   13887019
         USING CSCB,XRINF              CSCB ADDRESSABILITY              13888019
         LA    XRINF,CHECBP            LOAD ECB/CIB PTR LIST ADDRESS    13889019
EX9      LTR   XROTCB,XROTCB           RESET CONDITION CODE    AC 21372 13889421
         DROP  XRINF                   REGISTER CONTAINS ANSWER         13890019
EX8      BAL   XRLINK,QSTORE                                   AC 21372 13892021
         SPACE 2                                                        13894020
*  (TSO) LOAD TCB TIME SHARING FLAG BYTE ADDRESS.                 20021 13896020
         SPACE                                                          13898020
         LA    XRINF,TCBTSFLG(XRETCB)  LOAD FLAG BYTE ADDRESS     20021 13900020
         BAL   XRLINK,QSTORE                                      20021 13902020
         SPACE 2                                                  20021 13904020
*  (PSB) LOAD PROTECTED STORAGE CONTROL BLOCK ADDRESS.            20021 13906020
         SPACE                                                          13908020
         L     XRINF,TCBJSCB(XRETCB)   LOAD JSCB ADDRESS          20021 13910020
         BC    12,EX4                                                   13912020
         LTR   XRINF,XRINF             Q JSCB PTR ZERO ?          20021 13914020
         BZ    EX5                     YES-TAKE BRANCH        AC  21372 13916021
         USING IEZJSCB,XRINF                                      20021 13918020
         L     XRINF,JSCBPSCB          LOAD ADDRESS OF PSCB       20021 13920020
EX5      LTR   XROTCB,XROTCB           RESET CONDITION CODE       20021 13922020
         DROP  XRINF                                              20021 13924020
EX4      BAL   XRLINK,QSTORE                                      20021 13926020
         SPACE 2                                                        13940000
         SPACE  2                                                 20021 13942020
*  (TJID) LOAD TIME SHARING OPTION TERMINAL ID                    20021 13944020
         SPACE                                                          13946020
         L     XRINF,TCBJSCB(XRETCB)   LOAD JSCB ADDRESS          20021 13948020
         BC    12,EX6                                                   13950020
         LTR   XRINF,XRINF             Q JSCB PTR ZERO ?          20021 13952020
         BZ    EX7                     YES-TAKE BRANCH        AC  21372 13954021
         USING IEZJSCB,XRINF                                      20021 13956020
         LH    XRINF,JSCBTJID          LOAD TERMINAL ID           20021 13958020
EX7      LTR   XROTCB,XROTCB           RESET CONDITION CODE       20021 13960020
         DROP  XRINF                                              20021 13962020
EX6      BAL   XRLINK,QSTORE                                      20021 13964020
         SPACE  2                                                       13966020
         BR    XRRETURN                                           20021 13968020
         SPACE  2                                                 20021 13970020
*  ERROR EXIT.                                                          13972020
ERROR1   LA    XRERCODE,ERRXRACT       $LD ERROR CODE                   13980000
         L     XRRETURN,ATYPE1XT       ADDR OF SVC1 EXIT RTN  AC A37037 13990021
         BR    XRABTERM              ***GO TO ABTERM ROUTINE            14000000
ERROR5   LA    XRERCODE,ERRAXT3        INVALID SUB TASK                 14020000
         L     XRRETURN,ATYPE1XT       ADDR OF SVC1 EXIT RTN  AC A37037 14030021
         BR    XRABTERM                                                 14040000
ERROR3   LA    XRERCODE,ERRXAT2        INPUT P LIST ADDRESS   AC A37037 14060021
*                                       INVALID               AC A37037 14062021
         L     XRRETURN,ATYPE1XT       ADDR OF SVC1 EXIT RTN  AC A37037 14070021
         BR    XRABTERM                GO TO ABTERM ROUTINE   AC A37037 14080021
         SPACE 2                                                        24400000
* DEFINE CONSTANT                                                       24420000
         SPACE 1                                                        24440000
         DS    0F                                                       24460000
ROUND    DC    X'00FFFFFC'                                              24480000
TESTBIT  DC    X'80000000'                                              24500000
HALF0    DC    X'0000FFFF'                                              24520000
P255     DC    H'255'                                                   24540000
         DS    0F                                                       24560000
         EXTRN IEA0VL01,IEA0AB01,IEA0XE00                     AC A37037 24580021
ABTERM   DC    A(IEA0AB01)             ABTERM'S ADDRESS                 24600000
CHECK    DC    A(IEA0VL01)             VALIDITY CHECK ADDRESS           24620000
TSKSWTR  DC    A(IEA0DS02)             ADR OF TASK SWITCH ROUTINE       24640000
ATYPE1XT DC    A(IEA0XE00)             ADDR OF TYPE 1 EXIT RT AC A37037 24650021
         END                                                            24660000
