         TITLE 'IEAQTM0B / ABEND11 - CLOSE DATA SETS / IGC0B01C '       00100000
IGC0B01C START                                                          00200000
*                                                                       00300000
*                                                                       00400000
*                                                                       00500000
*   THE FOLLOWING CODE IS THE ELEVENTH LOAD OF ABEND                    00600000
*                                                                       00700000
* ROUTINE NAME- ABEND11                                                 00800000
*                                                                       00900000
*             1. TURNS ON GTF FOR EACH TASK IN THE ABENDING             00920021
*                TREE WHICH HAD PREVIOUSLY TURNED GTF OFF.              00940021
*                                                                       00960021
*             2. ERASES ALL COMPLETE SUBTASKS OF THE TASK WHICH IS      01000021
*                CURRENTLY BEING ABNORMALLY TERMINATED.                 01100000
*                                                                       01200000
*             3. CLOSES ALL DATA SETS WHICH HAVE BEEN LEFT OPEN BY THE  01300021
*                TASK WHICH IS CURRENTLY BEING ABNORMALLY TERMINATED.   01400000
*                THIS INCLUDES THE SYSABEND DATA SET IF IT HAS BEEN     01500000
*                OPENED AND IF THE JOB STEP TASK IS BEING TERMINATED.   01600000
*                IF AN OLTEP TASK, SVC 59 IS ISSUED FOR                 01630021
*                FINAL CLEAN-UP IN CASE THE STAE EXIT FAILED.           01660021
*                                                                       01700000
*             4. INVOKES THE 'FORCE CLOSE' FUNCTION EACH TIME           01740021
*                CLOSE FAILS TO DEQUEUE A DEB.                          01780021
*                                                                       01820021
*             5. FREES PROGRAM INTERRUPT ELEMENT (PIE).                 01860021
*                                                                       01900000
*             6. SELECTS AND SETS UP FOR ABNORMAL TERMINATION VIA       02000021
*                RE-DISPATCHING TO THIS LOAD OF ABEND ALL INCOMPLETE    02100000
*                SUBTASKS OF THE TASK FOR WHICH ABEND WAS INVOKED       02200000
*                ORIGINALLY. THUS FUNCTIONS OF ERASING, CLOSING,        02300021
*                AND FREEING THE PIE ARE ALSO PERFORMED FOR THESE       02400021
*                SUBTASKS.                                              02420021
*                                                                       02500000
*             7. IF THIS LOAD OF ABEND IS REENTERED FOR A GIVEN TASK:   02550021
*                A. AS THE RESULT OF A FAILURE IN A CLOSE OPERATION,    02600021
*                   AND IF THE DEB FOR THE DATA SET HAS NOT BEEN        02650021
*                   DEQUEUED, THE 'FORCE CLOSE' FUNCTIONED IS INVOKED   02700021
*                   TO PERFORM CLEANUP PROCESSING. UPON RETURN FROM     02750021
*                   'FORCE CLOSE', THE DEB IS REMOVED FROM THE DEB      02800021
*                   QUEUE, FREED, AND ADDITIONAL CLOSES ARE ISSUED      02850021
*                   FOR THE REMAINING OPEN DATA SETS. IF THE DEB        02900021
*                   HAS ALREADY BEEN DEQUEUED, THE 'FORCE CLOSE'        02950021
*                   FUNCTION IS BYPASSED.                               03000021
*                                                                       03050021
*                B. AS THE RESULT OF A FAILURE IN THE 'FORCE CLOSE'     03100021
*                   FUNCTION, THE DEB IS DEQUEUED AND CLOSE PROCESSING  03150021
*                   CONTINUES ON THE REMAINING OPEN DATA SETS.          03200021
*                                                                       03300000
* ENTRY POINT NAMES - 1. IGC0B01C                                       03400000
*                                                                       03500000
*                        A. ENTRY FROM NINTH LOAD OF ABEND FOR          03600000
*                           NORMAL FIRST-TIME ENTRY.                    03700000
*                                                                       03800000
*                        B. ENTRY FROM THIRD LOAD OF ABEND IF           03900000
*                           RECURSION DUE TO A CLOSE FAILURE HAS        04000000
*                           OCCURRED.                                   04100000
*                                                                       04200000
*                        C. ENTRY FROM STEAL CORE LOAD (ABEND12)  21472 04300000
*                           IF CORE WAS NOT AVAILABLE TO CLOSE    21472 04400000
*                           AT LAST ENTRY TO THIS MODULE.         21472 04500000
*                                                                       04600000
*                     2. ENTRY2 (INTERNAL USAGE ONLY).                  04700000
*                                                                       04800000
*                        A. ENTRY FROM THIS LOAD OF ABEND WHEN A        04900000
*                           SELECTED SUBTASK HAS BEEN RE-DISPATCHED     05000000
*                           FOR ABNORMAL TERMINATION.                   05100000
*                                                                       05200000
* CONTAINED IN MODULE - IEAQTM0B.                                       05300000
*                                                                       05400000
* ATTRIBUTES - TYPE 4 SVC, REENTRANT, SUPERVISOR STATE,                 05500000
*              PARTIALLY ENABLED.                                       05600000
*                                                                       05700000
* APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                05800000
*                                                                       05900000
* SVC USAGE - FREEMAIN,CLOSE,XCTL                                       06200000
*                                                                       06300000
* INPUT - NONE.                                                         06400000
*                                                                       06500000
* OUTPUT - NONE.                                                        06600000
*                                                                       06700000
* ENTRY POINTS - 1. IGC0B01C AND ENTRY2                                 06800000
*                                                                       06900000
*                   A. THE CURRENT PSW MUST BE                          07000000
*                                                                       07100000
*                      (1) DISABLED FOR ALL MASKABLE INTERRUPTS         07200000
*                          EXCEPT MACHINE CHECK.                        07300000
*                                                                       07400000
*                      (2) UNDER SUPERVISOR PROTECTION KEY.             07500000
*                                                                       07600000
*                      (3) IN SUPERVISOR MODE.                          07700000
*                                                                       07800000
*                   B. REGISTERS                                        07900000
*                                                                       08000000
*                      (1) REGISTER 3 MUST CONTAIN THE ADDRESS          08100000
*                          OF THE CVT.                                  08200000
*                                                                       08300000
*                      (2) REGISTER 4 MUST CONTAIN THE ADDRESS          08400000
*                          OF THE CURRENT TCB.                          08500000
*                                                                       08600000
*                      (3) REGISTER 5 MUST CONTAIN THE ADDRESS          08700000
*                          OF THE CURRENT RB.                           08800000
*                                                                       08900000
* EXIT POINTS - 1. BRANCH TO DISPATCHER IN ORDER TO DISPATCH A          09000000
*                  SELECTED SUBTASK FOR ENTRY TO THIS LOAD OF ABEND.    09100000
*                                                                       09200000
*               2. XCTL TO THE THIRTEENTH LOAD OF ABEND TO CONTINUE     09300000
*                  THE ABNORMAL TERMINATION OF A TREE OF TASKS.         09400000
*                                                                       09500000
*               3. IN BOTH CASES THE CURRENT PSW IS                     09600000
*                                                                       09700000
*                  A. DISABLED FOR ALL MASKABLE INTERRUPTS              09800000
*                     EXCEPT MACHINE CHECK.                             09900000
*                                                                       10000000
*                  B. UNDER SUPERVISOR PROTECTION KEY.                  10100000
*                                                                       10200000
*                  C. IN SUPERVISOR MODE.                               10300000
*                                                                       10400000
*               4. REGISTERS                                            10500000
*                                                                       10600000
*                  A. REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.       10700000
*                                                                       10800000
*                  B. REGISTER 4 CONTAINS THE ADDRESS OF                10900000
*                     THE CURRENT TCB.                                  11000000
*                                                                       11100000
*                  C. REGISTER 5 CONTAINS THE ADDRESS OF                11200000
*                     THE CURRENT RB.                                   11300000
*                                                                       11400000
* ERROR EXIT POINTS - NONE.                                             11500000
*                                                                       11600000
* NOTES -                                                               22000000
*                                                                       22100000
*         1. THIS CODE IS NOT CHARACTER CODE DEPENDENT.                 22200021
*                                                                       22220021
*         2. THIS MODULE CONTAINS TWO TASK SELECT ROUTINES.             22240021
*            SELECTR IS USED SIMILARLY TO TASK SELECT ROUTINES          22260021
*            IN PREVIOUS LOADS OF ABEND. TASKSEL3 PROCEEDES FROM        22280021
*            LOWEST TASK IN THE TREE TO THE HIGHEST. AS PART OF         22284021
*            TASKSEL3, COMPLETE SUBTASKS ARE ERASED AND ARE             22288021
*            TRANSPARENT TO THE CALLER.                                 22292021
*                                                                       22296021
*         3. AT EXIT FROM THIS MODULE, ABEND'S SVRB IS RUNNING          22296821
*            UNDER THE TOP TASK IN THE ABENDING TREE.                   22297621
*                                                                       22300000
         EJECT                                                          22400000
