IGC0N01C CSECT                                                          00100021
 TITLE 'IGC0N01C / DAR LOAD 3 - SYSTEM TASK REINSTATEMENT / IEAQTM0N'   00200021
*                                                                       00300021
* MODULE NAME        - IEAQTM0N                                         00400021
*                                                                       00500021
* MVT SUPERVISOR     - DAR LOAD 3                                       00600021
*                                                                       00700021
* SVCS USED          - WTO, XCTL, EXIT                                  00800021
*                                                                       00900021
* EXTERNAL ROUTINES  - NONE                                             01000021
*                                                                       01100021
* FUNCTION           - RECOGNIZE AND REINSTATE THE FOLLOWING TASKS:     01200021
*                        1. MASTER SCHEDULER TASK                       01300021
*                        2. TRANSIENT AREA FETCH TASK                   01400021
*                        3. IORMS TASK                                  01500021
*                        4. SYSTEM ERROR TASK                           01600021
*                        5. COMMUNICATIONS TASK                         01700021
*                      PLACE THE ROLLOUT/ROLLIN TASK IN A NON-          01800021
*                      DISPATCHABLE STATE IF IT HAS FAILED AND          01900021
*                      SCHEDULE THE TASK, ON WHOSE BEHALF THE RORI      02000021
*                      TASK WAS OPERATING, FOR ABEND WITH A 'D0A'       02100021
*                      COMPLETION CODE.                                 02200021
*                                                                       02300021
* ENTRY POINT        - IGC0N01C FROM DAR LOAD 1 (IEAQTM0L)              02400021
*                                                                       02500021
* EXITS              - VIA XCTL TO DAR LOAD 4 (IEAQTM0P) TO SET         02600021
*                      THE ROLLOUT/ROLLIN TASK NON-DISPATCHABLE         02700021
*                    - VIA XCTL TO ABEND 1 (IEAQTM01) TO CONTINUE       02800021
*                      TERMINATION PROCESSING FOR NON-SPECIAL SYSTEM    02900021
*                      TASKS.                                           03000021
*                    - VIA SVC 3 (EXIT) TO INITIATE ACTUAL              03100021
*                      REINSTATEMENT OF THE SYSTEM TASKS LISTED ABOVE.  03200021
*                                                                       03300021
* OPERATIONS         - DAR LOAD 3 RECEIVES CONTROL FROM DAR LOAD 1      03400021
*                      (IEAQTM0L) WHEN THE LATTER RECOGNIZES THAT       03500021
*                      THE FAILING TASK IS EITHER THE MASTER SCHEDULER  03600021
*                      TASK OR A DAUGHTER OF THE MASTER SCHEDULER AND   03700021
*                      THE TASK IS NOT IN MUST-COMPLETE STATUS.         03800021
*                      TASK REINSTATEMENTS ARE ACCOMPLISHED AS FOLLOWS: 03900021
*                                                                       04000021
*                      MASTER SCHEDULER TASK:  POINT THE PSWS OF ALL    04100021
*                      RBS QUEUED OFF THE MASTER SCHEDULER TCB TO AN    04200021
*                      SVC 3 INSTRUCTION IN THE CVT. THE TOP RB PSW IS  04300021
*                      POINTED TO A LOCATION WITHIN ABTERM WHERE A LINK 04400021
*                      WILL BE ISSUED TO THE MASTER SCHEDULER WAIT      04500021
*                      ROUTINE, IEEVWAIT.                               04600021
*                                                                       04700021
         EJECT                                                          04800021
*                      TRANSIENT AREA FETCH TASK:  POINT THE PSWS OF    04900021
*                      ALL RBS QUEUED OFF THE TRANSIENT AREA FETCH TCB  05000021
*                      TO AN SVC 3 INSTRUCTION IN THE CVT. THE TOP RB   05100021
*                      PSW IS POINTED TO THE ENTRY POINT WITHIN THE     05200021
*                      TRANSIENT AREA HANDLER WHERE CODE HAS BEEN       05300021
*                      INSERTED TO HANDLE ENTRY FROM DAR.               05400021
*                                                                       05500021
*                      IORMS TASK:  POINT THE PSWS OF ALL RBS QUEUED    05600021
*                      OFF THE IORMS TCB TO AN SVC 3 INSTRUCTION IN THE 05700021
*                      CVT. POINT THE PSW OF THE TOP RB TO AN IORMS     05800021
*                      SVC WHOSE ADDRESS IS OBTAINED FROM THE SCVT.     05900021
*                                                                       06000021
*                      SYSTEM ERROR TASK:  THE ERROR FLAGS IN THE       06100021
*                      SVCLIB DCB ARE CLEARED. IF AN RQE EXISTS, THE    06200021
*                      TCB ON WHOSE BEHALF THE ERROR TASK WAS OPERATING 06300021
*                      IS SET UP TO BE SCHEDULED FOR A 'B06' ABEND.     06400021
*                      THE RBOPSW OF THE SIRB IS SET TO POINT TO AN     06500021
*                      SVC 3 INSTRUCTION. IF AN RQE DOES NOT EXIST,     06600021
*                      THE RBOPSW OF THE SIRB IS SET TO POINT TO AN     06700021
*                      SVC 3 INSTRUCTION.                               06800021
*                                                                       06900021
*                      COMMUNICATIONS TASK:  POINT THE PSWS OF ALL RBS  07000021
*                      QUEUED OF THE COMMTASK TCB TO AN SVC 3           07100021
*                      INSTRUCTION IN THE CVT. THE TOP RB PSW IS        07200021
*                      POINTED TO AN ENTRY POINT (IEECVCTW) WITHIN      07300021
*                      COMMTASK                                         07400021
*                                                                       07500021
*                      AFTER ALL RBS HAVE BEEN PROPERLY INITIALIZED     07600021
*                      FOR REINSTATEMENT, DAR 3 WILL ISSUE A MESSAGE    07700021
*                      TO THE OPERATOR VIA WTO INFORMING HIM OF THE     07800021
*                      TASK REINSTATEMENT. DAR 3 THEN PURGES ALL        07900021
*                      ENTRIES IN THE INFORMATION LIST PERTAINING TO    08000021
*                      THE TASK ABOUT TO BE REINSTATED. FINALLY, DAR 3  08100021
*                      ISSUES AN SVC 3 (EXIT) INSTRUCTION TO COMMENCE   08200021
*                      THE REINSTATEMENT PROCESS.                       08300021
*                                                                       08400021
*                      IF THE SYSTEM TASK BEING ABENDED IS NOT ONE OF   08500021
*                      THE TASKS LISTED ABOVE, IT IS CONSIDERED TO BE   08600021
*                      NON-SPECIAL AND CONTROL WILL BE RETURNED TO      08700021
*                      ABEND VIA XCTL TO ABEND LOAD 1 (IEAQTM01).       08800021
         EJECT                                                          08900021
