  TITLE 'IEAQTM07 / ABEND7 - ABDUMP RELATED HOOKS - GRAPHICS, DIRECT SY*00100021
               SOUT / IGC0701C'                                         00200021
IGC0701C START                                                          00300021
*THE FOLLOWING ROUTINE IS THE SEVENTH LOAD OF ABEND                     00400021
*                                                                       00500021
*STATUS CHANGE LEVEL=0                                                  00600021
*                                                                       00700021
*ROUTINE NAME - ABEND7                                                  00800021
*                                                                       00900021
*FUNCTIONS-                                                             01000021
*           ABEND7 PERFORMS THE FOLLOWING BASIC OPERATIONS:             01100021
*                                                                       01200021
*      1.  IF THE ABENDING TASK IS A GRAPHICS FOREGROUND JOB OR    MTSB 01300021
*          THE GRAPHICS JOB PROCESSOR, THE GRAPHICS EXIT IS TAKEN. MTSB 01400021
*             ABEND DETERMINES WHETHER THERE IS ENOUGH CORE        MTSB 01500021
*          AVAILABLE FOR A DUMP.                                   MTSB 01600021
*             BRANCHES TO THE GRAPHICS DEBUG ROUTINE.  UPON RETURN MTSB 01700021
*          FROM THE DEBUG ROUTINE, A DUMP IS EITHER REQUESTED OR   MTSB 01800021
*          CANCELLED, ACCORDING TO THE USERS SPECIFICATIONS FROM   MTSB 01900021
*          THE DEBUG ROUTINE.                                      MTSB 02000021
*                                                                       02100021
*        2. IF DUMP HAS BEEN REQUESTED, A TEST IS                       02200021
*           MADE TO DETERMINE WHETHER THE DUMP DATA SET                 02300021
*           IS ALLOCATED TO A TAPE DEVICE TO WHICH A DIRECT             02400021
*           SYSOUT WRITER HAS BEEN STARTED. IF SO:                      02500021
*           A) FOR A SUBTASK, THE DUMP WOULD BE BYPASSED TO             02600021
*              PREVENT LATER ATTEMPTED USE OF THE TAPE                  02700021
*              DEVICE CAUSING ANOTHER ABEND.                            02800021
*           B) FOR A JOB STEP, THE SYSOUT DATA SET WOULD BE CLOSED,     02900021
*              IF ALREADY OPEN SO THAT IT CAN BE USED FOR THE DUMP.     03000021
*                                                                       03100021
*                                                                       03200021
*ENTRY POINT NAMES - IGC0701C                                           03300021
*                                                                       03400021
*CONTAINED IN MODULE - IEAQTM07                                         03500021
*                                                                       03600021
*ATTRIBUTES -                                                           03700021
*                                                                       03800021
*          1.  TYPE 4 SVC. SUPERVISOR STATE, REENTRANT.                 03900021
*                                                                       04000021
*APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                 04100021
*                                                                       04200021
*SVC USAGE -                                                            05900021
*             FREEMAIN - SP 251, 252, 255                               06000021
*             CLOSE - DIRECT SYSOUT DATA SET                            06100021
*             XCTL -  IGC0801C, IGC0B01C                                06200021
*                                                                       06300021
*INPUT - NONE                                                           06400021
*                                                                       06500021
*OUTPUT -                                                               06600021
*                                                                       06700021
*ENTRY POINTS -                                                         06800021
*                                                                       06900021
*          1.  THE PSW MUST BE                                          07000021
*                                                                       07100021
*             A. DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT            07200021
*                MACHINE CHECK.                                         07300021
*                                                                       07400021
*             B. UNDER SUPERVISOR PROTECTION PROTECTION KEY.            07500021
*                                                                       07600021
*             C. IN SUPERVISOR STATE.                                   07700021
*                                                                       07800021
*          2.  REGISTERS UPON INPUT.                                    07900021
*                                                                       08000021
*             A. REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.            08100021
*                                                                       08200021
*             B. REGISTER 4 CONTAINS ADDRESS OF CURRENT TCB.            08300021
*                                                                       08400021
*             C. REGISTER 5 CONTAINS THE ADDRESS OF THE CURRENT RB.     08500021
*                                                                       08600021
*EXIT POINTS - XCTL TO:                                                 08700021
*                                                                       08800021
*        1. ABEND11 (IGC0B01C) IF THE DUMP IS NOT REQUESTED             08900021
*           OR MUST BE BYPASSED.                                        09000021
*                                                                       09100021
*        2. ABEND8 (IGC0801C) IF DUMP IS REQUESTED AND                  09200021
*           AT THIS POINT CAN BE GIVEN.                                 09300021
*                                                                       09400021
*ERROR EXIT POINTS - NONE                                               09500021
*                                                                       12700021
*RESTRICTIONS ON USE OF ROUTINE - NONE                                  12800021
*                                                                       12900021
*NOTES -                                                                13000021
*                                                                       13100021
*                                                                       13200021
*        1. THIS MODULE IS NOT CHARACTER CODE DEPENDENT.                13300021
*                                                                       13400021
         EJECT                                                          13500021
