         TITLE 'IEAQTM00 / ABEND0 - INTERFACES / IGC0001C'              00100000
IGC0001C START                                                          00200000
*                                                                       00300000
* SVC 13 (ABEND) CONSISTS OF THREE SOMEWHAT DISTINCT FUNCTIONS.   21472 00400000
* MODULES IGC0001C THRU IGC0K01C ARE EITHER USED BY OR RESERVED   21472 00500000
* FOR THE MAINLINE ABEND FUNCTION. MODULES IGC0L01C THRU IGC0Q01C 21472 00600000
* ARE EITHER USED BY OR RESERVED FOR THE DAMAGE ASSESSMENT        21472 00700021
* ROUTINES (DAR). MODULES IGC0R01C THRU IGC0Z01C ARE EITHER USED  21472 00800000
* BY OR RESERVED FOR THE ABEND/STAE INTERFACE ROUTINES (ASIR).    21472 00900000
* MODULES IGC0I01C AND IGC0O01C ARE NOT USED.                     21472 01000000
*                                                                       01100000
* MODULES IGC0$01C, IGC0#01C, AND IGC0@01C ARE TEMPORARILY        21472 01200000
* RESERVED FOR ANY FE/SE SERVICE AID ABEND MODULES. MODULES       21472 01300000
* IGCS*01C (WHERE * IS ANY DIGIT OR ANY CHARACTER OF THE 29       21472 01400000
* CHARACTER UNIVERSAL ALPHABET) ARE RESERVED FOR ANY NONSTANDARD  21472 01500000
* ABEND MODULES (INCLUDING THOSE THREE TEMPORARILY RESERVED FOR   21472 01600000
* FE/SE). NOTE- THESE RESERVATIONS ARE UNOFFICIAL, BY CONVENTION  21472 01700000
* OFFICIAL SVC 13 ROUTINES MAY USE ANY OF THE IGC**01C MODULES.   21472 01800000
*                                                                       01800821
* THE MAINLINE ABEND FUNCTION IS TO CLEANUP THOSE QUEUES                01801621
* RELATED TO THE TERMINATING TASK WHICH WERE CHANGED AS A               01802421
* RESULT OF THE CREATION AND EXECUTION OF THE TASK. IF THE              01803221
* TASK WAS THE INITIAL TASK OF THE JOBSTEP OR WAS A SYSTEM TASK,        01803321
* THOSE QUEUES WHICH CHANGED AS A RESULT OF THE THE TASK'S ALSO         01803421
* BEING IN SOME OTHER CLASSIFICATION ARE NOT CLEANED UP BY ABEND.       01803521
* THOSE QUEUES ARE CLEANED UP BY OTHER SYSTEM ROUTINES WHICH            01803621
* ARE GIVEN CONTROL WHETHER THE TASK TERMINATES NORMALLY OR             01803721
* ABNORMALLY.                                                           01803821
*                                                                       01803921
* THE STAE FUNCTION IS TO ALLOW THE TASK TO AVOID BEING                 01806921
* ABNORMALLY TERMINATED EXCEPT UNDER CERTAIN CONDITIONS.                01807721
*                                                                       01807821
* THE DAR FUNCTION IS TO HANDLE THOSE TASK TERMINATIONS WHICH           01807921
* BY VIRTUE OF THEIR SYSTEM STATUS OR EXECUTION HAVE BECOME             01808021
* BEYOND THE SCOPE OF THE USUAL ABEND PROCESSING CAPABILITIES.          01812021
* SOMETIME DAR WORKS IN CONJUNCTION WITH ABEND, SOMETIMES INSTEAD       01812821
* OF ABEND, AND FOR CERTAIN SYSTEM TASKS PERFORMS A FUNCTION            01813621
* SIMILAR TO THE STAE FUNCTION.                                         01814421
         EJECT                                                          01815621
*    DEBUGGING SVC 13 MODULES                                           01818621
*                                                                       01821621
* SOME DEBUGGING FEATURES WERE ADDED TO THE SVC 13 MODULES IN           01840021
* RELEASE 20 AND HAVE BEEN EXTENDED IN RELEASE 21. THESE                01860021
* DEBUGGING FEATURES ARE CONSISTANT ACROSS ABEND AND ASIR, BUT          01880021
* THE CURRENT IMPLEMENTATION OF SOME OF THE DAR FUNCTIONS               01884021
* PRECLUDES CONSISTANCY ACROSS ALL PORTIONS OF THE DAR MODULES          01888021
* AT THIS TIME. ABEND/DAR INTERFACES HAVE BEEN ALTERED TO INSURE        01892021
* THAT WHEN ABEND GETS CONTROL BACK FROM DAR, THAT DEBUGGING            01896021
* INFORMATION WHICH IS STILL AVAILABLE IS RETAINED IN THE               01896821
* DEBUGGING FUNCTIONS. THE GENERAL DEBUGGING AIDS ARE-                  01897621
*                                                                       01898421
*  1. WHEN A SVC 13 MODULE XCTLS TO ANOTHER SVC 13 MODULE, THE          01899221
*     LAST 4 BYTES OF THE CSECT NAME OF THE FIRST MODULE IS             01899321
*     PLACED IN REGISTER 0. THE LAST 4 BYTES OF THE CSECT               01899421
*     NAME OF THE MODULE WHICH WILL GET CONTROL AFTER THE XCTL          01899521
*     IS PLACED IN REGISTER 1. A QUICK GLANCE AT THE TRACE              01899621
*     TABLE WILL TELL A SYSTEMS PROGRAMMER EXACTLY WHICH                01899721
*     SVC 13 MODULES HAVE GOTTEN CONTROL AND IN WHICH ORDER.            01899821
*     NOTE- ALL SVC 13 MODULES IN MVT END IN C'*01C' WHERE *            01899921
*     IS ANY DIGIT OR ANY LETTER OF THE UNIVERSAL ALPHABET.             01919921
*                                                                       01920721
*  2. AT ENTRY TO ABEND0 FOR A TRUE ABEND, THE EXTENDED SAVE            01921521
*     AREA OF ABEND'S SVRB IS ZEROED OUT. THUS, ANY NONZERO             01922321
*     VALUE IN THE EXTENDED SAVE AREA MUST HAVE BEEN PUT                01923121
*     THERE BY ABEND.                                                   01923221
*                                                                       01923321
*  3. THE LAST TWO WORDS OF THE EXTENDED SAVE AREA CONTAIN              01923421
*     C'ABEND',C'*',X'SSS0' WHERE * IS THE FIFTH CHARACTER              01923521
*     IN THE NAME OF THE ABEND CSECT WHICH LAST GOT CONTROL.            01923621
*     SSS IS THE SYSTEM COMPLETION CODE FOR THE ABEND WHICH             01923721
*     IS BEING PROCESSED BY THE ABEND SVRB (IF SSS IS 000,              01923821
*     EITHER THE ABEND WAS A USER ABEND OR THE SYSTEM                   01926921
*     COMPLETION CODE WAS NOT AVAILABLE AT THE TIME                     01930921
*     ABEND0 GOT CONTROL).                                              01931721
*                                                                       01932521
*     FOR EXAMPLE IF THE THE ABEND SVRB POINTED TO BY THE               01932621
*     TCB IN AN ABEND DUMP CONTAINED IN ITS LAST 2 WORDS                01932721
*     THE HEXADECIMAL CHARACTERS 'C1C2C5D5C4F90C10', THEN               01932821
*     IT WOULD MEAN THAT THE ABEND MODULE IN CONTROL AT THE             01935621
*     TIME OF THE DUMP WAS IGC0901C, AND IT WAS PROCESSING              01938621
*     A 0C1 PROGRAM CHECK.                                              01941621
*                                                                       01944621
*     IF THERE WAS ANOTHER ABEND SVRB ON THE CHAIN WITH A               01964321
*     VALUE IN ITS EXTENDED SAVE AREA OF 'C1C2C5D5C4F48060',            01965121
*     THEN THERE WAS AN ABEND PREVIOUS TO THE 0C1 PROGRAM               01965921
*     CHECK, I.E. THERE MUST HAVE BEEN AN ABEND RECURSION.              01966021
*     THE PRIOR ABEND WAS AN 806 ABEND. THE LAST ABEND MODULE           01966121
*     TO HAVE CONTROL WAS IGC0401C.                                     01966221
*                                                                       01966321
*     THE SYSTEMS PROGRAMMER MIGHT USE THIS DEBUGGING INFO              01968621
*     TO DETERMINE THE FOLLOWING CHAIN OF LOGIC TO LIMIT THE            01971621
*     LIKELY PROBLEM AREA.                                              01974621
*     A. THE PREVIOUS ABEND MODULE IN CONTROL WAS IGC0401C,             01977721
*        SO EITHER IT PROGRAM CHECKED OR SOME ROUTINE CALLED            01981721
*        ON ITS BEHALF PROGRAM CHECKED.                                 01985721
*     B. THE ABEND DUMP WAS TAKEN ON THE RECURSION, SO THE              01986621
*        THE RECURSION WAS HANDLED VALIDLY, I.E. ABEND WAS              01989621
*        PREPARED TO HANDLE THE RECURSIVE ABEND.                        01992621
*     C. IGC0401C HAS ONLY ONE VALID RECURSION - ACROSS THE             01995621
*        WRITE TO PROGRAMMER. (WTP IS NOT SUPOSED TO ABEND,             01998621
*        BUT IT DOES SOMETIMES, THUS THE VALID RECURSION.)              02001621
*     D. THEREFORE WTP MUST HAVE PROGRAM CHECKED OR SOME                02004621
*        SYSTEM ROUTINE CALLED ON ITS BEHALF.                           02007621
*                                                                       02010621
*     THE SYSTEMS PROGRAMMER WOULD PROBABLY CHECK OTHER INFO            02013621
*     IN THE DUMP TO VERIFY THIS (SUCH AS LOOKING AT THE RB             02016621
*     CHAIN) AND THEN START TO CHECK FOR THE FAULT IN WTP.              02036621
*                                                                       02044421
         EJECT                                                          02064421