DAR3     BALR  BASEREG,ZERO             ESTABLISH                       09000021
         USING *,BASEREG                ADDRESSABILITY                  09100021
         USING CVTSECT,CVTREG           ADDRESS THE CVT                 09200021
         USING TCBSECT,TCBREG           ADDRESS THE TCB                 09300021
         USING TCBDSECT,ATCBREG         ADDRESS THE ALT. TCB            09400021
         L     RBREG,RBPTR(TCBREG)      CURRENT RB ADDRESS              09500021
         USING RBSECT,RBREG             ADDRESS THE RB                  09600021
         L     SCVTREG,CVTABEND         RESTORE SEC CVT BASE            09700021
         USING SCVTSECT,SCVTREG         ADDRESS THE SECONDARY CVT       09800021
         SPACE 2                                                        09900021
****                                                               **** 10000021
*     DETERMINE WHICH SYSTEM TASK IS ABENDING AND REINSTATE IT        * 10100021
****                                                               **** 10200021
         SPACE 1                                                        10300021
****                                                               **** 10400021
*        MASTER SCHEDULER REINSTATEMENT                               * 10500021
****                                                               **** 10600021
MASTER   EQU   *                                                        10700021
         L     TASKREG,TCBOTC           GET MOTHER OF CURRENT TASK      10800021
         LTR   TASKREG,TASKREG          MASTER SCHEDULER ABENDING       10900021
         BNZ   TAFTASK                  NO-CHECK FOR TRANS AREA TASK    11000021
         BAL   RETREG,STORPSW                                           11100021
*                                                                     * 11200021
*        THIS CODE SETS THE TOP RB OFF THE MASTER TCB TO EXECUTE      * 11300021
*        A LINK TO THE MASTER SCHEDULER WAIT ROUTINE                  * 11400021
*                                                                     * 11500021
         L     WORK,CVTMSER                                             11600021
         SR    PARREG1,PARREG1          CLEAR REGISTER FOR TEST         11700021
         CL    PARREG1,LCA(WORK)        IS THERE A LOG CNTL AREA        11800021
         BE    ELADECB                  NO-CLEAR ELEMENT ADDED ECB ONLY 11900021
         L     SAVE,LCA(WORK)           YES-GET ADDR OF LOG ECB         12000021
         ST    PARREG1,ZERO(SAVE)       CLEAR LOG ECB                   12100021
ELADECB  EQU   *                                                        12200021
         ST    PARREG1,SZE(WORK)        CLEAR THE ELEMENT ADDED ECB     12300021
         MVI   SZE(WORK),POSTBIT        POST MASTER SCHEDULER ECB TO    12400021
*                                       ALLOW UNINTERRUPTED PROCESSING  12500021
         NI    STATFLG(WORK),DAOFF      CLEAR TASK ACTIVE BIT           12600021
         L     WORK,SCVTABLK            ADDR OF LINK INST IN ABTERM     12700021
         ST    WORK,ACTOPSW(CHEKREG)    STORE THAT ADDR IN RESUME PSW   12800021
         B     MSGREIN                  GO WRITE REINSTATEMENT MSG      12900021
         EJECT                                                          13000021
****                                                               **** 13100021
*        TRANSIENT AREA FETCH TASK REINSTATEMENT                      * 13200021
****                                                               **** 13300021
TAFTASK  EQU   *                                                        13400021
         L     PARREG1,CVTHEAD         GET FIRST XIENT TASK ADDRESS.    13500021
         L     CHEKREG,SCVTTACT        GET THE TACT ADDRESS.            13600021
         L     CHEKREG,FOUR(CHEKREG)   GET NR OF TACT ENTRIES AD  52736 13800021
         TM    CVTDCB,CVTMPB           MULTIPROCESSING?                 13900021
         BZ    TAFTEST                 NO, CONTINUE.                    14000021
         LA    CHEKREG,ONE(CHEKREG)    YES, BUMP COUNTER.               14100021
