         TITLE 'IEAQTM09 / ABEND9 - TAKE ABDUMP / IGC0901C '            00100021
IGC0901C START                                                          00200021
*                                                                       00300021
*                                                                       00400021
*                                                                       00500021
*   THE FOLLOWING CODE IS THE NINTH LOAD OF ABEND                       00600021
*                                                                       00700021
* ROUTINE NAME- ABEND9                                                  00800021
*                                                                       00900021
*                                                                       01000021
* FUNCTIONS -                                                           01100021
*             1. PERFORMS A LOAD OF ABDUMPS REENTRANT MODULE IF ENTRY   01200021
*                IS FROM LOAD 8 AND THE DCB ADDRESS OF THE SYSABEND     01300021
*                DATA SET HAS BEEN PASSED IN A STANDARD REGISTER        01400021
*                                                                       01500021
*             2. PERFORMS AN ENQUEUE ON THE SYSABEND DATA SET WITH      01600021
*                THE EXCLUSIVE OPTION.                                  01700021
*                                                                       01800021
*             3. PERFORMS A DUMP OF THE CURRENT TASK WITH THE FOLLOWING 01900021
*                INFORMATION - JOBNAME, STEPNAME, DATE, TIME, COMP.     02000021
*                CODE, PSW AT ENTRY TO ABEND, TCB, RB'S, LOAD LIST,     02100021
*                CDE'S, TIOT, EXTENT LISTS, DEB'S, SPQE'S, DQE'S,       02200021
*                FQE'S, PQE, FBQE'S, SAVE AREA TRACE, QCB'S, LAST POINT 02300021
*                OF INTERRUPT, REGISTERS AT ENTRY TO ABEND, NUCLEUS,    02400021
*                LOAD MODULES, AND SUBPOOL BLOCKS. NOTE - IF THE        02500021
*                SYSUDUMP DD CARD WAS USED TO OPEN THE SYSABEND         02600021
*                DATA SET, THE NUCLEUS WILL NOT BE DUMPED.              02700021
*                                                                       02800021
*             4. PERFORMS A DUMP OF ALL SUBTASK'S OF THE TASK ABENDING. 02900021
*                WITH THE FOLLOWING INFORMATION- JOBNAME, STEPNAME,     03000021
*                DATE,TIME,ID=001,COMPL. CODE,TCB,RB'S, LOAD LIST,      03100021
*                CDE'S, EXTENT LISTS, TIOT, DEB'S, SPQE'S, DQE'S,       03200021
*                FQE'S, PQE, FBQE'S, QCB'S, LAST POINT OF INTERRUPT,    03300021
*                AND SAVE AREA TRACE.                                   03400021
*                                                                       03500021
*             5. PERFORMS A DUMP OF THE MATRIARCHAL LINE OF THE TASK    03600021
*                ABENDING INCLUDING THE JOBSTEP TASK WITH THE FOLLOWING 03700021
*                INFORMATION.- JOBNAME, STEPNAME, DATE, TIME, ID=002,   03800021
*                COMPL. CODE, TCB, RB'S, LOAD LIST, CDE'S, EXTENT       03900021
*                LISTS, TIOT, DEB'S, SPQE'S, DQE'S, FQE'S, PQE, FBQE'S, 04000021
*                QCB'S, LAST POINT OF INTERRUPT, AND SAVE AREA TRACE.   04100021
*                                                                       04200021
*             6. DEQUEUES FROM THE SYSABEND DATA SET WHEN FINISHED      04300021
*                ABDUMPING.                                             04400021
*                                                                       04500021
*             7. DELETES ABDUMP'S REENTRANT MODULE.                     04600021
*                                                                       04700021
*                                                                       04800021
* ENTRY POINT NAMES - 1. IGC0901C                                       04900021
*                                                                       05000021
*             A. ENTRY FROM EIGHTH LOAD OF ABEND FOR NORMAL             05100021
*                FIRST-TIME ENTRY.                                      05200021
*                                                                       05300021
*             B. ENTRY FROM THIRD LOAD OF ABEND IF                      05400021
*                RECURSION DUE TO ABDUMP                                05500021
*                                                                       05600021
* CONTAINED IN MODULE - IEAQTM09.                                       05700021
*                                                                       05800021
* ATTRIBUTES - TYPE 4 SVC, REENTRANT, SUPERVISOR STATE,                 05900021
*              PARTIALLY ENABLED.                                       06000021
*                                                                       06100021
* APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                06200021
*                                                                       06300021
* SVC USAGE - LOAD, ENQ, DEQ, DELETE, SNAP, XCTL.                       06600021
*                                                                       06700021
* INPUT - NONE.                                                         06800021
*                                                                       06900021
* OUTPUT - NONE.                                                        07000021
*                                                                       07100021
* ENTRY POINTS - 1. IGC0901C                                            07200021
*                                                                       07300021
*                   A. THE CURRENT PSW MUST BE                          07400021
*                                                                       07500021
*                      (1) DISABLED FOR ALL MASKABLE INTERRUPTS         07600021
*                          EXCEPT MACHINE CHECK.                        07700021
*                                                                       07800021
*                      (2) UNDER SUPERVISOR PROTECTION KEY.             07900021
*                                                                       08000021
*                      (3) IN SUPERVISOR MODE.                          08100021
*                                                                       08200021
*                   B. REGISTERS                                        08300021
*                                                                       08400021
*                      (1) REGISTER 3 MUST CONTAIN THE ADDRESS          08500021
*                          OF THE CVT.                                  08600021
*                                                                       08700021
*                      (2) REGISTER 4 MUST CONTAIN THE ADDRESS          08800021
*                          OF THE CURRENT TCB.                          08900021
*                                                                       09000021
*                      (3) REGISTER 5 MUST CONTAIN THE ADDRESS          09100021
*                          OF THE CURRENT RB.                           09200021
*                                                                       09300021
*                      (4) REGISTER 11 MUST CONTAIN THE ADDRESS         09400021
*                          OF THE DCB OF THE DUMP DATA SET OR 0.        09500021
*                         (EXCEPT ON ENTRY FOR ABDUMP RECURSION)        09600021
*                                                                       09700021
* EXIT POINTS - 1. BRANCH TO DISPATCHER IN ORDER TO DISPATCH A          09800021
*                  SELECTED SUBTASK FOR ENTRY TO THIS LOAD OF ABEND.    09900021
*                                                                       10000021
*               2. XCTL TO THE ELEVENTH LOAD OF ABEND TO CLOSE          10100021
*                  OPEN DATA SETS FOR THE TREE OF ABENDING TASKS        10200021
*                                                                       10300021
*               3. IN BOTH CASES THE CURRENT PSW IS                     10400021
*                                                                       10500021
*                  A. DISABLED FOR ALL MASKABLE INTERRUPTS              10600021
*                     EXCEPT MACHINE CHECK.                             10700021
*                                                                       10800021
*                  B. UNDER SUPERVISOR PROTECTION KEY.                  10900021
*                                                                       11000021
*                  C. IN SUPERVISOR MODE.                               11100021
*                                                                       11200021
*               4. REGISTERS                                            11300021
*                                                                       11400021
*                  A. REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.       11500021
*                                                                       11600021
*                  B. REGISTER 4 CONTAINS THE ADDRESS OF                11700021
*                     THE CURRENT TCB.                                  11800021
*                                                                       11900021
*                  C. REGISTER 5 CONTAINS THE ADDRESS OF                12000021
*                     THE CURRENT RB.                                   12100021
*                                                                       12200021
* ERROR EXIT POINTS - NONE.                                             12300021
*                                                                       12400021
* RESTRICTIONS ON USE OF ROUTINE - NONE.                                17400021
*                                                                       17500021
* NOTES -                                                               17600021
*                                                                       17700021
*         THIS CODE IS NOT CHARACTER CODE DEPENDENT.                    17800021
*                                                                       17900021
         EJECT                                                          17920021
