         TITLE 'IEAQTM0G / ABEND16 - SUPERVISOR PURGES / IGC0G01C'      00100021
*                                                                       00200021
IGC0G01C START                                                          00300021
*                                                                       00400021
*  THE FOLLOWING CODE IS SIXTEENTH LOAD OF THE ABEND SERVICE ROUTINE    00500021
*                                                                       00600021
* ROUTINE NAME - ABEND16                                                00700021
*                                                                       00800021
*                                                                       00900021
* FUNCTIONS-                                                            01000021
*                                                                       01100021
*     1. INITIALIZATION                                                 01200021
*                                                                       01300021
*        ABEND16 IS ENTERED SUCH THAT THE TOP TASK IN THE FAMILY OF     01400021
*        TASKS THAT ARE ABENDING (THE 'T' TASK) IS THE CURRENTLY        01500021
*        DISPATCHED TASK.  THE ADDRESS OF THE 'T' OR CURRENT TASK       01600021
*        IS SAVED.                                                      01700021
*                                                                       01800021
*     2. TASK SELECTION                                                 01900021
*                                                                       02000021
*        THE FOLLOWING PURGE FUNCTIONS ARE PERFORMED FOR THE LOWEST     02100021
*        TASK IN THE FAMILY OF TASKS THAT ARE ABENDING.                 02200021
*        THE PURGES ARE PERFORMED WITHOUT SETTING THE                   02300021
*        SELECTED TASK DISPATCHABLE. THE TOP TASK IS ALWAYS THE         02400021
*        CURRENTLY DISPATCHED TASK.                                     02500021
*                                                                       02600021
*                                                                       02700021
*     3. INITIALIZE FOR RBREMOVE                                        02800021
*                                                                       02900021
*        IF THE SELECT TASK IS THE TOP TASK, THE ADDRESS OF THE RB      03000021
*        POINTED TO BY THE ABEND SVRB IS LOADED.  IF THE SELECT TASK    03100021
*        IS NOT THE TOP TASK, THE FIRST RB ON THE TCB RB QUEUE          03200021
*        IS LOADED.                                                     03300021
*                                                                       03400021
*     4. RBREMOVE - PROCESS SVRB, IRB, PRB                              03500021
*                                                                       03600021
*        THE RBREMOVE ROUTINE OF ABEND16 IS ENTERED WITH THE ADDRESS    03700021
*        OF THE RB TO BE PURGED.  THE FOLLOWING PURGES OF THE RB        03800021
*        ARE PERFORMED BASED ON RB TYPE.                                03900021
*                                                                       04000021
*           A. SVRB                                                     04100021
*              IF THE RB IS AN SVRB, IT MUST BE AN SVRB THAT            04200021
*              DESCRIBES A RESIDENT SVC BECAUSE ABEND13 PURGES ALL      04300021
*              SVRBS DESCRIBING TRANSIENT SVRB'S.  THEREFORE, NO        04400021
*              SPECIAL PROCESSING IS REQUIRED AND CONTROL IS PASSED     04500021
*              TO STEP 5 TO DEQUEUE AND FREE THE SVRB.                  04600021
*                                                                       04700021
*           B. IRB                                                      04800021
*              IF THE RB IS AN IRB,ALL IQE,S ARE DEQUEUED FROM THE      04900021
*              IRB AND THE IQE COUNT IN THE IRB IS DECREMENTED          05000021
*              ACCORDINGLY.  IF THE IQE COUNT IN THE IRB IS NOT         05100021
*              ZERO, CONTROL IS PASSED TO STEP 5.  IF THE IQE COUNT     05200021
*              IS ZERO, THE 72 BYTE IRB SAVE AREA, IF PRESENT, IS       05300021
*              FREED FROM SUBPOOL 250, AND THEN CONTROL IS PASSED       05400021
*              TO STEP 5 TO DEQUEUE AND FREE THE IRB.                   05500021
*                                                                       05600021
*           C. PRB                                                      05700021
*              IF THE RB IS A PRB, CONTROL                              05800021
*              IS PASSED TO STEP 5 TO DEQUEUE AND FREE THE PRB.         05900021
*                                                                       06000021
*     5. RBREMOVE - DEQUEUE AND FREE RB                                 06100021
*                                                                       06200021
*        IF THE RB IS THE LAST RB ON THE RB QUEUE OF THE TOP (T) TCB,   06300021
*        THE RB IS ALTERED TO A PRB, THE WAIT COUNT AND CDE FIELDS ARE  06400021
*        ZEROED, AND THE ADDRESS OF AN SVC EXIT INSTRUCTION IS STORED   06500021
*        IN THE RIGHT HALF OF THE PRB'S RESUME PSW.  THE ABOVE          06600021
*        PROCEDURE IS PERFORMED IN ORDER TO ESTABLISH A NORMAL          06700021
*        INTERFACE TO EXIT AND EOT FROM ABEND.                          06800021
*                                                                       06900021
*        IF THE RB IS NOT THE LAST RB OF THE TOP TCB, OR IS AN RB ON    07000021
*        A SUBTASK, THE ADDRESS OF THE NEXT RB IS SAVED AND THE         07100021
*        SELECTED RB IS DEQUEUED FROM THE TCB RB QUEUE.  THE SELECT     07200021
*        RB IS THEN SET INACTIVE.  IF THE RB IS NOT DYNAMICALLY         07300021
*        ACQUIRED, CONTROL IS PASSED TO STEP 6.  OTHERWISE, THE SIZE    07400021
*        OF THE RB IS DEVELOPED, AND THE RB IS FREED FROM SUBPOOL 255   07500021
*        IF IT IS A PRB OR AN SVRB, AND FROM SUBPOOL 253 IF IT IS AN    07600021
*        IRB.                                                           07700021
*                                                                       07800021
*     6. RBREMOVE- TEST NEXT RB                                         07900021
*                                                                       08000021
*        THE SAVED RB ADDRESS IS COMPARED TO THE TCB ADDRESS TO         08100021
*        DETERMINE WHETHER THE LAST RB HAS BEEN PROCESSED.  IF THE      08200021
*        LAST RB HAS BEEN PROCESSED, CONTROL PASSES TO STEP 7.          08300021
*        OTHERWISE, THE SAVED RB IS DESIGNATED THE SELECT RB AND        08400021
*        CONTROL PASSES TO STEP 4 TO PURGE THIS RB.                     08500021
*                                                                       08600021
*     7. LOAD LIST PURGE                                                08700021
*                                                                       08800021
*        BRANCHES TO A RESIDENT LOAD LIST PURGE ROUTINE WHICH DEQUEUES  08900021
*        AND FREES ALL OF THE LOAD LIST ELEMENTS FOR THE SELECT TASK,   09000021
*        DECREMENTS THE USE COUNT IN THE CDE, AND PURGES THE CDE AS     09100021
*        APPROPRIATE.                                                   09200021
*                                                                       09300021
*     8. SPEOT                                                          09400021
*                                                                       09500021
*        BRANCHES TO THE RESIDENT SPEOT ROUTINE (SUBPOOL END OF TASK)   09600021
*        WHICH FREES THE CORE ALLOCATED TO OWNED SPQE'S AND DEQUEUES    09700021
*        AND FREES ALL SPQE'S FOR THE SELECT TCB.                       09800021
*                                                                       09900021
*     9. IF TOP TCB - EXIT                                              10000021
*                                                                       10100021
*        IF THE SELECT TCB IS THE TOP (T) TASK THAT IS ABENDING, THE    10200021
*        COMPLETION CODE IS LOADED INTO REGISTER 15 FROM THE            10300021
*        COMPLETION CODE FIELD OF THE TCB, AND AN SVC 3 IS ISSUED.      10400021
*        (NOTE THAT THE RESUME PSW OF THE NEXT RB POINTS TO AN SVC 3    10500021
*        INSTRUCTION SUCH THAT EXIT WILL BE ENTERED AS IF FROM A PRB).  10600021
*                                                                       10700021
*    10. DEQUEUE TCB                                                    10800021
*                                                                       10900021
*        IF THE SELECT TASK IS NOT THE TOP ABENDING TCB, ABEND16        11000021
*        BRANCHES TO THE RESIDENT DQTCB ROUTINE WHICH DEQUEUES THE      11100021
*        TCB FROM THE TCB READY QUEUE.                                  11200021
*                                                                       11300021
*    11. ERASE TCB                                                      11400021
*                                                                       11500021
*        ABEND8 THEN BRANCHES TO THE RESIDENT ERASE ROUTINE WHICH       11600021
*        UPDATES THE FAMILY RELATIONSHIP QUEUES AND FREES THE CORE      11700021
*        ASSOCIATED WITH THE TCB.  CONTROL IS THEN PASSED ABEND7        11800021
*        IN ORDER TO SELECT THE NEXT TASK TO BE PURGED.                 11900021
*                                                                       12000021
*                                                                       12100021
* ENTRY POINT NAMES -   IGC0G01C                                        12200021
*                                                                       12300021
* CONTAINED IN MODULE - IEAQTM0G                                        12400021
*                                                                       12500021
* ATTRIBUTES- TYPE 4 SVC, REENTRANT, SUPERVISOR STATE,                  12600021
*             PARTIALLY ENABLED                                         12700021
*                                                                       12800021
* APPLICABILITY - OPTION 4 SYSTEMS ONLY.                                12900021
*                                                                       13000021
* SVC USAGE-   EXIT                                                     17000021
*              XCTL TO - IGC0K01C                                       17100021
*                                                                       17200021
* INPUT-       NONE                                                     17300021
*                                                                       17400021
* OUTPUT-      NONE                                                     17500021
*                                                                       17600021
* ENTRY POINTS-                                                         17700021
*                                                                       17800021
*        IGC0G01C -                                                     17900021
*           A. PSW                                                      18000021
*                1. DISABLED FOR ALL MASKABLE INTERRUPTS EXCEPT         18100021
*                MACHINE CHECK.                                         18200021
*                2. UNDER SUPERVISOR PROTECTION KEY.                    18300021
*                3. IN SUPERVISOR MODE.                                 18400021
*                                                                       18500021
*           B. REGISTERS                                                18600021
*                1. REGISTER 3 CONTAINS THE ADDRESS OF THE              18700021
*                COMMUNICATIONS VECTOR TABLE (CVT).                     18800021
*                2. REGISTER 4 CONTAINS THE ADDRESS OF THE CURRENTLY    18900021
*                DISPATCHED TCB (THE TOP ABENDING TCB).                 19000021
*                3. REGISTER 5 CONTAINS THE ADDRESS OF THE CURRENT      19100021
*                RB (THE ABEND SVRB).                                   19200021
*                                                                       19300021
*                                                                       19400021
*                                                                       19500021
* EXIT POINTS-                                                          19600021
*              SVC EXIT - WHEN THE PURGING FUNCTIONS OF ABEND8 (EXCEPT  19700021
*                         TCB DQ AND ERASE) HAVE BEEN PERFORMED FOR     19800021
*                         THE TOP ABENDING TASK, THE COMPLETION CODE    19900021
*                         THE TCBCMP FIELD IS LOADED IN REGISTER        20000021
*                         15 AND AN SVC EXIT IS ISSUED.                 20100021
*                                                                       20200021
* ERROR MESSAGES- NONE                                                  20300021
*                                                                       20400021
* RESTRICTIONS ON USE OF ROUTINE - NONE                                 26300021
*                                                                       26400021
*                                                                       26500021
* NOTES-                                                                26600021
*        1. THIS CODE IS NOT CHARACTER CODE DEPENDENT.                  26700021
*                                                                       26800021
*                                                                       26900021
*        2. IN RELEASE 20.1, A HOOK WAS ADDED TO ABTERM AND THE         27000021
*           RESIDENT SUBROUTINES IN IEAQET WHICH ARE BRANCHED TO        27100021
*           BY THIS MODULE. THE HOOK MAKES ALL BRANCH ENTRIES           27200021
*           INTO FREEMAIN BY ABEND DURING THIS MODULE TO BE             27300021
*           ESSENTIALLY CONDITIONAL. THESE CHANGES WERE MADE TO         27400021
*           INSURE THAT ABEND WOULD NOT LOSE CONTROL DURING ANY         27500021
*           PURGES WHICH WOULD LEAVE SYSTEM CONTROL BLOCK CHAINS        27600021
*           IN SUCH A STATE THAT OTHER SYSTEM ROUTINES WOULD BE         27700021
*           UNABLE TO HANDLE THOSE CONTROL BLOCKS, I.E. A TCB           27800021
*           ON THE READY QUEUE HAVING NO RB.                            27900021
*                                                                       28000021
*        3. THIS MODULE WAS RECOMBINED WITH THE PREVIOUS MODULE         28100021
*           AND SPLIT IN RELEASE 21 TO TAKE IGC0701C OUT OF THE         28200021
*           NUCLEUS AND TO MAKE ABEND MORE MAINTAINABLE.                28300021
*                                                                       28400021
         EJECT                                                          28500021