*                MISCELANEOUS EQUATES                                   13600021
*                                                                       13700021
TIOTUCB  EQU   16                                                       13800021
DEVTYPE  EQU   18                                                       13900021
TAPE     EQU   X'80'                                                    14000021
DSPSYBIT EQU   12                                                       14100021
SWTR     EQU   X'40'                                                    14200021
DEBUCB   EQU   32                                                       14300021
TCBGRPH  EQU   X'20'              FOREGROUND JOB OR GJP                 14400021
RMSCODE  EQU   X'01'              TO TEST IF RMS IS THE CALLER          14500021
GFXABND  EQU   4                  OFFSET OF ABEND EP IN GFX             14600021
NODUMP   EQU   0                  DUMP NOT ALLOWED FOR THIS ABEND       14700021
DUMP     EQU   1                  GFX USER REQUESTS A DUMP              14800021
DUMPBIT  EQU   31                 SHIFT SIZE FOR DUMP BIT IN REG 1      14900021
TCBFE    EQU   X'40'              NORMAL END                            15000021
         SPACE 5                                                        15100021
*                BCR EQUATES                                            15200021
*                                                                       15300021
ON       EQU   1                                                        15400021
Z        EQU   8                                                        15500021
         EJECT                                                          15600021
*                REGISTER EQUATES                                       15700021
*                                                                       15800021
PARREG0  EQU   0                   PARAMETER REGISTER ZERO              15900021
PARREG1  EQU   1                   PARAMETER REGISTER ONE         20472 16000021
LINKREG  EQU   2                   INTERNAL LINK REG                    16100021
CVTREG   EQU   3                   CONTAINS POINTER TO CVT              16200021
TCBREG   EQU   4                   CURRENT TCB REGISTER.                16300021
RBREG    EQU   5                   CURRENT RB REGISTER.                 16400021
ENTRYREG EQU   6                   ENTRY TO RES GRAPHICS ROUTINE  21472 16500021
WKREG    EQU   6                   WORK REGISTER                        16600021
RBREG2   EQU   7                   ALTERNATE RB REG                     16700021
UCBREG   EQU   7                                                        16800021
ATCBREG  EQU   8                   ALTERNATE TCB REGISTER               16900021
BASEREG  EQU   9                   BASE REGISTER FOR ABEND              17000021
XCTLREG  EQU   10                  ADDR OF NEXT MODULE NAME       21472 17100021
SAVEREG  EQU   10                                                       17200021
DEBREG   EQU   10                  DEBREG.FOR ACCESS DEB.               17300021
PREVDEB  EQU   11                  PREVIOUS DEB ADDRESS           M3876 17400021
SELREG   EQU   12                  TASK SELECT REG                      17500021
TIOTREG  EQU   12                  REGISTER USED IN ACCESS TIOT         17600021
LNGTREG  EQU   13                  LENGTH OF TIOTREG                    17700021
RETREG   EQU   14                  RETURN REGISTER                      17800021
WTREG    EQU   14                  TEMP WORK REGISTER             21472 17900021
RTNREG   EQU   15                  RETURN REGISTER                      18000021
SCVTREG  EQU   15                  REG ON SCVTSECT- ABEND CVT           18100021
MPREG    EQU   15                  MUST BE REGISTER 15                  18200021
         EJECT                                                          18300021
IGC0701C CSECT                                                          18400021
ABEND7   BALR  BASEREG,0                ESTABLISH ADDRESSIBILITY        18500021
         USING *,BASEREG          9                                     18600021
         USING CVTSECT,CVTREG     3     SET ADDRESSIBILITY FOR CVT DSEC 18700021
         USING TCBSECT,TCBREG     4     SET ADDRESSIBILITY FOR CURR TCB 18800021
         USING TCBDSECT,ATCBREG   8     ALTERNATE TCBREG                18900021
         USING RBSECT,RBREG       5     CURRENT RB(SVRB)                19000021
         USING SCVTSECT,SCVTREG   F                                     19100021
         USING DEBSECT,DEBREG     A                                     19200021
