         TITLE 'IEAQTM0V/IGC0V01C - ABEND/STAE INTERFACE RTN, LOAD 5'   00100021
IGC0V01C CSECT                                                          00200021
*199000,205000-211000,269000-348000                               19472 00300021
*                                                                       00400021
*        THIS MODULE IS RENAMED FOR RELEASE 21 TO IEAQTM0V.             00500021
*        IT WAS PREVIOUSLY NAMED IEAQTM0F.                              00600021
*                                                                       00700021
* ABEND/STAE INTERFACE ROUTINE - LOAD 4                                 00800021
*        LIBRARY NAME - IEAQTM0V                                        00900021
*        MODULE NAME  - IGC0V01C                                        01000021
*                                                                       01100021
* FUNCTION -                                                            01200021
*                                                                       01300021
*        TO SCAN THE RB CHAIN OF THE TASK TO DTERMINE IF ANY RB'S       01400021
*        EXIST BETWEEN THE RB ASSOCIATED WITH THE CURRENT STAE AND      01500021
*        THE RB ASSOCIATED WITH THE ABEND. IF THERE ARE INTERVENING     01600021
*        RB'S, THE PGM'S RELATED TO THESE RB'S ARE EXAMINED TO          01700021
*        DETERMINE IF ANY OPEN DATA SETS EXIST. FOR EACH OPEN DATA      01800021
*        SET FOUND (VIA DEB CHAIN) THE IOB RESTORE CHAIN ESTABLISHED    01900021
*        BY THE PURGE ROUTINE IN LOAD 1 IS SCANNED, AND ANY IOB'S       02000021
*        RELATED TO THE DATA SET ABOUT TO BE CLOSED IS DEQUEUED         02100021
*        FROM THE CHAIN. SUBSEQUENTLY THE DATA SETS ARE CLOSED.         02200021
*        CONTROL IS THEN PASSED TO THE NEXT LOAD.                       02300021
*                                                                       02400021
* APPLICABILITY -                                                       02500021
*                                                                       02600021
*        OPTION 4 SYSTEMS ONLY - MVT                                    02700021
*                                                                       02800021
* ATTRIBUTES -                                                          02900021
*                                                                       03000021
*        REENTRANT, REFRESHABLE, DISABLED, PRIVILEGED, NON-RESIDENT,    03100021
*        TYPE IV SVC ROUTINE.                                           03200021
*                                                                       03300021
* ENTRY POINT -                                                         03400021
*                                                                       03500021
*        IGC0V01C                                                       03600021
*                                                                       03700021
*        CONTROL IS PASSED TO THIS ROUTINE FROM LOAD 2 AFTER IT HAS     03800021
*        BEEN DETERMINED THAT ONE OR MORE DCB'S ARE OPEN WHICH          03900021
*        REPRESENT I/O WITH ISAM, BTAM OR QTAM FOR A LINE GROUP         04000021
*        AS THE ACCESS METHOD BEING USED.                               04100021
*                                                                       04200021
* EXITS - NORMAL                                                        04300021
*                                                                       04400021
*        TO LOAD4 VIA XCTL TO CONTINUE STAE PROCESSING                  04500021
*                                                                       04600021
*       - ABNORMAL                                                      04700021
*                                                                       04800021
*        TO ABEND1 VIA EXIT IF DURING THE PGM SEARCH FUNCTION A CDE     04900021
*        COULD NOT BE IDENTIFIED TO REPRESENT A PGM ON THE RB CHAIN.    05000021
*                                                                       05100021
* INPUT -                                                               05200021
*                                                                       05300021
*        REGISTERS UPON ENTRY                                           05400021
*                                                                       05500021
*        REG 3 - CVT ADDR                                               05600021
*        REG 4 - ACTIVE TCB ADDR                                        05700021
*        REG 6 - CURRENT SCB ADDR                                       05800021
*        REG 7 - IOB RESTORE CHAIN ADDR                                 05900021
*        REG 8 - WORKAREA ADDR                                          06000021
*        REG 10 - ADDR OF RETRY RTN                                     06100021
*        REG 11 - NAME OF ABENDING                                      06200021
*        REG 12 -    PROGRAM                                            06300021
*        REG 13 - EP ADDR OF ABENDING PGM (IF P/P)                      06400021
* NOTE - REG 5 CONTAINS THE ADDR OF THE XCTLING RTN'S. RB WHICH IS      06500021
*        DELETED BY THE XCTL RTN. AND THERE FORE REQUIRES REINITIALIZA- 06600021
*        TION FROM THE TCB.TO REFLECT THE ADDR OF THE NEW RB CREATED    06700021
*        BY THE XCTL RTN.                                               06800021
*                                                                       06900021
* OUTPUT -                                                              07000021
*                                                                       07100021
*        REGISTERS 3,4,6,7,8,10,11,12,13 AT EXIT ARE THE SAME AS AT     07200021
*        ENTRY                                                          07300021
*                                                                       07400021
* EXTERNAL REFERENCES -                                                 07500021
*                                                                       07600021
*        1. CVT                                                         07700021
*        2. TCB                                                         07800021
*        3. RB                                                          07900021
*        4. TACT                                                        08000021
*        5. SCVT                                                        08100021
*        6. CDE                                                         08200021
*        7. BLOCK EXTENT LIST                                           08300021
*        8. SCATTER EXTENT LIST                                         08400021
*        9. DEB                                                         08500021
*       10. DCB                                                         08600021
*       11. IOB                                                         08700021
*       12. SCB                                                         08800021
*                                                                       08900021
* SVC'S USED -                                                          09000021
*                                                                       09100021
*        1. XCTL - SVC 7                                                09200021
*        2. CLOSE - SVC 20                                              09300021
*                                                                       09400021
* TABLES & WORK AREAS -                                                 09500021
*                                                                       09600021
*        SVRB ESA USED AS TEMPORARY STORAGE                             09700021
*                                                                       09800021
* NOTES -                                                               09900021
*                                                                       10000021
*        NONE                                                           10100021
         EJECT                                                          10200021