*                                                                       28600021
*                                                                       28700021
* FOLLOWING ARE THE REGISTER ASSIGNMENTS USED IN THIS MODULE            28800021
*                                                                       28900021
*                                                                       29000021
PARREG0  EQU   0              PARAMETER REG 0, WORK REG                 29100021
PARREG1  EQU   1              PARAMETER REG 1, WORK REG                 29200021
IQEREG   EQU   1              ADDRESS OF IQE CHAINED OFF IRB            29300021
SCVTREG  EQU   2              ADDRESS OF THE SECONDARY CVT              29400021
CVTREG   EQU   3              ADDRESS OF THE CVT                        29500021
ABDELRET EQU   3              RETURN REG FROM LOAD LIST PURGE           29600021
SPEOTREG EQU   3              RETURN REG FROM SPEOT                     29700021
TCBREG   EQU   4              ADDRESS OF TCB TO BE PURGED               29800021
RBREG    EQU   5              ADDRESS OF CURRENT RB                     29900021
RBRMREG  EQU   6              ADDRESS OF RB BEING REMOVED               30000021
ERASEREG EQU   7              ADDRESS OF TCB TO BE ERASED               30100021
BASEREG  EQU   9              BASE REGISTER                             30200021
XCTLREG  EQU   10             ADDR OF NEXT LOAD NAME                    30300021
SAVTCB   EQU   11             SAVE ADDR OF CURRENT TCB                  30400021
RBSAVREG EQU   12             SAVE REG FOR NEXT RB ON QUEUE             30500021
ATCBREG  EQU   13             ADDRESS OF CURRENT TCB                    30600021
RETREG   EQU   14             RETURN ADDRESS FROM SUBROUTINES           30700021
ENTRYREG EQU   14             ENTRY POINT OF ROUTINES                   30800021
FREERMN  EQU   14             ENTRY POINT OF REGMAIN                    30900021
COMPREG  EQU   15             COMPLETION CODE REG FOR EXIT              31000021
         EJECT                                                          31100021