*    FUNCTIONAL LOGIC OF ABEND PROCESSING.                              02068421
*                                                                       02069221
* THERE IS A GENERAL PHILOSOPHY  WHICH THE LOGIC OF ABEND               02070021
* FOLLOWS IN THE PLACEMENT OF ITS FUNCTIONS. IN GENERAL A               02070821
* FUNCTION IS LOCATED WHERE IT IS IN THE ABENDING PROCESS               02071621
* BECAUSE THERE IS GOOD REASON TO HAVE IT THERE. ANY CHANGES            02071721
* OR ADDITIONS TO THE ABEND FUNCTIONAL FLOW SHOULD TAKE THIS            02071821
* PHILOSOPHY INTO ACCOUNT. THE FOLLOWING IS A GENERAL LIST              02071921
* OF THE TYPES OF FUNCTIONS IN ABEND, GIVEN IN THE ORDER OF             02072021
* NEED TO OCCUR FIRST TO NEED TO OCCUR LAST.                            02072121
*  1. THINGS THAT MUST BE DONE PRIOR TO DECIDING WHETHER THE            02081421
*     ABEND SHOULD CONTINUE.                                            02085421
*  2. THINGS WHICH MUST BE DONE FOR A REAL ABEND PRIOR TO               02089421
*     LOSING CONTROL ACROSS AN XCTL.                                    02090221
*  3. THINGS THAT SERIOUSLY DEGRADE THE PERFORMANCE OF OTHER            02090321
*     TASKS UNTIL THEY ARE DONE.                                        02090421
*  4. PURGES WHICH MUST BE DONE PRIOR TO ROUTING CONTROL TO             02090521
*     DAR.                                                              02090621
*  5. PURGES WHICH MUST BE DONE ON ALL NON-DAR ENTRIES, WHICH           02117921
*     MUST BE DONE PRIOR TO PROVIDING DIAGNOSTIC AIDS TO THE            02137921
*     PROBLEM PROGRAMMER, AND WHICH MAY BE DONE WHILE THE               02141921
*     ORIGINALLY ABENDING TASK IS IN CONTROL.                           02142721
*  6. FUNCTIONS WHICH MUST BE DONE ONLY ONCE PER ABEND                  02143521
*     REGARDLESS OF RECURSIONS AND MUST BE DONE PRIOR TO THE            02144321
*     PROVIDING OF DIAGNOSTIC AIDS.                                     02145121
*  7. PROVIDE DIAGNOSTIC AIDS TO THE PROBLEM PROGRAMMER (FOR            02145221
*     EXAMPLE, TAKE A SYSUDUMP/SYSABEND DUMP).                          02145321
*  8. FUNCTIONS WHICH MUST BE DONE UNDER CONTROL OF EACH                02154421
*     ABENDING TASK.                                                    02158421
*  9. FUNCTIONS WHICH MAY BE DONE UNDER CONTROL OF THE TOP              02162421
*     ABENDING TASK'S TCB.                                              02163221
* 10. FINAL PROCESSING FOR THE TOP TASK WHICH MUST BE DONE              02163321
*     AT A TIME IN WHICH ABEND WILL NOT LOSE CONTROL.                   02163421
*                                                                       02163521
* NOTE THAT THERE COULD BE A FUNCTION ADDED WHICH DOES NOT              02172621
* FIT IN ONE OF THESE PIGEON HOLES. IN THAT CASE A NEW CLASS            02172721
* WOULD HAVE TO BE CREATED SOMEWHERE BETWEEN STEPS 1 AND 10.            02176721
* THE GENERAL PACKAGING OF ABEND ALLOWS FOR THE POSSIBLE                02180721
* ADDITION OF THE MOST LIKELY NEW CLASSES OF NEW FUNCTIONS.             02181521
* THE NEXT SECTION OF THE PROLOGUE INCLUDES FUNCTIONAL                  02181621
* DESCRIPTIONS OF SOME PRESENTLY NONEXISTANT ABEND MODULES              02181721
* WHICH COULD CONTAIN NEW FUNCTIONS IN NEW CLASSES.                     02205321
         EJECT                                                          02229221
*    THE GENERAL OPERATION OF EACH ABEND MODULE FOLLOWS BELOW.          02252821
*                                                                       02276421
*                                                                       02300000
* IGC0001C - * INITIAL INTERFACES AND ESSENTIAL PURGES                  02400000
*                                                                       02500000
*            PREVENT ASYNCHRONOUS EXITS                                 02600000
*            ABEND/ABTERM HOUSEKEEPING                                  02700000
*            SVC DUMP INTERFACE                                         02800000
*            GTF INTERFACE                                              02820000
*            INITIAL STAE/STAI INTERFACE                                02900000
*            PURGE I/O FOR CURRENT TASK                                 03000000
*            TS0 INTERFACE                                              03100000
*            ABDUMP INTERFACE                                           03200000
*            TEST FOR INVALID RECURSION                                 03300000
*            SET ABEND BIT FOR THE ABENDING TASK                        03400000
*                                                                       03500000
*                                                                       03600000
* IGC0101C - * PURGES FOR EACH ENTRY INTO ABEND                         03700000
*                                                                       03800000
*            ROUTE SERIOUS ERROR TO DAR                                 03900000
*            CONVERT TO JOBSTEP ABEND                                   04000000
*            SET SUBTASKS NONDISPATCHABLE                               04100000
*            VALIDITY CHECK FQE                                         04200000
*            RELEASE PIE                                                04300000
*            PURGE, I/O, AEQS, TIMER, AND WTOR                          04400000
*                                                                       04500000
*                                                                       04600000
* IGC0201C - * RESERVED FOR EVERY ENTRY PURGES AND FUNCTIONS            04700000
*                                                                       04800000
*                                                                       04900000
* IGC0301C - * EVERY ENTRY PURGES AND FUNCTIONS                         05000000
*                                                                       05100000
*            RELEASE PARTIALLY LOADED PROGRAMS                          05200000
*            PURGE TYPE 1 MESSAGES ON RECURSION                         05300000
*            ROUTE CONTROL FOR VALID RECURSIONS                         05400000
*                                                                       05500000
*                                                                       05600000
* IGC0401C - * ONE TIME FUNCTIONS                                       05700000
*                                                                       05800000
*            WRITE TYPE 1 MESSAGES                                      05900000
*            PURGE MSG LIST ELEMENTS                                    06000000
*            FREE TYPE 1 MSG WTP BUFFERS                                06100000
*                                                                       06200000
*                                                                       06300000
* IGC0501C - * ONE TIME PURGES AND FUNCTIONS                            06400000
*                                                                       06500000
*            PURGE ROLLOUT REQUESTS                                     06600000
*                                                                       06700000
*                                                                       06800000
* IGC0601C - * RESERVED FOR ONE TIME FUNCTIONS                          06900000
*                                                                       07000000
*                                                                       07100000
* IGC0701C - * ONE TIME, DUMP RELATED FUNCTIONS                         07200000
*                                                                       07300000
*            GRAPHICS DEBUG ROUTINE INTERFACE                           07400000
*            DIRECT SYSOUT HOOK                                         07500000
*                                                                       07600000
*                                                                       07700000
* IGC0801C - * ONE TIME DUMP RELATED FUNCTIONS                          07800000
*                                                                       07900000
*            OPEN THE DUMP DATA SET                                     08000000
*            SAVE AND RESTORE LOAD LIST POINTER                         08100000
*            SAVE AND RESTORE CURRENT TCBMSS POINTER                    08200000
*                                                                       08300000
*                                                                       08400000
* IGC0901C - * DIAGNOSTIC AIDS                                          08500000
*                                                                       08600000
*            LOAD ABDUMP'S RESIDENT LOAD                                08700000
*            ENQUEUE ON THE DUMP DATA SET                               08800000
*            GIVE AN ABDUMP VIA SNAP (SVC 51)                           08900000
*            DEQUEUE ON THE DUMP DATA SET                               09000000
*            DELETE ABDUMP'S RESIDENT LOAD                              09100000
*                                                                       09200000
*                                                                       09300000
* IGC0A01C - * RESERVED FOR POST-ABDUMP/PRE-CLOSE FUNCTIONS             09400000
*                                                                       09500000
*                                                                       09600000
* IGC0B01C - * DATA MANAGEMENT INTERFACES & RELATED PURGES              09700000
*                                                                       09800000
*            OLTEP INTERFACE                                            09850021
*            ERASE COMPLETE SUBTASKS                                    09900000
*            CHECK FOR CORE TO CLOSE AND ROUTE TO STEAL                 10000000
*            CLOSE OPEN DATA SETS                                       10100000
*            FREE THE PIE                                               10200000
*                                                                       10300000
*                                                                       10400000
* IGC0C01C - * STEAL CORE                                               10500000
*                                                                       10600000
*            STEAL CORE FOR CLOSE                                       10700000
*                                                                       10800000
*                                                                       10900000
* IGC0D01C - * DATA MANAGEMENT AND SUBSYSTEM INTERFACES & PURGES        11000000
*                                                                       11100000
*            TCAM HOOKS (REINITIALIZE TCAM TASK & CANCEL PENDING        11200000
*             INTERPARTITION POSTS FOR USER TASKS)                      11300000
*            FREE SCBS                                                  11400000
*            CANCEL PENDING INTERPARTITION POSTS BY TSO TASKS           11500000
*            PURGE QUELS                                                11600000
*            PURGE TRANSIENT SVRBS                                      11700000
*            ROUTE FOR DD-DYNAM CLEANUP                                 11800000
*                                                                       11900000
*                                                                       12000000
* IGC0E01C - * RESERVED FOR DATA MANAGEMENT AND SUPERVISOR PURGES       12100000
*                                                                       12200000
*                                                                       12300000
* IGC0F01C - * INITIAL CONTENTS SUPERVISION PURGE                       12400000
*                                                                       12500000
*            PURGE CDES AND ASSOCIATED PROGRAMS AND EXTENT LISTS        12600000
*                                                                       12700000
*                                                                       12800000
* IGC0G01C - * SUPERVISOR RELATED PURGES                                12900000
*                                                                       13000000
*            PURGE IRBS, PRBS, AND RESIDENT SVRBS                       13100000
*            PURGE LOAD LIST, AND MAIN CORE STORAGE                     13200000
*            DEQUEUE AND ERASE SUBTASK TCBS                             13300000
*            LOAD COMPLETION CODE IN REGISTER 15                        13400000
*            EXIT TO NORMAL END OF TASK                                 13500000
*                                                                       13600000
*                                                                       13700000
* IGC0H01C - * RESERVED FOR ABEND PROCESSING                            13800000
*                                                                       13900000
*                                                                       14000000
* IGC0I01C - * NOT USED                                                 14100000
*                                                                       14200000
*                                                                       14300000
* IGC0J01C - * RESERVED FOR ABEND PROCESSING                            14400000
*                                                                       14500000
*                                                                       14600000
* IGC0K01C - * STORAGE RECONFIGURATION (MP65 ONLY)                      14700000
*                                                                       14800000
*            STORAGE RECONFIGURATION                                    14900000
*            LOAD COMPLETION CODE IN REGISTER 15                        15000000
*            EXIT TO NORMAL END OF TASK                                 15100000
         EJECT                                                          15200000
*   THE FOLLOWING MODULES ARE NOT TRUE ABEND MODULES BUT ARE            15300000
*   GIVEN DIRECT CONTROL FROM ABEND DURING ABEND PROCESSING.            15400000
*                                                                       15500000
* IGC0Q01C - * TCAM CLEANUP EXECUTER (RELEASE 20.1 ONLY)                15600000
*                                                                       15700000
* IGG0193H - * FREE DD-DYNAMS INVALIDLY MARKED BUSY                     15800000
         EJECT                                                          15900000
