         TITLE 'IEAQTM0U/IGC0U01C - ABEND STAE INTERFACE RTN, LOAD 3'   00100000
IGC0U01C CSECT                                                          00200000
*199600,201200-202800,273000-353000                               19472 00300000
*                                                                       00400000
* IEAQTM0U IS A RENAME OF RELEASE 20.1 IEAQTM0D                         00500000
*                                                                       00600000
* ABEND/STAE INTERFACE ROUTINE - LOAD 3                                 00700000
*        LIBRARY NAME - IEAQTM0U                                        00800000
*        MODULE NAME  - IGC0U01C                                        00900000
*                                                                       01000000
* FUNCTION -                                                            01100000
*                                                                       01200000
*        TO SCAN THE RB CHAIN OF THE TASK TO DETERMINE IF ANY RB'S      01300000
*        EXIST BETWEEN THE RB ASSOCIATED WITH THE CURRENT STAE AND      01400000
*        THE RB ASSOCIATED WITH THE ABEND. IF THERE ARE INTERVENING     01500000
*        RB'S, THE PGM'S RELATED TO THESE RB'S ARE EXAMINED TO          01600000
*        DETERMINE IF ANY OPEN DATA SETS EXIST. FOR EACH OPEN DATA      01700000
*        SET FOUND (VIA DEB CHAIN) THE IOB RESTORE CHAIN ESTABLISHED    01800000
*        BY THE PURGE ROUTINE IN THE PREVIOUS LOAD IS SCANNED, AND ANY  01900000
*        IOB'S RELATED TO THE DATA SET ABOUT TO BE CLOSED ARE DEQUEUED  02000000
*        FROM THE CHAIN. SUBSEQUENTLY THE OPEN DATA SETS ARE CLOSED.    02100000
*        THE RESIDENT WTOR PURGE ROUTINE IS THEN CALLED VIA A BALR      02200000
*        INSTRUCTION. CONTROL IS THEN PASSED TO THE NEXT LOAD.          02300000
*                                                                       02400000
* APPLICABILITY -                                                       02500000
*                                                                       02600000
*        OPTION 4 SYSTEMS ONLY - MVT                                    02700000
*                                                                       02800000
* ATTRIBUTES -                                                          02900000
*                                                                       03000000
*        REENTRANT, REFRESHABLE, DISABLED, PRIVILEGED, NON-RESIDENT,    03100000
*        TYPE IV SVC ROUTINE.                                           03200000
*                                                                       03300000
* ENTRY POINT -                                                         03400000
*                                                                       03500000
*        IGC0U01C                                                       03600000
*                                                                       03700000
*        CONTROL IS PASSED TO THIS ROUTINE FROM LOAD 1 VIA XCTL         03800000
*        MACRO INSTRUCTION IF THE USER SPECIFIED A RETRY ATTEMPT        03900000
*        W/O PURGE OF THE RB CHAIN                                      04000000
*                                                                       04100000
* EXITS - NORMAL                                                        04200000
*                                                                       04300000
*        1. TO LOAD3 VIA XCTL TO CONTINUE STAE PROCESSING               04400000
*        2. TO LOAD4 VIA XCTL IF DURING THE CLOSING OF DATA SETS        04500000
*           FUNCTION ONE OR MORE DCB'S WERE FOUND TO BE USING           04600000
*           ISAM, BTAM OR QTAM FOR A LINE GROUP ACCESS METHOD.          04700000
*                                                                       04800000
*       - ABNORMAL                                                      04900000
*                                                                       05000000
*        1. TO ABEND1 VIA EXIT IF DURING THE PGM SEARCH FUNCTION        05100000
*           A CDE COULD NOT BE IDENTIFIED TO REPRESENT A PGM ON THE     05200000
*           RB CHAIN.                                                   05300000
*                                                                       05400000
* INPUT -                                                               05500000
*                                                                       05600000
*        REGISTERS UPON ENTRY;                                          05700000
*                                                                       05800000
*        REG 3 - CVT ADDR                                               05900000
*        REG 4 - ACTIVE TCB ADDR                                        06000000
*        REG 6 - CURRENT SCB ADDR                                       06100000
*        REG 7 - IOB RESTORE CHAIN ADDR                                 06200000
*        REG 8 - WORKAREA ADDR                                          06300000
*        REG 10 - ADDR OF RETRY RTN                                     06400000
*        REG 11 - NAME OF ABENDING                                      06500000
*        REG 12 -    PROGRAM                                            06600000
*        REG 13 - EP ADDR OF ABENDING PGM (IF P/P)                      06700000
* NOTE - REG 5 CONTAINS THE ADDR OF THE XCTLING RTN'S RB WHICH IS       06800000
*        DELETED BY THE XCTL RTN AND THEREFORE REQUIRES REINITIALIZA-   06900000
*        TION FROM THE TCB TO REFLECT THE ADDR OF THE NEW RB CREATED    07000000
*        BY THE XCTL ROUTINE.                                           07100000
*                                                                       07200000
* OUTPUT -                                                              07300000
*        REGISTERS 7,8,10,11,12,13,3,4 AT EXIT ARE THE SAME             07400000
*        AS AT ENTRY.                                                   07500000
*                                                                       07600000
* EXTERNAL REFERENCES                                                   07700000
*                                                                       07800000
*        1. CVT                                                         07900000
*        2. TCB                                                         08000000
*        3. RB                                                          08100000
*        4. TACT                                                        08200000
*        5. SCVT                                                        08300000
*        6. CDE                                                         08400000
*        7. BLOCK EXTENT LIST                                           08500000
*        8. SCATTER EXTENT LIST                                         08600000
*        9. DEB                                                         08700000
*       10. DCB                                                         08800000
*       11. IOB                                                         08900000
*       12. SCB                                                         09000000
*                                                                       09100000
* SVC'S USED -                                                          09200000
*                                                                       09300000
*        1. FREEMAIN - SVC 10                                           09400000
*        2. XCTL - SVC 7                                                09500000
*        3. CLOSE- SVC 20                                               09600000
*                                                                       09700000
* EXTERNAL ROUTINES -                                                   09800000
*                                                                       09900000
*        WTOR PURGE ROUTINE                                             10000000
*                                                                       10100000
* TABLES AND WORK AREAS                                                 10200000
*                                                                       10300000
*        ESA OF SVRB USED FOR TEMPORARY STORAGE                         10400000
*                                                                       10500000
* NOTES - NONE                                                          10600000
         EJECT                                                          10700000
