         TITLE 'IEAQTM04 / WTP FOR TYPE 1 MSG, MSG PURGE / IGC0401C '   00100000
IGC0401C START                                                          00200000
***************************************************************         00300000
*                        PROLOGUE                             *         00400000
***************************************************************         00500000
*                                                                       00600000
*   STATUS-                                                             00700021
*      CHANGE LEVEL = 0                                                 00800021
*                                                                       00900000
*   FUNCTION-                                                           01000021
*                                                                       01020021
*   1. IF ENTRY WAS DUE TO WTP RECURSION, CONTROL IS PASSED             01040021
*      TO STEP FOUR FOR MSG RELATED PURGES AND CLEANUP.                 01060021
*                                                                       01080021
*   2. A CONDITIONAL GETMAIN IS ISSUED TO GET CORE FROM                 01100021
*      WHICH TO WRITE MESSAGES.  IF THE GETMAIN FAILS, NO               01200021
*      LIST ELEMENTS ARE FORMATTED. CONTROL IS PASSED TO                01300021
*      STEP FOUR FOR LIST CLEANUP.                                      01400021
*                                                                       01500000
*   3. THE INFORMATION LIST MODULE, IEAQMSGS, IS SCANNED                01600021
*      FOR ENTRIES WHOSE TCB ADDRESS MATCHES THE ADDRESS                01700021
*      OF THE CURRENTLY ABENDING TCB.  FOR EACH SUCH ENTRY              01800021
*      FOUND, THE INFORMATION IS FORMATTED INTO AN IEA7XXI              01900021
*      MESSAGE AND OUTPUT VIA WTP.                                      02000021
*                                                                       02100000
*   4. WHEN ALL ENTRIES HAVE BEEN OUTPUT, A CHECK IS MADE OF            02200021
*      THE INFORMATION LIST FOR ENTRIES CORRESPONDING TO                02300000
*      TASKS IN THE ABENDING TREE. SUCH ENTRIES ARE PURGED              02400000
*      SO THE ELEMENTS CAN BE USED AGAIN.                               02500021
*                                                                       02520021
*   5. A LOWER LEVEL TASK MAY HAVE ABENDED EARLIER AND BEEN             02540021
*      PROCESSING TYPE 1 MESSAGES FOR THAT TASK WHEN THE                02560021
*      CURRENT ABEND OCCURRED. IF SO THEN ABEND4 MAY HAVE               02580021
*      ALREADY OBTAINED STORAGE FOR A WTP BUFFER; THEREFORE,            02584021
*      ABEND NEXT CHECKS FOR SUCH A SITUATION AND IF THERE IS           02588021
*      A BUFFER FOR A SUBTASK, IT IS FREED.                             02592021
*                                                                       02600000
*   6. WHEN ALL ENTRIES HAVE BEEN PURGED, ABEND4 DETERMINES             02700021
*      WHERE TO ROUTE CONTROL TO NEXT AND XCTLS TO THE PROPER           02800000
*      MODULE (IGC0501C IF RORI IS IN THE SYSTEM, OTHERWISE TO          02900000
*      IGC0701C IF A DUMP IS WANTED, IGC0B01C IF IT IS NOT).            03000021
*                                                                       03100000
*   ENTRY POINTS-                                                       03200000
*      IGC0401C:                                                        03300021
*         ENTERED VIA XCTL FROM IEAQTM03 FOR FIRST TIME ENTRY           03400021
*         OR ON WTP RECURSION.                                          03500021
*                                                                       03700000
*   INPUT-                                                              03800021
*      REGISTER CONTENT:                                                03900021
*         R3 = ADDRESS CVT                                              04000021
*         R4 = ADDRESS TCB                                              04100021
*         R5 = ADDRESS CURRENT RB                                       04200021
*                                                                       04300021
*      THE FORMAT OF THE INFORMATION LIST ENTRY IS SHOWN                04400021
*      BY THE INFORMATION LIST DSECT, INFOLIST, INCLUDED                04500021
*      AT THE END OF THIS MODULE. THE FIRST WORD IN THE LIST            04600021
*      POINTS TO THE FIRST BYTE BEYOND THE LAST INFORMATION             04620021
*      LIST ENTRY. IF THERE ARE NO ENTRIES (NOT POSSIBLE                04640021
*      IN RELEASE 21. THE CODE IS ONLY TO FACILITATE ANY                04660021
*      FUTURE CHANGE WHICH ALLOWS SUCH A CASE.) THE FIRST               04680021
*      WORD POINTS TO THE SECOND WORD. ORDINARILY THE SECOND            04684021
*      WORD IS THE BEGINNING OF THE FIRST INFO LIST ENTRY.              04688021
*                                                                       04700000
*   OUTPUT-                                                             04800021
*      REGISTER CONTENT:                                                04900021
*         R3 = ADDRESS CVT                                              05000021
*         R4 = ADDRESS TCB                                              05100021
*         R5 = ADDRESS CURRENT RB                                       05200021
*                                                                       05300000
*      A WTP IS ISSUED FOR EACH ENTRY IN THE INFORMATION                05400021
*      LIST WHICH WAS ENTERED FOR THIS TCB, I.E. INFTCB                 05500021
*      CONTAINS THE ADDRESS OF THE CURRENTLY ABENDING TCB.              05600021
*                                                                       05700000
*   EXTERNAL REFERENCES-                                                05800021
*      THE ADDRESS OF THE INFORMATION LIST MODULE IS                    05900021
*      OBTAINED FROM A POINTER, CVTQMSGS.                               06000021
*                                                                       06100000
*   EXITS, NORMAL-                                                      06200000
*      XCTL TO IGC0501C IF ROLLOUT IS IN THE SYSTEM,                    06300000
*      TO IGC0701C IF A DUMP IS WANTED, TO IGC0B01C                     06400000
*      IF A DUMP IS NOT WANTED.                                         06500000
*                                                                       06600000
*   EXITS, ERRORS- NONE                                                 06900021
*                                                                       07000000
*   TABLE/WORK AREAS-                                                   07100000
*      THE MSG OUTPUT BUFFER, OBTAINED VIA A CONDITIONAL                07200000
*      GETMAIN, CONTAINS ONE WORD FOR PARAMETERS FOR                    07300021
*      THE WTO FOLLOWED BY 72 BYTES IN WHICH TO BUILD                   07400021
*      THE MESSAGE, FOLLOWED BY 4 MORE BYTES FOR PARMS.                 07500021
*                                                                       07600000
*   ATTRIBUTES-                                                         07700021
*      TYPE 4 SVC, PRIVILEGED, DISABLED EXCEPT TO ISSUE                 07800021
*      WTP.                                                             07900021
*                                                                       08000000
*   NOTES-                                                              08100021
*      NOT CHARACTER CODE DEPENDENT.                                    08200021
***************************************************************         08300000
***************************************************************         08400000
         SPACE 5                                                        08500000