TAFTEST  EQU   *                                                        14200021
         CR    TCBREG,PARREG1          XIENT AREA TASK ADDR?            14300021
         BE    TRANTASK                YES, PROCESS IT.                 14400021
         BCTR  CHEKREG,ZERO            DECREMENT THE COUNTER.           14500021
         L     PARREG1,TCTCB(PARREG1)  GET NEXT FETCH TASK ADDR. A30103 14600021
         LTR   CHEKREG,CHEKREG         ANY MORE TAFS?                   14700021
         BNZ   TAFTEST                 GO BACK AND TEST THIS ONE.       14800021
         B     SYSERTSK                 CHECK FOR SYS ERROR TSK FAILURE 14900021
*                                                                       14950021
* WHEN THE TRANSIENT AREA FETCH TASK IS REINSTATED, ITS LOGIC AD  52736 15000021
* ASSUMES THAT REGISTER 5 CONTAINS ITS SVRB ADDRESS. SINCE    AD  52736 15050021
* THERE IS A POSSIBILITY OF A FAILURE HAVING OCCURRED WHILE   AD  52736 15100021
* BUILDING ABEND'S SVRB INITIALLY, AN INTERVENING SVRB MAY    AD  52736 15150021
* EXIST BETWEEN DAR'S AND THAT OF THE TRANSIENT AREA FETCH    AD  52736 15200021
* TASK. IN THAT CASE, THE INTERVENING SVRB'S REGISTER SAVE    AD  52736 15250021
* AREA MUST CONTAIN THE CORRECT VALUE IN REG 5 SINCE IT       AD  52736 15300021
* CONTAINS THE REGISTER VALUES WHICH WILL BE ASSIGNED TO THE  AD  52736 15350021
* TRANSIENT AREA FETCH TASK WHEN ITS SVRB REGAINS CONTROL.    AD  52736 15400021
*                                                                       15450021
TRANTASK EQU   *                                                        15500021
         BAL   RETREG,STORPSW           BRANCH TO REDIRECT PSWS         15900021
         ST    CHEKREG,REGSAVE+TWNTY(,SAVE) RESET R5           @PD62726 15950021
* SVRB ADDR UPON REINSTATEMENT--SEE EXPLANATION ABOVE.        AD  52736 16098021
         NI    APSWMSK(CHEKREG),DISABLE TRANSIENT AREA FETCH AD  52736  16098421
* TASK WILL BE MASKED OFF FOR ALL INTERRUPTS UPON RE-ENTRY   AD  52736  16098821
         L     WORK,SCVTNFND            ADDR IN IEAQTR33                16100021
         ST    WORK,ACTOPSW(CHEKREG)    STORE THAT ADDR IN RESUME PSW   16200021
         B     MSGREIN                  GO WRITE REINSTATEMENT MSG      16300021
         EJECT                                                          16400021
****                                                               **** 16500021
*        SYSTEM ERROR TASK REINSTATEMENT                              * 16600021
****                                                               **** 16700021
SYSERTSK EQU   *                                                        16800021
         L     PARREG1,SCVTETCB         SYSTEM ERROR TASK ADDRESS       16900021
         CR    PARREG1,TCBREG           ERROR TASK FAILED               17000021
         BNE   COMMTASK                 NO-CHECK FOR COMM TASK FAILURE  17100021
         BAL   RETREG,STORPSW      SET INTERVENING PSWS        @PD62726 17150021
*                                  POINTING TO SVC 3           @PD62726 17550021
         MVI   RBWCF-RBSECT(CHEKREG),1 RESET WAIT COUNT IN     @PD62726 17950021
*                                  DUMMY RB                    @PD62726 18350021
         L     WORK,CVTSVDCB           GET SCVLIB DCB ADDR   AD  A55639 19000021
         NI    DCERFLG(WORK),ERFLGS    TURN OFF ERROR FLAGS  AD  A55639 19050021
         L     PARREG1,SIRBTCB(SIRBREG) GET FAILING TCB ADDR AD  A55639 19100021
*                                      FROM SIRB             AD  A55639 19150021
         OI    ABTRMFLG(PARREG1),TCBABTRM SET ABTERM FLAG ON            19200021
         MVC   COMPFLD(4,PARREG1),IOERR SET COMP CODE TO 'B06'          19300021
         L     RETREG,CVTBTERM         ADDR OF ABTERM.                  19400021
         L     RETREG,ABDINSTR(RETREG) GET ADDR OF SVC 13 INSTR         19500021
         L     PARREG1,ZERO(PARREG1)   GET REQUESTING RB ADDR           19600021
         ST    RETREG,RHRBOPSW(PARREG1) AND POINT TO ABEND              19700021
         TM    RBSTABX(PARREG1),X'C0' IF SVRB                  @PD62726 19800021
         BNO   SYSERTS1            AND                         @PD62726 19805021
         CLI   LINKFLD(PARREG1),255 NOT IN                     @PD62726 19810021
         BNE   SYSERTS1            CORE THEN                   @PD62726 19815021
         MVI   RBQE(PARREG1),0     RESET ALTERNATE             @PD62726 19820021
         B     SYSERTS2            WAIT COUNT                  @PD62726 19825021
