 TITLE 'IGC0101C / ABEND1 - DEFINE TREE, CONVERT, INIT PURGES, DAR ROUT*00100000
               ER / IEAQTM01'                                           00200000
IGC0101C START                                                          00300000
* THE FOLLOWING CODE IS LOAD ONE OF ABEND                               00400000
*                                                                       00500000
* ROUTINE NAME - ABEND1                                                 00600000
*                                                                       00700000
* FUNCTIONS -                                                           00800000
*                                                                       00900000
*                                                                       01000000
*        1. HANDLES A VALID RECURSION ENTRY WITHIN ABEND. ABEND1        01100000
*    RESETS THE RECURSION BIT, PURGES THE AEQ FOR THE                   01200000
*    CURRENT TASK AND PASSES CONTROL TO ABEND3.                         01300000
*                                                                       01400000
*        2. IF ENTRY IS FOR THE PURPOSE OF CONVERSION TO A STEP         01500021
*    ABEND, ABEND1 CONVERTS THE ABEND TO A JOBSTEP ABEND, THEN          01600021
*    TREATS THE ABEND AS A FIRST TIME ENTRY.                            01700000
*                                                                       01720021
*        3. IF RETURN IS FROM DAR TO CONTINUE THE ABEND, ABEND1         01740021
*    BYPASSES DAR TESTING AND CONTINUES PROCESSING AT STEP # 5.         01760021
*                                                                       01780021
*        4. IF ABENDING TASK IS A SYSTEM TASK OR IN MUST-COMPLETE       01784021
*    STATUS, CONTROL IS PASSED TO DAR AFTER PURGING AEQS.               01788021
*                                                                       01800000
*        5. IF THIS IS A FIRST-TIME ENTRY INTO ABEND, ABEND1            01900021
*    MOVES THE COMPLETION CODE TO THE TOP ABENDING TCB (JOBSTEP TCB     02000000
*    FOR A STEP ABEND OR CURRENT TCB FOR A TASK ABEND). IT THEN         02100000
*    PERFORMS THE FOLLOWING FUNCTIONS FOR EACH TASK IN THE FAMILY OF    02200000
*    ABENDING TASKS-                                                    02300000
*             A. ALTERS FLAG SETTINGS-                                  02400000
*                  (1).  ALL ABEND INDICATORS ARE RESET AND             02500021
*                THE ABEND BIT AND PREVENT ASYNCHRONOUS EXIT BIT        02600021
*                ARE SET IN THE TCB.                                    02700021
*                  (2). THE ABTERM FLAG IS TURNED OFF AND THE           03100021
*               THE ABNORMAL WAIT BIT ON (NOT FOR CURRENT TCB).         03200021
*                  (3). THE T BIT IS SET IN THE TOP TASK IN THE TREE    03300021
*                OF ABENDING TASKS (JOBSTEP TCB FOR STEP ABEND OR       03400000
*                CURRENT TCB FOR TASK ABEND).                           03500000
*             B. VALIDITY CHECKS ALL FQES (NOT 251 IF SUBTASK ABEND)    03600000
*             C. RELEASES THE PIE                                       03700021
*             D. PURGES THE TIMER. (THIS INCLUDES A TAXE PURGE    M4915 04100000
*                OF ALL TASKS IN THE ABENDING TREE EXCEPT THE     M4915 04200000
*                CURRENT TASK WHICH WAS PURGED ALREADY)           M4915 04300000
*             E. PURGES I/O WITH THE HALT I/O OPTION                    04400000
*             F. PURGES THE WTOR QUEUES.                                04500000
*             G. PURGES NON 16* AEQS.                                   04600000
*                                                                       05000000
*         6. CONTROL IS PASSED TO ABEND3.                               05100021
*                                                                       05200000
*                                                                       05300000
* ENTRY POINT NAME - IGC0101C                                           05400000
*                                                                       05500000
* CONTAINED IN MODULE - IEAQTM01                                        05600000
*                                                                       05700000
*                                                                       05800000
* ATTRIBUTES-                                                           05900000
*        TYPE 4 SVC, REENTERABLE, SUPERVISOR STATE, DISABLED.           06000000
*                                                                       06100000
* APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                06200000
*                                                                       08700000
* SVC USAGE -                                                           08800000
*        XCTL                                                           08900000
*        GETMAIN                                                   MTSB 09000000
*        FREEMAIN                                                       09100000
*                                                                       09200000
* INPUT -                                                               09300000
*                                                                       09400000
* OUTPUT - NONE                                                         09500000
*                                                                       09600000
*                                                                       09700000
* ENTRY POINTS -                                                        09800000
*        IGC0101C                                                       09900000
*             1. PSW                                                    10000000
*                 A. DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT        10100000
*                MACHINE CHECK.                                         10200000
*                 B. UNDER SUPERVISOR PROTECTION KEY.                   10300000
*                 C. IN SUPERVISOR MODE.                                10400000
*             2. REGISTERS UPON ENTRY                                   10500000
*                 A. REGISTER 3 CONTAINS THE ADDRESS OF THE             10600000
*                    COMMUNICATIONS VECTOR TABLE (CVT).                 10700000
*                 B. REGISTER 4 CONTAINS THE ADDRESS OF THE CURRENT     10800000
*                    TCB.                                               10900000
*                 C. REGISTER 5 CONTAINS THE ADDRESS OF THE CURRENT RB. 11000000
*             3. IF ENTRY TO CONVERT TO STEP ABEND, TCBRECDE      21472 11100000
*                CONTAINS X'32' (TCBCONVR) AND THE CURRENT ABEND  21472 11200000
*                SVRB HAS THE CONVERSION CODE (WITH THE DUMP BIT  21472 11300000
*                ON IF WANTED) IN THE 2ND WORD OF THE EXTENDED    21472 11400000
*                SAVE AREA.                                       21472 11500000
*                                                                       11600000
* EXIT POINTS -                                                         11700000
*                                                                       11800000
*        1. TO DAR1 IF SERIOUS ERROR.                                   11900000
*        2. TO ABEND3 OTHERWISE                                         12000000
*                                                                       12020021
* ERROR MESSAGES - NONE                                                 12100000
*                                                                       13300000
* LIST ORIGINS, TABLES, CONTROL BLOCKS INCLUDED - NONE                  21600000
*                                                                       21700000
* RESTRICTIONS ON THE USE OF THIS ROUTINE -  NONE                       21800000
*                                                                       21900000
* NOTES - THIS MODULE IS NOT CHARACTER CODE DEPENDENT                   22000000
*                                                                       22200000
*                                                                       22300000
*                                                                       22400000
*                                                                       22500000
         EJECT                                                          22600000
*                MISCELLANEOUS EQUATES                                  22700000
RMSCODE  EQU   X'01'                    TO TEST IF RMS IS CALLER        22800000
TSELSAVE EQU   20                       TASK SELECT SAVE AREA    A36648 22900000
*                                        IN RBEXSAVE             A36648 23000000
WORD     EQU   4                        LENGTH CODE = 4           20472 23100000
*                  MASKS FOR BCR INSTRUCTIONS                           23200000
*                                                                       23300000
O        EQU   1                        BRANCH IF ONE(S)                23400000
H        EQU   2                        HIGH                            23500000
NE       EQU   7                        NOT EQUAL                       23600000
NZ       EQU   7                        BRANCH IF NOT ZEROS             23700000
E        EQU   8                        EQUAL                           23800000
Z        EQU   8                        BRANCH ON ZERO(S)               23900000
NL       EQU   11                       NOT LOW                         24000000
         EJECT                                                          24100000
