 TITLE 'IEAQTM08 / ABEND8 - OPEN ABEND DUMP DATASET / IGC0801C'         00100021
IGC0801C START                                                          00200021
*THE FOLLOWING ROUTINE IS THE EIGHTH LOAD OF ABEND                      00300021
*                                                                       00400021
*STATUS CHANGE LEVEL=0                                                  00500021
*                                                                       00600021
*ROUTINE NAME - ABEND8                                                  00700021
*                                                                       00800021
*FUNCTIONS-                                                             00900021
*        ABEND8 PERFORMS THE FOLLOWING BASIC OPERATIONS UPON            01000021
*         FIRST TIME ENTRY                                              01100021
*                                                                       01200021
*        1. SETS THE TASK TREE FOR THE JOBSTEP NONDISPATCHABLE          01300021
*           (EXCEPT FOR THE CURRENT TASK) AND SAVES THE TCBMSS          01400021
*           POINTER FOR THE CURRENT TASK IN THE EXTENDED SAVE           01500021
*           AREA. THE TCBMSS POINTER FROM THE JOBSTEP TCB IS PUT        01600021
*           IN THE TCBMSS FIELD OF THE CURRENT TASK. THIS               01700021
*           INSURES THAT THE IOBS FOR THE DUMP DATA SET WILL            01800021
*           COME FROM THE JOBSTEP TASK'S SUBPOOL 0.                     01900021
*                                                                       02000021
*        2. GET CORE FOR AND MOVE DCB                                   02100021
*                                                                       02200021
*        3. SAVE LOAD LIST POINTER                                      02300021
*                                                                       02400021
*        4. OPEN'S THE SYSABEND DATA SET AND INSURES THAT THE DATA SET  02500021
*           WILL REMAIN OPEN FOR THE DURATION OF THE JOBSTEP BY         02600021
*           UNIQUELY IDENTIFYING  THE DEB CREATED FOR THE OPEN AND      02700021
*           ALTERING THE DEB QUEUE OF THE JOBSTEP AND SETTING AN        02800021
*           INDICATOR WHICH INDICATES THAT THE DATA SET IS OPEN.        02900021
*                                                                       03000021
*          ONE OF TWO DD CARDS MAY BE SPECIFIED FOR THE SYSABEND        03100021
*          DATA SET.                                                    03200021
*                                                                       03300021
*          BOTH MAY BE SPECIFIED IN A JCL PROCEDURE, HOWEVER, THE       03400021
*          FIRST ONE FOUND IN THE TIOT WILL BE USED ACROSS THE          03500021
*          JOB STEP.                                                    03600021
*                                                                       03700021
*          THE FUNCTION OF EACH IS AS FOLLOWS                           03800021
*                                                                       03900021
*          SYSABEND = A DUMP OF THE NUCLEUS, CONTROL BLOCKS, AND        04000021
*                     THE JOB STEP REGION WILL BE GIVEN.                04100021
*                                                                       04200021
*                                                                       04300021
*          SYSUDUMP = A DUMP OF THE CONTROL BLOCKS AND JOB STEP         04400021
*                     REGION ONLY WILL BE GIVEN.                        04500021
*                                                                       04600021
*                                                                       04700021
*        5. INSURES THAT THE BSAM ACCESS METHOD IS IN CORE FOR THE      04800021
*           DURATION OF THE JOBSTEP.                                    04900021
*                                                                       05000021
*        6. INDICATE NO DUMP THIS TIME IF OPEN NOT SUCCESSFUL.          05100021
*                                                                       05200021
*        7. RESTORE LOAD LIST POINTER                                   05300021
*                                                                       05400021
*        8. RESTORE TCBMSS POINTER AND SET TASKS DISPATCHABLE.          05500021
*                                                                       05600021
*        9. FLAG DUMP DEB                                               05700021
*                                                                       05800021
*        10. XCTL TO ABEND9 IF DUMP WANTED, OTHERWISE TO ABEND11.       05900021
*                                                                       06000021
*                                                                       06100021
*                                                                       06200021
*        IF ENTRY IS DUE TO RECURSION ABEND8 PERFORMS THE FOLLOWING     06300021
*                                                                       06400021
*        1. RESETS THE OPEN/RECURSION INDICATORS IN THE CURRENT TASK.   06500021
*                                                                       06600021
*        2. LOCATES THE PREVIOUS SVRB UNDER WHICH ABEND WAS OPERATING   06700021
*           AND EXTRACTS THE SAVED LOAD LIST ELEMENTS AND TCBMSS PTR.   06800021
*                                                                       06900021
*        3. INDICATE NO DUMP NOW                                        07000021
*                                                                       07100021
*        4. UPDATES THE LOAD LIST QUEUE ON THE CURRENT TCB.             07200021
*                                                                       07300021
*        5. RESTORES THE CURRENT TCBMSS POINTER AND SETS NON-           07400021
*           ABENDING TASKS OF THE JOBSTEP DISPATCHABLE.                 07500021
*                                                                       07600021
*         6. XCTLS TO ABEND11.                                          07700021
*                                                                       07800021
*                                                                       07900021
*                                                                       08000021
*ENTRY POINT NAMES - IGC0801C                                           08100021
*                                                                       08200021
*CONTAINED IN MODULE - IEAQTM08                                         08300021
*                                                                       08400021
*ATTRIBUTES -                                                           08500021
*                                                                       08600021
*          1.  TYPE 4 SVC. SUPERVISOR STATE, REENTRANT.                 08700021
*                                                                       08800021
*APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                 08900021
*                                                                       09000021
*SVC USAGE -                                                            10300021
*              GETMAIN-  GETMAIN FOR DCB(SUBPOOL 0).                    10400021
*                                                                       10500021
*              FREEMAIN-SP 251,252,255                                  10600021
*                                                                       10700021
*              OPEN    - SYSABEND DATA SET.                             10800021
*                                                                       10900021
*              XCTL - TO IGC0901C, IGC0B01C                             11000021
*                                                                       11100021
*INPUT - NONE                                                           11200021
*                                                                       11300021
*OUTPUT - THE ADDRESS OF THE DCB OPENED FOR BSAM IF APPLICABLE          11400021
*                                                                       11500021
*ENTRY POINTS -                                                         11600021
*                                                                       11700021
*          1.  THE PSW MUST BE                                          11800021
*                                                                       11900021
*             A. DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT            12000021
*                MACHINE CHECK.                                         12100021
*                                                                       12200021
*             B. UNDER SUPERVISOR PROTECTION PROTECTION KEY.            12300021
*                                                                       12400021
*             C. IN SUPERVISOR STATE.                                   12500021
*                                                                       12600021
*          2.  REGISTERS UPON INPUT.                                    12700021
*                                                                       12800021
*             A. REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.            12900021
*                                                                       13000021
*             B. REGISTER 4 CONTAINS ADDRESS OF CURRENT TCB.            13100021
*                                                                       13200021
*             C. REGISTER 5 CONTAINS THE ADDRESS OF THE CURRENT RB.     13300021
*                                                                       13400021
*EXIT POINTS - XCTL TO:                                                 13500021
*                                                                       13600021
*        1) ABEND9 (IGC0901C) FOR NORMAL PROCESSING OR ABDUMP           13700021
*            RECURSION                                                  13800021
*                                                                       13900021
*        2) ABEND11 (IGC0B01C) IF NO DUMP WANTED                        14000021
*                                                                       14100021
*ERROR EXIT POINTS - NONE                                               14200021
*                                                                       14300021
*LIST ORGINS,TABLES,CONTROL BLOCKS INCLUDED                             18000021
*                                                                       18100021
*              DCB CONTROL BLOCK INITIALIZED FOR BSAM IS INCLUDED HERE  18200021
*              FOR SYSABEND DATA SET.                                   18300021
*                                                                       18400021
*RESTRICTIONS ON USE OF ROUTINE - NONE                                  18500021
*                                                                       18600021
*NOTES - THIS MODULE IS NOT CHARACTER CODE DEPENDENT.                   18700021
*                                                                       18800021
*        1. THIS MODULE IS NOT CHARACTER CODE DEPENDENT                 18900021
*                                                                       19000021
         EJECT                                                          19100021