GTFSECT  DSECT                         TO GENERATE HOOK EQUATES   21014 17940021
         HOOK EID=IHLMABOF                                        21014 17960021
         EJECT                                                          18000021
*                                                                       18100021
* THE FOLLOWING ARE REGISTER ASSIGNMENTS FOR THIS MODULE.               18200021
*                                                                       18300021
PARREG0  EQU   0                        PARAMETER REG.                  18400021
PARREG1  EQU   1                        PARAMETER REG.                  18500021
ARBREG   EQU   2                        ADDRESSES ALTERNATE RB          18600021
LINKREG  EQU   2                        LINK REGISTER                   18700021
CVTREG   EQU   3                        CVTDSECT REG. USED THRU-OUT     18800021
TCBREG   EQU   4                        TCBDSECT REG. CURRENT TCB       18900021
RBREG    EQU   5                        RBSECT REG. CURRENT RB          19000021
SELREG   EQU   7                        1SED IN TASK SELECTION          19100021
SAVEREG  EQU   8                        SAVE REGISTER                   19200021
BASEREG  EQU   9                        ABEND BASEREG - USED THRU-OUT   19300021
ATCBREG  EQU   10                       ADDRESSES ALTERNATE TCB         19400021
XCTLREG  EQU   10                       ADDR EPLOC NAME NEXT MOD        19500021
DCBREG   EQU   11                       DCB FOR DUMP REGISTER           19600021
SPIDREG  EQU   11                       USED TO SET UP SUBPOOL IDENTIF. 19700021
WORKREG  EQU   12                       TEMPORARY WORK REGISTER         19800021
MAJREG   EQU   13                       USED TO SET UP QCB PARAMETERS   19900021
MINREG   EQU   13                       USED TO SET UP QCB PARAMETERS   20000021
RETREG   EQU   14                       RETURN REG FROM ERASE ROUTINE   20100021
SCVTREG  EQU   15                       ADDR OF SECONDARY CVT           20200021
         EJECT                                                          20300021