*REGISTERS USED IN LOAD ONE ABEND.                                      24200000
SEVENREG EQU   0                        CONST. REG IN FQE VAL CK A25410 24300000
PARREG0  EQU   0                        PARAMETER REGISTER ZERO         24400000
PARREG1  EQU   1                        PARAMETER REGISTER ONE          24500000
IQEREG   EQU   1                        REG USED TO ACCESS NON-16* IQE  24600000
WKREG    EQU   1                        WORK REG                        24700000
SCVTREG2 EQU   2                        SECONDARY CVT                   24800000
SAVTCB   EQU   2                        SAVE TCB REG BEFORE TIMER PURGE 24900000
SAVEREG  EQU   2                        SAVE SPQR ADDRESS         M4135 25000000
LINKREG  EQU   2                        INTERNAL LINK REGISTER          25100000
CVTREG   EQU   3                        CONTAINS POINTER TO CVT.        25200000
TCBREG   EQU   4                        CURRENT TCB REGISTER.           25300000
RBREG    EQU   5                        CURRENT RB REGISTER.            25400000
ENTRYREG EQU   6                        ENTRYPOINT REG TO RESID ROUT    25500000
RPTIMER  EQU   6                        BASE REG OF PURGE TIMER REG.    25600000
DQEREG   EQU   6                        DQE REG                         25700000
TEMPREG  EQU   6                        WORK REG FOR FQE VAL CHK RTN    25800000
FQEREG   EQU   7                        FQE REG                         25900000
ATCBREG  EQU   8                        ALTERNATE TCB REGISTER          26000000
BASEREG  EQU   9                        BASE REGISTER FOR ABEND         26100000
XCTLREG  EQU   10                       EPLOC FOR XCTL            M4135 26200000
EPREG    EQU   10                       ENTRY POINT REGISTER            26300000
CODEREG  EQU   10                       CONVERSION COMP CODE ADDR 20472 26400000
TOPREG   EQU   10                       IND. HI BOUND FOR FQE    A25410 26500000
AEQREG   EQU   11                       WORK REG TO ACCESS AEQ          26600000
SPQEREG  EQU   11                       SPQE REG                        26700000
SELREG   EQU   12                       TASK SELECT REG                 26800000
BRNREG   EQU   12                       TEMPORARY BRANCH REG      20472 26900000
PREVPTR  EQU   13                       PREVIOUS POINTER REGISTER.      27000000
RETREG   EQU   14                       REGISTER 14                     27100000
WTREG    EQU   14                       TEMPORARY WORK REG              27200000
SCVTREG  EQU   15                       REG ON SCVTSECT- ABEND CVT      27300000
RTNREG   EQU   15                       RETURN FROM MSSLOOP             27400000
MPREG    EQU   15                       MUST BE REGISTER 15       21472 27500000
         EJECT                                                          27600000
IGC0101C CSECT                                                          27700000
         BALR   BASEREG,0              ESTABLISH ADDRESSABILITY         27800000
         USING *,BASEREG          9                                     27900000
         USING CVTSECT,CVTREG     3                                     28000000
         USING TCBSECT,TCBREG     4     SET ADDRESSABILITY FOR CURR TCB 28100000
         USING TCBDSECT,ATCBREG   8     SET ADDRESS FOR ALT. TCB  20472 28200000
         USING SCVTSECT,SCVTREG   F     SET ADDRESS. FOR ABEND CVT      28300000
         USING RBSECT,RBREG       5     SET ADDRESSABILITY FOR CURR RB  28400000
*                                                                       28500000
         MVI   RBEXSAVE+45,C'1'         FLAG SVRB AS THIS MODULE  21472 28600000
         NI    TCBRECDE,255-TCBREC      TURN OFF VALID REC INDIC  21016 28700000
         CLI   TCBRECDE,TCBCONVR        Q. NEED TO CONVERT?       21472 28800000
         BE    CONVERT                  YES. HANDLE THE CONVERSN  21472 28900000
         CLI   TCBRECDE,TCBDARET        Q. RETURN FROM DAR?       21472 29000000
         BE    DARETOFF                 YES. SKIP DAR TESTING     21472 29100021
         TM    TCBRECDE,255-TCBREC      Q. SPECIAL HANDLING?      21472 29200000
         BZ    DARTSTS                  NO, HANDLE 1ST TIME ENTRY 20472 29300000
         LR    ATCBREG,TCBREG           SET UP CURRENT TCB ADDR         29400000
*                                                                       29500000
*THE FOLLOWING PURGES THE AEQ OF NON-16* IQE THAT ARE                   29600000
*WAITING TO BE QUEUED ON CURRENT TASK.                                  29700000
*                                                                       29800000
         BAL   LINKREG,PURGEAEQ         LINK TO PURGE AEQ ROUTINE       29900000
*                                                                       30000000
         SPACE 5                                                        30100000
NEXTLOAD EQU   *                                                  21472 30200000
         LA    XCTLREG,NMLOAD3          LOAD ADDR OF LOAD3 NAME   M4135 30300000
XCTL     EQU   *                                                  21472 30400000
         LA    15,RBEXSAVE              LD ADDR OF EXT SAVE AREA  20472 30500000
         L     PARREG0,THISMOD          FLAG XCTL FOR TRACE       20472 30600000
         L     PARREG1,4(,XCTLREG)      SHOW WHO GOING TO         20472 30700000
         XCTL  EPLOC=(XCTLREG),SF=(E,(15))                        M4135 30800000
         EJECT                                                          30900000
DARTSTS  EQU   *                                                        31000000
         TM    TCBFLGS+1,TCBMC         IS STATUS MUST COMPLETE?   20472 31100000
         BNZ   DARPROC                 YES GO TO DAR              20472 31200000
         L     ATCBREG,TCBOTC          GET MOTHER ADDRESS.         SWTD 31300000
         LTR   ATCBREG,ATCBREG         IS CURRENT THE MASTER?      SWTD 31400000
         BZ    DARPROC                 YES GO TO DAR              20472 31500000
         L     ATCBREG,TCBOTCP         NO, GET GRANDMOTHER.       19472 31600000
         LTR   ATCBREG,ATCBREG         IS CURRENT A SYSTEM TASK?  19472 31700000
         BNZ   ABD26                   NO CONTINUE ABEND          20472 31800000
DARPROC  EQU   *                                                  20472 31900000
         OI    TCBFLGS,TCBFT           SET TOP ABENDING TASK BIT A31754 32000000
         LR    ATCBREG,TCBREG          PREPARE FOR AEQ PURGE      21472 32100000
         BAL   LINKREG,PURGEAEQ        PURGE AEQ                  20472 32200000
         LA    XCTLREG,DARLOAD         GET ADDR OF DAR NAME       20472 32300000
         B     XCTL                    GO TO XCTL TO DAR          20472 32400000
         SPACE 5                                                        32500000
