         START                                                          00300018
*********************************************************************** 00302018
*                                                                     * 00304018
*TITLE 'IEAQTM2K'                                                       00308018
*                                                                       00316018
*STATUS:CHANGE LEVEL                                                    00324018
*                                                                       00332018
*FUNCTION/OPERATION: RECIEVES ADDRESS OF JOBSTEP TCB WHICH IGFASR2K   * 00340018
*   HAD FLAGGED TO INDICATE A SOLID STORAGE FAILURE WAS FOUND IN ITS  * 00348018
*   REGION. THE AFFECTED 2K BLOCKS ARE MARKED OFFLINE IN THE FSSEMAP, * 00356018
*   WITH ANY UNAFFECTED STORAGE CHAINED TO THE SYSTEM FBQE CHAIN. THE * 00364018
*   PQE AND RELATED CONTROL BLOCKS FOR THE REGION ARE FREED. IF THERE * 00372018
*   IS A VARY COMMAND CROSSING THE REGION BOUNDARY, THE VARY STORAGE  * 00380018
*   OFFLINE SUBROUTINE IS ENTERED TO PLACE THIS STORAGE OFFLINE. A    * 00388018
*   NEW REGION IS OBTAINED IN ORDER THAT THIS TCB MAY BE ABENDED.     * 00396018
*                                                                     * 00404018
*INPUT:JOBSTP TCB WHICH WAS SCHEDULED FOR ABEND BY IGFASR20 AFTER     * 00412018
*   IT WAS FLAGGED AS AFFECTED BY IGFASR2K.                           * 00420018
*                                                                     * 00428018
*OUTPUT: FSSEMAP UPDATED WITH THE AFFECTED 2K BLOCKS OF THE REGION    * 00436018
*   MARKED AS OFFLINE. THE SYSTEM FBQE CHAIN UPDATE TO CONTAIN ALL    * 00444018
*   OF THE UNAFFECTED STORAGE OF THE CORRESPONDING REGION.            * 00452018
*                                                                     * 00460018
*ENTRY POINT: IGCOKO1C                                                * 00468018
*                                                                     * 00476018
*EXTERNAL ROUTINES: VARY STORAGE OFFLINE SUBROUTINE, GETMAIN, FREEPART* 00484018
*                                                                     * 00492018
*EXITS-NORMAL-GOES TO EXIT(SVC 3)WITH THE MOTHER TCB OF THE JOBSTEP   * 00500018
*   POINTING TO THE NEW REGION SO THAT TERMINATION CAN BE FINISHED.   * 00508018
*                                                                     * 00516018
*                                                                     * 00524018
*     -ERROR-IF GETMAIN IS UNABLE TO ALLOCATE A NEW REGION FOR THE    * 00532018
*   TCB, A MESSAGE IS ISSUED STATING THIS AND IT TRIES AGAIN TO       * 00540018
*   ALLOCATE. IF STILL UNSUCCESSFUL, THE TASK IS ABNORMALLY TERMINATED* 00548018
*TABLES/WORK AREAS:FSSEMAP                                            * 00556018
*                                                                     * 00564018
*ATTRIBUTES: SERIALLY REUSABLE, NON-RESIDENT                          * 00572018
*                                                                     * 00581018
*********************************************************************** 00590018
         IEAQFX  65,MCH,1,GENCODE=NO                                    00600018
         IHBABCTL                                                       00900018
         MPCVT                                                          00950018
IGC0K01C CSECT                                                          01000018
         BALR  BASE,0                   ESTABLISH BASE REG              01100018
         USING *,BASE                                                   01200018
         USING TCBSECT,TCBREG                                           01500018
         USING CVTSECT,CVTREG                                           01800018
         USING IEAMPCVT,RETURN          BASE FOR MPCVT                  01900018
         SPACE 5                                                        02100018
WKREG2   EQU   0                        WORK REGISTER                   02400018
PQEADR   EQU   1                        ADDR OF PQE UNDER CONSIDERATION 02700018
PQEREG   EQU   2                                                        03000018
FIRST0   EQU   8                                                        03300018
BASE     EQU   3                        BASE REGISTER                   03600018
LASTPQE  EQU   4                        POINTER TO LAST PQE             03900018
TCBREG   EQU   4                                                        04200018
CVTREG   EQU   5                                                        04500018
PTNBEG   EQU   8                        BEGINING ADDR OF PARTITION      04800018
WKREG    EQU   8                                                        05100018
PTNEND   EQU   9                        END ADDRESS OF PARTITION        05400018
RET      EQU   14                       RETURN REG FOR BAL              05700018
COMPREG  EQU   15                                                       06000018
PARTITN  EQU   X'01'                    PARTITION MODE MASK             07500018
PQESIZE  EQU   20                       DISPLACEMENT OF                 07800018
BORROWD  EQU   X'80'                    INDICATES SPACE IS BORROWD      08100018
PQERFLGS EQU   28                       ROLLOUT FLAGS                   08400018
FOWARD   EQU   0                                                        08700018
CURRENT  EQU   4                                                        09000018
PQEFPQE  EQU   8                        FORWARD PTR                     09600018
PQETCB   EQU   16                                                       09900018
PQEBPQE  EQU   12                       PRECEDING PQE                   10200018
RETURN   EQU   6                        RETURN REGISTER                 10300018
         SPACE 5                                                        10500018