*       MISCELANEOUS EQUATES                                            08600000
*                                                                       08700000
GETLEN   EQU   80                                                       08800000
TSOTASK  EQU   X'80'       TIME SHARING TASK FLAG                 21016 08900000
TCBTSTSK EQU   148         DISP TO TIME SHARING FLAG              21016 09000000
JSCB     EQU   X'B4'       DISP TO JSCB ADDR IN TCB          AD  A49808 09050021
TJID     EQU   X'10C'      DISP TO TJID IN JSCB              AD  A49808 09060021
*                                                                       09100000
         EJECT                                                          09200000
***************************************************************         09300000
*    REGISTER EQUATES                                         *         09400000
***************************************************************         09500000
PARREG0  EQU   0                                                        09600000
PARREG1  EQU   1                                                        09700000
MSGBASE  EQU   1             BASE FOR WTP MSG BUFFER                    09800000
LINKREG  EQU   2             INTERNAL LINKAGE REGISTER                  09900000
SAVETCB  EQU   2             SAVE ADDR FOR CURRENT TCB                  10000000
CVTREG   EQU   3             CVT ADDR                                   10100000
TCBREG   EQU   4             CURRENT TCB                                10200000
RBREG    EQU   5             CURRENT RB                                 10300000
LISTREG  EQU   6             ADDR INFO LIST ELEMENT                     10400000
ENDREG   EQU   7             ADDR 1ST BYTE BEYOND INFO LIST             10500000
ATCBREG  EQU   8             ALTERNATE TCB                              10600000
BASEREG  EQU   9             BASE FOR THIS MODULE                       10700000
XCTLREG  EQU   10            EPLOC NAME ADDR FOR NEXT MOD               10800000
WORK     EQU   10                                                       10900000
ARBREG   EQU   10            ALTERNATE RB                               11000000
JSCBREG  EQU   10            ADDR OF J/S CONTROL BLOCK       AD  A49808 11050021
WORK2    EQU   11                                                       11100000
SELREG   EQU   12            USED BY TASK SELECT                        11200000
RETREG   EQU   14                                                       11300000
SCVTREG  EQU   15            ADDR SCVT                                  11400000
RTNREG   EQU   15            RETURN CODE FROM GETMAIN                   11500000
         EJECT                                                          11600000
IGC0401C CSECT                                                          11700000
         BALR  BASEREG,0              ESTABLISH ADDRESSIBILITY          11800000
         USING *,BASEREG          9                                     11900000
         USING CVTSECT,CVTREG     3                                     12000000
         USING TCBSECT,TCBREG     4                                     12100000
         USING RBSECT,RBREG       5                                     12200000
         USING SCVTSECT,SCVTREG   F                                     12300000
         USING TCBDSECT,ATCBREG   8                                     12400000
         USING RBSECT2,ARBREG     A                                     12500000
