 TITLE 'IEAQTM0D / ABEND13 - DATA MANAGEMENT AND SUBSYSTEM INTERFACES A*00100000
               ND PURGES / IGC0D01C'                                    00200000
IGC0D01C START                                                          00300000
*                                                                       00400000
*                                                                       00500000
*                                                                       00600000
*   THE FOLLOWING CODE IS THE THIRTEENTH LOAD OF ABEND                  00700000
*                                                                       00800000
* ROUTINE NAME- ABEND13                                                 00900000
*                                                                       01000000
*             1. GIVES CONTROL TO A SPECIAL TCAM 'CLOSE'                01020021
*                MODULE WHICH DOES SOME CLEANUP OF TCAM                 01040021
*                QUEUES IN CASE CLOSE FAILED EARLIER.                   01060021
*                NOTE- THIS SUPPORT WHICH WAS SUPPLIED IN               01080021
*                RELEASE 20 WILL BE SUPPORTED THRU RELEASE              01084021
*                21 ONLY.                                               01088021
*                                                                       01092021
*             2. CANCELS INTERPARTITION POSTS PENDING FOR               01100021
*                TSO & TCAM                                             01200000
*                                                                       01300000
*             3. FREES STAE CONTROL BLOCKS (SCB)                        01400021
*                                                                       01500000
*             4. BRANCHES TO THE RESIDENT ENQ/DEQ PURGE                 01600021
*                ROUTINE WHICH PURGES THE SYSTEM QCB CHAIN OF           01700000
*                ANY OUTSTANDING ENQ'S FOR THE SELECTED TASK.           01800000
*                                                                       01900000
*             5. DEQUEUES TRANSIENT SVRB'S FROM THE RB QUEUE ON THE     02000021
*                TCB OF THE TASK WHICH IS CURRENTLY BEING ABNORMALLY    02100000
*                TERMINATED, FREES MAIN STORAGE OCCUPIED BY THESE       02200000
*                TRANSIENT SVRB'S, AND, WHEN APPLICABLE, DEQUEUES       02300000
*                THESE SVRB'S FROM THE TRANSIENT AREA HANDLER'S QUEUES. 02400000
*                NOTE: AN SVRB WHICH WAS ABEND'S MUST HAVE              02500000
*                THE ABEND INDICATOR IN THE EXTENDED SAVE AREA          02600000
*                DESTROYED OR A LATER USE OF THIS AREA IN SQS AS        02700000
*                A NON-ABEND SVRB COULD FOOL ABEND INTO MAKING          02800000
*                A BAD DECISION BECAUSE THE NEW SVRB WOULD LOOK         02900000
*                LIKE AN ABEND SVRB.                                    03000000
*                                                                       03100000
*             6. INTERFACES WITH THE DD-DYNAM CLEANUP MODULE            03200021
*                                                                       03300000
*                                                                       03400000
* ENTRY POINT NAMES - 1. IGC0D01C                                       03500000
*                                                                       03600000
*                        A. ENTRY FROM ELEVENTH LOAD OF ABEND           03700000
*                           FOR NORMAL FIRST-TIME ENTRY.                03800000
*                                                                       03900000
*                        B. ENTRY FROM THIRD LOAD OF ABEND IF           04000000
*                           RECURSION DUE TO A QTIP, SVC102, TIOT       04100000
*                           CLEANUP, OR TCAM CLEANUP FAILURE HAS        04200000
*                           OCCURRED.                                   04300000
*                                                                       04400000
* CONTAINED IN MODULE - IEAQTM0D                                        04500021
*                                                                       04600000
* ATTRIBUTES - TYPE 4 SVC, REENTRANT, SUPERVISOR STATE,                 04700000
*              PARTIALLY ENABLED.                                       04800000
*                                                                       04900000
* APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                05000000
*                                                                       05300000
* SVC USAGE - FREEMAIN, QTIP, 102, ABEND, XCTL                          05400000
*                                                                       05500000
* INPUT - NONE.                                                         05600000
*                                                                       05700000
* OUTPUT - NONE.                                                        05800000
*                                                                       05900000
* ENTRY POINTS - 1. IGC0D01C                                            06000000
*                                                                       06100000
*                   A. THE CURRENT PSW MUST BE                          06200000
*                                                                       06300000
*                      (1) DISABLED FOR ALL MASKABLE INTERRUPTS         06400000
*                          EXCEPT MACHINE CHECK.                        06500000
*                                                                       06600000
*                      (2) UNDER SUPERVISOR PROTECTION KEY.             06700000
*                                                                       06800000
*                      (3) IN SUPERVISOR MODE.                          06900000
*                                                                       07000000
*                   B. REGISTERS                                        07100000
*                                                                       07200000
*                      (1) REGISTER 3 MUST CONTAIN THE ADDRESS          07300000
*                          OF THE CVT.                                  07400000
*                                                                       07500000
*                      (2) REGISTER 4 MUST CONTAIN THE ADDRESS          07600000
*                          OF THE CURRENT TCB.                          07700000
*                                                                       07800000
*                      (3) REGISTER 5 MUST CONTAIN THE ADDRESS          07900000
*                          OF THE CURRENT RB.                           08000000
*                                                                       08100000
* EXIT POINTS - 1. BRANCH TO DISPATCHER IN ORDER TO DISPATCH A          08200000
*                  SELECTED SUBTASK FOR ENTRY TO THIS LOAD OF ABEND.    08300000
*                                                                       08400000
*               2. XCTL TO THE SEVENTH LOAD OF ABEND TO CONTINUE        08500000
*                  THE ABNORMAL TERMINATION OF A TREE OF TASKS.         08600000
*                                                                       08700000
*               3. IN BOTH CASES THE CURRENT PSW IS                     08800000
*                                                                       08900000
*                  A. DISABLED FOR ALL MASKABLE INTERRUPTS              09000000
*                     EXCEPT MACHINE CHECK.                             09100000
*                                                                       09200000
*                  B. UNDER SUPERVISOR PROTECTION KEY.                  09300000
*                                                                       09400000
*                  C. IN SUPERVISOR MODE.                               09500000
*                                                                       09600000
*               4. REGISTERS                                            09700000
*                                                                       09800000
*                  A. REGISTER 3 CONTAINS THE ADDRESS OF THE CVT.       09900000
*                                                                       10000000
*                  B. REGISTER 4 CONTAINS THE ADDRESS OF                10100000
*                     THE CURRENT TCB.                                  10200000
*                                                                       10300000
*                  C. REGISTER 5 CONTAINS THE ADDRESS OF                10400000
*                     THE CURRENT RB.                                   10500000
*                                                                       10600000
* ERROR EXIT POINTS - NONE.                                             10700000
*                                                                       10800000
* RESTRICTIONS ON USE OF ROUTINE - NONE.                                20800000
*                                                                       20900000
* NOTES -                                                               21000000
*                                                                       21100000
*     1.  THIS CODE IS NOT CHARACTER CODE DEPENDENT.                    21200000
*                                                                       21300000
*     2. THIS TASK SELECT ROUTINE IS DIFFERENT FROM THOSE IN            21400000
*        PREVIOUS ABEND MODULES IN THAT TCBREG (4) RATHER THAN          21500000
*        ATCBREG (13) IS THE INPUT AND OUTPUT REGISTER. THIS            21600000
*        IS BECAUSE REGISTER 4 IS NEEDED AS AN INPUT REGISTER           21700000
*        FOR RESIDENT CODE AS THE ADDRESS OF THE TCB TO BE              21800000
*        MANIPULATED. TCBREG AND ATCBREG ARE THEREFORE REVERSED         21900000
*        IN THIS MODULE. SINCE THE 'T' BIT IS ALWAYS ON IN THE          22000000
*        TOP ABENDING TASK WHICH MUST BE THE INITIAL INPUT TCB,         22100000
*        THE 'T' BIT IS USED TO INDICATE WHEN THE WHOLE TREE            22200000
*        HAS BEEN SELECTED.                                             22300000
*                                                                       22400000
         EJECT                                                          22500000