IGC0901C CSECT                                                          20400021
ABEND9   BALR  BASEREG,0                ESTABLISH ADDRESSABILITY        20500021
         USING *,BASEREG           9                                    20600021
         USING TCBSECT,TCBREG      4                                    20700021
         USING TCBDSECT,ATCBREG    8                                    20800021
         USING RBSECT,RBREG        5                                    20900021
         USING RBSECT2,ARBREG      2                                    21000021
         USING CVTSECT,CVTREG      3                                    21100021
         USING SCVTSECT,SCVTREG    F                                    21200021
         L     SCVTREG,CVTABEND         GET ADDR OF SECONDARY CVT       21300021
         MVI   RBEXSAVE+45,C'9'         FLAG RB FOR THIS MODULE   21472 21400021
*                                                                       21500021
* THE FOLLOWING CODE CHECKS FOR RECURSION OR RE-ENTRY TO THIS LOAD OF   21600021
*ABEND DUE TO AN ABNORMAL TERMINATION WHILE IN ABDUMP.                  21700021
*                                                                       21800021
         L     ATCBREG,TCBJSTCB         LOAD ADDR OF JOB STEP TCB       21900021
         CLI   TCBRECDE,TCBADUMP       IS RECURSION DUE TO ABDUMP 20472 22000021
         BE    ABRECURS                YES, NO DUMP WANTED NOW    20472 22100021
         TM    TCBFLGSP,TCBPDUMP        Q. DUMP PREV. FOR STEP    20472 22200021
         BO    RECRSOFF                 YES. SKIP THE DUMPS             22300021
         LTR   DCBREG,DCBREG            Q. IS DUMP TO BE TAKEN    20472 22400021
         BZ    RECRSOFF                 NO. SKIP THE DUMPS        20472 22500021
