 TITLE ' IEAQTM05 / ABEND5 - ONE TIME FUNCTIONS - RORI / IGC0501C'      00100000
IGC0501C START                                                          00200000
*THE FOLLOWING ROUTINE IS THE FIFTH LOAD OF ABEND                       00300000
*                                                                       00400000
*STATUS CHANGE LEVEL=0                                                  00500000
*                                                                       00600000
*ROUTINE NAME - ABEND5                                                  00700000
*                                                                       00800000
*FUNCTIONS-                                                             00900000
*           ABEND PERFORMS THE FOLLOWING BASIC OPERATIONS:              01000000
*                                                                       01100000
*        1. IF ROLLOUT/ROLLIN PRESENT, PURGES THE FOLLOWING QUEUES      01200000
*           FOR THE ROLLOUT IQE FOR ALL TASKS IN THE ABENDING           01300000
*           TREE. THIS IS NECESSARY SINCE AN ABEND MAY HAVE             01400000
*           OCCURRED AT SOME POINT IN THE ROLLOUT PROCESS.              01500000
*                                                                       01600000
*          A. WHEN A REQUEST FOR ROLLOUT CANNOT BE SATISFIED, THE IQE   01700000
*       REPRESENTING THAT REQUEST MAY BE ADDED ON A FIFO BASIS TO A     01800000
*       QUEUE TO DEFER THE REQUEST UNTIL A LATER TIME WHEN THE REQUEST  01900000
*       MAY BE SATISFIED.  WHILE A TASK HAS AN IQE ON THE ROLLOUT QUEUE 02000000
*       (IEAROQUE), IT IS SET NON-DISPATCHABLE.  IT MAY BE ABNORMALLY   02100000
*       TERMINATED, HOWEVER, AND THE IQE MUST BE REMOVED FROM THE       02200000
*       ROLLOUT QUEUE SINCE THE TASK HAS NO MORE NEED FOR THE ROLLOUT   02300000
*       REQUEST.  THIS ABNORMAL TERMINATION MAY BE THE RESULT OF A      02400000
*       CANCEL OR TIMER EXPIRATION.                                     02500000
*                                                                       02600000
*           B. AT THE TIME OF ABNORMAL TERMINATION IT IS ALSO POSSIBLE  02700000
*       THAT AN IQE REPRESENTING A REQUEST FOR ROLLOUT MAY BE ON THE    02800000
*       IQE ASYNCHRONOUS EXIT QUEUE.  A IQE REPRESENTING THE            02900000
*       TERMINATING TASK MUST BE REMOVED.                               03000000
*                                                                       03100000
*          C. IT IS POSSIBLE THAT AN IQE MAY BE ON THE QUEUE OF IQE'S   03200000
*       ON THE ROLLOUT IRB. SUCH AND IQE FOR THE TERMINATING TASK MUST  03300000
*       BE REMOVED.                                                     03400000
*                                                                       03500000
*          D. AN IQE REPRESENTING A REQUEST FOR ROLLOUT MAY BE THE      03600000
*       CURRENT IQE ON THE ROLLOUT IRB. SIMPLY REMOVING THE IQE WILL    03700000
*       NOT HANDLE THE SITUATION ENTIRELY SINCE THE REQUEST IS          03800000
*       CURRENTLY BEING PROCESSED. ABEND SETS A FLAG IN THE PARAMETER   03900000
*       LIST TO INDICATE TO ROLLOUT THAT THE ROLLOUT PROCESSING MUST    04000000
*       CEASE.                                                          04100000
*                                                                       04200000
*           THE QUEUES DESCRIBED ABOVE ARE EXAMINED UNTIL AN IQE        04300000
*    REPRESENTING THE TERMINATING TASK IS FOUND OR THE QUEUES ARE       04400000
*    EXHAUSTED.                                                         04500000
*                                                                       04600000
*                                                                       04700000
*                                                                       04800000
*ENTRY POINT NAMES - IGC0501C                                           04900000
*                                                                       05000000
*CONTAINED IN MODULE - IEAQTM05                                         05100000
*                                                                       05200000
*ATTRIBUTES -                                                           05300000
*                                                                       05400000
*          1.  TYPE 4 SVC. SUPERVISOR STATE, REENTRANT.                 05500000
*                                                                       05600000
*APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                 05700000
*                                                                       05800000
*SVC USAGE -                                                            07500000
*             FREEMAIN-SP 251,252,255                                   07600000
*                                                                       07700000
*              XCTL - IGC0701C (DUMP WANTED), IGC0B01C (NO DUMP)        07800021
*                                                                       07900000
*INPUT - NONE                                                           08000000
*                                                                       08100000
*OUTPUT -                                                               08200000
*                                                                       08300000
*ENTRY POINTS -                                                         08400000
*                                                                       08500000
*          1.  THE PSW MUST BE                                          08600000
*                                                                       08700000
*             A. DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT            08800000
*                MACHINE CHECK.                                         08900000
*                                                                       09000000
*             B. UNDER SUPERVISOR PROTECTION PROTECTION KEY.            09100000
*                                                                       09200000
*             C. IN SUPERVISOR STATE.                                   09300000
*                                                                       09400000
*          2.  REGISTERS UPON INPUT.                                    09500000
*                                                                       09600000
*             A. REGISTER 2 CONTAINS THE ADDRESS OF THE SCVT            09700000
*                                                                       09800000
*             B. REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.            09900000
*                                                                       10000000
*             C. REGISTER 4 CONTAINS ADDRESS OF CURRENT TCB.            10100000
*                                                                       10200000
*             D. REGISTER 5 CONTAINS THE ADDRESS OF THE CURRENT RB.     10300000
*                                                                       10400000
*EXIT POINTS - XCTL TO:                                                 10500000
*        3. ABEND11 IF THE DUMP IS NOT REQUESTED OR MUST                10600000
*           BE BYPASSED.                                                10700000
*        2. ABEND7 (IGC0701C) IF DUMP IS REQUESTED AND                  10800000
*           AT THIS POINT CAN BE GIVEN.                                 10900000
*                                                                       11000000
*ERROR EXIT POINTS - NONE                                               11100000
*                                                                       14300000
*RESTRICTIONS ON USE OF ROUTINE - NONE                                  14400000
*                                                                       14500000
*NOTES -                                                                14600000
*                                                                       14700000
*        1. THIS MODULE IS NOT CHARACTER CODE DEPENDENT.                14800000
*                                                                       14900000
         EJECT                                                          15000000
