IGC0M01C CSECT                                                          00100021
 TITLE 'IGC0M01C / DAR LOAD 2 - MUST COMPLETE STATUS / IEAQTM0M'        00200021
*                                                                       00300021
* MODULE NAME        - IEAQTM0M                                         00400021
*                                                                       00500021
* MVT SUPERVISOR     - DAR LOAD 2                                       00600021
*                                                                       00700021
* SVC USED           - WTO/WTOR,XCTL,STATUS                             00800021
*                                                                       00900021
* EXTERNAL ROUTINES  - NONE                                             01000021
*                                                                       01100021
* FUNCTION           - TASKS ABENDING IN MUST COMPLETE STATUS WILL      01200021
*                      BE REINSTATED IF THEIR RESOURCES ARE NOT         01300021
*                      CRITICAL; OTHERWISE, THEY WILL BE MADE NON-      01400021
*                      DISPATCHABLE.                                    01500021
*                                                                       01600021
* ENTRY POINT        - IGC0M01C FROM ABEND/DAR ONE (IEAQTM0L)           01700021
*                                                                       01800021
* EXITS              - DAR LOAD 4 - TO SET THE FAILING TASK AND ITS     01900021
*                                   SUBTASKS NON-DISPATCHABLE IF        02000021
*                                   ANY OF THE ENQUEUED RESOURCES       02100021
*                                   ARE CRITICAL.                       02200021
*                    - ABEND LOAD 1 - TO CONTINUE NORMAL ABEND          02300021
*                                   PROCESSING IF THE ENQUEUED          02400021
*                                   RESOURCES ARE NOT CRITICAL.         02500021
*                                                                       02600021
* OPERATION          - DAR2 IS ENTERED FOR TASKS IN MUST COMPLETE       02700021
*                      STATUS. A SEARCH IS MADE OF THE QUEUE ELEMENTS   02800021
*                      OF THE ABENDING TCB UNTIL THE MAJOR AND MINOR    02900021
*                      QCB NAMES ASSOCIATED WITH THE FAILING TASK ARE   03000021
*                      FOUND. ONCE FOUND, THESE NAMES ARE OUTPUT TO     03100021
*                      THE OPERATOR WHO IS REQUESTED TO STATE WHETHER   03200021
*                      OR NOT THE RESOURCES ARE CRITICAL TO CONTINUED   03300021
*                      SYSTEM OPERATION. IF THE RESOURCES ARE NOT       03400021
*                      CRITICAL, CONTROL IS RETURNED BACK TO ABEND      03500021
*                      (IEAQTM01) AND THE RESOURCES WILL EVENTUALLY     03600021
*                      BE PURGED DURING NORMAL ABEND PROCESSING.        03700021
*                      IF THE RESOURCES ARE CRITICAL, CONTROL IS        03800021
*                      PASSED TO DAR 4 (IEAQTM0P) WHERE THE FAILING     03900021
*                      TASK AND ITS SUBTASKS ARE RETAINED IN A NON-     04000021
*                      DISPATCHABLE STATE FOR THE DURATION OF THE       04100021
*                      CURRENT IPL,AFTER THE OPERATOR IS INFORMED       04200021
*                      THAT THE ABENDING TASK FAILED TO BE              04300021
*                      REINSTATED.                                      04400021
*                                                                       04500021
         EJECT                                                          04600021
*        REGISTER EQUATES                                               04700021
PARREG0  EQU   0                                                        04800021
PARREG1  EQU   1                                                        04900021
CHEKREG  EQU   2                                                        05000021
CVTREG   EQU   3                                                        05100021
FOUR     EQU   4                                                        05200021
TCBREG   EQU   4                                                        05300021
RBREG    EQU   5                                                        05400021
GIVEN    EQU   7                                                        05500021
ATCBREG  EQU   8                                                        05600021
SZE      EQU   8                                                        05700021
BASEREG  EQU   9                                                        05800021
QELREG   EQU   10                                                       05900021
R10      EQU   10                                                       06000021
IDSZ     EQU   12                                                       06100021
JSNAME   EQU   17                                                       06200021
WORK     EQU   11                                                       06300021
MINN     EQU   12                                                       06400021
MAJN     EQU   12                                                       06500021
R12      EQU   12                                                       06600021
RETREG   EQU   14                                                       06700021
BREG     EQU   15                                                       06800021
SCVTREG  EQU   15                                                       06900021
         EJECT                                                          07000021