CONVERT  EQU   *                                                  20472 32600000
         LA    CODEREG,RBEXSAVE+4       SET UP FOR COMP CODE      21472 32700000
         L     ATCBREG,TCBJSTCB         GET ADDR OF JOB/STEP TCB  21472 32800000
         L     WTREG,TCBCMP             PICK UP CURRENT COMPCODE  20472 32900000
         SLL   WTREG,8                  CLEAR OUT ALL BUT SYS     20472 33000000
         SRL   WTREG,20                  COMPLETION CODE          20472 33100000
         O     WTREG,0(,CODEREG)        SET UP CONVERSION CODE    20472 33200000
         ST    WTREG,TCBCMPP            PUT IT IN THE JSTCB       20472 33300000
         MVI   TCBRECDE,X'00'           CLEAN OUT CONFIGURATION   21472 33320021
         B     HOUSKEEP                 BR TO FINISH CONVERSION   20472 33400000
         SPACE 5                                                        33500000
DARETOFF EQU   *                                                        33520021
         MVI   TCBRECDE,X'00'           CLEAN OUT CONFIGURATION   21472 33540021
ABD26    EQU   *                                                        33600000
         L     ATCBREG,TCBJSTCB         GET ADDR OF JOB/STEP TCB        33700000
         CR    TCBREG,ATCBREG           Q. IS THIS STEP ABEND?   A31481 33800000
         BE    HOUSKEEP                 YES. ATCBREG IS OK       A31481 33900000
         TM    TCBCMP,STEPMASK          IS THIS A STEP ABEND            34000000
         BC    1,ABD26A                 YES, ALT TCB IS JS TCB          34100000
         TM    TCBFLGSP,TCBFT           Q. STEP ABEND             20472 34200000
         BO    ABD26A                   YES, CONVERTED ALREADY    20472 34300000
         LR    ATCBREG,TCBREG           NO, ALT TCB IS CURR TCB         34400000
ABD26A   EQU   *                                                        34500000
         MVC   TCBCMPP(4),TCBCMP        MOVE COMPL CODE TO ALT TCB      34600000
         EJECT                                                          34700000
HOUSKEEP EQU   *                                                        34800000
         LCR   ATCBREG,ATCBREG          INDICATE FIRST TIME ENTRY       34900000
ABD27    BAL   LINKREG,SELECT           LINK TO SELECT TASK ROUTINE     35000000
         B     ABD31                    BRANCH,NO MORE TASK             35100000
*                                                                       35200000
* FALL THROUGH IF TASK SELECTED TO RESET ABEND INDICATORS AND SET       35300000
* ABEND, PREVENT ASYNCH EXITS AND ABEND WAIT FLAGS                      35400000
*                                                                       35500000
         NI    TCBFLGSP,255-TCBFT                                 21472 35600000
         OI    TCBFLGSP,TCBFA+TCBFX                                     35700000
         CR    TCBREG,ATCBREG           Q. CURRENT TCB?           20472 35800000
         BE    ABD27                    YES. SKIP NEXT HOUSKEEP   20472 35900000
         NI    TCBFLGSP+2,255-TCBABTRM  TURN OFF ABTERM FLG       21016 36000000
         MVI   TCBRECDP,X'00'           TURN OFF RECURSION BITS   21016 36100000
         OI    TCBFLGSP+4,TCBABWF       SET TASK NONDISP                36200000
         B     ABD27                    SELECT NEXT TASK                36300000
ABD31    EQU   *                                                        36400000
* AN ABENDING TASK JUST FLAGGED NON-DISPATCHABLE MAY STILL         MPOC 36500000
* BE ACTIVE ON THE SECOND CPU. IF SO, IT MUST BE REMOVED           MPOC 36600000
* FROM EXECUTION. THE NEW AND OLD POINTERS MUST BE ALTERED         MPOC 36700000
* IF THEY POINT TO NON-DISPATCHABLE TASKS. THE ROUTINE             MPOC 36800000
* TESTDSP LOCATED WITHIN THE PSA WILL ACCOMPLISH THIS TASK.             36900000
*                                                                       37000000
         TM    CVTDCB,CVTDCBMP         IS THIS AN M65MP?           MP0C 37100000
CVTDCBMP EQU   X'04'                   MASK 00000100               MP0C 37200000
         BZ    AROUND                  NO                          MPOC 37300000
         L     MPREG,CVTMPCVT          GET MPCVT ADDR.            21472 37400000
*                                                                       37500000
*          XXXXXXXXXX                                                   37600000
         DROP  SCVTREG                                                  37700000
         USING IEAMPCVT,MPREG                                     21472 37800000
*          XXXXXXXXXX                                                   37900000
*                                                                       38000000
         L     MPREG,CVTTKRM           GET TESTDSP ADDRESS.       21472 38100000
*                                                                       38200000
*          XXXXXXXXXX                                                   38300000
         DROP  MPREG                                              21472 38400000
         USING SCVTSECT,SCVTREG                                         38500000
*          XXXXXXXXXX                                                   38600000
*                                                                       38700000
         BALR  RETREG,MPREG            BRANCH TO TESTDSP.         21472 38800000
         L     SCVTREG,CVTABEND        RELOAD SCVT ADDRESS        21472 38900000
         EJECT                                                          39000000
AROUND   EQU   *                                                   MPOC 39100000
*                                                                       39200000
* AT THIS TIME ATCBREG CONTAINS THE TOP ABENDING TCB ADDRESS            39300000
* WHICH WAS RETURNED BY THE TASK SELECT ROUTINE AT THE END OF THE       39400000
* HOUSEKEEPING ROUTINE LOOP. THIS TOP ABENDING TCB ADDRESS IS NOW       39500000
* READY FOR THE NEXT SERIES OF TASK SELECTS FOR THE PURGE LOOP.         39600000
*                                                                       39700000
         OI    TCBFLGSP,TCBFT           SET T-BIT IN TOP TASK           39800000
*                                                                       39900000
* THE FQES FOR SUBPOOL 251 MUST BE VALIDITY CHECKED AND          A34816 40000000
* CORRECTED EVEN IF THE ABEND IS NOT A STEP ABEND .  THE FQES    A34816 40100000
* TO BE CORRECTED ARE NOT NECESSARILY ASSOCIATED WITH ANY        A34816 40200000
* CURRENTLY ABENDING TASK, BUT WOULD HAVE CAUSED AN EVENTUAL     A34816 40300000
* ABEND OF THE WHOLE JOBSTEP.  THE GENERAL EFFECT OF THIS        A34816 40400000
* CHECK IS TO PROTECT THE JOBSTEP FROM PROGRAMS WHICH ARE NOT    A34816 40500000
* WELL BEHAVED.                                                  A34816 40600000
         TM    TCBNSTAE,RMSCODE         STORAGE RECONFIGURATION? A34816 40700000
         BO    TASKPURG                 YES. DO PURGE NOW        A34816 40800000
         ST    ATCBREG,RBEXSAVE+16      SAVE TOP TCB             A34816 40900000
         L     ATCBREG,TCBJSTCB         PICK UP JOB STEP TASK    A34816 41000000
         BAL   RETREG,CHKJSFQE          CHECK SP 251 FQES        A34816 41100021
         L     ATCBREG,RBEXSAVE+16      RESTORE JOB STEP TASK    A34816 41200000