GTFSECT  DSECT                          TO GENERATE GTF EQUATES   21014 22420021
         HOOK  EID=IHLMABON                                       21014 22440021
         EJECT                                                          22460021
*                                                                       22500000
* THE FOLLOWING ARE REGISTER ASSIGNMENTS FOR THIS MODULE.               22600000
*                                                                       22700000
PARREG0  EQU   0                        PARAMETER REG.                  22800000
PARREG1  EQU   1                        PARAMETER REG.                  22900000
LISTPTR  EQU   1                        ADDR OF ECB/LIST      CI A45983 22950021
ARBREG   EQU   2                        ADDRESSES ALTERNATE RB          23000000
LINKREG  EQU   2                        LINK REGISTER                   23100000
CVTREG2  EQU   2                        SCVT ADDRESS                    23200000
CVTREG   EQU   3                        CVTDSECT REG. USED THRU-OUT     23300000
TCBREG   EQU   4                        TCBDSECT REG. CURRENT TCB       23400000
RBREG    EQU   5                        RBSECT REG. CURRENT RB          23500000
ENTRYREG EQU   6                        ENTRY POINT OF RESID ROUTINES   23600000
ECBREG   EQU   6                        ADDR OF ECB           CI A45983 23650021
SELREG   EQU   7                        1SED IN TASK SELECTION          23700000
ERASEREG EQU   7                        ADDR OF TCB TO BE ERASED        23800000
DEBREG   EQU   7                        DEB REG                         23900000
BASEREG  EQU   9                        ABEND BASEREG - USED THRU-OUT   24000000
ATCBREG  EQU   10                       ADDRESSES ALTERNATE TCB         24100000
XCTLREG  EQU   10                       EPLOC FOR XCTL            M1132 24200000
SWITCH   EQU   11                       POINTS TO TASK SWITCHING RTN    24300000
WKREG    EQU   11                       WORK REGISTER                   24400000
SAVETCB  EQU   12                       SAVE ADDR OF CURRENT TCB        24500000
WORKREG  EQU   12                       TEMPORARY WORK REGISTER         24600000
RETREG   EQU   14                       RETURN REG FROM ERASE ROUTINE   24700000
SWRET    EQU   14                       HOLDS RTN ADDR FROM TASK SWITCH 24800000
R14      EQU   14                  ECB PSEUDO-POST WORK REG    @SA70451 24830021
R15      EQU   15                  ECB PSEUDO-POST WORK REG    @SA70451 24860021
NEXT     EQU   15                       TASK SELECTION REGISTER         24900000
SCVTREG  EQU   15                       ADDR OF SECONDARY CVT           25000000
RTNREG   EQU   15                       RET PARMREG FROM GETMAIN  21472 25100000
         SPACE 2                                                        25200000
         EJECT                                                          25300000
IGC0B01C CSECT                                                          25400000
ABEND11   BALR  BASEREG,0                ESTABLISH ADDRESSABILITY       25500000
         USING *,BASEREG         9                                      25600000
         USING TCBSECT,TCBREG    4                                      25700000
         USING TCBDSECT,ATCBREG  10                                     25800000
         USING RBSECT,RBREG      5                                      25900000
         USING RBSECT2,ARBREG    2                                      26000000
         USING CVTSECT,CVTREG    3                                      26100000
         USING SCVTSECT,SCVTREG  F                                      26200000
         MVI   RBEXSAVE+45,C'B'         FLAG SVRB AS THIS MODULE  21472 26300000
         L     SCVTREG,CVTABEND         GET ADDR OF SECONDARY CVT       26400000
*                                                                       26500000
* THE FOLLOWING CODE CHECKS FOR RECURSION OR RE-ENTRY TO THIS LOAD OF   26600000
* ABEND DUE TO A PROGRAM CHECK IN CLOSE.                                26700021
*                                                                       26800000
         CLI   TCBRECDE,TCBSTRET        Q. RETURN FROM STEAL?     21472 26900000
         BE    ANYDEBS                  YES. CORE AVAILABLE NOW   21472 27000000
         CLI   TCBRECDE,TCBOLT59        RECURSION ACCROSS      PD OLTEP 27030021
         BE    ANYDEBS                  OLTEP SVC 59           PD OLTEP 27060021
         CLI   TCBRECDE,TCBCLOSE        HAS CLOSE BEEN ISSUED           27100000
         BE    CLOSEREC                 YES-TEST IF          AD  A33565 27120021
*                                       DEB DEQUEUED         AD  A33565 27140021
         CLI   TCBRECDE,TCBCLOSF        HAS GRAPHICS FORCE PD FORCE CLS 27160021
*                                       CLOSE BEEN ENTERED PD FORCE CLS 27166021
         BE    GENFCRTN                 YES-GO TO GENERAL  PD FORCE CLS 27172021
*                                       FORCE CLOSE CALL   PD FORCE CLS 27178021
         CLI   TCBRECDE,TCBFCREC        HAS GENERAL FORCE  PD FORCE CLS 27184021
*                                       CLOSE BEEN ENTERED PD FORCE CLS 27190021
         BE    FCLOSREC                 YES-GO DEQ THE DEB   AD  A33565 27200021
         B     GTFCHECK                 NO-HANDLE FIRST      AD  A33565 27220021
*                                       TIME ENTRY           AD  A33565 27240021
*********************************************************************** 27300000
********************   CLOSE RECURSION PROCESSING   ******************* 27400000
*********************************************************************** 27500000
*                                                                       27600000
*                                                                       27700000
* THE FOLLOWING CODE RECOVERS THE ABNORMAL TERMINATION PROCESS IF AN    27800000
* ERROR OCCURRED DURING CLOSE. THE PREVIOUS ABEND SVRB IS LOCATED       27900000
* AND THE DEB ADDRESS IS EXTRACTED FROM THAT SVRB.                      28000000
*                                                                       28100000
* NOTE- IN RELEASE 21, THE PURGE OF INTERVENING TRANSIENT SVRBS         28200000
*       WAS ELIMINATED TO ALLOW MORE DEBUGGING INFORMATION TO BE        28300000
*       IN A DUMP IF A SYSTEM PROBLEM OCCURED LATER DURING ABEND        28400000
*       PROCESSING.                                                     28500000
*                                                                       28600000
CLOSEREC EQU   *                                                        28700000
         LR    ARBREG,RBREG             GET ABEND SVRB ADDRESS          28800000
NEXTRB   EQU   *                                                  21472 28900000
         L     ARBREG,RBLINK2-1         GET NEXT RB ON RB QUEUE   21472 29000000
         TM    RBSTAB2,RBFTP            IS THIS AN SVRB?                29100000
         BC    14,NEXTRB                NO, GO GET NEXT RB ON RB QUEUE  29200000
         CLC   RBEXSAV2+40(6),NMABEND   Q.PREVIOUS ABEND SVRB?   A41372 29300000
         BNE   NEXTRB                   NO. LOOK BACK ONE MORE    21472 29400000
         MVC   RBEXSAVE(4),RBEXSAV2     MOVE OLD DEB FOR CHECK    21472 29500000
         B     DEBFREED                 GO SEE IF DEB HAS BEEN FREED    29600000
         EJECT                                                          29620021
