         TITLE 'IEAQTM0F / ABEND15 - PRB''S CDE PURGE / IGC0F01C'       00100021
*                                                                       00200021
IGC0F01C START                                                          00300021
*                                                                       00400021
*  THE FOLLOWING CODE IS THE LOAD 15 OF THE ABEND SERVICE ROUTINE       00500021
*                                                                       00600021
* ROUTINE NAME - ABEND15                                                00700021
*                                                                       00800021
*                                                                       00900021
* FUNCTIONS-                                                            01000021
*                                                                       01100021
*     1. INITIALIZATION                                                 01200021
*                                                                       01300021
*        ABEND15 IS ENTERED SUCH THAT THE TOP TASK IN THE FAMILY OF     01400021
*        TASKS THAT ARE ABENDING (THE 'T' TASK) IS THE CURRENTLY        01500021
*        DISPATCHED TASK.  THE ADDRESS OF THE 'T' OR CURRENT TASK       01600021
*        IS SAVED.                                                      01700021
*                                                                       01800021
*     2. TASK SELECTION                                                 01900021
*                                                                       02000021
*        THIS TASK SELECT ROUTINE IS DIFFERENT FROM THOSE IN            02100021
*        OTHER ABEND MODULES IN THAT TCBREG (4) RATHER THAN             02200021
*        ATCBREG (13) IS THE INPUT AND OUTPUT REGISTER. THIS            02300021
*        IS BECAUSE REGISTER 4 IS NEEDED AS AN INPUT REGISTER           02400021
*        FOR RESIDENT CODE AS THE ADDRESS OF THE TCB TO BE              02500021
*        MANIPULATED. TCBREG AND ATCBREG ARE THEREFORE REVERSED         02600021
*        IN THIS MODULE. SINCE THE 'T' BIT IS ALWAYS ON IN THE          02700021
*        TOP ABENDING TASK WHICH MUST BE THE INITIAL INPUT TCB,         02800021
*        THE 'T' BIT IS USED TO INDICATE WHEN THE WHOLE TREE            02900021
*        HAS BEEN SELECTED.                                             03000021
*                                                                       03100021
*     3. INITIALIZE FOR PRBCHK                                          03200021
*                                                                       03300021
*        THE PRBCHK ROUTINE OF ABEND15 IS INITIALLY ENTERED WITH        03400021
*        THE ADDRESS OF THE TOP RB OF THE SELECTED TASK.                03500021
*                                                                       03600021
*     4. PRBCHK - PROCESS PRB                                           03700021
*                                                                       03800021
*        EACH RB IS CHECKED IN TURN AND IF THE RB IS A PRB, THE         03900021
*        FOLLOWING PURGES ARE PERFORMED.                                04000021
*                                                                       04100021
*        IF THE CDE FIELD IS ZERO, THERE IS NO SPECIAL                  04200021
*        PROCESSING AND CONTROL IS PASSED TO STEP 5 BELOW.              04300021
*        IF THE CDE FIELD IS NOT ZERO, THE FOLLOWING                    04400021
*        CDE  PROCESSING IS PERFORMED TO PURGE THIS RB                  04500021
*        FROM THE CONTENTS DIRECTORY QUEUES.                            04600021
*                                                                       04700021
*        A.CDE FOR MODULE NOT IN STORAGE                                04800021
*          IF THE CDE POINTED TO BY THE SELECT RB DESCRIBES             04900021
*          A PROGRAM WHICH IS NOT IN STORAGE, THE ADDRESS               05000021
*          OF THE MAJOR CDE FOR THAT PROGRAM IS ACQUIRED.               05100021
*          IF A FETCH WORK AREA HAS BEEN ACQUIRED FOR THE               05200021
*          SELECT RB, IT IS FREED.  IF THE RB POINTED TO                05300021
*          BY THE CDE IS NOT THE SELECT RB (IE. THE SELECT              05400021
*          RB DOES NOT CONTROL THE RESOURCE), THE SELECT RB             05500021
*          IS DEQUEUED FROM THE CDE RB QUEUE, AND CONTROL               05600021
*          IS PASSED TO STEP 5.  IF THE CDE RB IS THE SAME              05700021
*          AS THE SELECT RB (THE SELECT RB CONTROLS THE                 05800021
*          RESOURCE), EACH RB ON THE PGMQ (CDE RB QUEUE) OF             05900021
*          THE SELECT RB IS ACCESSED, THE ADDRESS OF                    06000021
*          CDCONTROL IS STORED  IN THE RESUME PSW (IN ORDER             06100021
*          TO RESTART THE REQUEST FOR THE PROGRAM), THE                 06200021
*          WAIT COUNT, CDE, AND PGMQ FIELDS OF THE QUEUED               06300021
*          RB ARE ZEROED, THE CDE USE COUNT IS DECREMENTED,             06400021
*          THE FETCH WORK AREA, IF ALLOCATED, IS FREED AND              06500021
*          THE ADDRESS OF THE TCB ASSOCIATED WITH THE QUEUED            06600021
*          RB IS PASSED AS INPUT TO THE TASK SWITCH ROUTINE.            06700021
*          UPON RETURN FROM THE TASK SWITCH ROUTINE, THE                06800021
*          EXTENT LIST AND PROGRAM AREA OF THE MAJOR CDE ARE            06900021
*          FREED IF THEY WERE ACQUIRED, AND THE MAJOR CDE               07000021
*          AND ALL OF ITS MINOR CDE'S ARE DEQUEUED FROM THE             07100021
*          JOB PACK AREA CONTROL QUEUE (JPACQ) OR LINK PACK             07200021
*          AREA QUEUE (LPAQ) AND THEN FREED. CONTROL THEN               07300021
*          PASSES TO STEP 5.                                            07400021
*                                                                       07500021
*        B. CDE FOR SERIALLY REUSABLE PROGRAM                           07600021
*          IF THE CDE DESCRIBES A SERIALLY RESUSABLE PROGRAM            07700021
*          AND THE RB POINTED TO BY THE CDE IS NOT THE                  07800021
*          SELECT RB (IE. THE SELECT RB DOES NOT CONTROL                07900021
*          THE RESOURCE), THE SELECT RB IS DEQUEUED FROM                08000021
*          THE CDE RB QUEUE, THE USE/RESPONSIBILITY COUNT               08100021
*          IN THE CDE IS DECREMENTED BY 1, AND CONTROL PASSES           08200021
*          TO STEP 5.  IF THE PROGRAM DESCRIBED IS SERIALLY             08300021
*          REUSABLE AND THE CDE RB IS THE SELECT RB (IE. THE            08400021
*          SELECT RB CONTROLS THE RESOURCE), EACH RB ON THE             08500021
*          PGMQ (CDE RB QUEUE) OF THE SELECT RB IS ACCESSED.            08600021
*          THE ADDRESS OF CDCONTROL IS STORED IN THE RESUME             08700021
*          PSW (IN ORDER TO RESTART THE REQUEST FOR THE                 08800021
*          PROGRAM), THE WAIT COUNT, CDE, AND PGMQ FIELDS OF            08900021
*          THE QUEUED RB ARE ZEROED, THE CDE USE COUNT IS               09000021
*          DECREMENTED, AND THE ADDRESS OF THE TCB ASSOCIATED           09100021
*          WITH THE QUEUED RB IS PASSED AS INPUT TO THE TASK            09200021
*          SWITCH ROUTINE.  UPON RETURN FROM THE TASK SWITCH            09300021
*          ROUTINE, THE SERIALLY REUSABLE FLAG IN THE CDE               09400021
*          IS ZEROED AND THE NON-REUSABLE FLAG IS SET.  THEN            09500021
*          THE RESIDENT CDHKEEP ROUTINE IS ENTERED TO PURGE             09600021
*          THE CDE IF APPROPRIATE.  CONTROL IS THEN PASSED              09700021
*          TO STEP 5.                                                   09800021
*                                                                       09900021
*        C. CDE FOR PROGRAM WHICH IS NOT SERIALLY REUSABLE              10000021
*                                                                       10100021
*          IF THE CDE DESCRIBES A PROGRAM WHICH IS IN CORE              10200021
*          AND IS NOT SERIALLY REUSABLE, THE USE COUNT IN THE           10300021
*          CDE IS DECREMENTED BY 1 AND THE CDHKEEP ROUTINE              10400021
*          IS ENTERED FOR THIS CDE.  AFTER CDHKEEP RETURNS              10500021
*          FROM PURGING THE CDE, CONTROL IS PASSED TO STEP 5.           10600021
*                                                                       10700021
*     5. TESTLAST- TEST NEXT RB                                         10800021
*                                                                       10900021
*        THE SAVED RB ADDRESS IS COMPARED TO THE TCB ADDRESS TO         11000021
*        DETERMINE WHETHER THE LAST RB HAS BEEN PROCESSED.  IF THE      11100021
*        LAST RB HAS BEEN PROCESSED, CONTROL PASSES TO ''TASKSEL''      11200021
*        WHICH SELECTS THE NEXT TCB AND CONTINUES THE PROCESS OF        11300021
*        HANDLING PRBS.                                                 11400021
*                                                                       11500021
*     6. WHEN ALL PRBS FOR ALL TASKS OF THE ABENDING TREE               11600021
*        HAVE BEEN PROCESSED, ABEND15 WILL XCTL TO ABEND16              11700021
*        TO FINISH ABEND PROCESSING.                                    11800021
*                                                                       11900021
*                                                                       12000021
*                                                                       12100021
* ENTRY POINT NAMES -   IGC0F01C                                        12200021
*                                                                       12300021
* CONTAINED IN MODULE - IEAQTM0F                                        12400021
*                                                                       12500021
* ATTRIBUTES- TYPE 4 SVC, REENTRANT, SUPERVISOR STATE,                  12600021
*             PARTIALLY ENABLED                                         12700021
*                                                                       12800021
* APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                12900021
*                                                                       15800021
* SVC USAGE-   EXIT,XCTL                                                15900021
*                                                                       16000021
* INPUT-       NONE                                                     16100021
*                                                                       16200021
* OUTPUT-      NONE                                                     16300021
*                                                                       16400021
* ENTRY POINTS-                                                         16500021
*                                                                       16600021
*        IGC0F01C -                                                     16700021
*           A. PSW                                                      16800021
*                1. DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT         16900021
*                MACHINE CHECK.                                         17000021
*                2. UNDER SUPERVISOR PROTECTION KEY.                    17100021
*                3. IN SUPERVISOR MODE.                                 17200021
*                                                                       17300021
*           B. REGISTERS                                                17400021
*                1. REGISTER 3 CONTAINS THE ADDRESS OF THE              17500021
*                COMMUNICATIONS VECTOR TABLE (CVT).                     17600021
*                2. REGISTER 4 CONTAINS THE ADDRESS OF THE CURRENTLY    17700021
*                DISPATCHED TCB (THE TOP ABENDING TCB).                 17800021
*                3. REGISTER 5 CONTAINS THE ADDRESS OF THE CURRENT      17900021
*                RB (THE ABEND SVRB).                                   18000021
*                                                                       18100021
* EXIT POINTS- XCTL TO IGC0G01C                                         18200021
*                                                                       18300021
*                                                                       25600021
* RESTRICTIONS ON USE OF ROUTINE - NONE                                 25700021
*                                                                       25800021
*                                                                       25900021
* NOTES-   THIS CODE IS NOT CHARACTER CODE DEPENDENT.                   26000021
         EJECT                                                          26100021