TASKPURG EQU   *                                                 A34816 41300000
         LCR   ATCBREG,ATCBREG          INDICATE FIRST TIME ENTRY       41400000
ABD33    BAL   LINKREG,SELECT           WAS TASK SELECTED               41500000
         B     NEXTLOAD                 GO TO NEXT MODULE         21472 41600000
*        FALL THROUGH IF TASK SELECTED                            20472 41700000
*********************************************************************** 41800000
* P U R G E  S U B R O U T I N E                                        41900000
*********************************************************************** 42000000
         TM    TCBNSTAE,RMSCODE         WAS STG RECONF THE CALLER    2K 42300000
         BO    WTOPURGE                 YES, SKIP TO WTO PURGE    M3810 42400000
         EJECT                                                          42500000
****************************************************************        42600000
*        VALIDITY CHECK FQE'S FOR SELECTED TASK                         42700000
****************************************************************        42800000
*                                                                       42900000
* THE VALIDITY CHECK ROUTINE IS MADE UP OF TWO PARTS, MSSLOOP     21472 43000000
* AND THE ACTUAL FQE CHECK. PRIOR TO RELEASE 21, MSSLOOP WAS NOT  21472 43100000
* ONLY USED FOR THE FQE VALIDITY CHECK, BUT ALSO FOR THE 2NDARY   21472 43200000
* STEAL CORE ROUTINE WHICH WAS PART OF THIS MODULE. A FEW BYTES   21472 43300000
* COULD BE SAVED BY COMPRESSING BOTH ROUTINES INTO ONE AND THIS   21472 43400000
* SHOULD BE CONSIDERED IF THIS MODULE EVER HAS TO BE SPLIT OR     21472 43500000
* COMPRESSED, BUT THE ROUTINES HAVE BEEN LEFT SEPARATE IN THIS    21472 43600000
* MODULE TO MAKE THE ROUTINE CONFORM WITH THE CODE IN THE STEAL   21472 43700000
* MODULE AND TO PROVIDE A READY MADE ROUTINE TO LOOK AT SPQES     21472 43800000
* SHOULD ABEND EVER REQUIRE ONE SOMEPLACE ELSE. JUST LEAVING THE  21472 43900000
* MSSLOOP INTACT IN THE STEAL MODULE WOULD NOT SAVE A COMPLETE    21472 44000000
* COPY IF THE SECONDARY STEAL IS EVER ALTERED OR ELIMINATED.      21472 44100000
*                                                                       44200000
* THE FOLLOWING REGISTERS ARE NEEDED FOR INPUT BY THESE ROUTINES  21472 44300000
*                                                                       44400000
*         14 RETREG   RETURN ADDR WHEN VALIDITY CHECK IS DONE     21472 44500000
*          8 ATCBREG  ADDR OF TCB WHICH IS BEING CHECKED          21472 44600000
*          9 BASEREG  BASE REGISTER FOR THIS MODULE               21472 44700000
*                                                                       44800000
*  THE FOLLOWING REGISTERS ARE USED BY THESE ROUTINES             21472 44900000
*                                                                       45000000
*          1 WKREG                                                21472 45100000
*          2 SAVEREG                                              21472 45200000
*          6 DQEREG,TEMPREG                                       21472 45300000
*          7 FQEREG                                               21472 45400000
*         10 TOPREG                                               21472 45500000
*         11 SPQEREG                                              21472 45600000
*         12 BRNREG                                               21472 45700000
*         15 RTNREG                                               21472 45800000
*                                                                       45900000
*  REGISTERS 0, 3, 4, 5, AND 13 ARE TRANSPARENT.                        46000000
*                                                                       46100000
         LA    RETREG,PIECHK            ESTABLISH BRANCH TO PIE RELEASE 46200000
CHKJSFQE EQU   *                                                 A34816 46300000
         LA    RTNREG,GETFQE            ESTABLISH BRANCH TO PROC FQE    46400000
         EJECT                                                          46500000
MSSLOOP  L     SPQEREG,TCBMSSP          GET SPQE ADDRESS                46600000
SPQECHK1 EQU   *                                                        46700000
         LA    SPQEREG,0(,SPQEREG)       CLEAR HI BYTE            21472 46800000
         LTR   SAVEREG,SPQEREG          SAVE ADDR AND TEST FOR 0   5566 46900000
         BCR   Z,RETREG                 SPQE=ZERO, BR TO NEXT RT  20472 47000000
         SPACE 2                                                        47100000
* THE FOLLOWING 4 INSTRUCTIONS ARE NOT PART OF MSSLOOP. THEY      21472 47200000
* WERE ADDED IN RELEASE 21 TO SKIP THE FQE VALIDITY CHECK FOR     21472 47300000
* PROTECTED CORE SINCE A CHECK OF SUCH CORE COULD MASK OUT A      21472 47400000
* SERIOUS SYSTEM PROBLEM, I. E. SOME SYSTEM ROUTINE CLOBBERING    21472 47500000
* FQES IN PROTECTED CORE.                                         21472 47600000
         SPACE                                                          47700000
*                                                              @PD64479 47800021
** THE INSTRUCTIONS TO BYPASS CHECKING SP-252                  @PD64479 47850021
** HAVE BEEN REMOVED.  IF CORE HAS BEEN STOLEN                 @PD64479 47900021
** FROM SP-252, THE PGMS WHICH ASSUMED THAT                    @PD64479 47950021
** CORE TO BE VALID MAY HAVE OVERLIAD FQES.                    @PD64479 48000021
** ALSO, THIS ALLOWS PRGMS WITH BAD SP-252 CHAINS              @PD64479 48050021
** TO TERMINATE, KEEPING THE SYSTEM ALIVE.  THE                @PD64479 48100021
** ORIGINAL DUMP SHOULD BE ENOUGH TO TELL THAT                 @PD64479 48150021
** A PROBLEM EXISTS.                                           @PD64479 48200021
*                                                              @PD64479 48250021
         SPACE 2                                                        48300000
SPQECHK2 EQU   *                                                        48400000
         L     TEMPREG,SPQEDQE(,SPQEREG) SPQE IS NOT ZERO. GET          48500000
*                                         SPQE OR DQE ADDR              48600000
         TM    SPQEFLGS(SPQEREG),SPQESHAR IS SUBPOOL SHARED-DQE OR SPQE 48700000
         BZ    TESTDQE                   NO,BRANCH TO PROCESS DQE       48800000
         LA    SPQEREG,0(,TEMPREG)       YES, PROCESS SPQE OF OWNER     48900000
         B     SPQECHK2                                                 49000000
         SPACE 2                                                        49100000
* THE NEXT INSTRUCTION IS USED ONLY BY THE FQE VALIDITY CHECK     20472 49200000
* ROUTINE, NOT BY MSSLOOP. THE INSTRUCTION WAS PLACED HERE FOR    20472 49300000
* SPACE CONSIDERATIONS.                                           20472 49400000
         SPACE                                                          49500000
BADFQE   EQU   *                                                 A25410 49600000
         XC    1(3,DQEREG),1(DQEREG)    ZERO FQE PTR IN DQE      A25410 49700000
         SPACE 2                                                        49800000
GETDQE   EQU   *                                                        49900000
         L     TEMPREG,DQEDQE(,DQEREG)  GET NEXT DQE                    50000000