*                                                                       19300021
         MVI   RBEXSAVE+45,C'7'         DEBUGGING AID             21472 19400021
         L     SCVTREG,CVTABEND         ADDRESS SECONDARY CVT     21472 19500021
         CLI   TCBRECDE,TCBGREC        Q. GRAPHICS RECURSION?     21472 19600021
         BO    GRAPHREC                YES, SKIP GRAPHICS         21472 19700021
         EJECT                                                          19800021
*********************************************************************   19900021
*        GRAPHICS HOOK                                                  20000021
*********************************************************************   20100021
*                                                                       20200021
ABGR00   EQU   *                                                   MTSB 20300021
         L     ATCBREG,TCBJSTCB        ESTABLISH JOB STEP TCB      MTSB 20400021
         TM    TCBTRNP,TCBGRPH         Q. FOREGROUND JOB OR GJP  A29408 20500021
         BZ    ENDGRPH                 NO, BYPASS GRAPHICS ROUTINE MTSB 20600021
         TM    TCBNSTAE,RMSCODE        WAS STG RECONF THE CALLER     2K 20700021
         BO    ENDGRPH                 YES, BYPASS GRAPHICS      A29408 20800021
         LR    ATCBREG,TCBREG          SET UP INPUT REG            MTSB 20900021
*                                                                       21000021
* IN RELEASE 21, THE CODE TO SET QUALIFIED SUBTASKS NONDISPATCH-  21472 21100021
* ABLE WAS ELIMINATED BECAUSE ALL SUCH TASKS HAVE ALREADY BEEN    21472 21200021
* SET NONDISPATCHABLE BY ABEND IN EARLIER PROCESSING. BEFORE REL  21472 21300021
* 21, THE CODE WAS NEEDED BECAUSE PLACEMENT OF THE GRAPHICS       21472 21400021
* HOOK BEFORE INITIAL ABEND HOUSEKEEPING ALLOWED THOSE TASKS      21472 21500021
* TO BE DISPATCHABLE AT THE TIME OF THE GRAPHICS EXIT.            21472 21600021
*                                                                       21700021
         LR    RTNREG,BASEREG          INDICATE NO DUMP           21472 21800021
         TM    TCBCMP,DUMPMASK         Q. IS DUMP ALLOWED?        M3879 21900021
         BZ    CHKNODMP                NO. SHOW 'NO DUMP'         M3879 22000021
*                                                                       22100021
* EVEN THOUGH A DUMP IS ALLOWED TO THE GRAPHICS USER BY THE       M3879 22200021
* SYSTEM, THERE MAY NOT BE ENOUGH CORE AVAILABLE IN SUBPOOL 252   M3879 22300021
* FOR ABDUMP'S RESIDENT LOAD (IGC0A05A).  ABEND NOW MAKES A CHECK M3879 22400021
* FOR SPACE AVAILABLE FOR IGC0505A.  IF CORE IS NOT AVAILABLE,THE M3879 22500021
* USER WILL NOT GET THE OPTION OF SPECIFYING THAT HE WANTS A      M3879 22600021
* DUMP.                                                           M3879 22700021
*                                                                       22800021
         MVC   RBEXSAVE(10),GETLIST    MOVE GETMAIN PARAM TO ESA   MTSB 22900021
         LA    WTREG,RBEXSAVE+12       ESTAB POINTER TO ESA        MTSB 23000021
         LA    PARREG1,RBEXSAVE        LOAD ADDR OF PARA LIST      MTSB 23100021
         GETMAIN A=(WKREG),MF=(E,(1))   CHECK FOR AVAIL CORE.     21472 23200021
CHKNODMP EQU   *                                                  M3879 23300021
         LA    ENTRYREG,NODUMP         SET PARAM FOR NO DUMP      M2156 23400021
         LTR   RTNREG,RTNREG           TEST GETMAIN RETURN CODE    MTSB 23500021
         BNZ   ABGR08                  NO CORE, NO DUMP           21472 23600021
         SPACE 2                                                        23700021
* REGISTER 1 CONTAINS THE ADDRESS OF THE PARAMETER LIST POINTER         23800021
* AT THIS TIME. IF GETMAIN EVER CHANGES TO DESTROY THE INPUT            23900021
* VALUE IN REGISTER 1, THE FOLLOWING INSTRUCTION WILL HAVE TO           24000021
* BE INSERTED HERE.                                                     24100021
         SPACE 1                                                        24200021