*                                                                       22600021
*********************************************************************** 22700021
**********************   ABDUMP CURRENT TASK AND SUBTASKS   *********** 22800021
*********************************************************************** 22900021
*        ABDUMP THE CURRENT TASK                                        23000021
*                                                                       23100021
DUMPIT   EQU   *                                                        23200021
         MVI   TCBRECDE,TCBADUMP+TCBREC SET ABDUMP AND RECUR IND.       23300021
         L     PARREG1,CVTSVDCB         GET ADDR. OF THE SVC LIB. DCB   23400021
         LA    PARREG0,LOADNAME         GET NAME OF THE NON-TRANSIENT   23500021
*                                       MODULE USED BY ABDUMP           23600021
*                                                                       23700021
ABD12    LOAD  EPLOC=(0),DCB=(1)        LOAD IEAQAD0A MODULE            23800021
*                                                                       23900021
*                                                                       24000021
*  ENQ SYSABEND DATA SET                                                24100021
*                                                                       24200021
         LA    PARREG1,RBEXSAVE+16      LOAD ADDR OF ABEND SVRB ESA     24300021
         MVC   12(11,PARREG1),MAJ       MOVE MAJOR + MINOR NAMES TO ESA 24400021
         LA    MAJREG,12(,PARREG1)      LOAD ADDR OF MAJOR QCB NAME     24500021
         ST    MAJREG,4(,PARREG1)       STORE ADDR OF MAJOR IN PARAM.   24600021
         LA    MINREG,20(,PARREG1)      LOAD ADDR OF MINOR QCB NAME     24700021
         ST    MINREG,8(,PARREG1)       STORE ADDR OF MINOR IN PARAM.   24800021
         MVC   0(4,PARREG1),ENQFLAGS    SET UP SIZE, OPTIONS ETC.       24900021
         ENQ   (,,E,,STEP),MF=(E,(1))                                   25000021
         L     ATCBREG,TCBJSTCB         LOAD ADDR OF JOB STEP TCB       25100021
         TM    TCBFLGSP,TCBPDUMP        IS PREVENT DUMP INDIC. ON 20472 25200021
         BC    7,ABD21                  YES, SKIP DUMP- GO TO DEQ       25300021
         L     WORKREG,TCBTIOP          LOAD TIOT ADDR                  25400021
         LH    PARREG1,DCBTIO(0,DCBREG) PICK UP INDEX TO TIOT           25500021
         LA    WORKREG,4(WORKREG,PARREG1) AND COMPUTE ADDR OF DD        25600021
*                                        CARD BEING USED FOR ABEND      25700021
         LA    PARREG1,RBEXSAVE         GET ADDR OF ABDUMP'S PAR LIST   25800021
         XC    0(16,PARREG1),0(PARREG1) ZERO IT OUT               M2899 25900021
         MVI   2(1),X'29'               SET ABDUMP OPTION FLAGS         26000021
         MVI   3(1),X'BE'               SET ABDUMP OPTION FLAGS         26100021
         TM    TCBFLGS,TCBFS            Q. DUMP THIS TASK BEFORE  20472 26200021
*                                        POSSIBLE ON SOME RECURS  20472 26300021
         BO    TESTSUBS                 YES. CHECK FOR SUBTASKS   20472 26400021
         TM    CVTGTFST,CVTGTFS+CVTFORM Q. IS GTF ACTIVE AND      21014 26500021
*                                        FORMATTING               21014 26600021
         BNO   NOTRACE                  NO. DON'T ASK FOR TRACE   21014 26700021
         CLI   7(WORKREG),C'P'          IS SYSUDUMP BEING USED    21014 26800021
         BE    NOTRACE                  YES. THEN SYSABEND NOT    21014 26900021