INCRMREG EQU   0                        2K INCREMENT                    10800018
MASKSAVE EQU   2                                                        11100018
FWDPTR   EQU   5                        ADDR OF NEXT FBQE IN CHAIN      11400018
PREV     EQU   6                        ADDR OF PREV FBQE IN CHAIN      11700018
LOWLIM   EQU   8                        LOW ADDR OF STORAGE TO BE SCAND 12000018
MSKREG   EQU   11                                                       12300018
HILIM    EQU   9                        END ADDR OF STORAGE TO BE TESTD 12600018
MAPDISP  EQU   10                       POINTER IN FSSEMAP              12900018
MAPPTR   EQU   10                       POINTER TO PROPER BYTE IN FSSMP 13200018
SHIFT    EQU   10                       DISPLACEMENT WITHIN BYTE        13500018
MASKREG  EQU   11                       CORRECTLY POSITIONED MASK       13800018
MSSREG   EQU   11                       MAIN STORAGE SUPERVISOR PQE     14100018
ENTRY    EQU   12                       BASE REG FOR ADDRESSIBILITY     14400018
MAPREG   EQU   12                       ENTRY POINT OF FSSEMAP SCAN RTN 14700018
RETREG   EQU   14                       RETURN REGISTER                 15000018
PQEFFBQE EQU   0                        FWD PQE PTR DISPLACEMENT INPQE  15600018
PRFBQELM EQU   7                        PREVIOUS FBQE LIMIT             15900018
PREVSIZE EQU   1                        SIZE OF PREVIOUS FBQE           16200018
FBQESIZE EQU   8                        FBQE SIZE DISPLACEMENT          16500018
EXSAVE   EQU   32                                                       16600018
FMBRETRY EQU   28                       BRANCH ENTRY POINT TO FREEMAIN  16700018
SCVTGOV  EQU   16                       PTR TO GOVRFLB                  16800018
BCKPTR   EQU   4                        POINTER TO PREVIOUS FBQE        17100018
PQEREGN  EQU   24                       PTN BEG ADDR                    17200018
LNKFIELD EQU   28                       RB LINK FIELD                   17207018
TYPFIELD EQU   10                       STATUS BITS                     17214018
CDEPTR   EQU   12                       CDE PTR                         17221018
WAITCNT  EQU   28                       RB WAIT COUNT FIELD             17228018
TQEADR2  EQU   6                        REG FOR TQE CN FIELD            17235018
RHOLDPSW EQU   20                       RB OLD PSW                      17242018
DPQEPTR  EQU   X'98'                    DUMMY PQE PTR                   17249018
TWOMEG   EQU   256                      TWO MEGABYTE STORAGE CONSTANT   17256018
SPPTR    EQU   X'18'                    TCBMSS PTR                      17263018
NXTTQE   EQU   4                        TQE CHAIN PTR                   17270018
TQEADDR  EQU   1                        TQE REG                         17277018
TQEPTR   EQU   120                      ADDR OF TIMER QUE ELEMENT       17284018
CONST    EQU   0                                                        17291018
RSPQE    EQU   1                        SPQE PTR                        17298018
RFQE     EQU   2                         FQE PTR                        17305018
RDQE     EQU   6                         DQE PTR                        17312018
VQEPTR   EQU   X'14'                    VQE ORIGN PTR IN GOVRFLB        17319018
VQECHNPT EQU   0                        VQE CHAIN PTR                   17326018
VRYBEG   EQU   6                        REG TO CONTAIN BEG OF VARY AREA 17333018
VRYEND   EQU   7                        REG TO CONTAIN END OF VARY AREA 17340018
XVARYBEG EQU   4                        OFFSET IN VQE FOR AREA LIMITS   17347018
VQELEN   EQU   8                        OFFSET OF LENGTH IN VQE         17354018
ECBREG   EQU   11                       ADDR OF ECB TO BE POSTED        17361018
COMPREG0 EQU   10                       COMPLETION REG FOR POST         17368018
LNKREG   EQU   15                       LINK REGISTER                   17375018
VRYECB   EQU   12                       DISPLACEMENT OF ECB ADDR IN VQE 17382018
LEN3     EQU   3                                                        17385018
K4       EQU   4                                                        17388018
K5       EQU   5                                                        17391018
K8       EQU   8                                                        17394018
SHARED   EQU   X'80'                    MASK TO TEST SPQE               17397018
         EJECT                                                          17400018