*                                                                       10800000
*                   REGISTER EQUATES                                    10900000
*                                                                       11000000
REG0     EQU   0                                                  20472 11100000
INDEX    EQU   0                                                        11200000
PARREG0  EQU   0                                                  M2965 11300000
PARREG1  EQU   1                                                  M2965 11400000
PREVDEB  EQU   1                                                  M5731 11500000
WORK1    EQU   1                                                  M2965 11600000
REG1     EQU   1                                                  20472 11700000
LIST     EQU   1                                                        11800000
BASE     EQU   2                                                        11900000
CVT      EQU   3                                                        12000000
NCIOB    EQU   3                                                        12100000
TCB      EQU   4                                                        12200000
RB       EQU   5                                                        12300000
WORK     EQU   5                       TEMPORARY DCB ADDR REG           12400000
SCB      EQU   6                                                        12500000
WTOPADR  EQU   6                                                        12600000
IOB      EQU   7                                                        12700000
DCB      EQU   7                                                        12800000
IRBEP    EQU   7                                                        12900000
WORKAREA EQU   8                                                        13000000
OCIOB    EQU   8                                                        13100000
CDEEP    EQU   8                                                        13200000
LINK     EQU   8                                                        13300000
DEB      EQU   9                                                        13400000
ENTRY    EQU   9                                                  20472 13500000
ABENDRB  EQU   10                                                       13600000
RETRY    EQU   10                                                       13700000
ADDR     EQU   11                                                       13800000
END      EQU   12                                                 20472 13900000
TACT     EQU   13                                                       14000000
CDE      EQU   13                                                       14100000
JPADDR   EQU   13                                                       14200000
LPADDR   EQU   13                                                       14300000
EP       EQU   13                                                       14400000
UPPER    EQU   14                                                       14500000
RETREG   EQU   14                                                       14600000
ESA      EQU   14                                                       14700000
LOWER    EQU   15                                                       14800000
         EJECT                                                          14900000
*                                                                       15000000
*                   MISCELLANEOUS EQUATES                               15100000
*                                                                       15200000
TCBSTAE  EQU   160                     STAE FIELD IN TCB                15300000
TCBDEB   EQU   8                       DISP TO TCBDEB FIELD             15400000
RBLINK   EQU   28                      DISP TO RBLINK FIELD             15500000
RBSTAB   EQU   10                      DISP TO RBFLAG FIELD             15600000
RBCDE    EQU   13                      DISP TO RBCDE FIELD              15700000
RBOPSW   EQU   16                      DISP TO RBOPSW FIELD             15800000
TCBFLGS  EQU   29                      DISP TO TCBFLAG FIELD            15900000
DCBDSORG EQU   26                      DISP TO DCBDSORG FIELD           16000000
DCBOPTCD EQU   52                      DISP TO DCBOPTCD FIELD           16100000
TCBCMP   EQU   16                      DISP TO TCBCMP FIELD             16200000
ESASCB   EQU   28                      DISP TO SCB ADDR FIELD     20028 16300000
TWELVE   EQU   12                                                 20028 16400000
RBSCB    EQU   124                     DISP TO SCB ADDR FIELD     20028 16500000
DCBMACRF EQU   42                                                       16520021
         EJECT                                                          16600000
*                                                                       16700000
*                   FLAG MASKS                                          16800000
*                                                                       16900000
SVRBMASK EQU   X'C0'                   RB IS SVRB                       17000000
SIRBMASK EQU   X'80'                   RB IS SIRB                       17100000
IRBMASK  EQU   X'40'                   RB IS IRB                        17200000
TRANSVRB EQU   X'10'                   SVRB IS FOR TRANS. RTN.          17300000
MINCDE   EQU   X'04'                   CDE IS A MINOR                   17400000
SCATFLAG EQU   X'10'                   RESIDENT PGM SCATTER LOADED      17500000
SW       EQU   X'01'                   INTERNAL SWITCH                  17600000
OFFMASK  EQU   X'EE'                   MASK TO CLEAR SCATFLAG & SW      17700000
HIOFLAG  EQU   X'08'                   HIO OPTION USED W/PURGE          17800000
SINGIOB  EQU   X'01'                   AM HAS ONE IOB/DCB               17900000
SAMPAM   EQU   X'42'                   AM IS BSAM,BPAM OR QSAM          18000000
GAM      EQU   X'80'                   AM IS GAM                        18100000
BDAM      EQU  X'20'                   AM  IS BDAM                      18200000
ISAMTAM  EQU   X'90'                   MASK FOR ISAM & TAM              18300000
CHAINSCD EQU   X'20'                   CHAINED SCHEDULING W/BSAM,BPAM,  18400000
*                                      OR QSAM                          18500000
QTAMMSG  EQU   X'08'                   QTAM FOR PROCESSING PGM MSG Q    18600000
FOXFOX   EQU   X'FF'                   COMPARING MASK FOR END OF        18700000
*                                      IOB CHAIN                        18800000
STAI     EQU   X'20'                   STAI SCB INDICATOR FLAG    20028 18900000
*                                                                 M2965 19000000
RBEXSAVE EQU   X'60'                   EXTSA DISPLMT INTO RB      M2965 19100000
NEXTDEB  EQU   X'80'                                              M5731 19200000
NIC      EQU   X'40'                   CDE ATTRIBUTE FOR     AD  A46218 19220021
*                                      PGM BEING FETCHED     AD  A46218 19240021
DEBDEB   EQU   4                       DEB PTR TO NEXT DEB        M2965 19300000
DEBAPPAD EQU   28                                                 M2965 19400000
DUBLWORD EQU   7                                                  M2965 19500000
         EJECT                                                          19600000
         BALR  BASE,0                  ESTABLISH                        19700000
         USING *,BASE                      ADDRESSABILITY               19800000
         L     RB,0(TCB)               GET CURRENT RB ADDR              19900000
         LA    ESA,96(RB)              GET ADDR OF SVRB ESA             20000000
         MVI   45(ESA),C'U'            FLAG ESA WITH MODULE ID    20472 20100020
         STM   IOB,WORKAREA,0(ESA)     SAVE IOB CHAIN ADR & WORKAREA @  20200000
         STM   RETRY,EP,12(ESA)        SAVE ADDR RETRY, PGM NAME,       20300000