*                                        USED, SO DON'T STOP GTF  21014 27000021
         TM    TCBFLGS,TCBGTOFM         Q. TCB ALREADY FROZEN GTF 21014 27100021
         BO    NOTRACE                  YES. DON'T STOP IT AGAIN  21014 27200021
         HOOK  EID=IHLMABOF             FREEZE GTF FOR SYSABEND   21014 27300021
         OI    TCBFLGS,TCBGTOFM         FLAG TCB HAS FROZEN GTF   21014 27400021
         OI    BYTE2(PARREG1),TRCREQ    REQUEST TRACE TABLE       21014 27500021
BYTE2    EQU   2                        2ND BYTE OF PARAM LIST    21014 27600021
TRCREQ   EQU   X'10'                    FLAG FOR TRACE REQUEST    21014 27700021
NOTRACE  EQU   *                                                  21014 27800021
         BAL   LINKREG,SNAP1            ABDUMP CURRENT TASK             27900021
*                                                                       28000021
* UPON RETURN FROM ABDUMP SET 'TCBFS' BIT TO PREVENT MULTIPLE           28100021
* DUMPS FOR THE SAME TASK                                               28200021
         OI    TCBFLGS,TCBFS            SET 'S' BIT IN CURR TCB         28300021
TESTSUBS EQU   *                                                  20472 28400021
         OC    TCBLTC(4),TCBLTC         DOES CURRENT TASK HAVE DAUGHTER 28500021
         BC    8,ABD17                  NO BRANCH                       28600021
         LR    SAVEREG,TCBREG           YES,SAVE CURR. TCB ADDRESS      28700021
         LR    SELREG,TCBREG            INITIALIZE SELREG               28800021
*SELECT A SUBTASK TO BE DUMPED VIA SELECT TASK ROUTINE                  28900021
ABD13    BAL   LINKREG,SELECT           WAS SUBTASK SELECTED            29000021
         B     ABD15                    YES,BRANCH                      29100021
         B     ABD17                    NO,BRANCH                       29200021
ABD15    TM    TCBFLGSP,TCBFS           HAS SELECTED TASK BEEN DUMPED   29300021
         BC    1,ABD13                  YES,SELECT NEXT TASK            29400021
         LA    PARREG1,RBEXSAVE         GET ADDR OF ABDUMP'S PAR. LIST  29500021
*                                                                       29600021
*        ABDUMP SUBTASKS WITHOUT REDUNDANT INFORMATION(ID=1)            29700021
*                                                                       29800021
         MVI   0(1),1                   ID=1 MEANS SUBTASKS             29900021
         BAL   LINKREG,SNAP             ABDUMP A SUBTASK                30000021
         OI    TCBFLGSP,TCBFS           SET 'TCBFS' BIT IN SELECTED TCB 30100021
         B     ABD13                    SELECT NEXT SUBTASK             30200021
ABD17    EQU   *                                                        30300021
*                                                                       30400021
*  ABDUMP MATRIARCHY OF THE CURRENT TASK FROM BOTTOM TO TOP             30500021
*                                                                       30600021
         LR    ATCBREG,TCBREG           GET ADDRESS OF CURRENT TCB      30700021
ABD19    C     ATCBREG,TCBJSTCB         Q. CURRENT TCB JSTCB?    A31771 30800021
         BC    8,ABD21                  YES,ALL DONE-BRANCH             30900021
         L     ATCBREG,TCBOTCP          NO,GET MOTHER ADDRESS           31000021
         LA    PARREG1,RBEXSAVE         GET ABDUMP'S PAR LIST ADDRESS   31100021
         MVI   0(1),2                   ID=2 MEANS MATRIARCHY           31200021
         BAL   LINKREG,SNAP             ABDUMP MATRIARCHY               31300021
         B     ABD19                    ABDUMP NEXT TASK                31400021
ABRECURS EQU   *                                                  20472 31500021
         L     ARBREG,RBLINK-1          GET ADDR OF PREV RB       20472 31600021
         B     CHECKAB                  GO TO CHECK IT            20472 31700021
CHEKNEXT EQU   *                                                  20472 31800021
         L     ARBREG,RBLINK2-1         GET ADDR OF NEXT RB       20472 31900021