*****************************************************************       29624021
************************   GTF INTERFACE   **********************       29628021
*****************************************************************       29632021
*                                                                       29636021
GTFCHECK EQU   *                                                  21014 29636821
         LR    ATCBREG,TCBREG           START TO READY FOR SELCT  21014 29637621
         TM    TCBFLGSP,TCBFT           Q. THIS TASK TOP IN TREE  21014 29638421
         BO    PREPGTF                  YES. CAN SELECT NOW       21014 29639221
         L     ATCBREG,TCBJSTCB         JS TASK MUST BE TOP       21014 29639321
PREPGTF  EQU   *                                                  21014 29639421
         LCR   ATCBREG,ATCBREG          READY FOR FIRST TASK SEL  21014 29639521
CHKGTF   EQU   *                                                  21014 29639621
         BAL   LINKREG,SELECTR          SELECT A TASK FOR CHECK   21014 29639721
         B     SKIPGTF                  END SELECT. HOP SVRB NOW  21012 29639821
*                                       TASK SELECTED. FALL THRU  21014 29639921
         TM    TCBFLGSP,TCBGTOFM        Q. WAS GTF TRACE STOPPED  21014 29640021
         BNO   CHKGTF                   NO. BYPASS RESUMING IT.   21014 29660021
         HOOK  EID=IHLMABON             TURN TRACE BACK ON        21014 29680021
ALL      EQU   X'FF'                    MASK FOR FLAGS            21014 29684021
         NI    TCBFLGSP,ALL-TCBGTOFM    RESET TRACE SUSPNDED BIT  21014 29688021
         B     CHKGTF                   CHECK NEXT TASK           21014 29688821
SKIPGTF  EQU   *                                                  21014 29692021
         EJECT                                                          29693021
*************************************************************           29694021
*************   PURGE OUTSTANDING ECB WAITS   ***************           29695021
*************************************************************           29696021
*                                                                       29697021
* THE FOLLOWING ROUTINE PURGES THE ECBS THAT ARE STILL BEING            29698021
* AWAITED BY TASKS IN THE ABENDING TREE.  THIS IS DONE BY               29699021
* SETTING THE COMPLETION FLAG IN THESE ECBS AND HAS THE                 29700021
* EFFECT OF CAUSING SUBSEQUENT POSTS AGAINST THEM TO BE                 29701021
* TREATED AS NO-OPS.  THIS PURGE IS PERFORMED SO AS TO AVOID            29702021
* PROBLEMS THAT COULD RESULT WHEN A POST IS ISSUED AGAINST              29703021
* ONE OF THESE ECBS AND THE CONTENTS OF REGISTER 1 AT THE               29704021
* TIME THE WAIT WAS ISSUED IS NO LONGER AVAILABLE.                      29705021
*                                                                       29706021
         LR    ATCBREG,TCBREG           GET CURRENT TCB       CI A45983 29707021
         TM    TCBFLGSP,TCBFT           Q. TOP ABENDING TASK  CI A45983 29708021
         BO    FIRSTSEL                 YES, BRANCH           CI A45983 29709021
         L     ATCBREG,TCBJSTCB         JOBSTEP TASK IS TOP   CI A45983 29710021
FIRSTSEL EQU   *                                              CI A45983 29711021
         LCR   ATCBREG,ATCBREG          SET FOR 1ST SELECT    CI A45983 29712021
NEXTSEL  EQU   *                                              CI A45983 29713021
         BAL   LINKREG,SELECTR          SELECT A TASK IN TREE CI A45983 29714021
         B     ENDECBPG                 RET HERE IF NO MORE   CI A45983 29715021
*                                       RET HERE IF TCB FOUND CI A45983 29716021
         LA    R14,NXTRB           GOTO IF RB NOT WAITING      @SA70451 29716521
         L     RBREG,TCBRBPP            GET TOP RB OF SEL TCB CI A45983 29717021
         TM    RBSTAB,RBWAITP           Q. WAITING ON ECB     CI A45983 29718021
         BCR   8,R14               NO--BRANCH                  @SA70451 29719021
         L     LISTPTR,TCBGRSP+4        GET ADDR OF ECB/LIST  CI A45983 29720021
PURGEECB EQU   *                                              CI A45983 29721021
         LA    RBREG,0(,RBREG)     CLEAR WAIT COUNT            @SA70451 29721521
         NI    RBSTAB,X'FF'-RBWAITP     RESET RB WAITING FLAG CI A45983 29722021
         LTR   ECBREG,LISTPTR           Q. WAITING ON LIST    CI A45983 29723021
         BP    CHKECB                   NO, BRANCH-SINGLE ECB CI A45983 29724021
CHKLIST  EQU   *                                              CI A45983 29725021
         LCR   WKREG,LISTPTR            GET ADDR OF LIST      CI A45983 29726021
         BAL   LINKREG,VALCHECK         VALIDITY CHECK ADDR   CI A45983 29727021
*                                       RETURN HERE IF VALID  CI A45983 29728021
         L     ECBREG,0(,WKREG)         GET ADDR OF ECB       CI A45983 29729021
         LA    WKREG,4(,WKREG)          BUMP PTR TO NEXT ECB  CI A45983 29730021
         LCR   LISTPTR,WKREG            SAVE FOR NEXT PASS    CI A45983 29731021
CHKECB   EQU   *                                              CI A45983 29732021
         LR    WKREG,ECBREG             GET ECB ADDR FOR CHK  CI A45983 29733021
         BAL   LINKREG,VALCHECK         VALIDITY CHECK ADDR   CI A45983 29734021
*                                       RETURN HERE IF VALID  CI A45983 29735021
         L     R15,0(,ECBREG)      GET ECB ADDRESS             @SA70451 29736021
         LTR   R15,R15             IF HIGH ORDER BIT NOT ON    @SA70451 29736321
         BCR   11,R14              THEN ALREADY POSTED         @SA70451 29736621
         LA    R15,0(,R15)         CLEAR POST BIT; GET RB ADDR @SA70451 29736921
         CR    RBREG,R15           IF NOT THIS RB THEN         @SA70451 29737221
         BCR   7,R14               DONOT PSEUDO-POST           @SA70451 29737521
         OI    0(ECBREG),POSTFLG        MARK ECB AS POSTED    CI A45983 29738021
         LTR   LISTPTR,LISTPTR          Q. PROCESSING A LIST  CI A45983 29739021
         BCR   2,R14               NO-BRANCH                   @SA70451 29740021
         LTR   ECBREG,ECBREG            Q. END OF LIST        CI A45983 29741021
         BP    CHKLIST                  NO, BRANCH            CI A45983 29742021
NXTRB    EQU   *                                              CI A45983 29743021
         TM    RBSTAB+1,RBTCBNXT        Q. LAST RB ON CHAIN   CI A45983 29744021
         BO    NEXTSEL                  YES, BRANCH           CI A45983 29745021
         LR    ARBREG,RBREG             SAVE PREVIOUS RB      CI A45983 29746021
         L     RBREG,RBLINK-1           GET NEXT RB           CI A45983 29747021
         TM    RBSTAB,RBWAITP           Q. WAITING ON ECB     CI A45983 29748021
         BCR   8,R14               NO--BRANCH                  @SA70451 29749021
         L     LISTPTR,RBGRSAV2+4       GET ADDR OF ECB/LIST  CI A45983 29750021
         B     PURGEECB                 BRANCH TO PURGE IT    CI A45983 29751021
         SPACE 3                                              CI A45983 29752021