SYSERTS1 EQU   *                   ELSE RESET                  @PD62726 19830021
         MVI   LINKFLD(PARREG1),0  NORMAL WAIT COUNT           @PD62726 19835021
SYSERTS2 EQU   *                                               @PD62726 19840021
         MVC   ACTOPSW(4,SIRBREG),IOSRTN(SIRBREG) SET UP THE AD  A55639 19850021
* SIRB RESUME PSW TO THE ENTRY POINT OF IECRQE00-AN IOS RTN  AD  A55639 19900021
* WHICH WILL RETURN THE RQE TO THE SYSTEM WHEN THE SIRB IS   AD  A55639 19950021
* DISPATCHED.                                                AD  A55639 20000021
         B     MSGREIN                  GO WRITE REINSTATEMENT MSG      20900021
         EJECT                                                          21000021
****                                                               **** 21100021
*        COMMUNICATIONS TASK REINSTATEMENT                            * 21200021
****                                                               **** 21300021
COMMTASK EQU   *                                                        21400021
         L     TASKREG,SCVTCTCB         COMM TASK ADDRESS               21500021
         CR    TASKREG,TCBREG           COMM TASK FAILED                21600021
         BNE   IORMSTSK                 NO-CHECK FOR IORMS TASK FAILURE 21700021
         BAL   RETREG,STORPSW           GO SET RBS TO EXIT              21800021
         L     WORK,SCVTCOMM            ADDR OF IEECVCTB                21900021
         ST    WORK,ACTOPSW(CHEKREG)    STORE INTO RESUME PSW           22000021
         B     MSGREIN                  GO WRITE REINSTATEMENT MSG      22100021
         SPACE 2                                                        22200021
****                                                               **** 22300021
*        IORMS TASK REINSTATEMENT                                     * 22400021
****                                                               **** 22500021
IORMSTSK EQU   *                                                        22600021
         C     TCBREG,SCVTRMTC          IORMS TASK FAILING              22700021
         BNE   RORITASK                 NO-GO ABEND RORI REQUESTOR      22800021
         BAL   RETREG,STORPSW           GO SET RBS TO EXIT              22900021
         MVC   ACTOPSW(4,CHEKREG),SCVTRMSV  PT TOP RB TO RMS SVC        23000021
         B     MSGREIN                  GO WRITE REINSTATEMENT MSG      23100021
         SPACE 2                                                        23200021
****                                                               **** 23300021
*        ABEND THE ROLLOUT REQUESTOR                                  * 23400021
****                                                               **** 23500021
RORITASK EQU   *                                                        23600021
         C     TCBREG,SCVTRTCB          ROLLOUT TASK FAILING            23700021
         BNE   NONSYS                   NO-NON SYSTEM TASK FAILURE      23800021
         L     WORK,RBWCF               GET LINK PTR TO RORI SIRB       23900021
         L     WORK,RBQE(WORK)          GET RQE ADDRESS                 24000021
         SLL   WORK,SHFT               CLEAR LEFT HALF OF REG.    20472 24100021
         SRL   WORK,SHFT               REALIGN.                   20472 24200021
         L     WORK,ROREQ(WORK)        GET TCB REQUESTING RORI.   20472 24300021
         LR    PARREG1,WORK            REQUESTORS TCB.            20472 24400021
         NI    DSP(PARREG1),ROBT       TURN OFF RORI REQUEST BIT. 20472 24500021
         LA    WORK,0(WORK)                                       20472 24600021
         LR    PARREG0,WORK            TCB ADDR IN R0 FOR ABTERM. 20472 24700021
         L     PARREG1,RORICODE        INDICATE ABEND CODE.       20472 24800021
         L     RETREG,CVTBTERM         ADDR OF ABTERM EP.         20472 24900021
         BALR  RETREG,RETREG           ABTERM THE RIGHT TCB.      20472 25000021
         B     TODAR4                  GO FREEZE THE TASK               25100021
         EJECT                                                          25200021
*  THE FAILING TASK HAS BEEN SUCCESSFULLY REINSTATED AND THIS CODE      25300021
*  WILL ISSUE A WTO TO INFORM THE OPERATOR.                             25400021
*                                                                       25500021
*                                                                       25600021
MSGREIN  EQU   *                                                        25700021
         XC    RBGRSAVE+SIXTY(FIFTY),RBGRSAVE+SIXTY  CLEAR BUFFER.      25800021
         MVC   RBGRSAVE+SIXTY(IDSZE),MSGC  SET MSG ID                   25900021
         MVC   RBGRSAVE+SEV2(JSNAME),RBGRSAVE+SEV1 BLANK NAMES          26000021
         L     PARREG1,TCBTIO          TIOT ADDRESS.                    26100021
         LTR   PARREG1,PARREG1         TIOT EXISTS                      26200021
         BZ    MSGRA                   NO, SKIP JOB/STEP NAME STORE     26300021
         MVC   RBEXSAVE+EIGHT(SZE),ZERO(PARREG1) MOVE IN JOBNAME        26400021
         MVC   RBEXSAVE+SVNTN(SZE),SZE(PARREG1) MOVE IN STEPNAME        26500021