*                                                                       22600000
* THE FOLLOWING ARE REGISTER ASSIGNMENTS FOR THIS MODULE.               22700000
*                                                                       22800000
PARREG0  EQU   0                        PARAMETER REG.                  22900000
TAHCTREG EQU   0                        TRANSIENT AREA HANDLER USER CT. 23000000
TQREG    EQU   1                        CONTAINS ADDR OF TAH REQUEST Q. 23100000
PARREG1  EQU   1                        PARAMETER REG.                  23200000
ARBREG   EQU   2                        ADDRESSES ALTERNATE RB          23300000
LINKREG  EQU   2                        LINK REGISTER                   23400000
PARREG2  EQU   2                        PARAM REG FOR QTIP MACRO  M3027 23500000
PARREG3  EQU   3                        PARAM REG FOR QTIP MACRO  M3027 23600000
CVTREG   EQU   3                        CVTDSECT REG. USED THRU-OUT     23700000
TCBREG   EQU   4                        TCBDSECT REG. SELECT TCB        23800000
RBREG    EQU   5                        RBSECT REG. CURRENT RB          23900000
TPREVREG EQU   6                        PREVIOUS SVRB ADDRESS           24000000
SELREG   EQU   7                        USED IN TASK SELECTION          24100000
SAVREG   EQU   8                        PREVIOUS RB REG                 24200000
BASEREG  EQU   9                        ABEND BASEREG - USED THRU-OUT   24300000
ATCBREG  EQU   10                       ADDRESSES ALTERNATE TCB         24400000
XCTLREG  EQU   10                       EPLOC FOR XCTL            M1132 24500000
SPIDREG  EQU   11                       USED TO SET UP SUBPOOL IDENTIF. 24600000
TDONEREG EQU   11                       EXIT REG FROM TAH DEQUEUE       24700000
TCAMREG  EQU   11                       TCAM HOOK WORK REGISTER   M1132 24800000
RTNREG   EQU   12                       RET REG FROM TAH AND RBREMOVE   24900000
TACTREG  EQU   13                       TACT ENTRY REG                  25000000
RETREG   EQU   14                       RETURN REG FROM ERASE ROUTINE   25100000
TAHWKREG EQU   14                       ADDR OF TRANS. AREA COUNT       25200000
TCURREG  EQU   14                       SVRB REG USED TO CHAIN TAH QUE  25300000
DEQENTRY EQU   14                       ENTRY FOR ENQ/DEQ PURGE   M4358 25400000
SCVTREG  EQU   15                       ADDR OF SECONDARY CVT           25500000
         SPACE 2                                                        25600000
         EJECT                                                          25700000
IGC0D01C CSECT                                                          25800000
ABEND13  BALR  BASEREG,0                ESTABLISH ADDRESSABILITY        25900000
         USING *,BASEREG         9                                      26000000
         USING TCBSECT,ATCBREG   10     CURRENT TCB                     26100000
         USING TCBDSECT,TCBREG   4      TCB TO BE PURGED                26200000
         USING RBSECT,RBREG      5                                      26300000
         USING RBSECT2,ARBREG    2                                      26400000
         USING CVTSECT,CVTREG    3                                      26500000
         USING SCVTSECT,SCVTREG  F                                      26600000
         SPACE 3                                                        26700000
         MVI   RBEXSAVE+45,C'D'         FLAG SVRB AS THIS MODULE  21472 26800000
         L     SCVTREG,CVTABEND         GET ADDR OF SECONDARY CVT       26900000
         LR    ATCBREG,TCBREG           SAVE CURRENT TCB ADDR           27000000
*                                                                       27100000
* CURRENT TCB ADDRESS WILL BE IN REG 10 FOR THE DURATION OF THIS MODULE 27200000
*                                                                       27300000
         TM    TCBRECDE,X'FF'           Q. RECURSION?                   27400000
         BZ    INITNTRY                 NO. HANDLE FIRST TIME           27500000
         LR    ARBREG,RBREG             GET ABEND SVRB ADDRESS          27600000
NEXTRB   EQU   *                                                        27700000
         L     ARBREG,RBLINK2-1         GET NEXT RB ON RB QUEUE         27800000
         TM    RBSTAB2,RBFTP            IS THIS AN SVRB?                27900000
         BNO   NEXTRB                   NO, GO GET NEXT RB ON RB QUEUE  28000000
         CLC   RBEXSAV2+40(6),NMABEND   IS THIS PREVIOUS ABEND SVRB?    28100000
         BNE   NEXTRB                   NO. GET NEXT RB                 28200000
         L     TCBREG,RBEXSAV2+4        RESTORE SELECT TCB        21472 28300000
         LA    TCBREG,0(,TCBREG)        CLEAR HIBYTE              21472 28400000
         ST    TCBREG,RBEXSAVE+4        FLAG NEW SVRB WITH        21472 28500000
*                                        SELECT TCB ADDRESS       21472 28600000
*                                                                       28700000
* THE FOLLOWING CODE CHECKS FOR RECURSION OR RE-ENTRY TO THIS LOAD OF   28800000
* ABEND DUE TO QTIP, SVC102, OR DD-DYNAM RECURSION.                     28900000
*                                                                       29000000
         CLI   TCBRECDE,TCBQTIP         Q. QTIP RECURSION?        M3027 29100000
         BE    QTIPREC                  YES. HANDLE THE RECURS    M3027 29200000
         CLI   TCBRECDE,TCBDYNAM        Q. TIOT CHECK RECURSION?  20472 29300000
         BE    TRANTEST                 YES. PURGE TRANS SVRBS    20472 29400000
         CLI   TCBRECDE,TCBTCAMP        Q. INTERP. POST RECUR     M1132 29500021
         BE    NOTCAM                   YES. SKIP TCAM HOOK       M1132 29600000
         CLI   TCBRECDE,TCBTCAMR        Q. MCP CLEANUP RECUR AD   M1176 29620021
         BE    NOTCAM                   YES. SKIP TCAM HOOK  AD   M1176 29640021
         SPACE 1                                                        29700021
* CAN'T FALL THRU. BRANCH ABOVE HAD TO BE TAKEN.                        29800021
         SPACE 3                                                        29900000
INITNTRY EQU   *                                                        30000000
         LCR   TCBREG,TCBREG            PREPARE TO SELECT A TASK        30100000