VALCHECK EQU   *                                              CI A45983 29753021
         EX    WKREG,WORDTEST           Q. ADDR ON FWORD BDY  CI A45983 29754021
         BCR   7,R14               NO--BRANCH                  @SA70451 29755021
         LA    WKREG,0(,WKREG)          CLEAR TOP BYTE        CI A45983 29756021
         CL    WKREG,CVTMZ00            Q. ADDR IN MACHINE    CI A45983 29757021
         BCR   11,R14              NO--BRANCH                  @SA70451 29758021
         TM    RBOPSW+1,KEYMASK         Q. RBOPSW KEY = 0     CI A45983 29759021
         BCR   8,LINKREG                YES, RETURN           CI A45983 29760021
         LR    WORKREG,WKREG                                  CI A45983 29761021
         IC    WORKREG,KEYTEST+1        CLEAR BITS 24-31      CI A45983 29762021
         ISK   WORKREG,WORKREG          GET STORAGE KEY       CI A45983 29763021
         EX    WORKREG,KEYTEST          Q. KEY = TCB KEY      CI A45983 29764021
         BCR   8,LINKREG                YES, RETURN           CI A45983 29765021
         L     WORKREG,TCBJSCBP-1       GET ADDR OF JSCB      CI A45983 29766021
         USING IEZJSCB,WORKREG                                CI A45983 29767021
         L     WORKREG,JSCBCSCB         GET ADDR OF CSCB      CI A45983 29768021
         USING CSCBSECT,WORKREG                               CI A45983 29769021
         L     WORKREG,CHECBP           GET ADDR OF COMM ECB  CI A45983 29770021
         DROP  WORKREG                                        CI A45983 29771021
         CR    WKREG,WORKREG            Q. PASSED ADDR =      CI A45983 29772021
*                                          COMMUNICATION ECB  CI A45983 29773021
         BCR   7,R14               NO--BRANCH                  @SA70451 29774021
         BR    LINKREG                  RETURN                CI A45983 29775021
         SPACE 1                                                        29776021
*                                                             CI A45983 29777021
* THE FOLLOWING INSTRUCTIONS ARE REACHED VIA EXECUTE          CI A45983 29778021
*                                                             CI A45983 29779021
WORDTEST TM    WORDBDY,X'00'            TEST FOR WORD BDY     CI A45983 29780021
KEYTEST  CLI   TCBPKFP,X'00'            TEST FOR KEY MATCH    CI A45983 29781021
         SPACE 3                                              CI A45983 29782021
ENDECBPG EQU   *                                              CI A45983 29783021
         L     RBREG,TCBRBP             RESTORE PTR TO        CI A45983 29784021
*                                       ABEND'S SVRB          CI A45983 29785021
         EJECT                                                          29786021
*********************************************************************** 29800000
************************   INITIAL TASK SELECTION   ******************* 29900000
*********************************************************************** 30000000
*                                                                       30100000
* THE FOLLOWING CODE SELECTS A SUBTASK FOR ABNORMAL TERMINATION. THE    30200000
* TASK SELECTED IS THE LOWEST, INCOMPLETE SUBTASK, IF ANY, IN THE TREE  30300000
* FORMED BY THE CURRENT TASK AS THE TOP TASK IN THE TREE.               30400000
*                                                                       30500000
INITSEL  EQU   *                                                        30600000
         LR    ATCBREG,TCBREG           LOAD ADDR OF CURRENT TCB        30700000
TESTT    TM    TCBFLGSP,TCBFT           IS CURRENT TASK THE TOP TASK    30800000
         BC    7,FINDLOW                YES, BR TO FIND LOWEST SUBTASK  30900000
         L     ATCBREG,TCBOTCP          LOAD MOTHER FIELD OF SELECT TCB 31000000
         BC    15,TESTT                 BR TO TEST FOR TOP TASK         31100000
FINDLOW  EQU   *                                                        31200000
         LR    SELREG,ATCBREG           INITIALIZE SELECT REGISTER      31300000
NXTLTC   LR    ATCBREG,SELREG           SAVE ADDR OF PRESENT SELECT TCB 31400000
         L     SELREG,TCBLTCP           LOAD DAUGHTER FLD OF SELECT TCB 31500000
         LTR   SELREG,SELREG            IS DAUGHTER FIELD ZERO          31600000
         BC    7,NXTLTC                 IF NOT, BR TO CHK NEXT DAUGHTER 31700000
         BAL   LINKREG,SELECT22         BR TO TASK SELECT TO CHECK      31800000
*                                       WHETHER SELECTED TASK IS COMPLE 31900000
         CR    TCBREG,ATCBREG           IS SELECT TASK SAME AS CURRENT  32000000
         BC    8,ENTRY2                 IF YES, SKIP DISPATCHING        32100000
* AT RETURN FROM TASK SELECT, THE LOWEST INCOMPLETE TCB IN THE          32200000
* ABENDING FAMILY WILL BE SELECTED IN ATCBREG.                          32300000
*                                                                       32400000
*********************************************************************** 32500000
********************   DISPATCH SELECTED TASK     ********************* 32600000
*********************************************************************** 32700000
*                                                                       32800000
* THE FOLLOWING CODE SETS THE CURRENT TASK (TCBREG) NONDISPATCHABLE,    32900000
* MAKES THE SELECTED TASK DISPATCHABLE, SETS THE RESUME PSW OF THE      33000000
* SELECTED TASK TO POINT TO ENTRY2 OF ABEND5, BRANCHES TO THE TASK      33100000
* SWITCH ROUTINE AND THEN TO THE DISPATCHER.                            33200000
*                                                                       33300000
SETCURND OI    TCBFLGS+4,TCBABWF        MAKE CURRENT TASK NON-DISP.     33400000
         XC    TCBFLGSP+3(2),TCBFLGSP+3 MAKE SELECTED TASK DISP.        33500000
         XC    TCBNDSPP(3),TCBNDSPP     MAKE SEL TASK DISP   AD  A43314 33530021
         MVI   TCBSTPCP,X'00'           CLEAR STOP COUNT     AD  A43314 33560021
         MVI   TCBRECDE,X'00'           CLEAR RECURSION BITS            33600000
         OI    TCBTSFLP,X'20'           SHOW SVC IN PROGRESS  AD A54200 33650021
         LA    WKREG,ENTRY2             GET ENTRY POINT TO THIS LOAD    33700000
         ST    WKREG,RBOPSW+4           PLACE IN RESUME PSW IN ABEND RB 33800000
         MVC   TCBRBP+1(3),RBLINK       DEQ ABEND SVRB FROM CURRENT TCB 33900000
         MVC   RBLINK(3),TCBRBPP+1      ENQ ABEND SVRB ON SELECTED TCB  34000000
         ST    RBREG,TCBRBPP            MAKE ABEND SVRB TOP ON SEL. TCB 34100000
         LR    TCBREG,ATCBREG           MAKE SELECTED TCB CURRENT TCB   34200000
         STM   0,15,TCBGRSP             STORE REGS 0-15 IN SELECTED TCB 34300000
         L     SCVTREG,CVTABEND         LOAD ADDR OF SECONDARY CVT      34400000
         L     SWITCH,SCVTTASW          GET EPA OF TASK SWITCHING RTN   34500000
         STM   0,15,TCBGRS              STORE REGISTERS                 34600000
         BALR  SWRET,SWITCH             CAUSE TASK SWITCHING            34700000
         SR    PARREG0,PARREG0          CLEAR REGISTER                  34800000
         L     WKREG,CVTTCBP            LOAD POINTER NEW-OLD            34900000
         CLC   0(4,WKREG),4(WKREG)      Q. HAS TASK SWITCH OCCURRED     35000000
         BC    7,DISP                   YES,BRANCH                      35100000
         ST    PARREG0,0(,WKREG)        ZERO NEW                        35200000
DISP     L     WKREG,CVT0DS             GET EPA OF DISPATCHER           35300000
         BCR   15,WKREG                 GO TO DISPATCHER                35400000
         EJECT                                                          35500000