TESTDQE EQU   *                                                         50100000
         LA    DQEREG,0(,TEMPREG)       PROCESS NEW DQE                 50200000
         LTR   DQEREG,DQEREG            IS THIS LAST DQE                50300000
         BCR   NZ,RTNREG                NO, BRANCH                20472 50400000
GETSPQE  EQU   *                                                  21472 50500000
         LR    SPQEREG,SAVEREG          RESTORE REAL SPQE ADDRESS       50600000
         TM    SPQEFLGS(SPQEREG),SPQELAST IS THIS LAST SPQE             50700000
         BCR   O,RETREG                 YES, BRANCH TO NEXT RTN   20472 50800000
         L     SPQEREG,SPQESPQE(,SPQEREG) NO, GET NEXT SPQE             50900000
         B     SPQECHK1                 BRANCH TO SAVE THE SPQE         51000000
         EJECT                                                          51100000
GETFQE   EQU   *                                                        51200000
         L     TOPREG,DQEBLOCK(,DQEREG) GET BLOCK ADDRESS        A25410 51300000
         AL    TOPREG,DQELGTH2(,DQEREG) COMPUTE TOP OF DQE       A25410 51400000
         LA    TOPREG,1(,TOPREG)        CLEAR HI BYTE & BUMP      M4344 51500000
*                                        FOR FIRST TIME ENTRY     M4344 51600000
         L     FQEREG,DQEFQE(,DQEREG)   GET FQE ADDRESS                 51700000
         LA    FQEREG,0(,FQEREG)        CLEAR HIBYTE                    51800000
TESTFQE  EQU   *                                                        51900000
         LTR   FQEREG,FQEREG            IS THERE AN FQE                 52000000
         BZ    GETDQE                   NO, BRANCH TO PROCESS NEXT DQE  52100000
         LA    BRNREG,BADFQE            INITIALIZE BRANCH REG     20472 52200000
         L     WKREG,4(,FQEREG)         GET LENGTH OF FREECORE     4611 52300000
         LTR   WKREG,WKREG              IS LENGTH ZERO             4611 52400000
         BCR   Z,BRNREG                 YES,ZERO FQE PTR IN DQE   20472 52500000
         TM    7(FQEREG),X'07'     INSURE DOUBLEWORD           @DS63452 52530021
         BCR   NZ,BRNREG           ALIGNMENT                   @DS63452 52560021
         AR    WKREG,FQEREG             ADD FQE ADDRESS TO SIZE  A25410 52600000
         CR    WKREG,TOPREG             IS SIZE TOO LARGE        A25410 52700000
         BCR   NL,BRNREG                YES GO TO ZERO FQE       A36645 52800000
         TM    4(FQEREG),X'FF'          IS HI-ORDER OF SIZE ZERO A25410 52900000
         BCR   NZ,BRNREG                NO,INVALID                20472 53000000
         TM    0(FQEREG),X'FF'          IS HIGH ORDER OF FQE 0   A25410 53100000
         BCR   NZ,BRNREG                NO,INVALID                20472 53200000
         L     WKREG,0(,FQEREG)         GET NEXT FQE             A25410 53300000
         LA    SEVENREG,7               SET UP TO TEST DBL WRD   A25410 53400000
         NR    SEVENREG,WKREG           TEST IF DOUBLE WORD      A25410 53500000
         BCR   NZ,BRNREG                NO-BRANCH                 20472 53600000
         CR    WKREG,FQEREG             NEXT LESS THAN UPPER LMT  M3889 53700000
         BCR   NL,BRNREG                NO-BRANCH                 20472 53800000
         LR    TOPREG,FQEREG            SAVE CURRENT AS TOP      A25410 53900000
         LR    FQEREG,WKREG             SET UP FQE TO TEST       A25410 54000000
         B     TESTFQE                  VALIDITY CHECK NEXT FQE    4611 54100000
         EJECT                                                          54200000
****************************************************************        54300000
*     FREE THE PIE                                                      54400000
****************************************************************        54500000
*                                                                       54600000
PIECHK   EQU   *                                                        54700000
         L     SCVTREG,CVTABEND        GET SCVT ADDRESS           21472 54800000
         L     PARREG1,TCBPIEP         ESTABLISH PIE ADDRESS.     21472 54900000
         LTR   PARREG1,PARREG1         Q. IS THERE A PIE?         21472 55000000
         BZ    NOPIE                   NO. SKIP FREE OF THE PIE   21472 55100000
         L     PARREG0,PIECONS         PUT SPID 250 AND SIZE 32 IN REG  55200000
         LR    SAVTCB,TCBREG           SAVE CURRENT TCB          A33742 55300000
         LR    TCBREG,ATCBREG          USE SELECT TCB FOR FREE   A33742 55400000
         XC    TCBPIEP(WORD),TCBPIEP   ZERO PIEP PTR IN TCB        MP0C 55500000
         OI    SCVTFMSA,SCVTSW1        SET CONDITIONAL FREEMAIN   21472 55600000
         L     RETREG,SCVTRMBR         ADDRESS REGMAIN BR ENTRY   21472 55700000
         BALR  RETREG,RETREG           CONDITIONALLY FREE THE PIE 21472 55800000
         L     SCVTREG,CVTABEND        GET SCVT ADDRESS           21472 55900000
         NI    SCVTFMSA,255-SCVTSW1    RESET CONDIT FREMAIN SW    21472 56000000
         LR    ATCBREG,TCBREG          RESTORE SELECTED TCB      A33742 56100000
         LR    TCBREG,SAVTCB           RESTORE CURRENT TCB       A33742 56200000
NOPIE   EQU   *                                                         56300000
         EJECT                                                          56400000
*********************************************************************   56500000
*   TIMER PURGE INTERFACE                                               56600000
*********************************************************************   56700000
*    INPUT REGISTERS-                                                   56800000
*        REG  3 -  CVT                                                  56900000
*        REG  4 -  TCB TO BE PURGED                                     57000000
*        REG 14 -  RETURN ADDRESS                                       57100000
*                                                                       57200000
*        TRANSPARENT REGISTERS -  2-5,9,14                              57300000
*                                                                       57400000
         L     RPTIMER,SCVTPGTM         GET PURGE TIMER ROUTINE ADDR    57500000
         OI    SCVTFMSA,SCVTSW2        SET COND FREEMAIN SW   AH A50601 57550021
*                                        ACROSS TAXE PURGE HOOK   M4915 57700000
*                                        IN EOT'S TIMER PURGE.    M4915 57800000
         LR    SAVTCB,TCBREG            SAVE CURRENT TCB REG            57900000
         LR    TCBREG,ATCBREG           SPECIFY SELECTED TCB ADDR       58000000
         BALR  RETREG,RPTIMER           LINK TO PURGE TIMER ROUTINE     58100000
         LR    ATCBREG,TCBREG           RESTORE SELECTED TCB            58200000
         LR    TCBREG,SAVTCB            RESTORE CURRENT TCB             58300000
         L     SCVTREG,CVTABEND         GET SCVT ADDRESS      AH A50601 58350021
         NI    SCVTFMSA,255-SCVTSW2     RESET FREEMAIN SW     AH A50601 58400021
         SPACE 1                                                        58500000