*                                                                       15100000
* MISCELANEOUS EQUATES                                                  15200000
*                                                                       15300000
ABROLL   EQU   X'80'    ABEND FLAG IN IQE PARAMETER LIST           R00A 15400000
ROQCT    EQU   2        DISP. FOR QUEUED ROLLOUT COUNT             R00A 15500000
         EJECT                                                          15600000
PARREG0  EQU   0                   PARAMETER REGISTER ZERO              15700000
PARREG1  EQU   1                   PARAMETER REGISTER ONE         20472 15800000
RORIWKRG EQU   1                   ROLLOUT/ROLLIN PURGE WORKREG         15900000
LINKREG  EQU   2                   INTERNAL LINK REG                    16000000
CVTREG   EQU   3                   CONTAINS POINTER TO CVT              16100000
TCBREG   EQU   4                   CURRENT TCB REGISTER.                16200000
RBREG    EQU   5                   CURRENT RB REGISTER.                 16300000
IQEREG   EQU   6                   ADDRESS OF IQE                  R00A 16400000
PRVREG   EQU   7                   ADDRESS OF 'PREVIOUS' IQE       R00A 16500000
RBREG2   EQU   7                   ALTERNATE RB REG                     16600000
ATCBREG  EQU   8                   ALTERNATE TCB REGISTER               16700000
BASEREG  EQU   9                   BASE REGISTER FOR ABEND              16800000
WKREG1   EQU   10                  WORK REGISTER                   R00A 16900000
XCTLREG  EQU   10                  ADDR OF NAME OF NEXT MODULE          17000000
WKREG2   EQU   11                  WORK REGISTER                   R00A 17100000
SELREG   EQU   12                  TASK SELECT REG                      17200000
CTNREG   EQU   13                  CONTINUATION ADDRESS            R00A 17300000
RETREG   EQU   14                  RETURN REGISTER                      17400000
SCVTREG  EQU   15                  REG ON SCVTSECT- ABEND CVT           17500000
         EJECT                                                          17600000