* REGISTERS USED BY ABEND8                                              19200021
*                                                                       19300021
PARREG0  EQU   0                        PARAMETER REGISTER ZERO         19400021
PARREG1  EQU   1                        PARAMETER REGISTER ONE          19500021
FREEREG  EQU   2                        REG FOR MP TASK SWITCH          19600021
LINKREG  EQU   2                        INTERNAL LINK REG               19700021
CVTREG   EQU   3                        CONTAINS POINTER TO CVT.        19800021
TCBREG   EQU   4                        CURRENT TCB REGISTER.           19900021
RBREG    EQU   5                        CURRENT RB REGISTER.            20000021
WKREG    EQU   6                        WORK REGISTER                   20100021
RBREG2   EQU   7                        ALTERNATE RB REG                20200021
ATCBREG  EQU   8                        ALTERNATE TCB REGISTER          20300021
BASEREG  EQU   9                        BASE REGISTER FOR ABEND         20400021
XCTLREG  EQU   10                       ADDR OF EPLOC NEXT MOD    21472 20500021
DEBREG   EQU   10                       DEBREG.FOR ACCESS DEB.          20600021
SAVEREG  EQU   10                                                       20700021
TSWIREG  EQU   10                       TASK SWITCHING TCB ADDRESS      20800021
CVTREG2  EQU   11                       SECONDARY CVT REG               20900021
ENTRYTSW EQU   11                       ENTRY POINT TO TASK SW ROUTINE  21000021
DCBREG   EQU   11                       DCBREG FOR SYSABEND OPEN.       21100021
SELREG   EQU   12                       TASK SELECT REG                 21200021
TIOTREG  EQU   12                       REGISTER USED IN ACCESS TIOT    21300021
LNGTREG  EQU   13                       LENGTH OF TIOTREG               21400021
LINKREG2 EQU   13                       LINK REG TO HLTSUB              21500021
RETREG   EQU   14                       REGISTER 14                     21600021
LLEREG   EQU   15                      LOAD LIST ELEM ADDR              21700021
         EJECT                                                          21800021
IGC0801C CSECT                                                          21900021
ABEND8   BALR  BASEREG,0                                                22000021
         USING *,BASEREG         9                                      22100021
         USING CVTSECT,CVTREG    3      SET ADDRESSIBILITY FOR CVT DSEC 22200021
         USING SCVTSECT,CVTREG2  B      ADDRESSABILITY FOR 2NDARY CVT   22300021
         USING TCBSECT,TCBREG    4      SET ADDRESSIBILITY FOR CURR TCB 22400021
         USING TCBDSECT,ATCBREG  8      ALTERNATE TCBREG                22500021
         USING RBSECT,RBREG      5      CURRENT RB(SVRB)                22600021
         USING RBSECT2,RBREG2    7      ALTERNATE RB DSECT              22700021
         USING DEBSECT,DEBREG    A      DEB                             22800021
*                                                                       22900021
*                                                                       23000021
         MVI   RBEXSAVE+45,C'8'         FLAG AS THIS MODULE       20472 23100021
         L     ATCBREG,TCBJSTCB        GET JOB STEP TCB ADDR            23200021
         CLI   TCBRECDE,TCBOPEN        Q. ENTRY DUE TO OPEN RECURSION   23300021
         BE    ABD29                   YES, BRANCH                      23400021
ABD01    EQU   *                                                        23500021
         TM    TCBFLGSP,TCBPDUMP       IS PREV. DUMP INDICATOR ON 20472 23600021
         BO    GOTOB                   YES. XCTL TO LOAD 11       21472 23700021
         TM    TCBCMP,DUMPMASK          HAS A DUMP BEEN REQUESTED       23900021
         BZ    GOTOB                   NO. BYPASS THE DUMP        21472 24000021
ABD04    EQU    *                                                       24100021
         TM    TCBFLGSP+1,TCBFDSOP     WAS DATA SET PREV. OPENED        24200021
         BC    1,ABD23                  YES,BRANCH                      24300021
*                                                                       24400021
* THERE IS NO NEED TO CHECK FOR OPEN IN PROCESS BECAUSE ALL             24500021
* TASKS IN THE JOBSTEP EXCEPT THE ONE OPENING THE DUMP DATA SET         24600021
* ARE SET NONDISPATCHABLE ACROSS THE OPEN. THIS TASK IS OBVIOUSLY       24700021
* DISPATCHABLE, SO THE OPEN IS NOT NOW IN PROGRESS.                     24800021
*                                                                       24900021
*CHECK FOR SYSABEND DD ENTRY IN THE TIOT                                25000021
         MVI   RBEXSAVE,X'00'          CLEAR SWITCH IN ESA              25100021
         L     TIOTREG,TCBTIO           GET TIOT ADDRESS                25200021
         LA    TIOTREG,TIOTLNTH(,TIOTREG) POINT TO FIRST DD ENTRY       25300021