*                                                                       10300021
*                   REGISTER EQUATES                                    10400021
*                                                                       10500021
LCBSIZE  EQU   0                                                        10600021
COUNT    EQU   0                                                        10700021
ZERO     EQU   0                                                  20472 10800021
REG0     EQU   0                                                  20472 10900021
PARREG0  EQU   0                                                  M2965 11000021
REG1     EQU   1                                                  20472 11100021
LIST     EQU   1                                                        11200021
PARREG1  EQU   1                                                  M2965 11300021
WORK1    EQU   1                                                  M2965 11400021
PREVDEB  EQU   1                                                  M5731 11500021
BASE     EQU   2                                                        11600021
CVT      EQU   3                                                        11700021
NCIOB    EQU   3                                                        11800021
TCB      EQU   4                                                        11900021
RB       EQU   5                                                        12000021
SCB      EQU   6                                                        12100021
IOB      EQU   7                                                        12200021
DCB      EQU   7                                                        12300021
IRBEP    EQU   7                                                        12400021
INDEX    EQU   8                                                  M0186 12500021
WORKAREA EQU   8                                                        12600021
OCIOB    EQU   8                                                        12700021
CDEEP    EQU   8                                                        12800021
LINK     EQU   8                                                        12900021
DEB      EQU   9                                                        13000021
ENTRY    EQU   9                                                  20472 13100021
ABENDRB  EQU   10                                                       13200021
RETRY    EQU   10                                                       13300021
ADDR     EQU   11                                                       13400021
END      EQU   12                                                 20472 13500021
TACT     EQU   13                                                       13600021
CDE      EQU   13                                                       13700021
JPADDR   EQU   13                                                       13800021
LPADDR   EQU   13                                                       13900021
EP       EQU   13                                                       14000021
UPPER    EQU   14                                                       14100021
RETREG   EQU   14                                                       14200021
ESA      EQU   14                                                       14300021
UCB      EQU   14                                                       14400021
PTR      EQU   15                                                       14500021
LCB      EQU   15                                                       14600021
LOWER    EQU   15                                                       14700021
         EJECT                                                          14800021
*                                                                       14900021
*                   MISCELLANEOUS EQUATES                               15000021
*                                                                       15100021
TCBDEB   EQU   8                       DISP TO TCBDEB FIELD             15200021
TCBSTAE  EQU   160                     STAE FIELD IN TCB                15300021
RBLINK   EQU   28                      DISP TO RBLINK FIELD             15400021
RBSTAB   EQU   10                      DISP TO RBFLAG FIELD             15500021
RBCDE    EQU   13                      DISP TO RBCDE FIELD              15600021
RBOPSW   EQU   16                      DISP TO RBOPSW FIELD             15700021
DCBDSORG EQU   26                      DISP TO DCBDSORG FIELD           15800021
DCBIOBAD EQU   28                                                       15900021
DCBEIOBX EQU   36                                                       16000021
DCBMACRF EQU   42                                                       16100021
DCBWKPT1 EQU   228                                                      16200021
IOBINCAM EQU   28                                                       16300021
LCBSTATE EQU   0                                                        16400021
DEBNMEXT EQU   16                       DISP FOR VIR EQUIPMENT    M0186 16500021
DEBEXSCL EQU   28                                                 M0186 16600021
DEBNPEE  EQU   36                       DISP FOR DASD EXTENTS     M0186 16700021
NIC      EQU   X'40'                   CDE ATTRIBUTE FOR     AD  A46202 16730021
*                                      PGM BEING FETCHED     AD  A46202 16760021
RBEXSAVE EQU   X'60'                   EXTSA DISPLMT INTO RB      M2965 16800021
NEXTDEB  EQU   X'80'                   ADDR OF NEXT DEB           M5731 16900021
DEBDEB   EQU   4                       DEB PTR TO NEXT DEB        M2965 17000021
DEBAPPAD EQU   28                                                 M2965 17100021
DUBLWORD EQU   7                                                  M2965 17200021
         EJECT                                                          17300021
*                                                                       17400021
*                   FLAG MASKS                                          17500021
*                                                                       17600021
SVRBMASK EQU   X'C0'                   RB IS SURB                       17700021
SIRBMASK EQU   X'80'                   RB IS SIRB                       17800021
IRBMASK  EQU   X'40'                   RB IS IRB                        17900021
TRANSVRB EQU   X'10'                   SVRB IS FOR TRANS. RTN.          18000021
MINCDE   EQU   X'04'                   CDE IS A MINOR                   18100021
SCATFLAG EQU   X'10'                   RESIDENT PGM SCATTER LOADED      18200021
SW       EQU   X'01'                   INTERNAL SWITCH                  18300021
OFFMASK  EQU   X'EE'                   MASK TO CLEAR SCATFLAG & SW      18400021
*                                      OR QSAM                          18500021
RDWRITE  EQU   X'20'                                                    18600021
TAM      EQU   X'10'                                                    18700021
QISAMGP  EQU   X'40'                                                    18800021
ISAM     EQU   X'80'                                                    18900021
TWOFLGS  EQU   X'A0'                                                    19000021
FOXFOX   EQU   X'FF'                   COMPARING MASK FOR END OF        19100021
*                                      IOB CHAIN                        19200021
         EJECT                                                          19300021
         BALR  BASE,0                  ESTABLISH                        19400021
         USING *,BASE                      ADDRESSABILITY               19500021
         L     RB,0(TCB)               GET CURRENT RB ADDR              19600021
         LA    ESA,96(RB)              GET ADDR OF SVRB ESA             19700021
         MVI   45(ESA),C'V'            FLAG ESA WITH MODULE ID    20472 19800021
         STM   IOB,WORKAREA,0(ESA)     SAVE IOB CHAIN ADR & WORKAREA @  19900021
         STM   RETRY,EP,12(ESA)        SAVE ADDR RETRY, PGM NAME,       20000021
*                                      & PGM EP ADDR                    20100021
         LR    ABENDRB,RB               GET ABENDING PGM'S RB     M0186 20200021
         XI    12(SCB),X'40'            SET FLAG BITS TO 0        M0186 20300021