*                                      & PGM EP ADDR                    20400000
         ST    SCB,ESASCB(ESA)         SAVE CURRENT SCB           20028 20500000
         TM    TWELVE(SCB),STAI        Q  SCB FOR STAI?           20028 20600000
         BO    WTOPURGE                YES - TAKE BRANCH          20028 20700000
         LR    ABENDRB,RB              SET UP FOR FIRST RB CHECK A34147 20800000
RBTEST   EQU   *                                                 A34147 20900000
         CLC   RBLINK+1(3,ABENDRB),13(SCB) NEXT RB USING STAE?   A34147 21000000
         BE    WTOPURGE                YES, LAST RB ON CHAIN     A34147 21100000
         L     ABENDRB,RBLINK(ABENDRB) GET NEXT RB ADDR          A34147 21200000
*                                                                       21300000
*       A STAI EXIT HAS JUST BEEN PROCESSED OR                    20028 21400000
* IT HAS NOW BEEN DETERMINED THAT AT LEAST ONE RB EXISTS BETWEEN        21500000
* THE PGM THAT ISSUED STAE AND THE PGM THAT ABENDED. A SEARCH IS        21600000
* NOW MADE TO DETERMINE IF THE INTERVENING RB(S)  HAVE ANY              21700000
* OPEN DATA SET(S) AND PURGED I/O. IF SO, THE I/O WILL BE DEQUEUED      21800000
* FROM THE RESTORE CHAIN AND THE DATA SET(S) WILL BE CLOSED.            21900000
*                                                                       22000000
STAIPROC EQU   *                                                  20028 22100000
         L     DEB,TCBDEB(TCB)         GET DEB ADDR              A34147 22200000
         LTR   DEB,DEB                 IS THER AT LEAST ONE DEB? A34147 22300000
         BZ    WTOPURGE                NO, TAKE BRANCH           A34147 22400000
         TM    RBSTAB(ABENDRB),SVRBMASK IS RB AN SVRB?                  22500000
         BNZ   RBTEST                  YES, DCB SEARCH NOT REQ'D  19472 22600000
*                                                                       22700000
PRBPROC  EQU   *                                                        22800000
         L     CDE,RBCDE-1(ABENDRB)    GET CDE ADDR                     22900000
         LA    CDE,0(CDE)              CLEAR FLAG BYTE                  23000000
         LTR   CDE,CDE                 CDE ADDR PRESENT?                23100000
         BZ    RBTEST                  NO, EP ADDR AND LENGTH OF  M4272 23200000
*                                      PGM CANNOT BE FOUND- BRANCH      23300000
         TM    0(CDE),NIC              MODULE BEING FETCHED  AD  A46218 23320021
         BO    RBTEST                  YES, GO TO NEXT RB    AD  A46218 23340021
         TM    0(CDE),MINCDE           IS CDE A MINOR?                  23400021
         BZ    MAJOR                   NO, TAKE BRANCH                  23500000
         L     CDE,20(CDE)             GET MAJOR CDE ADDR               23600000
MAJOR    EQU   *                                                        23700000
         L     LIST,20(CDE)            GET EXTENT LIST ADDR             23800000
         LA    LIST,0(LIST)            CLEAR FLAG BYTE                  23900000
         LTR   LIST,LIST               DOES XL EXIST         AD  A46218 23920021
         BE    RBTEST                  NO, GO TO NEXT RB     AD  A46218 23940021
         CLI   7(LIST),X'01'           IS PGM SCATTER LOADED            24000000
         BH    SCATTER                 YES, TAKE BRANCH                 24100000
*                             PGM IS BLOCK LOADED                       24200000
         L     UPPER,12(LIST)          GET EP ADDR - UPPER BOUND        24300000
         L     LOWER,8(LIST)           GET BLOCK LENGTH                 24400000
         LA    LOWER,0(LOWER,UPPER)    GET LOWER ADDR OF BLOCK          24500000
         B     GETDCB                                                   24600000
SCATTER  EQU   *                                                        24700000
         OI    TCBSTAE(TCB),SCATFLAG    INDICATE SCATTER LOAD           24800000
         LR    END,LIST                SET POINTER TO END               24900000
         A     END,0(LIST)                  OF LIST                     25000000
         LA    END,0(END)              CLEAR FLAG BYTE                  25100000
         BAL   LINK,SCATFIX            GO TO SUBRTN WHICH WILL EXTRACT  25200000
         B     GETDCB                  DATA FROM EXTENT LIST            25300000
SCATRTN  EQU   *                                                        25400000
         LA    ADDR,4(ADDR)            SET PTR TO NEXT SGMENT           25500000
         CR    ADDR,END                END OF LIST?                     25600000
         BNL   FIXUP                   YES, TAKE BRANCH                 25700000
         LA    LIST,4(LIST)            SET PTR TO NEXT LENGTH           25800000
         BAL   LINK,EXTRACT            GO TO SUBRTN TO RESET BOUND REGS 25900000
         B     GETDCB                                                   26000000
FIXUP    EQU   *                                                        26100000
         L     DEB,4(DEB)              GET NEXT DEB ADDR          M5731 26200000
FIXLIST  EQU   *                                                  M5731 26300000
         L     LIST,20(CDE)            RESTORE PTR TO TOP OF LIST       26400000
         LA    LIST,0(LIST)            CLEAR FLAG BYTE                  26500000
         LR    END,LIST                RESTORE PTR TO                   26600000
         A     END,0(LIST)                  END OF LIST                 26700000
         BAL   LINK,SCATFIX            GO TO SUBRTN TO FIX SCATTER PTRS 26800000
         B     DEBCHK                                             M5731 26900000
