IGC0P01C START                                                          00100021
 TITLE 'IGC0P01C / DAR LOAD 4 - REINSTATEMENT FAILURE / IEAQTM0P'       00200021
*                                                                       00300021
* MODULE NAME        - IEAQTM0P                                         00400021
*                                                                       00500021
* MVT SUPERVISOR     - DAR LOAD 4                                       00600021
*                                                                       00700021
* SVCS USED          - WTO                                              00800021
*                                                                       00900021
* EXTERNAL ROUTINES  - NONE                                             01000021
*                                                                       01100021
* ENTERED BY         - DAR LOAD 1 - IEAQTM0L IF THE ABENDING TASK       01200021
*                                     A. HAS RECURSED INVALIDLY         01300021
*                                        THROUGH DAR                    01400021
*                                     B.  HAS FAILED TASK REINSTATEMENT 01500021
*                                     C.  IS A SUBTASK WHOSE JOBSTEP    01600021
*                                         IS ABENDING                   01700021
*                                     D.  IS A JOBSTEP WHICH HAS        01800021
*                                         RECURSED INVALIDLY THROUGH    01900021
*                                         ABEND AND IS NEITHER A        02000021
*                                         SPECIAL SYSTEMS TASK OR A     02100021
*                                         TASK IN MUST-COMPLETE STATUS. 02200021
*                    - DAR LOAD 2 - IEAQTM0M IF THE ABENDING TASK IS IN 02300021
*                                   MUST-COMPLETE STATUS AND THE        02400021
*                                   SYSTEMS OPERATOR HAS INDICATED THAT 02500021
*                                   THE RESOURCES UPON WHICH THE TASK   02600021
*                                   IS ENQUEUED ARE CRITICAL.           02700021
*                                                                       02800021
* EXITS TO           - DISPATCHER - AFTER SETTING THE TASKS IN THE      02900021
*                                   ABENDING TREE PERMANENTLY NON-      03000021
*                                   DISPATCHABLE.                       03100021
*                                                                       03200021
* WORK AREAS - THE TWELVE WORDS OF THE EXTENDED SAVE AREA               03300021
*              OF THE DAR SVRB.                                         03400021
*                                                                       03500021
         EJECT                                                          03600021
*                                                                       03700021
* OPERATION          - DAR 4 IS ENTERED FOR THE SOLE PURPOSE OF         03800021
*                      SETTING TASKS PERMANENTLY NON-DISPATCHABLE.      03900021
*                      UPON ENTRY, DAR 4 ISSUES A WTO INFORMING THE     04000021
*                      SYSTEMS OPERATOR THAT REINSTATEMENT HAS FAILED   04100021
*                      FOR THE ABENDING TASK. THE SUBSYSTEM PURGE       04200021
*                      ROUTINE IS ENTERED TO ALLOW ANY NECESSARY        04300021
*                      SUBSYSTEM CLEANUP TO BE ACCOMPLISHED BEFORE THE  04400021
*                      TASK IS SET PERMANENTLY NON-DISPATCHABLE. NEXT,  04500021
*                      THE FAILING TASK IS SET PERMANENTLY NON-         04600021
*                      DISPATCHABLE ALONG WITH EVERY TASK IN THE        04700021
*                      ABENDING TREE (THOSE HAVING THE SAME JOBSTEP).   04800021
*                      HOWEVER, IF THE MASTER SCHEDULER IS ABENDING,    04900021
*                      ITS SUBTASKS ARE ALLOWED TO CONTINUE PROCESSING  05000021
*                      SINCE THEY ARE CRITICAL SYSTEM TASKS VITAL TO    05100021
*                      THE POSSIBLE CONTINUED OPERATION OF THE SYSTEM.  05200021
*                                                                       05300021
*                      IF THE GTF TRACE FUNCTION HAD BEEN SET           05400021
*                      INOPERATIVE, IT IS REACTIVATED VIA HOOK TO       05500021
*                      MODULE IHLMABON.                                 05600021
*                                                                       06300021
*                      DAR 4 THEN TAKES A BRANCH ENTRY TO THE           06400021
*                      DISPATCHER.                                      06500021
*                                                                       06600021
         EJECT                                                          06700021