* NOTE: IF THERE IS A RECURSION ACROSS THE TAXE PURGE, ABEND      M4915 58600000
* WILL HANDLE IT AS IF ENTRY WAS THE SAME AS THE PREVIOUS ENTRY   M4915 58700000
* TO ABEND, I.E. IF ABEND WAS HANDLING A VALID RECURSION WHEN IT  M4915 58800000
* RECURSED PURGING TAXES, THEN ABEND WILL CONTINUE TO HANDLE THE  M4915 58900000
* VALID RECURSION. THE ONLY DIFFERENCE IS THE ADDITIONAL SVRB     M4915 59000000
* FOR IGC0101C ON THE CHAIN. IF ABEND WAS HANDLING A FIRST TIME   M4915 59100021
* ENTRY, THE RECURSION WILL BE TREATED AS A FIRST TIME ENTRY.     M4915 59200000
         SPACE 3                                                        59300000
* THESE TWO INSTRUCTIONS WERE USED TO CHECK OPEN IN PROCESS. THE A34277 59400000
* CHANGES MADE IN THE OPEN OF THE SYSABEND DATA SET OBSOLETE     A34277 59500000
* THESE INSTRUCTIONS.  IF THE OLD PROCESSING IS EVER REVIVED,    A34277 59600000
* THESE INSTRUCTIONS WILL BE NEEDED AGAIN.                       A34277 59700000
*                                                                       59800000
*        TM    TCBFLGSP+2,TCBOPEN       TEST IF OPEN IN PROCESS  A25382 59900000
*        BO    WTOPURGE                 YES,BYPASS PURGE SO THAT A25382 60000000
*                                       THE OPEN WON'T HANG      A25382 60100000
*                                                                       60200000
         SPACE 3                                                        60300000
*                                                                       60400000
*        PURGE I/O                                                      60500000
*                                                                       60600000
         BAL   LINKREG,PURGEIO         LINK TO PURGE I/O ROUTINE        60700000
         EJECT                                                          60800000
*                                                                       60900000
*        PURGE WTOR                                                     61000000
*                                                                       61100000
* THE INPUT TO THE WTOR PURGE IS AS FOLLOWS                             61200000
*        REG  3 =  CVT                                                  61300000
*        REG  4  =  TCB                                                 61400000
*        REG  5  =  RB                                                  61500000
*        REG  6  =ENTRY POINT                                           61600000
*        REG 14  =  RETURN REG                                          61700000
*        REG  2,9 =  TRANSPARENT ACROSS PURGE                           61800000
WTOPURGE EQU   *                                                        61900000
         LR    TCBREG,ATCBREG           SPECIFY SELECTED TCB ADDR       62000000
         L     SCVTREG,CVTABEND         LOAD ADDR OF ABEND CVT          62100000
         L     ENTRYREG,SCVTPGWR        LOAD ENTRY POINT TO WTOR PURGE  62200000
         BALR  RETREG,ENTRYREG          BRANCH TO WTOR PURGE            62300000
         LR    ATCBREG,TCBREG           REESTABLISH SELECTED TCB        62400000
         L     WKREG,CVTTCBP            LOAD ADDR OF OLD AND NEW        62500000
         L     TCBREG,OLD(,WKREG)       LOAD ADDR OF CURRENT TCB        62600000
*                                                                       62700000
*                                                                       62800000
*        PURGE AEQ2                                                     62900000
*                                                                       63000000
         BAL   LINKREG,PURGEAEQ                                         63100000
         B     ABD33                   GO TO SELECT TASK           4984 63200000
         EJECT                                                          63300000
*********************************************************************   63400000
*        PURGE I/O ROUTINE                                              63500000
*********************************************************************   63600000
PURGEIO  LA    PARREG1,RBEXSAVE         GET PARAM LIST ADDRESS          63700000
         XC    0(12,PARREG1),0(PARREG1) CLEAR PARAMETER LIST            63800000
         MVI   0(PARREG1),X'22'          SET OPTION FLAG           4613 63900000
         ST    ATCBREG,4(,PARREG1)      SPECIFY SELECTED TCB ADDR       64000000
*                                                                       64100000
* PURGE I/O BRANCH INTERFACE                                            64200000
*        REG 1  = PARAMETER LIST                                        64300000
*        REG 14 = RETURN ADDRESS                                        64400000
         L     SCVTREG,CVTABEND         LOAD ADDR OF ABEND CVT          64500000
         L     EPREG,SCVTPGIO           LOAD ADDR OF PURGE I/O          64600000
         ST    2,RBEXSAVE+24            SAVE REG 2               A36648 64700000
         STM   6,8,RBEXSAVE+28          SAVE REGS 6-8            A36648 64800000
PURGEBR  EQU   *                                                        64900000
         BALR  RETREG,EPREG             BR TO PURGE I/O ENTRY PT        65000000
         LA    PARREG0,PURGEBR-IGC0101C LOAD DISP FROM BEG OF LOAD      65100000
         LR    BASEREG,RETREG           LOAD BASEREG WITH CURR ADDR     65200000
         SLR   BASEREG,PARREG0          SUBTRACT DISPLACEMT FROM BEG    65300000
         L     CVTREG,CVTPTR            REESTABLISH CVT REG             65400000
         L     WKREG,CVTTCBP            LOAD PTR TO OLD AND NEW         65500000
         L     TCBREG,OLD(,WKREG)       LOAD ADDR OF CURRENT TCB        65600000
         L     RBREG,TCBRBP             LOAD ADDR OF CURRENT RB         65700000
         L     2,RBEXSAVE+24            RESTORE REG 2            A36648 65800000
         LM    6,8,RBEXSAVE+28          RESTORE REGS 6-8         A36648 65900000
         BCR   15,LINKREG               RETURN TO CALLER OF PURGE I/O   66000000
         EJECT                                                          66100000
*********************************************************************   66200000
*        PURGE AEQ ROUTINE                                              66300000
*********************************************************************   66400000
PURGEAEQ EQU   *                                                        66500000
         L     AEQREG,CVTIERLC         GET ADDRESS OF ERROR LOGICAL     66600000
*                                      CHANNEL Q FROM CVT               66700000
         LA    AEQREG,AEQDISP(,AEQREG) GET ADDR OF NON 16* POINTER      66800000
         LR    IQEREG,AEQREG                                       0123 66900000
SAVEPTR  LR    PREVPTR,IQEREG          SAVE PREVIOUS POINTER       0123 67000000
         L     IQEREG,IQELINK(,PREVPTR) GET NEXT IQE               0123 67100000
         LTR   IQEREG,IQEREG           IS THIS LAST IQE            0123 67200000
         BCR   4,LINKREG               YES,RETURN TO CALLER        0123 67300000
CHKTCB   ST    ATCBREG,RBEXSAVE                                    0123 67400000
         CLC   RBEXSAVE+1(3),IQETCB+1(IQEREG) IQE BELONG TO TCB    0123 67500000
         BNE   SAVEPTR                 NO,GET NEXT IQE             0123 67600000
         MVC   IQELINK(4,PREVPTR),IQELINK(IQEREG) REMOVE IQE       0123 67700000
         L     IQEREG,IQELINK(,PREVPTR) GET NEXT IQE               0123 67800000
         LTR   IQEREG,IQEREG           IS THIS LAST IQE            0123 67900000
         BP    CHKTCB                  NO,BRANCH TO CHECK TCB      0123 68000000
         ST    PREVPTR,AEQLAST(,AEQREG) UPDATE 2ND PTR IN AEQ      0123 68100000
         BCR   15,LINKREG              RETURN TO CALLER                 68200000
         EJECT                                                          68300000