*                                                                       12600000
         MVI   RBEXSAVE+45,C'4'       IDENTIFY THIS MODULE              12700000
         L     SCVTREG,CVTABEND       GET ADDR OF SCVT                  12720021
         CLI   TCBRECDE,TCBTYP1W      Q. MSG RECURSION?                 12800000
         BE    CLEANUP                YES. PURGE LIST ELEMENTS          12900000
         L     LISTREG,CVTQMSG        ADDR INFO LIST                    13100021
         LA    LISTREG,0(,LISTREG)    CLEAR HI BYTE                     13120021
         SPACE 1                                                        13200000
         L     ENDREG,0(,LISTREG)     END OF INFO LIST                  13300000
         LA    LISTREG,4(,LISTREG)    1ST ENTRY IN INFO LIST            13400000
         SPACE 1                                                        13500000
*                                                                       13600000
*        XXXXXXXXXX                                                     13700000
         USING INFOLIST,LISTREG                                         13800000
*        XXXXXXXXXX                                                     13900000
*                                                                       14000000
         SR    MSGBASE,MSGBASE        INDICATE GETMAIN NOT DONE         14100000
         ST    MSGBASE,RBEXSAVE+4+LISTLEN CLEAR OUT ADDR/SWITCH         14120021
SCAN     EQU   *                                                        14200000
         CR    ENDREG,LISTREG         ALL ENTRIES PROCESSED?            14300000
         BE    CLEANUP                YES. GO TO NEXT MODULE            14400000
         C     TCBREG,INFTCB        ENTRY FOR THIS TCB ADDR  AD  A49808 14450021
         BNE   NEXT                   NO. CHECK NEXT LIST ELEM          14600000
         TM    TCBTSFLG,TSOTASK       TIME SHARING TASK      AD  A49808 14650021
         BZ    FORMAT                 NO-CONTINUE            AD  A49808 14660021
         L     JSCBREG,JSCB(,TCBREG)  JSCB NEEDED FOR        AD  A49808 14670021
*                                      TJID COMPARE          AD  A49808 14680021
         CLC   INFTJID(2),TJID(JSCBREG) ENTRY REALLY FOR     AD  A49808 14690021
*                                       CURRENT TASK         AD  A49808 14692021
         BNE    NEXT                  NO-CHECK NEXT ENTRY    AD  A49808 14694021
FORMAT   EQU   *                                                        14700000
         LTR   MSGBASE,MSGBASE        HAS GETMAIN BEEN DONE YET?        14800000
         BNZ   FORMAT1                IF YES, BYPASS                    14900021
*                                                                       15000000
         SPACE 1                                                        15100000
         MVC   RBEXSAVE+4(LISTLEN),GETLIST MOVE PARAM LIST TO ESA       15200000
         LA    WORK,RBEXSAVE+4+LISTLEN ADDR PTR TO GOTMAINED AREA       15300000
         LA    PARREG1,RBEXSAVE+4     ADDR GETMAIN PARAM LIST           15500000
         GETMAIN A=(WORK),MF=(E,(1))  GET MSG BUFFER CORE               15600000
         LTR   RTNREG,RTNREG          GETMAIN SUCCESSFUL?               15700000
         L     SCVTREG,CVTABEND       PICK UP SCVT ADDR AGAIN           15800000
         BE    FORMAT0                IF YES, START FORMATTING          15900000
         SPACE 1                                                        16000000
* AT THIS TIME THE 5TH WORD IN THE ESA IS ZERO IF NO CORE.              16100000
* AT PRESENT THERE IS NO REASON WHY THE GETMAIN FOR SP 255              16200000
* SHOULD FAIL. IF AT A LATER DATE, THE SUBPOOL SHOULD CHANGE            16300000
* TO AN AREA NOT IN SQS, THE CONDITIONALITY OF THE GETMAIN WILL         16400000
* OBTAIN SOME SIGNIFICANCE.                                             16500000
*                                                                       16600000
         B     CLEANUP                PURGE LIST ENTRIES                16700000
         SPACE 1                                                        16800000
FORMAT0  L     MSGBASE,RBEXSAVE+4+LISTLEN ADDR OF CORE OBTAINED         16900000
*                                                                       17000000
*      XXXXXXXXXX                                                       17100000
         USING MSGFORM,MSGBASE                                          17200000
*      XXXXXXXXXX                                                       17300000
*                                                                       17400000
FORMAT1  EQU   *            R1 CONTAINS ADDR OF GETMAINED AREA          17500000
         UNPK  MSGCC-1(5),INFCC(3)    SET COMPLETION CODE               17600000
         MVI   MSGCC-1,C' '                                             17700000
         TR    MSGCC(3),TRANTAB-X'EF'      INTO MSG AREA.               17800000
         MVC   MSGPARM+2(9),WTO+2     SET SKELETAL MSG ID AND PARMS     17900000
         CLI   INFCC+1,X'05'           CORRECT                          18000000
         BL    FORMAT2                  MSG                             18100000
         MVI   MSGID+5,C'1'             ID                              18200000
         BE    FORMAT2                  FOR DIFFERENT                   18300000
         MVI   MSGID+5,C'2'             SVC CODES                       18400000