*   THE GENERAL FUNCTIONS OF EACH DAR MODULE ARE AS FOLLOWS             16000000
*                                                                       16100000
* IGC0L01C - * TAKE A DAR DUMP                                          16200000
*                                                                       16300000
* IGC0M01C - * HANDLE TASKS IN MC STATUS                                16400000
*                                                                       16500000
* IGC0N01C - * REINSTATE SPECIAL SYSTEM TASKS                           16600000
*                                                                       16700000
* IGC0O01C - * NOT USED                                                 16800000
*                                                                       16900000
* IGC0P01C - * REINSTATEMENT AND REINSTATEMENT FAILURE                  17000000
*                                                                       17100000
* IGC0Q01C - * RESERVED FOR DAR PROCESSING                              17200000
         EJECT                                                          17220021
*   THE GENERAL FUNCTIONS OF EACH ASIR MODULE FOLLOWS                   17240021
*                                                                       17260021
* IGC0R01C - * PURGE I/O                                                17280021
*                                                                       17284021
* IGC0S01C - * SYNCH TO USER'S STAE EXIT ROUTINE                        17288021
*                                                                       17292021
* IGC0T01C - * DETERMINE IF RETRY WANTED                                17296021
*                                                                       17296821
* IGC0U01C - * CLOSE OPEN DATA SETS BEFORE RETRY                        17297621
*                                                                       17298421
* IGC0V01C - * CLOSE OPEN DATA SETS ( CONTINUED)                        17299221
*                                                                       17299321
* IGC0W01C - * PREPARE FOR AND CAUSE STAE RETRY                         17299421
         EJECT                                                          17300000
*  THE FOLLOWING CODE IS LOAD0 OF ABEND.                                17400000
*                                                                       17500000
*  ROUTINE NAME - ABEND0 (ABEND INTERFACE MODULE).                      17600000
*                                                                       17700000
*  FUNCTIONS   -                                                        17800000
*                                                                       17900000
*      1.  CHECK FOR AND FINISH PSUEDO LINK PROCESSING TO GIVE          17920000
*          CONTROL TO A NON-ABEND MODULE VIA XCTL BUT UNDER A NEW       17940000
*          RB.                                                          17960000
*                                                                       17980000
*      2.  PREVENT ASYNCHRONOUS EXITS.                                  18000000
*                                                                       18100000
*      3.  ZERO OUT THE ABEND SVRB EXTENDED SAVE AREA AND MOVE          18200000
*          'ABEND' TO ITS END.                                          18300000
*                                                                       18400000
*      4.  IF THE ABEND CAME THRU ABTERM AND THIS IS NOT A RECURSION    18500000
*          THRU ABEND, ABEND0 RESTORES THE RIGHT HALF OF THE ABENDING   18600000
*          RB FROM THE RBABOQSW FIELD WHERE IT WAS SAVED BY ABTERM.     18700000
*          THE CORRECT PSW INFORMATION WILL THUS BE PASSED TO THE       18800000
*          USER'S EXIT ROUTINE IF A STAE OR STAI IS HONORED.            18900000
*                                                                       19000000
*      5.  IF THE ABEND DID NOT COME THRU ABTERM AND THIS IS NOT        19100000
*          AN ABEND RECURSION, ABEND0 STORES THE COMPLETION CODE        19200000
*          IN REGISTER 1 INTO THE ABENDING TCB.                         19300000
*                                                                       19400000
*      6.  NEXT ABEND0 TESTS FOR SVC DUMP IN PROCESS FOR THIS TASK.     19500000
*          ALL TASKS SET NONDISPATCHABLE BY SVC DUMP ARE RESET          19600000
*          DISPATCHABLE AND THE TASK SWITCH ROUTINE IS ENTERED TO       19700000
*          ALLOW A HIGHER PRIORITY TASK TO BE DISPATCHED NEXT. THE      19800000
*          TRACE TABLE IS TURNED BACK ON. NOTE- IF GTF WAS BEING        19900000
*          USED, THE STOP COUNT IS REDUCED BY 1 AND GTF IS              19920000
*          NOTIFIED VIA THE HOOK MACRO.                                 19940000
*                                                                       19960000
*      7.  FOR A FIRST TIME ENTRY INTO ABEND, ABEND0 ISSUES A           19980000
*          HOOK MACRO TO ALLOW GTF TO CHECK IF IT IS BEING              19984000
*          ABENDED. IF SO, GTF WILL DO SOME SYSTEM CLEANUP PRIOR        19988000
*          TO RETURNING CONTROL TO ABEND.                               19992000
*                                                                       20000000
*      8.  BEFORE TESTING TO SEE IF THERE IS A STAE/STAI IN EFFECT      20100000
*          FOR THE TASK, ABEND0 CHECKS IF THIS TASK WAS PREVIOUSLY      20200000
*          ABENDING (CLOSE FAILURE FROM IGC0B01C) OR IF THE ABEND       20300000
*          WAS ISSUED BY STORAGE RECONFIGURATION BECAUSE OF A SOLID     20400000
*          HARDWARE FAILURE.  IF SO, CONTROL IS PASSED TO STEP # 13     20500000
*          BELOW.                                                       20600000
*                                                                       20700000
*      9.  NOW ABEND0 DETERMINES IF THERE IS A STAE/STAI IN EFFECT      20800000
*          FOR THIS TASK BY INSPECTING TCB LOCATION 160(DEC) FOR        20900000
*          A STAE ADDRESS. IF A STAE HAS NOT BEEN ISSUED, CONTROL       21000000
*          IS PASSED TO STEP # 13 BELOW.                                21100000
*                                                                       21200000
*                                                                       21300000
*     10.  PRIOR TO CHECKING FOR STAE/STAI PURGE, ABEND0 CHECKS         21400000
*          FOR THE ABEND OF THE JOBSTEP BECAUSE OF TIMER EXPIRATION     21500000
*          OR OPERATOR CANCEL. IF SO AND THE ABENDING TASK IS           21600000
*          NOT THE OLTEP TASK, CONTROL IS PASSED TO STEP # 14           21620000
*          BELOW.                                                       21700000
*                                                                       21800000
*     11.  IF THE STAE ADDRESS IS PRESENT, BIT ONE OF THE TCBNSTAE      21900000
*          FIELD IS TESTED FOR A PURGE W/QUIESCE REQUEST.  IF BIT ONE   22000000
*          IS NOT ON, STEP NO. 12, BELOW, IS NEXT EXECUTED. OTHERWISE   22100021
*          THE RIGHT-HALF OF THE RBOPSW OF EACH RB BETWEEN ABEND'S      22200021
*          SVRB AND THAT OF THE ASIR IS POINTED TO AN SVC 3 (EXIT)      22300021
*          INSTRUCTION. THEN ABEND0 EXITS VIA SVC 3.                    22400021
*          THE PURPOSE OF THIS IS TO RETURN CONTROL TO THE RB LEVEL     22600000
*          AT WHICH THE ASIR HAS INVOKED PURGE. IF CONTROL IS           22700000
*          RETURNED IN THIS WAY, IT CAN BE DETERMINED THAT PURGE HAS    22800000
*          ABENDED.                                                     22900000
*                                                                       23000000
*     12.  EVEN IF A STAE/STAI IS IN EFFECT FOR THIS TASK, ABEND0       23100000
*          WILL NOT NECESSARILY HONOR THE STAE/STAI. AT THIS POINT      23200000
*          ABEND0 CHECKS FOR SPECIAL CONDITIONS FOR WHICH THE           23300000
*          STAE/STAI WILL NOT BE HONORED. THOSE CONDITIONS ARE:         23400000
*          A. INVALID STAE/STAI RECURSION WITH NO HIGHER STAI IN        23700000
*             EFFECT.                                                   23800000
*          B. THIS TASK DETACHED BY ITS MOTHER BEFORE IT HAS            23900000
*             COMPLETED NORMALLY (CC=13E).                              24000000
*             NOTE. IF THE DETACH WAS WITH THE STAE=YES OPTION          24100000
*             (CC=33E), THE STAE IS HONORED BY ABEND BUT ASIR           24200000
*             WILL NOT ALLOW A RETRY.                                   24300000
*          C. JOB STEP IN A 30 MINUTE WAIT (CC=522).                    24400000
*          D. SYSOUT DATA FOR THIS TASK EXCEEDED THE OUTLIM             24500000
*             PARAMETER ON THE DD CARD (CC=722).                        24600000
*                                                                       24700000
*     13.  IF ALL PREVIOUS TESTS HAVE BEEN PASSED, THEN IT IS           24800000
*          ASSURED THAT STAE/STAI PROCESSING MAY BEGIN.                 24900000
*          ABEND0 NOW ISSUES XCTL TO ASIR1 (IGC0R01C) TO                25300021
*          PROCESS THE STAE/STAI.                                       25400000
*                                                                       25500000
*     14.  IF THE STAE/STAI IS NOT HONORED AND THIS IS NOT AN           25600021
*          INVALID RECURSION, I/O IS PURGED FOR THE CURRENT TASK.       25700021
*                                                                       25720021
*     15.  FOR TSO TASKS, ENTRY IS MADE INTO THE RESIDENT TAXE          25740021
*          PURGE ROUTINE IN EXIT.                                       25760021
*                                                                       25800000
*     16.  ABEND0 RESETS THE ABDUMP NON-DISPATCHABILITY FLAG            25900021
*          AND BRANCHES TO THE TASK SWITCH ROUTINE FOR EACH             26000000
*          TASK IN JOB STEP.                                            26100000
*                                                                       26500000
*     17.  IF THIS IS AN INVALID RECURSION THRU ABEND OR DAR,           26600021
*          A VALID RECURSION THRU DAR, OR A VALID RECURSION THRU        26700021
*          ABEND IN MUST COMPLETE STATUS, ABEND0 XCTLS TO DAR1.         26800021
*          OTHERWISE ABEND0 XCTLS TO ABEND1.                            26900021
*                                                                       27000000
*  ENTRY POINT NAME - IGC0001C                                          27100000
*                                                                       27200000
*  CONTAINED IN MODULE - IEAQTM00                                       27300000
*                                                                       27400000
*  ATTRIBUTES - TYPE 4 SVC, REENTRANT, REFRESHABLE, SUPERVISOR          27500021
*               STATE, PROTECT KEY ZERO, PARTIALLY ENABLED.             27520021
*                                                                       27600000
*  SVC USAGE - XCTL TO - IEAQTM0R                                       28300000
*                      - IEAQTM01                                       28400000
*                      - IEAQTM0L                                       28500000
*              EXIT TO - IEAQTM0R IF I/O PURGE RECURSION                28600000
*                                                                       28700000
*  INPUT -                                                              28800000
*                                                                       28900000
*           REGISTERS                                                   29000000
*               3 - CVT ADDR                                            29100000
*               4 - ADDRESS OF ABENDING TCB                             29200000
*               5 - ADDRESS OF ABEND'S SVRB                             29300000
*                                                                       29400000
*           BECAUSE OF RECURSIONS THRU ABEND, DAR, AND ASIR,            29420021
*           SEVERAL BITS AND FIELDS IN THE TCB CAN SIGNIFY BY           29440021
*           THEIR PRESENCE OR ABSENCE THAT CERTAIN CONDITIONS           29460021
*           EXIST. THOSE SPECIFIC BITS AND FIELDS REFERENCED            29500021
*           BY THIS MODULE ARE LISTED BELOW WITH THEIR MEANINGS.        29600021
*           UNLISTED BITS AND FIELDS MAY BE REFERENCED BY LATER         29700021
*           MODULES. IF SO THEY REMAIN UNCHANGED THRUOUT THIS           29800021
*           MODULE.                                                     29900021
*                                                                       29920021
*     TCBFA    - ABEND RECURSION                                        29940021
*     TCBDARP  - DAR DUMP RECURSION (UNLESS TCBDARS IS ON)              29960021
*     TCBDARS  - DAR REINSTATMENT RECURSION                             29980021
*     TCBDARMC - DAR RECURS IN MC STATUS                                29984021
*     TCBABTRM - ENTRY THRU ABTERM IF ON. TCBCMP HAS COMP CODE          29992021
*              - IF OFF, REG ONE HAS COMPLETION CODE FOR ABEND          29996021
*     TCBNSTAE - IF NON-ZERO, STAE/STAI ENVIRONMENT IN EFFECT           29997621
*       STAREC   - STAE/STAI RECURSION                                  29998421
*       PURGEBIT - ASIR I/O PURGE RECURSION                             29999221
*       RMSCODE  - ABEND BY STORAGE CONFIGURATION ON M65MP              29999321
*     TCBRECDE - IF NONZERO, ABEND/ASIR/DAR RECURSION OR                29999421
*                COMMUNICATION                                          29999521
*       TCBREC   - VALID ABEND RECURSION                                30016221
*       TCBNOSTA - RETURN FROM ASIR. DON'T HONOR A STAI                 30033221
*       TCBNEWRB - SVRB PROTECTION SCHEME TO BE COMPLETED               30049921
*       TCBPTAXE - PURGE TAXE RECURSION                                 30066621
*                                                                       30083321
*   OUTPUT -                                                            30100000
*                                                                       30200000
*            REGISTERS                                                  30300000
*                3 - CVT ADDRESS                                        30400000
*                4 - ADDRESS OF ABENDING TCB                            30500000
*                5 - ADDRESS OF ABEND'S SVRB                            30600000
*                                                                       30700000
*     CORRECT COMPLETION CODE IN TCBCMP                                 30800021
*     TCBDWSTA ON IF TO ASIR1 FOR 33E ABEND                             30900021
*     TCBFX ON IF FIRST TIME ENTRY                                      30920021
*     TCBFA ON IF EXIT TO ABEND1                                        30940021
*                                                                       31000000
*  ERROR  MESSAGES - NONE                                               31100000
*                                                                       31200000
* EXITS -                                                               36100000
*         1. TO ASIR1 (IGC0R01C) IF VALID STAE/STAI (VIA XCTL)          36200021
*            OR I/O PURGE RECURSION (VIA EXIT)                          36300021
*         2. TO DAR1 (IGC0L01C) FOR INVALID ABEND RECURSION,            36400000
*            VALID DAR RECURSION, OR INVALID DAR RECURSION FOR          36500000
*            A JOB STEP ABEND                                           36600000
*         3. OTHERWISE TO ABEND1 (IGC0101C)                             36700000
*                                                                       36800000
* LIST ORIGINS, TABLES, CONTROL BLOCKS INCLUDED - NONE                  36900000
*                                                                       37000000
* RESTRICTIONS ON THE USE OF THIS ROUTINE -  NONE                       37100000
*                                                                       37200000
* NOTES -                                                               37300000
*         1. THIS MODULE IS NOT CHARACTER CODE DEPENDENT                37400000
*                                                                       37500000
*         2. THE WORD 'ABEND' WHICH IS USED TO FLAG ALL IGC**01C        37600000
*            ABEND SVRBS EXCEPT DAR IS ALSO USED BY THE MODULE          37700000
*            GENERATED AT SYSGEN TIME BY THE MACRO IEAQGM. AT           37800000
*            SYMBOLIC LOCATION 'GNOLSQS' IN A TSO GEN, THIS IS          37900000
*            USED TO SEE IF THE ABEND BIT(TCBFA) IS OFF BUT THAT        38000000
*            AN ABEND OR ASIR SVRB MADE THE REQUEST FOR CORE FOR        38100000
*            AN RB WHICH SHOULD COME OUT OF SQS, NOT LSQS.              38200000
*                                                                       38300000
         EJECT                                                          38400000