TASKSEL  EQU   *                                                        30200000
         BAL   LINKREG,SELECT           SELECT TASK FOR PURGE           30300000
         B     ENDPROC                  XCTL TO NEXT MODULE             30400000
         ST    TCBREG,RBEXSAVE+4        SAVE SELECT TCB ADDR            30500000
         EJECT                                                          30600000
*********************************************************************** 30700000
************************   TCAM REINITIALIZATION HOOK   *************** 30800000
*********************************************************************** 30900000
*                                                                       31000000
* THIS TCAM HOOK IS SUPPLIED FOR R20, 20.1, AND 21 ONLY. IT             31100021
* WILL NOT BE AVAILABLE IN LATER RELEASES.  THE PURPOSE OF              31200021
* THIS HOOK IS TO GIVE CONTROL TO A SPECIAL MODULE WHICH                31300021
* PERFORMS ''CLOSE'' FUNCTIONS FOR TCAM IF THEY HAVE BEEN               31400021
* BYPASSED IN NORMAL CLOSE PROCESSING OR CLOSE RECURSION.               31420021
* NOTE:  THIS HOOK PROVIDES FUNCTIONS SIMILAR TO THOSE REQUIRED         31500021
* FOR THE FIX TO APAR 33565 WHICH IS SCHEDULED FOR RELEASE 22.          31600021
*                                                                       31700000
*    THE INTERFACE OF IGC0D01C WITH THE ''TCAM CLOSE'' PROCESSING       31800000
* MODULE USES THE PSUEDO SVC WITH A RECURSION CONFIGURATION             31900021
* SET ACROSS ''TCAM CLOSE'' PROCESSING.  THE ''TCAM CLOSE''             32000021
* MODULE MAY USE ANY PART OF THE SVRB EXTENDED SAVE AREA.               32200021
* WHEN FINISHED THE TCAM CLOSE MODULE MUST ISSUE AN SVC 3.              32300021
*                                                                       32500000
TESTCAM  EQU   *                                                  M1132 32600000
         L     TCAMREG,CVTAQAVT          GET PARAM LIST ADDRESS   M1132 32700000
         LTR   TCAMREG,TCAMREG           Q. IS PARAM LIST AVAIL   M1132 32800000
         BE    NOTCAM                    NO,BYPASS TCAM PROCESS   M1132 32900000
         L     TCAMREG,TCAMTCB(,TCAMREG) LOAD POINTER TO          M1132 33000000
TCAMTCB  EQU   8                          TCAM TASK               M1132 33100000
         LA    TCAMREG,0(,TCAMREG)       CLEAR HI ORDER BYTE      M1132 33200000
         CR    TCAMREG,TCBREG            Q.IS THIS TCAM TASK      M1132 33300000
         BNE   USERTCAM                  NO,HANDLE USERS POSTS    M1132 33400000
         MVC   RBEXSAVE+8(8),NMTCAMHK    WILL XCTL TO TCAM MOD    21472 33800000
         MVI   RBEXSAVE+16,TCBREC+TCBTCAMR SET VALID RECURS  AD  A33565 33900021
         MVI   TCBRECDE,TCBNEWRB         FLAG FOR PROTECTION RB   21472 34000000
         SVC   13                         AND ISSUE PSUEDO LINK   21472 34100000
         L     SCVTREG,CVTABEND          GET ADDR OF 2ND CVT  AI  21114 34120021
TCAMREC  EQU   *                                                        34200000
         B     NOTCAM                    SKIP OTHER TCAM HOOK AI  21472 34320021
         EJECT                                                          34400000
****************************************************************        34500000
*****     CANCEL PENDING INTERPARTITION POSTS FOR TCAM     *****        34600000
****************************************************************        34700000
*                                                                       34800000
* IN A TCAM ENVIRONMENT THERE MAY BE A PENDING REQUEST TO POST    M4308 34900000
* THIS TASK BY ANOTHER TASK.  SVC 102 IS AN SVC WHICH WILL        M4308 35000000
* EFFECTIVELY CANCEL SUCH PENDING REQUESTS.  IF THOSE REQUESTS    M4308 35100000
* WERE NOT CANCELLED, THIS TASK COULD TERMINATE AND ANOTHER       M4308 35200000
* TASK POSSIBLY HAVING THE SAME TJID, TCB ADDRESS,AND RB          M4308 35300000
* ADDRESS AS THIS TASK COULD BE POSTED BY MISTAKE.                M4308 35400000
*                                                                       35500000
* INPUT TO SVC 102                                                M4308 35600000
*                                                                       35700000
*        REG 1 - ADDRESS OF TWO WORD PARAMETER LIST AS FOLLOWS    M4308 35800000
*                                                                       35900000
*   1  FLAG BYTE   1            NEXT THREE BYTES               1        36000000
*   1--------------1-------------------------------------------1        36100000
*   1              1   (1 BYTE)   .                            1        36200000
*   1     X'FF'    1      NO      .    TJID IF A TSO TASK      1        36300000
*   1              1    MEANING   .    0 IF NOT A TSO TASK     1        36400000
*   1              1              .                            1        36500000
*   1--------------1-------------------------------------------1        36600000
*   1              1                                           1        36700000
*   1     NO       1  ADDRESS OF TCB FOR WHICH THE PURGE IS    1        36800000
*   1   MEANING    1   BEING REQUESTED                         1        36900000
*   1              1                                           1        37000000
*   ------------------------------------------------------------        37100000
*                                                                 M4308 37200000
* SVC CALL IS-                                                    M4308 37300000
*                   SVC 102                                       M4308 37400000
USERTCAM EQU   *                                                        37500000
*                                                                       37600000
*        ST    TCBREG,RBEXSAVE+4        TCB ADDR IN SECOND WORD   21472 37700000
*                                                                       37800000
         SR    PARREG2,PARREG2          ZERO OUT TJID REG         M4308 37900000
         TM    TCBTSTSK(TCBREG),TSOTASK Q. FOREGROUND TASK?       M4308 38000000
         BNO   NOTSO                    NO. NO TJID EXISTS        M4308 38100000
         L     PARREG2,TCBJSCBP-1       ADDRESS OF JSCB           M4308 38200000
*                                                                       38300000
*         XXXXXXXXXX                                                    38400000
         USING IEZJSCB,PARREG2          SET UP ADDRESSABILITY     M4308 38500000
*         XXXXXXXXXX                                                    38600000
*                                                                       38700000
         LH    PARREG2,JSCBTJID         PICK UP TJID              M4308 38800000
*                                                                       38900000
*         XXXXXXXXXX                                                    39000000
         DROP  PARREG2                                            M4308 39100000
         USING RBSECT2,ARBREG           RESTORE ALT RB ADDRESS.   M4308 39200000
*         XXXXXXXXXX                                                    39300000
*                                                                       39400000
NOTSO    EQU   *                                                  M4308 39500000
         ST    PARREG2,RBEXSAVE         STORE IN  L.O. BYTES      M4308 39600000
         OI    RBEXSAVE,X'FF'           STORE  FF IN H.O. BYTE    M4308 39700000
         LA    PARREG1,RBEXSAVE         ADDRESS OF PARAM LIST     M4308 39800000
         MVI   TCBRECDE,TCBREC+TCBTCAMP SET RECURSION IND         M1132 39900000
         SVC   102                      KILL PENDING TCAM POSTS   M4308 40000000
         L     SCVTREG,CVTABEND         GET ADDR OF 2ND CVT   AI  21114 40020021