*                                        (SET ON IN LOAD 2)       M0186 20400021
RBTEST   EQU   *                                                        20500021
         CLC   RBLINK+1(3,ABENDRB),13(SCB) Q.NEXT RB THE ONE      M0186 20600021
*                                           USING STAE            M0186 20700021
         BE    SETLIST                  YES,LAST RB, BRANCH       M0186 20800021
         L     ABENDRB,RBLINK(ABENDRB)  GET NEXT RB ADDR          M0186 20900021
*                                                                       21000021
* IT HAS NOW BEEN DETERMINED THAT AT LEAST ONE RB EXISTS BETWEEN        21100021
* THE PGM THAT ISSUED STAE AND THE PGM THAT ABENDED. A SEARCH IS        21200021
* NOW MADE TO DETERMINE IF THE INTERVENING RB(S)  HAVE ANY              21300021
* OPEN DATA SET(S) AND PURGED I/O. IF SO, THE I/O WILL BE DEQUEUED      21400021
* FROM THE RESTORE CHAIN AND THE DATA SET(S) WILL BE CLOSED.            21500021
*                                                                       21600021
         L     DEB,TCBDEB(TCB)          GET DEB ADDRESS           M0186 21700021
         LTR   DEB,DEB                  AT LEAST ONE DEB?     AH  M1520 21720021
         BZ    SETLIST                  NO, TAKE BRANCH       AH  M1520 21740021
         TM    RBSTAB(ABENDRB),SVRBMASK IS RB AN SVRB             M0186 21800021
         BNZ   RBTEST                  YES, NO DCB SEARCH REQ'D.  19472 21900021
*                                                                       22000021
PRBPROC  EQU   *                                                        22100021
         L     CDE,RBCDE-1(ABENDRB)    GET CDE ADDR                     22200021
         LA    CDE,0(CDE)              CLEAR FLAG BYTE                  22300021
         LTR   CDE,CDE                  Q. CDE ADDR ZERO?         M0186 22400021
         BZ    RBTEST                  YES, EP ADDR AND LENGTH OF M4528 22500021
*                                      PGM CANNOT BE FOUND              22600021
         TM    0(CDE),NIC              MODULE BEING FETCHED  AD  A46202 22630021
         BO    RBTEST                  YES, GO TO NEXT RB    AD  A46202 22660021
TSTCDE   TM    0(CDE),MINCDE           IS CDE A MINOR ?                 22700021
         BZ    MAJOR                   NO, TAKE BRANCH                  22800021
         L     CDE,20(CDE)             GET MAJOR CDE ADDR               22900021
MAJOR    EQU   *                                                        23000021
         L     LIST,20(CDE)            GET EXTENT LIST ADDR             23100021
         LA    LIST,0(LIST)            CLEAR FLAG BYTE                  23200021
         LTR   LIST,LIST               DOES XL EXIST         AD  A46202 23230021
         BE    RBTEST                  NO, GO TO NEXT RB     AD  A46202 23260021
         CLI   7(LIST),X'01'           IS PGM SCATTER LOADED            23300021
         BH    SCATTER                 YES, TAKE BRANCH                 23400021
*                             PGM IS BLOCK LOADED                       23500021
         L     UPPER,12(LIST)          GET EP ADDR - UPPER BOUND        23600021
         L     LOWER,8(LIST)            ADD BLOCK LENGTH TO EP    M0186 23700021
         LA    LOWER,0(LOWER,UPPER)      ADDR TO GET DEB LOC      M0186 23800021
         B     GETDCB                                                   23900021
SCATTER  EQU   *                                                        24000021
         OI    TCBSTAE(TCB),SCATFLAG    INDICATE SCATTER LOAD           24100021
         LR    END,LIST                SET POINTER TO END               24200021
         A     END,0(LIST)                  OF LIST                     24300021
         LA    END,0(END)              CLEAR FLAG BYTE                  24400021
         BAL   LINK,SCATFIX            GO TO SUBRTN WHICH WILL EXTRACT  24500021
         B     GETDCB                  DATA FROM EXTENT LIST            24600021
SCATRTN  EQU   *                                                        24700021
         LA    ADDR,4(ADDR)            SET PTR TO NEXT SGMENT           24800021
         CR    ADDR,END                END OF LIST?                     24900021
         BNL   FIXUP                   YES, TAKE BRANCH                 25000021
         LA    LIST,4(LIST)            SET PTR TO NEXT LENGTH           25100021
         BAL   LINK,EXTRACT            GO TO SUBRTN TO RESET BOUND REGS 25200021
         B     GETDCB                                                   25300021
FIXUP    EQU   *                                                        25400021
         L     DEB,4(DEB)              GET NEXT DEB ADDR          M5731 25500021
FIXLIST  EQU   *                                                  M5731 25600021
         L     LIST,20(CDE)            RESTORE PTR TO TOP OF LIST       25700021
         LA    LIST,0(LIST)            CLEAR FLAG BYTE                  25800021
         LR    END,LIST                RESTORE PTR TO                   25900021
         A     END,0(LIST)                  END OF LIST                 26000021
         LA    END,0(END)              CLEAR FLAG BYTE                  26100021
         BAL   LINK,SCATFIX         GO TO SUBRTN TO FIX SCATTER PTRS    26200021
         B     DEBCHK                                             M5731 26300021
SCATFIX  EQU   *                                                        26400021
         LA    LIST,8(LIST)            ADJUST TO BYPASS  PREFIX         26500021
         LR    ADDR,LIST               USE END PTR TO                   26600021
         SR    ADDR,END                GET LENGTH OF LIST MINUS PREFIX  26700021
         LCR   ADDR,ADDR               MAKE LIST LENGTH POSITIVE        26800021
         SRL   ADDR,1                  DIVIDE BY 2 AND ADD              26900021
         AR    ADDR,LIST                    TO GET MID PTR.             27000021
EXTRACT  L     UPPER,0(ADDR)           GET SEGMENT ADDR - UPPER BOUND   27100021
         LR    LOWER,UPPER             ADD LENGTH TO GET                27200021
         A     LOWER,0(LIST)                 LOWER BOUND                27300021
         BR    LINK                    RETURN TO CALLER                 27400021