CHECKAB  EQU   *                                                  20472 32000021
         CLC   NMABEND,RBEXSAV2+40      Q. PREV ABEND'S SVRB?     20472 32100021
         BNE   CHEKNEXT                 NO. LOOK FARTHER BACK     20472 32200021
         MVC   RBEXSAVE+16(23),RBEXSAV2+16 SET UP FOR DEQ         20472 32300021
ABD21    EQU   *                        DELETE ABDUMP'S NON-TRANS. MOD. 32400021
*                                                                       32500021
*  DEQ SYSABEND DATA SET                                                32600021
*                                                                       32700021
         LA    PARREG1,RBEXSAVE+16      LOAD ADDR OF ABEND SVRB ESA     32800021
         MVC   0(4,PARREG1),ENQFLAGS    SET UP SIZE, OPTION FLAGS ETC   32900021
         DEQ   (,,,STEP),RET=HAVE,MF=(E,(1))                      20472 33000021
         LA    PARREG0,LOADNAME         GET NAME OF THE MODULE          33100021
*                                                                       33200021
         DELETE  EPLOC=(0)                                              33300021
RECRSOFF EQU   *                                                  20472 33400021
         MVI   TCBRECDE,X'00'          RESET DUMP RECURS IND.     20472 33500021
*                                                                       33600021
         LA    XCTLREG,NMLOAD11         GET ADDR OF ABEND11 NAME  21472 33700021
         LA    15,RBEXSAVE              ADDR OF PAR. LIST AREA    20472 33800021
         L     PARREG0,THISMOD          FLAG XCTL FOR TRACE       20472 33900021
         L     PARREG1,4(,XCTLREG)      SHOW NEXT MODULE          21472 34000021
         XCTL  EPLOC=(XCTLREG),SF=(E,(15)) GO TO NEXT LOAD        21472 34100021
*                                                                       34200021
         EJECT                                                          34300021
*********************************************************************** 34400021
*********************   TASK SELECT FOR ABDUMP   ********************** 34500021
*********************************************************************** 34600021
*                                                                       34700021
SELECT   LR    ATCBREG,SELREG          SAVE GIVEN TCB ADDR              34800021
         L     SELREG,TCBLTCP          GET DAUGHTER                     34900021
SELECT1  LTR   SELREG,SELREG           DOES DAUGHTER EXIST              35000021
         BC    7,SELECT3               YES,BRANCH                       35100021
         L     SELREG,TCBNTCP          NO,GET SISTER                    35200021
         CR    ATCBREG,SAVEREG         IS SCAN COMPLETE                 35300021
         BE    4(,LINKREG)             YES. LAST TIME RETURN            35400021
         L     ATCBREG,TCBOTCP         NO,GET MOTHER                    35500021
         B     SELECT1                                                  35600021
SELECT3  LR    ATCBREG,SELREG          MODIFY ATCBREG                   35700021
         BCR   15,LINKREG              RETURN                           35800021
         EJECT                                                          35900021
*********************************************************************** 36000021
************************ SNAP   ROUTINE   ***************************** 36100021
*********************************************************************** 36200021
*                                                                       36300021
SNAP     MVI   2(1),X'62'              SET OPTION FLAGS                 36400021
         MVI   3(1),X'80'              SET OPTION FLAGS                 36500021
         ST    ATCBREG,8(0,1)          SPECIFY TCB ADDR                 36600021
SNAP1    ST    DCBREG,4(0,1)           SPECIFY DCBADDR                  36700021
         CLI   7(WORKREG),C'P'         IS SYSUDUMP BEING USED           36800021
         BNE   SNAP2                   NO                               36900021
         NI    2(PARREG1),X'E7'        RESET NUCLEUS AND TRACE          37000021
*                                      TABLE SNAP FLAGS                 37100021
SNAP2    DS    0H                                                       37200021
         SNAP  MF=(E,(1))              SNAP                             37300021