ABD05    CLI   0(TIOTREG),0             IS THIS LAST OR ONLY DD ENTRY   25400021
*                                                                       25500021
* THE DD CARD COULD BE MISSING NOW BUT DEFINED LATER IF DYNAMIC         25600021
* DEVICE ALLOCATION IS BEING USED. IN THIS CASE, WE SHOULD SKIP THE     25700021
* DUMP NOW BUT ALLOW AN ABEND DUMP OF A FUTURE ABENDING TASK.           25800021
*                                                                       25900021
         BZ    CHKDD                    YES. CHECK IF DD FND  AI  21472 26000021
         CLC   TIOTDDNM(8,TIOTREG),SYSAB  IS SYSABEND DD ENTRY PRESENT  26100021
         BNE   CHKUDMP                  NO. CHECK SYSUDUMP    AI  21472 26150021
         MVI   RBEXSAVE,X'40'           FLAG ESA FOR SYSABEND AI  21472 26200021
CHKUDMP  EQU   *                                              AI  21472 26250021
         CLC   TIOTDDNM(8,TIOTREG),SYSUDMP  IS THIS DD ENTRY SYSUDUMP   26300021
         BNE   LOOKMORE                 NO. LOOK FURTHER      AI  21472 26370021
         MVI   RBEXSAVE,X'80'           FLAG ESA FOR SYSUDUMP AI  21472 26440021
LOOKMORE EQU   *                                              AI  21472 26510021
         SR    LNGTREG,LNGTREG                                          26600021
         IC    LNGTREG,0(,TIOTREG)      GET LENGTH OF THIS DD ENTRY     26700021
         AR    TIOTREG,LNGTREG          POINT TO NEXT DD ENTRY          26800021
         BC    15,ABD05                 BR TO TRY NEXT DD ENTRY         26900021
CHKDD    EQU   *                                              AI  21472 26970021
         TM    RBEXSAVE,X'C0'           Q. ABEND DD FOUND?    AI  21472 27040021
         BZ    GOTOB                    NO. SKIP THE DUMP     AI  21472 27110021
         SPACE 3                                                        27200021
*                                                                       27300021
**  THIS LINE WAS TO SET THE TCBFOINP BIT IN THE JOBSTEP TCB**   A34277 27400021
*                                                                       27500021
         SPACE 3                                                        27600021
         MVI   TCBRECDE,TCBREC+TCBOPEN SET OPEN/REC BITS                27700021
*                                                                       27800021
* AT THIS TIME IT IS NECESSARY TO ZERO OUT THE FIELD IN THE             27900021
* EXTENDED SAVE AREA IN WHICH THE LLE POINTER WILL BE SAVED AFTER       28000021
* THE GETMAIN. THIS POINTER WILL BE ADDED TO THE PRESENT LLE CHAIN      28100021
* IF THE GETMAIN FAILS AND THERE IS A RECURSION. IF THIS WERE NOT       28200021
* DONE, THERE WOULD BE AN INVALID RECURSION LATER WHEN ABEND TRIES      28300021
* TO FREE THE LOAD LIST.                                                28400021
*                                                                       28500021
         XC    RBEXSAVE+16(4),RBEXSAVE+16 ZERO LLE PTR SAVE AREA  20472 28600021
         BAL   LINKREG2,SETONDSP        SET TASKS NON-DISP AND   A34277 28700021
*                                        MOVE TCBMSSP TO TCBMSS  A34277 28800021
*                                        ACROSS THE OPEN         A34277 28900021
*                                                                       28920021
* THE SUBPOOL FOR THE DCB WAS CHANGED IN RELEASE 21 FROM 252 TO  A40891 28940021
* 0 TO RESOLVE A SYSTEM INTEGRITY PROBLEM INTRODUCED BY HAVING   A40891 28960021
* THE DCB IN PROTECTED CORE AND THE IOB IN UNPROTECTED CORE.     A40891 28980021
* ALL BSAM RELATED CONTROL BLOCKS MUST BE IN THE SAME KIND OF    A40891 28984021
* CORE.                                                          A40891 28988021
*                                                                       28992021
         L     PARREG0,DCBCONS          GET SP/SIZE OF THE DCB   A40891 29000021
*                                                                       29100021
*  GET CORE FOR THE DCB                                                 29200021
*                                                                       29300021
         GETMAIN R,LV=(0)                                               29400021
*                                                                       29500021
* REGISTER ONE CONTAINS THE ADDRESS OF CORE ACQUIRED.                   29600021
         MVC   0(SIZEDCB,PARREG1),DCBIMAGE MOVE PREASSEMBLED DCB        29700021
         TM    RBEXSAVE,X'80'          IS SYSUDUMP DD BEING USED        29800021
         BZ    ABD10                   NO                               29900021
         MVC   DCBDDNM(8,PARREG1),SYSUDMP  YES. OPEN DCB USING          30000021
*                                          SYSUDUMP DD CARD             30100021
ABD10    DS    0H                                                       30200021
         LR    DCBREG,PARREG1           SAVE DCB ADDRESS                30300021
         LA    PARREG1,RBEXSAVE         GET ADDR OF OPEN'S PAR. LIST    30400021
         ST    DCBREG,0(PARREG1)        STORE DCB ADDR INTO PARAM. LIST 30500021
         MVI   0(PARREG1),X'8F'         SET ONE OPEN DCB INDICATOR      30600021
*                                                                       30700021
*SAVE TCBLLS ADDRESS IN THE EXT. SAVE AREA THEN ZERO TCBLLS IN ORDER    30800021
*TO GET  FRESH LLES FOR THE BSAM ROUTINES.THESE ROUTINES WILL REMAIN    30900021
*IN STORAGE DURING TERMINATION OF ONE OR MORE TASK IN A JOB-STEP.       31000021
*                                                                       31100021
         MVC   RBEXSAVE+16(4),TCBLLS                                    31200021
         XC    TCBLLS(4),TCBLLS                                         31300021
*                                                                       31400021
*        OPEN SYSABEND DATA SET                                         31500021
*                                                                       31600021
         OPEN  MF=(E,(1))                                               31700021
*                                                                       31800021
         MVI   TCBRECDE,X'00'          ZERO OPEN REC BITS               31900021
         LR    RBREG2,RBREG             PRIME THE RESTORE REG W/  M3872 32000021
*                                        CURRENT RB ADDRESS       M3872 32100021
         BAL   LINKREG2,SETODSP         RESET TASKS DISPATCHABLE A34277 32200021