FORMAT2  MVC   MSGRC(3),BLANKS                                          18500000
         SR    WORK,WORK                                                18600000
         IC    WORK,INFRCL            GET POSSIBLE                      18700000
         SRL   WORK,5                  REASON CODE IN REG               18800000
         LTR   WORK,WORK              WAS REASON CODE GIVEN?            18900000
         BE    FORMAT3                NO. DON'T PUT IN MSG              19000000
         STC   WORK,MSGRC+1           SET REASON                        19100000
         OI    MSGRC+1,X'F0'           CODE IN MSG.                     19200000
         MVI   MSGRC,C'-'                                               19300000
FORMAT3  L     WORK,TCBTIO            GET TIOT ADDR                     19400000
         MVC   MSGJOB(8),0(WORK)      SET JOBNAME IN MESSAGE            19500000
         TM    INFFLG,INFFLG0         WAS THIS BRANCH ENTRY?            19600000
         BZ    FORMAT4                NO. CONTINUE                      19700000
         UNPK  MSGJOB(9),INFBADDR(5)  IF YES, SET BRANCH ADDRESS        19800000
         TR    MSGJOB(8),TRANTAB-X'EF' IN JOBNAME FIELD OF MSG          19900000
FORMAT4  MVI   MSGJOB+8,C' '          SET BLANK AFTER JOBNAME           20000000
         MVC   MSGSTEP(8),8(WORK)     SET STEPNAME IN MESSAGE           20100000
         MVI   MSGSTEP+8,C' '         SET BLANK AGTER STEPNAME          20200000
*                                                                       20300000
         UNPK  MSGFLG(3),INFFLG(2)    SET FLAG CHARACTERS               20400000
         TR    MSGFLG(2),TRANTAB-X'EF' IN MESSAGE                       20500000
         MVI   MSGFLG+2,C' '          SET BLANK AFTER FLAG FIELD        20600000
*                                                                       20700000
         UNPK  MSGVAR1(9),INFVAR1(5)  UNPACK                            20800000
         UNPK  MSGVAR2(9),INFVAR2(5)   VARIABLE DATA                    20900000
         UNPK  MSGVAR3(9),INFVAR3(5)   IN FORMATTED                     21000000
         UNPK  MSGVAR4(9),INFVAR4(5)   MESSAGE                          21100000
         MVI   MSGVAR1+8,X'EF'        SET PRE-TRANSLATE BLANKS          21200000
         MVI   MSGVAR2+8,X'EF'         BETWEEN VARIABLE DATA WORDS      21300000
         MVI   MSGVAR3+8,X'EF'         TO BE OUTPUT                     21400000
         TR    MSGVAR(35),TRANTAB-X'EF' TRANSLATE ALL TO EBCDIC         21500000
         SPACE 1                                                        21600000
*   CALCULATE LENGTH OF MESSAGE AND SET IN PARM FIELD                   21700000
         NI    INFRCL,X'1F'           TURN OFF REASON CODE IF EXISTS    21800000
         CLI   INFRCL,X'10'           COMPARE TO MAXIMUM LENGTH         21900000
         BNH   FORMAT5                IF NOT TOO GREAT, CONTINUE.       22000000
         MVI   INFRCL,X'10'           OTHERWISE, SET TO MAX OF 16.      22100000
FORMAT5  SR    WORK,WORK              CLEAR REGISTER                    22200000
         IC    WORK,INFRCL            NO. OF VARIABLE BYTES TO OUTPUT   22300000
         SRDL  WORK,2                 NO. OF FULL WORDS OF VAR DATA     22400000
         MH    WORK,H9                9 BYTES INCLUDING LEADING BLANK  *22500000
                                     TO OUTPUT 4 BYTES OF VARIABLE DATA 22600000
         SRL   WORK2,30               REMAINDER IN WORK2                22700000
         SLL   WORK2,1                REMAINDER X 2 FOR OUTPUT          22800000
         LTR   WORK2,WORK2            IF NO REMAINDER                   22900000
         BE    FORMAT6                 DON'T INCREMENT                  23000000
         LA    WORK2,1(,WORK2)         ELSE, ADD 1 FOR LEADING BLANK    23100000
         AR    WORK,WORK2              ( LENGTH OF VARIABLE PORTION )   23200000
FORMAT6  LA    WORK,FIXEDLNG+4(,WORK)  + ( LENGTH OF FIXED PORTION ) +4 23300000
         STH   WORK,MSGPARM            = MESSAGE LENGTH + 4 BYTES PARMS 23400000
         LA    WORK,MSGPARM(WORK)     END OF MSG                        23500000
         MVC   0(4,WORK),WTPPARM2     SET DESC CODE + ROUT              23600000
*                                      CODE AFTER MESSAGE.              23700000
         MVI   TCBRECDE,TCBTYP1W+TCBREC SET MSG RECUR CONFIG            23800000
         SPACE 1                                                        23900000
         WTO   MF=(E,(1))             WRITE MESSAGE                     24000000
         SPACE 1                                                        24100000
         MVI   TCBRECDE,X'00'         END OF VALID RECURSION            24200000
         L     MSGBASE,RBEXSAVE+4+LISTLEN RELOAD BUFFER ADDR  AI  M0604 24220021
         XC    0(INFLEN,LISTREG),0(LISTREG) ZERO OUT ENTRY              24300000