*                                                                       37400021
         BCR   15,LINKREG              RETURN TO MAIN LINE              37500021
         EJECT                                                          37600021
* THE FOLLOWING ARE CONSTANTS USED IN THIS LOAD OF ABEND.               37700021
*                                                                       37800021
CONS32   DC    H'32'                                                    37900021
CONS4    DC    F'4'                                                     38000021
LOADNAME DC    C'IGC0A05A'             CSECT NAME ABDUMP LOAD MODULE    38100021
NMLOAD11 DC    CL8'IGC0B01C'                                            38200021
THISMOD  DC    C'901C'                 FLAG FOR XCTL              20472 38300021
CONS253  DC    X'FD000000'                                              38400021
CONS254  DC    X'FE000000'                                              38500021
CONS255  DC    X'FF000000'                                              38600021
ENQFLAGS DC    X'FF030000'                    NAME FOR EN@ OF SYSABEND  38700021
MAJ      DC    C'SYSIEA01'              MAJOR NAME FOR EN@ OF SYSABEND  38800021
         DC    C'IEA'                   MINOR NAME FOR EN@ OF SYSABEND  38900021
NMABEND  DC    C'ABEND9'                TO IDENTIFY ABEND SVRB   A41372 39000021
         EJECT                                                          39100021
*                                                                       39200021
*                                                                       39300021
*             THE FOLLOWING CODE IS ZAP SPACE FOR MAINTANENCE USE       39400021
*                                                                       39500021
*                                                                       39600021
*                                                                       39700021
         DC    H'0'                                                     39800021
         DC    H'0'                                                     39900021
         DC    H'0'                                                     40000021
         DC    H'0'                                                     40100021
         DC    H'0'                                                     40200021
         DC    H'0'                                                     40300021
         DC    H'0'                                                     40400021
         DC    H'0'                                                     40500021
         DC    H'0'                                                     40600021
         DC    H'0'                                                     40700021
         DC    H'0'                                                     40800021
         DC    H'0'                                                     40900021
         DC    H'0'                                                     41000021
         DC    H'0'                                                     41100021
         DC    H'0'                                                     41200021
         DC    H'0'                                                     41300021
         DC    H'0'                                                     41400021
         DC    H'0'                                                     41500021
         DC    H'0'                                                     41600021
         DC    H'0'                                                     41700021
         DC    H'0'                                                     41800021
         DC    H'0'                                                     41900021
         DC    H'0'                                                     42000021
         DC    H'0'                                                     42100021
         DC    H'0'                                                     42200021
         DC    H'0'                                                     42300021
         DC    H'0'                                                     42400021
         DC    H'0'                                                     42500021
         DC    H'0'                                                     42600021
         DC    H'0'                                                     42700021
         EJECT                                                          42800021
         IHBABCTL                                                       42900021
DCBTIO   EQU   40                 OFFSET IN DCB TO TIOT INDEX VALUE     43000021
DUBLWORD EQU   X'07'                   MASK TO TEST FOR DOUBLE WORD     43100021
         EJECT                                                          43120021
****                                                               **** 43140021
*        FLOWCHART STATEMENTS FOR ABEND 9                             * 43160021
****                                                               **** 43180021
         SPACE 1                                                        43184021