*                                                                       26200021
*                                                                       26300021
* FOLLOWING ARE THE REGISTER ASSIGNMENTS USED IN THIS MODULE            26400021
*                                                                       26500021
*                                                                       26600021
PARREG0  EQU   0                        PARAMETER REG 0, WORK REG       26700021
PARREG1  EQU   1                        PARAMETER REG 1, WORK REG       26800021
SUBREG   EQU   1                        RETURN REG FROM QDRBS SUBROUT.  26900021
WKRBREG  EQU   1                        RB ADDRESS IN CDE               27000021
HKBASE   EQU   2                        ENTRY POINT TO CDHKEEP          27100021
SCVTREG  EQU   2                        ADDRESS OF THE SECONDARY CVT    27200021
CVTREG   EQU   3                        ADDRESS OF THE CVT              27300021
TCBREG   EQU   4                        ADDRESS OF TCB TO BE PURGED     27400021
RBREG    EQU   5                        ADDRESS OF CURRENT RB           27500021
ARBREG   EQU   6                        ADDRESS OF RB FOR PURGE         27600021
CDEREG   EQU   7                        ADDRESS OF CDE TO BE PURGED     27700021
XREG     EQU   8                        RB QUEUED ON RBPGMQ OF RB       27800021
DECRET   EQU   8                        RETURN ADDR FROM CDE USE  20472 27900021
*                                        CNT DECREMENT ROUTINE    20472 28000021
BASEREG  EQU   9                        BASE REGISTER                   28100021
TESTREG  EQU   10                       REG USED FOR EXTENT LIST PROC.  28200021
LINKREG  EQU   10                       RETURN REG FROM TASK SELECT     28300021
TSWIREG  EQU   10                       TCB ADDR- INPUT TO TASK SWITCH  28400021
PREVCDE  EQU   10                       ADDR OF PREVIOUS CDE ON JPACQ   28500021
XCTLREG  EQU   10                       ADDR OF NEXT LOAD NAME          28600021
ENTRYTSW EQU   11                       ENTRY PT. OF TASK SWITCH ROUT.  28700021
WKCDE    EQU   11                       CDE ADDR- INPUT TO CDHKEEP      28800021
OUTCDCHK EQU   11                       BRANCH OUT ADDR OF CDE   A32002 28900021
*                                        ON JPQ TEST             A32002 29000021
NXTCDE   EQU   12                       ADDR OF NEXT CDE ON JPACQ       29100021
RBSUBREG EQU   12                       RETURN ADDR FROM RBQUEUED SUBRT 29200021
SELREG   EQU   12                       USED BY TASK SELECT             29300021
CDHKPRET EQU   13                       RETURN REG FROM CDHKEEP         29400021
ATCBREG  EQU   13                       ADDRESS OF CURRENT TCB          29500021
RETREG   EQU   14                       RETURN ADDRESS FROM SUBROUT.S   29600021
FREERMN  EQU   14                       ENTRY POINT OF REGMAIN          29700021
FMBRREG  EQU   14                       ENTRY POINT OF FREEMAIN         29800021
XRET     EQU   14                       RETURN REG FROM DQRB SUBROUTINE 29900021
SAVEREG  EQU   15                       RB SAVE REG USED IN QDRBS SUBRT 30000021
ZREG     EQU   15                       WORK RB REG USED IN DQRB SUBRT  30100021
TCBRREG  EQU   15                       TEMP REG USED TO GET JSTCB ADDR 30200021
         EJECT                                                          30300021
IGC0F01C CSECT                                                          30400021
ABEND15  BALR  BASEREG,0                ESTABLISH ADDRESSIBILITY        30500021
         USING *,BASEREG        9                                       30600021
         USING TCBSECT,ATCBREG  D       DSECT FOR CURRENT TCB           30700021
         USING TCBDSECT,TCBREG  4       DSECT FOR ALTERNATE TCB         30800021
         USING CVTSECT,CVTREG   3                                       30900021
         USING SCVTSECT,SCVTREG 2       DSECT FOR ABEND CVT             31000021
         USING RBSECT,RBREG     5       DSECT FOR CURRENT RB            31100021
         USING RBSECT2,ARBREG   6       DSECT FOR ALTERNATE RB          31200021