SCATFIX  EQU   *                                                        27000000
         LA    LIST,8(LIST)            ADJUST TO BYPASS  PREFIX         27100000
         LR    ADDR,LIST               USE END PTR TO                   27200000
         SR    ADDR,END                GET LENGTH OF LIST MINUS PREFIX  27300000
         LCR   ADDR,ADDR               MAKE LIST LENGTH POSITIVE        27400000
         SRL   ADDR,1                  DIVIDE BY 2 AND ADD              27500000
         AR    ADDR,LIST                    TO GET MID PTR.             27600000
EXTRACT  L     UPPER,0(ADDR)           GET SEGMENT ADDR - UPPER BOUND   27700000
         L     LOWER,0(LIST)           GET SEGMT LENGTH                 27800000
         LA    LOWER,0(LOWER,UPPER)    GET LOWER ADDR OF SEGMT          27900000
         BR    LINK                    RETURN TO CALLER                 28000000
*                                                                       28100000
GETDCB   EQU   *                                                        28200000
         L     DCB,24(DEB)             GET DCB ADDR                     28300000
         LA    DCB,0(DCB)              CLEAR FLAG BYTE                  28400000
         CR    DCB,UPPER               IS DCB ADDR BELOW UPPER BOUND    28500000
         BL    TSTSCAT                 NO, TAKE BRANCH                  28600000
         CR    DCB,LOWER               IS DCB ADDR ABOVE LOWER BOUND    28700000
         BL    FOUND                   YES, DCB IS W/IN PGM BOUNDS      28800000
TSTSCAT  EQU   *                                                        28900000
         TM    TCBSTAE(TCB),SCATFLAG   PGM SCATTER LOADED?              29000000
         BO    SCATRTN                 YES, TAKE BRANCH                 29100000
NXTDEB   EQU   *                                                        29200000
         L     DEB,4(DEB)              GET NEXT DEB ADDR                29300000
DEBCHK   EQU   *                                                  M5731 29400000
         LA    DEB,0(DEB)              CLEAR FLAG BYTE                  29500000
         LTR   DEB,DEB                 ANOTHER DEB EXISTS?              29600000
         BNZ   GETDCB                  YES, TAKE BRANCH                 29700000
ENDDEBS  EQU   *                                                  M5731 29800000
         NI    TCBSTAE(TCB),OFFMASK    CLEAR SCATFLAG & SW              29900000
         B     RBTEST                  END OF DEB PROCESSING            30000000
*                                                                       30100000
FOUND    EQU   *                                                        30200000
         CLI   99(RB),FOXFOX           ANY I/O PURGED?                  30300000
         BE    CLOSE                   NO, TAKE BRANCH                  30400000
         NC    96(4,RB),96(RB)         ANY I/O IN PROGRESS?             30500000
         BNZ   AMSEARCH                YES, TAKE BRANCH                 30600000
*                                                                       30700000
CLOSE    EQU   *                                                        30800000
         L     DCB,24(DEB)             RESTORE DCB ADDR                 30900000
         MVC   NEXTDEB+1(3,RB),5(DEB)  SAVE ADDR OF NEXT DEB      M5731 31000000
         L     RB,0(TCB)               RESTORE RB ADDR REG              31100000
         L     SCB,RBSCB(RB)           SAVE SCB ADDR ACROSS CLOSE 20028 31200000
         LA    WORK1,124(RB)           SET PTR TO PARM WD FOR CLOSE     31300000
         ST    DCB,0(0,WORK1)          STORE IN DCB ADDR                31400000
         MVI   0(WORK1),128            SET OPTION BYTE                  31500000
         SVC   20                      ISSUE CLOSE SVC                  31600000
         ST    SCB,RBSCB(RB)           RESTORE SCB ADDRESS   AD   M2497 31650021
*        TEST TO SEE IF CLOSE WAS ABLE TO DEQUEUE THE DEB         M2965 31700000
         L     PREVDEB,TCBDEB(TCB)     GET ADDR OF FIRST DEB      M5731 31800000
         LTR   PREVDEB,PREVDEB         HAVE ALL DEBS              M5731 31900000
*                                      BEEN DEQUEUED              M5731 32000000
         BE    ENDDEBS                 YES-CONTINUE TO NEXT RB    M5731 32100000
         CR    PREVDEB,DEB             IS DEB FIRST ON CHAIN      M5731 32200000
         BNE   DEBSRCH                 NO-CONTINUE SCAN           M5731 32300000
         NC    5(3,DEB),5(DEB)         IS DEB ONLY ONE ON CHAIN   M5731 32400000
         BZ    ENDCHAIN                YES-GO CLEAR DEB CHAIN     M5731 32500000
         MVC   TCBDEB+1(3,TCB),NEXTDEB+1(RB) DEQUEUE CURRENT DEB  M5731 32600000
*                                      AND CHAIN NEXT DEB TO TCB  M5731 32700000
         B     FREEDEB                 GO FREE CURRENT DEB        M5731 32800000
ENDCHAIN EQU   *                                                  M5731 32900000
         XC    TCBDEB(4,TCB),TCBDEB(TCB) ZERO-OUT PTR TO          M5731 33000000
*                                      DEB CHAIN IN TCB           M5731 33100000
         B     FREEDEB                 GO FREE THE DEB            M5731 33200000
DEBSRCH  EQU   *                                                  M5731 33300000
         LA    PREVDEB,0(PREVDEB)      CLEAR HI-ORDER BYTE        M5731 33400000
         NC    5(3,PREVDEB),5(PREVDEB) END OF DEB CHAIN           M5731 33500000
         BZ    RESTORE                 YES-DEB DEQUEUED           M5731 33600000
         C     DEB,4(PREVDEB)          IS NEXT DEB THE ONE        M5731 33700000
*                                      NOT DEQUEUED               M5731 33800000
         BE    DEQDEB                  YES-DEQUEUE IT             M5731 33900000
         L     PREVDEB,4(PREVDEB)      GET NEXT DEB               M5731 34000000
         B     DEBSRCH                 CONTINUE SCAN              M5731 34100000