NOTCAM   EQU   *                                                  M1132 40100000
         MVI   TCBRECDE,X'00'           RESET RECUR INDICS        M1132 40200000
         EJECT                                                          40300000
****************************************************************        40400000
************************ FREE SCB ROUTINE **********************        40500000
****************************************************************        40600000
*                                                                       40700000
FREESCBS EQU   *                                                  20472 40800000
*                                                                       40900000
         L     PARREG1,TCBNSTAP         GET SCB ADDR              20472 41000000
         LA    PARREG1,0(,PARREG1)      CLEAR OUT FLAGS           20472 41100000
         LTR   PARREG1,PARREG1          Q. DOES SCB EXIST?        20472 41200000
         BZ    NOSCB                    NO. SKIP SCB PROCESSING   20472 41300000
         MVC   TCBNSTAP,0(PARREG1)      UPDATE SCB CHAIN          20472 41400000
         L     PARREG0,SCBCONS          PARAMETER TO FREE SCB     20472 41500000
         FREEMAIN R,LV=(0),A=(1)        FREE THE SCB              20472 41600000
         B     FREESCBS                 NOW CHECK FOR MORE SCBS   20472 41700000
NOSCB    EQU   *                                                  20472 41800000
         L     SCVTREG,CVTABEND         GET ADDR OF 2ND CVT   AI  21114 41820021
         EJECT                                                          41900000
***************************************************************   M3027 42000000
*****    CANCEL PENDING INTERPARTITION POSTS FOR TSO    ********  M3027 42100000
****************************************************************  M3027 42200000
*                                                                 M3027 42300000
* IN A TSO ENVIRONMENT THERE MAY BE A PENDING REQUEST TO POST     M3027 42400000
* THIS TASK BY ANOTHER TASK, POSSIBLY SWAPPED OUT AT THIS TIME.   M3027 42500000
* 'QTIP' IS A MACRO WITH A NON-STANDARD INTERFACE WHICH WILL      M3027 42600000
* EFFECTIVELY CANCEL ALL SUCH PENDING REQUESTS. IF THOSE          M3027 42700000
* REQUESTS WERE NOT CANCELLED, THIS TASK COULD TERMINATE AND      M3027 42800000
* ANOTHER TASK POSSIBLY HAVING THE SAME TJID, TCB ADDRESS, AND    M3027 42900000
* RB ADDRESS AS THIS TASK COULD BE POSTED BY MISTAKE.             M3027 43000000
*                                                                 M3027 43100000
* INPUT TO QTIP -                                                 M3027 43200000
*                                                                 M3027 43300000
*        REG  1 - ADDRESS OF PRE-SUPPLIED REGISTER SAVE AREA      M3027 43400000
*        REG  2 - TJID IN LO ORDER 2 BYTES, ZERO IN HI BYTES      M3027 43500000
*        REG  3 - ADDRESS OF THE TCB FOR WHOM THE REQUEST IS      M3027 43600000
*                 BEING MADE                                      M3027 43700000
*                                                                 M3027 43800000
* MACRO CALL IS -                                                 M3027 43900000
*                 QTIP  29,(1)                                    M3027 44000000
*                                                                 M3027 44100000
* NOTES -                                                         M3027 44200000
*         1. IF TSO IS ACTIVE, THIS MACRO MUST BE CALLED EVEN IF  M3027 44300000
*            THIS IS NOT A TSO TASK,BECAUSE THIS COULD BE A       M3027 44400000
*            FOREGROUND INITIATED BACKGROUND TASK.                M3027 44500000
*                                                                 M3027 44600000
*         2. THE MACRO CALL IS MADE FOR EACH TASK IN THE          M3027 44700000
*            ABENDING TREE.                                       M3027 44800000
*                                                                 M3027 44900000
*         3. THIS MACRO MAY BE CALLED MORE THAN ONCE FOR AN       M3027 45000000
*            ABENDING TASK WITHOUT COMPLICATIONS, THUS NO         M3027 45100000
*            SPECIAL PRECAUTIONS ARE NECESSARY TO AVOID A SECOND  M3027 45200000
*            CALL DURING RECURSIVE PROCESSING.                    M3027 45300000
*                                                                 M3027 45400000
QTIPHOOK EQU   *                                                  M3027 45500000
*                                                                 M3027 45600000
         TM    CVTTSFLG,CVTTSRDY        Q. IS TSO ACTIVE?         M3027 45700000
         BNO   NOQTIP                   NO. DON'T ISSUE QTIP      M3027 45800000
         L     PARREG1,CVTTSCVT         PICK UP TSO CVT ADDR      M3027 45900000
*                                                                       46000000
*        XXXXXXXXXX                                                     46100000
         USING TSCVT,PARREG1            ADDRESSABILITY ON TSCVT   M3027 46200000
*        XXXXXXXXXX                                                     46300000
*                                                                       46400000
         L     PARREG1,TSCVTRPT         ADDR OF TIOC REFERENCE    M3027 46500000
*                                        POINTER TABLE            M3027 46600000
*                                                                       46700000
*        XXXXXXXXXX                                                     46800000
         USING TIOCRPT,PARREG1          ADDRESS. ON TIOCRPT       M3027 46900000
*        XXXXXXXXXX                                                     47000000
*                                                                       47100000
         LA    PARREG1,TIOCSAVE         ADDR OF 12 WD SAVE AREA   M3027 47200000
*                                                                       47300000
*        XXXXXXXXXX                                                     47400000
         DROP  PARREG1                                            M3027 47500000
*        XXXXXXXXXX                                                     47600000
*                                                                       47700000
         SR    PARREG2,PARREG2          ZERO OUT TJID REG         M3027 47800000
         TM    TCBTSTSK(TCBREG),TSOTASK Q. FOREGROUND TASK?       M3027 47900000
         BNO   NOTJID                   NO. NO TJID EXISTS        M3027 48000000
         L     PARREG2,TCBJSCBP-1       ADDR OF JSCB              M3027 48100000
*                                                                       48200000
*        XXXXXXXXXX                                                     48300000
         USING IEZJSCB,PARREG2          ADDRESSIBILITY FOR JOB    M3027 48400000
*        XXXXXXXXXX                      STEP CONTROL BLOCK       M3027 48500000
*                                                                       48600000
         LH    PARREG2,JSCBTJID         LOAD TJID PARAMETER       M3027 48700000
*                                                                       48800000
*        XXXXXXXXXX                                                     48900000
         DROP  PARREG2                                            M3027 49000000
         USING RBSECT2,ARBREG           RESTORE ALT RB ADDRESS.   M3027 49100000
*        XXXXXXXXXX                                                     49200000
*                                                                       49300000
NOTJID   EQU   *                                                  M3027 49400000
         LR    PARREG3,TCBREG           USE SELECT TCB FOR QTIP   M3027 49500000
         MVI   TCBRECDE,TCBREC+TCBQTIP  SET VALID RECURSION       21472 49600000
         QTIP  29,(1)                                             M3027 49700000
         L     CVTREG,CVTPTR            PICK UP CVT ADDR AGAIN    M3027 49800000
         L     SCVTREG,CVTABEND         GET ADDR OF 2ND CVT   AI  21114 49820021