*                                                                       31300021
         MVI   RBEXSAVE+45,C'F'         FLAG SVRB AS THIS MODULE  21472 31400021
         MVI   TCBRECDP,X'00'           CANCEL TIOT REC FLGS      M4567 31500021
         L     SCVTREG,CVTABEND         LOAD ADDRESS OF SECONDARY CVT   31600021
         LR    ATCBREG,TCBREG           LOAD CURRENT TCB ADDR           31700021
*                                                                       31800021
*  NOTE - THE CURRENT TCB IS IN REGISTER 13 FOR THE DURATION            31900021
*         OF THIS MODULE EXCEPT DURING THE BRANCH TO HKPROC.            32000021
*                                                                       32100021
         EJECT                                                          32200021
*********************************************************************** 32300021
*                                                                       32400021
         LCR   TCBREG,TCBREG            READY FOR TASK SELECT           32500021
*                                                                       32600021
TASKSEL  EQU   *                                                        32700021
         BAL   LINKREG,SELECT           SELECT TASK FOR PURGE           32800021
         B     GOTO16                   ALL THRU, XCTL TO NEXT MOD      32900021
*                                                                       33000021
*                                                                       33100021
         L     ARBREG,TCBRBPP           GET RB ADR OF ALTERNATE TCB.    33200021
PRBCHK   EQU   *                                                        33300021
         LA    ARBREG,0(,ARBREG)        CLEAR HIGH ORDER BYTE.          33400021
         TM    RBSTAB2,RBFTP            Q. IS THIS A PRB                33500021
         BNZ   TESTLAST                 NO. GET NEXT RB                 33600021
         L     CDEREG,RBCDE2-1          LOAD CDE PTR                    33700021
         LA    CDEREG,0(,CDEREG)        CLEAR HIGH ORDER BYTE           33800021
         LTR   CDEREG,CDEREG            Q,IS PRB CREATED BY SYNCH       33900021
         BNZ   CDTERM                   NO. BRANCH TO PURGE CDE- RETURN 34000021
*                                       WILL BE AT NEXT INSTRUCTION     34100021
TESTLAST EQU   *                                                        34200021
         TM    RBSTAB2+1,RBTCBNXT       DOES THIS RB POINT TO TCB?      34300021
         BO    TASKSEL                  YES. GET NEXT TASK              34400021
         L     ARBREG,RBLINK2-1         GET LINK FIELD OF NXT.RB ON Q.  34500021
         B     PRBCHK                   NOW CHECK NEXT RB               34600021
         EJECT                                                          34700021
*********************************************************************** 34800021
***************************** CDTERM SUBROUTINE *********************** 34900021
*********************************************************************** 35000021
*                                                                       35100021
* THE FOLLOWING CODE IS CONTAINED ENTIRELY WITHIN ABEND AND PERFORMS    35200021
* THE FOLLOWING FUNCTIONS-                                              35300021
*                                                                       35400021
*  1. DEQUEUES REQUESTS FOR SERIALLY REUSABLE RESOURCES WHEN THE PRB    35500021
*     GIVEN AS INPUT IS PRESENTLY USING THE RESOURCE.                   35600021
*                                                                       35700021
*  2. IF OTHER REQUESTORS OF A SERIALLY REUSABLE RESOURCE ARE QUEUED    35800021
*     THEN THE PRBS ARE ALTERED TO BRING IN A NEW COPY OF THE RESOURCE. 35900021
*                                                                       36000021
*  3. THE PROGRAMS, EXTENT LIST AND CDE OF THE SELECT PRB ARE           36100021
*     FREED IF THE PRB IS FOR A PROGRAM WHICH HAS BEEN                  36200021
*     PARTIALLY LOADED.                                                 36300021
*                                                                       36400021
*                                                                       36500021
CDTERM   EQU   *                                                        36600021
*                                                                       36700021
*   XXXXXXXXXXXXXXX                                                     36800021
         USING CDESECT,CDEREG           SET ADDRESSIBILITY FOR CDE DSEC 36900021
*   XXXXXXXXXXXXXXX                                                     37000021
*                                                                       37100021
         TM    CDATTR1,CDEMINOR        IS THIS A MINOR CDE              37200021
         BZ    CDTERM1                 NO, PROCEED                      37300021
         L     CDEREG,CDXLMJP-1        YES, LOAD MAJOR POINTER          37400021
         LA    CDEREG,0(,CDEREG)       CLEAR THE HIGH ORDER BYTE        37500021
*                                                                       37600021
CDTERM1  EQU   *                                                        37700021
*                                                                       37800021
         TM    CDATTR1,CDENIS           Q,IS LOAD MODULE IN STORAGE     37900021
*                                                                       38000021
         BC    1,MODNIC                 NO. PARTIALLY LOADED PROG       38100021
*                                                                       38200021
         TM    CDATTR1,CDESER+CDEREN    IS PROG SERIALLY REUSABLE       38300021
         BC    4,SERUSE                 YES. REQUEUE OTHER USERS        38400021
*                                       NO. PURGE THE CDE               38500021
SETDEC   EQU   *                                                        38600021
         BAL   DECRET,DECUSE            BR TO DECREMENT USE COUNT 20472 38700021
         EJECT                                                          38800021
*********************************************************************** 38900021
*****************************CDHKEEP INTERFACE************************* 39000021
*********************************************************************** 39100021
*                                                                       39200021
* ENTRY POINT - CDHKEEP  - OBTAINED FROM ABEND CVT.                     39300021
*                                                                       39400021
* THE REGISTER REQUIREMENTS ARE AS FOLLOWS-                             39500021
*                                                                       39600021
*        CVTREG - 3   CVT REGISTER                                      39700021
*        TCBREG - 4   ADDR OF TCB OF SUBJECT PRB.                       39800021
*                                                                       39900021
*        WKCDE -11   ADDR OF SUBJECT MAJOR CDE.                         40000021
*        CDHKPRET - 13  RETURN ADDRESS                                  40100021
*                                                                       40200021
*     TRANSPARENT REGISTER 3-7,9,13                                     40300021
*                                                                       40400021
HKPPROC  EQU   *                                                        40500021
*                                                                       40600021
         LR    WKCDE,CDEREG             LOAD CDE PARAMETER REG.         40800021
         OI    SCVTFMSA,SCVTSW2         SET SW TO CAUSE EXIT      M3806 40900021
*                                        TO DO COND FREE          M3806 41000021
         L     HKBASE,SCVTHSKP                                 AI 21472 41020021
         BALR  CDHKPRET,HKBASE          BALR TO CDHKEEP                 41100021
         L     ATCBREG,CVTTCBP          LOAD POINTER TO NEW AND OLD     41200021
         L     ATCBREG,4(ATCBREG)       RESTORE ADDRESS OF CURRENT TCB  41300021
         L     SCVTREG,CVTABEND         RELOAD ADDRESS OF ABEND CVT     41400021
         NI    SCVTFMSA,255-SCVTSW2     RESET CONDIT FREE SWITCH  21472 41500021
         B     TESTLAST                 BRANCH TO GET NEXT RB           41600021
         EJECT                                                          41700021
* DECRUSE1 AND DECUSE WERE COMBINED INTO A SUBROUTINE IN RELEASE        41800021
* 20 BECAUSE OF SPACE CONSIDERATIONS BEFORE THE MODULE SPLIT.           41900021
*                                                                       42000021
*                                                                       42100021
DECRUSE1 EQU   *                                                        42200021
         LA    DECRET,TESTLAST          SET RETURN TO GET NEXT PRB      42300021
         SPACE 5                                                        42400021
DECUSE   EQU   *                                                        42500021
         SR    PARREG1,PARREG1          CLEAR REGISTER                  42600021
         IC    PARREG1,CDUSE            GET USE RESPONSIBILITY COUNT    42700021