*                                                                       18000018
*        REMOVE THE STORAGE IN THE PARTITION FROM THE KNOWLEDGE OF THE  18300018
*        SYSTEM BY RESETTING THE FBQE POINTERS IN THE PARTITION'S PQE.  18600018
*                                                                       18900018
*                                                                       19200018
         L     CVTREG,CVTPTR            GET CVT POINTER                 19500018
         L     TCBREG,CVTTCBP           GET NEW/OLD POINTER             19800018
         L     TCBREG,CURRENT(TCBREG)   GET CURRENT(OLD) TCB ADDRESS    20100018
         L     PQEREG,TCBPQE            GET ADDR OF DUMMY PQE           20400018
         L     PQEREG,FIRST0(PQEREG)    GET ADDR OF FIRST PQE           20700018
TSTNXT   TM    PQERFLGS(PQEREG),BORROWD SEE IF SPACE IS BORROWED        21000018
         BO    TSTBORWD                 SEE IF PQE IS FROM UNASSN. STOR 21300018
FREESPAC ST    PQEREG,FOWARD(PQEREG)    RESET FORWARD FBQE POINTER      21600018
         ST    PQEREG,BCKPTR(PQEREG)    RESET BACKWARD FBQE PTR         21900018
         L     PTNEND,PQESIZE(PQEREG)   GET SIZE OF REGION              22100018
         L     PTNBEG,PQEREGN(PQEREG)   GET PTN BEGN ADDR               22300018
         AR    PTNEND,PTNBEG            CALCULATE PARTITION END ADDR    22500018
         BAL   RETURN,IFSSEF01          BRANCH TO RECONFIG RGN RTN      22800018
         L     PTNBEG,PQEREGN(PQEREG)   GET PTN BEGN ADDR               22820018
         L     PTNEND,PQESIZE(PQEREG)   GET SIZE OF REGION              22840018
         AR    PTNEND,PTNBEG            CALCULATE PARTITION END ADDR    22860018
         LA    RETURN,TESTVQE           GO TEST FOR VARY CROSSUNG RGN   22960018
         B     FREEPQE                                                  23100018
*                                                                       23400018
TSTBORWD EQU   *                                                        23700018
         L     WKREG,PQETCB(PQEREG)     GET PTR TO OWNIN TCB            24000018
         LTR   WKREG,WKREG              IS THERE AN OWNING TCB          24300018
         BZ    FREESPAC                 NO,FREE SPACE DESCRIBED BY PQE  24600018
NXTPQE   L     PQEREG,PQEFPQE(PQEREG)   GET PTR TO NEXT PQE             24900018
         LTR   PQEREG,PQEREG            ANY MORE PQES                   25200018
         BNZ   TSTNXT                   YES,BRANCH                      25500018
         L     MSSREG,TCBMSS            GET SPQE PTR FOR THIS TCB       25510018
SPLOOP   LA    MSSREG,CONST(MSSREG)     HOUSEKEEP ADDR                  25520018
         LTR   MSSREG,MSSREG            ANY SPQE'S PRESENT              25530018
         BZ    FINISH                   NO, CONTINUE CLEAN UP           25540018
         TM    CONST(MSSREG),SHARED     IS SUBPOOL SHARED               25550018
         BO    UPDATE                   YES, GO GET NEXT SPQE           25560018
         LR    WKREG,MSSREG             SAVE ADDR AS CALLER             25570018
SPCHK    L     REG1,K4(WKREG)           GET DQE PTR                     25580018
         LA    REG1,CONST(REG1)         HOUSEKEEP ADDR                  25590018
         LTR   REG1,REG1                DQE PRESENT                     25600018
         BNZ   FREEDQE                  YES, GO FREE IT                 25610018
UPDATE   L     MSSREG,CONST(MSSREG)     GET NEXT SPQE                   25620018
         B     SPLOOP                   GO TEST IT                      25630018
FREEDQE  L     WKREG2,FMDQECON          LENGTH OF 10                    25640018
         MVC   K5(LEN3,WKREG),K5(REG1)  RECHAIN DQE'S                   25650018
         BAL   RETURN,DQENTRY           GO FREE DQE IN SQA              25660018
         B     SPCHK                                                    25670018
FINISH   EQU   *                                                        25680018
         L     PQEREG,TCBPQE            GET ADDR OF ORIG DUMMY PQE      25700018
         L     PQEREG,FIRST0(PQEREG)    GET BORROWED PQE                25900018
         TM    CPUSTAT,PARTITN          TEST FOR PARTITION MODE         26100018
         BO    GETPART                  YES,BYPASS UPDAT OTHER CPU MAP  26300018
         L     WKREG,PREFIX2            GET ADDR OF OTHER CPU PSA       26500018
         MVC   FSSEMAP-IPLPSW(TWOMEG,WKREG),FSSEMAP UPDATE OTHER MAP    26700018
         SPACE 5                                                        27300018