DEQDEB   MVC   5(3,PREVDEB),NEXTDEB+1(RB) DEQUEUE THE DEB         M5731 34200000
FREEDEB  EQU   *                                                  M5731 34300000
         SR    PARREG0,PARREG0         INITIALIZE REGISTER        M2965 34400000
         S     DEB,CONS4               GET ADDR OF DEB LENGTH FLD M2965 34500000
         IC    PARREG0,0(DEB)          GET DEB LEN IN DOUBLEWORDS M2965 34600000
         SLL   PARREG0,3               CONVERT TO BYTES           M2965 34700000
         O     PARREG0,CONS254          SUB POOL ID=254 FOR DEB   M2965 34800000
         SH    DEB,CONS32              GET ADDRESS OF DEB APPEND  M4529 34900000
         L     WORK1,DEBAPPAD+36(DEB)  GET ADDR OF DEB APPENDAGE  M2965 35000000
         LA    WORK1,0(WORK1)          CLEAR HIGH-ORDER BYTE      M2965 35100000
         CR    DEB,WORK1               Q. QTAM DEB                M2965 35200000
         BE    NOQTAM                  NO, FREE CORE AT DEB-36    M2965 35300000
         ST    DEB,RBEXSAVE+8(RB)                                 M2965 35400000
         TM    RBEXSAVE+11(RB),DUBLWORD IS APP TBL ON DBL WD BDRY M2965 35500000
         BZ    NOQTAM                  YES BRANCH- NOT QTAM DEB   M2965 35600000
         LA    DEB,20(DEB)             QTAM- FREE CORE AT DEB-16  M2965 35700000
NOQTAM   EQU   *                                                  M2965 35800000
         LR    PARREG1,DEB             LOAD ADDR OF DEB TO FREE   M2965 35900000
         FREEMAIN R,LV=(0),A=(1)       ISSUE FREEMAIN MACRO       M2965 36000000
*                                                                 M2965 36100000
RESTORE  L     DEB,NEXTDEB(RB)          ACCESS NEW DEB PTR        M5731 36200000
         TM    TCBSTAE(TCB),SCATFLAG   WAS PGM SCATTER LOADED?          36400000
         BO    FIXLIST                 YES-RETURN TO              M5731 36500000
*                                      SCATTER PROCESS            M5731 36600000
         B     DEBCHK                  CHECK FOR MORE DEBS        M5731 36700000
*                                                                       36800000
AMSEARCH EQU   *                                                        36900000
*                                                                 M5938 36920021
* BECAUSE THE CONTENTS OF DCBDSORG IS UNRELIABLE FOR EXCP DCB A   M5938 36940021
* TEST TO ISOLATE EXCP DCB IS NECESSARY.                          M5938 36960021
EXCPDCBF EQU   X'80'                   EXCP DCB ID                M5938 36980021
         TM    DCBMACRF(DCB),EXCPDCBF  Q. IS THIS EXCP DCB        M5938 36984021
         BNZ   NXTDEB                  YES. PROCESS IT            M5938 36988021
         TM    DCBDSORG(DCB),SAMPAM    TEST FOR BPAM,BSAM,QSAM          37000000
         BZ    AMTEST                  NOT BPAM,BSAM,QSAM - CONTINUE    37100000
         TM    DCBOPTCD(DCB),CHAINSCD  IS CHAINED SCHEDULING BEING USED 37200000
         BO    ONEIOB                  YES, TAKE BRANCH                 37300000
         L     INDEX,MINEIGHT          SET INDEX TO IOB PTR FIELD       37400000
         L     IOB,68(DCB)             GET IOBADDR FROM DCB             37500000
ADD      AH    IOB,EIGHT               ADJUST TO BYPASS PREFIX          37600000
         B     IOBPROC                                                  37700000
ONEIOB   EQU   *                                                        37800000
         OI    TCBSTAE(TCB),SINGIOB    INDICATE ONE IOB/DCB             37900000
         L     IOB,28(DCB)             GET IOB ADDR FROM DCB            38000000
         LA    IOB,16(IOB)             BUMP PAST PREFIX                 38100000
         B     IOBPROC                                                  38200000
AMTEST   EQU   *                                                        38300000
         TM    DCBDSORG(DCB),ISAMTAM   IS AM ISAM OR TAM?               38400000
         BC    4,RECORD                RECORD AM= ISAM, TAM             38500000
         TM    DCBDSORG+1(DCB),GAM     AM = GAM?                        38600000
         BZ    AMTEST2                 NO, TAKE BRANCH                  38700000
         LA    INDEX,36                SET INDEX TO IOB PTR FIELD       38800000
GETIOB   L     IOB,28(DCB)             GET IOB ADDR LINKED TO DCB       38900000
         B     IOBPROC                                                  39000000
AMTEST2  EQU   *                                                        39100000
         TM    DCBDSORG(DCB),BDAM      AM = BDAM?                       39200000
         BZ    AMTEST3                 NO, TAKE BRANCH                  39300000
         LA    INDEX,44                SET INDEX TO IOB PTR FIELD       39400000
         B     GETIOB                                                   39500000
AMTEST3  EQU   *                                                        39600000
         TM    DCBDSORG(DCB),QTAMMSG   AM = QTAM FOR PGM MSG QUEUE?     39700000
         BO    CLOSE                   YES, TAKE BRANCH                 39800000
*                                                                       39900000
*              REMAINING AM'S HAVE ONE IOB/DCB                          40000000
*                                                                       40100000
         OI    TCBSTAE(TCB),SINGIOB    INDICATE ONE IOB/DCB             40200000
         L     IOB,28(DCB)             GET FIRST IOB ADDR               40300000
*                                                                       40400000
* FOLLOWING CODE IS DESIGNED TO REMOVE IOB'S FROM THE RESTORE CHAIN     40500000
* THAT ARE ASSOCIATED WITH DCB'S WHICH ARE TO BE CLOSED IN PREPERATION  40600000
* FOR THE PURGE OF THE RB QUEUE                                         40700000
*                                                                       40800000
IOBPROC  EQU   *                                                        40900000
         L     RB,0(TCB)               RESTORE RB REG                   41000000
         LA    IOB,0(IOB)              CLEAR FLAG BYTE                  41100000
         SR    OCIOB,OCIOB             CLEAR OLD IOB REG                41200000
         L     NCIOB,96(RB)            GET 1ST IOB ADDR OFF CHAIN       41300000
         LA    NCIOB,0(NCIOB)          CLEAR FLAG BYTE                  41400000
         LTR   NCIOB,NCIOB             ANY IOB'S ON RESTORE CHAIN?      41500000
         BZ    CLOSE                   NO, BRANCH                       41600000