*        REGISTER EQUATES                                               06800021
*                                                                       06900021
CLEAR    EQU   0                                                        07000021
RBPTR    EQU   0                                                        07100021
ZERO     EQU   0                                                        07200021
ONE      EQU   1                                                        07300021
PARREG1  EQU   1                                                        07400021
CVTREG   EQU   3                                                        07500021
THREE    EQU   3                                                        07600021
FOUR     EQU   4                                                        07700021
TCBREG   EQU   4                                                        07800021
RBREG    EQU   5                                                        07900021
ATCBREG  EQU   8                                                        08000021
SZE      EQU   8                                                        08100021
BASEREG  EQU   9                                                        08200021
NINE     EQU   9                                                        08300021
IDSZE    EQU   12                                                       08400021
WORK     EQU   11                                                       08500021
TASKREG  EQU   13                                                       08600021
RETREG   EQU   14                                                       08700021
R15      EQU   15                                                       08800021
SCVTREG  EQU   15                                                       08900021
         EJECT                                                          09000021
*        MISCELANEOUS EQUATES                                           09100021
*                                                                       09200021
PTRCVT   EQU   16                                                       09300021
SVNTN    EQU   17                                                       09400021
TWNT9    EQU   29                                                       09500021
DSP      EQU   33                                                 20472 09600021
SYSDISP  EQU   33                                                       09700021
DCERFLG  EQU   44                      LOC OF DCB ERROR INDIC.          09800021
FIFT2    EQU   52                                                       09900021
FIFT9    EQU   59                                                       10000021
TCTCB    EQU   116                                                      10100021
TCJPFLD  EQU   124                                                      10200021
TCBOTCB  EQU   132                                                      10300021
DARDISP  EQU   173                                                      10400021
DISPLOC  EQU   X'01'                                                    10500021
SDAR     EQU   X'40'                                                    10600021
XFF      EQU   X'FF'                                                    10700021
EIGHTN   EQU   18                                                       10800021
FORT3    EQU   43                                                       10900021
JSNAME   EQU   17                                                       11000021
SIX4     EQU   64                                                       11100021
SIX3     EQU   63                                                       11200021
         SPACE 2                                                        11300021
GTFSECT  DSECT                          TO GENERATE GTF EQUATES         11400021
         HOOK  EID=IHLMABON             RESUME GTF                      11500021
         EJECT                                                          11600021
IGC0P01C CSECT                                                          11700021
DAR4     BALR  BASEREG,ZERO            ESTABLISH ADDRESSABILITY.        11800021
         USING *,BASEREG                                                11900021
         USING CVTSECT,CVTREG           ADDRESS THE CVT                 12000021
         USING TCBSECT,TCBREG           ADDRESS THE TCB                 12100021
         USING TCBDSECT,ATCBREG         ADDRESS THE ALT. TCB            12200021
         L     RBREG,RBPTR(TCBREG)     PICK CURRENT RB ADDRESS.         12300021
         USING RBSECT,RBREG             ADDRESS THE RB                  12400021
         L     SCVTREG,CVTABEND        RESTORE SEC CVT REGISTER         12500021
         USING SCVTSECT,SCVTREG         ADDRESS THE SECONDARY CVT       12600021
         SPACE 1                                                        12700021
*  INFORM THE OPERATOR THAT THE ABENDING TASK FAILED TO BE REINSTATED * 12800021
         SPACE 1                                                        12900021
         TM    TCBDAR,TDAR              Q. IS THIS A DAR WTO     A36614 13000021
*                                        RECURSION               A36614 13100021
         BO    SETSWTCH                 YES, BYPASS SECOND MSG   A36614 13200021
         OI    TCBDAR,TDAR              TURN ON DAR REC FLAG TO  A36614 13400021