MSGRA    EQU   *                                                        26600021
         MVC   RBEXSAVE+TWNTY7(FIFTN),REINMSG MESSG TEXT                26700021
         MVC   RBEXSAVE+FORT2(FOUR),ROUT ROUTER AND DECSP CODES         26800021
         LA    WTOREG,RBGRSAVE+SIXTY  PARM FOR WTO.                     26900021
         WTO   MF=(E,(PARREG1))                   ISSUE WTO.            27000021
         XC    RBGRSAVE+SIXT3(FIFTY),RBGRSAVE+SIXT3  CLEAR THE BUFFER.  27100021
         SPACE 2                                                        27200021
****                                                               **** 27300021
*        INFORMATION LIST PURGE                                       * 27400021
****                                                               **** 27500021
         SPACE 1                                                        27600021
         L     LISTREG,CVTQMSG          START OF INFORMATION LIST       27700021
         L     ENDREG,0(,LISTREG)       END OF INFORMATION LIST         27800021
         LA    LISTREG,4(LISTREG)       ADDRESS FIRST ENTRY   AD  M0606 27820021
PRGSCAN  EQU   *                                                        27900021
         CR    ENDREG,LISTREG           HAVE ALL ENTRIES BEEN PROCESSED 28000021
         BE    REINSTAT                 YES-GO REINSTATE THE TASK       28100021
         C     TCBREG,4(,LISTREG)       ENTRY FOR CURR. TASK AD  A49808 28150021
         BNE   PRGNEXT                  NO-DON'T PURGE THIS ENTRY       28300021
         XC    0(INFLEN,LISTREG),0(LISTREG) PURGE LIST ENTRY            28400021
PRGNEXT  EQU   *                                                        28500021
         LA    LISTREG,INFLEN(,LISTREG) GET ADDR OF NEXT ENTRY          28600021
         B     PRGSCAN                  CHECK NEXT ENTRY                28700021
         EJECT                                                          28800021
*                                                                       28900021
*  ALL RBOPSW'S ARE SET FOR REINSTATEMENT. THE TCB WILL NOW BE          29000021
*  PROPERLY RESET AND DAR3 WILL EXIT CAUSING ALL RBS TO BE REMOVED      29100021
*  FROM THE RB CHAIN EXCEPT THE TOP RB WHOSE PSW HAS BEEN SET           29200021
*  TO INITIALIZE REINSTATEMENT                                          29300021
*                                                                       29400021
REINSTAT EQU   *                                                        29500021
         NI    TCBFLGS,ZERO            CLEAR TCB LOC 29.                29600021
         NI    TCBFLGS+ONE,TCLOC30     CLEAR TCB LOC 30.                29700021
         NI    TCBFLGS+2,255-TCBABTRM  CLEAR ABTERM BIT                 29800021
         MVI   TCBRECDE,X'00'          CLEAR RECURSION BITS             29900021
         L     BREG,CVTBTERM           ADDRESS OF ABTERM                30000021
         LA    BREG,TWO(BREG)          SET UP BASE.                     30100021
         SVC   EXIT                    EXIT FROM ABEND/DAR.             30400021
*  CONTROL WILL NOW BE RETURNED TO ABEND TO CONTINUE THE TERMINATION  * 30500021
*  PROCESS FOR A NON-SPECIAL SYSTEM TASK OR DAR 4 WILL GAIN CONTROL   * 30600021
*  TO SET THE ROLLOUT/ROLLIN TASK NON-DISPATCHABLE.                   * 30700021
         SPACE 1                                                        30800021
NONSYS   EQU   *                                                        30900021
         XC    RBEXSAVE(ESASZ),RBEXSAVE CLEAR THE SVRB ESA              31000021
         MVC   RBEXSAVE+40(6),ABENDN    INDICATE DAR 3 ENTRY TO ABEND1  31100021
         NI    TCBDAR,255-VMCDAR        TURN OFF VALID RECURS FLG       31200021
         MVI   TCBRECDE,TCBDARET        INDICATE RETURN FROM DAR        31400021
         LA    R10,NMABEND1             SET TO RETURN CONTROL TO ABEND  31500021
         B     XCTL                                                     31600021
TODAR4   EQU   *                                                        31700021
         LA    R10,NMDAR4               SET TO PASS CONTROL TO DAR 4    31800021
XCTL     EQU   *                                                        31900021
         L     PARREG0,THISMOD          SHOW ORIGIN FOR TRACE           31920021
         L     PARREG1,4(R10)           SHOW DESTINATION                31940021
         LA    R15,RBEXSAVE             ADDR OF PARAM LIST FOR XCTL     32000021
         XCTL  EPLOC=(10),SF=(E,(15))   TRANSFER CONTROL                32100021
         EJECT                                                          32200021
*  THIS SUBROUTINE IS PASSED CONTROL TO STORE THE ADDRESS OF AN EXIT    32300021
*  (SVC 3) INSTRUCTION INTO THE RESUME PSW OF EACH RB QUEUED OFF THE    32400021
*  FAILING TASK TCB AND THOSE OF ITS SUBTASKS. UPON REACHING THE TOP    32500021
*  LEVEL RB ON THE CHAIN, IT RETURNS CONTROL TO THE CALLER FOR FINAL    32600021
*  SPECIAL HANDLING OF THE TOP LEVEL RB.                                32700021
*                                                                       32800021
*                                                                       32900021
STORPSW  EQU   *                                                        33000021
         LA    WORK,CVTEXIT             ADDR OF SVC 3 INSTRUCTION       33100021
         LR    SAVE,RBREG          INITIALIZE NEXT_TO_TOP      @PD62726 33200021
         L     CHEKREG,RBLINK-1    AND TOP RB POINTERS         @PD62726 33240021