GTFSECT  DSECT                         TO GENERATE GTF EQUATES    21014 38500000
         HOOK  EID=IHLMSVON            RESUME GTF                 21014 38600000
         SPACE 3                                                        38700000
RBIRB    EQU   X'40'                   IRB                         MTSB 38800000
TWELVE   EQU   12                      LENGTH OF SHIFT            20472 38900000
ALL      EQU   X'FF'                                              20048 39000000
PRIMND   EQU   X'01'                                              20048 39100000
STAISCB  EQU   X'20'                   STAI SCB INDICATOR FLAG    20028 39200000
ZERO     EQU   0                                                  20028 39300000
TSOTASK  EQU   X'80'                   TIME SHARING TASK FLAG     20028 39400000
TCBTSTSK EQU   148                     DISP TO TIME SHARING FLAG  20028 39500000
SDAR     EQU   X'40'                   SECONDARY DAR RECURSION   A31481 39600000
VMCDAR   EQU   X'10'                   DAR RECURSION WHILE        M3826 39700000
*                                       HANDLING MUST COMPLETE    M3826 39800000
*                                       VALID ABEND RECURSION     M3826 39900000
TCBDWSTA EQU   X'01'                   DETACH W/O STAE RETRY  AI  21472 39920021
*                                                                       40000000
         EJECT                                                          40100000
*    MASKS FOR  BCR  INSTRUCTIONS                                       40200000
*                                                                       40300000
Z        EQU   8                        TO BRANCH ZERO                  40400000
E        EQU   8                        TO BRANCH EQUAL                 40500000
ON       EQU   1                        TO BRANCH IF ON                 40600000
NE       EQU   7                        TO BRANCH IF NOT EQUAL          40700021
NZ       EQU   7                        TO BRANCH IF NOT ON             40800000
         EJECT                                                          40900000
*REGISTERS USED IN LOAD ONE ABEND.                                      41000000
PARREG0  EQU   0                        PARAMETER REGISTER ZERO         41100000
PARREG1  EQU   1                        PARAMETER REGISTER ONE          41200000
WKREG    EQU   1                        WORK REG                        41300000
LINKREG  EQU   2                        INTERNAL LINK REGISTER          41400000
R1TEMSAV EQU   2                        TEMPORARY SAVE OF REG 1   21014 41500000
CVTREG   EQU   3                        CONTAINS POINTER TO CVT.        41600000
TCBREG   EQU   4                        CURRENT TCB REGISTER.           41700000
RBREG    EQU   5                        CURRENT RB REGISTER.            41800000
WKREG7   EQU   7                        REG FOR SAVING CURR TCB         41900000
ATCBREG  EQU   8                        ALTERNATE TCB REGISTER          42000000
BASEREG  EQU   9                        BASE REGISTER FOR ABEND         42100000
TCBINREG EQU   10                       INPUT REG TO TASK SWITCH RTN    42200000
WKREG1   EQU   10                       WORK REGISTER              R00A 42300000
ARBREG   EQU   10                       ALTERNATE RB REGISTER.          42400000
SCB      EQU   10                       SCB ADDRESS REGISTER      20028 42500000
XCTLREG  EQU   10                       ADDR OF NEXT MODULE             42600000
WKREG2   EQU   11                                                 20048 42700000
SWITREG  EQU   11                       ENTRY PT REG FOR TASK SWITCH    42800000
NOSTAREG EQU   11                       BRANCH REG IF NO STAE           42900000
SELREG   EQU   12                       TASK SELECT REG                 43000000
RETREG   EQU   14                       REGISTER 14                     43100000
BRNCHREG EQU   14                       WORK REG FOR BRANCH       21472 43200000
TAXEPRG  EQU   15                       ADDR TAXE PURGE RTN REG   20028 43300000
SCVTREG  EQU   15                       REG ON SCVTSECT- ABEND CVT      43400000
         EJECT                                                          43500000
IGC0001C CSECT                                                          43600000
         BALR   BASEREG,0              ESTABLISH ADDRESSABILITY         43700000
         USING *,BASEREG        9                                       43800000
         USING CVTSECT,CVTREG   3                                       43900000
         USING TCBSECT,TCBREG   4     ADDRESSABILITY FOR CURR TCB       44000000
         USING TCBDSECT,ATCBREG 8     ADDRESSABILITY FOR ALT. TCB       44100000
         USING SCVTSECT,SCVTREG F     ADDRESS. FOR ABEND CVT            44200000
         USING RBSECT,RBREG     5     ADDRESSABILITY FOR CURR RB        44300000
         USING RBSECT2,ARBREG   A     ADDRESSABILITY FOR ALTERNATE RB   44400000
*                                                                       44500000
         MVI   RBEXSAVE+45,C'0'         FLAG SVRB IN CASE OF      M3859 44600000
*                                        XCTL FROM ASIR           M3859 44700000
         CLI   TCBRECDE,TCBNOSTA        Q. RETURN FROM STAI?      21016 44800000
         BNE   REALABND                 NO. FINISH NORMAL ENTRY   21016 44900000
         OI    TCBFLGS,TCBFX            PREVENT ASYNCHRONOUS EXITS      45000000
         MVI   TCBRECDE,X'00'           TURN OFF INDICATOR.       21016 45100000
         B     NOSTAE                   SKIP STAE PROCESSING            45200000
         SPACE 3                                                        45300000
REALABND EQU   *                                                  M3859 45400000
         XC    RBEXSAVE(48),RBEXSAVE    ZERO OUT EXT SAVE AREA          45500000
         CLI   TCBRECDE,TCBNEWRB        ABEND SVRB PROTECTION?    21472 45600000
         BNE   VALABEND                 NO. ABEND INTENDED        21472 45700000
*                                                                       45800000
* A NEW SVRB HAS BEEN CREATED BY AN SVC 13 ISSUED BY ABEND. THIS  21472 45900000
* NEW SVRB WILL BE USED TO GIVE CONTROL TO A NON-ABEND MODULE     21472 46000000
* VIA XCTL. WHEN THE NON-ABEND MODULE IS FINISHED, IT WILL        21472 46100000
* EXIT AND THE PREVIOUS ABEND MODULE WILL GET CONTROL IMMEDIATELY 21472 46200000
* FOLLOWING THE SVC 13 IT ISSUED. THE NAME OF THE MODULE TO GET   21472 46300000
* CONTROL IS IN BYTES 8 THRU 15 OF THE PREVIOUS ABEND'S SVRB      21472 46400000
* EXTENDED SAVE AREA. THE RECURSION CONFIGURATION TO BE USED      21472 46500000
* ACROSS THE XCTL IS IN BYTE 16 OF THE PREVIOUS EXTENDED SAVE     21472 46600000
* AREA.                                                           21472 46700000
*                                                                       46800000
         L     ARBREG,RBLINK-1          GET PREV AVEND'S SVRB     21472 46900000
         MVC   TCBRECDE(1),RBEXSAV2+16  USE CORRECT RECURS CONFIG 21472 47100000
         LA    XCTLREG,RBEXSAV2+8       ADDR OF SPECIFIED MOD AI  21472 47120021
         B     XCTL                     LOAD TRACE FLAGS & XCTL   21472 47200000
         SPACE 3                                                        47300000