*                                                                       27600018
*        ISSUE  GETPART FOR NEW REGION                                  27900018
*                                                                       28200018
*                                                                       28500018
GETPART  EQU   *                                                        28800018
         GETMAIN  EC,LV=53248,A=0,SP=247                                28840018
         LTR   COMPREG,COMPREG          DID GETPART GO                  28880018
         BZ    EXIT                     YES,ISSUE EXIT                  28920018
         WTO   'IEA007I NO CORE AVAILABLE FOR REGN',ROUTCDE=(2),       X28940019
               DESC=(4)                                                 28960019
         GETMAIN  R,LV=53248,SP=247                                     29000018
EXIT     EQU   *                                                        29040018
         LTR   PQEREG,PQEREG            ANY BORROWED PQES               29045018
         BZ    NOBORWD                  NO,BRANCH                       29050018
         L     WKREG,TCBPQE             GET NEW DUMMY PQE               29055018
*      CHAIN BORROWED PQES ONTO PQE CHAIN FOR NEW REGION                29055618
         L     MSSREG,FIRST0(WKREG)     GET PQE FOR REGION              29056218
         ST    PQEREG,PQEFPQE(MSSREG)   MAKE RGN PQE PT TO BORROWED     29056818
         ST    MSSREG,PQEBPQE(PQEREG)   MAKE BOROWD PT BACK TO RGN PQE  29057418
GETLAST  L     MSSREG,PQEFPQE(PQEREG)   GET NEXT PQE ON CHAIN           29058018
         LTR   MSSREG,MSSREG            ANY MORE PRESENT                29058618
         BZ    SHOWLAST                 NO, GO CHAIN ON TO DUMMY        29059218
         LR    PQEREG,MSSREG            YES, UPDATE TO NEXT             29059818
         B     GETLAST                  GO CHECK FOR LAST               29060418
SHOWLAST ST    PQEREG,PQEBPQE(WKREG)    UPDATE DUMMY LAST POINTER       29061018
*  MAKE FBQE FOR BORROWED REGION DESCRIBE TOTAL REGION SO REGION IS     29061618
*  FREE AND ROLLIN CAN BE INVOKED. TO DO THIS, MUST MAKE SURE BORROWED  29062218
*  REGION HAS NO SOLID FAILURES.                                        29062818
         L     PQEREG,FIRST0(WKREG)     GET OWNING PQE                  29063418
         L     PQEREG,FIRST0(PQEREG)    GET BORROWED PQE                29064018
CKSOLID  L    LOWLIM,PQEREGN(PQEREG)    GET BEGINING OF REGION          29064618
         L     HILIM,PQESIZE(PQEREG)    GET REGION SIZE                 29065218
         AR    HILIM,LOWLIM             COMPUTE REGION END              29065818
         LA    ENTRY,IFSSEM00           GET ENTRY OF FSSEMAP CHK RTN    29066418
NXT2K    BALR  RETREG,ENTRY             GO SEE IF SOLID FAILRE IN REGN  29067018
         B     BLDFBQE                  RGN IS OK                       29067618
         EX    MSKREG,TMMAPA            IS 2K BLOCK MARKED SOLID        29068218
         BZ    NXT2K                    NO, GO GET NEXT 2K BLOCK        29068818
MOREPQES L     PQEREG,FIRST0(PQEREG)    GET NEXT BORROWED PQE           29069418
         LTR   PQEREG,PQEREG            IS ANOTHER PRESENT              29070018
         BNZ   CKSOLID                  YES, GO CHECK IT                29070618
         B     NOBORWD                  NO, DONE WITH PQES              29071218
BLDFBQE  L     PTNBEG,PQEREGN(PQEREG)   GET BEG OF BORROWED REGION      29071818
         ST    PQEREG,CONST(PTNBEG)     MAKE FORWARD POINT TO PQE       29072418
         ST    PQEREG,K4(PTNBEG)        MAKE BACKWARD POINT TO PQE      29073018
         MVC   K8(K4,PTNBEG),PQESIZE(PQEREG) MAKE FBQE SIZE OR REGION   29073618
         B     MOREPQES                                                 29074218
NOBORWD  EQU   *                                                        29075018
         L     WKREG,TCBOTC             GET MOTHER OF CURRENT TASK      29080018
         MVC   DPQEPTR(4,WKREG),TCBPQE  MOVE IN NEW DUMMY PQE PTR       29120018
         OI    19(WKREG),X'F4'          SET F4 IN USER FIELD OF MOTHER  29160018