QTIPREC  EQU   *                                                        49900000
         MVI   TCBRECDE,X'00'           END OF VALID RECURS       M3027 50000000
NOQTIP   EQU   *                                                  M3027 50100000
         EJECT                                                          50200000
*********************************************************************** 50300000
***************************    ENQ/DEQ PURGE   ************************ 50400000
*********************************************************************** 50500000
*                                                                 M4358 50600000
* ENQ/DEQ PURGE IS A RESIDENT ROUTINE WHICH DEQUEUES & RELEASES   M4358 50700000
* THE CORE FOR ALL QEL'S ON THE SYSTEM QCB CHAIN THAT ARE         M4358 50800000
* ASSOCIATED WITH THE TCB GIVEN AS INPUT. IF BY SO DOING,THERE    M4358 50900000
* ARE NO QEL'S ASSOCIATED WITH A MINOR QCB, THERE ARE NO MINORS   M4358 51000000
* ASSOCIATED WITH A MAJOR QCB,THE MAJOR QCB IS DEQUEUED AND       M4358 51100000
* FREED.                                                          M4358 51200000
*                                                                 M4358 51300000
* THIS PURGE WAS MOVED HERE IN RELEASE 20.1 TO ALLOW FOR THE      M4358 51400000
* CASE IN WHICH CONTROL MAY BE LOST IN A SHARED DASD ENVIRNMENT   M4358 51500000
* DURING A RELEASE.                                               M4358 51600000
*                                                                 M4358 51700000
* ENTRY POINT - IEA0EQ01 - OBTAINED FROM ABEND CVT                M4358 51800000
*                                                                 M4358 51900000
* THE REGISTER REQUIREMENTS ARE AS FOLLOWS-                       M4358 52000000
*              TCBREG -4   TCB ADDR FOR WHICH THE PURGE IS TO     M4358 52100000
*                          BE PERFORMED                           M4358 52200000
*              RETREG -14  RETURN REGISTER                        M4358 52300000
*                                                                 M4358 52400000
* THE ROUTINE ESTABLISHES ITS OWN ADDRESSIBILITY AND USES         M4358 52500000
* ALL REGISTERS. ABEND MUST REESTABLISH  PERTINENT REGISTERS      M4358 52600000
* UPON RETURN FROM ROUTINE                                        M4358 52700000
*                                                                 M4358 52800000
*                                                                 M4358 52900000
ENQPURGE EQU   *                                                  M4358 53000000
*                                                                 M4358 53100000
*                                                                 M4358 53200000
         L     DEQENTRY,SCVTPGEQ        LOAD ADDR OF ENQ PURGE    M4358 53300000
*                                                                 M4358 53400000
ENQBR    BALR  RETREG,DEQENTRY          BRANCH TO ENQ PURGE       M4358 53500000
* ABEND MUST REESTABLISH ADDRESSIBILITY.                          M4358 53600000
         LA    PARREG0,ENQBR-ABEND13    LOAD DISP FROM BEGIN      M4358 53700000
         LR    BASEREG,RETREG           LOAD BASEREG WITH         M4358 53800000
*                                        CURRENT ADDRESS          M4358 53900000
         SLR   BASEREG,PARREG0          SUBTRACT DISPLACEMENT TO  M4358 54000000
*                                        GET ADDRESSIBILITY       M4358 54100000
         L     CVTREG,16                REESTABLISH CVT ADDRESS   M4358 54200000
         L     SCVTREG,CVTABEND         RESTORE SCVT ADDRESS      M4358 54300000
         L     ATCBREG,CVTTCBP          PICK UP NEW/OLD PTR       M4358 54400000
         L     ATCBREG,OLD(,ATCBREG)    GET ADDR OF CURRENT TCB   M4358 54500000
         L     RBREG,TCBRBP             ADDR CURRENT SVRB         M4358 54600000
         L     TCBREG,RBEXSAVE+4        RESTORE SELECT TCB ADDR   21472 54700000
         LA    TCBREG,0(,TCBREG)        CLEAR HIBYTE              21472 54800000
*                                                                       54900000
*        FALL THROUGH TO REMOVE TRANSIENT SVRBS                   M1132 55000000
         EJECT                                                          55100000
*********************************************************************** 55200000
************************   REMOVE TRANSIENT SVRBS   ******************* 55300000
*********************************************************************** 55400000
*                                                                       55500000
* THE FOLLOWING CODE CHECKS FOR THE EXISTENCE OF AND REMOVES TRANSIENT  55600000
* SVRB'S FROM THE RB QUEUE ON THE SELECT TASK.                          55700000
*                                                                       55800000
         CR    TCBREG,ATCBREG           Q. CURRENT TASK TO PURGE  21472 55900000
         BE    TRANTEST                 YES. USE ABEND SVRB FOR   21472 56000000
*                                        INITIAL PREVIOUS RB      21472 56100000
         LA    ARBREG,RBLINK2-1-RBTMFLDS GENERATE FAKE ADDRESS    21472 56200000
         LCR   ARBREG,ARBREG             FOR PREVIOUS RB AT LOC.  21472 56300000
         AR    ARBREG,TCBREG             TCBRBP-X'1C'             21472 56400000
         B     TRANTS00                 NOW CHK FOR TRANS SVRBS   21472 56500000
TRANTEST LR    ARBREG,RBREG             GET ABEND SVRB ADDRESS          56600000
TRANTS00 LR    SAVREG,ARBREG            SAVE PREVIOUS RB ADDRESS        56700000
*                                                                       56800000
*        XXXXXXXXXX                                                     56900000
         DROP RBREG                                                     57000000
         USING RBSECT,SAVREG                                            57100000
*        XXXXXXXXXX                                                     57200000
*                                                                       57300000
TRANTS01 L     ARBREG,RBLINK-1          GET NEXT RB ON RB QUEUE         57400000
         LA    ARBREG,0(,ARBREG)        CLEAR OUT WAIT COUNT      21472 57500000
         TM    RBSTAB2+1,RBTCBNXT       IS THIS LAST RB ON RB QUEUE?    57600000
         BO    ENDTRANS                 YES-PRB. HOP OUT OF LOOP  21472 57700000
         TM    RBSTAB2,RBFTP            NO, IS THIS AN SVRB?            57800000
         BNO   TRANTS00                 NO. GO GET NEXT RB        21472 57900000
         TM    RBSTAB2,RBFNSVRB         IS THIS A TRANSIENT SVRB?       58000000
         BC    14,TRANTS00              NO, GO ACCESS NEXT RB ON QUEUE  58100000
         CLC   RBEXSAV2+40(5),NMABEND   Q. IS IT AN ABEND SVRB?   20472 58200000
         BNE   NOTABEND                 NO. SVRB IS NOT FLAGED    20472 58300000
         MVI   RBEXSAV2+44,C'*'         ELIMINATE ABEND FLAG      20472 58400000
NOTABEND EQU   *                                                  20472 58500000
         MVC   RBLINK(3),RBLINK2        DEQUEUE THIS SVRB FROM RB QUEUE 58600000
         BAL   RTNREG,TAHABEND          DEQUEUE SVRB FROM TAH QUEUE     58700000
         BC    15,TRANTS01              GO GET NEXT RB ON RB QUEUE      58800000