*        LA    PARREG1,RBEXSAVE         LOAD ADDR OF PARAM LIST         24300021
         SPACE 2                                                        24400021
         FREEMAIN MF=(E,(1))            MAKE CORE AVAILABLE       21472 24500021
         LA    ENTRYREG,DUMP           SET PARAM REG FOR DUMP     M2156 24600021
         EJECT                                                          24700021
*                                                                       24800021
*     INTERFACE WITH GRAPHICS DEBUG ROUTINE                        MTSB 24900021
*                                                                       25000021
* INPUT REGISTERS TO THE GRAPHICS ABEND EXIT ROUTINE               MTSB 25100021
*                                                                       25200021
*        REGISTER 5 = RETURN REGISTER                              MTSB 25300021
*        REGISTER 12 = TCB ADDRESS                                 MTSB 25400021
*        REGISTER 1 = DUMP OPTION INDICATOR                       M2156 25500021
*        REGISTER 15= ENTRY POINT OF GRAPHICS EXIT ROUTINE         MTSB 25600021
*                                                                       25700021
*        ALL REGISTERS WITH THE EXCEPTION OF THE INPUT REGISTERS   MTSB 25800021
*        MUST REMAIN TRANSPARENT ACROSS THE GRAPHICS ROUTINE.      MTSB 25900021
*                                                                       26000021
* RETURN REGISTERS FROM THE GRAPHICS ABEND EXIT                    MTSB 26100021
*                                                                       26120021
*        REG 1 = 0 - NO DUMP WANTED                                     26140021
*                1 - DUMP WANTED                                        26160021
*                                                                       26200021
*                                                                       26300021
ABGR08   EQU   *                                                   MTSB 26400021
         MVI   TCBRECDE,TCBREC+TCBGREC TURN ON RECURSION CONFIG   21472 26500021
         LR    PARREG1,ENTRYREG        PASS DUMP OPTION           M2516 26600021
         L     RTNREG,CVTQOCR          ADDR OF GFX PARA LIST       MTSB 26700021
         L     RTNREG,GFXABND(,RTNREG) ABEND ENTRYPOINT IN GFX     MTSB 26800021
         BALR  RBREG,RTNREG            BRANCH TO GFX               MTSB 26900021
*                                                                       27000021
* THE GRAPHICS INTERFACE ROUTINE IS RESPONSIBLE FOR INSURING THAT M3879 27100021
* IF THE DUMP OPTION INDICATOR IS OFF WHEN ABEND RELEASES CONTROL M3879 27200021
* IT IS OFF WHEN ABEND RECEIVES CONTROL BACK FROM GRAPHICS.       M3879 27300021
*                                                                       27400021
         OI    TCBCMP,DUMPMASK         TURN ON DUMP BIT INITIALLY 20472 27500021
         SLL   PARREG1,DUMPBIT         ISOLATE DUMP BIT            MTSB 27600021
         LTR   PARREG1,PARREG1         DOES USER WISH TO DUMP      MTSB 27700021
         BM    ABGR12                  YES, CONTINUE THE ABEND    20472 27800021
         NI    TCBCMP,255-DUMPMASK     TURN OFF DUMP BIT           MTSB 27900021
ABGR12   EQU   *                                                   MTSB 28000021
         L     RBREG,TCBRBP            RESTORE RB ADDRESS          MTSB 28100021
GRAPHREC EQU   *                                                        28200021
         MVI   TCBRECDE,X'00'          TURN OFF RECURSION CONFIG  21472 28300021
         B     ENDGRPH                 CONTINUE PROCESSING        21472 28400021
         SPACE 5                                                        32500021
GETLIST  GETMAIN EC,LV=1694,MF=L       GETMAIN PARAMETER LIST     20472 32600021
*                                                                       32700021
*        END OF GRAPHICS HOOK                                           32800021
*                                                                       32900021
*****************************************************************       33000021
ENDGRPH  EQU   *                                                  21472 33100021
         EJECT                                                          33200021