*/*IEAQTM09: CHART */                                                   43200021
*/*IEAQTM09: E ABEND9 */                                                43300021
*/*IGC0901C: P GET ADDR OF SEC CVT & FLAG ENTRY TO THIS MOD */          43400021
*/* D (N,,Y,ABRECURS) IS RECURSION DUE TO ABDUMP */                     43500021
*/* D (N,,Y,RECRSOFF) PREV DUMP */                                      43600021
*/* D (Y,,N,RECRSOFF) IS DUMP TO BE TAKEN */                            43700021
*/*DUMPIT: P SET ABEND VALID RECURSION FLAG ACROSS ABDUMP */            43800021
*/* S LOAD:RESIDENT LOAD OF ABDUMP */                                   43900021
*/* S ENQ:ON SYSABEND DATA SET */                                       44100021
*/* P GET JOBSTEP TCB */                                                44200021
*/* D (N,,Y,ABD21) IS PREV DUMP BIT ON */                               44300021
*/* D (N,,Y,TESTSUBS) THIS TASK DUMPED BEFORE */                        44500021
*/* D (Y,,N,NOTRACE) GTF ACTIVE AND FORMATTING */                       44600021
*/* D (N,,Y,NOTRACE) SYSUDUMP BEING USED */                             44700021
*/* D (N,,Y,NOTRACE) IS GTF OR SYSABEND ALREADY FROZEN */               44800021
*/* S  HOOK: FREEZE GTF FOR SYSABEND */                                 44820021
*/* P FLAG TCB FROZEN, REQUEST TRACE TABLE */                           44840021
*/*NOTRACE:  S SNAP1:DUMP CURR TASK */                                  44900021
*/* P SET 'TASK DUMPED' BIT IN CURRENT TCB */                           45000021
*/*TESTSUBS: D (Y,,N,ABD17) CURRENT TCB HAVE SUBTASKS */                45100021
*/* P SET INPUT TCB = CURRENT TCB */                                    45200021
*/*ABD13: S (FND,,NONE,ABD17) SELECT: SELECT A SUBTASK TO DUMP */       45300021
*/*ABD15: D (N,,Y,ABD13) HAS SELECTED TSK BEEN DUMPED */                45400021
*/* S SNAP:SUBTASK, ID=1 */                                             45600021
*/* P (,ABD13) SET 'TASK DUMPED' BIT IN TCB */                          45700021
*/*ABD17: P SELECT CURRENT TCB AS THE TCB TO DUMP */                    45800021
*/*ABD19: D (N,,Y,ABD21) TCB TO DUMP = JOBSTEP */                       45900021
*/* P SET TCB TO DUMP = ITS MOTHER */                                   46000021
*/* S (,ABD19) SNAP:A HIGHER TASK, ID=2 */                              46100021
*/*ABRECURS: P (,CHECKAB) GET PREVIOUS RB */                            46200021
*/*CHEKNEXT: P GET PREVIOUS RB */                                       46300021
*/*CHECKAB: D (Y,,N,CHEKNEXT) PREV ABEND RB */                          46400021
*/*ABD21: S DEQ:SYSABEND DATA SET */                                    46700021
*/* S DELETE:RESIDENT LOAD OF ABDUMP */                                 46900021
*/*RECRSOFF: P RESET REC BITS, GET TRACE OF THIS & NXT MODS */          47000021
*/* R XCTL */                                                           47100021
*/*SELECT: E ENTRY */                                                   47200021
*/* P SET OUTPUT TCB = INPUT TCB */                                     47300021
*/* P SET SELECTED TCB = DAUGHTER OF INPUT TCB */                       47400021
*/*SELECT1: D (NO,,YES,SELECT3) SELECTED TCB EXIST */                   47500021
*/* P SET SELECTED TCB = SISTER OF OUTPUT TCB */                        47600021
*/* D (YES,,NO,%GETMOM) OUTPUT TCB = INPUT TCB */                       47700021
*/* R RETURN - NONE */                                                  47800021
*/*%GETMOM: P (,SELECT1) SET OUTPUT TCB = ITS MOTHER */                 47900021
*/*SELECT3: P SET OUTPUT TCB = SELECTED TCB */                          47920021
*/* R RETURN - FND */                                                   47940021
*/*SNAP: E ENTRY */                                                     48000021
*/* D (Y,,N,SNAP2) IS THIS SYSUDUMP */                                  48300021
*/*          P RESET NUCLEUS & TRACE */                                 48400021
*/*SNAP2: S SNAP:ISSUE SVC 51 */                                        48500021
*/* R RETURN */                                                         48600021
*/*IEAQTM09: END */                                                     48700021
         END                                                            48800021