IGC0G01C CSECT                                                          31200021
ABEND16  BALR  BASEREG,0                ESTABLISH ADDRESSIBILITY        31300021
         USING *,BASEREG         9                                      31400021
         USING TCBSECT,ATCBREG   D      DSECT FOR CURRENT TCB           31500021
         USING TCBDSECT,TCBREG   4      DSECT FOR ALTERNATE TCB(FOR     31600021
         USING CVTSECT,CVTREG    3                                      31700021
         USING SCVTSECT,SCVTREG  2      SET ADDRESSIBILITY FOR ABENDCVT 31800021
         USING RBSECT,RBREG      5      DSECTFOR CURRENT RB             31900021
         USING RBSECT2,RBRMREG   6      DSECT FOR ALTERNATE RB          32000021
*                                                                       32100021
         MVI   RBEXSAVE+45,C'G'         FLAG SVRB                       32200021
         L     SCVTREG,CVTABEND         LOAD ADDRESS OF SECONDARY CVT   32300021
         LR    ATCBREG,TCBREG           LOAD CURRENT TCB ADDR           32400021
         OI    SCVTFMSA,SCVTSW2         SET SW TO CAUSE EXIT      M3806 32500021
*                                        TO DO COND FREE          M3806 32600021
         EJECT                                                          32700021
*********************************************************************** 32800021
* THIS IS THE TASK SELECT ROUTINE                                       32900021
* ENTERED WITH THE ADDRESS OF THE CURRENT TCB IN REGISTER 13            33000021
*                                                                       33100021
TASKSEL  EQU   *                                                        33200021
         LR    TCBREG,ATCBREG                                           33300021
CHECKLOW EQU   *                                                        33400021
         OC    TCBLTCP(4),TCBLTCP       Q. IS DAUGHTER PRESENT    20472 33500021
         BZ    RBSET                    NO. HAVE LOWEST TASK. BR  20472 33600021
         L     TCBREG,TCBLTCP           LOAD DAUGHTER                   33700021
         B     CHECKLOW                 BRANCH TO TEST NEXT TCB   20472 33800021
RBSET    EQU   *                                                  20472 33900021
         L     RBRMREG,RBLINK-1         LOAD LINK FIELD OF CURRENT RB   34000021
*                                        JUST IN CASE CURRENT TASK      34100021
*                                        IS THE LOWEST TASK.            34200021
         CR    ATCBREG,TCBREG           Q. TOP TASK SELECTED?           34300021
         BE    CLEARHO                  YES. REMOVE CURRENT RBS         34400021
         L     RBRMREG,TCBRBPP          GET RB ADR OF ALTERNATE TCB.    34500021
CLEARHO  LA    RBRMREG,0(,RBRMREG)      CLEAR HIGH ORDER BYTE.          34600021
         EJECT                                                          34700021
*********************************************************************   34800021
**************************   RBREMOVE      **************************   34900021
*********************************************************************   35000021
*                                                                       35100021
*                                                                       35200021
* RBREMOVE IS A ROUTINE CONTAINED WITHIN ABEND7                         35300021
*                                                                       35400021
* THE INPUT TO THE ROUTINE IS THE FOLLOWING IN RBRMREG-                 35500021
*        1. THE CURRENT RB ON THE RB QUEUE IF THE TCB IS NOT THE        35600021
*      ABENDING TASK.                                                   35700021
*        2. THE RB POINTED TO BY THE ABEND SVRB IF THE CURRENT TASK IS  35800021
*      THE ABENDING TASK.                                               35900021
*                                                                       36000021
* IF THE SELECTED TCB IS THE CURRENT TCB, EACH RB ON THE QUEUE IS       36100021
* PURGED, DEQUEUED AND FREED WITH THE FOLLOWING EXCEPTION-              36200021
*        1. THE HIGHEST LEVEL RB WHICH IS PURGED, CHANGED TO A PRB,     36300021
*      WITH A RESUME PSW WHICH POINTS TO AN SVC EXIT INSTRUCTION.       36400021
*        2. THE ABEND SVRB WHICH IS NOT PURGED, DEQUEUED OR FREED.      36500021
*                                                                       36600021
* IF THE SELECTED TCB IS NOT THE CURRENT TCB, ALL RB'S ON THE QUEUE     36700021
* ARE PURGED, DEQUEUED AND FREED.                                       36800021
* THE RB'S ARE PURGED AND FREED IN THE FOLLOWING MANNER-                36900021
*        1. PRB                                                         37000021
*              THE RB IS DEQUEUED                                       37100021
*              THE RB IS FREED FROM SUBPOOL 255                         37200021
*                                                                       37300021
*        2. IRB                                                         37400021
*              IQE'S ARE DEQUEUED AND THE IQE COUNT IS DECREMENTED      37500021
*          ACCORDINGLY                                                  37600021
*              THE IRB IS DEQUEUED                                      37700021
*              THE IRB IS FREED FROM SUBPOOL 255 IF THE IQE COUNT IS    37800021
*          ZERO AND THE RB IS DYNAMIC                                   37900021
*        3. SVRB                                                        38000021
*              DEQUEUED FROM RB CHAIN                                   38100021
*              THE SVRB IS FREED FROM SUBPOOL 255                       38200021
*              (NOTE- ALL SVRB'S DESCRIBING TRANSIENT SVC'S HAVE BEEN   38300021
*              PURGED IN ABEND11)                                       38400021
*                                                                       38500021
RBREMOVE TM    RBSTAB2,RBFTP            Q. IS THIS AN IRB               38600021
         BNM   TESTOCT                  NO. SKIP IRB PROCESSING         38700021
*                                                                       38800021
*                                                                       38900021
* THE FOLLOWING CODE PERFORMS PROCESSING UNIQUE TO IRB'S                39000021
*ENTERED TO REDUCE COUNT OF Q'D IQE'S                                   39100021
*                                                                       39200021
*                                                                       39300021
         L     IQEREG,RBIQE2-1          LOAD IQE FIELD FROM RB          39400021
LOAD     LA    IQEREG,0(,IQEREG)        CLEAR HIGH ORDER BYTE           39500021
         LTR   IQEREG,IQEREG            IS AN IQE PRESENT               39600021
         BC    8,TESTOCT                NO,BRANCH                       39700021
         SR    PARREG0,PARREG0          CLEAR REGISTER                  39800021
         IC    PARREG0,RBWCSAT2         INSERT COUNT FROM RB            39900021
         BCTR  PARREG0,0                DECREMENT COUNT                 40000021
         STC   PARREG0,RBWCSAT2         STORE UPDATED WAIT COUNT        40100021
         L     IQEREG,IQELINK(IQEREG)   LOAD NEXT IQE ON QUEUE          40200021
         BC    15,LOAD                  RETURN TO PICK UP NXT IQE ON Q. 40300021
         EJECT                                                          40400021
*********************************************************************** 40500021
****************              TESTOTC               ******************* 40600021
*********************************************************************** 40700021
*                                                                       40800021
TESTOCT  CR    TCBREG,ATCBREG           Q,OPERATING FOR CURRENT TASK    40900021
         BC    8,TESTLAST               YES,BRANCH                      41000021
         L     RBSAVREG,RBLINK2-1       GET NEXT RB ON QUEUE            41100021
         LA    RBSAVREG,0(,RBSAVREG)    CLEAR HIGH ORDER BYTE           41200021
         ST    RBSAVREG,TCBRBPP         UPDATE RB PTR IN TCB            41300021
EDACT    NI    RBSTAB2+1,255-RBFACTV    SET RB INACTIVE                 41400021
* FREE CORE IF RB FLAGGED AS DYNAMIC.                                   41500021
         TM    RBSTAB2+1,RBFDYN         CAN RB BE FREED.                41600021
         BC    8,LASTRB                 NO,BRANCH                       41700021
         TM    RBSTAB2,RBSVRB         Q. IS THIS AN SVRB OR PRB?  20472 41800021
         BNM   TSTABEND                 YES. SKIP IRB CHECK       20472 41900021
         TM    RBSTAB2,RBIRB            Q. IS THIS AN IRB         20472 42000021
         BZ    ADFRB                    NO. SKIP IRB PROCESSING   20472 42100021
         CLI   RBIQE2-1,0               Q,IS RB USE COUNT ZERO          42200021
         BC    7,LASTRB                 NO,DON'T FREE IRB.              42300021
         TM    RBSTAB2+1,RBATTN         Q. IS THIS A TAXE?        M0385 42400021
         BZ    NOTTAXE                  NO. DON'T FREE THE TAIE   M0385 42500021
         L     PARREG1,TAIEPTR(,RBRMREG) GET ADDR OF THE TAIE     M0385 42600021
         LA    PARREG1,0(,PARREG1)      CLEAR THE HI BYTE         M0385 42700021
         LTR   PARREG1,PARREG1          Q. IS THERE A TAIE?       M0385 42800021
         BZ    NOTTAXE                  NO. DON'T FREE IT         M0385 42900021
         XC    TAIEPTR+1(3,RBRMREG),TAIEPTR+1(RBRMREG) ZERO PTR   M0385 43000021
         L     PARREG0,K72F250          PICK UP FREEMAIN INFO     M0385 43100021
         L     FREERMN,SCVTRMBR         BRANCH ENTRY TO FREEMAIN  M0385 43200021
         OI    SCVTFMSA,SCVTSW1         SET SWITCH TO CAUSE       M3806 43300021
*                                        CONDITIONAL FREEMAIN     M3806 43400021
         BALR  RETREG,FREERMN           FREE THE TAIE FROM SP 0   M0385 43500021
         NI    SCVTFMSA,255-SCVTSW1     RESET CONDITIONAL         M3806 43600021
*                                        FREEMAIN SWITCH          M3806 43700021
NOTTAXE EQU   *                                                   M0385 43800021
* FREE PP. REG SAVE AREA ASSOCIATED WITH IRB.                           43900021
         L     PARREG1,RBPPSAV2-1       GET ADDRESS OF AREA             44000021
         LA    PARREG1,0(,PARREG1)      CLEAR HIGH ORDER BYTE.          44100021
         LTR   PARREG1,PARREG1          Q,IS SAVE AREA PRESENT.         44200021
         BC    8,ADFRB                  NO. SKIP FREEING                44300021
         L     PARREG0,K72F250          SET FREEMAIN PARAMETERS         44400021
*                                       CVT ADDRESS.                    44500021
         L     FREERMN,SCVTRMBR         LOAD ENTRY POINT TO REGMAIN     44600021
         OI    SCVTFMSA,SCVTSW1         SET SWITCH TO CAUSE       M3806 44700021
*                                        CONDITIONAL FREEMAIN     M3806 44800021
         BALR  RETREG,FREERMN           BRANCH LINK TO FREE SAVE AREA.  44900021
         NI    SCVTFMSA,255-SCVTSW1     RESET CONDITIONAL         M3806 45000021
*                                        FREEMAIN SWITCH          M3806 45100021
* THE FOLLOWING CODE FREES THE RB                                       45200021
ADFRB    LR    PARREG1,RBRMREG          LOAD ADDRESS OF RB TO BE FREED  45300021
         SR    PARREG0,PARREG0          CLEAR REGISTER                  45400021
         IC    PARREG0,RBSIZE2          GET SIZE RB IN DOUBLE WORDS     45500021
         SLL   PARREG0,3                DEVELOP BYTES(DWB WORDS)        45600021
         O     PARREG0,K255             SET SUBPOOL TO 255 FOR PRB/SVRB 45700021
         TM    RBSTAB2,RBFTP            Q. IS THIS A PRB OR SVRB?       45800021
         BM    LASTRB                   NO. BRANCH                      45900021
         L     FREERMN,SCVTRMBR         LOAD ENTRY POINT TO REGMAIN     46000021
*                                                                       46100021
* CONDITIONAL FREEMAIN IS NOT USED BECAUSE RB IS IN PROTECTED CORE.     46200021
*                                                                       46300021
         BALR  RETREG,FREERMN           BRANCH LINK TO FREE RB          46400021
LASTRB   LR    RBRMREG,RBSAVREG         LOAD NEXT RB ON QUEUE           46500021
         CR    TCBREG,RBRMREG           ALL RB'S DEQUEUED               46600021
         BNE   RBREMOVE                 NO. PROCESS NEXT RB       M3329 46700021
LASTRB1  SR    PARREG0,PARREG0          CLEAR REGISTER            M3329 46800021
         ST    PARREG0,TCBRBPP          ZEROS IN TCBRB POINTER    M2785 46900021
         B     LOADREL                  BRANCH TO MORE PURGES     M3329 47000021
*                                                                       47100021
*                                                                       47200021
TSTABEND EQU   *                                                        47300021
         CLI   RBSIZE2,SVRBSIZE         Q. IS THIS A PRB?         20472 47400021
         BNE   ADFRB                    YES. SKIP ABEND CHECK     20472 47500021
         CLC   RBEXSAV2+40(5),NMABEND   Q. IS IT AN ABEND SVRB?   20472 47600021
         BNE   ADFRB                    NO. FREE THE RB           20472 47700021
         MVI   RBEXSAV2+44,C'*'         ELIMINATE ABEND FLAG      20472 47800021
         B     ADFRB                    NOW FREE THE RB           20472 47900021
*                                                                       48000021
*                                                                       48100021
TESTLAST TM    RBSTAB2+1,RBTCBNXT       DOES THIS RB POINT TO TCB       48200021
         BC    1,RBLAST                 YES BRANCH                      48300021
         MVC   RBLINK(3),RBLINK2        DEQUEUE RB WHICH IS BEING DQ'D  48400021
         L     RBSAVREG,RBLINK2-1       GET LINK FIELD OF NXT.RB ON Q.  48500021
         LA    RBSAVREG,0(RBSAVREG)     CLEAR HIGH ORDER BYTE           48600021
         BC    15,EDACT                 BRANCH TO  MAIN LINE OF RBRMVE  48700021
*                                                                       48800021
* THE FOLLOWING CODE PERFORMS SPECIAL PROCESSING FOR THE LAST RB ON RBQ 48900021
*                                                                       49000021
RBLAST   NI    RBSTAB2,X'3F'            ALTER RB TYPE TO PRB            49100021
         SR    PARREG1,PARREG1          CLEAR REGISTER                  49200021
         ST    PARREG1,RBCDE2-1         CLEAR CDE ADDRESS IN RB         49300021
         STC   PARREG1,RBLINK2-1        ZERO RB WAIT COUNT              49400021
         LA    PARREG1,CVTEXIT          LOAD ADDR OF SVC EXIT IN REG    49500021
         ST    PARREG1,RBOPSW2+4        ST ADDR OF SVC EXIT IN OPSW     49600021
*                                                                       49620021
*        B     LOADREL                  BRANCH TO MORE PURGES           49700021
*                                                                       49720021
         EJECT                                                          49800021
*********************************************************************** 49900021
***************************LOAD LIST PURGE***************************** 50000021
*********************************************************************** 50100021
*                                                                       50200021
* THE LOAD LIST PURGE IS A RESIDENT ROUTINE WHICH DECREMENTS THE USE-   50300021
* RESPONSIBILITY COUNT OF THE CDE BY THE LOAD LIST RESPONSIBILITY COUNT 50400021
* IT ALSO RELEASES THE LOAD LIST ELEMENTS. IT INTERFACES WITH ANOTHER   50500021
* RESIDENT MODULE (CDHKEEP) WHICH MAINTAINS THE CONTENTS DIRECTORY      50600021
* QUEUES BASED UPON THE DECREMENTED USE/RESP COUNTS.                    50700021
*                                                                       50800021
* ENTRY POINT - IEAQABL - OBTAINED FROM ABEND CVT                       50900021
*                                                                       51000021
* THE REGISTER REQUIREMENTS ARE AS FOLLOWS-                             51100021
*              TCBREG- 4  TCB ADDR FOR WHICH THE PURGE IS PERFORMED.    51200021
*              ABDELRET- 3 RETURN ADDRESS                               51300021
*                                                                       51400021
*THE ROUTINE ESTABLISHES ITS OWN ADDRESSIBILITY AND USES ALL REGISTERS  51500021
*                                                                       51600021
* ABEND MUST REESTABLISH CVTREG,BASEREG UPON RETURN FROM ROUTINE.       51700021
*                                                                       51800021
LOADREL  EQU   *                                                        51900021
*                                                                       52000021
         L     SCVTREG,CVTABEND         LOAD ADDR OF ABEND CVT.         52100021
         L     ENTRYREG,SCVTPABL        LOAD ADDR OF IEAQABL            52200021
LOADBR   EQU   *                                                        52300021
         BALR  ABDELRET,ENTRYREG        BRANCH TO LOAD PROGRAM RELEASE  52400021
         LA    PARREG0,LOADBR-ABEND16   LOAD DISP FROM BEGIN OF LOAD    52500021
*                                                                       52600021
         LR    BASEREG,ABDELRET         LOAD BASEREG WITH CURRENT ADDR  52700021
         SLR   BASEREG,PARREG0          REESTABLISH BASEADR.            52800021
         L     CVTREG,16                REESTABLISH CVT REGISTER.       52900021
         EJECT                                                          53000021
*********************************************************************** 53100021
****************************** SPEOT INTERFACE ************************ 53200021
*********************************************************************** 53300021
*                                                                       53400021
* SPEOT (SUBPOOL END OF TASK) IS A RESIDENT ROUTINE WHICH PERFORMS THE  53500021
* FOLLOWING FUNCTIONS FOR THE TCB GIVEN AS INPUT.                       53600021
*     . FREES CORE ASSOCIATED WITH OWNED SPQE'S                         53700021
*     . DEQUEUES AND FREES ALL SPQE'S.                                  53800021
*     . RELEASES SUBPOOL 253 CORE ALLOCATED TO THE TCB GIVEN AS INPUT.  53900021
* IF THE TCB GIVEN AS INPUT IS THE JOBSTEP TCB,SPEOT ALSO DEQUEUES AND  54000021
* FREES CONTENT DIRECTORY ENTRIES(CDE'S) AND EXTENT LISTS THAT DESCRIBE 54100021
* PROGRAMS IN THE JOB PACK AREA(JPACQ).                                 54200021
*                                                                       54300021
* ENTRY POINT - IEAQSPET - OBTAINED FROM THE ABEND CVT.                 54400021
* THE REGISTER REQUIREMENTS ARE AS FOLLOWS-                             54500021
*        TCBREG -4   TCB ADDR FOR WHICH THE FUNCTION IS PERFORMED       54600021
*        SPEOTREG -3 RETURN ADDRESS REGISTER.                           54700021
*                                                                       54800021
* TRANSPARENT REGISTERS ARE -   4,5,9                                   54900021
*                                                                       55000021
* ABEND MUST REESTABLISH CVTREG                                         55100021
*                                                                       55200021
PURGEMSS EQU   *                                                        55300021
         TM    TCBNSTAP,RMSCODE         WAS STG RECONF THE CALLER    2K 55400021
         BO    ARNDSPET                 YES, BYPASS SPEOT       R    2K 55500021
         L     SCVTREG,CVTABEND         LOAD ADDR OF ABEND CVT.         55600021
         L     ENTRYREG,SCVTSPET        LOAD ADDR OF SPEOT.             55700021
         BALR  SPEOTREG,ENTRYREG        BRANCH TO SPEOT.                55800021
ARNDSPET EQU   *                                                        55900021
         L     CVTREG,16                REESTABLISH CVTREG.             56000021
         L     ATCBREG,CVTTCBP          LOAD ADDR OF NEW-OLD            56100021
         L     ATCBREG,4(,ATCBREG)      GET ADDR OF CURRENT TCB         56200021
         CR    TCBREG,ATCBREG           OPERATING FOR CURRENT TCB       56300021
         BE    RETURN                   YES. END OF ABEND MAINLINE      56400021
         OI    TCBFLGSP+4,TCBFC         SET TASK COMPLETE               56500021
         EJECT                                                          56600021
*********************************************************************** 56700021
******************************DEQUEUE TCB****************************** 56800021
*********************************************************************** 56900021
*                                                                       57000021
* THE DEQUEUE TCB SUBROUTINE IS A RESIDENT FUNCTION CONTAINED IN THE    57100021
* EOT MODULE                                                            57200021
* ITS FUNCTION IS TO REMOVE FROM THE READY QUEUE A TASK WHICH HAS       57300021
* COMPLETED SUCH THAT WHENEVER THE DISPATCHER IS ENTERED ITS SEARCH OF  57400021
* THE READY QUEUE WILL BE DECREASED.                                    57500021
*                                                                       57600021
* ENTRY POINT - IEADQTCB - OBTAINED FROM THE ABEND CVT.                 57700021
* THE REGISTER REQUIREMENTS ARE AS FOLLWOS-                             57800021
*              TCBREG - 4  ADDR OF TCB TO BE REMOVED FROM READY QUEUE   57900021
*              CVTREG - 3  CVT ADDR                                     58000021
*              RETREG - 14 RETURN ADDR                                  58100021
* REGISTER  1,6,8 ARE VOLATILE                                          58200021
DQTCB    EQU   *                                                        58300021
*                                                                       58400021
         L     SCVTREG,CVTABEND         LOAD ADDR OF SECONDARY CVT      58500021
         L     ENTRYREG,SCVTDQTC        LOAD ADDR OF DQTCB              58600021
         BALR  RETREG,ENTRYREG          BRANCH TO DQ TCB                58700021
         EJECT                                                          58800021
*********************************************************************** 58900021
******************************* ERASE INTERFACE *********************** 59000021
*********************************************************************** 59100021
* ERASE IS A RESIDENT ROUTINE WHICH DEQUEUES A GIVEN TCB FROM THE       59200021
* FAMILY TREE AND FREES THE TCB.                                        59300021
*                                                                       59400021
* INPUT REGISTERS                                                       59500021
*        ERASEREG -7     ADDR OF TCB TO BE ERASED                       59600021
*        RETREG   -14    RETURN REGISTER                                59700021
*                                                                       59800021
*        OUTPUT REGISTERS-                                              59900021
*                      3   CVT ADDRESS                                  60000021
*                      4   ORIGIN TASK OF ERASED TASK                   60100021
*        TRANSPARENT REGISTERS-                                         60200021
*                      2,5,7,9-12,14,15                                 60300021
*                                                                       60400021
         LR    ERASEREG,TCBREG          LOAD TCB TO BE ERASED.          60500021
         LR    SAVTCB,ATCBREG           SAVE CURRENT TCB REG            60600021
         L     RBREG,TCBRBP             RESTORE CURRENT RB REGISTER     60700021
         L     ENTRYREG,SCVTERAS        LOAD ADDR OF ERASE ROUTINE      60800021
         BALR  RETREG,ENTRYREG          BRANCH TO ERASE SUBTASK ROUTINE 60900021
         LR    ATCBREG,SAVTCB           RESTORE ADDR OF CURRENT TCB     61000021
         B     TASKSEL                  RETURN TO MAINLINE        M3806 61100021
         EJECT                                                          61200021
****************************************************************        61300021
*                END OF ABEND PROCESSING                                61400021
****************************************************************        61500021
*                                                                       61600021
RETURN   L     COMPREG,TCBCMP           LOAD REGISTER 15 BEFORE EXIT    61700021
         L     CVTREG,16                REESTABLISH CVT           M3806 61800021
         L     SCVTREG,CVTABEND         LOAD ADDR OF ABEND CVT    M3806 61900021
         NI    SCVTFMSA,255-SCVTSW2     RESET EXIT ABEND FLAG     M3806 62000021
         MVI   RBEXSAVE+44,C'*'         ELIMINATE ABEND FLAG      20472 62100021
         L     PARREG0,THISMOD          FLAG XCTL FOR TRACE       20472 62200021
         TM    TCBNSTAE,RMSCODE         WAS STG RECONF THE CALLER    2K 62300021
         BNO   RETURN2                  NO, GO TO NORMAL EXIT        2K 62400021
         LA    XCTLREG,NMLOADK          YES. GO TO DO IT             2K 62500021
         L     PARREG1,4(,XCTLREG)      SHOW NEXT MODULE          20472 62600021
         LA    15,RBEXSAVE                                              62700021
         XCTL  EPLOC=(XCTLREG),SF=(E,(15))   TO 2K LOAD              2K 62800021
RETURN2  EQU   *                                                        62900021
         L     PARREG1,CHAREXIT         FLAG FOR TRACE            20472 63000021
         SVC   3                        EXIT FROM MODULE.               63100021
         EJECT                                                          63200021
*********************************************************************** 63300021
*                        CONSTANTS                                      63400021
*********************************************************************** 63500021
*                                                                       63600021
         DS    0F                                                       63700021
K72F250  DC    X'FA000048'             FREEMAIN FOR IRB WORK SPACE      63800021
K255     DC    X'FF000000'             SPECIFY SUBPOOL 255              63900021
NMLOADK  DC    CL8'IGC0K01C'                                            64000021
THISMOD  DC    C'G01C'                  INDICATE MODULE FOR XCTL  20472 64100021
CHAREXIT DC    C'EXIT'                  FLAG FOR TRACE            20472 64200021
NMABEND  DC    C'ABEND'                 ABEND FLAG FOR SVRB       20472 64300021
RMSCODE  EQU   X'01'                    TO TEST IF RMS IS CALLER        64400021
*                                                                       64500021
         EJECT                                                          64600021
*                                                                       64700021
*                                                                       64800021
*             THE FOLLOWING CODE IS ZAP SPACE FOR MAINTANENCE USE       64900021
*                                                                       65000021
*                                                                       65100021
*                                                                       65200021
         DC    H'0'                                                     65300021
         DC    H'0'                                                     65400021
         DC    H'0'                                                     65500021
         DC    H'0'                                                     65600021
         DC    H'0'                                                     65700021
         DC    H'0'                                                     65800021
         DC    H'0'                                                     65900021
         DC    H'0'                                                     66000021
         DC    H'0'                                                     66100021
         DC    H'0'                                                     66200021
         DC    H'0'                                                     66300021
         DC    H'0'                                                     66400021
         DC    H'0'                                                     66500021
         DC    H'0'                                                     66600021
         DC    H'0'                                                     66700021
         DC    H'0'                                                     66800021
         DC    H'0'                                                     66900021
         DC    H'0'                                                     67000021
         DC    H'0'                                                     67100021
         DC    H'0'                                                     67200021
         DC    H'0'                                                     67300021
         DC    H'0'                                                     67400021
         DC    H'0'                                                     67500021
         DC    H'0'                                                     67600021
         DC    H'0'                                                     67700021
         DC    H'0'                                                     67800021
         DC    H'0'                                                     67900021
         DC    H'0'                                                     68000021
         DC    H'0'                                                     68100021
         DC    H'0'                                                     68200021
         EJECT                                                          68300021
         IHBABCTL                                                       68400021
RBIRB    EQU   X'40'                    RBTYPE IS AN IRB          20472 68500021
RBSVRB   EQU   X'C0'                    RBTYPE IS AN SVRB         20472 68600021
SVRBSIZE EQU   X'12'                    SIZE IN DBLWDS OF SVRB    20472 68700021
TAIEPTR  EQU   132                      DISP OF TAIE IN TAXE      M0385 68800021
RBATTN   EQU   X'20'                    MASK FOR ATTN IRB FLAG    M0385 68900021
         EJECT                                                          68920021
****                                                               **** 68940021
*        FLOWCHART STATEMENTS FOR ABEND 16                            * 68960021
****                                                               **** 68980021
         SPACE 1                                                        68984021
*/*IEAQTM0G: CHART */                                                   68988021
*/*IEAQTM0G: E ABEND 16 */                                              68992021
*/*IGC0G01C: P ESTABLISH ADDRESSABILITY */                              68996021
*/*          P SET 'CONDITIONAL FREEMAIN' SW IN SCVT */                 68996821
*/*TASKSEL:  P SET SEL TCB = CURRENT TCB */                             68997621
*/*CHECKLOW: D (YES,,NO,RBSET) DAUGHTER EXIST */                        68998421
*/*          P (,CHECKLOW) SET SEL TCB = DAUGHTER */                    68999221
*/*RBSET:    P SET RB ADDR TO ABEND SVRB RBLINK FIELD */                68999321
*/*          D (NO,,YES,RBREMOVE) SEL TCB = CURRENT TCB */              68999421
*/*          P SET RB ADDR TO RB OF SELECTED TCB */                     68999521
*/*RBREMOVE: D (YES,,NO,TESTOCT) RB AN IRB */                           68999621
*/*LOAD:     D (YES,,NO,TESTOCT) IQE EXIST */                           68999721
*/*          P DECREMENT THE IQE COUNT IN THE IRB BY ONE */             68999821
*/*          P (,LOAD) GET NEXT IQE */                                  68999921
*/*TESTOCT:  D (NO,,YES,TESTLAST) SEL TCB = CURRENT TCB */              69099921
*/*          P DEQUEUE THE RB FROM THE RB QUEUE */                      69119921
*/*EDACT:    P SET THE RB INACTIVE */                                   69139921
*/*          D (YES,,NO,LASTRB) CAN RB BE FREED */                      69159921
*/*          D (NO,,YES,TSTABEND) RB AN SVRB OR PRB */                  69179921
*/*          D (YES,,NO,ADFRB) RB AN IRB */                             69183921
*/*          D (YES,,NO,LASTRB) RB USE COUNT ZERO */                    69187921
*/*          D (YES,,NO,NOTTAXE) IS IRB A TAXE */                       69191921
*/*          D (YES,,NO,NOTTAXE) DOES A TAIE EXIST */                   69195921
*/*          P ZERO PTR TO TAIE IN TAXE */                              69196721
*/*          P SET 'CONDITIONAL FREEMAIN' SW IN SCVT */                 69197521
*/*          S FREEMAIN: FREE THE TAIE FROM SUBPOOL 0 */                69198321
*/*          P RESET 'CONDITIONAL FREEMAIN' SW */                       69199121
*/*NOTTAXE:  D (YES,,NO,ADFRB) IRB SAVE AREA EXIST */                   69199221
*/*          P SET 'CONDITIONAL FREEMAIN' SW IN SCVT */                 69199321
*/*          S FREEMAIN: FREE THE IRB SAVE AREA FROM SUBPOOL 250 */     69199421
*/*          P RESET 'CONDITIONAL FREEMAIN' SW */                       69199521
*/*ADFRB:    P INDICATE FREEMAIN FROM SUBPOOL 255 */                    69199621
*/*          D (YES,,NO,LASTRB) RB A PRB OR SVRB */                     69199721
*/*          S FREEMAIN: FREE THE RB */                                 69199821
*/*LASTRB:   P GET PREVIOUS RB ON QUEUE */                              69299821
*/*          D (NO,,YES,RBREMOVE) RB EXIST */                           69319821
*/*LASTRB1:  P (,LOADREL) ZERO OUT TCB RB PTR */                        69339821
*/*TSTABEND: D (NO,,YES,ADFRB) RB A PRB */                              69359821
*/*          D (YES,,NO,ADFRB) RB AN ABEND SVRB */                      69379821
*/*          P (,ADFRB) CLEAR THE ABEND INDICATOR IN THE SVRB */        69383821
*/*TESTLAST: D (NO,,YES,RBLAST) RB POINT TO TCB */                      69387821
*/*          P (,EDACT) REMOVE THE RB FROM THE RB QUEUE */              69391821
*/*RBLAST:   P CHANGE RB TYPE FIELD TO INDICATE A PRB */                69395821
*/*          P ZERO CDE ADDRESS AND RB WAIT COUNT IN THE RB */          69396621
*/*          P (,LOADREL) POINT RBOPSW TO SVC 3 INSTRUCTION */          69397421
*/*LOADREL:  S IEAQABL: LOAD LIST PURGE */                              69398221
*/*          P RE-ESTABLISH ADDRESSABILITY */                           69399021
*/*PURGEMSS: D (NO,,YES,ARNDSPET) TASK ABENDED BY STG RECONF */         69399121
*/*          S IEAQSPET: END OF TASK SUBPOOL RELEASE */                 69399221
*/*ARNDSPET: D (NO,,YES,RETURN) SEL TCB = CURRENT TCB */                69399321
*/*          P INDICATE 'TASK COMPLETE' IN TCB */                       69399421
*/*DQTCB:    S IEADQTCB: REMOVE THE SEL TCB FROM THE READY Q */         69399521
*/*          S (,TASKSEL) IEAQERA: DEQ TCB FROM ABENDING TREE &         69499621
*/*FREE ITS CORE */                                                     69519621
*/*RETURN:   P RESET EXIT ABEND FLAG IN SCVT */                         69519721
*/*          P CLEAR THE ABEND INDICATOR IN THE CURRENT ABEND SVRB */   69539721
*/*          D (YES,,NO,RETURN2) TASK ABENDED BY STG RECONF */          69559721
*/*          R ABEND 20 */                                              69579721
*/*RETURN2:  R SVC 3 */                                                 69583721
*/*IEAQTM0G: END */                                                     69587721
         END                                                            69599721