*********************************************************************** 33300021
*                    DIRECT SYSOUT HOOK                              *  33400021
**********************************************************************  33500021
*                                                                       33600021
*   INPUT/OUTPUT REGISTERS -                                            33700021
*                            3 CVTREG   ADDR OF THE CVT                 33800021
*                            4 TCBREG   ADDR OF THE CURRENT TCB         33900021
*                            5 RBREG    ADDR OF ABEND'S SVRB            34000021
*                            9 BASEREG  BASE OF THIS MODULE             34100021
*                                                                       34200021
*   USES REGISTERS -                                                    34300021
*                     1 PARREG1                                         34400021
*                     2 LINKREG                                         34500021
*                     6 WKREG                                           34600021
*                     7 UCBREG                                          34700021
*                     8 ATCBREG                                         34800021
*                    10 SAVEREG,DEBREG                                  34900021
*                    11 PREVDEB                                         35000021
*                    12 TIOTREG,SELREG                                  35100021
*                    13 LNGTREG                                         35200021
*                    14 RETREG (NOT ESSENTIAL - USED TO SAVE SPACE)     35300021
*                    15        (POSSIBLY CLOBBERED ACROSS CLOSE)        35400021
*                                                                       35500021
ABD03    EQU   *                                                        35600021
         L     ATCBREG,TCBJSTCB         GET ADDR OF JOB STEP TCB        35700021
         TM    TCBCMP,DUMPMASK          HAS A DUMP BEEN REQUESTED       35800021
         BZ    SKIPDUMP                 NO DUMP WANTED. GO TO 6.  20472 35900021
         LA    RETREG,GOTO8             READY TO TAKE DUMP        21472 36000021
ABD04    EQU    *                                                       36100021
         TM    TCBFLGSP+1,TCBFDSOP      WAS DATA SET PREV. OPENED       36200021
         BCR   ON,RETREG                YES. GO TO NEXT LOAD      21472 36300021
*CHECK FOR SYSABEND DD ENTRY IN THE TIOT                                36400021
         SR    WKREG,WKREG              SET SW FOR NO DD      AI  21472 36450000
         L     TIOTREG,TCBTIO           GET TIOT ADDRESS                36500021
         LA    TIOTREG,TIOTLNTH(,TIOTREG) POINT TO FIRST DD ENTRY       36600021
ABD05    CLI   0(TIOTREG),0             IS THIS LAST OR ONLY DD ENTRY   36700021
         BZ    CHKDD                    YES. CHECK IF DD FND  AI  21472 36800000
         CLC   TIOTDDNM(8,TIOTREG),SYSAB IS SYSABEND DD ENTRY PRESENT   36900021
         BE    DDFOUND                  YES. SAVE ENTRY ADDR  AI  21472 37000000
         CLC   TIOTDDNM(8,TIOTREG),SYSUDMP  IS THIS DD ENTRY SYSUDUMP   37100021
         BNE   LOOKMORE                 NO. KEEP LOOKING      AI  21472 37140000
DDFOUND  EQU   *                                              AI  21472 37180000
         LR    WKREG,TIOTREG            SAVE ABEND DD ADDRESS AI  21472 37220000
LOOKMORE EQU   *                                              AI  21472 37260000
         SR    LNGTREG,LNGTREG                                          37300021
         IC    LNGTREG,0(,TIOTREG)      GET LENGTH OF THIS DD ENTRY     37400021
         AR    TIOTREG,LNGTREG          POINT TO NEXT DD ENTRY          37500021
         BC    15,ABD05                 BR TO TRY NEXT DD ENTRY         37600021
CHKDD    EQU   *                                              AI  21472 37650000
         LTR   TIOTREG,WKREG            Q. WAS ABEND DD FOUND AI  21472 37700000
         BZ    SKIPDUMP                 NO. BYPASS DUMP       AI  21472 37750000
*                                                                 19070 37800021
*     THE FOLLOWING CODE CHECKS IF A DIRECT SYSOUT WRITER         19070 37900021
*    HAS BEEN STARTED TO A TAPE DEVICE THAT HAS BEEN ALLOCATED    19070 38000021
*    FOR THE DUMP.  IF SO, THE SYSOUT DATA SET IS CLOSED SO THAT  19070 38100021
*    IT MAY BE OPENED FOR THE DUMP.                               19070 38200021
*                                                                 19070 38300021
         L     UCBREG,TIOTUCB(,TIOTREG) GET UCB FOR DUMP DATA SET 21472 38400021
         LA    UCBREG,0(0,UCBREG)                                 19070 38500021
         LTR   UCBREG,UCBREG           Q. IS THIS DD DUMMY    AH A49243 38550000
         BZ    SKIPDUMP                YES. BYPASS DUMP       AH A49243 38560000
         TM    DEVTYPE(UCBREG),TAPE    IS THIS A TAPE DEVICE      19070 38600021
         BCR   Z,RETREG                NO. PROCEED NORMALLY       21472 38700021
         TM    DSPSYBIT(UCBREG),SWTR   IS A SYSOUT WRITER STARTED 19070 38800021
         BCR   Z,RETREG                NO. PROCEED NORMALLY       21472 38900021
         TM    TCBFLGSP,TCBFT          IS THIS JOB STEP TERMIN    19070 39000021
         BZ    SKIPDUMP                NO, DO NOT GIVE DUMP       21472 39100021