*                                        AND RESTORE TCBMSS      A34277 32300021
DCBCHK   EQU *                                                   A34277 32400021
         L     DCBREG,RBEXSAVE          RESTORE DCB ADDRESS      A34277 32500021
         TM    OBIT(DCBREG),OPENMSK     HAS DCB BEEN OPENED             32600021
         BC    1,ABD11                  YES,BRANCH                      32700021
         SR    DCBREG,DCBREG            NO. INDICATE NO DUMP AT   20472 32800021
*                                        THIS TIME                20472 32900021
         LA    PARREG1,RBEXSAVE+16      GET ADDR OF SAVED LLE           33000021
         B     ABD33                                                    33100021
ABD11    OI    TCBFLGSP+1,TCBFDSOP      SET DATA SET OPENED BIT         33200021
         SPACE 3                                                        33300021
*                                                                       33400021
** THIS LINE WAS TO RESET THE TCBFOINP BIT IN THE JOBSTEP TCB**  A34277 33500021
*                                                                       33600021
         SPACE 3                                                        33700021
         CR    TCBREG,ATCBREG          IS CURR TCB JOBSTEP TCB          33800021
         BC    8,ABD13                 YES,BRANCH                       33900021
*ENQUEUE LLE ON THE JOBSTEP TCB                                         34000021
         LA    WKREG,TCBLLSP            SET UP INPUT REGISTERS          34100021
         LA    PARREG1,TCBLLS           USED BY THE LOAD LIST ROUTINE   34200021
         BAL   LINKREG,LLERTN           LINK TO THE LOAD LIST ROUTINE   34300021
         MVC   TCBLLS(4),RBEXSAVE+16    RESTORE SAVED LLE PTR TO TCB    34400021
         BC    15,GETDEB                BR. TO IDENTIFY SYSABEND DEB    34500021
ABD13    EQU   *                                                        34600021
*RESTORE LLE ADDRESS SAVED IN THE EXT. SAVE AREA                        34700021
         LA    WKREG,TCBLLS             SET UP INPUT REGS               34800021
         LA    PARREG1,RBEXSAVE+16                                      34900021
         BAL   LINKREG,LLERTN           LINK TO THE LLE ROUTINE         35000021
*IDENTIFY SYSABEND DEB                                                  35100021
GETDEB   EQU   *                                                        35200021
         L     DEBREG,TCBDEB            GET DEB ADDRESS(CURRENT TCB)    35300021
         OI    DEBFLGS,DEBSYSAB         SET SYSABEND DEB BIT            35400021
*ENQUEUE DEB ON JOBSTEP TCB                                             35500021
         MVC   TCBDEB+1(3),DEBLINK+1   DEQ DEB FROM CURRENT TCB         35600021
         MVC   DEBLINK+1(3),TCBDEBP+1  ENQ DEB ON JOBSTEP TCB           35700021
         ST    DEBREG,TCBDEBP                                           35800021
         IC    WKREG,DEBTCB             PICK UP HIGH BYTE         20472 35900021
         SLL   WKREG,24                 PUT IN HIGH ORDER BYTE    20472 36000021
         OR    WKREG,ATCBREG            FINISH DEBTCB FIELD AND   20472 36100021
         ST    WKREG,DEBTCB              CHANGE IN ABEND'S DEB    20472 36200021
         B     ABD340                                                   36300021
ABD23    EQU   *    ENTRY HERE MEANS DATA SET PREV. OPENED              36400021
         L     ATCBREG,TCBJSTCB         GET JOB STEP TCB ADDR           36500021
         L     DEBREG,TCBDEBP           GET DEB ADDRESS                 36600021
ABD25    EQU   *                                                 A25370 36700021
         LA    DEBREG,0(,DEBREG)        CLEAR HI BYTE            A25370 36800021
         LTR   DEBREG,DEBREG            IS THIS END OF CHAIN     A25370 36900021
*                                                                       37000021
* IF THIS NEXT BRANCH IS TAKEN, THE ABEND DATA SET HAD ALREADY   A25370 37100021
* BEEN OPENED FOR SOME TASK IN THIS JOBSTEP BUT LATER CLOSED     A25370 37200021
* IN NORMAL END OF TASK PROCESSING FOR THE JOBSTEP TASK. LATER   A25370 37300021
* END OF TASK PROCESSING RESULTED IN AN ABEND FOR THE JOBSTEP    A25370 37400021
* TASK. IT IS NOT POSSIBLE TO SIMPLY REOPEN THE SYSABEND DATA    A25370 37500021
* SET BECAUSE THAT WOULD WIPE OUT THE PREVIOUS DUMP ON IT.       A25370 37600021
*                                                                       37700021
         BZ    PREVDUMP                 YES, BRANCH PREVENT DUMP A25370 37800021
         TM    DEBFLGS,DEBSYSAB         IS SYSABEND BIT ON       A25370 37900021
         BC    1,ABD27                                                  38000021
         L     DEBREG,DEBLINK           GET PREVIOUS DEB ADDRESS        38100021
         B     ABD25                    TRY AGAIN                       38200021
ABD27    L     DCBREG,DEBDCB            EXTRACT DCB ADDRESS             38300021
         LA    DCBREG,0(DCBREG)         CLEAR HIGH ORDER BYTE           38400021
         B     GOTO9                    XCTL TO TAKE DUMP         20472 38500021
* THE FOLLOWING PATH IS TAKEN WHEN ENTRY IS DUE TO RECURSION            38600021
* CAUSED BY OPEN                                                        38700021
*                                                                       38800021
ABD29    EQU   *             ENTRY HERE MEANS REC DUE TO OPEN           38900021
         LR    RBREG2,RBREG             INITIALIZE ALTERNATE RB REG.    39000021
ABD31    EQU   *                                                        39100021
         L     RBREG2,RBLINK2-1         GET ADDRESS OF NEXT RB.         39200021
         CLC   RBEXSAV2+40(6),ABEND     Q. IS THIS PREVIOUS      A41372 39300021
*                                        ABEND'S SVRB?           A41372 39400021
         BC    7,ABD31                  NO,BRANCH                       39500021
         MVI   TCBRECDE,X'00'          ZERO OPEN RECURSION BITS         39600021
         BAL   LINKREG2,SETODSP         BR TO SET TASKS DISP AND A34277 39700021
*                                        RESTORE TCBMSS          A34277 39800021
         SR    DCBREG,DCBREG            INDICATE NO DUMP NOW      M0171 39900021
         LA    PARREG1,RBEXSAV2+16      YES,GET ADDRESS OF LLE SAVED    40000021