TSTEND   EQU   *                                               @PD62726 33280021
         USING RBSECT2,CHEKREG                                 @PD62726 33320021
         TM    RBSTAB2,X'C0'       RESET WAIT COUNT TO         @PD62726 33360021
         BNO   TSTEND1             ZERO                        @PD62726 33400021
         CLI   RBWCF2,255          FOR OVERLAID                @PD62726 33440021
         BNE   TSTEND1             TRANSIENT AREAS             @PD62726 33480021
         MVI   RBWCSAT2,0          USE                         @PD62726 33520021
         B     TSTEND2             ALTERNATE                   @PD62726 33560021
TSTEND1  EQU   *                   WAIT COUNT                  @PD62726 33600021
         MVI   RBWCF2,0            FIELD                       @PD62726 33640021
TSTEND2  EQU   *                                               @PD62726 33680021
         NI    RBSTAB2,X'FF'-RBWAITP NO LONGER WAITING ON ECB  @PD62726 33700021
         NI    RBSTAB2+1,X'FE'     TURN OFF MULTIPLE WAIT      @PD69859 33710021
         ST    WORK,RBOPSW+4       SET PSW TO SVC 3            @PD62726 33720021
         L     PARREG1,RBLINK2-1   POINT TO NEXT RB            @PD62726 33760021
         LA    PARREG1,0(,PARREG1) CLEAR WAIT COUNT            @PD62726 33800021
         CR    PARREG1,TCBREG      IF AT TCB,                  @PD62726 33840021
         BCR   SZE,RETREG          EXIT                        @PD62726 33880021
*                                                              @PD62726 33920021
** ON EXIT--                                                   @PD62726 33960021
**       CHEKREG--ADDRESS OF TOP RB                            @PD62726 34000021
**       SAVE--ADDRESS OF NEXT TO TOP RB                       @PD62726 34040021
*                                                              @PD62726 34080021
         LR    SAVE,CHEKREG        NEXT_TO_TOP = CURRENT       @PD62726 34120021
         LR    CHEKREG,PARREG1     CURRENT = NEXT_HIGHER       @PD62726 34160021
         B     TSTEND2             CONTINUE SCAN               @PD62726 34200021
         DROP  CHEKREG                                         @PD62726 34240021
         EJECT                                                          34300021
MSGC     DC    X'002E8000'                                              34400021
MSGD     DC    C'IEA029I '                                   AD  A56043 34500021
REINMSG  DC    C'TASK REINSTATED'                                       34600021
ROUT     EQU   *                                                        34700021
DES      DC    X'1000'                                                  34800021
RTE      DC    X'8000'                                                  34900021
         DS    0F                                                       35000021
NMDAR4   DC    C'IGC0P01C'              DAR LOAD 4 (REINSTAT FAILURE)   35100021
NMABEND1 DC    C'IGC0101C'              ABEND LOAD 1                    35200021
RORICODE DC    X'002FD000'              ROLLOUT ABEND CODE              35300021
IOERR    DC    X'80B06000'              I/O ERROR CODE                  35400021
THISMOD  DC    C'NO1C'                                                  35420021
ABENDN   DC    C'ABENDN'                                                35500021
         SPACE 1                                                        35600021
*        REGISTER EQUATES                                               35700021
*                                                                       35800021
PARREG0  EQU   0                                                        35900021
PARREG1  EQU   1                                                        36000021
WTOREG   EQU   1                                                        36100021
CHEKREG  EQU   2                                                        36200021
CVTREG   EQU   3                                                        36300021
TCBREG   EQU   4                                                        36400021
RBREG    EQU   5                                                        36500021
SCVTREG  EQU   6                                                        36600021
TASKREG  EQU   7                                                        36700021
LISTREG  EQU   7                                                        36800021
ATCBREG  EQU   8                                                        36900021
ENDREG   EQU   8                                                        37000021
BASEREG  EQU   9                                                        37100021
R10      EQU   10                                                       37300021
WORK     EQU   11                                                       37400021
SAVE     EQU   12                                                       37500021
SIRBREG  EQU   12                                              @PD62726 37550021
RETREG   EQU   14                                                       37600021
BREG     EQU   15                                                       37700021
R15      EQU   15                                                       37800021
         SPACE 1                                                        37900021
*        MISCELLANEOUS EQUATES (HEX)                                    38000021
*                                                                       38100021
HEXZERO  EQU   X'00'                                                    38200021
DISABLE  EQU   X'00'                                         AD   52736 38250021
CVTMPB   EQU   X'04'                                                    38300021
EXCPT    EQU   X'04'                                                    38400021
VMCDAR   EQU   X'10'                                                    38500021
APSWMSK  EQU   X'10'                                         AD   52736 38550021
LCA      EQU   X'1C'                                                    38600021
INFLEN   EQU   X'20'  INFORMATION LIST ENTRY LENGTH          AD  A49808 38650021
REGSAVE  EQU   X'20'                                         AD   52736 38750021
ERFLGS   EQU   X'3F'                                                    38800021
SDAR     EQU   X'40'                                                    38900021
POSTBIT  EQU   X'40'                                                    39000021
IOSRTN   EQU   X'40'                                         AD  A55639 39050021
SIRBTCB  EQU   X'44'                                         AD  A55639 39060021
TCLOC30  EQU   X'63'                                                    39100021
MISCMSK  EQU   X'70'                                                    39200021
SIRBMASK EQU   X'80'                                                    39300021
NOERROR  EQU   X'DF'                                                    39400021
DAOFF    EQU   X'FB'                                                    39500021
ROBT     EQU   X'FD'                                                    39600021
         EJECT                                                          39700021