IOBCOMP  CR    IOB,NCIOB               IOB FROM DCB = IOB OFF CHAIN?    41700000
         BE    IOBTEST                 YES TAKE BRANCH                  41800000
         LR    OCIOB,NCIOB             SAVE OLD IOB OFF CHAIN           41900000
         CLI   27(OCIOB),FOXFOX        LAST IOB ON CHAIN?               42000000
         BE    BITTEST                 YES, TAKE BRANCH                 42100000
         L     NCIOB,24(OCIOB)         GET NEXT IOB ADDR OFF CHAIN      42200000
         LA    NCIOB,0(NCIOB)          CLEAR FLAG BYTE                  42300000
         B     IOBCOMP                                                  42400000
IOBTEST  EQU   *                                                        42500000
         LTR   OCIOB,OCIOB             DID MATCH OCCUR W/ FIRST IOB ON  42600000
*                                      CHAIN?                           42700000
         BZ    FSTIOB                  YES, TAKE BRANCH                 42800000
         MVC   25(3,OCIOB),25(NCIOB)   SET OLD IOB TO POINT PAST IOB    42900000
*                                      MATCHING IOB FROM DCB - WHEN     43000000
*                                      DCB CLOSED,IOB IS FREED. ABOVE   43100000
*                                      REARRANGEMENT OF FWD PTRS WILL   43200000
*                                      INSURE RESTORE CHAIN WILL        43300000
*                                      CONTAIN NO GAPS.                 43400000
*                                                                       43500000
         B     BITTEST                                                  43600000
FSTIOB   EQU   *                                                        43700000
         CLI   27(NCIOB),FOXFOX        LAST IOB ON CHAIN?         M5930 43800000
         BNE   SETPTR                  NO, TAKE BRANCH                  43900000
         XC    96(4,RB),96(RB)         INDICATE NO I/O RESTORABLE       44000000
         B     CLOSE                                                    44100000
SETPTR   EQU   *                                                        44200000
         MVC   97(3,RB),25(NCIOB)      ADJUST CHAIN PTR TO POINT PAST   44300000
*                                      FIRST IOB ON RESTORE CHAIN       44400000
*                                      SINCE IT WILL BE FREED WHEN      44500000
*                                      THE DCB IS CLOSED                44600000
BITTEST  EQU   *                                                        44700000
         TM    TCBSTAE(TCB),SINGIOB    IS THERE ONLY ONE IOB/DCB?       44800000
         BO    PREPCLOS                YES, TAKE BRANCH                 44900000
         LR     WORK,IOB               KEEP ACTIVE IOB PTR              45000000
         AR    WORK,INDEX              ADD DISP TO FWD PTR FIELD        45100000
         L     WORK,0(WORK)            GET NEXT IOB ADDR                45200000
         LA    WORK,0(WORK)            CLEAR FLAG BYTE                  45300000
         LTR   WORK,WORK               ANY MORE IOB'S ON CHAIN?         45400000
         BZ    PREPCLOS                NO, BRANCH                       45500000
         CR    WORK,IOB                DOES IOB POINT TO ITSELF?        45600000
         BE    PREPCLOS                YES, BRANCH, END OF CHAIN        45700000
         LR    IOB,WORK                USE NEW IOB ADDR FOR PROCESSING  45800000
         L     WORK,24(DEB)            GET DCB ADDR FROM DEB            45900000
         TM    DCBDSORG(WORK),SAMPAM   BSAM,BPAM OR QSAM IN USE?        46000000
         BO    ADD                     ADJUST IOB ADDR TO POINT PAST    46100000
*                                      PREFIX AREA                      46200000
         TM    DCBDSORG+1(WORK),GAM    IS AM = GAM?                     46300000
         BZ    DAMTEST                 NOT GAM, TAKE BRANCH             46400000
         TM    36(IOB),X'80'           IS IOB IN USE?                   46500000
FINAL    EQU   *                                                        46600000
         BZ    CLOSE                   IOB NOT USED, LAST ON CHAIN      46700000
         B     IOBPROC                 IOB IN USE, CONTINUE SEARCH      46800000
DAMTEST  EQU   *                                                        46900000
         TM    DCBDSORG(WORK),BDAM     IS AM = BDAM?                    47000000
         BZ    IOBPROC                 NOT BDAM, CONTINUE PROCESSING    47100000
         CLI   44(IOB),X'00'           IS IOB IN USE?                   47200000
         B     FINAL                                                    47300000
PREPCLOS EQU   *                                                        47400000
         NI    TCBSTAE(TCB),255-SINGIOB  CLEAR SING IOB FLAG            47500000
         B     CLOSE                                                    47600000
*                                                                       47700000
*                                                                       47800000
*                                                                       47900000
WTOPURGE EQU   *                                                        48000000
         L     CVT,16                  RESTORE PTR TO CVT               48100000
         L     WTOPADR,200(CVT)        GET ADDR OF SCVT                 48200000
         L     WTOPADR,4(WTOPADR)      GET ADDR OF WTOR PURGE RTN       48300000
         BALR  RETREG,WTOPADR          GO TO WTOR PURGE                 48400000
         L     SCB,RBSCB(RB)           RESTORE  SCB  PTR          20028 48500000
         TM    12(SCB),X'40'           ISAM OR TAM ENCOUNTERED?         48600000
         BO    XFER                    YES, SET UP TO XCTL TO LOAD 4    48700000
         LA    ENTRY,LOADE             GET ADDR OF LOAD 3 NAME          48800000
SETLIST  EQU   *                                                        48900000
         L     SCB,RBSCB(RB)           RESTORE SCB ADDRESS        20028 49000000
         LM    IOB,WORKAREA,96(RB)     RECALL IOB CHAIN & WORKAREA ADDR 49100000
         LM    RETRY,EP,108(RB)        RECALL ADDR OF RETRY RTN, PGM    49200000