*        MISCELANEOUS EQUATES                                           07100021
ZERO     EQU   0                                                  20472 07200021
ONE      EQU   1                                                  20472 07300021
TWO      EQU   2                                                  20472 07400021
SVN      EQU   7                                                  20472 07500021
EIGHT    EQU   8                                                  20472 07600021
TEN      EQU   10                                                 20472 07700021
TWELVE   EQU   12                                                 20472 07800021
FORTN    EQU   14                                                 20472 07900021
PTRCVT   EQU   16                                                       08000021
SVNTN    EQU   17                                                       08100021
TWNTY    EQU   20                                                       08200021
RMDR     EQU   21                                                       08300021
RSET     EQU   21                                                       08400021
MNLG     EQU   23                                                       08500021
TWNT6    EQU   26                                                       08600021
THRT2    EQU   32                                                       08700021
DABUS    EQU   32                                                       08800021
THRT3    EQU   34                                                       08900021
ESOFFSET EQU   40                                                       09000021
FORTY    EQU   37                                                       09100021
OFSET1   EQU   44                                                       09200021
FORT4    EQU   44                                                       09300021
ESASZ    EQU   48                                                       09400021
FIFT2    EQU   52                                                       09500021
SIXT     EQU   60                                                       09600021
QEU      EQU   C'Q'                                                     09700021
ENN      EQU   X'D5'                                                    09800021
CEE      EQU   X'C3'                                                    09900021
SMCBIT   EQU   X'30'                                                    10000021
SDAR     EQU   X'40'                                                    10100021
LCA      EQU   X'1C'                                                    10200021
BLANK    EQU   C' '                                                     10300021
SYSMASK  EQU   X'10'                    TEST SYS MC              A30103 10400021
         EJECT                                                          10500021
DAR2     BALR  BASEREG,ZERO            ESTABLISH ADDRESSABILITY.        10600021
         USING *,BASEREG                                                10700021
         USING CVTSECT,CVTREG           ADDRESS THE CVT                 10800021
         USING TCBSECT,TCBREG           ADDRESS THE TCB                 10900021
         USING TCBDSECT,ATCBREG         ADDRESS THE ALT. TCB            11000021
         USING RBSECT,RBREG             ADDRESS THE RB                  11100021
         L     SCVTREG,CVTABEND        RESTORE SEC CVT REGISTER         11200021
         USING SCVTSECT,SCVTREG         ADDRESS THE SECONDARY CVT       11300021
         SPACE 2                                                        11400021
*  THIS SECTION WILL SEARCH TJE QUEUE ELEMENTS TO FIND THE RESOURCES    11500021
*  CAUSING THE MUST COMPLETE. THE RESOURCE NAMES ARE OUTPUT VIA WTO     11600021
*  AND THE OPERATOR MAY LATER SPECIFY ANY SPECIAL HANDLING. IF HE       11700021
*  INDICATES NO SPECIAL HANDLING, CONTROL WILL BE RETURNED TO ABEND     11800021
*  WHERE THE RESOURCES WILL EVENTUALLY BE PURGED DURING NORMAL          11900021
*  ABEND PROCESSING. OTHERWISE, DAR WILL PURSUE THE PATH TAKEN FOR      12000021
*  A REINSTATEMENT FAILURE.                                             12100021
*                                                                       12200021
         XC    RBGRSAVE+SIXT(FIFT2),RBGRSAVE+SIXT  CLEAR BUFFER.        12300021
         MVC   RBGRSAVE+SIXT(IDSZ),MCMSGID  MESSAGE ID.                 12400021
         MVC   RBEXSAVE+EIGHT(JSNAME),RBEXSAVE+SVN BLANK NAMES          12500021
         L     PARREG1,TCBTIO          GET THE TIOT ADDRESS.            12600021
         LTR   PARREG1,PARREG1         TEST FOR TIOT                    12700021
         BZ    SKIPTIOT                NO TIOT, SKIP AHEAD              12800021
         MVC   RBEXSAVE+EIGHT(SZE),ZERO(PARREG1)  MOVE IN JOBNAME.      12900021
         MVC   RBEXSAVE+SVNTN(SZE),SZE(PARREG1)  MOVE IN STEPNAME.      13000021