IGC0501C CSECT                                                          17700000
ABEND5   BALR  BASEREG,0                ESTABLISH ADDRESSIBILITY        17800000
         USING *,BASEREG          9                                     17900000
         USING CVTSECT,CVTREG     3     SET ADDRESSIBILITY FOR CVT DSEC 18000000
         USING TCBSECT,TCBREG     4     SET ADDRESSIBILITY FOR CURR TCB 18100000
         USING TCBDSECT,ATCBREG   8     ALTERNATE TCBREG                18200000
         USING RBSECT,RBREG       5     CURRENT RB(SVRB)                18300000
         USING SCVTSECT,SCVTREG   F                                     18400000
*                                                                       18500000
         MVI   RBEXSAVE+45,C'5'                                   21472 18600000
         L     SCVTREG,CVTABEND         ADDRESS SECONDARY CVT     21472 18700000
         EJECT                                                          18800000
ROLLPRG  EQU   *                  RORI PURGE                       ROOA 18900000
         L     ATCBREG,TCBJSTCB         GET JOBSTEP TCB ADRESS   A33581 19000000
         L     RORIWKRG,SCVTRTCB        GET ADDR OF ROLLOUT TCB  A33581 19100000
         L     RORIWKRG,0(,RORIWKRG)    GET TOP RB ADDR          A33581 19200000
         LTR   RORIWKRG,RORIWKRG        IS ROLLOUT IN SYSTEM     A33581 19300000
         BZ    ENDROLL                  NO,BYPASS ROLLOUT PURGE  A34277 19400000
         TM    TCBFLGSP,TCBFA           IS THIS A STEP ABEND      M3876 19500000
         BO    ROLLPRGA                 YES, SEL TCB IS JOB STEP TCROOA 19600000
         LR    ATCBREG,TCBREG           NO, SEL TCB IS CURRENT TCB ROOA 19700000
ROLLPRGA LCR   ATCBREG,ATCBREG          INDICATE FIRST-TIME ENTRY  ROOA 19800000
ROLLPRGB BAL   LINKREG,SELECTR          LINK TO SELECT SUBROUTINE  ROOA 19900000
         B     ENDROLL                  BRANCH, PURGE COMPLETE   A34277 20000000
*        FALL THROUGH IF TASK SELECTED                                  20100000
ROLLPRGC EQU   *                                                   ROOA 20200000
         L     PRVREG,SCVTROQ           PROVIDE ROLLOUT QUEUE ADDREROOA 20300000
         LA    RETREG,ROLLPRG1          PROVIDE RETURN ADDRESS     ROOA 20400000
         BAL   CTNREG,ROLLPRG3          PROVIDE CONTINUATION ADDRESROOA 20500000
         L     PRVREG,CVTIERLC          GET ADDRESS OF RQE-AEQ     ROOA 20600000
         LA    PRVREG,6(,PRVREG)        PROVIDE IQE-AEQ ADDRESS    ROOA 20700000
         LA    RETREG,ROLLPRG2          PROVIDE RETURN ADDRESS     ROOA 20800000
         BAL   CTNREG,ROLLPRG3          PROVIDE CONTINUATION ADDRESROOA 20900000
         L     PRVREG,SCVTRIRB          GET ADDRESS OF ROLLOUT IRB ROOA 21000000