NEXT     EQU   *                                                        24400000
         LA    LISTREG,INFLEN(,LISTREG) GET NEXT ENTRY ADDR             24500000
         B     SCAN                   CHECK NEXT ENTRY.                 24600000
         EJECT                                                          24700000
*****************************************************************       24800000
*             INFORMATION LIST CLEANUP AND PURGE                        24900000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *       25000000
*                                                                       25100000
*   AFTER ALL MSGS ARE PUT OUT, ALL ENTRIES IN THE INFORMATION          25200000
*   LIST FOR ALL TCBS PURGED AS A RESULT OF THIS ABEND MUST BE          25300000
*   CLEARED.                                                            25400000
*                                                                       25500000
*   IN ADDITION, ANY CORE GOTTEN BY ANY OF THESE TASKS BY               25600000
*   IGC0401C MUST BE FREED. THE FREEMAIN PARAMETER LIST IS              25700000
*   IN THE EXTENDED SAVE AREA OF THE ABEND4 SVRB AT RBEXSAVE+4.         25800000
*   IF THE GETMAIN HAD FAILED, THE ADDR (RBEXSAVE+16) WILL              25900000
*   HAVE BEEN SET TO ZERO BY IGC0401C, AND NO FREEMAIN SHOULD           26000000
*   BE ISSUED.                                                          26100000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *       26200000
*                                                                       26300000
CLEANUP  EQU   *                                                        26400000
         LR    ATCBREG,TCBREG          SET FOR CURRENT AS TOP           26500000
         TM    TCBFLGSP,TCBFT          Q. THIS TASK TOP TASK?           26600000
         BO    MSGPURG1                YES. NOW SKAN TREE               26700000
         L     ATCBREG,TCBJSTCB        JSTCB MUST BE TOP                26800000
MSGPURG1 EQU   *                                                        26900000
         LCR   ATCBREG,ATCBREG         READY FOR 1ST TASK SELECT        27000000
NEXTTCB  EQU   *                                                        27100000
         L     SCVTREG,CVTABEND        ADDR SCVT                        27120021
         BAL   LINKREG,SELECTR         SELECT A TASK TO PURGE           27200000
         B     EXIT                    PURGE THRU. TO NEXT MOD          27300000
*                                                                       27400000
* TASK SELECTED DROP THRU FOR PURGE. ADDRESS OF TCB SELECTED            27500000
* IS RETURNED IN ATCBREG.                                               27600000
         SPACE 3                                                        27700000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *       27800000
* FOR SELECTED TCB, CLEAR ALL ENTRIES FROM THE INFORMATION LIST         27900000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *       28000000
*                                                                       28100000
         L     LISTREG,CVTQMSG        ADDR INFO LIST         AD  A49808 28150021
         L     ENDREG,0(,LISTREG)      END OF INFO LIST                 28400000
         LA    LISTREG,4(,LISTREG)     1ST ENTRY IN INFO LIST           28500000
PRGSCAN  CR    ENDREG,LISTREG          Q. ALL ENTRIES PROCESSED?        28600000
         BE    MSGFREE                 YES. NOW CHECK SVRBS             28700000
         C     ATCBREG,INFTCB         ENTRY FOR SEL TCB ADDR AD  A49808 28750021
         BNE   PRGNEXT                 NO. DON'T PURGE THIS ELEM        28900000
         TM    TCBTSFLP,TSOTASK       TIME SHARING TASK      AD  A49808 28950021
         BZ    PRGNTRY                NO-PURGE THE ENTRY     AD  A49808 28960021
         L     JSCBREG,JSCB(,ATCBREG) JSCB NEEDED FOR        AD  A49808 28970021
*                                     TJID COMPARE           AD  A49808 28980021
         CLC   INFTJID(2),TJID(JSCBREG) ENTRY REALLY FOR     AD  A49808 28990021
*                                       SELECTED TASK        AD  A49808 28992021
         BNE   PRGNEXT                NO-CHECK NEXT ENTRY    AD  A49808 28994021
PRGNTRY  EQU   *                                             AD  A49808 28996021
         XC    0(INFLEN,LISTREG),0(LISTREG) PURGE LIST ELEMENT          29000000
PRGNEXT  EQU   *                                                        29100000
         LA    LISTREG,INFLEN(,LISTREG) GET NEXT ENTRY ADDR             29200000
         B     PRGSCAN                 CHECK NEXT ENTRY                 29300000
         SPACE 3                                                        29400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *       29500000
* FOR SELECTED TCB, SEARCH RB CHAIN FOR 'ABEND4' SVRB                   29600021
* CONTAINING PARAMETER LIST FOR CORE TO BE FREED.                       29700000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *       29800000
*                                                                       29900000
MSGFREE  EQU   *                                                        30000000
         L     ARBREG,TCBRBPP          TOP RB OF SELECT TCB             30100000
MSGFREE1 EQU   *                                                        30200000
         TM    RBSTAB2,RBFTP           Q. IS THIS AN SVRB?              30300000
         BNO   NEXTRB                  NO. GET NEXT RB                  30400000
         CLC   RBEXSAV2+40(6),ABEND4   IS THIS AN 'ABEND4' RB?          30500000
         BE    MSGFREE2                YES. CHECK FOR CORE TO FREE.     30600000