**********************************************************************  35600000
**************************   SECOND ENTRY IN ABEND5   ****************  35700000
**********************************************************************  35800000
*                                                                       35900000
ENTRY2   EQU   *                                                        36000000
         NI    TCBFLGS,255-TCBFX        ALLOW ASYNCH EXITS        20472 36100000
         SPACE 2                                                        36200000
* IF THIS IS THE OLTEP TASK, ISSUE SVC 59                      PD OLTEP 36300021
* TO GIVE OLTEP THE CHANCE TO PERFORM                          PD OLTEP 36350021
* A FAST CLEAN-UP.  NORMALLY OLTEP WILL                        PD OLTEP 36400021
* HAVE RUN FROM A STAE EXIT TO PERFORM                         PD OLTEP 36450021
* FINAL CLEAN-UP.  HOWEVER HE MAY HAVE ABENDED                 PD OLTEP 36500021
* AND NOT FREED HIS DEBS.  THIS WOULD CAUSE AN                 PD OLTEP 36550021
* INVALID RECURSION IN ABEND WHILE TRYING TO                   PD OLTEP 36600021
* FREE THE OLTEP DEBS (OLTEP'S DEBS                            PD OLTEP 36650021
* HAVE NO PREFIX).                                             PD OLTEP 36700021
**                                      OLTEP = APAR OS64126 PD OS64126 36720021
*                                                                       36750021
         TM    TCBTRN,TCBOLTEP          IF THE                 PD OLTEP 36800021
         BZ    ANYDEBS                  OLTEP TASK,            PD OLTEP 36850021
         SR    PARREG0,PARREG0          SET REG 0 EQUAL 0      PD OLTEP 36900021
         MVI   TCBRECDE,TCBOLT59+TCBREC ALLOW RECURSION        PD OLTEP 36950021
         SVC   OLTEP                    ISSUE OLTEP SVC        PD OLTEP 37000021
         SPACE 5                                                        37100000
*********************************************************************** 37200000
********************************   CLOSE INTERFACE   ****************** 37300000
*********************************************************************** 37400000
*                                                                       37500000
* THE FOLLOWING CODE CLOSES DATA SETS WHICH HAVE BEEN LEFT OPEN BY THE  37600000
* ABENDING TASK.                                                        37700000
*                                                                       37800000
ANYDEBS  EQU   *                                                        37900000
         MVI   TCBRECDE,X'00'           NO RECURS OR COMMUNICAT   21472 38000000
         L     DEBREG,TCBDEB            GET DEB POINTER FROM TCB        38100000
         USING DEBSECT,DEBREG                                           38200000
         LTR   DEBREG,DEBREG            ARE THERE ANY DEBS?             38300000
         BZ    NODEBS                   NO,  BYPASS CLOSE         M1132 38400000
         EJECT                                                          38500000
*********************************************************************   38600000
***********   CHECK FOR CORE FOR CLOSE ROUTINE     ******************   38700000
*********************************************************************   38800000
*                                                                       38900000
* THE GETMAIN PARAMETER LIST AND ASSOCIATED ADDRESS LIST ARE PLACED     39000000
* IN THE ABEND SVRB EXTENDED SAVE AREA IN THE FOLLOWING MANNER-         39100000
*                                                                       39200000
**************   EXTENDED SAVE AREA OF THE ABEND SVRB  ***************  39300000
*              *****************************************                39400000
*        0     *        * SIZE REQUESTED -  552 BYTES * *   GETMAIN     39500000
*              ****************************************  *  PARAMETER   39600021
*        4     *        * PTR TO ADDR OF CORE ALLOCAT.*   * LIST-       39700000
*              ****************************************  *  POINTED TO  39800000
*        8     * CODE   * SP ID    *                  * *   BY REG 1    39900000
*        ***********************************************                40000021
*        12    *        *  ADDRESS OF ALLOCATED CORE  *  INFO. PROVIDED 40100000
*              ****************************************  BY GETMAIN SVC 40200000
         SPACE 2                                                        40300000
TESTCLOS MVC   RBEXSAVE(10),GETLIST     MOVE GETMAIN PARAMETER TO ESA   40400000
         LA    WKREG,RBEXSAVE+12        ESTABLISH POINTER TO ADDRESS    40500000
         LA    PARREG1,RBEXSAVE         LOAD ADDR OF PARAM LIST         40600000
         GETMAIN A=(WKREG),MF=(E,(1))   TEST FOR CORE FOR CLOSE   21472 40700000
         LA    XCTLREG,STEALOAD         READY TO GO TO STEAL      21472 40800000
         LTR   RTNREG,RTNREG            TEST GETMAIN RETURN CODE        40900000
         BNZ   XCTL                     NO CORE GO STEAL IT       21472 41000000
         SPACE 2                                                        41100000
* REGISTER 1 CONTAINS THE ADDRESS OF THE PARAMETER LIST POINTER         41200000
* AT THIS TIME. IF GETMAIN EVER CHANGES TO DESTROY THE INPUT            41300000
* VALUE IN REGISTER 1, THE FOLLOWING INSTRUCTION WILL HAVE TO           41400000
* BE INSERTED HERE.                                                     41500000
         SPACE 1                                                        41600000
*        LA    PARREG1,RBEXSAVE         LOAD ADDR OF PARAM LIST         41700000
         SPACE 2                                                        41800000
         FREEMAIN MF=(E,(1))            MAKE CORE AVAILABLE       21472 41900000
         EJECT                                                          42000000
         ST    DEBREG,RBEXSAVE          SAVE THIS DEB ADDRESS     21472 42100000
         MVC   RBEXSAVE+4(4),DEBDCB     GET DCB ADDR FOR CLOSE PARALIST 42200000
         MVI   RBEXSAVE+4,ONEDCB        INDIC ONE DCB IN CLOSE PARALIST 42300000
         LA    PARREG1,RBEXSAVE+4       PROVIDE ADDR. OF CLOSE PARALIST 42400000
         MVI   TCBRECDE,TCBREC+TCBCLOSE SET CLOSE + RECUR FLGS          42500000
         CLOSE MF=(E,(1))               CLOSE THE DATA SET              42600000
*                                                                       42700000
* THE FOLLOWING CODE DETERMINES WHETHER CLOSE WAS ABLE TO FREE THE CORE 42800000
* OCCUPIED BY THE DEB ASSOCIATED WITH THE DATA SET FOR WHICH THE CLOSE  42900000
* WAS ISSUED.  IF THE DEB CORE HAS NOT BEEN FREED, IT IS FREED AT THIS  43000000
* TIME.                                                                 43100000
*                                                                       43200000
DEBFREED EQU   *                                                        43300000
         MVI   TCBRECDE,X'00'           RECURSION FLAGS RESET           43400000
         CLC   TCBDEB(4),RBEXSAVE       HAS THE DEB BEEN FREED?         43500000
         BNE   PIETEST                  YES. GO TEST FOR PIE     A31886 43600000
         EJECT                                                          43620021
*********************************************************************** 43640021
************** FORCE CLOSE HOOK *************************************** 43660021
*********************************************************************** 43680021
*                                                                       43700021
* SINCE IT HAS BEEN ESTABLISHED THAT THE DEB WAS NOT DEQUEUED BY        43720021
* CLOSE, SPECIAL PROCESSING NORMALLY PERFORMED BY VARIOUS ACCESS        43740021
* METHOD EXECUTORS WAS PROBABLY NOT DONE. TWO 'FORCE CLOSE'             43760021
* ROUTINES ARE USED TO PROVIDE SUPPLEMENTARY SUPPORT TO PERFORM         43780021
* A FAST CLEAN-UP FUNCTION. ONE INTERFACE ('IGGIFF01') PROVIDES         43800021
* GAM FORCE-CLOSE PROCESSING. THE OTHER INTERFACE ('IGG0201E')          43820021
* PROVIDES FORCE-CLOSE PROCESSING FOR ALL OTHER ACCESS METHODS.         43840021
*                                                                       43860021
* THE FORCE CLOSE MODULE MAY USE ANY PART OF THE SVRB                   43880021
* EXTENDED SAVE AREA. UPON COMPLETION, THE ROUTINE MUST ISSUE           43900021
* AN SVC 3.                                                             43920021
*                                                                       44020021
         MVC   RBEXSAVE+8(8),NMGAMHK    XCTL INFO FOR ABEND0 AD  A33565 44040021
         MVI   RBEXSAVE+16,TCBREC+TCBCLOSF SET VALID RECURS  AD  A33565 44060021
         MVI   TCBRECDE,TCBNEWRB        PROTECTION RB FLAG   AD  A33565 44080021
         SVC   13                       PSEUDO LINK          AD  A33565 44100021