*                                       IN ABEND'S SVRB                 40100021
*                                                                       40200021
* IF NO LLE SAVED, I.E. RECURSION DUE TO GETMAIN FOR DCB, THE           40300021
* PERTINENT SECTION OF THE SVRB WAS ZERO.                               40400021
*                                                                       40500021
ABD33    LA    WKREG,TCBLLS             SET UP PARAMETER REG            40600021
         BAL   LINKREG,LLERTN           LINK TO LLE ROUTINE             40700021
ABD340   EQU   *                                                        40800021
         SPACE 3                                                        40900021
*********************************************************************   41000021
*                                                                       41100021
* PRIOR TO RELEASE 20, IT WAS NECESSARY TO DO SOME PROCESSING TO        41200021
* MAKE SURE THAT THE HIGHEST CONTROLLING TASK IN THE ABENDING           41300021
* TASK TREE GOT CONTROL AFTER THE DUMP DATA SET HAD BEEN OPENED.        41400021
* SOME OF THAT PROCESSING WAS HERE, BUT IT HAS BEEN DELETED.            41500021
*                                                                       41600021
*********************************************************************   41700021
         SPACE 3                                                        41800021
         LTR   DCBREG,DCBREG            Q. DUMP WANTED?           20472 41900021
         BZ    GOTOB                    NO. SKIP DUMP LOAD        21472 42000021
GOTO9    EQU   *                                                  21472 42100021
         LA    XCTLREG,NMLOAD9          GET NAME LOAD 9           21472 42200021
XCTL     EQU   *                                                        42300021
         L     PARREG0,THISMOD          FLAG XCTL IN TRACE        20472 42400021
         L     PARREG1,4(,XCTLREG)      SHOW NEXT MODULE          20472 42500021
         LA    15,RBEXSAVE             GET ADDR OF PARAM LIST           42600021
         XCTL  EPLOC=(XCTLREG),SF=(E,(15))                              42700021
PREVDUMP EQU   *                                                        42800021
         OI    TCBFLGSP,TCBPDUMP        SET PREV DUMP INDICATOR   20472 42900021
GOTOB    EQU   *                                                        43000021
         LA    XCTLREG,NMLOADB          GET NAME OF ABEND11 ADDR  21472 43100021
         B     XCTL                                               20472 43200021
         EJECT                                                          43300021
****************************************************************        43400021
*        SET ALL TCBS IN JOBSTEP NON/DISPATCHABLE ROUTINE               43500021
****************************************************************        43600021
*                                                                       43700021
*    ENTRY POINTS - SETODSP (SET TASKS DISPATCHABLE)                    43800021
*                   SETONDSP (SET TASKS NONDISPATCHABLE)                43900021
*                                                                       44000021
*    INPUT REGS -                                                       44100021
*                 LINKREG2 - D  RETURN ADDRESS                          44200021
*                  (HIBIT IS ON)                                        44300021
*                 RBREG - 5 CURRENT SVRB (SETONDSP ENTRY ONLY)    M3872 44400021
*                 RBREG2 - 7 ABEND SVRB W/ MSS RESTORE PTR        M3872 44500021
*                  (SETODSP ENTRY ONLY)                           M3872 44600021
*                                                                       44700021
*    DESTROYS REGS -                                                    44800021
*                    ATCBREG - 8  ADDRESS OF JOBSTEP TCB RETURNED       44900021
*                    LINKREG/FREEREG - 2                                45000021
*                    WKREG - 6                                          45100021
*                    SCVTREG - B                                        45200021
*                    SELREG - C                                         45300021
*                                                                       45400021
SETODSP  EQU   *                        ENTRY TO SET TASKS DISP  A34277 45500021
         LA    LINKREG2,0(,LINKREG2)    INDICATE RESET DISP FLAG A34277 45600021
SETONDSP EQU   *                        ENTRY TO SET NONDISP     A34277 45700021
         L     ATCBREG,TCBJSTCB         GET ADDR OF JOB STEP TCB A34277 45800021
         L     SAVEREG,TCBOTCP          GET ADDR OF INIT TCB     A34277 45900021
         LR    SELREG,SAVEREG           INITIALIZE SELREG        A34277 46000021
FINDSUBT EQU   *                                                 A34277 46100021
         BAL   LINKREG,SELECT           WAS TASK SELECTED        A34277 46200021
         B     SETCHECK                 YES,BRANCH               A34277 46300021