*                                       FROM CDE.                       42800021
*                                                                       42900021
* PRIOR TO RELEASE 20, THE CDE FOR MODULES IN THE LINK PACK AREA        43000021
* KEPT TRACK OF THE NUMBER OF USERS OF THAT MODULE. A WRAP AROUND       43100021
* WOULD OCCUR IF 256 REQUESTS WERE MADE FOR THE SAME MODULE AT          43200021
* THE SAME TIME.                                                        43300021
* FROM RELEASE 20 ON, THE CDE FOR A MODULE IN THE LPA WILL NOT          43400021
* REFLECT THE NO. OF CURRENT USERS OF THE MODULE. FOR SUCH MODULES,     43500021
* ABEND SHOULD NOT DECREMENT THE USE COUNT. THE NEXT TWO INSTRUCTIONS   43600021
* ARE FOR THE PURPOSE OF SKIPING THE DECREMENT IF NECESSARY.            43700021
*                                                                       43800021
         TM    CDATTR1,CDENIP           WAS MODULE LOADED BY NIP  M0102 43900021
         BCR   1,DECRET                 YES. DON'T DECR USE CNT   M0102 44000021
         BCTR  PARREG1,0                REDUCE COUNT BY ONE             44100021
         STC   PARREG1,CDUSE            STORE UPDATED USE COUNT.        44200021
         BR    DECRET                   RETURN TO CALLER ADDR     20472 44300021
         EJECT                                                          44400021
SERUSE   BAL   XRET,DQRB                BR TO DQRB SUBROUTINE           44500021
         BC    15,DECRUSE1              RET= CURR. RB DOES NOT OWN      44600021
*                                       RESOURCE AND HAS BEEN DEQUEUED  44700021
*                                       FROM THE CDE RB QUEUE (PGMQ).   44800021
         BAL   SUBREG,QDRBS             RET= CURR. RB OWNS RESOURCE-    44900021
*                                       RESTART OTHER REQUESTORS        45000021
*                                                                       45100021
RESET    EQU   *                                                        45200021
         NI    CDATTR1,255-CDESER-CDEREN TURN OFF SER REUSABLE FLAG     45300021
         OI    CDATTR1,CDENFN           TURN ON NON REUSABLE FLAG       45400021
         B     SETDEC                   RETURN TO DECREMENT USE COUNT.  45500021
         EJECT                                                          45600021
MODNIC   EQU   *                                                        45700021
*                                                                       45800021
* AT THIS TIME CDEREG HAS THE ADDRESS OF A MAJOR CDE FOR A              45900021
* PROGRAM WHICH IS NOT IN MAIN STORAGE.                                 46000021
*                                                                       46100021
         LR    XREG,ARBREG              LOAD PARAMETER REG TO RBQUEUED  46200021
         BAL   RBSUBREG,FREEFWA         CHECK TO FREE FETCH WORK        46300021
         BAL   XRET,DQRB                BR TO DQRB SUBROUTINE           46400021
         B     TESTLAST                 RET= CURR. RB DOES NOT OWN      46500021
*                                       RESOURCE AND HAS BEEN DEQUEUED  46600021
*                                       FROM THE CDE RB QUEUE (PGMQ).   46700021
* IF THE CURRENT RB OWNS THE RESOURCE, THE RETURN FROM DQRB WILL BE     46800021
* AT THE FOLLOWING INSTRUCTION.                                         46900021
*                                                                       47000021
*   XXXXXXXXXXXXXXX                                                     47100021
         DROP  RBREG                                                    47200021
         USING RBSECT,XREG              SET UP ADDR. FOR DSECT          47300021
*   XXXXXXXXXXXXXXX                                                     47400021
*                                                                       47500021
FETCHLUP L     XREG,RBPGMQ-1            LOAD RB THAT IS QUEUED          47600021
         LA    XREG,0(,XREG)            CLEAR HIGH ORDER BYTE           47700021
         LTR   XREG,XREG                Q. ANY RB'S QUEUED              47800021
         BZ    QDRBSLNK                 BR TO RESTART OTHER REQUESTORS  47900021
         BAL   RBSUBREG,FREEFWA         BR AND LINK TO FREE FETCH WORK  48000021
*                                        FOR THAT RB                    48100021
         B     FETCHLUP                 PICK UP NEXT RB ON QUEUE        48200021
*                                                                       48300021
*   XXXXXXXXXXXXXXX                                                     48400021
         DROP  XREG                                                     48500021
         USING RBSECT,RBREG             SET UP ADDR. FOR DSECT          48600021
*   XXXXXXXXXXXXXXX                                                     48700021
         EJECT                                                          48800021
QDRBSLNK EQU   *                                                        48900021
         BAL   SUBREG,QDRBS             BRANCH AND LINK TO QRBSUB RTNE. 49000021
*                                       TO RESTART OTHER REQUESTORS     49100021
*                                        OF THIS PARTIALLY LOADED       49200021
*                                        PROGRAM.                       49300021
         TM    CDATTR2,CDEXLE           Q,HAS EXTENT LIST BEEN FORMED   49400021
         BC    12,REMCDE                NO. DEQUEUE AND FREE CDE        49500021
         L     PARREG1,CDXLMJP-1        LOAD ADDRESS OF EXTENT LIST     49600021
         LA    PARREG1,0(,PARREG1)       CLEAR HIGH ORDER BYTE          49700021
         L     PARREG0,DISNELM(,PARREG1) PICK UP NO OF ELEMENTS         49800021
         SLL   PARREG0,3                MULTIPY BY NO. OF BYTES         49900021
         LR    TESTREG,PARREG1          ADD BEGINNING OF EXTENT LIST    50000021
         AR    TESTREG,PARREG0          POINT TO NXT TO LAST WORD IN    50100021
*                                       EXTENT LIST                     50200021
         OC    5(3,TESTREG),5(TESTREG) HAS PROG AREA BEEN ACQUIRED LOOB 50300021
         BC    8,FREEXL                 NO,BRANCH                       50400021
         LA    TESTREG,8(,PARREG1)      LOAD LENGTHS                    50500021
         ST    TESTREG,RBEXSAVE         ST ADDR OF LENGTHS IN PARLIST   50600021
         SRL   PARREG0,1                DIVIDE BY 2                     50700021
         AR    TESTREG,PARREG0          ADD BEGIN OF ADDRESSES          50800021
         ST    TESTREG,RBEXSAVE+4       ST ADDR OF ADDRESSES            50900021
         MVI   RBEXSAVE+8,X'80'         END OF LIST INDICATOR           51000021
         TM    CDATTR1,CDEJPA           Q,IS PGM FROM PRIVATE LIBRARY   51100021
         MVI   RBEXSAVE+9,252           LOAD SUBPOOL 252                51200021
         BC    12,*+8                                                   51300021
         MVI   RBEXSAVE+9,251           LOAD SUBPOOL 251                51400021
         LA    PARREG1,RBEXSAVE         LOAD ADDR OF PARAMETER LIST     51500021
         L     FMBRREG,SCVTLFRM         LOAD FMLIST FORM OF FREE ENTRY  51600021
         OI    SCVTFMSA,SCVTSW1         SET SWITCH TO CAUSE       M3806 51700021
*                                        CONDITIONAL FREEMAIN     M3806 51800021
         BALR  RETREG,FMBRREG           BRANCH AND LINK TO FREE MAIN    51900021
         NI    SCVTFMSA,255-SCVTSW1     RESET CONDITIONAL         M3806 52000021
*                                        FREEMAIN SWITCH          M3806 52100021
         SPACE 3                                                        52200021
FREEXL   L     PARREG1,CDXLMJP-1        LOAD ADDRESS OF EXTENT LIST     52300021
         LA    PARREG1,0(,PARREG1)      CLEAR HIGH ORDER BYTE           52400021
         L     PARREG0,0(,PARREG1)      LOAD SIZE OF EXTENT LIST        52500021
         O     PARREG0,K255             OR SUBPOOL NUMBER INTO PARAM.   52600021
         L     FREERMN,SCVTRMBR         LOAD BRANCH ENTRY               52700021
         BALR  RETREG,FREERMN           BRANCH LINK TO FREE EXTENT LIST 52800021
         EJECT                                                          52900021