*                                       FORCE CLS = APAR OS63498  64126 44102021
GENFCRTN MVC   RBEXSAVE+8(8),NMFCLS     XCTL MODULE NAME   PD FORCE CLS 44104021
         MVI   RBEXSAVE+16,TCBREC+TCBFCREC VALID RECURSION PD FORCE CLS 44108021
         MVI   TCBRECDE,TCBNEWRB        ACROSS XCTL        PD FORCE CLS 44112021
         SVC   13                       PSEUDO LINK        PD FORCE CLS 44116021
         L     SCVTREG,CVTABEND         RE-INIT SCVT BASE    AD  A33565 44120021
         SPACE 1                                                        44140021
*****                                                             ***** 44160021
*        FALL THROUGH TO DEQUEUE THE DEB                              * 44180021
*****                                                             ***** 44200021
         EJECT                                                          44220021
FCLOSREC EQU   *                                             AD  A33565 44240021
         MVI   TCBRECDE,X'00'           RECURSION FLGS RESET AD  A33565 44260021
         L     DEBREG,TCBDEB            ACCESS LAST DEB OFF TCB         44400000
         MVC   TCBDEB+1(3),DEBLINK+1    DEQUEUE THIS DEB                44500000
         SR    PARREG0,PARREG0          INITIALIZE REGISTER             44600000
         S     DEBREG,CONS4             GET ADDR OF DEB LENGTH FIELD    44700000
         IC    PARREG0,0(,DEBREG)       GET DEB LNGTH IN DBLWRDS  21472 44800000
         SLL   PARREG0,3                DEVELOP DEB LENGTH IN BYTES     44900000
         O     PARREG0,CONS254          SET SUBPOOL ID=254 FOR DEB CORE 45000000
         SH    DEBREG,CONS32            GET START ADDR OF DEB APPENDAGE 45100000
         L     WORKREG,DEBAPPAD+36      GET START ADDR OF DEB APPENDAGE 45200000
         LA    WORKREG,0(,WORKREG)      CLEAR HIGH-ORDER BYTE           45300000
         CR    DEBREG,WORKREG           IS THIS A QTAM DEB?             45400000
         BE    NOQTAM                   NO, FREE CORE AT DEB - 36       45500000
         ST    DEBREG,RBEXSAVE+8                                        45600000
         TM    RBEXSAVE+11,DUBLWORD     IS APP TBL ON DBL WORD BND      45700000
         BZ    NOQTAM                   YES BRANCH - NOT A QTAM DEB     45800000
         LA    DEBREG,20(,DEBREG)       YES, FREE CORE AT DEB-16        45900000
NOQTAM   EQU   *                                                        46000000
         LR    PARREG1,DEBREG           PROVIDE ADDR OF DEB TO BE FREED 46100000
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN SVC              46200000
         EJECT                                                          46300000
****************************************************************        46400000
*                  FREE THE PIE                                         46500000
****************************************************************        46600000
*                                                                       46700000
PIETEST  EQU   *                                                 A31886 46800000
         L     PARREG1,TCBPIE           ESTABLISH PIE ADDRESS.    M2549 46900000
         LTR   PARREG1,PARREG1          Q. IS THERE A PIE        A31886 47000000
         BZ    ANYDEBS                  NO. CHECK FOR MORE DEBS  A31886 47100000
         XC    TCBPIE+1(3),TCBPIE+1     ZERO PIE PTR IN TCB       M2549 47200000
         L     PARREG0,PIECONS          PARAM TO FREE THE PIE    A31886 47300000
         L     SCVTREG,CVTABEND         POINT TO SCVT          @PD66102 47350021
         L     RETREG,SCVTRMBR          ADDR RGMAIN BR ENTRY      21472 47400000
         OI    SCVTFMSA,SCVTSW1         SET CONDIT FREEMAIN SW    21472 47500000
         BALR  RETREG,RETREG            CONDITIONALLY FREE PIE    21472 47600000
         L     SCVTREG,CVTABEND         RELOAD SCVT ADDR IF REC   21472 47700000
         NI    SCVTFMSA,255-SCVTSW1     RESET CONDIT FREEMAIN SW  21472 47800000
         B     ANYDEBS                  CHECK FOR MORE DEBS      A31886 47900000
NODEBS   EQU   *                                                        48000000
*                                                                       48100000
* FALL THRU TO END PROCESSING SECTION.                                  48200000
         EJECT                                                          48300000
*********************************************************************** 48400000
*****************************   END PROCESSING   ********************** 48500000
*********************************************************************** 48600000
*                                                                       48700000
* THE FOLLOWING CODE DETERMINES WHERE CONTROL IS TO BE ROUTED NEXT. IF  48800000
* THE CURRENT TASK IS THE TOP TASK IN A TREE WHICH IS ABNORMALLY        48900000
* TERMINATING, CONTROL IS PASSED TO LOAD 7 OF ABEND. OTHERWISE,A        49000000
* SUBTASK IS SELECTED FOR TERMINATION VIA RE-DISPATCHING TO THIS LOAD.  49100000
*                                                                       49200000
TOPTEST  EQU   *                                                        49300000
         LA    LINKREG,SETCURND         LOAD RETURN REG FROM TASKSEL    49400000
         TM    TCBFLGS,TCBFT            IS THIS TOP TASK IN TREE        49500000
         BC    8,TASKSEL3               NO, GO SELECT A SUBTASK         49600000
         LA    XCTLREG,NMLOAD13         YES. GET ADDR OF TM0D NAME      49700000
XCTL     EQU   *                                                  M1132 49800000
         L     PARREG0,THISMOD          SHOW XCTL IN TRACE TABLE  20472 49900000
         L     PARREG1,4(,XCTLREG)      SHOW NEXT MOD IN TRACE    20472 50000000
         LA    15,RBEXSAVE              GET ADDR OF AREA FOR PAR. LIST  50100000
         XCTL  EPLOC=(XCTLREG),SF=(E,(15)) TRANSFER CONTROL TO LOAD 11  50200000
         EJECT                                                          50300000
*********************************************************************** 50400000
***************************   HOP SVRB ROUTINE   ********************** 50500021
*********************************************************************** 50600000
*                                                                       50700000
* THE FOLLOWING CODE SELECTS A SUBTASK OF THE TASK WHICH IS CURRENTLY   50800000
* ABENDING FOR ABNORMAL TERMINATION PROCESSING VIA RE-DISPATCHING TO    50900000
* THIS LOAD OF ABEND.  THE SELECTION PROCESS IN A FAMILY TREE PROCEEDS  51000000
* FROM BOTTOM TO TOP% BEGINNING AT THE LOWEST INCOMPLETE SUBTASK AND    51100000
* ENDING AT THE TOP TASK IN THIS FAMILY TREE.                           51200000
*                                                                       51300000
TASKSEL3 LR    ATCBREG,TCBREG           SAVE CURRENT TCB ADDRESS        51400000
SELECT20 L     NEXT,TCBNTCP             ACCESS SISTER                   51500000
         L     ATCBREG,TCBOTCP          ACCESS MOTHER                   51600000