*                                        CATCH A WTO FAILURE     A36614 13500021
*                                                                       13600021
         LM    10,12,X'54'(5)      SAVE DESTROYED REGS         @PD68315 13700021
         L     13,X'8C'(,5)        SAVE ABEND CODE             @PD68315 13750021
         MVC   RBGRSAVE+FIFT2(IDSZE),MSGB  MOVE IN MESSAGE ID.          13800021
         L     PARREG1,TCBTIO          GET THE TIOT ADDRESS.            13900021
         MVC   RBGRSAVE+SIX4(JSNAME+1),RBGRSAVE+SIX3 BLANK NAMES        14000021
         LTR   PARREG1,PARREG1         TIOT EXISTS                      14100021
         BZ    NOTIOT                  NO, SKIP STORE OF JOB/STEP NAME  14200021
         MVC   RBEXSAVE(SZE),ZERO(PARREG1) MOVE IN JOBNAME              14300021
         MVC   RBEXSAVE+NINE(SZE),SZE(PARREG1) MOVE IN STEPNAME         14400021
NOTIOT   EQU   *                                                        14500021
         MVC   RBEXSAVE+EIGHTN(TWNT9),MSGFAIL MOVE IN TEXT              14600021
         LA    PARREG1,RBGRSAVE+FIFT2  GIVE PARM TO WTO.                14800021
         WTO   MF=(E,(PARREG1))                   ISSUE WTO.            14900021
         STM   10,12,X'54'(5)      RESTORE REGS                @PD68315 14930021
         ST    13,X'8C'(5)         RESTORE ABEND CODE          @PD68315 14960021
         NI    TCBDAR,255-TDAR          TURN OFF DAR REC FLAG    A36614 15000021
SETSWTCH EQU   *                                                        15100021
         L     TASKREG,CVTTCBP         ADDRESS NEW/OLD.                 15200021
         CLC   NEW+ONE(THREE,TASKREG),OLD+ONE(TASKREG)  IS NEW = OLD?   15300021
         BNE   QUIESCE                 NO-GO SET NON-DISPATCHABLE       15400021
         XC    NEW(FOUR,TASKREG),NEW(TASKREG)  INDICATE TASK SWITCH.    15500021
QUIESCE  EQU   *                                                        15600021
         NC    TCBOTC(FOUR),TCBOTC      MASTER SCHEDULER FAILING        15700021
         BC    7,NOTMASTR               NO-PREPARE TO SCAN READY QUEUE  15800021
         LR    TASKREG,TCBREG           PREPARE TO TEST FOR GTF TRACE   15900021
         OI    SYSDISP(TCBREG),DISPLOC  SET PERMANENTLY NON-DISP        16000021
         OI    DARDISP(TCBREG),SDAR     SET PERMANENTLY NON-DISP        16100021
         B     GTFTEST                  GO SEE IF GTF WAS STOPPED       16200021
NOTMASTR EQU   *                                                        16300021
         L     PARREG1,TCBJSTCB        INDIC. TASK TO STAY NON-DISP.    16400021
         LA    PARREG1,ZERO(PARREG1)   CLEAR THE FLAGS.                 16500021
*  OBTAIN THE JOBSTEP TCB ADDRESS OF EACH TASK ON THE TCB READY Q     * 16700021
         SPACE 1                                                        16900021
         L     CVTREG,PTRCVT           LOAD CVT POINTER.                17000021
         USING CVTSECT,CVTREG                                           17100021
         L     TASKREG,CVTHEAD         POINT TO TOP TCB                 17200021
         B     JOBSTEP                 GO TEST JOBSTEP       AD   M1512 17300021
QSEARCH  EQU   *                                                        17400021
         L     TASKREG,TCTCB(TASKREG)  NEXT TCB ON READY QUEUE          17500021
         LA    TASKREG,CLEAR(TASKREG)  CLEAR HI-ORDER BYTE.             17600021
         LTR   TASKREG,TASKREG         IS THERE ANOTHER READY TASK?     17700021
         BZ    TODISP                  NO-XFER CNTRL TO THE DISP        17800021