*        MISCELLANEOUS EQUATES (DECIMAL)                                39800021
*                                                                       39900021
ZERO     EQU   0                                                        40000021
RBPTR    EQU   0                                                        40100021
ONE      EQU   1                                                        40200021
TWO      EQU   2                                                        40300021
EXIT     EQU   3                                                        40400021
FOUR     EQU   4                                                        40500021
IOBPTR   EQU   4                                                        40600021
EIGHT    EQU   8                                                        40700021
SZE      EQU   8                                                        40800021
RBSTABX  EQU   10                                                       40900021
TCBRQE   EQU   12                                                       41000021
IDSZE    EQU   12                                                       41100021
FIFTN    EQU   15                                                       41200021
COMPFLD  EQU   16                                                       41300021
SHFT     EQU   16                                                       41400021
ROREQ    EQU   16                                                       41500021
EXITING  EQU   16                                                       41600021
JSNAME   EQU   17                                                       41700021
SVNTN    EQU   17                                                       41800021
ACTOPSW  EQU   20                                                       41900021
TWNTY    EQU   20                                                       42000021
ABDINSTR EQU   20                                                       42100021
RHRBOPSW EQU   20                                                       42200021
RBQE     EQU   24                                                       42300021
TWNTY7   EQU   27                                                       42400021
LINKFLD  EQU   28                                                       42500021
LNK      EQU   28                                                       42600021
ABTRMFLG EQU   31                                                       42700021
STATFLG  EQU   32                                                       42800021
DSP      EQU   33                                                       42900021
ESOFFSET EQU   40                                                       43000021
FORT2    EQU   42                                                       43100021
DCERFLG  EQU   44                                                       43200021
ESASZ    EQU   48                                                       43300021
FIFTY    EQU   50                                                       43400021
SIXTY    EQU   60                                                       43500021
SIXT3    EQU   63                                                       43600021
SEV1     EQU   71                                                       43700021
SEV2     EQU   72                                                       43800021
TCTCB    EQU   116                                                      43900021
         EJECT                                                          44000021
****                                                               **** 44020021
*        MAINTENANCE PATCH AREA                                       * 44040021
****                                                               **** 44060021
         SPACE 1                                                        44080021
         DC    H'0'                                                     44084021
         DC    H'0'                                                     44088021
         DC    H'0'                                                     44092021
         DC    H'0'                                                     44096021
         DC    H'0'                                                     44096821
         DC    H'0'                                                     44097621
         DC    H'0'                                                     44098421
         DC    H'0'                                                     44099221
         DC    H'0'                                                     44099321
         DC    H'0'                                                     44099421
         DC    H'0'                                                     44099521
         DC    H'0'                                                     44099621
         DC    H'0'                                                     44099721
         DC    H'0'                                                     44099821
         DC    H'0'                                                     44099921
         DC    H'0'                                                     44133221
         DC    H'0'                                                     44153221
         DC    H'0'                                                     44157221
         DC    H'0'                                                     44161221
         DC    H'0'                                                     44165221
         DC    H'0'                                                     44166021
         DC    H'0'                                                     44166121
         DC    H'0'                                                     44166221
         DC    H'0'                                                     44166321
         EJECT                                                          44166421
         IHBABCTL                                                       44166721
         EJECT                                                          44186721
****                                                               **** 44190721
*        FLOWCHART STATEMENTS FOR DAR 3                               * 44194721
****                                                               **** 44198721
         SPACE 1                                                        44199521