*                                                                 19070 39200021
         L     SAVEREG,TCBOTCP         GET INITIATOR TCB          19070 39300021
         LR    SELREG,SAVEREG          INITIALIZE SELREG          19070 39400021
TREESRCH BAL   LINKREG,SELECT          LOOK FOR TASK              19070 39500021
         B     FINDDEB                 TASK WAS SELECTED          19070 39600021
         BR    RETREG                  NO PROBLEMS. NEXT LOAD     21472 39700021
FINDDEB  L     DEBREG,TCBDEBP          GET DEB FROM TCB           19070 39800021
         LA    PREVDEB,TCBDEBP-4       USE AS DEB PTR FOR REQUE   M3876 39900021
NEXTDEB  LA    DEBREG,0(,DEBREG)       CLEAR HI BYTE              21472 40000021
         LTR   DEBREG,DEBREG           END OF CHAIN               19070 40100021
         BZ    TREESRCH                YES, TRY ANOTHER TASK      19070 40200021
         L     WKREG,DEBUCB(,DEBREG)   GET UCB ADDR FROM DEB      21472 40300021
         LA    WKREG,0(,WKREG)         CLEAR HI BYTE              21472 40400021
         CR    WKREG,UCBREG            IS THIS DEB FOR SYSOUT     19070 40500021
         BE    CLOSIT                  YES, CLOSE SYSOUT          19070 40600021
         LR    PREVDEB,DEBREG          SAVE PREV DEB ADDR FOR REQ M3876 40700021
         L     DEBREG,DEBLINK          GET NEXT DEB               19070 40800021
         B     NEXTDEB                 TRY AGAIN                  19070 40900021
CLOSIT   EQU   *                                                  M3876 41000021
         MVC   DEBLINK+1-DEBSECT(3,PREVDEB),DEBLINK+1 DEQ DEB     M4343 41100021
         IC    WKREG,DEBTCB            SAVE HI BYTE               19070 41200021
         ST    TCBREG,DEBTCB           ST CURRENT TCB ADR IN DEB  19070 41300021
         STC   WKREG,DEBTCB            STORE HI BYTE              19070 41400021
         MVC   DEBLINK+1(3),TCBDEB+1   PUT DEB ON                 M3876 41500021
         ST    DEBREG,TCBDEB           CURRENT TCB QUEUE.         M3876 41600021
         MVC   RBEXSAVE(4),DEBDCB      BUILD CLOSE PARM LIST      19070 41700021
         MVI   RBEXSAVE,ONEDCB         INDICATE ONE DCB           19070 41800021
         LA    PARREG1,RBEXSAVE        SET UP REG1 FOR CLOSE      19070 41900021
         MVI   TCBRECDE,TCBREC+TCBCLOSD INDICATE VALID RECURSION  20472 42000021
*                                                                       42100021
         CLOSE MF=(E,(1))              CLOSE SYSOUT               19070 42200021
         MVI   TCBRECDE,X'00'          TURN OFF RECURSION BITS    20472 42300021
         B     GOTO8                   REG 14 MAY BE BAD NOW IF   21472 42400021
*                                       SVC CLOSE RETURNED A      21472 42500021
*                                       PARAMETER IN IT.          21472 42600021
         EJECT                                                          42700021
**********************************************************************  42800021
*        TASK SELECT ROUTINE                                            42900021
**********************************************************************  43000021
SELECT   LR    ATCBREG,SELREG          SAVE GIVEN TCB ADDR              43100021
         L     SELREG,TCBLTCP          GET DAUGHTER                     43200021
SELECT1  LTR   SELREG,SELREG           DOES DAUGHTER EXIST              43300021
         BC    7,SELECT3               YES,BRANCH                       43400021
         L     SELREG,TCBNTCP          NO,GET SISTER                    43500021
         CR    ATCBREG,SAVEREG         IS SCAN COMPLETE                 43600021
         BE    4(,LINKREG)             YES. LAST TIME RETURN            43700021
         L     ATCBREG,TCBOTCP         NO,GET MOTHER                    43800021
         B     SELECT1                                                  43900021