REMCDE   EQU   *                                                        53000021
*                                                                       53100021
*   XXXXXXXXXXXXXXX                                                     53200021
         DROP  ATCBREG                                                  53300021
         USING TCBSECT,TCBRREG                                          53400021
*   XXXXXXXXXXXXXXX                                                     53500021
*                                                                       53600021
         L     TCBRREG,TCBJSTCP         LOAD JOB STEP TCB ADDR   A28415 53700021
*                                                                       53800021
* BECAUSE OF THE METHOD THAT CONTENTS SUPERVISION (QLK) LOADS MODULES,  53900021
* A CDE FOR A MODULE THAT IS NOT IN CORE CAN BE ON THE LINKPACK         54000021
* QUEUE. THIS IS BECAUSE THE CDE DOESN'T REALLY BELONG ON THE JOBPACK   54100021
* QUEUE AND MUST BE PUT SOMEWHERE WHILE QLK RELEASES CONTROL (LOADING   54200021
* A LOADABLE ONLY MODULE FOR EXAMPLE). IF A TASK ABENDS WHILE TRYING    54300021
* TO BRING THE MODULE IN, THE CDE MUST BE FREED AND DEQUEUED. IF A CDE  54400021
* EXISTS FOR A MODULE NOT IN CORE AND THE CDE IS NOT ON THE JOBPACK     54500021
* OR THE LINKPACK QUEUE, THE CDE MUST BE FREED BUT THERE IS NO          54600021
* NEED TO DEQUEUE IT.                                                   54700021
*                                                                       54800021
         LA    PREVCDE,TCBJPQ           FIRST CHECK JPQ FOR CDE  A32002 54900021
         LA    OUTCDCHK,NOTONJPQ  SET OUT ADDR FOR INITIAL CHECK A32002 55000021
         SPACE 3                                                        55100021
CHECKCDE L     NXTCDE,0(,PREVCDE)       LOAD CDE ADDRESS                55200021
         LA    NXTCDE,0(,NXTCDE)        CLEAR HIGH ORDER BYTE           55300021
         CR    CDEREG,NXTCDE            IS THIS SUBJECT CDE             55400021
         BC    8,FREECDE                YES, BR TO FREE CDE             55500021
         LTR   NXTCDE,NXTCDE            Q. ANY MORE CDES?        A32002 55600021
         BCR   8,OUTCDCHK               NO BR OUT OF CHECK       A32002 55700021
         LR    PREVCDE,NXTCDE           SAVE ADDR OF PREVIOUS CDE       55800021
         BC    15,CHECKCDE              BR TO CHECK NEXT CDE ON QUEUE   55900021
FREECDE  L     NXTCDE,CDCHAIN-1         LOAD ADDR OF NEXT CDE           56000021
         LR    PARREG1,CDEREG           LOAD ADDR OF CDE TO BE FREED    56100021
         L     PARREG0,K24F255          LOAD CDE FREEMAIN CONSTANT      56200021
         L     FREERMN,SCVTRMBR         LOAD ADDR OF REGMAIN BR ENTRY   56300021
         BALR  RETREG,FREERMN           BRANCH TO REGMAIN TO FREE CDE   56400021
         LA    CDEREG,0(,NXTCDE)        CLEAR HIGH ORDER BYTE           56500021
         LTR   CDEREG,CDEREG            IS NEXT CDE ADDR ZERO           56600021
         BC    8,REORDER                YES, BR TO REORDER CDE QUEUE    56700021
         TM    CDATTR1,CDEMINOR         IS NEXT CDE A MINOR             56800021
         BC    7,FREECDE                YES, BR TO FREE CDE             56900021
REORDER  EQU   *                                                        57000021
*                                                                       57100021
*   XXXXXXXXXXXXXXX                                                     57200021
         DROP  CDEREG                                                   57300021
         USING CDESECT,PREVCDE                                          57400021
*   XXXXXXXXXXXXXXX                                                     57500021
*                                                                       57600021
         LA    PARREG1,NOTONLPQ+4       Q. WAS THE CDE ON A      A32002 57700021
         CR    PARREG1,OUTCDCHK          QUEUE?                  A32002 57800021
         BE    TESTLAST                 NO. DO NOT DEQUEUE IT    A32002 57900021
         IC    PARREG1,CDATTR1          SAVE ATTRIBUTE OF PREVIOUS CDE  58000021
         ST    NXTCDE,CDCHAIN-1         STORE NEW CDE CHAIN FLD IN PREV 58100021
         STC   PARREG1,CDATTR1          RESTORE ATTRIBUTES OF PREV. CDE 58200021
         B     TESTLAST                 RETURN TO GET NEXT RB           58300021
*                                                                       58400021
*                                                                       58500021
*                                                                       58600021
* SINCE THE CDE WAS NOT ON THE JPQ, THE LPQ MUST BE CHECKED.            58700021
*                                                                       58800021
NOTONJPQ EQU   *                                                        58900021
         L     PREVCDE,CVTQLPAQ      GET ADDRESS OF LINK PACK Q  A32002 59000021
         BAL   OUTCDCHK,CHECKCDE     SET BR ADDR FOR SECOND LOOP A32002 59100021
*                                     AND THEN CHECK LPQ FOR CDE A32002 59200021
*                                                                       59300021
* THE CDE WAS ON NEITHER QUEUE AND MUST BE FREED BUT NOT DEQUEUED.      59400021
*                                                                       59500021
NOTONLPQ BAL   OUTCDCHK,FREECDE      BRANCH TO FREE THE CDE      A32002 59600021
*                                                                       59700021
* AT THIS POINT 'OUTCDCHECK' IS ONLY USED AS A SWITCH. CONTROL          59800021
* WILL NEVER BE RETURNED HERE FROM THE BRANCH AND LINK.                 59900021
*                                                                       60000021
*   XXXXXXXXXXXXXXX                                                     60100021
         DROP  TCBRREG                                                  60200021
         USING TCBSECT,ATCBREG                                          60300021
         DROP  PREVCDE                                                  60400021
         USING CDESECT,CDEREG                                           60500021
*   XXXXXXXXXXXXXXX                                                     60600021
         EJECT                                                          60700021
**********************************************************************  60800021
****************************   DQRB   ********************************  60900021
**********************************************************************  61000021
*                                                                       61100021
* DQRB TESTS IF THE SELECT PRB (ARBREG) IS POINTED TO BY THE CDE        61200021
* (CDEREG), IN OTHER WORDS, DOES THE SELECT PRB OWN THE RESOURCE.       61300021
* IF YES, RETURN IS MADE TO THE RETURN ADDRESS IN XRET, PLUS 4.         61400021
* IF THE SELECT PRB IS NOT THE PRB POINTED TO BY THE CDE, THE           61500021
* PGMQ FIELD OF THE CDE RB IS SEARCHED FOR THE SELECT PRB.  WHEN        61600021
* THE SELECT PRB IS FOUND, IT IS REMOVED FROM THE PGMQ, AND             61700021
* RETURN IS MADE TO THE ADDRESS IN XRET.                                61800021
*                                                                       61900021
*        INPUT                                                          62000021
*              ARBREG -  THE PRB BEING PROCESSED                        62100021
*              CDEREG -  CDE POINTED TO BY THE SELECT PRB               62200021
*                                                                       62300021
*        RETURN                                                         62400021
*              XRET   -  RETURN ADDRESS- DEQUEUE HAS BEEN PERFORMED     62500021
*              XRET+4 -  RETURN ADDRESS- RBRMREG OWNS RESOURCE- NO DQ.  62600021
*                                                                       62700021
*                                                                       62800021
*   XXXXXXXXXXXXXX                                                      62900021
         DROP  RBREG                                                    63000021
         USING RBSECT,WKRBREG                                           63100021