*                                                                       21100000
*        XXXXXXXXXX                                                     21200000
         USING RBSECT,PRVREG                                       ROOA 21300000
*        XXXXXXXXXX                                                     21400000
*                                                                       21500000
         L     IQEREG,RBIQE-1      POINT TO FIRST IQE          @PD66075 21600021
         LA    IQEREG,0(,IQEREG)   CLEAR HI-ORDER              @PD66075 21620021
         ST    IQEREG,RBEXSAVE     SAVE ADDRESS OF FIRST       @PD66075 21640021
         LA    PRVREG,RBEXSAVE     USE LIST WITH HI-ORDER = 0  @PD66075 21660021
         LA    CTNREG,ROLLPRGB          PROVIDE CONTINUATION ADDRESROOA 21700000
         BAL   RETREG,ROLLPRG3          PROVIDE RETURN ADDRESS     ROOA 21800000
         L     WKREG1,SCVTRIRB          GET ADDRESS OF ROLLOUT IRB ROOA 21900000
*                                                                       22000000
*        XXXXXXXXXX                                                     22100000
         USING RBSECT,WKREG1                                       ROOA 22200000
*        XXXXXXXXXX                                                     22300000
*                                                                       22400000
         L     WKREG1,RBIQE-1           GET ADDRESS OF CURRENT IQE ROOA 22500000
         LA    WKREG1,0(,WKREG1)   CLEAR HI ORDER              @PD66075 22550021
         CR    IQEREG,WKREG1            IS 'FOUND' IQE THE CURRENT ROOA 22600000
         BNE   ROLLPRG2                 NO, GO REMOVE THE 'FOUND' IROOA 22700000
         OI    0(RORIWKRG),ABROLL  SET ABEND FLG IN IQE PARM LST A33581 22800000
         B     ROLLPRGB                 GO GET NEXT TASK IN FAMILY ROOA 22900000
         EJECT                                                          23000000
ROLLPRG1 L     WKREG1,SCVTROCT          GET ADDRESS OF ROLLOUT COUNROOA 23100000
         LH    WKREG2,ROQCT(,WKREG1)    GET COUNT OF QUEUED REQUESTROOA 23200000
         BCTR  WKREG2,0                 DECREMENT QUEUED COUNT BY 1ROOA 23300000
         STH   WKREG2,ROQCT(,WKREG1)    STORE UPDATED QUEUED COUNT ROOA 23400000
ROLLPRG2 MVC   IQELINK(4,PRVREG),IQELINK(IQEREG)  REMOVE IQE FROM QROOA 23500000
         L     WKREG1,SCVTRIRB          GET ADDRESS OF ROLLOUT IRB ROOA 23600000
         L     WKREG2,RBNEXAV           GET NEXT AVAILABLE         ROOA 23700000
         ST    WKREG2,IQELINK(,IQEREG)  LINK THIS IQE TO NEXT-AVAILROOA 23800000
         ST    IQEREG,RBNEXAV           MAKE THIS IQE NEXT-AVAILABLROOA 23900000
         B     ROLLPRGB                 GO GET NEXT TASK IN FAMILY ROOA 24000000
         SPACE 5                                                        24100000