KILLTQE  XC    TQEPTR(4,WKREG),TQEPTR(WKREG)  ZERO TQE PTR IN TCB       29200018
******* FREEMAIN TQE ******                                             29240018
CONTINUE EQU   *                                                        29280018
         L     MSSREG,FOWARD(TCBREG)    GET CURRENT RB                  29320018
         L     MSSREG,LNKFIELD(MSSREG)  GET ADDR OF NEXT RB ON QUE      29360018
         NI    TYPFIELD(MSSREG),X'3F'   ALTER RBTYPE TO PRB             29400018
         SR    WKREG2,WKREG2            CLEAR REG                       29440018
         ST    WKREG2,CDEPTR(MSSREG)    ZERO CDE PTR                    29480018
         STC   WKREG2,WAITCNT(MSSREG)   ZERO WAIT COUNT                 29520018
         LA    WKREG2,CVTEXIT           LOAD ADDR OF SVC EXIT           29560018
         ST    WKREG2,RHOLDPSW(MSSREG)  STORE ADDR OF EXIT IN OPSW      29600018
         L     COMPREG,TCBCMP           LOAD REGISTER 15                29700018
         SVC   3                        EXIT                            30000018
         SPACE 5                                                        30300018
*        DEQ THE PQE AND FREE UP THE SPACE OCCUPIED BY IT               30600018
*                                                                       30900018
FREEPQE  EQU   *                                                        31200018
         L     WKREG,PQEBPQE(PQEREG)    GET PRECEDING PQE               31500018
         LTR   WKREG,WKREG              WAS THERE A PRECEDING PQE       31800018
         BZ    FIXDUMY                  NO,BRANCH                       32100018
         MVC   PQEFPQE(4,WKREG),PQEFPQE(PQEREG)  RECHAIN FWD POINTERS   32400018
TSTBAKPT EQU   *                                                        32700018
         L     WKREG,PQEFPQE(PQEREG)    GET NEXT PQE                    33000018
         LTR   WKREG,WKREG              IS THERE ANOTHER PQE            33300018
         BZ    FIXDUMY2                 NO,BRANCH                       33600018
         MVC   PQEBPQE(4,WKREG),PQEBPQE(PQEREG)  RECHAIN BACKWARD PTRS  33900018
FREEMAIN EQU   *                                                        34200018
         LR    PQEADR,PQEREG            GET ADDR OF PQE TO BE FREED     34500018
         L     WKREG2,FMPQECON          INIT REG0 FOR REGMAIN           34800018
DQENTRY  EQU   *                                                        34900018
         L     COMPREG,CVTABEND         GET PTR TO ABEND SEC CVT        35000018
         L     COMPREG,FMBRETRY(COMPREG) GET FREEMAIN BR ENTRY          35200018
         BALR  RETREG,COMPREG           BRANCH & LINK TO FREEMAIN       35400018
         BR    RETURN                   RETURN TO CALLER                35500018
FIXDUMY  EQU   *                                                        35730018
         L     WKREG,TCBPQE             GET PTR TO DUMY PQE             35760018
         MVC   8(4,WKREG),PQEFPQE(PQEREG) ADJUST FORWARD DUMMY PQE PTR  35790018
         B     TSTBAKPT                 GO TEST BACK PTR                35820018
FIXDUMY2 EQU   *                                                        35850018
         L     WKREG,TCBPQE             GET PTR TO DUMY PQE             35880018
         MVC   12(4,WKREG),PQEBPQE(PQEREG) ADJUST DUMY BKPTR            35910018
         B     FREEMAIN                                                 35940018
TESTVQE  L     MSSREG,CVTMPCVT          GET PTR TO MPCVT                35970018
*                                                                     * 35975018
*        TEST FOR VARY OVERLAPING THE REGION.  IF SO, GO TO THE       * 35980018
*        VARY STORAGE OFFLINE SUBROUTINE TO COMPLETE THE VARY         * 35985018
*        OPERATION.                                                   * 35990018
*                                                                     * 35995018
         SPACE 5                                                        36000018
         L     MSSREG,16(MSSREG)        GET PTR TO GOVRFLB              36040018
         LA    MSSREG,VQEPTR(MSSREG)    GET PTR TO FIRST VQE            36080018
NXTVQE   EQU   *                                                        36120018
         L     MSSREG,VQECHNPT(MSSREG)  GET PTR TO VQE                  36160018
         LA    MSSREG,VQECHNPT(MSSREG)  CLEAR HIGH ORDER BYTE           36200018
         LTR   MSSREG,MSSREG            ANY VQES                        36240018
         BZ    NXTPQE                   NO, GO GET AND TEST NEXT PQE    36400018
         LM    VRYBEG,VRYEND,XVARYBEG(MSSREG) GET BEGN ADDR OF VQE      36700018
         AR    VRYEND,VRYBEG            CALCULATE END OF VQE AREA       36800018
RGNCOMPR EQU   *                                                        36920018
         CR    PTNBEG,VRYBEG            TEST IF ELM CROSSES LOW BOUND   36940018
         BNL   CMPR01                   YES,USE AREA BOUND AS LOW LIMIT 36960018
         LR    PTNBEG,VRYBEG            NO-USE ELEM BNDRY AS LOW LIMIT  36980018