GETDCB   EQU   *                                                        27500021
         L     DCB,24(DEB)             GET DCB ADDR                     27600021
         LA    DCB,0(DCB)              CLEAR FLAG BYTE                  27700021
         CR    DCB,UPPER               IS DCB ADDR BELOW UPPER BOUND    27800021
         BL    TSTSCAT                 NO, TAKE BRANCH                  27900021
         CR    DCB,LOWER               IS DCB ADDR ABOVE LOWER BOUND    28000021
         BL    FOUND                   YES, DCB IS W/IN PGM BOUNDS      28100021
TSTSCAT  EQU   *                                                        28200021
         TM    TCBSTAE(TCB),SCATFLAG   PGM SCATTER LOADED?              28300021
         BO    SCATRTN                 YES, TAKE BRANCH                 28400021
NXTDEB   EQU   *                                                        28500021
         L     DEB,4(DEB)              GET NEXT DEB ADDR                28600021
DEBCHK   EQU   *                                                  M5731 28700021
         LA    DEB,0(DEB)              CLEAR FLAG BYTE                  28800021
         LTR   DEB,DEB                 ANOTHER DEB EXISTS?              28900021
         BNZ   GETDCB                  YES, TAKE BRANCH                 29000021
ENDDEBS  EQU   *                                                  M5731 29100021
         NI    TCBSTAE(TCB),OFFMASK    CLEAR SCATFLAG & SW              29200021
         B     RBTEST                  END OF DEB PROCESSING            29300021
*                                                                       29400021
FOUND    EQU   *                                                        29500021
         CLI   99(RB),FOXFOX           ANT I/O PURGED?                  29600021
         BE    CLOSE                   NO, TAKE BRANCH                  29700021
         NC    96(4,RB),96(RB)         ANY I/O IN PROGRESS?             29800021
         BZ    CLOSE                   NO, TAKE BRANCH                  29900021
         B     AMSEARCH                                                 30000021
*                                                                       30100021
CLOSE    EQU   *                                                        30200021
         L     DCB,24(DEB)             RESTORE DCB ADDR                 30300021
         MVC   NEXTDEB+1(3,RB),5(DEB)  SAVE ADDR OF NEXT DEB      M5731 30400021
         ST    DCB,RBEXSAVE+28(RB)     SET UP CLOSE LIST          20049 30500021
         LA    PARREG1,RBEXSAVE+28(RB)   AND POINT TO IT          20049 30600021
         MVI   0(PARREG1),128          SET OPTION BYTE            20049 30700021
         SVC   20                      ISSUE CLOSE SVC            20049 30800021
*        TEST TO SEE IF CLOSE WAS ABLE TO DEQUEUE THE DEB         M2965 30900021
         L     PREVDEB,TCBDEB(TCB)     GET ADDR OF FIRST DEB      M5731 31000021
         LTR   PREVDEB,PREVDEB         HAVE ALL DEBS              M5731 31100021
*                                      BEEN DEQUEUED              M5731 31200021
         BE    ENDDEBS                 YES-CONTINUE TO NEXT RB    M5731 31300021
         CR    PREVDEB,DEB             IS DEB FIRST ON CHAIN      M5731 31400021
         BNE   DEBSRCH                 NO-CONTINUE SCAN           M5731 31500021
         NC    5(3,DEB),5(DEB)         IS DEB ONLY ONE ON CHAIN   M5731 31600021
         BZ    ENDCHAIN                YES-GO CLEAR DEB CHAIN     M5731 31700021
         MVC   TCBDEB+1(3,TCB),NEXTDEB+1(RB) DEQUEUE CURRENT DEB  M5731 31800021
*                                      AND CHAIN NEXT DEB TO TCB  M5731 31900021
         B     FREEDEB                 GO FREE THE DEB            M5731 32000021
ENDCHAIN EQU   *                                                  M5731 32100021
         XC    TCBDEB(4,TCB),TCBDEB(TCB) ZERO-OUT PTR TO          M5731 32200021
*                                       DEB CHAIN IN TCB          M5731 32300021
         B     FREEDEB                 GO FREE THE DEB            M5731 32400021
DEBSRCH  EQU   *                                                  M5731 32500021
         LA    PREVDEB,0(PREVDEB)      CLEAR HI-ORDER BYTE        M5731 32600021
         NC    5(3,PREVDEB),5(PREVDEB) END OF DEB CHAIN           M5731 32700021
         BZ    RESTORE                 YES-DEB DEQUEUED           M5731 32800021
         C     DEB,4(PREVDEB)          IS NEXT DEB THE ONE        M5731 32900021
*                                      NOT DEQUEUED               M5731 33000021
         BE    DEQDEB                  YES-DEQUEUE IT             M5731 33100021
         L     PREVDEB,4(PREVDEB)      GET NEXT DEB               M5731 33200021
         B     DEBSRCH                 CONTINUE SCAN              M5731 33300021
DEQDEB   MVC   5(3,PREVDEB),NEXTDEB+1(RB) DEQUEUE THE DEB         M5731 33400021
FREEDEB  EQU   *                                                  M5731 33500021
         SR    PARREG0,PARREG0         INITIALIZE REGISTER        M2965 33600021
         S     DEB,CONS4               GET ADDR OF DEB LENGTH FLD M2965 33700021
         IC    PARREG0,0(DEB)          GET DEB LEN IN DOUBLEWORDS M2965 33800021
         SLL   PARREG0,3               CONVERT TO BYTES           M2965 33900021
         O     PARREG0,CONS254          SUB POOL ID=254 FOR DEB   M2965 34000021
         SH    DEB,CONS32              GET ADDRESS OF DEB APPEND  M2965 34100021
         L     WORK1,DEBAPPAD+36(DEB)  GET ADDRESS OF DEB APPEND  M4529 34200021
         LA    WORK1,0(WORK1)          CLEAR HIGH-ORDER BYTE      M2965 34300021
         CR    DEB,WORK1               Q. QTAM DEB                M2965 34400021
         BE    NOQTAM                  NO, FREE CORE AT DEB-36    M2965 34500021
         ST    DEB,RBEXSAVE+8(RB)                                 M2965 34600021
         TM    RBEXSAVE+11(RB),DUBLWORD IS APP TBL ON DBL WD BDRY M2965 34700021
         BZ    NOQTAM                  YES BRANCH- NOT QTAM DEB   M2965 34800021
         LA    DEB,20(DEB)             QTAM- FREE CORE AT DEB-16  M2965 34900021