*   XXXXXXXXXXXXXXX                                                     63200021
*                                                                       63300021
DQRB     EQU   *                                                        63400021
         L     WKRBREG,CDRBP-1          LOAD RB ADDR FROM CDE           63500021
         LA    WKRBREG,0(,WKRBREG)      CLEAR HIGH ORDER BYTE           63600021
         LTR   WKRBREG,WKRBREG          IS ADDRESS ZERO           25109 63700021
         BZ    4(,XRET)                 YES, RETURN TO RET ADDR+4 25109 63800021
*                                                                       63900021
*    THE ABOVE CHECK IS NECESSARY SINCE THE ABEND MAY HAVE        25109 64000021
* OCCURRED BEFORE THE RB ADDRESS WAS UPDATED IN THE CDE.          25109 64100021
*                                                                       64200021
         CR    WKRBREG,ARBREG           DOES SUBJ PRB OWN CDE           64300021
         BE    4(,XRET)                 YES, RETURN TO RET ADDR + 4     64400021
CHKAGN   EQU   *                                                        64500021
         L     ZREG,RBPGMQ-1            LOAD PGMQ LINK FIELD OF RB      64600021
         LA    ZREG,0(,ZREG)            ZERO HIGH ORDER BYTE            64700021
         LTR   ZREG,ZREG                IS THE RBPGMQ ZERO              64800021
         BCR   8,XRET                   YES, RETURN TO CALLER           64900021
         CR    ARBREG,ZREG              IS SUBJ PRB FOUND ON PGMQ       65000021
         BC    8,UNDO                   YES, BR TO DEQUEUE SUBJ PRB     65100021
         LR    WKRBREG,ZREG             SAVE PREVIOUS PRB ON PGMQ       65200021
         BC    15,CHKAGN                BR TO CHECK NEXT PRB            65300021
UNDO     EQU   *                                                        65400021
         MVC   RBPGMQ(3),RBQFIELD(ZREG) DEQUEUE SUBJ PRB FROM PGMQ      65500021
         BCR   15,XRET                  RETURN TO CALLER                65600021
*                                                                       65700021
*   XXXXXXXXXXXXXXX                                                     65800021
         DROP  WKRBREG                                                  65900021
         USING RBSECT,RBREG                                             66000021
*   XXXXXXXXXXXXXXX                                                     66100021
         EJECT                                                          66200021
*********************************************************************** 66300021
****************                    QDRBS          ******************** 66400021
*********************************************************************** 66500021
*                                                                       66600021
* REGISTERS AT ENTRANCE AND EXIT-                                       66700021
*                                                                       66800021
*                   SUBREG (1) - RETURN ADDRESS                         66900021
*                   CVTREG (3) - ADDRESS OF THE CVT                     67000021
*                   ARBREG (6) - RB OWNING CDE TO BE PURGED             67100021
*                                                                       67200021
QDRBS    L     XREG,RBPGMQ2-1           LOAD RB THAT IS QUEUED          67300021
*                                                                       67400021
*   XXXXXXXXXXXXXXX                                                     67500021
         DROP  RBREG                                                    67600021
         USING RBSECT,XREG              SET UP ADDRESSIBILITY FOR DSECT 67700021
*   XXXXXXXXXXXXXXX                                                     67800021
*                                                                       67900021
TESTFQRB LA    XREG,0(,XREG)            CLEAR HIGH ORDER BYTE           68000021
         LTR   XREG,XREG                ANY RB'S QUEUED                 68100021
         BCR   8,SUBREG                 NO, BRANCH                      68200021
         MVI   RBWCF,X'00'              ZERO WAIT COUNT IN QUEUED RB    68300021
         L     SCVTREG,CVTABEND         LOAD ABEND SECONDARY CVT.       68400021
         L     PARREG0,SCVTCDCL         LOAD ADDR OF CDCONTROL          68500021
         ST    PARREG0,RBOPSW+4         STORE CDCONTROL IN RHOPSW IN RB 68600021
         L     SAVEREG,RBPGMQ-1         LOAD Q,D RB                     68700021
         XC    RBPGMQ(3),RBPGMQ         ZERO LINK FIELD FOR SERIALLY    68800021
*                                       REUSABLE PROGRAMS               68900021
         SR    PARREG0,PARREG0          CLEAR WORK REGISTER             69000021
         IC    PARREG0,CDUSE            GET USE RESPONSIBILITY COUNT    69100021
         BCTR  PARREG0,0                DECREMENT COUNT IN CDE BY ONE   69200021
         STC   PARREG0,CDUSE            UPDATE USE RESPONSIBILITY COUNT 69300021
         XC    RBCDE-1(4),RBCDE-1       ZERO CDE POINTER IN RB          69400021
TESTAGAN TM    RBSTAB+1,RBTCBNXT        DOES RB POINT TO TCB            69500021
         BC    1,PREPTS                 YES BRANCH                      69600021
         L     XREG,RBLINK-1            LOAD LINK FIELD OF RB           69700021
         LA    XREG,0(,XREG)            CLEAR HIGH ORDER BYTE           69800021
         BC    15,TESTAGAN              BRANCH TO TST AGAIN             69900021
PREPTS   EQU   *                                                        70000021
         L     TSWIREG,RBLINK-1         LOAD TCB ADDR OF Q'D RB         70100021
         LA    TSWIREG,0(,TSWIREG)      CLEAR HIGH ORDER BYTE           70200021
         EJECT                                                          70300021
*********************************************************************** 70400021
********            TASK SWITCH SUBROUTINE INTERFACE             ****** 70500021
*********************************************************************** 70600021
*                                                                       70700021
* THE TASK SWITCH ROUTINE IS A RESIDENT ROUTINE THAT PERFORMS THE       70800021
* FUNCTION OF TASK SWITCHING.                                           70900021
*                                                                       71000021
*  INPUT    TSWIREG -10   SUBJECT TASK'S TCB ADDR                       71100021
*                                                                       71200021
*           ENTRYTSW-11   ENTRY POINT OF TASK SWITCH ROUTINE            71300021
*                                                                       71400021
*           RETREG - 14   RETURN ADDR REGISTER                          71500021
*                                                                       71600021
*  TRANSPARENT REGISTERS ,0-9,12,13,15                                  71700021
SWITCH   EQU   *                                                        71800021
*                                                                       71900021
         L     ENTRYTSW,SCVTTASW        LOAD ENTRY POINT OF TASK        72000021
*                                       SWITCH ROUTINE                  72100021
         BALR  RETREG,ENTRYTSW          BRANCH TO TASK SWITCH ROUTINE   72200021
         LR    XREG,SAVEREG             RESTORE REGISTER                72300021
         BC    15,TESTFQRB              RETURN TEST NXT ON QUEUE.       72400021
*                                                                       72500021
*   XXXXXXXXXXXXXXX                                                     72600021
         DROP  XREG                     DROP ADDRESSIBILITY FOR DSECT.  72700021
         USING RBSECT,RBREG                                             72800021
*   XXXXXXXXXXXXXXX                                                     72900021
         EJECT                                                          73000021
*********************************************************************   73100021
******************      FREE FETCH WORK AREA      *******************   73200021
*********************************************************************   73300021
*                                                                       73400021
*   XXXXXXXXXXXXXXX                                                     73500021
         DROP  RBREG                                                    73600021
         USING RBSECT,XREG                                              73700021
*   XXXXXXXXXXXXXXX                                                     73800021
*                                                                       73900021
*                                                                       74000021
FREEFWA  EQU   *                                                        74100021
         TM    RBCDFLGS,RBCDWAE        HAS A WORK AREA BEEN ACQUIRED    74200021
         BCR   12,RBSUBREG             NO, BRANCH                       74300021