NEXTRB   EQU   *                                                        30700000
         L     ARBREG,RBLINK2-1        NO ADDR NEXT RB                  30800000
         LA    ARBREG,0(,ARBREG)       (CLEAR HIGH ORDER BYTE)          30900000
         CR    ARBREG,ATCBREG          END OF RBS?                      31000000
         BE    NEXTTCB                 Y. PURGE DONE THIS TCB AI  M0607 31100021
         B     MSGFREE1                NO. CHECK NEXT RB.               31200000
         SPACE 1                                                        31300000
MSGFREE2 EQU   *                                                        31400000
         NC    RBEXSAV2+4+LISTLEN(4),RBEXSAV2+4+LISTLEN IF ADDR=0,      31500000
         BE    NEXTTCB                  NOTHING TO FREE                 31600000
         LA    PARREG1,RBEXSAV2+4      PARAMETERS FOR FREEMAIN          31700000
         L     SCVTREG,CVTABEND        GET ADDR OF SCVT                 31800000
         L     RTNREG,SCVTLFRM         BRANCH ENTRY TO FREEMAIN         31900000
         LR    SAVETCB,TCBREG          SAVE CURRENT TCB ADDR            32000000
         LR    TCBREG,ATCBREG          SELECT TCB FOR FREEMAIN          32100000
         BALR  RETREG,RTNREG           FREE WTP BUFFER                  32200000
         LR    TCBREG,SAVETCB          RESTORE CURRENT TCB ADDR         32400000
         B     NEXTTCB                                                  32500000
         EJECT                                                          32600000
*****************************************************************       32700000
*                                                                       32800000
* TASK SELECTION SUBROUTINE.                                            32900000
*                                                                       33000000
SELECTR  EQU   *                                                        33100000
         LTR   SELREG,ATCBREG          IS THIS FIRST-TIME ENTRY         33200000
         BC    10,SELECT1R             NO,BRANCH TO START SELECTION     33300000
         LCR   SELREG,SELREG           YES, RECOMPLEMENT TCB ADDRESS    33400000
SELECT3R LR    ATCBREG,SELREG          PASS BACK SELECTED TCB ADDRESS   33500000
         TM    TCBFLGSP+4,TCBFC        Q. TASK ALREADY COMPLETE  A43837 33520021
         BO    SELECTR                 YES. SELECT NEXT TASK     A43837 33540021
         B     4(,LINKREG)             RETURN TO MAIN ROUTINE           33600000
SELECT1R L     SELREG,TCBLTCP          GET DAUGHTER OF INPUT TASK       33700000
SELECT2R LTR   SELREG,SELREG           DOES A DAUGHTER EXIST            33800000
         BC    7,SELECT3R              YES,SELECTION HAS BEEN MADE      33900000
         L     SELREG,TCBNTCP          NO, GET SISTER                   34000000
         TM    TCBFLGSP,TCBFT          Q.IS SCAN OF TREE FINISHED 20472 34100000
         BCR   1,LINKREG               YES, RETURN TO MAINLINE  A41373  34200000
         L     ATCBREG,TCBOTCP         NO, GET MOTHER                   34300000
         B     SELECT2R                BRANCH TO TEST                   34400000
         EJECT                                                          34500000
*****************************************************************       34600000
EXIT     EQU   *                                                        34700000
         LA    XCTLREG,NMLOAD5        READY TO XCTL TO RORI             34800000
         L     ATCBREG,TCBJSTCB       GET JOBSTEP TCB ADRESS            34900000
         L     WORK2,SCVTRTCB         GET ADDR OF ROLLOUT TCB           35000000
         L     WORK2,0(,WORK2)        GET TOP RB ADDR                   35000821
         LTR   WORK2,WORK2            Q. IS ROLLOUT IN SYSTEM?          35200000
         BNZ   XCTL                   YES. GO TO ABEND5                 35300000
         TM    TCBFLGSP,TCBPDUMP      Q. DUMP PREVENTED?                35320021
         BO    SKIPDUMP               YES. SKIP DUMP PROCESSING         35340021
         LA    XCTLREG,NMLOAD7        NAME OF DUMP LOAD                 35400000
         TM    TCBCMP,DUMPMASK        Q. WAS A DUMP REQUESTED?          35500000
         BO    XCTL                   YES. GO TO TAKE DUMP              35600000
SKIPDUMP EQU   *                                                        35620021
         LA    XCTLREG,NMLOAD11       SKIP DUMP ORIENTED MODULES        35700000
XCTL     EQU   *                                                        35800000
         L     PARREG0,THISMOD        FLAG AS THIS MOD FOR TRACE        35900000
         L     PARREG1,4(,XCTLREG)    FLAG NEXT MOD FOR TRACE           36000000
         LA    15,RBEXSAVE            ADDR OF EXTENDED SAVE AREA        36100000
         XCTL  EPLOC=(XCTLREG),SF=(E,(15)) GO TO NEXT MOD               36200000
         EJECT                                                          36300000