CMPR01   EQU   *                                                        37000018
         CR    VRYEND,PTNEND            TEST IF ELEM CROSSES HI BOUND   37020018
         BNL   CMPR02                   YES,USE AREA BOUND AS HIGH      37040018
         LR    PTNEND,VRYEND            NO,USE ELEM BNDRY AS HIGH       37060018
CMPR02   EQU   *                                                        37080018
         CR    PTNBEG,PTNEND            COND CODE SHOWS IF HAVE AREA    37100018
         BNL   NXTVQE                   NO,GET NEXT VQE                 37220018
REG1     EQU   1                                                        37240018
         L     REG1,TCBRBP              GET ADDR OF RB                  37260018
         STM   BASE,LNKREG,EXSAVE(REG1) SAVE REGISTERS                  37280018
         LR    CONST,REG1               SAVE RB ADDR                    37300018
         L     RETURN,CVTMPCVT          SET UP TO  GAIN ACCESS TO VRY   37320018
         L     RETURN,CVTVRYOF          GET ADDR OF VARY RTN            37340018
         BALR  REG1,RETURN              GO TO VARY RTN                  37360018
         LR    REG1,CONST               RESTORE RB ADDR                 37380018
         LM    BASE,LNKREG,EXSAVE(REG1) RESTORE REGS PREVIOUSLY SAVED   37400018
         B     NXTPQE                   GO GET NEXT PQE TO TEST         37420018
*                                                                     * 37430018
*                                                                     * 37440018
*        THIS ROUTINE USES THE STORAGE STATUS INDICATORS IN FSSEMAP   * 37450018
*        (OVER THE ADDRESS RANGE SPECIFIED IN REG 8-9) TO ADD ONTO    * 37460018
*        THE EXISTING DYNAMIC FREE STORAGE FBQE CHAIN THOSE 2K BLOCKS * 37470018
*        WHOSE STATUS IS NOT MARKED 'SOLID FAIL' OR 'RECONFIGRD OUT'. * 37480018
*        THE ROUTINE WILL BUILD NEW FBQES,THEREFORE THE PREVIOUS        37500018
*        FBQES IN THE GIVEN ADDRESS RANGE MUST HAVE BEEN DESTROYED.     37800018
*                                                                       38100018
*                                                                       38400018
*        INPUT- GPR8 -BEG ADDR OF STORAGE AREA TO BE RECONFIGURED       38700018
*               GPR9 -END ADDR OF STORAGE AREA TO BE RECONFIGURED       39000018
*               GPR14-RETURN ADDRESS                                    39300018
*                                                                       39600018
*                                                                       39900018
*        OUTPUT--FREE STORAGE FBQE CHAIN IS MODIFIED                    40200018
*        --FSSEMAP IS UPDATED TO ELIMINATE STORAGE FAILURE FLAGS        40500018
*              LEAVE ONLY-NORMAL-AND-RECONFIGURED-                      40800018
*                                                                       41100018
IFSSEF01 EQU   *                        BRANCH ENTRY POINT              41400018
         L     MSSREG,TCBRBP            GET CURRENT RB ADDR             41700018
         STM   PQEREG,PTNEND,EXSAVE(MSSREG)  STORE REGS IN EXTD SAVE    42000018
         LA    INCRMREG,2048            2K INCREMENT FOR STEP STORGE BK 42300018
         LA    MAPREG,IFSSEM00          GET ADDR OF FSSEMAP SCAN RTN    42600018
         L     MSSREG,CVTMPCVT          GET PTR TO MPSCVT               42900018
         L     MSSREG,16(MSSREG)        GET PTR TO GOVRFLB              43200018
         L     MSSREG,8(MSSREG)         GET DUMMY   PQE PTR             43500018
         L     MSSREG,8(MSSREG)         GET PTR TO PQE                  43800018
*        SEARCH MSS DYNAMIC FREE STORAGE FBQE CHAIN TO FIND PLACE INTO  44100018
*        WHICH THE NEWLY CREATED FBQES WILL BE INSERTED.                44400018
*                                                                       44700018
*                                                                       45000018
         LR    FWDPTR,MSSREG            GET BEGINNING OF CHAIN          45300018
IFSBLOOP EQU   *                                                        45600018
         LR    PREV,FWDPTR              SAVE ADDR OF PREVIOUS FBQE      45900018
         L     FWDPTR,PQEFFBQE(FWDPTR)  GET NEXT FBQE IN CHAIN          46200018
         CR    FWDPTR,MSSREG            TEST IF AT END OF FBQE CHAIN    46500018
         BE    IFSPFIND                 YES- INSERT FBQE AT END         46800018
         CR    FWDPTR,LOWLIM            TEST IF FBQE IS BEYOND PARTITN  47100018
         BL    IFSBLOOP                 NO-GET NEXT FBQE                47400018