SKIPTIOT EQU   *                                                        13100021
         MVC   RBEXSAVE+TWNT6(RMDR),ENQRCS  MESSAGE TEXT.               13200021
         MVC   RBEXSAVE+FORT4(FOUR),ROUT  ROUTER AND DESC CODES.        13300021
         LA    PARREG1,RBGRSAVE+SIXT   PARM FOR WTO.                    13400021
         WTO   MF=(E,(1))        ISSUE WTO.                       20048 13500021
         L     CVTREG,PTRCVT           RESET CVT BASE.                  13600021
         L     SCVTREG,CVTABEND        RESTORE SEC CVT REGISTER         13700021
         L     WORK,SCVTQCBO           POINTER TO QCB LIST              13800021
         B     NEXTMAJ                 TEST FOR NO QCBS           20472 13900021
FINDMIN  EQU   *                                                        14000021
         L     QELREG,SZE(WORK)        PICKUP PTR TO FIRST MINOR QCB.   14100021
FINDQEL  EQU   *                                                        14200021
         L     CHEKREG,ZERO(QELREG)    PICKUP PTR TO FIRST QEL.         14300021
*                                                                       14400021
QELMCTST EQU   *                                                        14500021
         TM    ZERO(CHEKREG),SMCBIT    TEST QEL FOR MUST COMPLETE.      14600021
         BNZ   MAJMIN                  BRANCH TO WRITE MAJ/MIN NAMES    14700021
NEXTQEL  EQU   *                                                        14800021
         L     CHEKREG,ZERO(CHEKREG)   PICKUP QEL LINK PTR.             14900021
         LA    CHEKREG,ZERO(CHEKREG)   CLEAR FLAGS.                     15000021
         LTR   CHEKREG,CHEKREG         ANYMORE QELS?                    15100021
         BZ    NEXTMIN                 NO, GET NEXT MINOR QCB.          15200021
         B     QELMCTST                YES, TEST THIS QEL FOR MC.       15300021
*                                                                       15400021
NEXTMIN  EQU   *                                                        15500021
         L     QELREG,SZE(QELREG)      PICKUP PTR TO NEXT MINOR.        15600021
         LTR   QELREG,QELREG           ANYMORE MINORS?                  15700021
         BZ    NEXTMAJ                 NO, GET NEXT MAJOR.              15800021
         B     FINDQEL                 YES, BRANCH TO TEST QELS.        15900021
*                                                                       16000021
NEXTMAJ  EQU   *                                                        16100021
         L     WORK,ZERO(WORK)         PICKUP NEXT MAJOR POINTER.       16200021
         LTR   WORK,WORK               ANYMORE MAJORS?                  16300021
         BZ    REQUEST                 NO, GO TO ISSUE WTOR             16400021
         B     FINDMIN                 YES, RETURN TO FIND ITS MINOR.   16500021
         EJECT                                                          16600021
*  THIS CODE WILL OUTPUT THE MAJOR AND MINOR NAMES OF THE RESOURCE      16700021
*  CAUSING MUST COMPLETE STATUS.                                        16800021
*                                                                       16900021
*                                                                       17000021
MAJMIN   EQU   *                                                        17100021
*                                                                 M5172 17200021
         C     TCBREG,SZE(CHEKREG)     DOES QEL BELONG TO CURRENT TCB?  17300021
         BNE   NEXTQEL                 NO, DO NOT WTO.                  17400021
         MVC   RBEXSAVE+TWO(TEN),MCMSGID+TWO  MOVE MCS FLAGS,ID   M4508 17500021
         MVC   RBEXSAVE+TWELVE(SZE),MAJN(WORK)  MOVE MAJOR NAME   M4508 17600021
         MVI   RBEXSAVE+TWNTY,BLANK    SPACE AFTER MAJOR NAME     M4508 17700021
         LA    R12,MNLG                ROOM FOR MAX OF 23 CHARS   M4508 17800021
         CLI   MINN(QELREG),MNLG       IS MINOR NAME LONGER       M4508 17900021
         BNL   MAXNAME                 YES,USE ONLY 1ST 23 CHARS  M4508 18000021
         IC    R12,MINN(QELREG)        GET LENGTH OF MINOR NAME   M4508 18100021
MAXNAME  EQU   *                                                  M4508 18200021
         MVC   RBEXSAVE+RSET(MNLG),FORTN(QELREG)  MOVE MAX SIZE   M4508 18300021
         LA    R12,RSET(R12)           DETERMINE TOTAL MSG SIZE   M4508 18400021
         STH   R12,RBEXSAVE            PUT ZERO IN 1ST BYTE AND   M4508 18500021