*                                                                       24200000
* GENERAL IQE QUEUE SEARCH SUBROUTINE.                                  24300000
*                                                                       24400000
ROLLPRG3 L     IQEREG,0(PRVREG)         GET FIRST IQE ON QUEUE     ROOA 24500000
ROLLPRG4 EQU   *                                                        24600000
         LTR   IQEREG,IQEREG           IS THIS END IQE CHAIN       671A 24700000
         BCR   4,CTNREG                YES,CONTINUE TO NEXT TASK   671A 24800000
         LA    IQEREG,0(,IQEREG)       CLEAR HI BYTE               671A 24900000
         LTR   IQEREG,IQEREG           IS ADDR ZERO                671A 25000000
         BCR   8,CTNREG       YES,CONTINUE TO NEXT TEST/TASK       ROOA 25100000
         CLC   IQETCB(4,IQEREG),SCVTRTCB IS IQE ROLLOUT-RELATED?   ROOA 25200000
         BNE   ROLLPRG5                 NO, IGNORE                 ROOA 25300000
         L     RORIWKRG,IQEPARAM(,IQEREG) GET IQE PARM ADDR      A33581 25400000
         LTR   RORIWKRG,RORIWKRG        IS REQUEST FOR ROLLOUT   A33581 25500000
         BC    13,ROLLPRG5              NO, IGNORE                 ROOA 25600000
         C     ATCBREG,0(,RORIWKRG)     REQUEST FOR ENDING TASK? A33581 25700000
         BCR   8,RETREG                 YES, PROCESS ACCORDING TO QROOA 25800000
ROLLPRG5 LR    PRVREG,IQEREG            UPDATE 'PREVIOUS' IQE ADDREROOA 25900000
         L     IQEREG,IQELINK(,IQEREG)  GET NEXT IQE ADDRESS       ROOA 26000000
         B     ROLLPRG4                 GO TEST NEXT IQE ADDRESS   ROOA 26100000
*                                                                       26200000
*        XXXXXXXXXX                                                     26300000
         DROP  PRVREG                                                   26400000
         DROP  WKREG1                                                   26500000
         USING RBSECT2,RBREG2           ALTERNATE RB DSECT              26600000
*        XXXXXXXXXX                                                     26700000
         EJECT                                                          26800000
*                                                                       26900000
* TASK SELECTION SUBROUTINE.                                            27000000
*                                                                       27100000
SELECTR  EQU   *                                                        27200000
         LTR   SELREG,ATCBREG          IS THIS FIRST-TIME ENTRY         27300021
         BC    10,SELECT1R             NO,BRANCH TO START SELECTION     27400000
         LCR   SELREG,SELREG           YES, RECOMPLEMENT TCB ADDRESS    27500021
SELECT3R LR    ATCBREG,SELREG          PASS BACK SELECTED TCB ADDRESS   27600000
         TM    TCBFLGSP+4,TCBFC        Q. IS TASK COMPLETE?      A43837 27620021
         BO    SELECTR                 YES. SELECT NEXT TASK     A43837 27640021
         B     4(,LINKREG)             RETURN TO MAIN ROUTINE           27700000
SELECT1R L     SELREG,TCBLTCP          GET DAUGHTER OF INPUT TASK       27800000
SELECT2R LTR   SELREG,SELREG           DOES A DAUGHTER EXIST            27900000
         BC    7,SELECT3R              YES,SELECTION HAS BEEN MADE      28000000
         L     SELREG,TCBNTCP          NO, GET SISTER                   28100021
         TM    TCBFLGSP,TCBFT          Q.IS SCAN OF TREE FINISHED 20472 28200000
         BCR   1,LINKREG               YES, RETURN TO MAINLINE   A41373 28300021
         L     ATCBREG,TCBOTCP         NO, GET MOTHER                   28400021
         B     SELECT2R                BRANCH TO TEST                   28500000
*                                                                       28600000
*     END  OF   ROLLOUT PURGE                                           28700000
*                                                                       28800000
*****************************************************************       28900000
ENDROLL  EQU   *                                                        29000000
         EJECT                                                          29100000
**********************************************************************  29200000
         L     ATCBREG,TCBJSTCB        GET JSTCB ADDR AND CHECK   21472 29220021
         TM    TCBFLGSP,TCBPDUMP        IF DUMP IS ALLOWED.       21472 29240021
         BO    GOTOB                   IF NOT, SKIP DUMP PROCESS  21472 29260021
         TM    TCBCMP,DUMPMASK         Q. IS DUMP REQUESTED?      21472 29300000
         BO    GOTO7                   YES. PREPARE FOR DUMP      21472 29400000