IFSPFIND SR    PRFBQELM,PRFBQELM        ZERO PREV HI LIMIT              47700018
         CR    PREV,MSSREG              TEST IF THERE WAS A PREV FBQE   48000018
         BE    IFSINSRT                 NO-BRANCH                       48300018
         L     PREVSIZE,FBQESIZE(PREV)  GET SIZE OF PREVIOUS FBQE       48600018
         LR    PRFBQELM,PREV            GET BEG ADDR OF PREV FREE BLOCK 48900018
         AR    PRFBQELM,PREVSIZE        ESTABLISH LIMIT OF PREV FBQE    49200018
*                                                                       49500018
*        TEST- STORAGE STATUS FOR EACH 2K STORAGE BLOCK WITHIN THE RANG 49800018
*        OF THE PARTITION. IF STATUS IS 'SOLID FAIL' CHANGE THE STATUS  50100018
*        TO 'RECONFIGURED OUT' AND DO NOT BUILD A FBQE FOR THAT BLOCK.  50400018
*                                                                       50700018
*                                                                       51000018
IFSINSRT EQU   *                                                        51300018
         BALR  RETREG,MAPREG            BRANCH TO FSSEMAP SCAN RTN      51600018
         B     IFSFLINK                 EXIT WHEN HAVE REACHED LIMIT    51900018
         LR    MASKSAVE,MSKREG          SAVE MASK RETURNED FROM SCAN    52200018
         ALR   MASKSAVE,MSKREG          DOUBLE MASK TO SET LEFT BIT     52500018
         ALR   MASKSAVE,MSKREG          TRIPLE MASK TO SET RGHT BIT     52800018
         EX    MSKREG,TMMAPA            TEST IF STORAGE BLOCK MKD AVAIL 53100018
         BZ    IFSBUILD                 YES-GO BUILD NEW FBQE           53400018
         EX    MASKSAVE,ORMAPA          MARK BLOCK'RECONFIGD OUT' IN MP 53700018
         BR    MAPREG                   GO INSPECT NEXT 2K              54000018
*                                                                       54300018
*        IF STORAGE STATUS FOR A 2K BLOCK WITHIN THE PARTITION IS       54600018
*        -NOT SOLID- RELEASE THE BLOCK TO THE SYSTEM BK BUILDING A NEW  54900018
*        FBQE,AND ENQUEING IT ON THE DYNAMIC FBQE CHAIN                 55200018
*                                                                       55500018
*                                                                       55800018
IFSBUILD EQU   *                                                        56100018
         LCR   MASKSAVE,MASKSAVE        GET TWOS COMPLEMENT OF MASK     56400018
         BCTR  MASKSAVE,0               GET ONES COMPLEMENT OF MASK     56700018
         EX    MASKSAVE,NDMAPA          MARK STORAGE NORMAL IN FSSEMAP  57000018
         LA    MASKSAVE,0                                               57300018
         CR    LOWLIM,PRFBQELM          TEST IF CONTIG WITH PREV BLOCK  57900018
         BE    IFSBGROW                 YES- INCREMENT SIZE OF PRV FBQE 58200018
         ST    LOWLIM,FOWARD(PREV)      POINT PREV BLK TO NEW BLT FBQE  58500018
         STM   FWDPTR,PREV,FOWARD(LOWLIM) INSERT NEW FBQE IN FBQE CHAIN 58800018
         LR    PREV,LOWLIM              JUST BUILT FBQE BECOMES PREV    59100018
         LR    PRFBQELM,PREV            PICK BEGIN ADDR NEW PREV FRE BL 59400018
         SR    PREVSIZE,PREVSIZE        SET SIZE OF NEW PREV TO ZERO    59700018
IFSBGROW EQU   *                                                        60000018
         AR    PRFBQELM,INCRMREG        STEP PREV BLOCK RIGHT LIM BY 2K 60300018
         AR    PREVSIZE,INCRMREG        INCREMNT PREV BLOCK SIZE BY 2K  60600018
         ST    PREVSIZE,FBQESIZE(PREV)  UPDATE SIZE FIELD OF PREV FBQE  60900018
         BR    MAPREG                   GO INSPECT NEXT 2K BLOCK IN MAP 61200018
*                                                                       61500018
*        COMBINE HIGHEST NEW FREE AREA WITH ANY ADJACENT OLD FREE AREA  61800018
*                                                                       62100018
IFSFLINK EQU   *                                                        62400018
         CR    FWDPTR,PRFBQELM          TEST IF LAST NEW = NEXT ADJACNT 62700018
         BNE   IFSBLINK                 NO-POINT LAST NEW TO NEXT FBQE  63000018
         A     PREVSIZE,FBQESIZE(FWDPTR) COMPUTE COMBINED SIZE OF BLKS  63300018
         ST    PREVSIZE,FBQESIZE(PREV)  PUT SIZE IN COMBINED FBQE       63600018
         L     FWDPTR,FOWARD(FWDPTR)    GET PTR TO FBQE BEYOND COMB BLK 63900018
         ST    FWDPTR,FOWARD(PREV)      POINT COMB FBQE TO NXT BLK      64200018