*/*IEAQTM0N: CHART */                                                   44199621
*/*IEAQTM0N: E DAR 3 */                                                 44199721
*/*IGC0N01C: P ESTABLISH ADDRESSABILITY */                              44199821
*/*          D (YES,,NO,TAFTASK) MASTER SCHEDULER ABEND */              44199921
*/*          S STORPSW: SET RESUME PSWS OF ALL RBS TO SVC 3 INSTR */    44299921
*/*          D (YES,,NO,ELADECB) LOG CNTL AREA EXIST */                 44339921
*/*          P CLEAR LOG ECB */                                         44359921
*/*ELADECB:  P CLEAR ELEMENT ADDED ECB */                               44379921
*/*          P POST MASTER SCHEDULER ECB. CLEAR TASK ACTIVE BIT */      44383921
*/*          P (,MSGREIN) SET TOP RB PSW TO EXECUTE A LINK TO SCHEDULER 44387921
*/* WAIT RTN */                                                         44391921
*/*TAFTASK:  P GET FIRST TRANSIENT AREA TASK ADDRESS */                 44395921
*/*          P GET NUMBER OF TRANS AREA CONTROL TASK (TACT) ENTRIES */  44396721
*/*          D (YES,,NO,TAFTEST) MULTI - PROCESSING */                  44397521
*/*          P INCREMENT NUMBER OF TACT ENTRIES BY ONE */               44398321
*/*TAFTEST:  D (NO,,YES,TRANTASK) CURRENT TASK = TRANS AREA TASK */     44399121
*/*          P DECREMENT NUMBER OF TACT ENTRIES BY ONE */               44399221
*/*          P GET NEXT TRANS AREA TASK ADDR */                         44399321
*/*          D (YES,TAFTEST,NO,SYSERTSK) MORE TRANS AREA TASKS */       44399421
*/*TRANTASK: D (NO,,YES,PSW) ABEND SVRB ONLY RB ON CHAIN */             44399521
*/*MORRBS:   S STORPSW: SET RESUME PSW OF ALL RBS TO SVC 3 INSTR */     44399621
*/*PSW:      P (,MSGREIN) POINT TOP RB PSW TO ADDR IN IEAQTR33 */       44399821
*/*SYSERTSK: D (YES,,NO,COMMTASK) SYSER TASK FAILURE */                 44499821
*/*          P GET PREVIOUS RB ADDR */                                  44519821
*/*ERRTASK:  D (YES,,NO,NOTSIRB) IS RB THE SIRB */                      44539821
*/*          P TURN OFF ERROR FLAGS IN SVCLIB DCB */                    44559821
*/*          D (NO,STORSVC3,YES,DORQE) RQE EXIST */                     44579821
*/*NOTSIRB:  P POINT RBOPSW TO SVC 3 INSTRUCTION */                     44583821
*/*          P (,ERRTASK) GET NEXT PREVIOUS RB ADDR */                  44587821
*/*DORQE:    P GET FAILING TCB ADDR FROM RQE */                         44591821
*/*          P TURN ON ABTERM FLAG AND SET COMP CODE = X'80B0600' */    44595821
*/*          P POINT TOPRB OPSW TO SVC 13 INSTR AND CLEAR WAIT COUNT */ 44596621
*/*          P SET REG 1 = RQE ADDR FOR ERREXCP (SVC 15) */             44597421
*/*          P CLEAR 'ERROR RTN IN PROCESS' FLGS IN IOB AND TURN ON     44598221
*/*EXCEPTION BIT */                                                     44599021
*/*STORSVC3: P (,MSGREIN) POINT SIRB RBOPSW TO SVC 3 INSTR */           44599121
*/*COMMTASK: D (YES,,NO,IORMSTSK) COMM TASK FAILURE */                  44599221
*/*          S STORPSW: SET RESUME PSWS OF ALL RBS TO SVC 3 INSTR */    44599321
*/*          P (,MSGREIN) POINT RBOPSW OF TOP RB TO EP OF IEECVCTB */   44599421
*/*IORMSTSK: D (YES,,NO,RORITASK) IORMS TASK FAILURE */                 44599521
*/*          S STORPSW: SET RESUME PSWS OF ALL RBS TO SVC 3 INSTR */    44599621
*/*          P (,MSGREIN) POINT TOP RB PSW TO RMS SVC */                44599721
*/*RORITASK: D (YES,,NO,NONSYS) RORI TASK FAILURE */                    44699721
*/*          P GET TCB REQUESTING RORI AND TURN OFF ITS RORI BIT */     44719721
*/*          S ABTERM: SCHEDULE THE TASK REQUESTING RORI FOR ABEND */   44739721
*/*          R DAR 4 */                                                 44779721
*/*MSGREIN:  D (YES,,NO,MSGRA) TIOT EXIST */                            44783721
*/*          P MOVE JOBNAME AND STEPNAME INTO MESSAGE TEXT */           44787721
*/*MSGRA:    S WTO: IEA029I: TASK REINSTATED */                         44791721
*/*          P GET FIRST ENTRY IN INFORMATION LIST */                   44795721
*/*PRGSCAN:  D (NO,,YES,REINSTAT) ALL ENTRIES PROCESSED */              44796521
*/*          D (YES,,NO,PRGNEXT) ENTRY FOR CURRENT TASK */              44797321
*/*          P CLEAR THE ENTRY */                                       44798121
*/*PRGNEXT:  P (,PRGSCAN) GET NEXT ENTRY */                             44798921
*/*REINSTAT: P CLEAR TCBFLGS (LOC. 29 & 30) */                          44799021
*/*          P CLEAR ABTERM AND ALL VALID RECURSION FLAGS */            44799121
*/*          P SET REG 15 TO ABTERM EP AND REG 1 TO RQE ADDRESS */      44799221
*/*          R SVC 3 */                                                 44799321
*/*NONSYS:   P CLEAR SVRB ESA. TURN OFF VALID RECURS FLG */             44799421
*/*          P TURN ON DAR VALID RECURS FLG */                          44799521
*/*          R ABEND 1 */                                               44799621
*/*STORPSW:  E ENTRY */                                                 44899621
*/*          P POINT CURRENT RB PSW TO SVC 3 INSTRUCTION */             44919621
*/*          P GET ADDRESS OF PREVIOUS RB */                            44939621
*/*TSTEND:   D (YES,,NO,%NXTRB) DOES RB POINT TO TCB */                 44959621
*/*          R RETURN */                                                44979621
*/*%NXTRB:   P POINT RBOPSW TO SVC 3 INSTRUCTION */                     44983621
*/*          P (,TSTEND) GET NEXT PREVIOUS RB ADDRESS */                44987621
*/*IEAQTM0N: END */                                                     44991621
         END                                                            44999621