*                                                                       58900000
*        XXXXXXXXXX                                                     59000000
         DROP  SAVREG                                                   59100000
         USING RBSECT,RBREG                                             59200000
*        XXXXXXXXXX                                                     59300000
*                                                                       59400000
ENDTRANS EQU   *                                                        59500000
*                                                                       59600000
         B     TASKSEL                  GET NEW TCB FOR PURGES          59700000
         EJECT                                                          59800000
*********************************************************************** 59900000
********************   TRANSIENT AREA HANDLER PURGE   ***************** 60000000
*********************************************************************** 60100000
*                                                                       60200000
* THE FOLLOWING CODE PURGES THE TRANSIENT AREA HANDLER'S QUEUES OF      60300000
* TRANSIENT SVRB'S ASSOCIATED WITH THE SELECT TASK. THE CORE OCCUPIED   60400000
* BY THESE TRANSIENT SVRB'S IS ALSO FREED.                              60500000
*                                                                       60600000
*  INPUT -    ARBREG MUST CONTAIN ADDRESS OF SVRB TO BE PURGED          60700000
*             (HIGH BYTE MUST BE ZERO)                                  60800000
*                                                                       60900000
TAHABEND LA    TDONEREG,SPID255         SET EXIT ADDRESS           071  61000000
         L     TQREG,SCVTTACT           GET ADDR OF TA CONTROL TABLE    61100000
         LR    TPREVREG,TQREG           GET ADDR OF REQUEST QUEUE PTR   61200021
         LH    TACTREG,RBTABNO2         GET TACT ENTRY DISP FROM SVRB   61300000
         LTR   TACTREG,TACTREG          IS DISP ZERO (IS SVRB ON REQ Q) 61400000
         BC    8,TAHAB1                 YES, GO SEARCH REQUEST QUEUE    61500000
*                                       REINITIALIZE FOR USER QUEUE     61600000
         L     TAHWKREG,SCVTAUCT        LOAD ADDR OF TRANS. AREA COUNT  61700000
         L     TAHCTREG,0(,TAHWKREG)    LOAD TRANS. AREA USER COUNT     61800000
         BCTR  TAHCTREG,0               DECREMENT COUNT BY ONE          61900000
         ST    TAHCTREG,0(,TAHWKREG)    STORE DECREMENTED COUNT         62000000
         LA    TACTREG,0(TACTREG,TQREG) ACCESS THE TACT ENTRY           62100000
         LA    TPREVREG,TACTQAD(,TACTREG) ACCESS USER QUEUE ORIGIN      62200000
         LA    TDONEREG,TAHAB3          INITIALIZE EXIT FROM USER Q SCH 62300000
         SPACE 3                                                        62400000
TAHAB1   L     TCURREG,0(,TPREVREG)     ACCESS NEXT SVRB ON QUEUE       62500000
         LA    TCURREG,0(0,TCURREG)     CLEAR HI BYTE                   62600021
         LTR   TCURREG,TCURREG          CAN BE ZERO FOR REQ Q      071  62700000
*                                        BECAUSE OF TA REFRESH     071  62800000
*                                        USER Q CAN NEVER BE ZERO  071  62900000
         BCR   8,TDONEREG               EXIT OR CONTINUE USER Q PROCESS 63000000
         CR    TCURREG,ARBREG           IS THIS THE SVRB IN QUESTION?   63100000
         BC    8,TAHAB2                 YES, GO DEQUEUE IT              63200000
*                                                                       63300000
*        XXXXXXXXXX                                                     63400000
         DROP RBREG                                                     63500000
         USING RBSECT,TCURREG                                           63600000
*        XXXXXXXXXX                                                     63700000
*                                                                       63800000
         LA    TPREVREG,RBSVTQN         NO, SET UP NEXT SVRB ADDRESS    63900000
         BC    15,TAHAB1                GO SEE IF QUEUE IS EXHAUSTED    64600000
         SPACE 3                                                        64620021
TAHAB2   MVC   0(4,TPREVREG),RBSVTQN    DEQUEUE THIS SVRB               64700000
         BCR   15,TDONEREG              EXIT OR CONTINUE USER Q PROCESS 64800000
*        XXXXXXXXXX                                                     64900021
         DROP TCURREG                                                   64920021
         USING RBSECT,RBREG                                             64940021
*        XXXXXXXXXX                                                     64960021
*                                                                       64980021
TAHAB3   L     TCURREG,TACTQAD(,TACTREG) ACCESS USER QUEUE ORIGIN       65000000
         LTR   TCURREG,TCURREG          DEQ'ED SVRB THE ONLY USER?  397 65100000
         BC    7,SPID255                NO. DON'T FLAG TAB AS FREE  397 65200000
         MVI   TACTFLG(TACTREG),TABFREE INDICATE THIS TAB IS NOW FREE   65300000
*                                                                       65310021
* THE TRANSIENT AREA FETCH TCB REGS MUST BE REFRESHED SINCE  AD  A55998 65320021
* THE TASK MAY HAVE BEEN ABENDED(E.G. CANCELLED) WHILE THE   AD  A55998 65330021
* TRANSIENT AREA WAS IN THE PROCESS OF BEING LOADED AND      AD  A55998 65340021
* FETCH PROCESSING MAY HAVE ALTERED THE REGS.                AD  A55998 65342021
*                                                                       65344021
         L     PARREG1,TACTIOB(,TACTREG) ADDRESS ASSOCIATED  AD  A55998 65350021
*                                  TRANSIENT AREA FETCH TCB  AD  A55998 65360021
         L     TCURREG,0(,PARREG1)      GET TAH SVRB ADDRESS AD  A55998 65370021
         MVC   48(64,PARREG1),32(TCURREG) REFRESH TCB REGS   AD  A55998 65380021
SPID255  EQU   *                                                        65400000
         L     SPIDREG,CONS255          SET SP = 255 FOR SVRB           65500000
DEACTRB  NI    RBSTAB2+1,255-RBFACTV    DEACTIVATE THIS RB              65600000
         TM    RBSTAB2+1,RBFDYN         WAS THIS RB CREATED DYNAMICALLY 65700000
         BCR   8,RTNREG                 NO. RETURN TO CALLER            65800000
         LR    PARREG1,ARBREG           LOAD ADDRESS OF THIS SVRB       65900000
         SR    PARREG0,PARREG0          CLEAR PARAMETER REGISTER        66000000
         IC    PARREG0,RBSIZE2          GET SIZE OF RB IN DOUBLEWORDS   66100000
         SLL   PARREG0,3                DEVELOP SIZE OF RB IN BYTES     66200000
         OR    PARREG0,SPIDREG          LOAD PREVIOUSLY-SET SUBPOOL ID  66300000
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN SVC              66400000
         L     SCVTREG,CVTABEND         GET ADDR OF 2ND CVT   AI  21114 66420021
         BCR   15,RTNREG                RETURN TO CALLER                66500000
         EJECT                                                          66600000