*                                      NO. SKIP DUMP PROCESSING   21472 29500000
GOTOB    EQU   *                                                  21472 29600000
         LA    XCTLREG,NMLOADB         GET NAME OF LOAD 11        21472 29700000
         B     XCTL                                               19070 29800000
GOTO7    LA    XCTLREG,NMLOAD7         GET NAME OF LOAD 7         21472 29900000
XCTL     LA    15,RBEXSAVE                                        19070 30000000
         L     PARREG0,THISMOD         FLAG XCTL FOR TRACE        20472 30100000
         L     PARREG1,4(,XCTLREG)     SHOW NEXT MODULE IN TRACE  20472 30200000
         XCTL  EPLOC=(XCTLREG),SF=(E,(15))                              30300000
         EJECT                                                          30400000
*                                                                       30500000
*      CONSTANTS                                                        30600000
         DS    0F                                                       30700000
NMLOAD7  DC    CL8'IGC0701C'                                      21472 30800000
NMLOADB  DC    CL8'IGC0B01C'                                      21472 30900000
THISMOD  DC    C'501C'                  INDICATOR FOR XCTL TRACE  21472 31000000
         EJECT                                                          31100000
*********************************************************************** 31200000
*******************   ZAP SPACE FOR MAINTENANCE   ********************* 31300000
*********************************************************************** 31400000
*                                                                       31500000
         DC    H'0'                                                     31600000
         DC    H'0'                                                     31700000
         DC    H'0'                                                     31800000
         DC    H'0'                                                     31900000
         DC    H'0'                                                     32000000
         DC    H'0'                                                     32100000
         DC    H'0'                                                     32200000
         DC    H'0'                                                     32300000
         DC    H'0'                                                     32400000
         DC    H'0'                                                     32500000
         DC    H'0'                                                     32600000
         DC    H'0'                                                     32700000
         DC    H'0'                                                     32800000
         DC    H'0'                                                     32900000
         DC    H'0'                                                     33000000
         DC    H'0'                                                     33100000
         DC    H'0'                                                     33200000
         DC    H'0'                                                     33300000
         DC    H'0'                                                     33400000
         DC    H'0'                                                     33500000
         DC    H'0'                                                     33600000
         DC    H'0'                                                     33700000
         DC    H'0'                                                     33800000
         DC    H'0'                                                     33900000
         DC    H'0'                                                     34000000
         DC    H'0'                                                     34100000
         DC    H'0'                                                     34200000
         DC    H'0'                                                     34300000
         DC    H'0'                                                     34400000
         DC    H'0'                                                     34500000
         DC    H'0'                                                     34600000
         DC    H'0'                                                     34700000
         EJECT                                                          34800000
         IHBABCTL                                                       34900000