VALABEND EQU   *                                                        47400000
         OI    TCBFLGS,TCBFX            PREVENT ASYNCHRONOUS EXITS      47500000
         LA    BRNCHREG,FLAGSVRB        ADDR COMMON END OF HKEEP  21472 47600000
         TM    TCBFLGS+2,TCBABTRM       Q. ENTERED THRU ABTERM?   20472 47700000
         BO    ABTRM                    YES. HANDLE ABTERM ENTRY  20472 47800000
         LR    WKREG1,PARREG1           SAVE COMP CODE            20472 47900000
         SRL   WKREG1,8                 SHIFT TO CORRECT POS      20472 48000000
         ST    WKREG1,RBEXSAVE+44       SAVE COMP CODE IN RBEXSA  20472 48100000
         TM    TCBFLGS,TCBFA            Q. ABEND RECURSION? TST1  20472 48200000
         BCR   ON,BRNCHREG              YES. SKIP TCBCMP STORE    21472 48300000
         CLI   TCBRECDE,X'00'           Q. ABEND RECURSION? TST2  21016 48400000
         BCR   NE,BRNCHREG              YES. SKIP TCBCMP STORE    21472 48500000
*                                                                 M4535 48600000
         ST    PARREG1,TCBCMP           STORE COMP CODE IN TCB    20472 48700000
         BR    BRNCHREG                 BR TO FLAG ABEND'S SVRB   21472 48800000
         EJECT                                                          48900000
ABTRM    EQU   *                                                  20472 49000000
         NI    TCBFLGS+2,X'FF'-TCBABTRM TURN OFF ABTERM BIT       20028 49100000
         LA    WKREG2,1                 CC NOT IN RBEXSAVE YET    20472 49200000
         LA    WKREG1,4                 SUBTRACT 4 FROM THE ADDR  20472 49300000
         LCR   WKREG1,WKREG1             OF ENTRY TO ABTERM FOR   20472 49400000
         A     WKREG1,CVTBTERM           PTR TO REG SAVE AREA     20472 49500000
         L     WKREG1,0(,WKREG1)        LOAD ADDR OF ABTERM S/A   20472 49600000
         C     TCBREG,0(,WKREG1)        Q. THIS TASK LAST ABTRM?  20472 49700000
         BNE   RECTEST                  NO. COMP CODE NOT AVAIL   20472 49800000
         MVC   RBEXSAVE+45(3),4(WKREG1) SAVE COMP CODE IN RBEXSA  20472 49900000
         SR    WKREG2,WKREG2            CC NOW IN RBEXSAVE        20472 50000000
RECTEST  EQU   *                                                  20472 50100000
         TM    TCBFLGS,TCBFA            Q. FIRST ENTRY TO ABEND? A27227 50200000
         BCR   ON,BRNCHREG              NO. BR TO FLAG ABND SVRB  21472 50300000
PSWRESET EQU   *                                                 A27227 50400000
         L     ARBREG,RBLINK-1          LOAD PTR TO ABENDING RB   21016 50500000
         MVC   RBOPSW2+4(4),RBABOPS2    RESTORE RBPSW            A27227 50600000
         TM    TCBRECDE,TCBREC          Q. ABEND RECURSION?       21472 50700000
         BCR   ON,BRNCHREG              YES. NO COMP CODE AVAIL   21472 50800000
         BCTR  WKREG2,BRNCHREG          SKIP CC SAVE IF DONE NOW  21472 50900000
         MVC   RBEXSAVE+45(3),TCBCMP    SAVE COMP CODE IN RBEXSA  20472 51000000
         SPACE 3                                                        51100000
FLAGSVRB EQU   *                                                  20472 51200000
         MVC   RBEXSAVE+40(6),ABEND     MOVE 'ABEND0' TO RBEXSA   20472 51300000
         CLI   TCBRECDE,TCBSAVCD+TCBREC Q.SAVE CMP CODE RECURSION 21472 51400000
         BNE   NOTSAVCD                 NO, CONTINUE NORMAL PROC  M3888 51500000
         MVI   TCBRECDE,X'00'           ZERO OUT SPEC CONDITION   21016 51600000
         SPACE 3                                                        51700000
NOTSAVCD EQU   *                                                        51800000
         CLI   TCBRECDE,TCBREC+TCBPTAXE Q. RET FROM TAXE PURGE    21016 51900000
         BE    TAXEPG                   YES. CONTINUE PURGE       21016 52000000
         EJECT                                                          52100000
*****************************************************************       52200000
*                                                                 20048 52300000
*        SVCDUMP INTERFACE                                        20048 52400000
*                                                                 20048 52500000
         TM    TCBDAR,TCBEXSVC         Q. SVC DUMP IN PROGRESS    20048 52600000
         BZ    NOSVCDMP                NO - BRANCH                20048 52700000
         NI    TCBDAR,ALL-TCBEXSVC     TURN OFF DUMP BIT          20048 52800000
         L     ATCBREG,CVTHEAD         GET TOP TCB                20048 52900000
TCBLOOP  EQU   *                                                  20048 53000000
         NI    TCBDARP+2,ALL-TCBNDSVC  TURN OFF NON-DISP FLAG     20048 53100000
         NC    TCBDARP+1(3),TCBDARP+1  Q. STILL NON-DISPATCHABLE  20048 53200000
         BNZ   NOTPRIM                 YES - BRANCH               20048 53300000
         NI    TCBFLGSP+4,ALL-PRIMND   TURN OFF PRIMARY FLAG      20048 53400000
         LR    TCBINREG,ATCBREG        INPUT REG FOR TASK SWITCH  20048 53500000
         L     SCVTREG,CVTABEND        GET SECONDARY CVT ADDR     20048 53600000
         L     SWITREG,SCVTTASW        GET ADDR OF TASK SWITCH    20048 53700000
         BALR  RETREG,SWITREG          MAKE SELECTED TASK DISP    20048 53800000
NOTPRIM  EQU   *                                                  20048 53900000
         L     ATCBREG,TCBTCBP         GET NEXT TCB               20048 54000000
         LTR   ATCBREG,ATCBREG         Q. END OF TCB CHAIN        20048 54100000
         BNZ   TCBLOOP                 NO - BRANCH                20048 54200000
         NI    CVTDAR,ALL-CVTLOCK      TURN OFF LOCK BIT          20048 54300000
         TM    CVTGTFST,CVTGTFS        Q. IS GTF ACTIVE?          21014 54400000
         BZ    ONSUPTRC                NO. SUPV TRACE CAN WORK    21014 54500021
         TM    TCBFLGS,TCBGTOFM        WAS GTF SUSPENDED FOR THE  21014 54600000
*                                       FAILING TASK              21014 54700000
         BZ    NOSVCDMP                NO. NO NEED TO START GTF   21014 54800000
         NI    TCBFLGS,ALL-TCBGTOFM    RESET TCB GTF FLAG         21014 54900000
         HOOK  EID=IHLMSVON            RESUME GTF                 21014 55000000
         B     NOSVCDMP                BYPASS SUPERV TRACE ON     21014 55100000
ONSUPTRC EQU   *                       RESUME SUPERVISOR TRACE    21014 55200000
         L     WKREG2,CVTBTERM         GET ABTERM ADDRESS         20048 55300000
         L     WKREG,8(,WKREG2)        GET PTR TO TRACE STOP      20048 55400000
         MVI   1(WKREG),X'00'          TURN ON TRACE              M3823 55500000
NOSVCDMP EQU   *                                                  20048 55600000
         EJECT                                                          55700000
*********************************************************************** 55800000
*                                                                       55800821
*        GTF INTERFACE                                                  55804021
*                                                                       55840021
GTFHOOK  EQU   *                                                  21014 55900000
         TM    CVTGTFST,CVTGTFS        IS GTF ACTIVE        AD    M1050 55920021
         BZ    NOGTF                   NO - SKIP HOOK       AD    M1050 55940021
         TM    TCBFLGS,TCBFA           Q. ABEND RECURSION? TST1   21014 56000000
         BO    NOGTF                   YES - SKIP HOOK            21014 56100000
         TM    TCBRECDE,TCBREC         Q. ABEND RECURSION? TST2   21014 56200000
         BO    NOGTF                   YES - SKIP HOOK            21014 56300000
         LR    R1TEMSAV,WKREG          SAVE REG1 DURING HOOK      21014 56400000
         LR    PARREG1,TCBREG          SET UP HOOK PARAM REGISTER 21014 56500000
         SPACE 2                                                        56600000
*          THIS HOOK ALLOWS GTF TO DETERMINE IF GTF ITSELF IS BE- 21014 56700000
*        ING ABENDED AND IF SO  TO PREVENT ANY RESULTING SYSTEM   21014 56800000
*        DAMAGE    .                                              21014 56900000
         SPACE 2                                                        57000000
         HOOK  EID=IHLMABND                                       21014 57100000
         SPACE 2                                                        57200000
         LR    WKREG,R1TEMSAV           RESTORE CONTENTS OF REG1  21014 57300000
NOGTF    EQU   *                                                  21014 57400000
         EJECT                                                          57596321
******************************************************************      57600000
*                                                                       57700000
*        STAE INTERFACE                                                 57800000
*                                                                       57900000
         LA    NOSTAREG,NOSTAE         INITIALIZE BRANCH REG            58000000
         TM    TCBFLGS,TCBFA           Q. IS THIS TASK IN ABEND   20472 58100000
*                                       ALREADY? POSSIBLE IF      20472 58200000
*                                       CLOSE PROCESSING FOR      20472 58300000
*                                       ABENDING SUBTASK.         20472 58400000
         BCR   ON,NOSTAREG             YES. BYPASS STAE PROCESS   20472 58500000
         TM    TCBNSTAE,RMSCODE        WAS STG RECONF THE CALLER     2K 58600000
         BCR   ON,NOSTAREG             YES,BYPASS STAE TESTING          58700000
TSTSTAE  EQU   *                                                        58800000
         NC    TCBNSTAE(4),TCBNSTAE    HAS STAE BEEN ISSUED        STAD 58900000
         BCR   Z,NOSTAREG              NO,BRANCH                        59000000
         L     WKREG7,TCBJSTCB         GET ADDR OF JOBSTEP TCB     STAD 59100000
         TM    30(WKREG7),X'40'        ENTRY FROM OPERATOR CANCEL 20472 59200000