*                                       NO. DROP THRU            A34277 46400021
*                                                                       46500021
* NOW THAT ALL OTHER TASKS IN THE JOBSTEP ARE NONDISPATCHABLE    A34277 46600021
* (OR DISPATCHABLE DEPENDING ON THE ENTRY POINTS), THE TCBMSS    A34277 46700021
* FIELD NEEDS TO BE ADJUSTED. IF ENTRY WAS AT 'SETONDSP', THE    A34277 46800021
* TCBMSS FIELD OF THE CURRENT TASK IS MOVED INTO THE FOURTH      A34277 46900021
* WORD OF ABEND'S SVRB'S EXTENDED SAVE AREA. THEN THE TCBMSS     A34277 47000021
* FIELD OF THE JOBSTEP TCB IS MOVED INTO THE TCBMSS FIELD OF     A34277 47100021
* THE CURRENT TASK'S TCB. IF ENTRY WAS AT 'SETODSP', THE         A34277 47200021
* TCBMSS FIELD OF THE CURRENT TCB IS RESTORED FROM THE FOURTH    A34277 47300021
* WORD OF THE EXTENDED SAVE AREA (FOR A RECURSION DUE TO OPEN,   A34277 47400021
* THE FIELD IS IN THE PREVIOUS ABEND'S SVRB'S EXTENDED SAVE      A34277 47500021
* AREA). THE REASON THIS MUST BE DONE IS TO HANDLE THE FOLLOWING A34277 47600021
* SITUATION.                                                     A34277 47700021
*                                                                       47800021
* WHEN A TASK ATTACHES A DAUGHTER TASK EXPLICITELY, THE MOTHER   A34277 47900021
* CAN SPECIFY THAT SUBPOOL ZERO NOT BE SHARED WITH THE           A34277 48000021
* DAUGHTER. IF THE DAUGHTER THEN ABEND'S, THE DCB FOR THE        A34277 48100021
* DUMP DATA SET WILL BE OPENED BY THE DAUGHTER AND THE DEB WILL  A34277 48200021
* BE QUEUED ONTO THE JOBSTEP TCB. THE DUMP IS TAKEN AND NORMAL   A34277 48300021
* ABEND PROCESSING IS CONTINUED FOR THE SUBTASK. SINCE THE       A34277 48400021
* SUBTASK NOW OWNS SUBPOOL ZERO, IT IS FREED ALONG WITH THE      A34277 48500021
* OTHER DYNAMICALLY ACQUIRED SUBPOOLS OF THE SUBTASK. AT THIS    A34277 48600021
* TIME THE IOBS FOR THE OPEN DUMP DATA SET ARE FREED BECAUSE     A34277 48700021
* OPEN GETS THEM OUT OF THE SUBTASK'S SUBPOOL ZERO. WHEN ABEND   A34277 48800021
* TRIES TO USE THE DUMP DATA SET LATER ON FOR ANOTHER ABEND      A34277 48900021
* SOMEWHERE IN THE JOBSTEP, THE FREED IOBS CAUSE A RECURSION.    A34277 49000021
* BY FREEZING THE JOBSTEP AND SWITCHING TCBMSS POINTERS, ABEND   A34277 49100021
* FOOLS GETMAIN INTO GETTING THE CORE FOR THE IOBS OUT OF THE    A34277 49200021
* JOBSTEP TCB'S SUBPOOL ZERO. THUS THE IOBS WILL REMAIN          A34277 49300021
* AVAILABLE TO ABENDING TASKS FOR THE DURATION OF THE JOBSTEP.   A34277 49400021
*                                                                       49500021
         L     ATCBREG,TCBJSTCB        PICK UP JSTCB'S ADDRESS   A34277 49600021
         LTR   LINKREG2,LINKREG2       Q. STORE OR RESTORE MSS?  A34277 49700021
         BP    RESTORE                 RESTORE, BR TO DO IT      A34277 49800021
         MVC   RBEXSAVE+12(4),TCBMSS   SAVE ABENDING TCBMSS PTR  A34277 49900021
         MVC   TCBMSS+1(3),TCBMSSP+1   USE JSTCB'S MSS PTR NOW   A34277 50000021
         BR    LINKREG2                RETURN TO CALLER          A34277 50100021
RESTORE  EQU   *                                                 A34277 50200021
         CR    ATCBREG,TCBREG          IS THIS TCB JOBSTEP TCB?   20472 50300021
         BCR   8,LINKREG2              YES. MSS PTRS ARE OK NOW   20472 50400021
         MVC   TCBMSSP+1(3),TCBMSS+1   RESTORE JOBSTEP MSS PTR    20472 50500021
         MVC   TCBMSS+1(3),RBEXSAV2+13 RESTORE ABENDING TCBMSS    M3872 50600021
         BR    LINKREG2                RETURN TO CALLER          A34277 50700021
SETCHECK EQU   *                                                 A34277 50800021
         LTR   LINKREG2,LINKREG2       Q. TURN BIT ON OR OFF     A34277 50900021
         BP    TURNOFF                 OFF. BRANCH TO DO IT      A34277 51000021
         OI    TCBFLGSP+3,TCBONDSP     SET TASK NONDISPATCHABLE  A34277 51100021
         NI    TCBFLGS+3,255-TCBONDSP  THIS TASK STILL DISPATCH  A34277 51200021
         B     SWITCH                  NOW DO TASK SWITCH        A34277 51300021
TURNOFF  EQU   *                                                        51400021
         NI    TCBFLGSP+3,255-TCBONDSP ZERO NON-DISP BITS        A34277 51500021
SWITCH   EQU   *                                                        51600021
         L     CVTREG2,CVTABEND        GET SECONDARY CVT ADDRESS A34277 51700021
         LR    WKREG,SAVEREG           SAVE REG USED BY SELECT   A34277 51800021
         LR    TSWIREG,ATCBREG         GET SUBJECT TCB ADDRESS   A34277 51900021
         L     ENTRYTSW,SCVTTASW       GET TASK SWITCH NTRY PT   A34277 52000021
         BALR  RETREG,ENTRYTSW         DO TASK SWITCH            A34277 52100021
         LR    SAVEREG,WKREG           RESTORE REG SAVED         A34277 52200021
         LTR   LINKREG2,LINKREG2       Q. TASK SET NONDISP?      A34277 52300021
         BP    FINDSUBT                NO. SKIP MP CHECK         A34277 52400021
*                                                                       52500021
* A TASK JUST FLAGGED NON-DISPATCHABLE MAY STILL                 A34277 52600021
* BE ACTIVE ON THE SECOND CPU. IF SO, IT MUST BE REMOVED         A34277 52700021
* FROM EXECUTION. THE NEW AND OLD POINTERS MUST BE ALTERED       A34277 52800021
* IF THEY POINT TO NON-DISPATCHABLE TASKS. THE ROUTINE           A34277 52900021
* TESTDSP LOCATED WITHIN THE PSA WILL ACCOMPLISH THIS.           A34277 53000021
*                                                                A34277 53100021
         TM    CVTDCB,CVTDCBMP          IS THIS AN M65MP?        A34277 53200021
CVTDCBMP EQU   X'04'                    MASK 00000100            A34277 53300021
         BZ    FINDSUBT                 NO. SKIP TESTDSP         A34277 53400021
         L     FREEREG,CVTMPCVT         GET MPCVT ADDR.          A34277 53500021
*                                                                       53600021
*        XXXXXXXXX                                                      53700021
         USING IEAMPCVT,FREEREG                                  A34277 53800021
*        XXXXXXXXX                                                      53900021
*                                                                       54000021
         L     FREEREG,CVTTKRM          GET TESTDSP ADDRESS.     A34277 54100021
*                                                                       54200021
*        XXXXXXXXX                                                      54300021
         DROP  FREEREG                                           A34277 54400021
*        XXXXXXXXX                                                      54500021
*                                                                       54600021
         BALR  RETREG,FREEREG           BRANCH TO TESTDSP.       A34277 54700021
         B     FINDSUBT                 SELECT NEXT TASK         A34277 54800021
         EJECT                                                          54900021
**********************************************************************  55000021
*        TASK SELECT ROUTINE                                            55100021
**********************************************************************  55200021
*                                                                       55300021
*        INPUT REGS -                                                   55400021
*                     LINKREG - 2                                       55500021
*                     SAVEREG - A                                       55600021
*                     SELREG  - C                                       55700021
*                                                                       55800021
*        OUTPUT REGS -                                                  55900021
*                      ATCBREG - 8 SELECTED TCB                         56000021
*                                                                       56100021
*        DESTROYS REGS -                                                56200021
*                        SELREG - C                                     56300021
*                                                                       56400021
SELECT   LR    ATCBREG,SELREG          SAVE GIVEN TCB ADDR              56500021
         L     SELREG,TCBLTCP          GET DAUGHTER                     56600021