NOQTAM   EQU   *                                                  M2965 35000021
         LR    PARREG1,DEB             LOAD ADDR OF DEB TO FREE   M2965 35100021
         FREEMAIN R,LV=(0),A=(1)       ISSUE FREEMAIN MACRO       M2965 35200021
*                                                                 M2965 35300021
RESTORE  L     DEB,NEXTDEB(RB)         ACCESS NEW DEB PTR         M5731 35400021
         TM    TCBSTAE(TCB),SCATFLAG   WAS PGM SCATTER LOADED?          35500021
         BO    FIXLIST                 YES-RETURN TO              M5731 35600021
*                                      SCATTER PROCESS            M5731 35700021
         B     DEBCHK                  CHECK FOR MORE DEBS        M5731 35800021
*                                                                       35900021
AMSEARCH EQU   *                                                        36000021
*                                                                       36100021
* BECAUSE THE CONTENTS OF DCBDSORG IS UNRELIABLE FOR EXCP DCB A   M5938 36200021
* TEST TO ISOLATE EXCP DCB IS NECESSARY.                          M5938 36300021
EXCPDCBF EQU   X'80'                   EXCP DCB ID                M5938 36400021
         TM    DCBMACRF(DCB),EXCPDCBF  Q. IS THIS EXCP DCB        M5938 36500021
         BNZ   NXTDEB                  YES. PROCESS IT            M5938 36600021
         TM    DCBDSORG(DCB),ISAM      IS A/M ISAM?                     36700021
         BO    ISAMPROC                YES, BRANCH                      36800021
         TM    DCBDSORG(DCB),TAM       IS A/M BTAM OR QTAM FOR LINE GP? 36900021
         BO    TAMPROC                 YES, BRANCH                      37000021
         TM    TCBSTAE(TCB),SCATFLAG   PGM SCATTER LOADED?              37100021
         BO    FIXUP                   YES, BRANCH                      37200021
         B     NXTDEB                                                   37300021
ISAMPROC EQU   *                                                        37400021
         TM    DCBMACRF(DCB),RDWRITE     IS READ BEING USED?            37500021
         BO    BISAM                   YES, BRANCH                      37600021
         TM    DCBMACRF+1(DCB),RDWRITE IS WRITE BEING USED?             37700021
         BO    BISAM                   YES, BRANCH                      37800021
* QISAM IS IN USE                                                       37900021
         L     IOB,DCBWKPT1(DCB)       GET DCB WORKAREA ADDR            38000021
         LA    IOB,4(IOB)              ADD 4 TO GET FIRST IOB ADDR      38100021
         TM    DCBMACRF(DCB),QISAMGP   IS 'GET' BEING USED?             38200021
         BO    QISAMSCN                YES, BRANCH, QISAM SCAN MODE     38300021
* QISAM LOAD MODE - 'PUT' IN USE                                        38400021
         BAL   RETREG,IOBPROC          LINK TO TEST IOB RESTORE CHAIN   38500021
         LA    IOB,44(IOB)             ADD 44 TO GET NEXT IOB ADDR      38600021
         BAL   RETREG,IOBPROC          LINK TO TEST IOB RESTORE CHAIN   38700021
         LA    IOB,44(IOB)             ADD 44 TO GET LAST IOB ADDR      38800021
RET2     EQU   *                                                        38900021
         LA    RETREG,CLOSE            SET RETURN ADDR                  39000021
         B     IOBPROC                 TEST IOB RESTORE CHAIN           39100021
QISAMSCN EQU   *                                                        39200021
         BAL   RETREG,IOBPROC          LINK TO TEST IOB RESTORE CHAIN   39300021
         LA    IOB,56(IOB)             ADD 56 TO GET NEXT (LAST) IOB    39400021
         B     RET2                                                     39500021
* BISAM - 'READ' AND/OR 'WRITE' IN USE                                  39600021
BISAM    EQU   *                                                        39700021
         TM    DEBEXSCL(DEB),X'04'      Q. DASD BEING USED?       M0186 39800021
         BZ    TSTUR                   NO, TEST FOR UNIT RECORD         39900021
         LA    INDEX,16                SIZE OF EXTENT FOR DASD          40000021
         SR    COUNT,COUNT              CLEAR COUNTER             M0186 40100021
         IC    COUNT,DEBNPEE(DEB)      GET NUMBER OF EXTENTS      20472 40200021
         B    CONTIN                                                    40300021
TSTUR    EQU   *                                                        40400021
         LA    INDEX,4                 SIZE OF EXTENT FOR U/R EQIP      40500021
         SR    COUNT,COUNT              CLEAR COUNTER                   40600021
         IC    COUNT,DEBNMEXT(DEB)     GET NO OF EXTENTS                40700021
CONTIN   EQU   *                                                        40800021
         LTR   COUNT,COUNT             ANY EXTENTS?                     40900021
         BZ    CLOSE                    NO, BRAMCH                      41000021
         LA    PTR,48(DEB)             SET PTR TO FIRST EXTENT (ISAM)   41100021
DOAGAIN   EQU   *                                                       41200021
         L     UCB,0(PTR)              GET UCB ADDR                     41300021
         TM    6(UCB),TWOFLGS          TEST BUSY AND POST BITS          41400021
         BO    CONTIN2                 BOTH ARE ON, GET IOB ADDR        41500021
         AR    PTR,INDEX               GET NEXT EXTENT ADDR             41600021
         BCT   COUNT,DOAGAIN           LAST EXTENT                      41700021
         B     CLOSE                   YES, BRANCH                      41800021