*                                                                       74400021
* THE CODE TO FIX APAR 14871 WAS ELIMINATED IN RELEASE 21               74500021
* BECAUSE THE ADDITION OF CONDITIONAL FREEMAIN PRECLUDES AN INVALID     74600021
* FREEMAIN RECURSION. THUS A POSSIBLE STEAL CORE FOR CLOSE DOES NOT     74700021
* CAUSE PROBLEMS BY HAVING PREVIOUSLY FREED THE CORE FREED NOW.         74800021
*                                                                       74900021
*  THE FOLLOWING CODE FREES THE WORK AREA ACQUIRED BY LINK              75000021
         L     PARREG1,RBEXSAVE        LOAD ADDR OF WORK AREA    A14871 75100021
         L     PARREG0,X500S252        SIZE=500 FROM SP252              75200021
         L     FREERMN,SCVTRMBR        LOAD ENTRYPOINT TO REGMAIN       75300021
         OI    SCVTFMSA,SCVTSW1        SET SWITCH TO CAUSE        M3806 75400021
*                                       CONDITIONAL FREEMAIN      M3806 75500021
         BALR  RETREG,FREERMN          BRANCH LINK TO FREE WORK AREA    75600021
         NI    SCVTFMSA,255-SCVTSW1    RESET CONDITIONAL          M3806 75700021
*                                       FREEMAIN SWITCH           M3806 75800021
         NI    RBCDFLGS,255-RBCDWAE    TURN OFF FETCH WORK AREA FLAG    75900021
SKIPFREE BCR   15,RBSUBREG             SUBROUTINE LINKAGE        A14871 76000021
*                                                                       76100021
*   XXXXXXXXXXXXXXX                                                     76200021
         DROP  XREG                                                     76300021
         USING RBSECT,RBREG                                             76400021
*   XXXXXXXXXXXXXXX                                                     76500021
*                                                                       76600021
         EJECT                                                          76700021
*********************************************************************** 76800021
* TASK SELECTION SUBROUTINE.                                            76900021
*********************************************************************** 77000021
*                                                                       77100021
*                                                                       77200021
SELECT   EQU   *                                                        77300021
         LTR   SELREG,TCBREG            IS THIS FIRST-TIME ENTRY        77400021
         BP    SELECT1                  NO. BRANCH TO START SELECTION   77500021
         LCR   SELREG,SELREG            YES. RECOMPLEMENT TCB ADDRESS   77600021
SELECT3  LR    TCBREG,SELREG            PASS BACK SELECTED TCB ADDRESS  77700021
         B     4(,LINKREG)              RETURN TO MAIN ROUTINE          77800021
SELECT1  L     SELREG,TCBLTCP           GET DAUGHTER OF INPUT TASK      77900021
SELECT2  LTR   SELREG,SELREG            DOES A DAUGHTER EXIST?          78000021
         BNZ   SELECT3                  YES. SELECTION HAS BEEN MADE    78100021
         L     SELREG,TCBNTCP           NO. GET SISTER                  78200021
         TM    TCBFLGSP,TCBFT           Q.IS SCAN OF TREE FINISHED?     78300021
         BCR   1,LINKREG                YES. RETURN TO MAIN ROUTINE     78400021
         L     TCBREG,TCBOTCP           NO. GET MOTHER                  78500021
         B     SELECT2                  BRANCH TO TEST                  78600021
         EJECT                                                          78700021
*********************************************************************** 78800021
GOTO16   EQU   *                                                        78900021
         LA    XCTLREG,NMLOAD16         GO TO NEXT LOAD FOR MORE PURGES 79000021
         L     PARREG1,4(,XCTLREG)      SHOW NEXT MODULE          20472 79100021
         L     PARREG0,THISMOD          FLAG XCTL FOR TRACE             79200021
         LA    15,RBEXSAVE                                              79300021
         XCTL  EPLOC=(XCTLREG),SF=(E,(15))                              79400021
         EJECT                                                          79500021
*********************************************************************** 79600021
         DS    0F                                                       79700021
K24F255  DC    X'FF000018'             FREEMAIN CONSTANT FOR IRB        79800021
K255     DC    X'FF000000'             SPECIFY SUBPOOL 255              79900021
X500S252 DC    X'FC000500'             CONS- SIZE 500, SP 252           80000021
THISMOD  DC    C'F01C'                 FLAG FOR XCTL TRACE        20472 80100021
NMLOAD16 DC    C'IGC0G01C'             RB PURGE MODULE                  80200021
         EJECT                                                          80300021
*                                                                       80400021
*                                                                       80500021
*             THE FOLLOWING CODE IS ZAP SPACE FOR MAINTANENCE USE       80600021
*                                                                       80700021
*                                                                       80800021
*                                                                       80900021
         DC    H'0'                                                     81000021
         DC    H'0'                                                     81100021
         DC    H'0'                                                     81200021
         DC    H'0'                                                     81300021
         DC    H'0'                                                     81400021
         DC    H'0'                                                     81500021
         DC    H'0'                                                     81600021
         DC    H'0'                                                     81700021
         DC    H'0'                                                     81800021
         DC    H'0'                                                     81900021
         DC    H'0'                                                     82000021
         DC    H'0'                                                     82100021
         DC    H'0'                                                     82200021
         DC    H'0'                                                     82300021
         DC    H'0'                                                     82400021
         DC    H'0'                                                     82500021
         DC    H'0'                                                     82600021
         DC    H'0'                                                     82700021
         DC    H'0'                                                     82800021
         DC    H'0'                                                     82900021
         DC    H'0'                                                     83000021
         DC    H'0'                                                     83100021
         DC    H'0'                                                     83200021
         DC    H'0'                                                     83300021
         DC    H'0'                                                     83400021
         DC    H'0'                                                     83500021
         DC    H'0'                                                     83600021
         DC    H'0'                                                     83700021
         DC    H'0'                                                     83800021
         DC    H'0'                                                     83900021
         DC    H'0'                                                     84000021
         DC    H'0'                                                     84100021
         DC    H'0'                                                     84200021
         DC    H'0'                                                     84300021
         DC    H'0'                                                     84400021
         DC    H'0'                                                     84500021
         DC    H'0'                                                     84600021
         DC    H'0'                                                     84700021
         DC    H'0'                                                     84800021
         DC    H'0'                                                     84900021
         DC    H'0'                                                     85000021
         EJECT                                                          85100021
         IHBABCTL                                                       85200021
RBQFIELD EQU   25                       DISPL OF PGM Q FIELD IN RB      85300021
RBCDWAE  EQU   X'08'                   FETCH WORK AREA EXISTS           85400021
DISNELM  EQU   4                       NO OF ELEMENTS IN EXTENT LIST    85500021
CDENIP   EQU   X'80'               MODULE LOADED BY NIP (IN LPA)  M0102 85600021
         EJECT                                                          85620021
****                                                               **** 85640021
*        FLOWCHART STATEMENTS FOR ABEND 15                            * 85660021
****                                                               **** 85680021
         SPACE 1                                                        85684021