*                                      OR TIMER EXPIRATION?       20472 59300000
         BNO   TSTSTAE2                NO. CONTINUE TEST FOR STAE 21472 59400021
         TM    TCBTRN,TCBOLTEP         Q. IS THIS OLTEP TASK?     21472 59500021
TCBOLTEP EQU   X'02'                   OLTEP TASK BIT             21472 59600021
         BCR   Z,NOSTAREG              NO. CONTINUE THE ABEND     21472 59700021
TSTSTAE2 EQU   *                                                  21472 59800021
         TM    TCBNSTAE,PURGEBIT       Q. IS PURGE W/QUIESCE            59900000
*                                       REQUESTED?                 STAD 60000000
         BZ    STRECURS                NO, CHECK STAE RECURSION   20472 60100000
         LA    WKREG,CVTEXIT           ADDR OF SVC 3 INSTR   AD   M2190 60200021
*                                      FROM THE CVT.               STAD 60400000
         LR    WKREG7,RBREG            INITIALIZE FOR SCAN   AD  A44962 60420021
SETEXIT  EQU   *                                             AD  A44962 60440021
         L     ARBREG,28(,WKREG7)      GET PREVIOUS RB ADDR  AD  A44962 60460021
         CLC   RBEXSAV2+40(6),ABENDR   ASIR SVRB             AD  A44962 60480021
         BE    SETTRACE                YES, PREPARE TO EXIT  AD  A44962 60500021
         ST    WKREG,RBOPSW2+4         FORCE INTERVENING     AD   M2190 60520021
*                                      RB TO EXIT            AD  A44962 60540021
         LR    WKREG7,ARBREG           UPDATE RB ADDR        AD  A44962 60560021
*                                      FOR SCAN              AD  A44962 60580021
         B     SETEXIT                 CONTINUE SCAN FOR     AD  A44962 60600021
*                                      ASIR SVRB             AD  A44962 60620021
SETTRACE EQU   *                                             AD  A44962 60640021
         L     PARREG0,THISMOD         TRACE ORIGIN          AD  A44962 60660021
         L     PARREG1,EXIT            TRACE DESTINATION     AD  A44962 60680021
SVC3     EQU   *                                                  20472 60800000
         SVC   3                       ISSUE EXIT.                 STAD 60900000
*                                                                       61000000
STRECURS EQU   *                                                  20472 61100000
         TM    TCBNSTAE,STAEREC        Q. STAE/STAI RECURSION     20472 61200000
         BZ    NOSTAI                  NO. SKIP STAI CHECK        21472 61300000
CKSTAI   EQU   *                                                  20028 61400000
         L     SCB,TCBNSTAE            GET FIRST SCB              20028 61500000
         LA    SCB,ZERO(,SCB)          CLEAR FLAG BYTE            20028 61600000
         TM    TWELVE(SCB),STAISCB     Q. STAI SCB ?              20028 61700000
         BCR   Z,NOSTAREG              NO. CONTINUE THE ABEND     21472 61800000
NOSTAI   EQU   *                                                  20028 61900000
         CLC   TCBCMP+1(2),CC13E       DETACH ISSUED FOR                62000000
*                                       INCOMPLETE SUBTASK?             62100000
         BCR   E,NOSTAREG              YES. DO NOT HONOR STAE           62200000
         TM    TCBTRN,TCBOLTEP          IF OLTEP TASK        PD OS64126 62220021
*                                       THEN BYPASS CHECK    PD OS64126 62240021
         BO    OLTEP                    FOR 522/722 CHECK    PD OS64126 62260021
         CLC   TCBCMP+1(2),CC522       WAS STEP IN 30 MIN. WAIT         62300000
         BCR   E,NOSTAREG              YES. DO NOT HONOR STAE           62400000
         CLC   TCBCMP+1(2),CC722       Q. OUTLIM EXCEEDED FOR SYSOUT    62500000
         BCR   E,NOSTAREG              YES. DO NOT HONOR STAE           62600000
OLTEP    EQU   *                                             PD OS64126 62650021
         CLC   TCBCMP+1(2),CC33E       Q. DETACH WITHOUT RETRY?   M4535 62700000
         BNE   LDSTADDR                NO. CONTINUE PROCESSING    M4535 62800000
         OI    TCBFLGS+2,TCBDWSTA      YES. SET DETACH FLAG   AI  21472 62900021
LDSTADDR EQU   *                                                  M4535 63000000
         SPACE 3                                                        63010021
         SPACE 5                                                        63188121
         LA    XCTLREG,STAELOAD        ADDR OF NAME OF STAE LOAD.       63188921
         B     XCTL                    PREPARE TO XCTL                  63200000
NOSTAE   EQU   *                                                  M4257 63300000
         EJECT                                                          63400000
*********************************************************************   63500000
*        PURGE I/O ROUTINE                                              63600000
*********************************************************************   63700000
*                                                                       63800000
* SINCE I/O COULD BE ACTIVE AT THIS TIME, ANOTHER ABEND MIGHT     21472 63900000
* OCCUR AS SOON AS ABEND NEXT LOSES CONTROL TO THE SYSTEM SUCH    21472 64000000
* AS ACROSS THE XCTL TO THE NEXT LOAD OF ABEND. A PURGE OF I/O    21472 64100021
* IS DONE AT THIS TIME TO HANDLE THIS CASE. AFTER THE INITIAL     21472 64200021
* ABEND, LATER ABEND RECURSIONS MAY ALSO NEED AN I/O PURGE, BUT   21472 64300021
* THE PURGE IS MORE LIKELY TO BE NEEDED BEFORE THE XCTL AT FIRST  21472 64400021
* TIME ENTRY.                                                     21472 64500021
*                                                                       64520021
* SVC 16 IS NOT SUPPOSED TO BE ABLE TO ABEND, SO IF IT DOES, DAR  21472 64600000
* SHOULD BE ENTERED. TO ACCOMPLISH THIS AND AVOID AN ABEND PURGE  21472 64700021
* LOOP, THE PURGE IS SKIPPED IF THE ABEND BIT IS TURNED ON        21472 64800021
* UNLESS ABEND IS HANDLING A VALID RECURSION.                     21472 64820021
*                                                                       64824021
* BEFORE PURGING ON 1ST TIME (NONRECURSIVE) ENTRY THE ABEND BIT   21472 64840021
* IS TURNED ON JUST BEFORE THE PURGE AND IT IS TURNED OFF AFTER.  21472 64900021
* AN ABEND IN PURGE WILL BE TREATED AS AN INVALID RECURSION, AND  21472 65000000
* CONTROL WILL BE PASSED TO DAR WITHOUT TRYING ANOTHER PURGE.     21472 65100000
*                                                                       65104021
* FOR VALID RECURSIVE ENTRY, A SWITCH IS SET AND THE VALID        21472 65108021
* RECURSION INDICATOR IS TURNED OFF ACROSS THE PURGE. AT THE      21472 65112021
* END OF THE PURGE IT IS TURNED ON AGAIN. IN THIS CASE TOO, AN    21472 65116021
* ABEND IN PURGE WILL BE TREATED AS AN INVALID RECURSION AND      21472 65116821
* CONTROL WILL BE PASSED TO DAR.                                  21472 65117621
*                                                                       65120021
* PURGE WITH HALT IS USED TO AVOID AN I/O ABEND, MINIMISE               65140021
* CHANCES OF AN INTERLOCK BEING INADVERTENTLY DESIGNED INTO THE         65160021
* SYSTEM AT A LATER DATE, AND TO AVOID AN INFINITE WAIT FOR I/O         65180021
* WHICH MAY NEVER COME HOME (AS IN TP APPLICATIONS). NO POSTING         65184021
* IS DONE BECAUSE AN INVALID ECB COULD CAUSE ANOTHER ABEND.             65188021
*                                                                       65192021
* PURGE BY TCB CAUSES TTH RQE QUEUE TO BE CHECKED FOR AN I/O            65196021
* REQUEST MADE BY THIS TCB (ADDR OF THE TCB IN THE RQE). THUS           65196821
* THE I/O NEED NOT BE FOR A DEB WHICH IS ON THE DEB CHAIN OF            65197621
* THIS TCB. ALL PURGING BY ABEND IS BY TCB. A PURGE BY DEB WILL         65198421
* BE DONE BY DATA MANAGEMENT DURING CLOSE PROCESSING WHICH IS           65199221
* DONE IN LATER ABEND PROCESSING.                                       65199321
*                                                                       65200000
* IF THE ABENDING TASK IS COMMTASK, I/O PURGE MUST BE BYPASSED    44624 65250021
* SINCE COMMTASK WILL WAIT FOREVER, WHEN IT GETS REINSTATED BY    44624 65260021
* DAR, FOR I/O TO BE POSTED COMPLETE ON A CONSOLE DUE TO THE      44624 65270021
* BUSY BIT BEING SET IN THE UCM ENTRY. IN AN MCS SYSTEM, THIS     44624 65280021
* WILL CAUSE LOSS OF ONE CONSOLE(COMMTASK THINKS IT'S ALWAYS      44624 65290021
* BUSY) AND LOSS OF THE OUTSTANDING I/O ON THE OTHER CONSOLES     44624 65292021
* DUE TO THE PURGE IN ABEND. IN A NON-MCS SYSTEM THIS RESULTS,    44624 65294021
* IN EFFECT, IN THE LOSS OF THE COMMTASK SERVICES FOR THE CURRENT 44624 65296021
* IPL SINCE COMMTASK WILL ALWAYS BE WAITING ON I/O THAT WILL      44624 65298021
* NEVER GET POSTED COMPLETE FOR THE CONSOLE.                      44624 65298421
PURGEIO  EQU   *                                                  21472 65300000
         L     SCVTREG,CVTABEND         INIT ABEND CVT BASE   AD  44624 65310021
         L     WKREG2,SCVTCTCB          ADDRESS COMMTASK TCB  AD  44624 65312021
         CR    WKREG2,TCBREG            COMMTASK ABENDING     AD  44624 65314021
         BE    NOPRGIO                  YES-BYPASS I/O PURGE  AD  44624 65316021
         SR    WKREG2,WKREG2            SET SW FOR FIRST TIME AI  21472 65320021
         TM    TCBFLGS,TCBFA            FIRST TIME PAST ASIR? AI  21472 65400021
         BZ    FIRSTIME                 YES. SKIP RECURS CHCK AI  21472 65500021
         LA    WKREG2,1                 PREPARE TO HANDLE     AI  21472 65540021
*                                        RECURSION PURGE ABND AI  21472 65560021
         TM    TCBRECDE,TCBREC          Q. VALID RECURSION?   AI  21472 65580021
         BZ    NOPRGIO                  NO. AVOID POSSIBLE    AI  M0607 65584021
*                                        PURGE/ABEND LOOP     AI  21472 65588021
         NI    TCBRECDE,255-TCBREC      TO AVOID RECURS LOOP  AI  21472 65592021