SELECT21 LTR   NEXT,NEXT                IS THERE A DAUGHTER (OR SISTER) 51700000
         BC    8,SELECT22               NO, SEE IF TASK IS COMPLETE     51800000
         LR    ATCBREG,NEXT             YES, SAVE THIS TCB ADDRESS      51900000
         L     NEXT,TCBLTCP             ACCESS DAUGHTER                 52000000
         BC    15,SELECT21              LOOK FOR MORE DAUGHTERS         52100000
SELECT22 TM    TCBFLGSP+4,TCBFC         IS THIS TASK COMPLETE?          52200000
         BCR   8,LINKREG                NO, RETURN TO CALLER            52300000
*                                                                       52400000
**********************************************************************  52500000
*******************************   ERASE INTERFACE   *****************   52600000
**********************************************************************  52700000
*                                                                       52800000
* THE FOLLOWING CODE DETERMINES WHETHER SUBTASKS OF THE CURRENT TASK    52900000
* ARE TO BE ERASED AND, IF SO, BRANCHES TO THE RESIDENT ERASE PHASE IN  53000000
* EOT.                                                                  53100000
*                                                                       53200000
*        INPUT REGISTERS-                                               53300000
*           ERASEREG - 7   ADDR OF TCB TO BE ERASED                     53400000
*           RETREG   - 14   RETURN REGISTER                             53500000
*           ENTRYREG -  6   ENTRY ADDR TO ERASE ROUTINE IN EOT          53600000
*                                                                       53700000
*        OUTPUT REGISTERS-                                              53800000
*                      3   CVT ADDRESS                                  53900000
*                      4   ORIGIN TASK OF ERASED TASK                   54000000
*        TRANSPARENT REGISTERS-                                         54100000
*                      2,5,7,9-12,14,15                                 54200000
*                                                                       54300000
         LR    SAVETCB,TCBREG           SAVE CURRENT TCB OVER ERASE     54400000
         LR    ERASEREG,ATCBREG         LOAD ADDR OF TCB TO BE ERASED   54500000
         L     SCVTREG,CVTABEND         LOAD ADDR OF SECONDARY CVT      54600000
         L     ENTRYREG,SCVTERAS        GET ENTRY POINT OF ERASE PHASE  54700000
         OI    SCVTFMSA,SCVTSW2         SHOW CONDITIONAL     PD OS54202 54800021
         BALR  RETREG,ENTRYREG          BRANCH TO ERASE ROUTINE         54900000
         L     SCVTREG,CVTABEND         POINT TO SEC CVT     PD OS54202 54930021
         NI    SCVTFMSA,255-SCVTSW2     REMOVE CONDITIONAL   PD OS54202 54960021
         LR    TCBREG,SAVETCB           RESTORE ADDR OF CURRENT TCB     55000000
         BC    15,SELECT20              BR TO SELECT ANOTHER TASK       55100000
         EJECT                                                          55120021
*****************************************************************       55140021
*                                                                       55160021
* TASK SELECTION SUBROUTINE.                                            55180021
*                                                                       55184021
SELECTR  EQU   *                                                        55188021
         LTR   SELREG,ATCBREG          IS THIS FIRST-TIME ENTRY         55192021
         BC    10,SELECT1R             NO,BRANCH TO START SELECTION     55196021
         LCR   SELREG,SELREG           YES, RECOMPLEMENT TCB ADDRESS    55196821
SELECT3R LR    ATCBREG,SELREG          PASS BACK SELECTED TCB ADDRESS   55197621
         TM    TCBFLGSP+4,TCBFC        Q. TASK ALREADY COMPLETE  A43837 55198421
         BO    SELECTR                 YES. SELECT NEXT TASK     A43837 55199221
         B     4(,LINKREG)             RETURN TO MAIN ROUTINE           55199321
SELECT1R L     SELREG,TCBLTCP          GET DAUGHTER OF INPUT TASK       55199421
SELECT2R LTR   SELREG,SELREG           DOES A DAUGHTER EXIST            55199521
         BC    7,SELECT3R              YES,SELECTION HAS BEEN MADE      55199621
         L     SELREG,TCBNTCP          NO, GET SISTER                   55199721
         TM    TCBFLGSP,TCBFT          Q.IS SCAN OF TREE FINISHED 20472 55199821
         BCR   1,LINKREG               YES, RETURN TO MAINLINE  A41373  55199921
         L     ATCBREG,TCBOTCP         NO, GET MOTHER                   55233221
         B     SELECT2R                BRANCH TO TEST                   55253221
         EJECT                                                          55266721
****************************************************************        55300000
GETLIST  GETMAIN EC,LV=552,MF=L                                   21472 55400000
         SPACE 5                                                        55500000
****************************************************************        55600000
**********************************************************************  55700000
* THE FOLLOWING ARE CONSTANTS USED IN THIS LOAD OF ABEND.               55800000
*                                                                       55900000
NMABEND  DC    C'ABENDB'                TO IDENTIFY ABEND SVRB   A41372 56000000
CONS32   DC    H'32'                                                    56100000
CONS4    DC    F'4'                                                     56200000
NMLOAD13 DC    CL8'IGC0D01C'                                            56300000
STEALOAD DC    CL8'IGC0C01C'            STEAL CORE MODULE         21472 56400000
NMGAMHK  DC    C'IGGIFF01'              GAM FORCE CLOSE RTN  AD  A33565 56450021
NMFCLS   DC    CL8'IGG0201E'            GENERAL FORCE CLS  PD FORCE CLS 56470021
CONS254  DC    X'FE000000'                                              56500000
PIECONS  DC    X'FA000020'              CONSTANT TO FREE PIE      20472 56600000
*                                        (32 BYTES OF SUBPOOL 0)  20472 56700000
THISMOD  DC    C'B01C'                  IDENTIFY THIS MODULE            56800000
WORDBDY  DC    X'03'                    FOR WORD BDY TEST     CI A45983 56850021
         EJECT                                                          56900000
*                                                                       57000000
*     ZAP SPACE FOR MAINTENANCE USE                                     57100000
*                                                                       57200000
         DC    H'0'                                                     57300000
         DC    H'0'                                                     57400000
         DC    H'0'                                                     57500000
         DC    H'0'                                                     57600000
         DC    H'0'                                                     57700000
         DC    H'0'                                                     57800000
         DC    H'0'                                                     57900000
         DC    H'0'                                                     58000000
         DC    H'0'                                                     58100000
         DC    H'0'                                                     58200000
         DC    H'0'                                                     58300000
         DC    H'0'                                                     58400000
         DC    H'0'                                                     58500000
         DC    H'0'                                                     58600000
         DC    H'0'                                                     58700000
         DC    H'0'                                                     58800000
         DC    H'0'                                                     58900000
         DC    H'0'                                                     59000000
         DC    H'0'                                                     59100000
         DC    H'0'                                                     59200000
         DC    H'0'                                                     59300000
         DC    H'0'                                                     59400000
         DC    H'0'                                                     59500000
         DC    H'0'                                                     59600000
         DC    H'0'                                                     59700000
         DC    H'0'                                                     59800000
         DC    H'0'                                                     59900000
         DC    H'0'                                                     60000000
         DC    H'0'                                                     60100000
         DC    H'0'                                                     60200000
         DC    H'0'                                                     60300000
         DC    H'0'                                                     60400000
         EJECT                                                          60410021
         IEZJSCB                                              CI A45983 60420021
         EJECT                                                          60430021
CSCBSECT DSECT                                                CI A45983 60440021
         IEECHAIN                                             CI A45983 60450021
         EJECT                                                          60500000
         IHBABCTL                                                       60600000
TCBOLTEP EQU   X'02'                    OLTEP TCB MASK            19026 60700000
DCBTIO   EQU   40                 OFFSET IN DCB TO TIOT INDEX VALUE     60800000
DUBLWORD EQU   X'07'                   MASK TO TEST FOR DOUBLE WORD     60900000
OLTEP    EQU   59                      OLTEP SVC                  19026 61000000
TCBTSTSK EQU   148                     DISPLACEMENT TO TSO FLAG   M3364 61100000
TSOTASK  EQU   X'80'                   TIME SHARING TASK FLAG     M3364 61200000
WAITFLG  EQU   X'80'                    ECB WAIT FLAG MASK    CI A45983 61220021
POSTFLG  EQU   X'40'                    ECB POST FLAG MASK    CI A45983 61240021
KEYMASK  EQU   X'F0'                    RB KEY MASK           CI A45983 61260021
         EJECT                                                          61300000