CONTIN2  EQU   *                                                        41900021
         L     UCB,20(UCB)             GET RQE ADDR                     42000021
         SRL   UCB,16                  REMOVE SENSE INF/                42100021
         L     IOB,4(UCB)              GET IOB ADDR                     42200021
         B     RET2                                                     42300021
TAMPROC  EQU   *                                                        42400021
         TM    DCBMACRF(DCB),RDWRITE   IS READ BEING USED               42500021
         BO    BTAMPROC                YES, BRANCH                      42600021
         TM    DCBMACRF+1(DCB),RDWRITE IS WRITE BEING USED?             42700021
         BO    BTAMPROC                YES, BRANCH                      42800021
* QTAM FOR LINE GROUP - 'GET/PUT' IN USE                                42900021
         L     LCB,32(DCB)             GET LCB ADDR                     43000021
         LA    LCB,0(LCB)              CLEAR FLAG BYTE                  43100021
         SR    LCBSIZE,LCBSIZE                                          43200021
         IC    LCBSIZE,DCBEIOBX(DCB)   GET SIZE OF LCB                  43300021
MOREIOBS EQU *                                                          43400021
         LA    IOB,48(LCB)             GET IOB ADDR                     43500021
         BAL   RETREG,IOBPROC                                           43600021
         CLI   LCBSTATE(LCB),X'00'     LAST LCB?                        43700021
         BE    CLOSE                                                    43800021
         AR    LCB,LCBSIZE             GET ADDR OF NEXT LCB             43900021
         B     MOREIOBS                                                 44000021
BTAMPROC EQU   *                                                        44100021
         SR    COUNT,COUNT                                              44200021
         IC    COUNT,DCBEIOBX(DCB)     GET SIZE OF IOB            20472 44300021
         L     IOB,DCBIOBAD(DCB)       GET BASE ADDR FOR IOB'S          44400021
         LA    IOB,0(IOB)              CLEAR FLAG BYTE                  44500021
GTNXTIOB EQU   *                                                        44600021
         AR    IOB,COUNT               GET ADDR OF IOB                  44700021
         BAL   RETREG,IOBPROC          TEST IOB CHAIN                   44800021
         TM    IOBINCAM(IOB),X'40'     LAST IOB?                        44900021
         BO    CLOSE                   YES, BRANCH                      45000021
         B     GTNXTIOB                                                 45100021
* FOLLOWING CODE IS DESIGNED TO REMOVE IOB'S FROM THE RESTORE CHAIN     45200021
* THAT ARE ASSOCIATED WITH DCB'S WHICH ARE TO BE CLOSED IN PREPERATION  45300021
* FOR THE PURGE OF THE RB QUEUE                                         45400021
*                                                                       45500021
IOBPROC  EQU   *                                                        45600021
         LA    IOB,0(IOB)              CLEAR FLAG BYTE                  45700021
         SR    OCIOB,OCIOB             CLEAR OLD IOB REG                45800021
         L     NCIOB,96(RB)            GET 1ST IOB ADDR OFF CHAIN       45900021
         LA    NCIOB,0(NCIOB)          CLEAR FLAG BYTE                  46000021
         LTR   NCIOB,NCIOB             ANY IOB'S ON RESTORE CHAIN?      46100021
         BCR   8,RETREG                NO, BRANCH                       46200021
IOBCOMP  CR    IOB,NCIOB               IOB FROM DCB = IOB OFF CHAIN?    46300021
         BE    IOBTEST                 YES TAKE BRANCH                  46400021
         LR    OCIOB,NCIOB             SAVE OLD IOB OFF CHAIN           46500021
         CLI   27(OCIOB),FOXFOX        LAST IOB ON CHAIN?               46600021
         BCR   8,RETREG                                                 46700021
         L     NCIOB,24(OCIOB)         GET NEXT IOB ADDR OFF CHAIN      46800021
         LA    NCIOB,0(NCIOB)          CLEAR FLAG BYTE                  46900021
         B     IOBCOMP                                                  47000021
IOBTEST  EQU   *                                                        47100021
         LTR   OCIOB,OCIOB             DID MATCH OCCUR W/ FIRST IOB ON  47200021
*                                      CHAIN?                           47300021
         BZ    FSTIOB                  YES, TAKE BRANCH                 47400021
         MVC   25(3,OCIOB),25(NCIOB)   SET OLD IOB TO POINT PAST IOB    47500021
*                                      MATCHING IOB FROM DCB - WHEN     47600021
*                                      DCB CLOSED,IOB IS FREED. ABOVE   47700021
*                                      REARRANGEMENT OF FWD PTRS WILL   47800021
*                                      INSURE RESTORE CHAIN WILL        47900021
*                                      CONTAIN NO GAPS.                 48000021
*                                                                       48100021
         BR    RETREG                                                   48200021
FSTIOB   EQU   *                                                        48300021
         CLI   27(NCIOB),FOXFOX        LAST IOB ON CHAIN?         M5930 48400021
         BNE   SETPTR                  NO, TAKE BRANCH                  48500021
         XC    96(4,RB),96(RB)         INDICATE NO I/O RESTORABLE       48600021
         BR    RETREG                                                   48700021
SETPTR   EQU   *                                                        48800021
         MVC   97(3,RB),25(NCIOB)      ADJUST CHAIN PTR TO POINT PAST   48900021
*                                      FIRST IOB ON RESTORE CHAIN       49000021
*                                      SINCE IT WILL BE FREED WHEN      49100021
*                                      THE DCB IS CLOSED                49200021
         BR    RETREG                                                   49300021
SETLIST  EQU   *                                                        49400021
         L     CVT,16                  RESTORE CVT POINTER        M3853 49500021
         LA    ENTRY,LOADE             GET ADDR OF LOAD 3 NAME          49600021
         LM    IOB,WORKAREA,96(RB)     RECALL IOB CHAIN & WORKAREA ADDR 49700021
         LM    RETRY,EP,108(RB)        RECALL ADDR OF RETRY RTN, PGM    49800021