SELECT1  LTR   SELREG,SELREG           DOES DAUGHTER EXIST              56700021
         BC    7,SELECT3               YES,BRANCH                       56800021
         L     SELREG,TCBNTCP          NO,GET SISTER                    56900021
         CR    ATCBREG,SAVEREG         IS SCAN COMPLETE                 57000021
         BE    4(,LINKREG)             YES. LAST TIME RETURN            57100021
         L     ATCBREG,TCBOTCP         NO,GET MOTHER                    57200021
         B     SELECT1                                                  57300021
SELECT3  LR    ATCBREG,SELREG          MODIFY ATCBREG                   57400021
         TM    TCBFLGSP+4,TCBFC        Q. THIS TASK TERMINATED   A43837 57420021
         BO    SELECT                  YES. SELECT NEXT TASK     A43837 57440021
         BCR   15,LINKREG              RETURN                           57500021
         EJECT                                                          57600021
*********************************************************************** 57700021
*        LLE  ROUTINE                                                   57800021
*********************************************************************** 57900021
*   INPUT:1)WKREG=ADDRESS OF THE TCBLLS FIELD IN QUESTION               58000021
*         2)PARREG1=POINTER TO THE 4-BYTE ADDRESS OF THE LLE TO BE      58100021
*           UPDATED OR RESTORED                                         58200021
*         3)LINKREG=RETURN ADDRESS                                      58300021
*                                                                       58400021
*    DESTROYS REGS:1)WKREG - F                                          58500021
*                  2)LLEREG - 6                                         58600021
*                                                                       58700021
LLERTN   LR    LLEREG,WKREG                                             58800021
         LTR   WKREG,WKREG              IS THIS LAST LLE                58900021
         BC    7,LLERTN2                NO,BRANCH                       59000021
         MVC   1(3,LLEREG),1(PARREG1)   UPDATE/RESTORE                  59100021
         BCR   15,LINKREG               RETURN TO CALLER                59200021
LLERTN2  LR    LLEREG,WKREG            SAVE LLE ADDRESS                 59300021
         L     WKREG,0(,WKREG)          GET ADDRESS OF NEXT LLE         59400021
         B     LLERTN+2                                                 59500021
         EJECT                                                          59600021
*********************************************************************   59700021
*                                                                       59800021
*              PREASSEMBLED DCB                                         59900021
*                                                                       60000021
DCBIMAGE DCB   DSORG=PS,MACRF=W,DDNAME=SYSABEND,RECFM=VBA,             X60100021
               BLKSIZE=1632,LRECL=125                                   60200021
SIZEDCB  EQU   *-DCBIMAGE               ADCON FOR GETTING SIZE DCB.     60300021
         EJECT                                                          60400021
*        CONSTANTS                                                      60500021
         DS    0F                                                       60600021
SYSUDMP  DC    C'SYSUDUMP'              ALTERNATE DD FOR ABEND          60700021
NMLOAD9  DC    CL8'IGC0901C'                                            60800021
NMLOADB  DC    CL8'IGC0B01C'                                            60900021
THISMOD  DC    C'801C'                 INDICATE THIS MOD IN XCTL  20472 61000021
DCBCONS  DC    AL1(250),AL3(SIZEDCB)   CONS FOR DCB GETMAIN      A40891 61020021
SYSAB    DC    C'SYSABEND',C'8'         DDNAME FOR ABDUMP        A41372 61100021
ABEND    EQU   SYSAB+3                                                  61200021
         EJECT                                                          61300021
*                                                                       61400021
*                                                                       61500021
*             THE FOLLOWING CODE IS ZAP SPACE FOR MAINTENANCE USE       61600021
*                                                                       61700021
*                                                                       61800021
*                                                                       61900021
         DC    H'0'                                                     62000021
         DC    H'0'                                                     62100021
         DC    H'0'                                                     62200021
         DC    H'0'                                                     62300021
         DC    H'0'                                                     62400021
         DC    H'0'                                                     62500021
         DC    H'0'                                                     62600021
         DC    H'0'                                                     62700021
         DC    H'0'                                                     62800021
         DC    H'0'                                                     62900021
         DC    H'0'                                                     63000021
         DC    H'0'                                                     63100021
         DC    H'0'                                                     63200021
         DC    H'0'                                                     63300021
         DC    H'0'                                                     63400021
         DC    H'0'                                                     63500021
         DC    H'0'                                                     63600021
         DC    H'0'                                                     63700021
         DC    H'0'                                                     63800021
         DC    H'0'                                                     63900021
         DC    H'0'                                                     64000021
         DC    H'0'                                                     64100021
         DC    H'0'                                                     64200021
         DC    H'0'                                                     64300021
         DC    H'0'                                                     64400021
         DC    H'0'                                                     64500021
         DC    H'0'                                                     64600021
         EJECT                                                          64700021
         IHBABCTL                                                       64800021
DCBDDNM  EQU   40                 OFFSET TO DDNAME IN DCB               64900021
         MPCVT                                                          65000021