*/*IEAQTM0F: CHART */                                                   85688021
*/*IEAQTM0F: E ABEND 15 */                                              85692021
*/*IGC0F01C: P ESTABLISH ADDRESSABILITY */                              85696021
*/*          P CLEAR ABEND VALID RECURS FLAGS */                        85696821
*/*          P INDICATE FIRST TIME ENTRY TO TASK SELECT RTN */          85697621
*/*TASKSEL:  S (NONE,,FND,%FOUND) SELECT: SELECT A TASK FROM THE        85698421
*/*ABENDING TREE */                                                     85699221
*/*          R ABEND 16 */                                              85699321
*/*%FOUND:   P GET TOP RB FROM SELECTED TCB */                          85699421
*/*PRBCHK:   D (YES,,NO,TESTLAST) IS RB A PRB */                        85699521
*/*          D (NO,,YES,CDTERM) CDE EXIST */                            85799521
*/*TESTLAST: D (NO,,YES,TASKSEL) LAST RB ON CHAIN */                    85899521
*/*          P (,PRBCHK) GET NEXT PREVIOUS RB */                        85919521
*/*CDTERM:   P GET MAJOR CDE */                                         85939521
*/*          D (YES,,NO,MODNIC) LOAD MODULE IN CORE */                  85959521
*/*          D (NO,,YES,SERUSE) PGM SER REUSABLE */                     85979521
*/*SETDEC:   S DECUSE: DECREMENT THE USE COUNT IN THE CDE */            85983521
*/*          P SET 'CONDITIONAL FREEMAIN' SW IN SCVT */                 85987521
*/*          S CDHKEEP: PURGE THE CDE */                                85991521
*/*          P (,TESTLAST) RESET THE 'CONDITIONAL FREEMAIN' SW */       85995521
*/*SERUSE:   S (DEQD,,NODQ,%TOQDRBS) DQRB: DEQ THE RB IF IT DOES NOT    85996321
*/*OWN THE RESOURCE */                                                  85997121
*/*          S (,TESTLAST) DECUSE: DECREMENT THE USE COUNT IN THE CDE   85997921
*/**/                                                                   85998721
*/*%TOQDRBS: S QDRBS: RESTART OTHER REQUESTORS OF THE RESOURCE */       85998821
*/*          P (,SETDEC) TURN OFF SER REUSABLE FLG AND TURN ON NON -    85998921
*/*REUSABLE FLG IN CDE */                                               85999021
*/*MODNIC:   S FREEFWA: FREE ANY ACQUIRED FETCH WORK AREA */            85999121
*/*          S (NODQ,,DEQD,TESTLAST) DQRB: DEQ THE RB IF IT DOES NOT    85999221
*/*OWN THE RESOURCE */                                                  85999321
*/*FETCHLUP: P GET NEXT RB ON THE CDE RB QUEUE */                       85999421
*/*          D (YES,,NO,QDRBSLNK) RB EXIST */                           86099421
*/*          S (,FETCHLUP) FREEFWA: FREE ANY ACQUIRED FETCH WORK AREA   86119421
*/**/                                                                   86139421
*/*QDRBSLNK: S QDRBS: RESTART OTHER REQUESTORS OF THE RESOURCE */       86159421
*/*          D (YES,,NO,REMCDE) EXTENT LIST EXIST */                    86179421
*/*          D (YES,,NO,FREEXL) PGM AREA EXIST */                       86183421
*/*          P INDICATE FREEMAIN FROM SUBPOOL 252 */                    86187421
*/*          D (NO,,YES,%FREEPGM) PGM IN PROTECTED CORE */              86191421
*/*          P INDICATE FREEMAIN FROM SUBPOOL 251 */                    86195421
*/*%FREEPGM: P SET 'CONDITIONAL FREEMAIN' SW IN SCVT */                 86196221
*/*          S FREEMAIN: FREE THE FROGRAM AREA */                       86197021
*/*          P RESET 'CONDITIONAL FREEMAIN' SW */                       86197821
*/*FREEXL:   S FREEMAIN: FREE THE EXTENT LIST FROM SUBPOOL 255 */       86198621
*/*REMCDE:   P SET INPUT QUEUE TO JOBPACK QUEUE */                      86198721
*/*          S CHECKCDE: FREE CDE IF FND ON INPUT Q. RTN IF NOT FND */  86198821
*/*          P SET INPUT QUEUE TO LINK PACK QUEUE */                    86199021
*/*          S CHECKCDE: FREE CDE IF FND ON INPUT Q. RTN IF NOT FND */  86199121
*/*          P (,FREECDE) INDICATE CDE NOT FOUND ON A QUEUE */          86199321
*/*DECUSE:   E ENTRY */                                                 86299321
*/*          D (NO,,YES,%DECRTN) MODULE LOADED BY NIP */                86319321
*/*          P DECREMENT THE USE COUNT IN THE CDE BY ONE */             86339321
*/*%DECRTN:  R RETURN */                                                86359321
*/*CHECKCDE: E ENTRY */                                                 86379321
*/*          D (NO,,YES,FREECDE) CDE ON INPUT QUEUE */                  86383321
*/*          R RETURN */                                                86387321
*/*FREECDE:  S FREEMAIN: FREE CDE CORE IN SUBPOOL 255 */                86391321
*/*          D (YES,,NO,REORDER) MORE CDES ON INPUT Q */                86395321
*/*          D (NO,,YES,FREECDE) NXT CDE ON Q A MINOR */                86396121
*/*REORDER:  D (YES,,NO,TESTLAST) CDE FOUND ON A Q */                   86396921
*/*          P (,TESTLAST) DEQUEUE THE CDE FROM THE INPUT QUEUE */      86397721
*/*DQRB:     E ENTRY */                                                 86398521
*/*          D (NO,,YES,%NODQ) CDE RB ADDR = 0 */                       86398621
*/*          D (YES,,NO,CHKAGN) PRB OWN CDE */                          86398721
*/*%NODQ:    R RETURN - NODQ */                                         86398821
*/*CHKAGN:   D (YES,,NO,%DEQD) PRB ON REQUESTORS Q */                   86398921
*/*          P DEQUEUE PRB FROM REQUESTORS Q */                         86399021
*/*%DEQD:    R RETURN - DEQD */                                         86399121
*/*QDRBS:    E ENTRY */                                                 86399221
*/*          P GET TOP RB ON RB PGMQ */                                 86499221
*/*TESTFQRB: D (NO,,YES,%ZEROWT) ANY RBS QUEUED */                      86519221
*/*          R RETURN */                                                86539221
*/*%ZEROWT:  P ZERO WAIT COUNT IN QUEUED RB */                          86559221
*/*          P POINT RESUME PSW OF QUEUED RB TO EP OF CDCONTROL */      86579221
*/*          P DECREMENT USE COUNT IN CDE BY ONE. ZERO CDE PTR IN RB */ 86583221
*/*TESTAGAN: D (NO,,YES,PREPTS) RB POINT TO TCB */                      86587221
*/*          P (,TESTAGAN) GET NEXT RB */                               86591221
*/*PREPTS:   S (,TESTFQRB) IEA0DS02: CREATE A TSK SW USING THE TCB OF   86595221
*/*THE Q'D RB */                                                        86596021
*/*FREEFWA:  E ENTRY */                                                 86596821
*/*          D (YES,,NO,SKIPFREE) ANY FETCH WORK AREA */                86597621
*/*          P SET 'CONDITIONAL FREEMAIN' SW IN SCVT */                 86598421
*/*          S FREEMAIN: FREE FETCH WORK AREA CORE FROM SUBPOOL 252 */  86598521
*/*          P RESET THE 'CONDITIONAL FREEMAIN' SW */                   86598621
*/*          P TURN OFF FETCH WORK AREA FLG IN RB */                    86598721
*/*SKIPFREE: R RETURN */                                                86598821
*/*SELECT:   E ENTRY */                                                 86598921
*/*          D (YES,,NO,SELECT1) FIRST TIME ENTRY */                    86599021
*/*          P RESET FIRST TIME ENTRY INDICATOR */                      86599121
*/*          P SET SELECTED TCB TO INPUT TCB */                         86699121
*/*SELECT3:  R RETURN - FND */                                          86719121
*/*SELECT1:  P SET SEL TCB = DAIGHTER OF INPUT TCB */                   86739121
*/*SELECT2:  D (NO,,YES,SELECT3) DAUGHTER EXIST */                      86759121
*/*          P SET SEL TCB = SISTER OF INPUT TCB */                     86779121
*/*          D (NO,,YES,%TSKFND) ENTIRE TCB TREE SCANNED */             86783121
*/*          P (,SELECT2) SET INPUT TCB = MOTHER TCB */                 86787121
*/*%TSKFND:  R RETURN - NONE */                                         86791121
*/*IEAQTM0F: END */                                                     86795121
         END                                                            86799121