*                                      NAME & EP ADDR                   49300000
         L     REG0,THISMOD            FLAG REGS 0 AND 1 IN       20472 49400000
         L     REG1,4(ENTRY)             XCTL'S TRACE TABLE ENTRY 20472 49500000
         LA    15,96(RB)               SAVE ADDR OF ESA FOR XCTL  20472 49600000
         XCTL  EPLOC=(ENTRY),SF=(E,(15))   GO TO XCTL TO GET LOAD       49700000
XFER     EQU   *                                                        49800000
         LA    ENTRY,LOADF             GET ADDR OF LOAD 4 NAME          49900000
         B     SETLIST                                                  50000000
RECORD   EQU   *                                                        50100000
         OI    12(SCB),X'40'           TAM OR ISAM IN USE?              50200000
         B     NXTDEB                  CONTINUE SEARCH                  50300000
         EJECT                                                          50400000
*                                                                       50500000
*                   CONSTANTS                                           50600000
*                                                                       50700000
CONS4    DC    F'4'                                               M2965 50800000
CONS254  DC    X'FE000000'                                        M2965 50900000
CONS32   DC    H'32'                                              M2965 51000000
*                                                                 M2965 51100000
         DS    0F                                                       51200000
THISMOD  DC    C'U01C'                 TRACE TABLE FLAG           20472 51300000
LOADE    DC    C'IGC0W01C'             NAME OF ABEND/STAE               51400000
*                                       INTERFACE ROUTINE, LOAD 3       51500000
LOADF    DC    C'IGC0V01C'             NAME OF ABEND/STAE               51600000
*                                       INTERFACE ROUTINE, LOAD 4       51700000
EIGHT    DC    H'8'                    ADDITION CONSTANT                51800000
ONEK     DC    H'1024'                                                  51900000
MINEIGHT DC    X'FFFFFFF8'             INDEX VALUE - MINUS EIGHT. 20472 52000000
*                                      FOR IOB PTR FIELD IN IOB - 20472 52100000
*                                      BPAM, BSAM, QSAM           20472 52200000
         EJECT                                                          52300000
*                                                                 M2991 52400000
*        THE FOLLOWING SPACE IS RESERVED FOR MAINTENANCE USE      M2991 52500000
*                                                                 M2991 52600000
         DC    H'0'                                               M2991 52700000
         DC    H'0'                                                     52800000
         DC    H'0'                                                     52900000
         DC    H'0'                                                     53000000
         DC    H'0'                                                     53100000
         DC    H'0'                                                     53200000
         DC    H'0'                                                     53300000
         DC    H'0'                                                     53400000
         DC    H'0'                                                     53500000
         DC    H'0'                                                     53600000
         DC    H'0'                                                     53700000
         DC    H'0'                                                     53800000
         DC    H'0'                                                     53900000
         DC    H'0'                                                     54000000
         DC    H'0'                                                     54100000
         DC    H'0'                                                     54200000
         DC    H'0'                                                     54300000
         DC    H'0'                                                     54400000
         DC    H'0'                                                     54500000
         DC    H'0'                                                     54600000
         EJECT                                                          54700000