*/*IEAQTM08:      CHART */                                              65200021
*/*IEAQTM08:      E ABEND8 */                                           65300021
*/*IGC0801C:      P FLAG ENTRY TO THIS MODULE */                        65400021
*/*               D (N,,Y,ABD29) IS ENTRY DUE TO OPEN RECURSION */      65500021
*/*ABD01:         D (YES,,NO,GOTOB) DUMP WANTED AND NOT PREVENTED */    65600021
*/*ABD04:         D (N,,Y,ABD23) DUMP DATA SET PREVIOUSLY OPENED */     65900021
*/*               P SET INTERNAL SWITCH FOR SYSABEND DD */              66000021
*/*               P LOCATE FIRST DD ENTRY IN TIOT */                    66020021
*/*ABD05:         D (YES,,NO,GOTOB) DOES DD ENTRY EXIST */              66100021
*/*               D (N,,Y,ABD09) DD FOR SYSABEND DATA SET */            66200021
*/*               D (N,,Y,ABD08) DD FOR SYSUDUMP DATA SET */            66300021
*/*               P (,ABD05) LOCATE NEXT DD ENTRY */                    66400021
*/*ABD08:         P SET INTERNAL SWITCH FOR SYSUDUMP DD  */             66500021
*/*ABD09:         P SET OPEN RECURSION FLAGS. ZERO LLE PTR SAVE AREA */ 66600021
*/*               S SETONDSP:SET STEP NON- DISP. MODIFY SPQE POINTER */ 66700021
*/*               S GETMAIN:AREA FOR DUMP DATA SET DCB */               66900021
*/*               P MOVE PREASSEMBLED DCB TO GOTTEN AREA */             67000021
*/*ABD10:         P PREPARE TO FORCE CREATION OF NEW BSAM LLES */       67300021
*/*               S OPEN: SPECIFIED DUMP DATA SET DCB */                67400021
*/*               P RESET VALID RECURSION FLAGS */                      67500021
*/*               S SETODSP: RESET STEP DISP. CORRECT SPQE CHAINS */    67600021
*/*DCBCHK:        D (N,,Y,ABD11) HAS DCB BEEN OPEN */                   67800021
*/*               P INDICATE NO DUMP FOR NOW */                         67900021
*/*               P (,ABD33) PREPARE TO RECHAIN LLES TO CURRENT TCB */  67920021
*/*ABD11:         P SET DUMP DATA SET PREVIOUSLY OPENED FLAG */         68000021
*/*               D (N,,Y,ABD13) IS CURR TCB JOBSTEP TCB */             68100021
*/*               S LLERTN: CHAIN FRESH LLES TO JOBSTEP TCB */          68300021
*/*               P (,GETDEB) RESTORE ORIGINAL LLE CHAIN TO ABENDING    68400021
*/*TCB */                                                               68420021
*/*ABD13:         S LLERTN: COMBINE OLD & FRESH LLES ON J.S. TCB CHAIN  68600021
*/**/                                                                   68620021
*/*GETDEB:        P FLAG SYSUDUMP/ SYSABEND DEB AS ABEND'S DEB */       68640021
*/*               P (,ABD340) QUEUE ABEND'S DEB TO JOBSTEP TCB */       68700021
*/*ABD23:         P SEARCH JOB STEP DEB CHAIN FOR ABEND'S DEB */        68800021
*/*               D (YES,,NO,PREVDUMP) ABEND'S DEB STILL AROUND */      68900021
*/*ABD27:         P (,GOTO9) GET DCB ADDRESS FROM ABEND'S DEB */        69200021
*/*ABD29:         P SEARCH RB CHAIN FOR PREVIOUS ABEND8 SVRB */         69400021
*/*               P RESET VALID RECURSION FLAGS */                      69600021
*/*               S SETODSP: SET TASK DISP. RESTORE SPQE CHAIN */       69700021
*/*               P INDICATE NO DUMP FOR NOW */                         69800021
*/*ABD33:         S LLERTN: RECHAIN LLES TO CURRENT TCB */              70000021
*/*ABD340:        D (Y,,N,GOTOB) DUMP STILL ALLOWED */                  70100021
*/*GOTO9:         P PREPARE TO TRANSFER CONTROL TO ABEND9 */            70200021
*/*XCTL:          P FLAG XCTL FOR TRACE */                              70300021
*/*               R XCTL TO INDICATED MODULE */                         70400021
*/*PREVDUMP:      P SET PREVENT DUMP INDICATOR */                       70500021
*/*GOTOB:         P (,XCTL) PREPARE TO TRANSFER CONTROL TO ABEND11 */   70600021
*/*SETODSP:       E ENTRY TO RESET DISP. RESTORE SPQE CHAIN */          70700021
*/*               P SET SWITCH FOR RESET DISP AND RESTORE SPQE CHAIN */ 70800021
*/*SETONDSP:      E ENTRY TO SET NON-DISP. ALTER SPQE CHAIN */          70900021
*/*               P PREPARE FOR 1ST ENTRY TO TASK SELECT (INITIATOR     70920021
*/*TCB) */                                                              70924021
*/*FINDSUBT:      S (LAST,,SLTD,SETCHECK) SELECT:A TASK FROM JOBSTEP */ 71000021
*/*               D (N,,Y,RESTORE) RESTORE SPQE CHAIN */                71200021
*/*               P (,%RETURN) SET CURRENT TCB TO USE SPQE CHAIN OF JOB 71300021
*/* STEP TCB */                                                         71304021
*/*RESTORE:       D (N,,Y,%RETURN) IS CURRENT TCB THE JOBSTEP TCB */    71400021
*/*               P (,%RETURN) RESTORE SPQE CHAIN FOR CURRENT TCB */    71500021
*/*SETCHECK:      D (NOND,,DISP,TURNOFF) SET DISPATCHABLE OR NON- DISP  71600021
*/**/                                                                   71620021
*/*               P (,SWITCH) SET SELECTED TASK NON-DISP IF NOT THE     71700021
*/*CURRENT TASK */                                                      71720021
*/*%RETURN:       R RETURN */                                           71800021
*/*TURNOFF:       P RESET TASK DISPATCHABLE */                          71900021
*/*SWITCH:        S IEA0DS02: TASK SWITCH  */                           72100021
*/*               D (NOND,,DISP,FINDSUBT) TASK TO BE SET DISP OR        72200021
*/*NON-DISP */                                                          72220021
*/*               D (Y,,N,FINDSUBT) IS THIS AN M65MP */                 72300021
*/*               S (,FINDSUBT) TESTDSP: REMOVE NON-DISP TASK FROM      72500021
*/*OTHER CPU */                                                         72520021
*/*SELECT:        E ENTRY TO TASK SELECT */                             72600021
*/*               P  SAVE GIVEN TCB & GET DAUGHTER */                   72700021
*/*SELECT1:       D (N,,Y,SELECT3) DOES DAUGHTER EXIST */               72800021
*/*               P GET SISTER */                                       72900021
*/*               D (Y,,N,%RETN) IS SCAN COMPLETE */                    73000021
*/*               P (,SELECT1) GET MOTHER */                            73100021
*/*SELECT3:       P  INITIALIZE ATCBREG */                              73200021
*/*               D (YES,SELECT1,NO,%RETN) THIS TASK TERMINATED */      73220021
*/*%RETN:         R RETURN-MORE */                                      73240021
*/*LLERTN:        E ENTRY TO MODIFY LLE CHAIN */                        73300021
*/*               P SEARCH FOR END OF INPUT LLE CHAIN */                73400021
*/*               P PUT IMPUT LLE ON END OF INPUT LLE CHAIN */          73600021
*/*%RET:          R RETURN */                                           73700021
*/*IEAQTM08:      END */                                                73900021
         END                                                            74000021