DCBDDNM  EQU   40                OFFSET TO DDNAME IN DCB                35000000
*/*IEAQTM05: CHART */                                                   35200021
*/*IEAQTM05: E ABEND5 */                                                35300021
*/*IGC0501C: P FLAG SVRB FOR ABEND5 */                                  35400021
*/*ROLLPRG:  D (YES,,NO,ENDROLL) IS ROLLOUT IN THE SYSTEM */            35800021
*/*          P READY FOR TASK SELECT */                                 36000021
*/*ROLLPRGA: P INDICATE FIRST ENTRY */                                  36100021
*/*ROLLPRGB: S (SLTD,,LAST,ENDROLL) SELECTR: SELECT A TASK FROM         36200021
*/*ABENDING TREE */                                                     36220021
*/*ROLLPRGC: P GET ROLLOUT QUEUE ADDR & SET RETURN ADDR=ROLLPRG1 */     36300021
*/*          S (NOTF,,FOUN,ROLLPRG1) ROLLPRG3: FIND IQE FOR SELECT TASK 36400021
*/*ON ROLLOUT Q */                                                      36420021
*/*          P GET IQE-AEQ ADDR & SET RETURN ADDR=ROLLPRG2 */           36500021
*/*          S (NOTF,,FOUN,ROLLPRG2) ROLLPRG3: FIND IQE FOR SELECT TASK 36600021
*/*ON AEQ */                                                            36620021
*/*          P GET RB IQE-QUEUE FROM IRB FOR ROLL & SET RET=ROLLPRGB */ 36700021
*/*          S (FOUN,,NOTF,ROLLPRGB) ROLLPRG3: FIND IQE FOR SELECT TASK 36800021
*/* ON ROLLOUT IRB Q */                                                 36820021
*/*          P GET CURR IQE FROM IRB */                                 36900021
*/*          D (Y,,N,ROLLPRG2) IS FOUND IQE CURRENT */                  37000021
*/*          P (,ROLLPRGB) SET ABEND FLAG IN IQE PARAMLIST */           37100021
*/*ROLLPRG1: P DECREMENT ROLLOUT'S QUEUE COUNT */                       37200021
*/*ROLLPRG2: P (,ROLLPRGB) REMOVE IQE FROM QUEUE  */                    37300021
*/*ROLLPRG3: E ENTRY TO GENERAL IQE SEARCH ROUTINE */                   37400021
*/*          P GET FIRST IQE ON QUEUE */                                37500021
*/*ROLLPRG4: D (N,,Y,%BCTNREG) IS THIS THE END OF IQE CHAIN */          37600021
*/*          D (N,,Y,%BCTNREG) IS IQE ADDR ZERO */                      37700021
*/*          D (Y,,N,ROLLPRG5) IS IQE FOR ROLLOUT TCB */                37800021
*/*          P GET IQE PARAM ADDR */                                    37900021
*/*          D (Y,,N,ROLLPRG5) IS REQUEST FOR ROLLOUT */                38000021
*/*          D (N,,Y,%BRETREG) IS REQUEST FOR ENDING TASK */            38100021
*/*ROLLPRG5: P (,ROLLPRG4) GET NEXT IQE ADDR */                         38200021
*/*%BCTNREG: R RETURN - NOT FOUND */                                    38220021
*/*%BRETREG: R RETURN - FOUND */                                        38240021
*/*ENDROLL:       D (NO,GOTOB,YES,GOTO7) DUMP REQUESTED & ALLOWED */    38260021
*/*GOTOB:         P (,XCTL) PREPARE TO XCTL TO ABEND11 */               38280021
*/*GOTO7:         P (,XCTL) PREPARE TO XCTL TO ABEND7 */                38284021
*/*XCTL:          P FLAG REGS 0 & 1 TO EASILY TRACE XCTL */             38288021
*/*               R XCTL TO SPECIFIED MODULE */                         38292021
*/*SELECTR:  E ENTRY TO TASK SELECT ROUTINE */                          38392021
*/*          D (NO,SELECT1R,YES,) FIRST TIME ENTRY */                   38396021
*/*          P SET UP TO RETURN INPUT TCB AS SELECTED TCB */            38396821
*/*          D (YES,SELECTR,NO,) SELECTED TASK COMPLETE */              38397621
*/*          R RETURN-MORE */                                           38398421
*/*SELECT3R: P SET UP RETURN PARAM WITH TCB ADDRESS JUST SELECTED */    38399221
*/*SELECT1R: P SELECT DAUGHTER OF INPUT TCB */                          38399321
*/*SELECT2R: D (YES,SELECT3R,NO,) SELECTED TASK EXIST */                38399421
*/*          P SELECT SISTER TASK */                                    38399521
*/*          D (YES,%RETURN,NO,) SKAN OF TREE FINISHED */               38399621
*/*          P (,SELECT2R) GET MOTHER OF INPUT TCB AS NEW INPUT TCB */  38399721
*/*%RETURN:  R RETURN-NONE */                                           38399821
*/*IEAQTM05: END */                                                     38400021
         END                                                            39500021