*********************************************************************** 66700000
*****************************   END PROCESSING   ********************** 66800000
*********************************************************************** 66900000
*                                                                       67000000
* THE FOLLOWING CODE DETERMINES WHERE CONTROL IS TO BE ROUTED NEXT. IF  67100000
* THE CURRENT TASK IS THE TOP TASK IN A TREE WHICH IS ABNORMALLY        67200000
* TERMINATING, CONTROL IS PASSED TO LOAD 7 OF ABEND.                    67300000
*                                                                       67400000
ENDPROC  EQU   *                                                        67500000
         C     TCBREG,TCBJSTCB          Q. IS THIS JOB STEP TCB?  M3364 67600000
         BE    GOTO15                   YES, SKIP TIOT CHECK      M3364 67700000
         TM    TCBTSTSK(TCBREG),TSOTASK Q. TIME SHARING TASK?     M3364 67800000
         BZ    GOTO15                   NO, SKIP TIOT CHECK       M3364 67900000
         CLI   TCBRECDE,TCBDYNAM        Q. TIOT RECURSION         20472 68000000
         BE    TIOTREC                  YES, DONT ISSUE AGAIN     20472 68100000
         MVC   RBEXSAVE+8(8),NMDYNAM    WILL XCTL TO TIOT MODULE  21472 68600000
         MVI   RBEXSAVE+16,TCBREC+TCBDYNAM SET FOR VALID RECURS   21472 68700000
         MVI   TCBRECDE,TCBNEWRB        FLAG FOR PROTECTION SVRB  21472 68800000
         SVC   13                        AND ISSUE PSUEDO LINK    21472 68900000
         NI    TCBFLGS,255-TCBFX        ALLOW ASYNCHRONOUS EXITS  21472 69000000
*                                                                       69100000
TIOTREC  EQU   *                                                        69200000
         MVI   TCBRECDE,X'00'           END OF VALID RECURSION    21472 69300000
GOTO15   EQU   *                                                  M3364 69400000
         LA    XCTLREG,NMLOAD15         ADDR OF LOAD 15 NAME            69500000
XCTL     EQU   *                                                  M1132 69600000
         L     PARREG0,THISMOD          SHOW XCTL IN TRACE TABLE  20472 69700000
         L     PARREG1,4(,XCTLREG)      SHOW NEXT MOD IN TRACE    20472 69800000
         LA    15,RBEXSAVE              GET ADDR OF AREA FOR PAR. LIST  69900000
         XCTL  EPLOC=(XCTLREG),SF=(E,(15)) PASS CONTROL TO LOAD 7       70000000
         EJECT                                                          70100000
*********************************************************************** 70200000
************************   TASK SELECT ROUTINE   ********************** 70300000
*********************************************************************** 70400000
*                                                                       70500000
*                                                                       70600000
SELECT   EQU   *                                                        70700000
         LTR   SELREG,TCBREG            IS THIS FIRST-TIME ENTRY        70800000
         BP    SELECT1                  NO. BRANCH TO START SELECTION   70900000
         LCR   SELREG,SELREG            YES. RECOMPLEMENT TCB ADDRESS   71000000
SELECT3  LR    TCBREG,SELREG            PASS BACK SELECTED TCB ADDRESS  71100000
         B     4(,LINKREG)              RETURN TO MAIN ROUTINE          71200000
SELECT1  L     SELREG,TCBLTCP           GET DAUGHTER OF INPUT TASK      71300000
SELECT2  LTR   SELREG,SELREG            DOES A DAUGHTER EXIST?          71400000
         BNZ   SELECT3                  YES. SELECTION HAS BEEN MADE    71500000
         L     SELREG,TCBNTCP           NO. GET SISTER                  71600000
         TM    TCBFLGSP,TCBFT           Q.IS SCAN OF TREE FINISHED?     71700000
         BCR   1,LINKREG                YES. RETURN TO MAIN ROUTINE     71800000
         L     TCBREG,TCBOTCP           NO. GET MOTHER                  71900000
         B     SELECT2                  BRANCH TO TEST                  72000000
         EJECT                                                          72100000
* THE FOLLOWING ARE CONSTANTS USED IN THIS LOAD OF ABEND.               72200000
*                                                                       72300000
         DS    0F                                                       72400000
NMLOAD15 DC    CL8'IGC0F01C'            NAME OF NEXT MODULE             72500000
NMDYNAM  DC    CL8'IGG0193H'            TIOT CHECK MODULE         21472 72600000
NMTCAMHK DC    CL8'IEDQOT01'            TCAM PROGRAM          AI  21101 72700021
CONS255  DC    X'FF000000'                                              72800000
SCBCONS  DC    X'FF000010'              CONSTANT TO FREE SCB (16  20472 72900000
*                                        BYTES OF SUBPOOL 255)    M1930 73000000
THISMOD  DC    C'D01C'                  IDENTIFY THIS MODULE            73100000
NMABEND  DC    C'ABENDD'                USED TO IDENTIFY ABEND SVRB     73200000
         EJECT                                                          73300000
*********************************************************************** 73400000
******          ZAP SPACE FOR MAINTENANCE USE                 ********* 73500000
*********************************************************************** 73600000
         SPACE                                                          73700000
         DC    H'0'                                                     73800000
         DC    H'0'                                                     73900000
         DC    H'0'                                                     74000000
         DC    H'0'                                                     74100000
         DC    H'0'                                                     74200000
         DC    H'0'                                                     74300000
         DC    H'0'                                                     74400000
         DC    H'0'                                                     74500000
         DC    H'0'                                                     74600000
         DC    H'0'                                                     74700000
         DC    H'0'                                                     74800000
         DC    H'0'                                                     74900000
         DC    H'0'                                                     75000000
         DC    H'0'                                                     75100000
         DC    H'0'                                                     75200000
         DC    H'0'                                                     75300000
         DC    H'0'                                                     75400000
         DC    H'0'                                                     75500000
         DC    H'0'                                                     75600000
         DC    H'0'                                                     75700000
         DC    H'0'                                                     75800000
         DC    H'0'                                                     75900000
         DC    H'0'                                                     76000000
         DC    H'0'                                                     76100000
         DC    H'0'                                                     76200000
         DC    H'0'                                                     76300000
         DC    H'0'                                                     76400000
         DC    H'0'                                                     76500000
         DC    H'0'                                                     76600000
         DC    H'0'                                                     76700000
         DC    H'0'                                                     76800000
         DC    H'0'                                                     76900000
         EJECT                                                          77000000
         IHBABCTL                                                       77100000
DUBLWORD EQU   X'07'                   MASK TO TEST FOR DOUBLE WORD     77200000
TCBTSTSK EQU   148                     DISPLACEMENT TO TSO FLAG   M3364 77300000
TSOTASK  EQU   X'80'                   TIME SHARING TASK FLAG     M3364 77400000
         EJECT                                                          77500000
         IKJTSCVT                                                       77600000
         EJECT                                                          77700000
         IKJTIOCP                                                       77800000
         EJECT                                                          77900000
         IEZJSCB                                                        78000000
         EJECT                                                          78100000
****                                                               **** 78120021
*        FLOWCHART STATEMENTS FOR ABEND 13                            * 78140021
****                                                               **** 78160021
         SPACE 1                                                        78180021