*********************************************************************** 68400000
* TASK SELECT SUBROUTINE                                                68500000
*********************************************************************   68600000
*FIRST TIME ENTRY SHOULD BE MADE WITH ATCBREG CONTAINING THE NEGATIVE   68700000
* ADDRESS OF THE INPUT TCB.SELECTED TASK ADDRESS IS RETURNED IN         68800000
* ATCBREG                                                               68900000
SELECT   EQU   *                                                        69000000
         LTR   SELREG,ATCBREG          IS THIS FIRST TIME ENTRY         69100000
         BC    10,SELECT1              NO,BRANCH                        69200000
         LCR   SELREG,SELREG           YES,MAKE ADDRESS POSITIVE        69300000
         ST    SELREG,RBEXSAVE+TSELSAVE SAVE INPUT TCB ADDRESS   A36648 69400000
SELECT3  LR    ATCBREG,SELREG          THIS TASK SELECTED               69500021
         TM    TCBFLGSP+4,TCBFC        IS SEL TASK COMPLETED     A43837 69520021
         BO    SELECT                  YES. SELECT NEXT TASK     A43837 69540021
         B     4(,LINKREG)             RETURN WITH SELECTED TASK  20472 69600021
SELECT1  EQU   *                                                        69700000
         L     SELREG,TCBLTCP          GET DAUGHTER                     69800000
SELECT2  LTR   SELREG,SELREG           DOES DAUGHTER OR SISTER EXIST    69900000
         BC    7,SELECT3               YES,BRANCH                       70000000
         L     SELREG,TCBNTCP          NO,GET SISTER                    70100000
         TM    TCBCMP,STEPMASK         Q. STEP OR TASK ABEND ?          70200000
         BC    1,SELECT4               IF STEP, BR TO COMPARE JSTCB     70300000
         C     ATCBREG,RBEXSAVE+TSELSAVE Q. IS SCAN COMPLETE?    A36648 70400000
         BCR   E,LINKREG               YES,LAST TIME RETURN       20472 70500000
SELECT4  C     ATCBREG,TCBJSTCB        Q. IS SCAN COMP FOR       A31771 70600000
*                                       TASK ABENDED ?           A31771 70700000
         BCR   E,LINKREG               YES,LAST TIME RETURN       20472 70800000
         L     ATCBREG,TCBOTCP         NO,GET MOTHER                    70900000
         B     SELECT2                                                  71000000
         EJECT                                                          71100000
         DS    0F                                                       71200000
PIECONS  DC    X'FA000020'              CONS TO FREE 32 BYTES OF SP250  71300000
NMLOAD3  DC    CL8'IGC0301C'           NEXT ABEND LOAD            21472 71600000
DARLOAD  DC    CL8'IGC0L01C'           FIRST LOAD OF DAR.         21472 71700000
THISMOD  DC    C'101C'                 FLAG TRACE AS THIS MOD     21472 71800000
         EJECT                                                          72100000
*                                                                       72200000
*                                                                       72300000
*             THE FOLLOWING CODE IS ZAP SPACE FOR MAINTENANCE USE       72400000
*                                                                       72500000
*                                                                       72600000
*                                                                       72700000
         DC    H'0'                                               20472 72800000
         DC    H'0'                                               20472 72900000
         DC    H'0'                                               20472 73000000
         DC    H'0'                                               20472 73100000
         DC    H'0'                                               20472 73200000
         DC    H'0'                                               20472 73300000
         DC    H'0'                                               20472 73400000
         DC    H'0'                                               20472 73500000
         DC    H'0'                                               20472 73600000
         DC    H'0'                                               20472 73700000
         DC    H'0'                                               20472 73800000
         DC    H'0'                                               20472 73900000
         DC    H'0'                                               20472 74000000
         DC    H'0'                                               20472 74100000
         DC    H'0'                                               20472 74200000
         DC    H'0'                                               20472 74300000
         DC    H'0'                                               20472 74400000
         DC    H'0'                                               20472 74500000
         DC    H'0'                                               20472 74600000
         DC    H'0'                                               20472 74700000
         DC    H'0'                                               20472 74800000
         DC    H'0'                                               20472 74900000
         DC    H'0'                                               20472 75000000
         DC    H'0'                                               20472 75100000
         DC    H'0'                                               20472 75200000
         DC    H'0'                                               20472 75300000
         DC    H'0'                                               20472 75400000
         DC    H'0'                                               20472 75500000
         DC    H'0'                                               20472 75600000
         DC    H'0'                                               20472 75700000
         DC    H'0'                                               20472 75800000
         DC    H'0'                                               20472 75900000
         DC    H'0'                                               20472 76000000
         DC    H'0'                                               20472 76100000
         DC    H'0'                                               20472 76200000
         DC    H'0'                                               20472 76300000
         DC    H'0'                                               20472 76400000
         DC    H'0'                                               20472 76500000
         DC    H'0'                                               20472 76600000
         EJECT                                                          77000000
         IHBABCTL                                                       77100000
         MPCVT                                                          77200000