JOBSTEP  EQU   *                                             AD   M1512 17820021
         L     WORK,TCJPFLD(TASKREG)   JOB STEP PTR OF THIS TCB.        17900021
         LA    WORK,CLEAR(WORK)        CLEAR HI-ORDER BYTE.             18000021
         EJECT                                                          18400021
*  AT THIS TIME REGISTER 1 CONTAINS THE ADDRESS OF THE JOBSTEP TCB.   * 18500021
*  ANY TCB ON THE READY QUEUE HAVING THE SAME JOBSTEP TCB ADDRESS AS  * 18600021
*  THAT CONTAINED IN REGISTER 1 MUST BE SET PERMANENTLY NON-          * 18700021
*  DISPATCHABLE.                                                      * 18800021
         SPACE 1                                                        18900021
         CR    WORK,PARREG1            SET THIS TASK ND?                19000021
         BNE   QSEARCH                  NO-PICK UP NEXT TASK            19100021
*                                                                     * 19200021
* INFORM THE SUBSYSTEM PURGE ROUTINE THAT A TASK IS ABOUT TO BE SET   * 19300021
* PERMANENTLY NON-DISPATCHABLE                                        * 19400021
*                                                                     * 19500021
         L     R15,CVTPURG              GET ADDR OF SUBSYSTEM PURGE     19600021
         LR    PARREG1,TASKREG          SET INPUT REG                   19700021
         BALR  RETREG,R15               LINK WITH SUBSYSTEM PURGE       19800021
         LR    PARREG1,WORK             RESTORE PARREG1                 19900021
         OI    DARDISP(TASKREG),SDAR   SET PERMANENTLY NON-DISP.        20000021
         OI    SYSDISP(TASKREG),DISPLOC SET PERMANENTLY NON-DISP        20100021
*                                                                     * 20200021
* THE FOLLOWING GTF SUPPORT WILL RESUME GTF TRACE AFTER THE TASK      * 20300021
* HAS BEEN SET PERMANENTLY NON-DISPATCHABLE                           * 20400021
*                                                                     * 20500021
GTFTEST  EQU   *                                                        20600021
         USING TCBSECT,TASKREG          DSECT ADDRESSABILITY            20700021
         TM    TCBFLGS,TCBGTOFM         HAS GTF TRACE BEEN SUSPENDED    20800021
         BNO   TSTMASTR                 NO-GO SEE IF SCHEDULER ABENDED  20900021
         HOOK  EID=IHLMABON             RESUME GTF TRACE                21000021
         NI    TCBFLGS,XFF-TCBGTOFM     TURN OFF TRACE SUSPENDED FLAG   21100021
TSTMASTR EQU   *                                                        21200021
         NC    TCBOTC(FOUR),TCBOTC      MASTER SCHEDULER FAILING        21300021
         BC    8,TODISP                 YES-LET ITS SUBTASKS CONTINUE   21400021
*                                       PROCESSING                      21500021
         DROP  TASKREG                                                  21600021
         B     QSEARCH                 GO TO NEXT TASK.                 21700021
TODISP   EQU   *                                                        21800021
         L     RETREG,CVT0DS            GET EP ADDR OF DISPATCHER       21900021
         BR    RETREG                   XFER CONTROL TO THE DISPATCHER  22000021
         EJECT                                                          22100021
****                                                               **** 22200021
*        CONSTANTS FOR WTO PROCESSING                                 * 22300021
****                                                               **** 22400021
         SPACE 1                                                        22420021
MSGB     DC    X'00378000'                                              22500021
         DC    C'IEA029I '                                              22600021
MSGFAIL  DC    C'TASK REINSTATEMENT FAILED'                             22700021
ROUT     DC    X'1000'                                                  23300021
         DC    X'8000'                 ROUTING CODE              A26974 23400021
         EJECT                                                          23500021