FIRSTIME EQU   *                                              AI  21472 65596021
         OI    TCBFLGS,TCBFA            FOR INVALID RECURS    AI  21472 65600021
         LA    PARREG1,RBEXSAVE         GET PARAM LIST ADDR   AI  21472 65700021
         XC    0(12,PARREG1),0(PARREG1) CLEAR PARAMETER LIST  AI  21472 65800021
         MVI   0(PARREG1),X'22'         SET OPTION FLAG       AI  21472 65900021
         ST    TCBREG,4(,PARREG1)       PURGE CURRENT TCB     AI  21472 66000021
         SVC   16                       ISSUE PURGE SVC       AI  21472 66100021
         LTR   WKREG2,WKREG2            Q. RECURSIVE ENTRY?   AI  21472 66120021
         BZ    RESET1ST                 NO. HANDLE 1ST TIME   AI  21472 66140021
         OI    TCBRECDE,TCBREC          VALID RECURS BACK ON  AI  21472 66160021
         B     NOPRGIO                  END OF PURGE I/O RTN  AI  21472 66180021
RESET1ST EQU   *                                              AI  21472 66184021
         NI    TCBFLGS,255-TCBFA        RESET FOR 1ST TIME    AI  21472 66200021
NOPRGIO EQU   *                                               AI  21472 66300021
         EJECT                                                          66400000
*****************************************************************       66500000
*                                                                 20028 66600000
*       TSO INTERFACE                                             20028 66700000
*                                                                 20028 66800000
TSOCHK   EQU   *                                                  20028 66900000
         TM    TCBTSTSK(TCBREG),TSOTASK Q. TIME-SHARING TASK?     20028 67000000
         BZ    NOTSO                   NOT TIME-SHARING - BRANCH  20028 67100000
         TM    TCBFLGS,TCBFA           Q. NON-TSO RECURSION?      M2180 67200000
         BO    NOTSO                   YES. DON'T NEED PURGE      M2180 67300000
         TM    TCBRECDE,X'FF'          Q. ANY KIND OF RECURSION?  21016 67400000
         BNZ   NOTSO                   YES. SKIP PURGE OF TAXE    21016 67500000
         MVI   TCBRECDE,TCBPTAXE+TCBREC TURN ON RECUR INDICATORS  21016 67600000
         L     SCVTREG,CVTABEND        GET ADDR OF SCVT           20028 67700000
         L     TAXEPRG,SCVTSTXP        GET TAXE PURGE RTN ADDR    20028 67800000
         BALR  RETREG,TAXEPRG          GO PURGE TAXE'S            20028 67900000
TAXEPG   MVI   TCBRECDE,X'00'          TURN OFF RECURSION INDIC   21016 68000000
         B     NOTSO                    BR TO ABDUMP INTERFACE    M4539 68100000
         EJECT                                                          68200000
*****************************************************************       68300000
*                                                                       68400000
*          ABDUMP INTERFACE                                             68500000
*                                                                       68600000
ABD00B   EQU   *                                                   MTSB 68700000
         USING TCBSECT,WKREG7                                     M4537 68800000
         CLC   TCBJSTCB+1(3),TCBJSTCP+1 Q. IS SEL TCB ON TREE     M4537 68900000
         BNE   ABD00A                   NO. GET NEXT IN QUEUE     M4537 69000000
         DROP  WKREG7                                             M4537 69100000
         USING TCBSECT,TCBREG           REESTABLISH ADDRESSABLTY  M4537 69200000
         NI    TCBFLGSP+3,255-TCBNDUMP TURN OFF ABDMP NONDISP BIT  MTSB 69300000
         LR    TCBINREG,ATCBREG        SET UP INPUT REG FOR TASK   MTSB 69400000
*                                      SWITCH                      MTSB 69500000
         L     SCVTREG,CVTABEND        ADDRESS SECONDARY CVT       MTSB 69600000
         L     SWITREG,SCVTTASW        OBTAIN ADDR OF TASK SWITCH  MTSB 69700000
         BALR  RETREG,SWITREG          BRANCH TO TASK SWITCH RTN   MTSB 69800000
         B     ABD00A                  RETURN TO SELECT NEXT TASK  MTSB 69900000
*                                                                       70000000
NOTSO    EQU   *                                                  M4257 70100000
         L     ATCBREG,TCBJSTCB         ESTABLISH JOB STEP TCB          70200000
         LA    WKREG7,0(,TCBREG)        CLEAR HIGH ORDER           5318 70300000
         LR    TCBREG,ATCBREG           ALTER CURR TCB FOR TASK SELECT  70400000
         LCR   ATCBREG,ATCBREG          INDICATE FIRST TIME ENTRY       70500000
ABD00A   BAL   LINKREG,SELECT           BRANCH TO TASK SELECT RTN       70600000
         B     ABD00B                   BRANCH, TASK WAS SELECTED       70700000
*                                       NO MORE TASKS              MTSB 70800000
         LR    TCBREG,WKREG7            RESTORE CURR TCB                70900000
         B     DARCHK                   GO TO NEXT MODULE         21472 71000000
         EJECT                                                          71100000
*                                                                       71200000
* TASK SELECTION SUBROUTINE.                                            71300000
*                                                                       71400000
SELECT   EQU   *                                                        71500000
         LTR   SELREG,ATCBREG           IS THIS FIRST-TIME ENTRY        71600000
         BC    10,SELECT1               NO, BRANCH TO START SELECTION   71700000
         LCR   SELREG,SELREG            YES, RECOMPLEMENT TCB ADDRESS   71800000
SELECT3  LR    ATCBREG,SELREG           PASS BACK SELECTED TCB ADDRESS  71900000
         TM    TCBFLGSP+4,TCBFC         Q. THIS TASK COMPLETE?   A43837 71920021
         BO    SELECT                   YES. SELECT NEXT TASK    A43837 71940021
         BR    LINKREG                  RETURN TO MAIN ROUTINE          72000000
SELECT1  L     SELREG,TCBLTCP           GET DAUGHTER OF INPUT TASK      72100000
SELECT2  LTR   SELREG,SELREG            DOES A DAUGHTER EXIST           72200000
         BC    7,SELECT3                YES, SELECTION HAS BEEN MADE    72300000
         L     SELREG,TCBNTCP           NO, GET SISTER                  72400000
         TM    TCBCMP,STEPMASK          IS THIS A STEP ABEND            72500000
         BO    SELECT4                  YES, SEE IF INPUT IS JSTCB      72600000
         CR    ATCBREG,TCBREG           NO, IS SCAN OF TREE FINISHED    72700000
         BC    8,4(LINKREG)             YES, RETURN TO MAIN ROUTINE     72800000
SELECT4  C     ATCBREG,TCBJSTCB         IS THIS JOB STEP TCB     A31771 72900000
         BC    8,4(LINKREG)             YES, RETURN TO MAIN ROUTINE     73000000
         L     ATCBREG,TCBOTCP          NO, GET MOTHER                  73100000
         B     SELECT2                  BRANCH TO TEST                  73200000
         EJECT                                                          73300000
*****************************************************************       73400000
*                                                                       73500000
*  BEFORE TRANSFERING CONTROL TO ABEND1, ABEND0 MUST CHECK FOR A        73600000
*  SITUATION IN WHICH CONTROL SHOULD BE TRANSFERED TO DAR1. DAR1        73700021
*  WILL GET CONTROL IF THIS IS AN INVALID RECURSION THRU ABEND          73800021
*  FOR THE ABENDING TASK OR IF ABEND IS VALIDLY RECURSING IN MUST       73900021
*  COMPLETE STATUS.                                                     74000021
*                                                                       74200000
*  FIRST TIME ENTRY INTO ABEND (RECURSIONS IN ABEND PRIOR TO            74300000
*  ENTERING IEAQTM01 FOR THE FIRST TIME ARE CONSIDERED TO BE            74400000
*  FIRST TIME ENTRY) OR A VALID RECURSION NOT IN MUST COMPLETE          74500021
*  STATUS THRU ABEND WILL CAUSE ABEND1 TO GET CONTROL NEXT.             74600021
*                                                                       74800000
DARCHK   EQU   *                                                        74900000
         LA    XCTLREG,NMLOAD1         GET NAME OF NEXT LOAD     A29408 75000000
         TM    TCBFLGS,TCBFA           Q. IS ENTRY DUE TO RECURS A29408 75100000
         BZ    SETFABIT                NO. GO TO ABEND1          A29408 75200000
         TM    TCBRECDE,TCBREC         Q. IS RECURSION VALID?     21016 75300000
         BZ    GOTODAR                 NO. GO TO DAR              21472 75400021
         TM    TCBFLGS+1,TCBMC         Q.VALID REC IN M.C. STATUS M3826 75500000
         BZ    XCTL                    NO. GO TO IEAQTM01         M3826 75600000
         TM    TCBDAR,VMCDAR           Q. IN DAR PROC NOW?        M3826 75700000
         BO    GOTODAR                 YES. GO TO DAR AGAIN       M3826 75800000
         OI    TCBDAR,VMCDAR           SET RECURSION BIT          M3826 75900000
         NI    TCBDAR,255-SDAR         RESET FOR NORMAL           M3826 76000000
*                                       DAR PROCESSING            M3826 76100000
*                                                                       76120021
*        B     GOTODAR                 NOW GO TO DAR              M3826 76200021
*                                                                       76300021
         SPACE 3                                                        77400000
GOTODAR  EQU   *                                                 A31481 77500000
         LA    XCTLREG,DARLOAD         LOAD ADDR OF DAR          A29408 77600000
SETFABIT EQU   *                                                 A32587 77700000
         OI    TCBFLGS,TCBFA           TURN ON ABEND BIT         A32587 77800000
*                              NOTE- ALREADY ON IF GOING TO DAR.        77820021
XCTL     EQU   *                                                        77900000
         L     PARREG0,THISMOD          FLAG XCTL FOR TRACE AND   20472 78000000
         L     PARREG1,4(,XCTLREG)      SHOW WHERE GOING TO       21472 78100000
         LA    15,RBEXSAVE         LOAD ADDR OF EXTENDED SAVE AREA ROOA 78200000
         XCTL  EPLOC=(XCTLREG),SF=(E,(15)) GO TO NEXT MODULE      21472 78300000
         EJECT                                                          78400021
         DS    0F                                                       78500000
DARLOAD  DC    C'IGC0L01C'             DAR ROUTINE, FIRST LOAD    20472 78600000
STAELOAD DC    C'IGC0R01C'             STAE ROUTINE, FIRST LOAD         78700000
NMLOAD1  DC    C'IGC0101C'             NAME OF LOAD1                    78800000
THISMOD  DC    C'001C'                 INDICATOR FOR XCTL         20472 78900000
EXIT     DC    C'EXIT'                 DESTINATION FOR TRACE AD  A44962 78950021
CC13E    DC    X'13E0'                 CC FOR INCOMPLETE SUBTASK        79000000
CC522    DC    X'5220'                 COMP CODE FOR 30 MINUTE WAIT     79100000
CC722    DC    X'7220'                 COMP CODE FOR EXCPLIMIT          79200000
CC33E    DC    X'33E0'                 COMP CODE FOR DETACH       M4535 79300000
ABEND    DC    C'ABEND0'                                                79400000
ABENDR   DC    C'ABENDR'               ASIR INDICATOR IN ESA AD  A44962 79450021
         EJECT                                                          79500000