***************************************************************         36400000
*      CONSTANTS                                              *         36500000
***************************************************************         36600000
WTO      WTO   'IEA700I',MF=L,ROUTCDE=11,DESC=6                         36700000
WTPPARM2 EQU   *-4                                                      36800000
IEA700I  EQU   WTO+4                                                    36900000
BLANKS   DC    C'   '                                                   37000000
TRANTAB  DC    C' 0123456789ABCDEF'                                     37100000
         DS    0F                                                       37200000
NMLOAD5  DC    C'IGC0501C'                                              37300000
NMLOAD7  DC    C'IGC0701C'                                              37400000
NMLOAD11 DC    C'IGC0B01C'                                              37500000
THISMOD  DC    C'401C'                                                  37600000
H9       DC    H'9'                                                     37700000
ABEND4   DC    C'ABEND4'                                                37800000
         SPACE 5                                                        37900000
***************************************************************         38000000
GETLIST  GETMAIN EC,LV=GETLEN,SP=255,MF=L                               38100000
         SPACE 1                                                        38200000
LISTLEN  EQU   (*-GETLIST+3)/4*4      ROUND TO FULL WORD LENGTH         38300000
***************************************************************         38400000
         EJECT                                                          38500000
***************************************************************         38600000
*                                                             *         38700000
*      THE FOLLOWING CODE IS ZAP SPACE FOR MAINTENANCE USE    *         38800000
*                                                             *         38900000
***************************************************************         39000000
ZAP      DC    H'0'                                                     39100000
         DC    H'0'                                                     39200000
         DC    H'0'                                                     39300000
         DC    H'0'                                                     39400000
         DC    H'0'                                                     39500000
         DC    H'0'                                                     39600000
         DC    H'0'                                                     39700000
         DC    H'0'                                                     39800000
         DC    H'0'                                                     39900000
         DC    H'0'                                                     40000000
         DC    H'0'                                                     40100000
         DC    H'0'                                                     40200000
         DC    H'0'                                                     40300000
         DC    H'0'                                                     40400000
         DC    H'0'                                                     40500000
         DC    H'0'                                                     40600000
         DC    H'0'                                                     40700000
         DC    H'0'                                                     40800000
         DC    H'0'                                                     40900000
         DC    H'0'                                                     41000000
         DC    H'0'                                                     41100000
         DC    H'0'                                                     41200000
         EJECT                                                          41300000
***************************************************************         41400000
*        DSECT TO COVER INFORMATION LIST ENTRY                          41500000
***************************************************************         41600000
         SPACE 1                                                        41700000
INFOLIST DSECT                                                          41800000
INFENTRY DS    H     RESERVED                                AD  A49808 41850021
INFTJID  DS    H     TJID FOR TSO TASKS(RESERVED IN MFT)     AD  A49808 41860021
INFTCB   DS    F                                                        41900000
INFBADDR DS    F                                                        42000000
INFRCL   DS    X     BITS 0-2 USED FOR REASON CODE(0=>NO RC)            42100000
*                    BITS 3-7 USED FOR COUNT OF VARIABLE DATA BYTES     42200000
INFFLG   DS    X     FLAG BYTE                                          42300000
INFFLG0  EQU   X'80' BIT 0 ON => BRANCH ENTRY                           42400000
INFCC    DS    H     COMPLETION CODE                                    42500000
INFVAR   DS    4F    VARIABLE INFORMATION                               42600000
         ORG   INFVAR                                                   42700000
INFVAR1  DS    F                                                        42800000
INFVAR2  DS    F                                                        42900000
INFVAR3  DS    F                                                        43000000
INFVAR4  DS    F                                                        43100000
INFEND   EQU   *                                                        43200000
INFLEN   EQU   (INFEND-INFENTRY)  LENGTH OF ENTRY            AD  A49808 43250021
         SPACE 2                                                        43400000
***************************************************************         43500000
*        DSECT TO COVER MESSAGE FORMAT                        *         43600000
***************************************************************         43700000
         SPACE 1                                                        43800000
MSGFORM  DSECT                                                          43900000
MSGPARM  DS    F                                                        44000000
MSG      DS    0X                                                       44100000
MSGID    DS    8C                                                       44200000
MSGCC    DS    3C                                                       44300000
MSGRC    DS    3C                                                       44400000
MSGJOB   DS    9C                                                       44500000
MSGSTEP  DS    9C                                                       44600000
MSGFLG   DS    3C                                                       44700000
MSGVAR   DS    35C                                                      44800000
         ORG   MSGVAR                                                   44900000
MSGVAR1  DS    8C                                                       45000000
         DS    C                                                        45100000
MSGVAR2  DS    8C                                                       45200000
         DS    C                                                        45300000
MSGVAR3  DS    8C                                                       45400000
         DS    C                                                        45500000
MSGVAR4  DS    8C                                                       45600000
         DS    C                                                        45700000
MSGEND   EQU   *                                                        45800000
MSGLEN   EQU   MSGEND-MSG                                               45900000
         SPACE 1                                                        46000000