****                                                               **** 23520021
*        MAINTENANCE PATCH AREA                                       * 23540021
****                                                               **** 23560021
         SPACE 1                                                        23580021
         DC    H'0'                                               20472 23600021
         DC    H'0'                                               20472 23700021
         DC    H'0'                                               20472 23800021
         DC    H'0'                                               20472 23900021
         DC    H'0'                                               20472 24000021
         DC    H'0'                                               20472 24100021
         DC    H'0'                                               20472 24200021
         DC    H'0'                                               20472 24300021
         DC    H'0'                                               20472 24400021
         DC    H'0'                                               20472 24500021
         DC    H'0'                                               20472 24600021
         DC    H'0'                                               20472 24700021
         DC    H'0'                                               20472 24800021
         DC    H'0'                                               20472 24900021
         DC    H'0'                                               20472 25000021
         DC    H'0'                                               20472 25100021
         DC    H'0'                                               20472 25200021
         DC    H'0'                                               20472 25300021
         DC    H'0'                                               20472 25400021
         DC    H'0'                                               20472 25500021
         DC    H'0'                                                     25520021
         DC    H'0'                                                     25540021
         DC    H'0'                                                     25560021
         DC    H'0'                                                     25580021
         EJECT                                                          25600021
         IHBABCTL                                                       25700021
TDAR     EQU   X'04'                    DAR TERTIARY RECURSION   A36614 25800021
         MPCVT                                                          25900021
         EJECT                                                          25920021
****                                                               **** 25940021
*        FLOWCHART STATEMENTS FOR DAR 4                               * 25960021
****                                                               **** 25980021
         SPACE 1                                                        25984021
*/*IEAQTM0P: CHART */                                                   25988021
*/*IEAQTM0P: E DAR 4 */                                                 25992021
*/*IGC0P01C: P ESTABLISH ADDRESSABILITY */                              25996021
*/*          D (NO,,YES,SETSWTCH) WTO RECURSION ACROSS DAR */           25996821
*/*          P SET DAR WRO RECURSION. CLEAR BUFFER FOR MESSAGE */       25997621
*/*          D (YES,,NO,NOTIOT) TIOT EXIST */                           25998421
*/*          P MOVE JOBNAME AND STEPNAME INTO MESSAGE TEXT */           25999221
*/*NOTIOT:   S WTO: IEA029I: TASK REINSTATEMENT FAILED */               25999321
*/*          P TURN OFF DAR WTO RECURSION FLAG */                       25999421
*/*SETSWTCH: D (NO,,YES,QUIESCE) TASK SWITCH EXIST */                   25999521
*/*          P SET TASK SWITCH (NEW=0) */                               25999621
*/*QUIESCE:  D (YES,,NO,NOTMASTR) MASTER SCHEDULER ABEND */             25999721
*/*          P (,GTFTEST) SET PRIMARY AND SECONDARY NON DISPATCHABILITY 25999821
*/* FLAGS */                                                            25999921
*/*NOTMASTR: P (,JOBSTEP) GET TOP TCB ADDR ON READY QUEUE */            26099921
*/*QSEARCH:  P GET NEXT LOWER TCB ON READY QUEUE */                     26119921
*/*          D (YES,,NO,TODISP) DOES THE TCB EXIST */                   26139921
*/*JOBSTEP:  D (YES,,NO,QSEARCH) SAME JOBSTEP AS ABENDING TASK */       26179921
*/*          S IEAASPRG: SUBSYSTEM PURGE */                             26183921
*/*          P SET PRIMARY AND SECONDARY NON DISPATCHABILITY FLAGS */   26187921
*/*GTFTEST:  D (YES,,NO,TSTMASTR) GTF SUSPENDED */                      26191921
*/*          S HOOK: IHLMABON: RESUME GTF TRACE */                      26195921
*/*TSTMASTR: D (YES,,NO,QSEARCH) MASTER SCHEDULER ABEND */              26196721
*/*TODISP:   R DISPATCHER */                                            26197521
*/*IEAQTM0P: END */                                                     26198321
         END                                                            26199921