*/*IEAQTM0D: CHART */                                                   78200000
*/*IEAQTM0D: E ABEND13 */                                               78300021
*/*IGC0D01C: P ESTABLISH ADDRESSABILITY */                              78400021
*/* D (YES,,NO,INITNTRY) VALID ABEND RECURSION */                       78500021
*/* P MOVE TCB ADDR FROM PREVIOUS TO CURRENT ABEND SVRB ESA */          78600021
*/* D (NONE,,QTIP,QTIPREC,TIOT,TRANTEST,TCAM,NOTCAM) WHAT KIND OF VALID 78700021
*/* RECURSION */                                                        78800021
*/*INITNTRY: P SET INPUT TCB = CURRENT TCB */                           79500021
*/* P INDICATE FIRST TIME ENTRY TO TASK SELECT RTN */                   79520021
*/*TASKSEL: S (FND,,NONE,ENDPROC) SELECT: A TASK FROM ABENDING TREE */  79600021
*/*TESTCAM: D (Y,,N,NOTCAM) IS TCAM ACTIVE */                           84700021
*/*TCAMTCB: D (Y,,N,USERTCAM) IS CURR TASK THE TCAM MSG CNTRL TASK */   84800021
*/* P SET ABEND VALID RECURSION FLAG ACROSS TCAM */                     84900021
*/* R SVC 13 PSEUDO LINK */                                             85020021
*/*USERTCAM: P SAVE TCB ADDR IN ESA & ZERO TJID */                      85100000
*/* P GET TJID IF TASK IS A FOREGROUND TASK */                          85200021
*/* S SVC102:KILL PENDING TSO POSTS */                                  85500000
*/*NOTCAM: P CLEAR ABEND VALID RECURSION FLAGS */                       85600021
*/*FREESCBS: P GET SCB ADDR */                                          85700000
*/* D (Y,,N,NOSCB) DOES SCB EXIST */                                    85800000
*/* P DEQ SCB  */                                                       85900021
*/* S (,FREESCBS) FREEMAIN:AREA OCCUPIED BY SCB */                      86000000
*/*NOSCB: $ */                                                          86020021
*/*QTIPHOOK: D (Y,,N,NOQTIP) IS TSO ACTIVE */                           86100000
*/* P SET ABEND VALID RECURSION FLAG ACROSS SVC 101 */                  86200021
*/* P GET TJID IF TASK IS A FOREGROUND TASK */                          86300021
*/* S SVC101:ISSUE QTIP SVC */                                          86600000
*/*QTIPREC: P CLEAR ABEND VALID RECURSION FLAGS */                      86700021
*/*NOQTIP: $ */                                                         86800021
*/*ENQBR: S ENQPURGE:PURGE OUT-STANDING ENQS */                         87000021
*/* P REESTABLISH ADDRESSABILITY */                                     87100021
*/*TRANTEST: $ */                                                       87200021
*/*TRANTS00: P SAVE PREVIOUS RB */                                      87300000
*/*TRANTS01: P GET NEXT RB ON CHAIN */                                  87400000
*/* D (N,,Y,ENDTRANS) IS THIS THE LAST RB */                            87500000
*/* D (Y,,N,TRANTS00) IS THIS AN SVRB */                                87600000
*/* D (Y,,N,TRANTS00) IS THIS A TRANSIENT SVRB */                       87700021
*/* D (Y,,N,NOTABEND) IS THIS ABEND SVRB */                             87800000
*/* P ELIMINATE ABEND INDICATOR IN ESA */                               87900021
*/*NOTABEND: P DEQ THIS SVRB & STORE CURRENT REGS IN TCB */             88000021
*/* S (,TRANTS01) TAHABEND:DEQ SVRB FROM TRANSIENT AREA HANDLER'S Q */  88100021
*/*ENDTRANS: $ */                                                       88200021
*/*TAHABEND: E ENTRY */                                                 90200000
*/* P SET TO BEGIN SEARCH ON TRANS AREA REQUEST Q */                    90300021
*/* P GET DISP OF INPUT SVRB ENTRY IN TRANS AREA CNTRL TABLE */         90320021
*/* D (N,,Y,TAHAB1) IS DISPLACEMENT ZERO */                             90400021
*/* P DECREMENT TRANS AREA USER COUNT BY ONE */                         90500021
*/* P SET TO BEGIN SEARCH ON TRANS AREA USER Q */                       90600021
*/*TAHAB1: P GET FIRST/NEXT SVRB ON THE Q BEING SEARCHED */             90700021
*/* D (N,,Y,%TSTQ) SVRB ADDR = 0 (REQ Q ONLY) */                        90800021
*/* D (N,,Y,TAHAB2) SVRB = INPUT SVRB */                                90820021
*/* P (,TAHAB1) GET NEXT SVRB */                                        90920021
*/*TAHAB2: P REMOVE THE SVRB FROM THE Q BEING SCANNED */                91020021
*/*%TSTQ: D (N,,Y,SPID255) SEARCH DONE ON REQUEST Q */                  91120021
*/*TAHAB3: D (Y,,N,SPID255) DEQ'D RB ONLY USER OF THIS TRANS AREA */    91400021
*/* P INDICATE THIS TRANS AREA BLOCK IS FREE NOW */                     91500021
*/*SPID255: $ */                                                        91600021
*/*DEACTRB: P TURN OFF THE ACTIVE BIT IN THE SVRB */                    91700021
*/* D (Y,,N,%TDNREG) SVRB CREATED DYNAMICALLY */                        91800021
*/* S FREEMAIN:AREA OCCUPIED BY RB IN SP255 */                          92000021
*/*%TDNREG: R RETURN */                                                 92100021
*/*ENDPROC: D (NO,,YES,GOTO15) IS THIS JOBSTEP TCB */                   92120000
*/* D (YES,,NO,GOTO15) TSO TASK */                                      92140000
*/* D (NO,,YES,TIOTREC) TIOT REC */                                     92160000
*/* P SET ABEND VAL RECURS FLG ACROSS TIOT (IGG0193H) PROCESSING */     92180021
*/* R SVC 13 PSEUDO LINK */                                             92184021
*/*TIOTREC: P CLEAR ABEND VALID RECURSION FLAGS */                      92188021
*/*GOTO15: P FLAG TRACE AND SET XCTL PARAM LIST */                      92196021
*/* R ABEND15 */                                                        92196821
*/*SELECT: E ENTRY */                                                   92196900
*/* P SET SELECTED TCB = INPUT TCB */                                   92197021
*/* D (YES,,NO,SELECT1) 1ST TIME ENTRY */                               92197600
*/* P RESET 1ST TIME ENTRY INDICATOR */                                 92198421
*/*SELECT3: P SET OUTPUT TCB = SELECTED TCB */                          92199221
*/* R RETURN - FND */                                                   92199321
*/*SELECT1: P SET SEL TCB = DAUGHTER OF OUTPUT TCB */                   92199421
*/*SELECT2: D (NO,,YES,SELECT3) SELECTED TCB EXIST */                   92199521
*/* P SET SEL TCB = SISTER OF OUTPUT TCB */                             92199621
*/* D (NO,,YES,%OUTA) OUTPUT TCB = ABENDING TCB */                      92199721
*/* P (,SELECT2) SET SEL TCB = MOTHER OF OUTPUT TCB */                  92199821
*/*%OUTA: R RETURN - NONE */                                            92199921
*/*IEAQTM0D: END */                                                     92200000
         END                                                            92300000