*/*IEAQTM0U: CHART */                                                   54800021
*/*IEAQTM0U: E ASIR3 */                                                 54900000
*/*IGC0U01C: D (NO,,YES,WTOPURGE) STAI SCB */                           55000021
*/*RBTEST:   D (NO,,YES,WTOPURGE) NEXT RB USING STAE */                 55100000
*/*          P UPDATE CURRENT RG ADDR TO NEXT RB ADDR */                55200000
*/*STAIPROC: D (YES,,NO,WTOPURGE) DEB EXIST */                          55300000
*/*          D (NO,,YES,RBTEST) IS RB AN SVRB */                        55400000
*/*PRBPROC:  D (YES,,NO,RBTEST) CDE EXIST */                            55500000
*/*          D (YES,,NO,RBTEST MODULE IN CORE */                        55600021
*/*          D (YES,,NO,RBTEST) MAJOR CDE HAVE EXTENT LIST */           55700021
*/*          D (NO,,YES,SCATTER) PGM SCATTER LOADED */                  55800021
*/*          P (,GETDCB) GET UPPER AND LOWER BDS AND BLK LENGTH FROM    55900000
*/*EXTENT LIST */                                                       56000000
*/*SCATTER:  P TURN ON 'SCATTER LOADED' FLAG IN TCB */                  56100000
*/*          S (,GETDCB) SCATFIX: GET SEGMENT LENGTH AND BOUNDS */      56200000
*/*SCATRTN:  P GET ADDR OF NEXT SEGMENT */                              56300000
*/*          D (NO,,YES,FIXUP) END OF EXTENT LIST */                    56400000
*/*          P SET INPUT ADDR TO NEXT SEGMENT LENGTH */                 56500000
*/*          S (,GETDCB) EXTRACT: GET NEXT SEGMENT BOUNDS AND LENGTH */ 56600000
*/*FIXUP:    P GET NEXT DEB ADDR */                                     56700000
*/*FIXLIST:  P SET INPUT PARAMS TO BEGINNING AND END OF EXTENT LIST */  56800000
*/*          S (,DEBCHK) SCATFIX: GET FIRST SEGMENT */                  56900000
*/*GETDCB:   D (NO,,YES,FOUND) DCB W/IN PGM BOUNDS */                   57000000
*/*TSTSCAT:  D (NO,,YES,SCATRTN) PGM SCATTER LOADED */                  57100000
*/*NXTDEB:   P GET NEXT DEB */                                          57200000
*/*DEBCHK:   P CLEAR FLAGS */                                           57220000
*/*          D (NO,,YES,GETDCB) ANY MORE */                             57240000
*/*ENDDEBS:  P (,RBTEST) TURN OFF 'SCATTER LOADED' FLG IN TCB */        57300000
*/*FOUND:    D (YES,,NO,CLOSE) ANY I/O PURGED */                        57400000
*/*          D (NO,,YES,AMSEARCH) ANY I/O IN PROGRESS */                57500000
*/*CLOSE:    S CLOSE: CLOSE DCB */                                      57600000
*/*          D (NO,,YES,ENDDEBS) ALL DEBS DEQUEUED */                   57700000
*/*          D (YES,,NO,DEBSRCH) SUBJECT DEB 1ST ON CHAIN */            57800000
*/*          D (NO,,YES,ENDCHAIN) SUBJ DEB ONLY ONE ON CHAIN */         57900000
*/*          P (,FREEDEB) DEQ SUBJ DEB AND CHAIN NEXT DEB TO TCB */     58000000
*/*ENDCHAIN: P (,FREEDEB) ZERO-OUT PTR TO DEB CHAIN IN TCB */           58100000
*/*DEBSRCH:  D (NO,,YES,RESTORE) ANY MORE DEBS */                       58200000
*/*          D (NO,,YES,DEQDEB) NEXT DEB THE SUBJ DEB */                58300000
*/*          P (,DEBSRCH) GET NEXT DEB */                               58400000
*/*DEQDEB:   P DEQUEUE THE DEB FROM DEB CHAIN */                        58500000
*/*FREEDEB:  P SET DEB ADDR TO DEB-36 */                                58600000
*/*          D (YES,,NO,NOQTAM) QTAM DEB */                             58700000
*/*          P SET DEB ADDR TO DEB-16 */                                58800000
*/*NOQTAM:   S FREEMAIN: FREE THE DEB */                                58900000
*/*RESTORE:  P GET NEXT DEB */                                          59000000
*/*          D (NO,DEBCHK,YES,FIXLIST) PGM SCATTER LOADED */            59100000
*/*AMSEARCH: D (NO,,YES,NXTDEB) EXCP DCB */                             59200021
*/*          D (YES,,NO,AMTEST) BPAM, BSAM OR QSAM AM */                59300000
*/*          D (NO,,YES,ONEIOB) CHAINED SCHEDULING */                   59400000
*/*          P SET IOB FWD PTR INDEX TO -8 */                           59500000
*/*          P GET IOB FROM DCB+68 */                                   59600000
*/*ADD:      P (,IOBPROC) SET IOB = IOB+8 (BYPASS PREFIX) */            59700000
*/*ONEIOB:   P TURN ON FLG IN TCBNSTAE INDICATING ONE IOB/DCB */        59800000
*/*          P (,IOBPROC) GET IOB FROM DCB+28. SET IOB = IOB+16 (BYPASS 59900000
*/* PREFIX) */                                                          60000000
*/*AMTEST:   D (YES,,NO,%GAMTST) ISAM OR TAM AM */                      60100000
*/*          P (,NXTDEB) FLAG SCB INDICATING ISAM OR TAM IN USE */      60200000
*/*%GAMTST:  D (YES,,NO,AMTEST2) AM = GAM */                            60300000
*/*          P SET IOB FWD PTR INDEX TO 36 */                           60400000
*/*GETIOB:   P (,IOBPROC) GET IOB FROM DCB+28 */                        60500000
*/*AMTEST2:  D (YES,,NO,AMTEST3) AM = BDAM */                           60600000
*/*          P (,GETIOB) SET IOB FWD PTR INDEX TO 44 */                 60700000
*/*AMTEST3:  D (NO,,YES,CLOSE) AM = QTAM FOR PGM MSG QUEUE */           60800000
*/*EXCPDCB:  P TURN ON FLG IN TCBNSTAE INDICATING ONE IOB/DCB */        60900000
*/*          P GET FIRST IOB FROM DCB+28 */                             61000000
*/*IOBPROC:  D (YES,,NO,CLOSE) ANY IOBS ON RESTORE CHAIN */             61100000
*/*IOBCOMP:  D (NO,,YES,IOBTEST) IOB FROM DCB = IOB OFF RES CHAIN */    61200000
*/*          D (YES,,NO,BITTEST) ANY MORE IOBS ON RES CHAIN */          61300000
*/*          P (,IOBCOMP) SELECT NEXT IOB OFF RESTORE CHAIN */          61400000
*/*IOBTEST:  D (NO,,YES,FSTIOB)  IOB OFF DCB = IOB OFF RES CHAIN */     61500000
*/*          P (,BITTEST) TAKE IOB FROM DCB OFF RESTORE CHAIN */        61600000
*/*FSTIOB:   D (YES,,NO,SETPTR) 1ST IOB ON RES CHAIN THE ONLY ONE */    61700000
*/*          P (,CLOSE) SET INTERNAL FLG IN SVRB INDICATING NO I/O      61800000
*/*RESTORABLE */                                                        61900000
*/*SETPTR:   P REMOVE FIRST IOB FROM RESTORE CHAIN */                   62000000
*/*BITTEST:  D (NO,,YES,PREPCLOS) ONLY ONE IOB/DCB */                   62100000
*/*          P NEXT IOB = CURRENT IOB ADDR + INDEX */                   62200000
*/*          D (YES,,NO,PREPCLOS) ANY MORE IOBS */                      62300000
*/*          D (NO,,YES,PREPCLOS) IOB POINT TO ITSELF */                62400000
*/*          D (NO,,YES,ADD) AM = BSAM, BPAM OR QSAM */                 62500000
*/*          D (YES,,NO,DAMTEST) AM = GAM */                            62600000
*/*          D (NO,CLOSE,YES,IOBPROC) IOB IN USE */                     62700000
*/*DAMTEST:  D (YES,,NO,IOBPROC) AM = BDAM */                           62800000
*/*          D (NO,CLOSE,YES,IOBPROC) IOB IN USE */                     62900000
*/*PREPCLOS: P (,CLOSE) TURN OFF FLG IN TCBNSTAE INDICATING ONE IOB/DCB 63000000
*/* */                                                                  63100000
*/*WTOPURGE: S IEECVPRG: WTOR PURGE */                                  63200000
*/*          D (NO,,YES,%LOADF) SCB INDICATE ISAM OR TAM */             63300000
*/*          R ASIR3 */                                                 63400000
*/*%LOADF:   R ASIR4 */                                                 63500000
*/*IEAQTM0U: END */                                                     63600021
         END   IGC0U01C                                                 63700000