*                                      NAME & EP ADDR                   49900021
         L     REG0,THISMOD            INSERT REGS 0 AND 1 IN     20472 50000021
         L     REG1,4(ENTRY)             XCTL'S TRACE TABLE ENTRY 20472 50100021
         LA    15,96(RB)               SAVE ADDR OF ESA FOR XCTL        50200021
         XCTL  EPLOC=(ENTRY),SF=(E,(15))   GO TO XCTL TO GET LOAD       50300021
         EJECT                                                          50400021
*                                                                       50500021
*                   CONSTANTS                                           50600021
*                                                                       50700021
CONS32   DC    H'32'                                              M2965 50800021
CONS4    DC    F'4'                                               M2965 50900021
CONS254  DC    X'FE000000'                                        M2965 51000021
         DS    0F                                                       51100021
THISMOD  DC    C'V01C'                 TRACE TABLE FLAG           20472 51200021
LOADE    DC    C'IGC0W01C'             NAME OF ABEND/STAE               51300021
*                                       INTERFACE ROUTINE, LOAD 3       51400021
ONEK     DC    H'1024'                                                  51500021
*                                      IOB PTR FIELD IN IOB -           51600021
*                                      BPAM, BSAM, QSAM                 51700021
         EJECT                                                          51800021
*                                                                 M2991 51900021
*        THE FOLLOWING SPACE IS RESERVED FOR MAINTENANCE USE      M2991 52000021
*                                                                 M2991 52100021
         DC    H'0'                                               M2991 52200021
         DC    H'0'                                                     52300021
         DC    H'0'                                                     52400021
         DC    H'0'                                                     52500021
         DC    H'0'                                                     52600021
         DC    H'0'                                                     52700021
         DC    H'0'                                                     52800021
         DC    H'0'                                                     52900021
         DC    H'0'                                                     53000021
         DC    H'0'                                                     53100021
         DC    H'0'                                                     53200021
         DC    H'0'                                                     53300021
         DC    H'0'                                                     53400021
         DC    H'0'                                                     53500021
         DC    H'0'                                                     53600021
         DC    H'0'                                                     53700021
         DC    H'0'                                                     53800021
         DC    H'0'                                                     53900021
         DC    H'0'                                                     54000021
         DC    H'0'                                                     54100021
         EJECT                                                          54200021