SELECT3  LR    ATCBREG,SELREG          MODIFY ATCBREG                   44000021
         TM    TCBFLGSP+4,TCBFC        Q. TASK ALREADY COMPLETE  A43837 44020021
         BO    SELECT                  YES. SELECT NEXT TASK     A43837 44040021
         BCR   15,LINKREG              RETURN                           44100021
         SPACE 5                                                        44200021
**********************************************************************  44300021
PREVDUMP EQU   *                                                  20472 44400021
         OI    TCBFLGS,TCBPDUMP        NO DUMP FOR JOBSTEP        20472 44500021
SKIPDUMP EQU   *                                                  20472 44600021
         LA    XCTLREG,NMLOADB         GET NAME OF LOAD 11        21472 44700021
         B     XCTL                                               19070 44800021
GOTO8    LA    XCTLREG,NMLOAD8         GET NAME OF LOAD 8         21472 44900021
XCTL     LA    15,RBEXSAVE                                        19070 45000021
         L     PARREG0,THISMOD         FLAG XCTL FOR TRACE        20472 45100021
         L     PARREG1,4(,XCTLREG)     SHOW NEXT MODULE IN TRACE  20472 45200021
         XCTL  EPLOC=(XCTLREG),SF=(E,(15))                              45300021
         EJECT                                                          45400021
*                                                                       45500021
*      CONSTANTS                                                        45600021
*                                                                       45700021
         DS    0F                                                       45800021
SYSAB    DC    C'SYSABEND'              DDNAME REQUIRED FOR ABDUMP      45900021
SYSUDMP  DC    C'SYSUDUMP'              ALTERNATE DD FOR ABEND          46000021
NMLOAD8  DC    CL8'IGC0801C'                                      19070 46100021
NMLOADB  DC    CL8'IGC0B01C'                                      20472 46200021
THISMOD  DC    C'701C'                  INDICATOR FOR XCTL TRACE  20472 46300021
         EJECT                                                          46400021
*********************************************************************** 46500021
*******************   ZAP SPACE FOR MAINTENANCE   ********************* 46600021
*********************************************************************** 46700021
*                                                                       46800021
         DC    H'0'                                                     46900021
         DC    H'0'                                                     47000021
         DC    H'0'                                                     47100021
         DC    H'0'                                                     47200021
         DC    H'0'                                                     47300021
         DC    H'0'                                                     47400021
         DC    H'0'                                                     47500021
         DC    H'0'                                                     47600021
         DC    H'0'                                                     47700021
         DC    H'0'                                                     47800021
         DC    H'0'                                                     47900021
         DC    H'0'                                                     48000021
         DC    H'0'                                                     48100021
         DC    H'0'                                                     48200021
         DC    H'0'                                                     48300021
         DC    H'0'                                                     48400021
         DC    H'0'                                                     48500021
         DC    H'0'                                                     48600021
         DC    H'0'                                                     48700021
         DC    H'0'                                                     48800021
         DC    H'0'                                                     48900021
         DC    H'0'                                                     49000021
         DC    H'0'                                                     49100021
         DC    H'0'                                                     49200021
         DC    H'0'                                                     49300021
         DC    H'0'                                                     49400021
         DC    H'0'                                                     49500021
         DC    H'0'                                                     49600021
         DC    H'0'                                                     49700021
         DC    H'0'                                                     49800021
         DC    H'0'                                                     49900021
         DC    H'0'                                                     50000021
         EJECT                                                          50100021
         IHBABCTL                                                       50200021
DCBDDNM  EQU   40                OFFSET TO DDNAME IN DCB                50300021
         MPCVT                                                          50400021
         EJECT                                                          50420021
****                                                               **** 50440021
*        FLOWCHART STATEMENTS FOR ABEND 7                             * 50460021
****                                                               **** 50480021
         SPACE 1                                                        50484021