****                                                               **** 61320021
*        FLOWCHART STATEMENTS FOR ABEND 11                            * 61340021
****                                                               **** 61360021
         SPACE 1                                                        61380021
*/*IEAQTM0B:      CHART */                                              61384021
*/*IEAQTM0B:      E ABEND 11 */                                         61388021
*/*IGC0B01C:      P ESTABLISH ADDRESSABILITY */                         61392021
*/*               D (NO,,YES,ANYDEBS) RETURN FROM ABEND 12 */           61396021
*/*               D (YES,,NO,GTFCHECK) CLOSE RECURSION */               61396821
*/*               P (,DEBFREED) MOVE DEB ADDR FROM PREVIOUS TO CURRENT  61397621
*/*ABEND SVRB ESA */                                                    61398421
*/*GTFCHECK:      P SET OUTPUT TCB = JOBSTEP TCB */                     61399221
*/*PREGTF:        P INDICATE FIRST TIME ENTRY TO TASK SELECT RTN */     61399321
*/*CHKGTF:        S (FND,,NONE,SKIPGTF) SELECTR: SELECT A TASK FOR GTF  61399421
*/*TRACE CHECK */                                                       61399521
*/*               D (YES,,NO,CHKGTF) WAS GTF TRACE STOPPED ON SEL TCB   61399621
*/**/                                                                   61399721
*/*               S HOOK: IHLMABON: RESUME GTF TRACE */                 61399821
*/*               P (,CHKGTF) RESET 'TRACE SUSPENDED' FLAG IN SELECTED  61399921
*/*TCB */                                                               61499921
*/*SKIPGTF:       $ */                                                  61519921
*/*NXTLTC:        P SET SELECTED TCB = LOWEST TCB IN ABENDING TREE */   61539921
*/*               P SET OUTPUT TCB = SELECTED TCB FOR TASKSEL3 RTN */   61559921
*/*               S TASKSEL3: AT EP SELECT22: SEE IF TASK COMPLETE */   61579921
*/*               D (NO,,YES,ENTRY2) SELECTED TCB = CURRENT TCB */      61583921
*/*SETCURND:      P SET CURRENT TASK NON DISPATCHABLE */                61587921
*/*               P MAKE SELECTED TASK DISPATCHABLE */                  61591921
*/*               P POINT ABEND SVRB RESUME PSW TO EP 'ENTRY2' IN THIS  61595921
*/*MODULE */                                                            61596721
*/*               P HOP ABEND SVRB FROM CURRENT TO SELECTED TASK */     61597521
*/*               P STORE CURRENT REGS IN SELECTED TCB */               61598321
*/*               S IEA0DS02: SET A TASK SWITCH CONDITION */            61599121
*/*DISP:          R DISPATCHER */                                       61599221
*/*ENTRY2:        E ABEND11 ENTRY FOR SELECTED TASKS */                 61599321
*/*               P (,:C) ALLOW ASYNCHRONOUS EXITS */                   61599421
*/*ANYDEBS:       P CLEAR ABEND VALID RECURSION FLAGS */                61599521
*/*               D (YES,,NO,NODEBS) ANY DEBS EXIST */                  61599621
*/*TESTCLOS:      S GETMAIN: TEST FOR 522 BYTES IN SP 0 FOR CLOSE */    61699621
*/*               D (NO,,YES,%FREECOR) STORAGE AVAILABLE FOR CLOSE */   61699821
*/*               R ABEND 12 */                                         61719821
*/*%FREECOR:      S FREEMAIN: GOTTEN STORAGE FOR CLOSE */               61739821
*/*               P SAVE CURR DEB ADDR IN ESA IN CASE OF RECURSION */   61759821
*/*               P SET ABEND VALID RECURSION FLAG ACROSS CLOSE */      61779821
*/*               S CLOSE: DCB OFF CURRENT DEB */                       61783821
*/*DEBFREED:      P CLEAR ABEND VALID RECURSION FLAGS */                61787821
*/*               D (NO,,YES,PIETEST) DID CLOSE FREE THE DEB */         61791821
*/*               P DEQ DEB FROM TCBDEB QUEUE */                        61795821
*/*               P SET TO FREE CORE AT DEB ADDR - 36 */                61796621
*/*               P SAVE DEB ADDR IN ABEND SVRB ESA */                  61797421
*/*               D (NO,,YES,NOQTAM) DEB APP ON D-WORD BND */           61798221
*/*               P SET TO FREE CORE AT DEB ADDR - 16 */                61799021
*/*NOQTAM:        S FREEMAIN: DEB AREA IN SUBPOOL 254 */                61799121
*/*PIETEST:       D (YES,,NO,ANYDEBS) DOES A PIE EXIST */               61799221
*/*               P ZERO THE PIE ADDRESS IN THE TCB */                  61799321
*/*               P SET THE 'CONDITIONAL FREEMAIN' FLAG IN THE SCVT */  61799421
*/*               S FREEMAIN: THE PIE IN SUBPOOL 250 */                 61799521
*/*               P (,ANYDEBS) RESET THE 'CONDITIONAL FREEMAIN' FLAG */ 61799621
*/*NODEBS:        $ */                                                  61799721
*/*TOPTEST:       D (NO,,YES,%TO13) CURR TASK TOP TASK IN TREE */       61899721
*/*               S (,SETCURND) TASKSEL3: SELECT NEXT SUBTASK */        61919721
*/*%TO13:         R ABEND 13 */                                         61939721
*/*TASKSEL3:      E ENTRY */                                            61959721
*/*               P SET OUTPUT TCB = CURRENT TCB */                     61979721
*/*SELECT20:      P SET SELECTED TCB = SISTER OF OUTPUT TCB */          61983721
*/*               P SET OUTPUT TCB = ITS MOTHER */                      61987721
*/*SELECT21:      D (YES,,NO,SELECT22) SELECTED TCB EXIST */            61991721
*/*               P SET OUTPUT TCB = SELECTED TCB */                    61995721
*/*               P SET SELECTED TCB = DAUGHTER OF OUTPUT TCB */        61996521
*/*SELECT22:      D (YES,,NO,%RET) OUTPUT TCB FLAGGED COMPLETE */       61997321
*/*               P STORE CURRENT REGS IN CURRENT TCB */                61998121
*/*               S (,SELECT20) IEAQERA: ERASE SELECTED TCB */          61998921
*/*%RET:          R RETURN */                                           61999021
*/*SELECTR:       E ENTRY */                                            61999121
*/*%NXTCB:        P SET SELECTED TCB = OUTPUT TCB */                    61999221
*/*               D (YES,,NO,SELECT1R) FIRST TIME ENTRY */              61999321
*/*               P RESET FIRST TIME INDICATOR */                       61999421
*/*SELECT3R:      P SET OUTPUT TCB = SELECTED TCB */                    61999521
*/*               D (NO,,YES,%NXTCB) SELECTED TASK FLAGGED COMPLETE */  61999621
*/*               R RETURN - FND */                                     62099621
*/*SELECT1R:      P SET SELECTED TCB = DAUGHTER OF OUTPUT TCB */        62119621
*/*SELECT2R:      D (NO,,YES,SELECT3R) SELECTED TCB EXIST */            62139621
*/*               P SET SELECTED TCB = SISTER OF OUTPUT TCB */          62159621
*/*               D (NO,,YES,%NONE) OUTPUT TCB TOP TCB */               62179621
*/*               P (,SELECT2R) SET OUTPUT TCB = ITS MOTHER */          62183621
*/*%NONE:         R RETURN - NONE */                                    62187621
*/*IEAQTM0B:      END */                                                62191621
         END                                                            62199621