*                                        MSG SIZE IN 2ND BYTE OF  M4508 18600021
*                                        PARAMETER LIST           M4508 18700021
         LA    R12,RBEXSAVE(R12)       POINT PAST MSG             M4508 18800021
         MVC   ZERO(FOUR,R12),DES      MOVE IN DESCRIPTOR AND     M4508 18900021
*                                        ROUTING CODES            M4508 19000021
         LA    PARREG1,RBEXSAVE        LOAD PARM REGISTER FOR WTO.      19100021
         WTO   MF=(E,(1))              ISSUE THE MESSAGE.               19200021
*                                                                       19300021
*  UPON RETURN, THIS CODE PERMITS EXCLUSION OF EXAMINING ANY MORE QELS  19400021
*  QUEUED ON THE MINOR WHOSE NAME HAS JUST BEEN WRITTEN.                19500021
*                                                                       19600021
         B     NEXTMIN                 PICKUP NEXT MINOR, IF ONE        19700021
*                                      EXISTS AND CONTINUE DOWN THE     19800021
*                                      QCB CHAIN.                       19900021
         EJECT                                                          20000021
*  AT THIS POINT ALL THE RESOURCES CAUSING MUST COMPLETE HAVE BEEN      20100021
*  INDICATED TO THE OPERATOR.  WE NOW WILL ISSUE THE WTOR REQUESTING    20200021
*  OPERATOR DECISION.                                                   20300021
*                                                                       20400021
*                                                                       20500021
REQUEST  EQU   *                                                        20600021
         XC    RBEXSAVE(ESASZ),RBEXSAVE   CLEAR MESSAGE AREA.           20700021
         MVC   RBEXSAVE(DABUS),REPLYMSG  MOVE IN MESSAGE TEXT.          20800021
         MVC   RBEXSAVE+THRT2(TWO),DESC  MOVE IN DESCRIPTOR CODE A26974 20900021
         MVC   RBEXSAVE+THRT3(TWO),RTE   MOVE IN ROUTING CODE    A26974 21000021
         LA    GIVEN,RBEXSAVE+ESOFFSET    SETUP REPLY ADDRESS.          21100021
         LA    WORK,RBEXSAVE+OFSET1       SETUP ECB ADDRESS.            21200021
         LA    PARREG1,RBEXSAVE        POINT TO LOCATION OF MESSAGE.    21300021
         XC    RBEXSAVE+OFSET1(FOUR),RBEXSAVE+OFSET1  CLEAR THE ECB.    21400021
*                                                                       21500021
         WTOR  ,(GIVEN),1,(WORK),MF=(E,(1))                             21600021
         WAIT  PARREG1,ECB=RBEXSAVE+OFSET1  ISSUE WAIT.                 21700021
         EJECT                                                          21800021
* WHEN CONTROL IS RETURNED BY WTOR, THE TASK IS NOW ENABLED.            21900021
* DAR2 MUST NOW DISABLE BEFORE CONTINUEING PROCESSING.                  22000021
*                                                                       22100021
         SSM   DISABLE                  DISABLE INTERRUPTS        20472 22200021
*                                                                       22300021
         CLI   RBEXSAVE+ESOFFSET,CEE   DID OPERATOR REPLY CRITICAL?     22400021
         BNE   NONCRIT                                                  22500021
         B     RETCALL                                                  22600021
NONCRIT  EQU   *                                                        22700021
         CLI   RBEXSAVE+ESOFFSET,ENN   DID OPERATOR REPLY NON-CRITICAL? 22800021
         BNE   REQUEST                 REPEAT MESSAGE                   22900021
*                                                                       23000021
* AT THIS TIME, THE MUST COMPLETE STATUS IS TO BE RESET. STATUS         23100021
* IS A MACRO WHICH WILL DO THIS. AS INPUT TO RESET A TASK FROM          23200021
* MUST COMPLETE STATUS, THE HIGH ORDER BIT OF REGISTER 1 MUST           23300021
* BE ON, THE REST OF REGISTER 1 IS IGNORED. THIS BIT IS TURNED          23400021
* ON HERE BY A BAL TO SAVE SPACE. IF STATUS IS EVER CHANGED TO          23500021
* EXPECT ANYTHING ELSE IN REG 1, THIS CODE WILL HAVE TO BE              23600021
* MODIFIED ACCORDINGLY.                                                 23700021
*                                                                       23800021
         BAL   PARREG1,*+4              INDICATE RESET FLAG      A30103 23900021