*/*IEAQTM07:      CHART */                                              50488021
*/*IEAQTM07:      E ABEND 7 */                                          50492021
*/*IGC0701C:      P ESTABLISH ADDRESSABILITY */                         50496021
*/*               P FLAG SVRB FOR ABEND 7 */                            50496821
*/*               D (NO,,YES,GRAPHREC) GRAPHICS RECURSION */            50497621
*/*ABGR00:        D (YES,,NO,ENDGRAPH) GJP OR FOREGND TSK */            50498421
*/*               D (NO,,YES,RMSCODE) TASK ABENDED BY STG RECONF */     50499221
*/*               P TURN ON 'NO DUMP' INDICATOR */                      50499321
*/*               D (YES,,NO,ABGR08) DUMP REQUESTED */                  50499421
*/*               S GETMAIN: CHECK FOR CORE FOR ABDUMP PROCESSING */    50499521
*/*CHKNODMP:      P TURN ON 'NO DUMP' INDICATOR */                      50499621
*/*               D (YES,,NO,ABGR08) CORE AVAILABLE */                  50499721
*/*               S FREEMAIN: FREE GOTTEN CORE */                       50499821
*/*               P TURN ON 'DUMP' INDICATOR */                         50499921
*/*ABGR08:        P SET GRAPHICS VALID RECURS FLG */                    50599921
*/*               S GRAPHICS: GRAPHICS ABEND EXIT RTN */                50619921
*/*               P TURN ON DUMP REQUESTED BIT IN TCBCMP */             50639921
*/*               D (NO,,YES,ABGR12) 'DUMP' IND SET */                  50659921
*/*               P TURN OFF DUMP REQUESTED BIT IN TCBCMP */            50679921
*/*ABGR12:        P RESTORE RB ADDRESSABILITY */                        50683921
*/*GRAPHREC:      P ZERO OUT ABEND VALID RECURS FLAGS */                50687921
*/*ENDGRPH:       D (YES,,NO,SKIPDUMP) DUMP REQUESTED */                50691921
*/*ABD04:         D (YES,,NO,%GETTIOT) DUMP DS OPEN */                  50695921
*/*GOTO8:         R ABEND 8 */                                          50696721
*/*%GETTIOT:      P GET FIRST DD ENTRY IN TIOT */                       50697521
*/*ABD05:         D (YES,,NO,SKIPDUMP) DD ENTRY EXIST */                50698321
*/*               D (NO,,YES,ABD09) SYSABEND OR SYSUDUMP ENTRY */       50699121
*/*               P (,ABD05) UPDATE TO NEXT DD ENTRY */                 50699221
*/*ABD09:         D (YES,,NO,GOTO8) TAPE DEVICE */                      50699321
*/*               D (YES,,NO,GOTO8) SYSOUT WTR STARTED */               50699421
*/*               D (YES,,NO,SKIPDUMP) JOBSTEP ABEND */                 50699521
*/*               P SET INPUT TCB TO MOTHER TCB */                      50699621
*/*TREESRCH:      S (FND,,NONE,GOTO8) SELECT: SELECT NEXT TASK IN       50699721
*/*ABENDING TREE */                                                     50699821
*/*FINDDEB:       P SEARCH DEB CHAIN OF SEL TCB FOR SYSOUT DEB */       50799821
*/*               D (YES,,NO,TREESRCH) DEB FOUND */                     50819821
*/*CLOSIT:        P DEQ DEB FROM SEL TCB DEB CHAIN */                   50839821
*/*               P PUT ADDR OF CURRENT TCB INTO DEB */                 50859821
*/*               P PUT DEB ON CURRENT TCB DEB QUEUE */                 50879821
*/*               P SET FLAG FOR VALID RECURS ACROSS CLOSE */           50883821
*/*               S CLOSE: CLOSE THE SYSOUT DATA SET */                 50887821
*/*               P (,GOTO8) RESET CLOSE RECURS FLAG */                 50891821
*/*SKIPDUMP:      R ABEND 11 */                                         50895821
*/*SELECT:        E ENTRY */                                            50896621
*/*               P SET OUTPUT TCB TO INPUT TCB */                      50897421
*/*%SELECTA:      P SET SELECTED TCB TO DAUGHTER OF OUTPUT TCB */       50898221
*/*SELECT1:       D (NO,,YES,SELECT3) DAUGHTER EXIST */                 50899021
*/*               P SET SEL TCB TO SISTER OF OUTPUT TCB */              50899121
*/*               D (YES,,NO,%MOTHER) OUTPUT TCB = INPUT TCB */         50899221
*/*               R RETURN-NONE */                                      50899321
*/*%MOTHER:       P (,SELECT1) SET OUTPUT TCB = MOTHER TCB */           50899421
*/*SELECT3:       P SET OUTPUT TCB = SEL TCB */                         50899521
*/*               D (NO,,YES,%SELECTA) TASK COMPLETED */                50899621
*/*               R RETURN-FND */                                       50899721
*/*IEAQTM07:      END */                                                50999721
         END                                                            51099721