*/*IEAQTM0V: CHART */                                                   54300021
*/*IEAQTM0V: E ASIR4 */                                                 54400021
*/*IGC0V01C: P SET CURR RB & ESA REGS, & FLAG ENTRY TO THIS MOD */      54500021
*/* P SAVE IOB CHAIN, WORK AREA, RETRY ADDRESSES, & PGM NAME */         54600021
*/* P GET ABENDING RB & SET FLAG BIT TO ZERO */                         54700021
*/*RBTEST: D (NO,,YES,SETLIST) NEXT RB USING STAE */                    54800021
*/* P GET NEXT RB AND DEB */                                            54900021
*/* D (YES,,NO,SETLIST) ANY DEBS */                                     54920021
*/* D (NO,,YES,RBTEST) IS RB AN SVRB */                                 55000021
*/*PRBPROC: P GET CDE ADDRESS */                                        55100021
*/* D (NO,,YES,RBTEST) IS CDE ADDR ZERO */                              55200021
*/*          D (YES,,NO,RBTEST)  MODULE IN CORE */                      55300021
*/*          D (YES,,NO,RBTEST) MAJOR CDE HAVE EXTENT LIST */           55400021
*/* D (NO,,YES,SCATTER) IS PGM SCATTER LOADED */                        55600021
*/* P (,GETDCB) GET EP ADDR, UPPER & LOWER BOUNDS & LEN, DEB LOC */     55700021
*/*SCATTER:  P INDICATE SCATTER & GET END */                            55800021
*/* S (,GETDCB) CATFIX:EXTRACT DATA FROM EXTENT LIST */                 55900021
*/*SCATRTN: P SET POINTER TO NEXT SEGMENT */                            56000021
*/* D (NO,,YES,FIXUP) END OF LIST */                                    56100021
*/* P GET POINTER TO NEXT LENGTH */                                     56200021
*/* S (,GETDCB) EXTRACT:RESET BOUND REGS */                             56300021
*/*FIXUP: P GET NEXT DEB ADDRESS */                                     56400021
*/*FIXLIST: P RESTORE PTRS TO TOP & END OF LIST */                      56500021
*/* S (,DEBCHK) SCATFIX:FIX SCATTER POINTERS */                         56600021
*/*SCATFIX: E ENTRY */                                                  56700021
*/* P ADJUST PTR TO BYPASS PREFIX,& GET MID PTR */                      56800021
*/*EXTRACT: P GET SEGMENT UPPER & LOWER BOUNDS */                       56900021
*/* R RETURN TO CALLER */                                               57000021
*/*GETDCB: P GET DCB ADDRESS */                                         57100021
*/* D (YES,,NO,TSTSCAT) IS DCB BELOW UPPER BOUND */                     57200021
*/* D (NO,,YES,FOUND) IS DCB ABOVE LOWER BOUND */                       57300021
*/*TSTSCAT: D (NO,,YES,SCATRTN) PGM SCATTER LOADED */                   57400021
*/*NXTDEB: P GET NEXT DEB */                                            57500021
*/*DEBCHK: D (NO,,YES,GETDCB) IS THERE ANOTHER DEB */                   57600021
*/*ENDDEBS: P (,RBTEST) CLEAR SCATTER FLAGS & SWITCH */                 57700021
*/*FOUND: D (YES,,NO,CLOSE) ANY I/O PURGED */                           57800021
*/* D (NO,,YES,AMSEARCH) ANY I/O PROCESS */                             57900021
*/*CLOSE: P RESTORE DCB ADDRESS & SET CLOSE PARAMS */                   58000021
*/* S CLOSE:DCB */                                                      58100021
*/* P GET PREVIOUS DEB */                                               58200021
*/* D (NO,,YES,ENDDEBS) END OF DEBCHN */                                58300021
*/* D (YES,,NO,DEBSRCH) IS DEB FIRST */                                 58400021
*/* D (NO,,YES,ENDCHAIN) DEB THE ONLY */                                58500021
*/* P (,FREEDEB) DEQUEUE CURRENT DEB */                                 58600021
*/*ENDCHAIN: P (,FREEDEB) ZERO TCBDEB OUT */                            58700021
*/*DEBSRCH: D (NO,,YES,RESTORE) END OF DEBCHN */                        58800021
*/* D (NO,,YES,DEQDEB) IS NXTDEB THE ONE */                             58900021
*/* P (,DEBSRCH) GET NEXT DEB */                                        59000021
*/*DEQDEB: P DEQUEUE THE DEB IN QUESTION */                             59100021
*/*FREEDEB: P GET DEB ADDR, LEN, SUBPOOL,& APP */                       59200021
*/* D (YES,,NO,NOQTAM) QTAM DEB */                                      59300021
*/* P PUT DEB ADDRESS IN PARAM LIST */                                  59400021
*/* D (NO,,YES,NOQTAM) APPTBL ON DBLWD BDRY */                          59500021
*/* P ADJUST POINTER FOR QTAM DEB */                                    59600021
*/*NOQTAM: S FREEMAIN:DEB */                                            59700021
*/*RESTORE: P GET NEW DEB POINTER */                                    59800021
*/* D (NO,DEBCHK,YES,FIXLIST) PGM SCATLD */                             59900021
*/*AMSEARCH: D (NO,,YES,NXTDEB) EXCPDCB */                        M5938 60000021
*/* D (NO,,YES,ISAMPROC) IS A/M ISAM */                                 60100021
*/* D (NO,,YES,TAMPROC) BTAM OR QTAM */                                 60200021
*/* D (NO,NXTDEB,YES,FIXUP) PGM SCATLD */                               60300021
*/*ISAMPROC: D (NO,,YES,BISAM) READ BEING USED */                       60400021
*/*D (NO,,YES,BISAM) WRITE BEING USED */                                60500021
*/* P GET FIRST IOB ADDRESS */                                          60600021
*/* D (NO,,YES,QISAMSCN) GET BEING USED */                              60700021
*/* S IOBPROC:TEST IOB RESTORE CHAIN */                                 60800021
*/* P GET NEXT IOB ADDRESS */                                           60900021
*/* S IOBPROC:TEST IOB RESTORE CHAIN */                                 61000021
*/* P GET LAST IOB ADDRESS */                                           61100021
*/*RET2: P (,IOBPROC) SET RETURN ADDRESS */                             61200021
*/*QISAMSCN: S IOBPROC:TEST IOB RESTORE CHAIN */                        61300021
*/* P (,RET2) GET NEXT OR LAST IOB */                                   61400021
*/*BISAM: D (YES,,NO,TSTUR) DASD BEING USED */                          61500021
*/* P (,CONTIN) GET SIZE OF XTENT, CLEAR COUNT & GET XTNT NO */         61600021
*/*TSTUR: P GET XTENT SIZE, CLEAR COUNTER & GET NUMBER OF EXTENTS */    61700021
*/*CONTIN: D (YES,,NO,CLOSE) ANY EXTENTS */                             61800021
*/* P GET FIRST EXTENT POINTER */                                       61900021
*/*DOAGAIN: P GET UCB ADDRESS */                                        62000021
*/* D (NO,,YES,CONTIN2) BUSY AND POST */                                62100021
*/* P DECREMENT COUNT BY ONE */                                         62200021
*/* D (YES,CLOSE,NO,DOAGAIN) LAST EXTENT */                             62300021
*/*CONTIN2: P (,RET2) REMOVE SENSE INFO & GET IOB ADDRESS */            62400021
*/*TAMPROC: D (NO,,YES,BTAMPROC) READ BEING USED */                     62500021
*/* D (NO,,YES,BTAMPROC) WRITE BEING USED */                            62600021
*/* P GET LCB SIZE */                                                   62700021
*/*MOREIOBS: P GET IOB ADDRESS */                                       62800021
*/* S IOBPROC:TEST IOB RESTORE CHAIN */                                 62900021
*/* D (NO,,YES,CLOSE) LAST LCB */                                       63000021
*/* P (,MOREIOBS) GET NEXT LCB */                                       63100021
*/*BTAMPROC: P GET SIZE OF IOBS & THEIR ADDR FROM DCB */                63200021
*/*GTNXTIOB: P GET ADDRESS OF NEXT IOB */                               63300021
*/* S IOBPROC:TEST IOB CHAIN */                                         63400021
*/* D (YES,CLOSE,NO,GTNXTIOB) LAST IOB */                               63500021
*/*IOBPROC: P CLEAR OLD IOB REG & GET 1ST IOB FROM CHAIN */             63600021
*/* D (YES,,NO,%RETREG) ANY IOB ON REST CHN */                          63700021
*/*IOBCOMP: D (NO,,YES,IOBTEST) DCB & CHN IOB SAME */                   63800021
*/* P SAVE OLD IOB ADDRESS */                                           63900021
*/* D (NO,,YES,%RETREG) LAST IOB */                                     64000021
*/* P (,IOBCOMP) GET NEXT IOB FROM CHAIN */                             64100021
*/*IOBTEST: D (NO,,YES,FSTIOB) MATCH WITH 1ST IOB */                    64200021
*/* P (,%RETREG) SET OLD IOB TO POINT TO PAST IOB */                    64300021
*/*FSTIOB: D (YES,,NO,SETPTR) LAST IOB ON CHAIN */                      64400021
*/* P (,%RETREG) INDICATE NO I/O RESTORABLE */                          64500021
*/*SETPTR: P ADJUST POINTER TO PAST */                                  64600021
*/*%RETREG: R RETURN TO CALLER */                                       64700021
*/*SETLIST: P RESTORE REGS & FLAG THIS & NEXT MODS TRACES */            64800021
*/* R XCTL */                                                           64900021
*/*IEAQTM0V: END */                                                     65000021
         END   IGC0V01C                                                 65100021