*/*IEAQTM01: CHART */                                                   77300021
*/*IEAQTM01: E ENTRY TO ABEND1 */                                       77400021
*/*IGC0101C: P FLAG SVRB FOR ENTRY TO THIS MODULE */                    77500021
*/*          P TURN OFF VALID RECURSION BIT */                          77600021
*/*          D (NO,,YES,CONVERT) ENTRY TO CONVERT TO STEP ABEND */      77700021
*/*          D (NO,,YES,DARETOFF) TRUE REINSTATEMENT BY DAR */          77800021
*/*          D (YES,,NO,DARTSTS) RECURSIVE ENTRY */                     77900021
*/*          S PURGEAEQ: PURGE AEQS OF 12 BYRE IQES FOR THIS TASK */    78000021
*/*NEXTLOAD: P PREPARE TO GO TO ABEND3 */                               78100021
*/*XCTL:     P FLAG XCTL FOR THE TRACE TABLE ENTRY */                   78200021
*/*          R XSFER CONTROL TO INDICATED MODULE */                     78300021
*/*DARTSTS:  D (N,,Y,DARPROC) IS STATUS MUST COMPLETE */                78400021
*/*          D (N,,Y,DARPROC) IS CURR THE MASTER SCHEDULER */           78800021
*/*          D (Y,,N,ABD26) IS CURR A SYSTEM TASK */                    79000021
*/*DARPROC:  P SET TOP ABENDING TASK FLAG */                            79100021
*/*          S PURGEAEQ: PURGE AEQS FOR IQES FOR THIS TASK */           79300021
*/*          P (,XCTL) PREPARE TO GO TO DAR */                          79400021
*/*CONVERT:  P (,HOUSKEEP) USE PASSED COMP CODE TO CREATE TRUE COMP     79500021
*/* CODE & PUT IT IN JOB STEP TCB */                                    79600021
*/*DARETOFF: P ELIMINATE COMMUNICATION CONFIGURATION */                 79700021
*/*ABD26:    P DETERMINE TOP ABENDING TASK */                           79800021
*/*          P INSURE CORRECT COMPLETION CODE IN TOP ABENDING TASK TCB  80000021
*/**/                                                                   80100021
*/*HOUSKEEP: P INDICATE 1ST TIME ENTRY */                               80200021
*/*ABD27:    S (SLTD,,LAST,ABD31) SELECT: ONE TASK FROM ABENDING TREE   80300021
*/**/                                                                   80320021
*/*          P  SET ABEND & PREVENT ASYN EXITS */                       80400021
*/*          D (N,,Y,ABD27) CURRENT TCB */                              80500021
*/*          P (,ABD27)  RESET ABTERM & REC BITS */                     80600021
*/*ABD31:    D (Y,,N,AROUND) IS THIS AN M65MP */                        80700021
*/*          S TESTDSP: STOP NONDISP TASK RUNNING ON OTHER CPU */       80800021
*/*AROUND:   P FLAG  AS TOP ABENDING TASK */                            80900021
*/*          D (N,,Y,TASKPURG) STORAGE RECONF */                        81000021
*/*          S CHKJSFQE: CHECK SUBPOOL 251 */                           81200021
*/*TASKPURG: P INDICATE 1ST TIME ENTRY */                               81400021
*/*ABD33:    S (SLTD,,LAST,NEXTLOAD) SELECT: A TASK FROM ABENDING TREE  81500021
*/**/                                                                   81520021
*/*          D (N,,Y,WTOPURGE) STORAGE RECONF */                        81700021
*/*          P ESTABLISH RETURN TO PIE RELEASE */                       81800021
*/*CHKJSFQE: P (,MSSLOOP) ESTABLISH RETURN TO PROCESS FQE */            81900021
*/*MSSLOOP:  E ENTRY TO MSS LOOK AT ROUTINE */                          82000021
*/*SPQECHK1: D (N,,Y,%BRETREG) SPQECHK:IS SPQE PTR=0 */                 82100021
*/*          D (NO,,YES,GETSPQE) SUBPOOL FOR PROTECTED CORE */          82120021
*/*SPQECHK2: P  GET NEXT SPQE OR DQE */                                 82200021
*/*          D (Y,,N,TESTDQE) IS SUBPOOL SHARED */                      82300021
*/*          P (,SPQECHK2) PROCESS SPQE FO OWNER */                     82400021
*/*%BRETREG: R RETURN */                                                82500021
*/*BADFQE:   P (,GETDQE) ZERO FQE PTR IN DQE */                         82600021
*/*GETDQE:   P GET NEXT DQE */                                          82700021
*/*TESTDQE:  D (Y,,N,%BRTNREG) THE LAST DQE? */                         82800021
*/*GETSPQE:  D (N,,Y,%BRETREG) LAST SPQE? */                            82900021
*/*          P (,SPQECHK1) GET NEXT SPQE */                             83000021
*/*%BRTNREG: R RETURN */                                                83100021
*/*GETFQE:   E ENTRY TO FQE VALIDITY CHECK */                           83200021
*/*          P GET FQE & COMPUTE LEN */                                 83300021
*/*TESTFQE:  D (Y,,N,GETDQE) IS THER AN FQE */                          83400021
*/*          P GET FREE CORE LENGTH */                                  83500021
*/*          D (N,,Y,BADFQE) IS LEN=0 */                                83600021
*/*          D (N,,Y,BADFQE) IS SIZE TOO LARGE */                       83700021
*/*          D (Y,,N,BADFQE) IS HI-ORDER OF SIZE ZERO */                83800021
*/*          D (Y,,N,BADFQE) IS HI-ORDER BIT OF FQE ZERO */             83900021
*/*          D (Y,,N,BADFQE) IS ADDR ON WORD BNDRY */                   84000021
*/*          D (Y,,N,BADFQE) IS NXT < UPPER LMT */                      84100021
*/*          P (,TESTFQE) SAVE CURR AS TOP ,GET FQE TO TEST */          84200021
*/*PIECHK:   E RE-ENTRY TO MAINLINE AFTER FQE VAL CHECK */              84300021
*/*          D (Y,,N,NOPIE) SELECT TCB HAVE A PIE */                    84500021
*/*          P PREPARE FOR CONDITIONAL FREEMAIN OF THE PIE */           84600021
*/*          S RMBRANCH: FREE THE PIE */                                84700021
*/*          P RESET CONDITIONAL FREEMAIN INDICATORS */                 84800021
*/*NOPIE:    P SET REC BIT, PARAM, SAVE CURR & SEL TCBS */              84900021
*/*          S TIMER: PURGE TIMER RTN */                                85000021
*/*          P RESTORE CURR &SEL TCBS, RESET REC BIT */                 85100021
*/*          S PURGEIO: PURGE ACTIVE I/O */                             85300021
*/*WTOPURGE: S WTORPURG: PURGE WTOR REQSTS */                           85400021
*/*          P REESTABLISH SEL TCB, GET NEW AND OLD */                  85600021
*/*          S (,ABD33) PURGEAEQ: AEQ PURGE */                          85700021
*/*PURGEIO:  E ENTRY */                                                 85800021
*/*          P SET PARAM LIST & SAVE REGS */                            85900021
*/*PURGEBR:  S PURGE: OUTSTANDING I/O */                                86000021
*/*          P RESTORE REGS */                                          86100021
*/*%RETURN:  R RETURN TO CALLER */                                      86200021
*/*PURGEAEQ: E ENTRY TO AEQ PURGE */                                    86300021
*/*          P GET ADDRESS OF ERROR LOGICAL CHANNEL Q & NON-16* PTR */  86400021
*/*SAVEPTR:  P SAVE PREVIOUS PTR & GET NXT IQE */                       86500021
*/*          D (N,,Y,%RETURN) LAST IQE */                               86600021
*/*CHKTCB:   D (Y,,N,SAVEPTR) IQE FOR THIS TCB */                       86700021
*/*          P REMOVE IQE  & GET NEXT IQE */                            86800021
*/*          D (Y,,N,CHKTCB) LAST IQE */                                86900021
*/*          P (,%RETURN) UPDATE 2ND PTR IN AEQ */                      87000021
*/*SELECT:   E ENTRY TO TASK SELECT ROUTINE */                          87100021
*/*          D (Y,,N,SELECT1) FIRST TIME ENTRY */                       87200021
*/*          P ERASE 1ST TIME ENTRY & SAVE INPUT TCB */                 87300021
*/*SELECT3:  D (YES,SELECT,NO,) TASK COMPLETE */                        87400021
*/*          R RETURN WITH TOP SELECTED TCB */                          87500021
*/*SELECT1:  P GET DAUGHTER ADDRESS */                                  87600021
*/*SELECT2:  D (N,,Y,SELECT3) DAUGHTER OR SISTER EXIST */               87700021
*/*          P GET SISTER ADDRESS */                                    87900021
*/*          D (N,,Y,SELECT4) STEP ABEND */                             88000021
*/*          D (N,,Y,%RETURN) IS SCAN COMPLETE */                       88100021
*/*SELECT4:  D (N,,Y,%RETURN) SCAN DONE FOR ABDNG TSK */                88200021
*/*          P (,SELECT2) GET MOTHER */                                 88300021
*/*IEAQTM01: END */                                                     88800021
         END                                                            88900021