*                                                                       24000021
* THE OTHER INPUT TO STATUS IS IN REGISTER 0. IF THE MC STATUS IS       24100021
* SYSTEM MUST COMPLETE, REG 0 CONTAINS A 2, FOR STEP MC STATUS          24200021
* IT CONTAINS A 1.                                                      24300021
*                                                                       24400021
         LA    PARREG0,2                INDICATE SYS MC STATUS   A30103 24500021
         TM    TCBFLGS+1,SYSMASK        Q. IS IT SYS MC?         A30103 24600021
         BO    RESETMC                  YES. ISSUE STATUS NOW    A30103 24700021
         BCT   PARREG0,RESETMC          INDICATE STEP MC         A30103 24800021
RESETMC  EQU   *                                                 A30103 24900021
         SVC   79                       ISSUE STATUS MACRO       A30103 25000021
*                                                                       25100021
* CONTROL CAN NOW BE RETURNED TO ABEND AS IF THE TASK WAS               25200021
* NEVER IN MUST COMPLETE STATUS. THE SECONDARY DAR RECURSION BIT        25300021
* IS TURNED OFF TO ALLOW A CHANCE FOR TRUE DAR REINSTATEMENT,           25400021
* THE WORD 'ABEND' IS PUT IN ABEND'S EXTENDED SAVE AREA, AND            25500021
* CONTROL IS PASSED BACK TO ABEND 1 WHERE THE TASK WILL ONCE            25600021
* AGAIN GO THRU TESTING TO SEE IF DAR SHOULD BE ENTERED.                25700021
*                                                                       25800021
         XC    RBEXSAVE(ESASZ),RBEXSAVE CLEAR THE SVRB ESA              25900021
         NI    TCBDAR,255-SDAR-VMCDAR   ALLOW FOR LATER DAR NTRY  M3826 26000021
*                                        AND TURN OFF VALID       M3826 26100021
*                                        RECURSION SWITCH         M3826 26200021
         MVC   RBEXSAVE+40(6),ABENDM    INDICATE NORMAL ENTRY     20472 26300021
         LA    R10,NMABEND1              AND GO TO ABEND1         20472 26400021
         B     XCTL                      FOR NORMAL PROCESSING    20472 26500021
         EJECT                                                          26600021
*                                                                       26700021
*  PROCESSING IS NOW COMPLETE AND CONTROL WILL BE RETURNED TO ABEND     26800021
*  IF THE ENQUEUED RESOURCES ARE NOT CRITICAL OR TO DAR 4 IF THE        26900021
*  RESOURCES ARE CRITICAL. DAR 4 WILL SET THE ABENDING TASK             27000021
*  PERMANENTLY NON-DISPATCHABLE.                                        27100021
*                                                                       27200021
RETCALL  EQU   *                                                        27300021
         LA    R10,NMDAR4              ADDR OF DAR4.                    27400021
XCTL     EQU   *                                                        27500021
         L     PARREG0,THISMOD          SHOW ORIGIN FOR TRACE           27520021
         L     PARREG1,4(R10)           SHOW DESTINATION                27540021
         LA    BREG,RBEXSAVE           ADDR OF PARMLIST.                27600021
         XCTL  EPLOC=(10),SF=(E,(15))                                   27700021
         EJECT                                                          27800021
ABENDM   DC    C'ABENDM'               EXTENDED SAVE AREA ID      20472 27900021
DISABLE  DC    X'00'                                                    28000021
         DS    0F                                                       28100021
NMDAR4   DC    CL8'IGC0P01C'                                            28200021
NMABEND1 DC    CL8'IGC0101C'                                            28300021
THISMOD  DC    C'MO1C'                                                  28320021
MCMSGID  DC    X'00308000'                                              28400021
         DC    C'IEA027I '                                              28500021
ENQRCS   DC    C'ENQUEUED RESOURCES '                                   28600021
REPLYMSG DC    CL8'00000000'                                            28700021
         DC    X'00188000'                                              28800021
         DC    C'IEA028A REPLY C OR N'                                  28900021
ROUT     EQU   *                                                 A26974 29000021
DES      DC    X'1000'                                                  29100021
RTE      DC    X'8000'                 ROUTING CODE              A26974 29200021
DESC     DC    X'4000'                                                  29300021
         EJECT                                                          29400021