IFSBLINK EQU   *                                                        64500018
         ST    PREV,BCKPTR(FWDPTR)      POINT NEXT BLK TO LAST BLT FBQE 64800018
         L     WKREG,TCBRBP             GET ADDR OF CURRENT RB          65400018
         LM    PQEREG,PTNEND,EXSAVE(WKREG) RESTORE REGS FROM EXTD SAVE  66000018
         BR    RETURN                   RETURN                          66400018
*                                                                       66900018
*        EXECUTED  INSTRUCTIONS                                         67200018
*                                                                       67500018
TMMAPA   TM    0(MAPPTR),0              TEST CPU MAP BITS WITH MASK     67800018
ORMAPA   OI    0(MAPPTR),0              INSERT MASK INTO MAP            68100018
NDMAPA   NI    0(MAPPTR),0              RESET EXECUTE MASK              68400018
*                                                                       68700018
*        INPUT -8- BEG ADDR OF STORAGE AREA FOR WHICH SCAN IS TOBE DONE 69000018
*              -9- END ADDR OF STORAGE AREA FOR WHICH SCAS IS TOBE DONE 69300018
*              -12-ADDR OF ENTRY POINT(BASE ADDR)                       69600018
*              -14-RETURN ADDR                                          69900018
*                                                                       70200018
*        OUTPUT-8- ADDR OF NEXT 2K BLOCK OF STORAGE (PREV &2K)          70500018
*              -10-ADDR OF MAP BYTE WITHIN OWN CPU-FSSEMAP-             70800018
*              -11-MASKREG WITH '01' BITS POSITIONED IN BYTE 1          71100018
*              -12-ADDR OF ENTRY POINT TO SCAN MAP FOR NXT 2K BLOCK     71400018
*                                                                       71700018
*        REGISTERS 0-7,13-15  ARE NOT CHANGED BY THIS SUBROUTINE. REGS  72000018
*        8,10-12 WILL BE MODIFIED.                                      72300018
*                                                                       72600018
*                                                                       72900018
IFSSEM00 DS    0H                                                       73200018
         SRL   HILIM,11                 TRUNCATE END ADDR TO 2K BOUNDRY 73500018
         SLL   HILIM,11                                                 73800018
         BAL   ENTRY,IFSETEST                                           74100018
*                                                                       74400018
*        SCAN LOOP- DETERMINE MAP BYTE BY TRUNCATING THE GIVEN ADDR IN  74700018
*        LOWLIM. POSITION A BIT MASK TO CORRESPOND TO THE PROPER TWO    75000018
*        BITS(DESCRIBING THE STATUS OF THE 2K BLOCK) WITHIN THE MAP     75300018
*        BYTE. INCREMENT-LOWLIM SO THAT WHEN THE LOOP IS AGAIN ENTERED, 75600018
*        THE NEXT 2K BLOCK STATUS WILL BE SCANNED.                      75900018
*                                                                       76200018
         LA    LOWLIM,2048(LOWLIM)      INCREMENT INPUT ADDR TO NXT 2K  76500018
IFSETEST CR    LOWLIM,HILIM             TEST IF HAVE EXCEEDED  STOR ARE 76800018
         BCR   10,RETREG                YES FINAL EXIT                  77100018
         LM    SHIFT,MASKREG,IFSEMCON   PICK MASKS USED TO SELECT BITS  77400018
         NR    SHIFT,LOWLIM             PICK LOW TWO BITS OF 2K BLK ADR 77700018
         SRL   SHIFT,10                 GET DISPLCMT OF 2K FRM 8K BNDRY 78000018
         SRL   MASKREG,0(SHIFT)         SHFT MASK FOR 2K POS WITHIN MAP 78300018
         LA    MAPDISP,0(LOWLIM)        CLEAR HIGH ORDER BITS OF ADDR   78600018
         SRL   MAPDISP,13               GET DISPLACMNT OF MAB BYT FOR8K 78900018
         LA    MAPDISP,FSSEMAP(MAPDISP) LOAD PROPER FSSEMAP POINTER     79200018
         B     4(RETREG)                RETURN                          79500018
*                                                                       79800018
*                                                                       80100018
IFSEMCON DC    F'6144,64'               MSK TO SEL SHFT AMT,TST BIT 1   80400018
FMPQECON DC    X'FF00001C'              FREEMAIN CONSTANT               80700018
FMDQECON DC    X'FF000010'              LENGTH TO BE FREED              80800018
TQECON   DC    X'FD000070'              TQE CONSTANT FOR FREEMAIN       80900018
         END                                                            81000018