*                                                                       79600000
*                                                                       79700000
*             THE FOLLOWING CODE IS ZAP SPACE FOR MAINTENANCE USE       79800000
*                                                                       79900000
*                                                                       80000000
*                                                                       80100000
         DC    H'0'                                                     80200000
         DC    H'0'                                                     80300000
         DC    H'0'                                                     80400000
         DC    H'0'                                                     80500000
         DC    H'0'                                                     80600000
         DC    H'0'                                                     80700000
         DC    H'0'                                                     80800000
         DC    H'0'                                                     80900000
         DC    H'0'                                                     81000000
         DC    H'0'                                                     81100000
         DC    H'0'                                                     81200000
         DC    H'0'                                                     81300000
         DC    H'0'                                                     81400000
         DC    H'0'                                                     81500000
         DC    H'0'                                                     81600000
         DC    H'0'                                                     81700000
         DC    H'0'                                                     81800000
         DC    H'0'                                                     81900000
         DC    H'0'                                                     82000000
         DC    H'0'                                                     82100000
         DC    H'0'                                                     82200000
         DC    H'0'                                                     82300000
         DC    H'0'                                                     82400000
         DC    H'0'                                                     82500000
         DC    H'0'                                                     82600000
         DC    H'0'                                                     82700000
         DC    H'0'                                                     82800000
         EJECT                                                          84400000
         IHBABCTL                                                       84500000
* MISCELLANEOUS MASKS CON'T                                        MTSB 84600000
*                                                                       84700000
CCTEST0  EQU   X'FF'                   USER OR SYSTEM ABEND        MTSB 84800000
CCTEST1  EQU   X'0C'                   PROGRAM CHECK               MTSB 84900000
CCTEST3  EQU   X'F0'                   USER ABEND                  MTSB 85000000
DUMP     EQU   1                       DUMP IS POSSIBLE            MTSB 85100000
DUMPBIT  EQU   31                      SHIFT FOR DUMP BIT IN REG 1 MTSB 85200000
DUMPIND  EQU   X'80'                   IF ON, INDICATES A DUMP     MTSB 85300000
*                                                                       85400000
* TCBFLGS      CON'T                                               MTSB 85500000
TCBFE    EQU   X'40'                   NORMAL END                  MTSB 85600000
* TCBTRN                                                                85700000
*                                                                       85800000
RMSCODE  EQU   X'01'                    TO TEST IF RMS IS CALLER        85900000
*                                                                       86000000
*   MASKS  IN  TCBNSTAE FIELD                                      STAD 86100000
*                                                                  STAD 86200000
CCDETACH EQU   X'01'                   FLAG DETACH CONDITION      M4535 86300000
STAEREC  EQU   X'80'                   STAE RECURSION BIT          STAD 86400000
PURGEBIT EQU   X'40'                   STAE PURGE  W/QUIESCE       STAD 86500000
         MPCVT                                                          86600000
*/*IEAQTM00: CHART */                                                   86620000
*/*IEAQTM00: E ENTRY TO ABEND0 */                                       86640000
*/*IGC0001C: P FLAG SVRB FOR ABEND0 */                                  86660000
*/*          D (NO,REALABND,YES,%RESETST) ASIR RENTRY TO NOT HONOR STAI 86680021
*/* */                                                                  86680821
*/*%RESETST:      P PREVENT ASYNCHRONOUS EXITS */                       86684021
*/*          P (,NOSTAE) RESET COMMUNICATION CONFIGURATION */           86688000
*/*REALABND: P ZERO-OUT SVRB'S EXTENDED SAVE AREA */                    86692000
*/*          D (YES,,NO,VALABEND) PSUEDO LINK VIA SVC 13 */             86696000
*/*          P SET CORRECT RECURSION CONFIGURATION */                   86696800
*/*          P (,XCTL) PREPARE TO XCTL TO NON-ABEND MODULE */           86697600
*/*VALABEND: P PREVENT ASYCHRONOUS EXITS */                             86698400
*/*          D (YES,ABTRM,NO,%NOTABTM) ENTRY VIA ABTERM PROCESSING */   86699221
*/*%NOTABTM:      P SAVE COMPCODE IN ESA FOR DEBUGGING */               86699321
*/*          D (YES,FLAGSVRB,NO,) ABEND RECURSION */                    86699400
*/*          P (,FLAGSVRB) STORE COMPLETION CODE IN TCB */              86699500
*/*ABTRM:    P RESET ABTERM INDICATOR */                                86699600
*/*          P FLAG SVRB WITH COMPCODE IF AVAILABLE */                  86699700
*/*          D (NO,FLAGSVRB,YES,) FIRST TIME ENTRY */                   86699800
*/*          P RESTORE PSW AT TIME OF ABEND */                          86699900
*/*          P SAVE COMPCODE IN ESA FOR DEBUGGING */                    86799921
*/*FLAGSVRB: P FLAG SVRB FOR ABEND0 (AGAIN) */                          86819900
*/*          P RESET ASIR RECURSION INDICATOR IF ON */                  86839900
*/*NOTSAVCD: D (YES,TAXEPG,NO,) TAXE PURGE RECURSION */                 86859900
*/*          D (NO,NOSVCDMP,YES,) SVC DUMP ABEND */                     86879900
*/*          P TURN OF SVCDUMP IN PROCESS INDICATOR */                  86883900
*/*          P RESET ALL OTHER TASKS SVC DUMP DISPATCHABLE */           86887900
*/*          P RESET LOCK BIT. TURN ON TRACE (SUPERVISOR OR GTF) */     86891921
*/*NOSVCDMP: P IF NOT RECURSION, TELL GTF OF ABEND */                   86896700
*/*          D (YES,NOSTAE,NO,) ABEND ALREADY IN PROCESS */             86897500
*/*          D (YES,NOSTAE,NO,) STORAGE RECONFIGURA- TION ABEND */      86898300
*/*          D (YES,TSTSTAE2,NO,) OLTEP TASK */                         86899100
*/*          D (YES,NOSTAE,NO,) OPERATOR CANCEL OR TIME OUT */          86899200
*/*TSTSTAE2: D (NO,STRECURS,YES,) ASIR PURGE WITH QUIESCE ABEND */      86899321
*/*          P PREPARE TO RETURN TO ASIR'S NSI */                       86899400
*/*          R EXIT TO ASIR */                                          86899500
*/*STRECURS: D (NO,NOSTAI,YES,) ASIR/STAE EXIT RECURSION */             86899600
*/*CKSTAI:   D (NO,NOSTAE,YES,) STAI IN EFFECT */                       86899700
*/*NOSTAI:   D (13E,NOSTAE,522,NOSTAE,722,NOSTAE,33E,,OTHR,LDSTADDR)    86899800
*/*COMPLETION CODE ALLOW ASIR */                                        86999800
*/*          P SET DETACH WITH STAE INDICATOR */                        87019800
*/*LDSTADDR: P (,XCTL) PREPARE TO GO TO ASIR0 */                        87039800
*/*NOSTAE:   D (NO,NOPRGIO,YES,) VALID RECURSION OR FIRST TIME ENTRY */ 87059800
*/*          P SET SWITCH FOR WHICH KIND OF ENTRY */                    87079800
*/*          P TURN OFF RECURSION BIT, ABEND BIT ON */                  87083800
*/*          S I/O PURGE: PURGE I/O BY TCB WITH HALT, NO POST */        87087800
*/*          P USING INTERNAL SWITCH, RESET ORIGINAL RECURSION BITS */  87091800
*/*NOPRGIO:  D (YES,,NO,NOTSO) FIRST TIME ENTRY FOR TIME SHARING TASK*/ 87095800
*/*          P SET FOR VALID RECURSION */                               87097400
*/*          S IEAKJXP: PURGE TAXES */                                  87098221
*/*TAXEPG:   P (,NOTSO) RESET VALID RECURSION */                        87099000
*/*ABD00B:   D (NO,ABD00A,YES,) SELECTED TASK FOR THIS JOBSTEP */       87099100
*/*          P RESET ABDUMP NONDISPATCH- ABILITY */                     87099200
*/*          S (,ABD00A) IEAODS02: TASK SWITCH IF NECESSARY */          87099300
*/*NOTSO:    P PREPARE FOR FIRST TASK SELECT */                         87099400
*/*ABD00A:   S (SLTD,ABD00B,LAST,DARCHK) SELECT: SELECT A TASK OF THE   87199400
*/*TREE */                                                              87299400
*/*DARCHK:   P PREPARE TO GO TO ABEND1 */                               87399400
*/*          D (YES,SETFABIT,NO,) NORMAL VALID RECURSION OR 1ST TIME    87499421
*/*ENTRY */                                                             87599400
*/*          P  (,GOTODAR) SET AND RESET PROPER DAR SWITCHES */         87899400
*/*GOTODAR:  P PREPARE TO GO TO DAR 1 */                                87999400
*/*SETFABIT: P INSURE THAT ABEND BIT IS ON */                           88099400
*/*XCTL:     P FLAG REGS 0 & 1 TO TRACE XCTL EASILY */                  88199400
*/*          R XCTL TO SPECIFIED MODULE */                              88299400
*/*SELECT:   E ENTRY TO TASK SELECT SUBROUTINE */                       88399400
*/*          D (YES,,NO,SELECT1) FIRST TIME ENTRY */                    88499400
*/*          P SET UP INPUT TCB AS SELECTED TCB */                      88599421
*/*SELECT3:  P SET UP RETURN PARAM WITH TCB ADDRESS JUST SELECTED */    88699400
*/*          D (NO,,YES,SELECT) SELECTED TASK COMPLETE */               88719421
*/*          R RETURN-MORE */                                           88799400
*/*SELECT1:  P SELECT DAUGHTER OF INPUT TCB */                          88899400
*/*SELECT2:  D (NO,,YES,SELECT3) SELECTED TASK EXIST */                 88999400
*/*          P SELECT SISTER TCB */                                     89099400
*/*          D (NO,,YES,SELECT4) JOB STEP ABEND */                      89199400
*/*          D (YES,,NO,SELECT4) ENTIRE ABENDING TREE SCANNED */        89299400
*/*%SELECT5: R RETURN-NONE */                                           89399400
*/*SELECT4:  D (NO,,YES,%SELECT5) IS INPUT TCB JOB THE STEP TCB */      89499421
*/*          P (,SELECT2) GET MOTHER OF INPUT TCB AS NEW INPUT */       89599421
*/*IEAQTM00: END */                                                     89699400
         END                                                            89799421