FIXEDLNG EQU   (MSGVAR-1-MSG)                                           46100000
         EJECT                                                          46200000
         IHBABCTL                                                       46300000
         EJECT                                                          46320021
****                                                               **** 46340021
*        FLOWCHART STATEMENTS FOR ABEND 4                             * 46360021
****                                                               **** 46380021
         SPACE 1                                                        46384021
*/*IEAQTM04: CHART */                                                   46484021
*/*IEAQTM04: E ABEND4 */                                                46584021
*/*IGC0401C: P FLAG SVRB FOR ABEND4 */                                  46684021
*/*          D (NO,,YES,CLEANUP) TYPE 1 MESG WTO RECURSION */           46784021
*/*SCAN:     P SEARCH INFO LIST FOR AN ENTRY FOR CURRENT TCB */         46884021
*/*          D (YES,,NO,CLEANUP) ENTRY FOUND */                         46984021
*/*FORMAT:   D (NO,,YES,FORMAT1) WTP BUFFER GOTTEN YET */               47084021
*/*          S GETMAIN: GET STORAGE FOR WTP BUFFER */                   47184021
*/*          D (YES,FORMAT0,NO,CLEANUP) CORE AVAILABLE */               47284021
*/*FORMAT0:  $ */                                                       47384021
*/*FORMAT1:  P MOVE COMP CODE, DESCRIPT/ROUTER CODE, & ID INTO WTP BUFF 47484021
*/*ER */                                                                47584021
*/*FORMAT2:  P MOVE IN REASON CODE IF AVAILABLE */                      47684021
*/*FORMAT3:  P MOVE IN JOBNAME & BRANCH ENTRY ADDR IF AVAILABLE */      47784021
*/*FORMAT4:  P MOVE IN STEP NAME & FLAGS. TRANSLATE TO EBCDIC. */       47884021
*/*FORMAT5:  P MOVE IN VARIABLE DATA */                                 47984021
*/*FORMAT6:  P FINISH PARAMETERS & ISSUE WRITE TO PROGRAMMER */         48084021
*/*NEXT:     P (,SCAN) PREPARE TO SCAN LIST FOR ANOTER ELEMENT FOR THIS 48184021
*/* TCB */                                                              48284021
*/*CLEANUP:  P READY FOR TASK SELECT */                                 48384021
*/*NEXTTCB:  S (LAST,EXIT,SLTD,) SELECTR: SELECT A TASK OF THE ABENDING 48484021
*/* TREE */                                                             48584021
*/*PRGSCAN:  P PURGE ENTRIES FOR SELECT TCB IN INFO LIST */             48684021
*/*MSGFREE:  D (NO,NEXTTCB,YES,) ABEND4 SVRB ON SELECT TCB CHAIN */     48784021
*/*MSGFREE2  D (NO,NEXTTCB,YES,) WTP BUFFER EXIST FOR SVRB */           48884021
*/*          S (,NEXTTCB) FMBRANCH: FREE WTP BUFFER */                  48984021
*/*SELECTR:  E ENTRY TO TASK SELECT ROUTINE */                          49084021
*/*%NXTCB:   D (NO,SELECT1R,YES,) FIRST TIME ENTRY */                   49184021
*/*          P RESET FIRST TIME ENTRY INDICATOR */                      49204021
*/*          P SET UP TO RETURN INPUT TCB AS SELECTED TCB */            49284021
*/*SELECT3R: P SET UP RETURN PARAM WITH TCB ADDRESS JUST SELECTED */    49304021
*/*          D (YES,%NXTCB,NO,) SELECTED TASK COMPLETE */               49384021
*/*          R RETURN-MORE */                                           49484021
*/*SELECT1R: P SELECT DAUGHTER OF INPUT TCB */                          49684021
*/*SELECT2R: D (YES,SELECT3R,NO,) SELECTED TASK EXIST */                49784021
*/*          P SELECT SISTER TASK */                                    49884021
*/*          D (YES,%RETURN,NO,) SCAN OF TREE FINISHED */               49984021
*/*          P (,SELECT2R) GET MOTHER OF INPUT TCB AS NEW INPUT TCB */  50084021
*/*%RETURN:  R RETURN-NONE */                                           50184021
*/*EXIT:     D (YES,%RORI,NO,) SYSTEM CONTAIN ROLLOUT/ ROLLIN */        50284021
*/*          D (NO,SKIPDUMP,YES,) DUMP WANTED AND NOT PREVENTED */      50384021
*/*          P (,XCTL) PREPARE TO GO TO ABEND7 */                       50484021
*/*%RORI:    P (,XCTL) PREPARE TO GO TO ABEND5 */                       50584021
*/*SKIPDUMP: P (,XCTL) PREPARE TO GO TO ABEND11 */                      50684021
*/*XCTL:     P FLAG REGS 0 & 1 TO TRACE XCTL EASILY */                  50784021
*/*          R XCTL TO SPECIFIED MODULE */                              50884021
*/*IEAQTM04: END */                                                     50984021
         END                                                            51084021