****                                                               **** 29420021
*        MAINTENANCE PATCH AREA                                       * 29440021
****                                                               **** 29460021
         SPACE 1                                                        29480021
         DC    H'0'                                                     29500021
         DC    H'0'                                                     29600021
         DC    H'0'                                                     29700021
         DC    H'0'                                                     29800021
         DC    H'0'                                                     29900021
         DC    H'0'                                                     30000021
         DC    H'0'                                                     30100021
         DC    H'0'                                                     30200021
         DC    H'0'                                                     30300021
         DC    H'0'                                                     30400021
         DC    H'0'                                                     30500021
         DC    H'0'                                                     30600021
         DC    H'0'                                                     30700021
         DC    H'0'                                                     30800021
         DC    H'0'                                                     30900021
         DC    H'0'                                                     31000021
         DC    H'0'                                                     31100021
         DC    H'0'                                                     31200021
         DC    H'0'                                                     31300021
         DC    H'0'                                                     31400021
         DC    H'0'                                                     31420021
         DC    H'0'                                                     31440021
         DC    H'0'                                                     31460021
         DC    H'0'                                                     31480021
         EJECT                                                          31500021
         IHBABCTL                                                       31600021
VMCDAR   EQU   X'10'             VALID RECURSION IN M.C. SWITCH   M4268 31700021
         MPCVT                                                          31800021
         EJECT                                                          31820021
****                                                               **** 31840021
*        FLOWCHART STATEMENTS FOR DAR 2                               * 31860021
****                                                               **** 31880021
         SPACE 1                                                        31884021
*/*IEAQTM0M: CHART */                                                   31888021
*/*IEAQTM0M: E DAR 2 */                                                 31892021
*/*IGC0M01C: P ESTABLISH ADDRESSABILITY */                              31892821
*/*          P CLEAR BUFFER FOR MESSAGE */                              31893621
*/*          D (YES,,NO,SKIPTIOT) TIOT EXIST */                         31896821
*/*          P MOVE JOBNAME AND STEPNAME INTO MESSAGE TEXT */           31897621
*/*SKIPTIOT: S WTO: IEA027I: ENQUEUED RESOURCES */                      31898421
*/*          P (,NEXTMAJ) GET ADDR OF QCB LIST FROM SCVT */             31899221
*/*FINDMIN:  P GET ADDR OF FIRST MINOR QCB */                           31899321
*/*FINDQEL:  P GET ADDR OF FIRST QEL */                                 31899421
*/*QELMCTST: D (NO,,YES,MAJMIN) QEL MUST COMPLETE */                    31899521
*/*NEXTQEL:  P GET ADDR OF NEXT QEL */                                  31899621
*/*          D (NO,,YES,QELMCTST) DOES QEL EXIST */                     31899721
*/*NEXTMIN:  P GET ADDR OF NEXT MINOR QCB */                            31899821
*/*          D (NO,,YES,FINDQEL) DOES MINOR QCB EXIST */                31899921
*/*NEXTMAJ:  P GET ADDR OF NEXT MAJOR QCB */                            31999921
*/*          D (NO,REQUEST,YES,FINDMIN) DOES MAJOR QCB EXIST */         32019921
*/*MAJMIN:   D (YES,,NO,NEXTQEL) QEL FOR CURRENT TCB */                 32039921
*/*          S (,NEXTMIN) WTO: LIST THE ENQUEUED RESOURCE */            32059921
*/*REQUEST:  S WTOR: IEA028A: REPLY CRITICAL(C) OR NOT(N) */            32079921
*/*          S WAIT: WAIT FOR OPERATOR RESPONSE */                      32083921
*/*          P DISABLE INTERRUPTS UPON RETURN FROM WAIT */              32087921
*/*          D (YES,,NO,NONCRIT) RESPONSE 'C' */                        32091921
*/*          R DAR 4 */                                                 32095921
*/*NONCRIT:  D (YES,,NO,REQUEST) RESPONSE 'N' */                        32096721
*/*          S STATUS: RESET THE MUST COMPLETE STATUS */                32097521
*/*          P CLEAR SVRB ESA AND RESET DAR RECUR FLAG */               32098321
*/*          R ABEND 1 */                                               32099121
*/*IEAQTM0M: END */                                                     32099221
         END                                                            32099921
