         TITLE 'SYSTEM/360 DECIMAL SIMULATOR'                           00070014
*********************************************************************** 00140014
*STATUS: CHANGE LEVEL 0                                                 00210014
*                                                                     * 00280014
*FUNCTION/OPERATION: THE SYSTEM/360 DECIMAL SIMULATOR IS DESIGNED TO  * 00350014
*   SIMULATE THE DECIMAL ARITHMETIC INSTRUCTIONS ON A SYSTEM/360      * 00420014
*   MODEL 91 AND MODEL 95.                                            * 00490014
*                                                                     * 00560014
*ENTRY POINT: DECENT     ENTRY BY DIRECT BRANCH,NORMALLY BY PFLIH.    * 00630014
*    DATA REQUIRED CONSISTS OF PROBLEM PROGRAM REGISTERS, OLD PSW AND * 00700014
*   DECIMAL INSTRUCTION. REGISTERS AND DECIMAL INSTRUCTION ARE PLACED * 00770014
*   BY THE ENTERING ROUTINE IN THE DECIMAL SIMULATOR COMMON WORK      * 00840014
*   AREA. THE OLD PSW IS LOCATED AT LOCATION 0028 (HEX).              * 00910014
*                                                                     * 00980014
*INPUT: N/A                                                           * 01050014
*                                                                     * 01120014
*OUTPUT: OPERAND 1 AND/OR CONDITION CODE ARE CHANGED DEPENDING UPON   * 01190014
*   THE DECIMAL INSTRUCTION BEING SIMULATED.                          * 01260014
*                                                                     * 01330014
*EXTERNAL ROUTINES: N/A                                               * 01400014
*                                                                     * 01470014
*EXITS-NORMAL: RETURN TO THE INSTRUCTION FOLLOWING THE DECIMAL        * 01540014
*   INSTRUCTION BEING SIMULATED OR, IF TESTRAN IS IN USE, RETURN IS   * 01610014
*   MADE DIRECTLY TO TESTRAN BY A LPSW.                               * 01680014
*                                                                     * 01750014
*     -ERROR: IF A DATA, ADDRESSING, DECIMAL OVERFLOW, DECIMAL DIVIDE,* 01820014
*   PROTECTION, OR SPECIFICATION EXCEPTION IS DETECTED, A RETURN IS   * 01890014
*   MADE TO PFLIH BY DIRECT BRANCH.                                   * 01960014
*                                                                     * 02030014
*TABLES/WORK AREAS: (SEE THE FOLLOWING PAGES)                         * 02100014
*                                                                     * 02170014
*ATTRIBUTES: REUSABLE AND DISABLED                                    * 02240014
*                                                                     * 02310014
*NOTES: THE MODULE IS ONLY INCLUDED IN THE NUCLEUS IF THE MODEL 91    * 02380014
*   AND DECIMAL SIMULATOR ARE REQUESTED IN THE SYSGEN INPUT.          * 02450014
*                                                                     * 02520014
*********************************************************************** 02590014
         EJECT                                                          02660014
* THE SYSTEM/360 DECIMAL SIMULATOR IS DESIGNED TO SIMULATE THE DECIMAL  02730014
* INSTRUCTIONS ON A MACHINE WITHOUT THE DECIMAL FEATURE.                02800014
         SPACE 1                                                        02870014
* THE SIMULATOR ALTHOUGH CONTAINED IN ONE CSECT HAS SEVEN MAJOR         02940014
* ROUTINES. THE SIMULATOR IS NON-REENTRANT, RUNS IN SUPERVISOR STATE,   03010014
* IS COMPLETELY DISABLED AND IS PART OF THE RESIDENT NUCLEUS.           03080014
         SPACE 2                                                        03150014
* THE MAJOR AREAS ARE -                                                 03220014
         SPACE                                                          03290014
*        SIMULATOR CONTROL                                              03360014
*        ADD/SUBTRACT/ZERO AND ADD DECIMAL                              03430014
*        MULTIPLY DECIMAL                                               03500014
*        COMPARE DECIMAL                                                03570014
*        DIVIDE DECIMAL                                                 03640014
*        ANALYZER AND END                                               03710014
*                                                                       03780014
* THE DECIMAL SIMULATOR IS ENTERED FROM THE PROGRAM FIRST LEVEL         03850014
* INTERRUPT HANDLER (PFLIH). PFLIH RECEIVES CONTROL FROM THE PROBLEM    03920014
* PROGRAM WHEN A PROGRAM INTERRUPT OCCURS. ATTEMPTED EXECUTION OF A     03990014
* DECIMAL INSTRUCTION WHEN THE DECIMAL FEATURE IS NOT INSTALLED RESULTS 04060014
* IN AN INVALID OPERATION INTERRUPT BEING GENERATED. AFTER PFLIH HAS    04130014
* DETERMINED THAT THE INTERRUPT WAS CAUSED BY A DECIMAL INSTRUCTION,    04200014
* THE PROBLEM PROGRAM REGISTERS AND THE DECIMAL INSTRUCTION ARE         04270014
* MOVED TO THE DECIMAL SIMULATOR. AN IDENTICAL PROCESS OCCURS FOR AN    04340014
* EXECUTE INSTRUCTION THAT ADDRESSES A DECIMAL INSTRUCTION. PFLIH NOW   04410014
* TURNS CONTROL OVER TO THE DECIMAL SIMULATOR.                          04480014
         EJECT                                                          04550014
* THE FOLLOWING TABLE SHOWS THE LABELS USED BY EACH MAJOR ROUTINE TO    04620014
* REFERENCE THE COMMON WORK AREA. THE COMMON WORK AREA HAS A LABEL OF   04690014
* STORAGE.                                                              04760014
         SPACE 2                                                        04830014
*...................................................................... 04900014
*BASE. NAME OF  . COMMON   . ADD/SUB/ . MULTIPLY . COMPARE  . DIVIDE  . 04970014
*ADDR. FIELD    . ROUTINES .   ZAP    . ROUTINE  . ROUTINE  . ROUTINE . 05040014
*    .          .          . ROUTINE  .          .          .         . 05110014
*...................................................................... 05180014
*000 . REGS     . REGS     .          .          .          .         . 05250014
*042 . OPCODE   . OPCODE   . OPCODE   . OPCODE   .          .         . 05320014
*043 . LENGTH   . LENGTH   .          .          .          .         . 05390014
*044 . OP1ADDR  . OP1ADDR  .          .          .          .         . 05460014
*046 . OP2ADDR  . OP2ADDR  .          .          .          .         . 05530014
*048 . OP1      . OP1      . OP1      . OP1      . OP1      . OP1     . 05600014
*058 . OP2      . OP2      . OP2      . OP2      . OP2      . OP2     . 05670014
*068 . DIVSX1   . OP1A     . SUBT     . OP1WKA2  .          . DIVSX1  . 05740014
*078 . DIVSX2   . OP1A     . MINU     . OP2WKA2  .          . DIVSX2  . 05810014
*088 . DIVSX4   .          . C16X0    . SUMS     .          . DIVSX4  . 05880014
*098 . DIVSX8   .          .          . SUMS     .          . DIVSX8  . 05950014
*0A8 . ZERO     .          .          . ZERO     .          . ZERO    . 06020014
*0B8 . DOUBWD   .          . AREA     . OP2WKA1  .          . DOUBWD  . 06090014
*0C0 . QUOT     .          . AREA     . WKAREA   .          . QUOT    . 06160014
*0D0 . SHFTCTR  .          .          .          .          . SHFTCTR . 06230014
*0D2 . LENGTH2  . LENGTH2  .          .          .          .         . 06300014
*0D4 . LENGTH1  . LENGTH1  .          .          .          .         . 06370014
*...................................................................... 06440014
         EJECT                                                          06510014
* REGISTER USAGE                                                        06580014
         SPACE                                                          06650014
* THE FOLLOWING TABLE INDICATES THE USAGE OF REGISTERS BY THE DECIMAL   06720014
* SIMULATOR. THOSE RESERVED FOR SPECIAL PURPOSES ARE, AT TIMES,         06790014
* DESTROYED WHEN THEY ARE NO LONGER NEEDED.                             06860014
         SPACE                                                          06930014
*...................................................................... 07000014
* REGISTER .  PURPOSE                                                   07070014
*...................................................................... 07140014
*   R0     .   WORK                                                     07210014
*   R1     .   WORK                                                     07280014
*   R2     .   EFFECTIVE ADDRESS FOR OPERAND 2 IN WORK AREA (OP2)       07350014
*   R3     .   EFFECTIVE ADDRESS FOR OPERAND 1 IN PROBLEM PROGRAM       07420014
*   R4     .   WORK                                                     07490014
*   R5     .   WORK                                                     07560014
*   R6     .   EFFECTIVE ADDRESS FOR OPERAND 1 IN WORK AREA (OP1)       07630014
*   R7     .   EFFECTIVE ADDRESS FOR OPERAND 2 IN PROBLEM PROGRAM       07700014
*   R8     .   WORK                                                     07770014
*   R9     .   WORK                                                     07840014
*   R10    .   LENGTH OF OPERAND 1 MINUS 1                              07910014
*   R11    .   LENGTH OF OPERAND 2 MINUS 1                              07980014
*   R12    .   BASE REGISTER                                            08050014
*   R13    .   WORK                                                     08120014
*   R14    .   WORK                                                     08190014
*   R15    .   WORK                                                     08260014
*...................................................................... 08330014
         SPACE                                                          08400014
         EJECT                                                          08470014
*        SIMULATOR CONTROL                                              08540014
         SPACE 2                                                        08610014
* THE SIMULATOR CONTROL ROUTINE HAS THE RESPONSIBILITY OF HANDLING      08680014
* THE GENERAL HOUSEKEEPING FUNCTIONS, CHECKING FUNCTIONS, AND CONTROLS  08750014
* WHICH PROCESSING ROUTINE IS USED TO HANDLE THE INSTRUCTION.           08820014
         SPACE 4                                                        08890014
*        ENTER SECTION                                                  08960014
         SPACE 1                                                        09030014
* THE ENTER ROUTINE SETS UP BASE REGISTERS, LOCATES THE SIZE OF CORE,   09100014
* DETERMINES THE EFFECTIVE ADDRESS (RIGHT AND LEFT) OF DATA REFERENCED  09170014
* BY OPERAND 1 AND OPERAND 2, AND THE LENGTH OF EACH DATA FIELD.        09240014
         SPACE 5                                                        09310014
DECENT   START 0                                                        09380014
         ENTRY REGS                                                     09450014
         EXTRN ENTRY2                                                   09520014
         BALR  R12,0          LOAD BASE REGISTER A                      09590014
         USING *,R12                                                    09660014
         SPACE 1                                                        09730014
         L     1,16           LOAD ADDR OF LOCATION FOR MAX CORE SIZE   09800014
         L     1,164(1)       LOAD SIZE OF CORE                         09870014
         SPACE 1                                                        09940014
         L     R2,OP1ADDR     LOAD OPERAND 1 PLUS MISC                  10010014
         LR    R4,R2               SAVE B1,D1                           10080014
         LR    R6,R2               MOVE B2,D2                           10150014
         SLL   R6,16               REMOVE B1,DU                         10220014
         SRL   R2,28          REMOVE B2,D2,D1                           10290014
         LTR   R3,R2          IS BASE REGISTER ZERO                     10360014
         BZ    RBG3A          BRNACH IF NO BASE REGISTER WAS USED       10430014
         SLL   R2,2      CALC DISPLACEMENT OF BASE REG IN SAVE AREA     10500014
         L     R3,REGS(R2)    LOAD BASE REG VALUE                       10570014
RBG3A    SLL   R4,4                REMOVE B1                            10640014
         SRL   R4,20                                                    10710014
         AR    R3,R4             ADD BASE PLUS DISPLACEMENT             10780014
         N     R3,MASK17      ZERO HI-ORDER 8 BITS OF R3                10850014
         LR    R8,R6               SAVE B2,D2                           10920014
         SRL   R6,28          REMOVE D2 AND UNKNOWN                     10990014
         LTR   R7,R6          IS BASE REGISTER ZERO                     11060014
         BZ    RBG3B          BRANCH IF NO BASE REGISTER WAS USED       11130014
         SLL   R6,2           MULTIPLY VALUE IN R6 BY 4                 11200014
         L     R7,REGS(R6)    LOAD BASE REG VALUE                       11270014
RBG3B    SLL   R8,4                REMOVE B2                            11340014
         SRL   R8,20          REMOVE UNKNOWN, LEAVING D2                11410014
         AR    R7,R8          DETERMINE EFFECTIVE ADDRESS OF OPERAND 2  11480014
         N     R7,MASK17      ZERO HIGH-ORDER 8 BITS                    11550014
         MVN   LENGTH2+1(1),LENGTH      MOVE LENGTH 2                   11620014
         MVO   LENGTH1(3),LENGTH(1)     MOVE LENGTH 1                   11690014
         LH    R10,LENGTH1                                              11760014
         LH    R11,LENGTH2                                              11830014
         AR    R10,R3         GET RIGHT HAND EFFECTIVE ADDRESS OF OP1   11900014
         AR    R11,R7         GET RIGHT HAND EFFECTIVE ADDRESS OF OP2   11970014
         SPACE 2                                                        12040014
*        ERROR CHECK                                                    12110014
         SPACE                                                          12180014
* THE ERROR CHECK ROUTINE PERFORMS THE ADDRESSING CHECK, DATA CHECK,    12250014
* AND PROTECTION CHECK. THE FOLLOWING CHECKS ARE PERFORMED              12320014
*        IS AN AREA OUTSIDE OF CORE ADDRESSED (ADDRESSING CHECK)        12390014
*        IF STORAGE PROTECTION IS BEING USED, IS ANY PORTION OF THE     12460014
*             FIELD PROTECTED (PROTECTION CHECK)                        12530014
*        IF THE OPERANDS OVERLAP, DO THEY OVERLAP SO THAT THE           12600014
*             RIGHT-HAND ADDRESSES ARE EQUAL (DOES NOT APPLY TO ZAP)    12670014
*             (DATA CHECK)                                              12740014
*        IS THE RIGHT-HAND CHARACTER OF EACH OPERAND A VALID SIGN       12810014
*             (DATA CHECK)                                              12880014
*        IS EACH CHARACTER OTHER THAN THE SIGN NUMERIC (DATA CHECK)     12950014
         SPACE                                                          13020014
* THE ERROR CHECK ROUTINE ALSO PERFORMS CERTAIN COMMON FUNCTIONS THAT   13090014
* ARE REQUIRED FOR THE PROPER OPERATION OF EACH OPERAND. THESE ARE-     13160014
*        MOVING THE DATA TO A COMMON WORK AREA WITHIN THE SIMULATOR     13230014
*        ESTABLISHING THE PREFERRED SIGN TO BE USED WITH THE ANSWER     13300014
         SPACE 2                                                        13370014
         CR    R10,R1         IS FIELD HIGHER THAN END OF CORE          13440014
         BNL   DECADDR        TO ADDRESS CHECK ERROR ROUTINE            13510014
         CR    R11,R1         IS FIELD HIGHER THAN END OF CORE          13580014
         BNL   DECADDR        TO ADDRESS CHECK ERROR ROUTINE            13650014
         XC    OP1(32),OP1         CLEAR WORK AREA                      13720014
         XC    DIVSX4(72),DIVSX4   CLEAR WORK AREA                      13790014
         CLI   OPCODE,X'F8'   IS OPCODE A ZAP                           13860014
         BE    RBK4           BRANCH IF ZAP                             13930014
         CR    R10,R11        DO LOW ORDER BYTES OF OPERANDS MATCH      14000014
         BE    RBK4                                                     14070014
         CLR   R3,R7          IS 1ST OPERAND ADDR LOWER THAN 2ND        14140014
         BL    FSTLOW         YES                                       14210014
         CR    R11,R3         DOES LAST BYTE OF OPERAND 2 OVERLAP       14280014
         BL    RBK4           INTO OPERAND 1.  NO EQUALS OK             14350014
         B     DECDC          DATA CHECK                                14420014
FSTLOW   CR    R10,R7         DOES LAST BYTE OF OP 1 OVERLAP OP2        14490014
         BNL   DECDC          TO DATA CHECK ROUTINE                     14560014
         EJECT                                                          14630014
* THIS PROTECTION CHECK ROUTINE CHECKS BOTH THE RIGHT-HAND ADDRESS AND  14700014
* LEFT-HAND ADDRESS OF EACH OPERAND FOR REFERENCE TO A PROTECTED AREA   14770014
* OF CORE. OPERAND 2 IS CHECKED FOR FETCH PROTECT ONLY. OPERAND 1 IS    14840014
* CHECKED FOR STORE AND FETCH PROTECTION, EXCEPT IN THE CASE OF         14910014
* COMPARE DECIMAL WHERE ONLY FETCH PROTECTION IS CHECKED. THE           14980014
* PROTECTION CHECK IS IGNORED IF THE PROTECTION KEY IN THE PROBLEM      15050014
* PROGRAM PSW IS ZERO.                                                  15120014
         SPACE                                                          15190014
RBK4     IC    R5,PSW+1       GET STORAGE PROTECT KEY FROM OLD PSW      15260014
         LA    R9,2           SET UP COUNTER                            15330014
         N     R5,MASIC       CLEAR AMWP BITS                           15400014
         BZ    NTH7                                                     15470014
         LR    R8,R10         EFFECTIVE ADDRESS OF OP1-RIGHT HAND ADDR  15540014
NTH3     N     R8,CHX800      MAKE OP1 ADDR MULTIPLE OF 2048            15610014
         CR    R8,R1               HAS PROTECTION KEY BEEN COMPARED     15680014
         BE    NTH1                BRANCH IF CHECK HAS BEEN MADE        15750014
         LR    R1,R8               SAVE ADDRESS OF PROTECTION KEY       15820014
         ISK   R4,R8          STORAGE KEY FOR OP1                       15890014
         STC   R4,STORKEY     SAVE FETCH PROTECT BIT                    15960014
         TM    STORKEY,X'08'  IS FETCH PROTECT IN EFFECT                16030014
         BO    NTH2           BRANCH IF FETCH PROTECT IS IN EFFECT      16100014
         CLI   OPCODE,X'F9'   IS INSTRUCTION DECIMAL COMPARE            16170014
         BE    NTH1           TO AVOID CHECKING OP1                     16240014
NTH2     N     R4,MASIC       CLEAR FETCH PROTECT BIT PLUS MISC         16310014
         CR    R5,R4          ARE KEYS EQUAL                            16380014
         BNE   DECPT          BRANCH TO PROTECTION CHECK ROUTINE        16450014
NTH1     LR    R8,R3          EFFECTIVE ADDRESS OF OP1- LEFT HAND ADDR  16520014
         BCT   R9,NTH3        BRANCH TO REPEAT TEST FOR OP1             16590014
         LA    R9,2           SET UP COUNTER                            16660014
         LR    R8,R11         EFFECTIVE ADDRESS OF OP2-RIGHT HAND ADDR  16730014
NTH5     N     R8,CHX800      MAKE OP2 ADDR MULTIPLE OF 2048            16800014
         CR    R8,R1               HAS PROTECTION KEY BEEN COMPARED     16870014
         BE    NTH4                BRANCH IF CHECK HAS BEEN MADE        16940014
         LR    R1,R8               SAVE ADDRESS OF PROTECTION KEY       17010014
         ISK   R4,R8          STORAGE KEY FOR OP2                       17080014
         STC   R4,STORKEY     SAVE FETCH PROTECT BIT                    17150014
         TM    STORKEY,X'08'  IS FETCH PROTECT IN EFFECT                17220014
         BZ    NTH4           BRANCH IF NOT IN EFFECT                   17290014
         N     R4,MASIC       CLEAR FETCH PROTECT BIT PLUS MISC         17360014
         CR    R5,R4          ARE KEYS EQUAL                            17430014
         BNE   DECPT          BRANCH TO PROTECTION CHECK ROUTINE        17500014
NTH4     LR    R8,R7          EFFECTIVE ADDRESS OF OP2- LEFT HAND ADDR  17570014
         BCT   R9,NTH5        BRANCH TO REPEAT TEST FOR OP2             17640014
NTH7     SR    R10,R3         TO RESTORE L1 VALUE TO REG 10             17710014
         LA    R6,OP1+15                                                17780014
         SR    R6,R10         SUBTRACT L1                               17850014
         SPACE 2                                                        17920014
* THIS ROUTINE MOVES OPERAND 1 AND OPERAND 2 (ONLY OPERAND 2 IN THE     17990014
* CASE OF ZAP) TO THE COMMON WORK AREA. IF THE INSTRUCTION IS ZAP,      18060014
* A PLUS ZERO IS ASSIGNED TO OPERAND 1. THE SIGN FIELD FOR OPERAND 1    18130014
* AND OPERAND 2 ARE THEN CHECKED FOR PROPER VALUE.                      18200014
         SPACE                                                          18270014
         CLI   OPCODE,X'F8'   IS OPCODE A ZAP                           18340014
         BNE   RBJ1                                                     18410014
         MVI   OP1+15,X'0C'        PLACE PLUS SIGN IN ZERO FIELD        18480014
         B     RBJ2                                                     18550014
RBJ1     EX    R10,MOVE1      MOVE OP1 DATA AND RIGHT JUSTIFY           18620014
RBJ2     SR    R11,R7         TO RESTORE L2 VALUE TO REG 11             18690014
         LA    R2,OP2+15                                                18760014
         SR    R2,R11         SUBTRACT L2                               18830014
         EX    R11,MOVE2A     MOVE OP2 DATA AND RIGHT JUSTIFY           18900014
         MVC   OP1A(32),OP1   MOVE OPERANDS TO WORK AREA                18970014
         MVN   S1(1),OP1+15   MOVE SIGN OF OP1 TO WORK AREA             19040014
         CLI   S1,X'09' TEST FOR VALID SIGN                             19110014
         BNH   DECDC          BRANCH IF NOT VALID                       19180014
         MVN   S2(1),OP2+15   MOVE SIGN OF OP2 TO WORK AREA             19250014
         CLI   S2,X'09' TEST FOR VALID SIGN                             19320014
         BNH   DECDC          BRANCH IF NOT VALID                       19390014
         SPACE 3                                                        19460014
* THIS ROUTINE CHECKS THE VALIDITY OF                                   19530014
* THE DIGITS OF THE OPERANDS. IT DOES                                   19600014
* THIS BY TRANSLATING VALID BYTES INTO                                  19670014
* ZEROS AND INVALID ONES INTO ONES. A                                   19740014
* VALID OPERAND WILL BE REPLACED BY ALL                                 19810014
* ZEROS.                                                                19880014
         SPACE 1                                                        19950014
         NI    OP1A+15,X'F0'  ZERO                                      20020014
         NI    OP1A+31,X'F0'               OUT SIGNS.                   20090014
         TR    OP1A(32),TABLE           TRANSLATE VALID BYTES TO ZEROS, 20160014
         CLC   OP1A(32),DIVSX4     OTHERS TO ONES, CHECK VALIDITY       20230014
         BNE   DECDC             IF NOT VALID GO TO DECDC               20300014
         SPACE 3                                                        20370014
         TM    S1,X'0F'            TEST FOR SIGN OF 1111                20440014
         BNO   VIC4                BRANCH IF NOT                        20510014
         NI    S1,X'FC'            SET SIGN TO 1100                     20580014
VIC4     NI    S1,X'FD'            SET SIGN TO 1000 OR 1001             20650014
         OI    S1,X'04'            SET SIGN TO 1100 OR 1101             20720014
         TM    S2,X'0F'            TEST FOR SIGN OF 1111                20790014
         BNO   VIC5                BRANCH IF NOT                        20860014
         NI    S2,X'FC'            SET SIGN TO 1100                     20930014
VIC5     NI    S2,X'FD'            SET SIGN TO 1000 OR 1001             21000014
         OI    S2,X'04'            SET SIGN TO 1100 OR 1101             21070014
         MVN   OP1+15(1),S1        MOVE SIGN TO DATA                    21140014
         MVN   OP2+15(1),S2        MOVE SIGN TO DATA                    21210014
         SPACE 2                                                        21280014
* THE FOLLOWING CODE DETERMINES IF THE INSTRUCTION IS MULTIPLY          21350014
* DECIMAL, DIVIDE DECIMAL OR COMPARE DECIMAL. ADD DECIMAL, SUBTRACT     21420014
* DECIMAL AND ZERO AND ADD DECIMAL ARE OTHERWISE ASSUMED TO EXIST       21490014
* IF NONE OF  THE ABOVE EXIST.                                          21560014
         SPACE 2                                                        21630014
         TM    OPCODE,X'FC'   TEST FOR MULTIPLY AND DIVIDE DECIMAL      21700014
         BC    1,DECMP        BRANCH IF EITHER                          21770014
         NI    PSW+4,X'CF'    SET CONDITION CODE TO ZERO                21840014
         CLI   OPCODE,X'F9'   TEST FOR COMPARE DECIMAL                  21910014
         BE    DECCP          BRANCH IF COMPARE DECIMAL                 21980014
*                             ENTER ADD,SUBTRACT,ZERO AND ADD DECIMAL   22050014
*                             ROUTINE                                   22120014
         EJECT                                                          22190014
*        ADD/SUBTRACT/ZERO AND ADD DECIMAL ROUTINE                      22260014
         SPACE 2                                                        22330014
* THIS ROUTINE CHECKS THE OPCODE.IF IT IS'SUBTRACT DECIMAL',THE SIGN    22400014
* OF THE 2ND OPERAND IS CHANGED.THE PROCEDURE IS THEN THE SAME FOR      22470014
* ADD DECIMAL, SUBTRACT DECIMAL AND ZERO AND ADD DECIMAL.               22540014
         SPACE 1                                                        22610014
* THE SIGN OF THE 2 OPERANDS ARE CHECKED TO DETERMINE THE OPERATION     22680014
* TO BE PERFORMED.IF THE SIGNS ARE ALIKE,THE 2 OPERANDS ARE SUMMED.     22750014
* IF THE SIGNS ARE UNLIKE,THE DIFFERENCE BETWEEN THE 2 OPERANDS IS      22820014
* FOUND  AND THE SIGN OF THE OPERAND OF GREATER ABSOLUTE VALUE IS GIVEN 22890014
* TO THE RESULT.THE CONDITION CODE IS SET ACCORDING TO THE VALUE OF THE 22960014
* RESULT.                                                               23030014
         SPACE 1                                                        23100014
* THERE ARE TWO EXITS FROM THE ADD/SUBTRACT/ZAP ROUTINE. THE NORMAL     23170014
* END IS TO LOCATION 'DECNEND' IN THE END ROUTINE. IF A DECIMAL         23240014
* OVERFLOW OCCURS, A BRANCH IS MADE TO LOCATION 'DECDO' IN THE          23310014
* ANALYZER ROUTINE.                                                     23380014
         SPACE 1                                                        23450014
DECASP   CLI   OPCODE,X'FB'   IS INSTRUCTION SUBTRACT DECIMAL           23520014
         BNE   SBF2                     IF NOT, GO TO SBF2.             23590014
         XI    S2,X'01'       REVERSE SIGN-PLUS TO MINUS/MINUS TO PLUS  23660014
         SPACE 2                                                        23730014
* THE FOLLOWING CODE HANDLES THE CONDITION OF OPERAND 1 EQUAL TO ZERO   23800014
* AND OPERAND 2 NOT EQUAL TO ZERO. THIS INCLUDES MOST ZAP INSTRUCTIONS. 23870014
* OPERAND 2 IS MOVED TO OPERAND 1. A CHECK IS MADE TO DETERMINE IF      23940014
* A CHECK FOR OVERFLOW IS NECESSARY. IF IT IS, THE CHECK IS MADE. IF    24010014
* IT IS NOT, THE CONDITION CODE IS SET APPROPRIATELY.                   24080014
         SPACE 1                                                        24150014
SBF2     NI    OP1+15,X'FE'   SET SIGN TO PLUS                          24220014
         NI    OP2+15,X'FE'                                             24290014
         MVN   SUBT+15(1),OP1+15   MOVE SIGN TO FIELD OF ZEROS          24360014
         CLC   OP1(16),SUBT   TEST OP1 FOR ZERO                         24430014
         BNE   SBJ2           BRANCH IF NOT ZERO                        24500014
         CLC   OP2(16),SUBT   TEST OP2 FOR ZERO                         24570014
         BE    MOVEEND             BRANCH IF ZERO                       24640014
         MVC   OP1(16),OP2    MOVE OP2 TO OP1                           24710014
         MVC   MS(1),S2            SAVE SIGN FOR RESULT                 24780014
         CR    R10,R11        COMPARE L1 OR L2                          24850014
         BNL   SFH3           NO OVERFLOW, GO TO SET CONDITION CODE     24920014
         B     SFG3A          TO TEST FOR OVERFLOW                      24990014
         SPACE 2                                                        25060014
*        OPERAND SIGN CHECK                                             25130014
         SPACE 1                                                        25200014
* IF OPERAND 1 IS EQUAL TO ZERO, THE SIGNS OF BOTH ARE COMPARED TO      25270014
* DETERMINE WHICH ROUTINE IS TO BE USED IN ADDING THE OPERANDS.IF       25340014
* THEIR SIGNS ARE ALIKE,THE OPERANDS ARE SUMMED.IF THE SIGNS ARE UN-    25410014
* LIKE THE DIFFERENCE BETWEEN THE TWO OPERANDS IS FOUND.                25480014
         SPACE 1                                                        25550014
SBJ2     LR    R5,R10         PLACE L1 IN REGISTER 5                    25620014
         CLR   R10,R11        IS L2 LONGER THAN L1                      25690014
         BH    SBG2           BRANCH IF OP1 IS LONGER THAN OP2          25760014
         LR    R5,R11         PLACE L2 IN REGISTER 5                    25830014
SBG2     CLC   S1,S2          TEST FOR LIKE SIGNS                       25900014
         BE    SEA3           BRANCH IF LIKE SIGNS                      25970014
         SPACE 2                                                        26040014
* ADDITION OF OPERANDS WITH UNLIKE SIGNS                                26110014
         SPACE 1                                                        26180014
* THE SIGNS OF THE OPERANDS HAVE BEEN SAVED.BOTH OPERANDS ARE MADE      26250014
* POSITIVE SO THAT THEIR ABSOLUTE VALUES CAN BE COMPARED.IF THE AB-     26320014
* SOLUTE VALUES OF THE OPERANDS ARE EQUAL,PLUS ZERO IS MOVED INTO THE   26390014
* 1ST OPERAND FIELD AND THE CONDITION CODE IS SET TO ZERO.CONTROL IS    26460014
* TRANSFERED TO THE END ROUTINE.                                        26530014
         SPACE 1                                                        26600014
         CLC   OP1(16),OP2    COMPARE OP1 TO OP2                        26670014
         BH    SCC3                     IF OP1 IS GREATER, GO TO SCC3.  26740014
         BL    SCB4                     IF OP2 IS GREATER, GO TO SCB4.  26810014
         XC    OP1(16),OP1    CLEAR OP1 TO ZERO                         26880014
         MVN   OP1+15(1),OP2+15    MOVE SIGN TO OP1                     26950014
         B     MOVEEND                                                  27020014
         SPACE 1                                                        27090014
* IF THE OPERANDS ARE UNEQUAL IN ABSOLUTE VALUE,THE OPERAND OF GREATER  27160014
* VALUE IS MADE THE MINVEND AND THE OPERAND OF LESSER VALUE IS MADE     27230014
* THE SUBTRAHEND.                                                       27300014
         SPACE 1                                                        27370014
SCB4     MVC   SUBT(32),OP1   MOVE OP1 AND OP2                          27440014
         MVC   MS(1),S2       SAVE SIGN OF OP2 FOR RESULT               27510014
         B     SCF3                                                     27580014
SCC3     MVC   MINU(16),OP1   EXCHANGE OPERANDS                         27650014
         MVC   SUBT(16),OP2                                             27720014
         SPACE 1                                                        27790014
* IF BOTH OPERAND LENGTHS ARE LESS THAN OR EQUAL TO 5 BYTES,THE OPER-   27860014
* ANDS IN THEIR ENTIRETY ARE CONVERTED TO BINARY.THE'CVB'INSTRUCTION    27930014
* PLACES THE BINARY FORM OF THE DECIMAL INSTRUCTION IN A GENERAL REG-   28000014
* ISTER.THE REGISTER CONTAINING THE SUBTRAHEND IS SUBTRACTED FROM THE   28070014
* REGISTER CONTAINING THE MINUEND.THE DIFFERENCE IS CONVERTED TO DEC-   28140014
* IMAL AND PLACED IN THE FIRST OPERAND LOCATION.                        28210014
         SPACE 1                                                        28280014
SCF3     LA    R13,4               SET UP CONSTANT                      28350014
         CR    R5,R13              IS OP LENGTH GREATER THAN 5          28420014
         BH    SCG3                     IF GREATER, GO TO SCG3.         28490014
         CVB   R8,MINU+8      CONVERT OP TO BINARY                      28560014
         CVB   R9,SUBT+8                                                28630014
         SR    R8,R9          SUBTRACT                                  28700014
         CVD   R8,OP1+8       CONVERT DIFFERENCE TO DECIMAL             28770014
         B     SFG3                     GO TO SETTING OF CONDITION CODE 28840014
         SPACE 1                                                        28910014
* BECAUSE THE BINARY FORM OF DECIMAL NUMBERS GREATER THAN 9 DIGITS CAN- 28980014
* NOT BE CONTAINED IN ONE REGISTER,IF EITHER OPERAND IS OF LENGTH GR-   29050014
* EATER THAN FIVE BYTES,THE OPERANDS ARE PROCESSED WORD BY WORD.        29120014
         SPACE 1                                                        29190014
* THE WORDS OF THE OPERANDS ARE MOVED TO A WORK AREA ONE AT A TIME AND  29260014
* CONVERTED.THE RESULT IS THE BINARY FORM OF THE 4-BYTE NUMBER IN A     29330014
* REGISTER.                                                             29400014
         SPACE 1                                                        29470014
* BEFORE SUBTRACTING A SUBTRAHEND WORD FROM ITS CORRESPONDING MINUEND   29540014
* WORD THE TWO ARE COMPARED.IF THE MINUEND IS LESS THAN THE SUBTRAHEND  29610014
* WORD A BORROW IS NECESSARY.A HIGH-ORDER 1 IS PLACED IN THE MINUEND    29680014
* WORD BY ADDING TO IT THE BINARY FORM OF 10000000 IF IT IS THE LOW-    29750014
* ORDER WORD OF THE MINUEND,OR THE BINARY FORM OF 100000000 IF IT IS    29820014
* A HIGH-ORDER WORD OF THE MINUEND.THE BORROW SWITCH IS SET ON TO IN-   29890014
* DICATE THAT 1 MUST BE SUBTRACTED FROM THE SUCCEEDING MINUEND WORD.    29960014
* THE HIGH-ORDER MINUEND WORD WILL ALWAYS BE GREATER THAN OR EQUAL TO   30030014
* ITS CORRESPONDING SUBTRAHEND WORD.                                    30100014
         SPACE 1                                                        30170014
* WHEN A SUBTRAHEND WORD IS SUBTRACTED FROM ITS CORRESPONDING MINUEND   30240014
* WORD THE DIFFERENCE IS CONVERTED TO DECIMAL IN A WORK AREA AND THEN   30310014
* PLACED IN ITS CORRECT POSITION IN THE 1ST OPERAND FIELD.              30380014
         SPACE 1                                                        30450014
* OPERAND WORDS OTHER THAN THOSE OF LOW-ORDER MUST BE SIGNED BEFORE     30520014
* BEING CONVERTED TO BINARY,AND DIFFERENCE WORDS OTHER THAN THOSE OF    30590014
* LOW-ORDER MUST BE RID OF THEIR SIGNS BEFORE BEING INSERTED IN THE     30660014
* 1ST OPERAND FIELD.                                                    30730014
         SPACE 1                                                        30800014
SCG3     LA    R4,STORAGE+12                                            30870014
         LA    R1,3                                                     30940014
         SR    0,0                                                      31010014
         MVC   AREA+4(4),MINU-STORAGE(R4) MOVE FOUR BYTES               31080014
         CVB   R8,AREA             CONVERT TO BINARY                    31150014
         MVC   AREA+4(4),SUBT-STORAGE(R4) MOVE FOUR BYTES               31220014
         CVB   R9,AREA             CONVERT TO BINARY                    31290014
         CR    R8,R9          MINUEND VS SUBTRAHEND WORD                31360014
         BNL   SDA2           BRANCH IF SUBTRAHEND IS LOW               31430014
         A     R8,BOR1        PLACE HIGH ORFER 1 IN MINUEND             31500014
         LA    R0,1           SET BORROW SWITCH                         31570014
SDA2     SR    R8,R9          SUBTRACT                                  31640014
         CVD   R8,AREA        CONVERT DIFFERENCE TO DECIMAL             31710014
SDB3     MVC   OP1-STORAGE(4,R4),AREA+4 MOVE DIFFERENCE TO OP1          31780014
         MVI   AREA+7,X'0C'                                             31850014
         AR    R1,R13              ADD 4                                31920014
         SR    R4,R13              SUBTRACT 4                           31990014
         MVO   AREA+3(5),MINU-STORAGE(4,R4) MOVE HIGH ORDER OPERAND WDS 32060014
         CVB   R8,AREA        CONVERT TO BINARY                         32130014
         MVO   AREA+3(5),SUBT-STORAGE(4,R4)                             32200014
         CVB   R9,AREA                                                  32270014
         BCT   R0,SDF3        BRANCH IF BORROW SWITCH IS NOT ON         32340014
         S     R8,CFX1        SUBTRACT 1 FROM MINUEND WORD              32410014
SDF3     CR    R8,R9          MINUEND VS SUBTRAHEND WORD                32480014
         BNL   SDG3           BRANCH IF SUBTRAHEND WORD IS LOW          32550014
         A     R8,BOR2        PLACE HIGH ORDER 1 IN MINUEND             32620014
         LA    R0,1           SET BORROW SWITCH                         32690014
SDG3     SR    R8,R9          SUBTRACT                                  32760014
         CVD   R8,AREA        CONVERT DIFFERENCE TO DECIMAL             32830014
         MVO   AREA+3(6),AREA+3(5)      RID PARTIAL DIFFERENCE OF SIGN  32900014
         CR    R1,R5          IS SUBTRACTION COMPLETE                   32970014
         BL    SDB3                     IF NOT, LOOP.                   33040014
         MVC   OP1-STORAGE(4,R4),AREA+4                                 33110014
         B     SFH3           TO TEST FOR OVERFLOW AND SET CONDIT. CODE 33180014
         SPACE 1                                                        33250014
* ADDITION OF OPERANDS WITH LIKE SIGNS.                                 33320014
         SPACE 1                                                        33390014
* IF BOTH OPERANDS ARE LESS THAN OR EQUAL TO 5 BYTES,THE OPERANDS IN    33460014
* THEIR ENTIRETY ARE CONVERTED TO BINARY.THE CVB INSTRUCTION PLACES     33530014
* THE BINARY FORM OF THE DECIMAL NUMBER IN A GENERAL REGISTER.THE REG-  33600014
* ISTERS CONTAINING THE OPERANDS ARE ADDED.THE SUM IS CONVERTED TO DEC  33670014
* IMAL AND PLACED IN THE 1ST OPERAND LOCATION WHERE IT IS CHECKED FOR   33740014
* A CARRY.                                                              33810014
         SPACE 1                                                        33880014
SEA3     LA    R13,4          SET UP CONSTANT                           33950014
         CR    R5,R13              IS OP1 LENGTH GREATER THAN 5         34020014
         BH    SEB3                     IF IT IS, GO TO SEB3.           34090014
         CVB   R8,OP1+8       CONVERT OP1 TO BINARY                     34160014
         CVB   R9,OP2+8                                                 34230014
         AR    R8,R9          ADD OP1 AND OP2                           34300014
         CVD   R8,OP1+8       CONVERT SUM TO DECIMAL                    34370014
         SR    R13,R5                                                   34440014
         EX    R13,COMP4           IS THERE A CARRY                     34510014
         BE    SFG3           IF NO CARRY                               34580014
         B     SFG2                                                     34650014
         SPACE 1                                                        34720014
* IF EITHER OPERAND IS OF LENGTH GREATER THAN 5 BYTES THE OPERANDS ARE  34790014
* PROCESSED WORD BY WORD.THE WORDS OF EACH OPERAND ARE MOVED TO A WORK  34860014
* AREA ONE AT A TIME AND CONVERTED.THE BINARY FORM OF THE 4-BYTE NUM-   34930014
* BER IS IN A REGISTER.THE REGISTERS CONTAINING THE CORRESPONDING OP-   35000014
* ERAND WORDS ARE ADDED AND THEIR SUM IS CONVERTED TO DECIMAL IN THE    35070014
* WORK AREA,WHERE IT IS EXAMINED FOR A CARRY.IF THERE IS A CARRY,THE    35140014
* CARRY SWITCH IS SET ON TO INDICATE THAT 1 MUST BE ADDED TO ONE OF     35210014
* THE SUCCEEDING OPERAND WORDS.A CARRY IN THE HIGH-ORDER SUM WORD IN-   35280014
* DICATES DECIMAL OVERFLOW.THE PARTIAL SUM IS INSERTED IN ITS CORRECT   35350014
* POSITION OF THE 1ST OPERAND FIELD.                                    35420014
         SPACE 1                                                        35490014
* OPERAND WORDS OTHER THAN THOSE OF LOW-ORDER MUST BE SIGNED BEFORE     35560014
* BEING CONVERTED TO BINARY,AND SUM WORDS OTHER THAN THOSE OF LOW-      35630014
* ORDER MUST BE RID OF THEIR SIGNS BEFORE BEING INSERTED IN THE 1ST     35700014
* OPERAND FIELD.                                                        35770014
         SPACE 1                                                        35840014
SEB3     LA    R4,STORAGE+12                                            35910014
         LA    R1,3                                                     35980014
         SR    R0,R0          CLEAR CARRY SWITCH                        36050014
         MVC   AREA+4(4),OP1-STORAGE(R4) MOVE LOW ORDER WORD OF OP1     36120014
         CVB   R8,AREA             CONVERT TO BINARY                    36190014
         MVC   AREA+4(4),OP2-STORAGE(R4) MOVE LOW ORDER WORD OF OP2     36260014
         CVB   R9,AREA             CONVERT TO BINARY                    36330014
         AR    R8,R9          ADD OP1 WORD AND OP2 WORD                 36400014
         CVD   R8,AREA        CONVERT SUM TO DECIMAL                    36470014
         CLI   AREA+3,X'00'        COMPARE FOR ZERO                     36540014
         BE    SEG3           BRANCH IF NO CARRY                        36610014
         LA    R0,1           SET CARRY SWITCH                          36680014
SEG3     MVC   OP1-STORAGE(4,R4),AREA+4 MOVE PARTIAL SUM TO OP1 FIELD   36750014
         MVI   AREA+7,X'0C'   MOVE IN SIGN                              36820014
         SR    R4,R13              SUBTRACT 4                           36890014
         AR    R1,R13              ADD 4                                36960014
         MVO   AREA+3(5),OP1-STORAGE(4,R4) MOVE HI-ORDER WORDS OF OP1   37030014
         CVB   R8,AREA             CONVERT TO BINARY                    37100014
         MVO   AREA+3(5),OP2-STORAGE(4,R4) MOVE HI-ORDER WORDS OF OP2   37170014
         CVB   R9,AREA             CONVERT TO BINARY                    37240014
         BCT   R0,SFA3        BRANCH IF CARRY SWITCH IS OFF             37310014
         A     R8,CFX1        ADD 1 TO OP1 WORD                         37380014
SFA3     AR    R8,R9          ADD OP1 TO OP2 WORD                       37450014
         CVD   R8,AREA        CONVERT SUM TO DECIMAL                    37520014
         MVO   AREA+3(6),AREA+3(5) RID PARTIAL SUM OF SIGN              37590014
         CLI   AREA+3,X'00'        COMPARE FOR ZERO                     37660014
         BE    SFD3           IF NO CARRY                               37730014
         LA    R0,1           SET CARRY SWITCH                          37800014
SFD3     CR    R1,R5          IS ADDITION COMPLETE                      37870014
         BL    SEG3           BRANCH IF NOT COMPLETE                    37940014
         MVC   OP1-STORAGE(4,R4),AREA+4 MOVE PARTIAL SUM TO OP1 FIELD   38010014
         SPACE 1                                                        38080014
* SETTING OF CONDITION CODE                                             38150014
         SPACE 1                                                        38220014
* IF THE OPERATION WAS ADDITION OF OPERANDS WITH LIKE SIGNS,THE CARRY   38290014
* SWITCH IS CHECKED TO DETERMINE WHETHER THERE WAS A CARRY IN THE HIGH  38360014
* ORDER POSITION OF THE SUM.IF SO,THE CONDITION CODE IS SET TO 3 TO     38430014
* INDICATE DECIMAL OVERFLOW.                                            38500014
         SPACE 1                                                        38570014
* IF THE LENGTH OF THE RESULT EXCEEDS THE LENGTH OF OPERAND 1,THE CON-  38640014
* DITION CODE ALSO IS SET TO 3 TO INDICATE DECIMAL OVERFLOW.            38710014
         SPACE 1                                                        38780014
* OTHERWISE THE CONDITION CODE IS SET TO 2 IF THE RESULT IS POSITIVE,   38850014
* OR SET TO 1 IF THE RESULT IS NEGATIVE.                                38920014
         SPACE 1                                                        38990014
* CONTROL IS TRANSFERED TO THE SIMULATOR END ROUTINE IF THE CONDITION   39060014
* CODE IS SET TO 1 OR 2.  IF THE CONDITION CODE IS SET TO 3, CONTROL    39130014
* IS PASSED TO THE 'ANALYZER' SECTION.                                  39200014
         SPACE 1                                                        39270014
         BCT   R0,SFH3        BRANCH IF NO CARRY                        39340014
SFG3     C     R10,CFX15                                                39410014
         BNL   SFG2           IF L1 IS 15 HEX                           39480014
SFG3A    LA    R1,14                                                    39550014
         SR    R1,R10                                                   39620014
         EX    R1,COMP3       IS SUM LENGTH GREATER THAN OP1            39690014
         BNE   SFG2                       LENGTH.                       39760014
SFH3     MVN   OP1+15(1),MS   MOVE SIGN TO OP1                          39830014
         TM    MS,X'01'       IS SIGN MINUS                             39900014
         BC    8,SFJ3         BRANCH IF PLUS                            39970014
SCC10    OI    PSW+4,X'10'    SET CONDITION CODE-LESS THAN ZERO         40040014
         B     DECNEND                                                  40110014
SFG2     MVN   OP1+15(1),MS   MOVE SIGN TO OP1                          40180014
         OI    PSW+4,X'30'    SET CONDITION CODE-OVERFLOW               40250014
         B     DECDO          OVERFLOW                                  40320014
         SPACE 2                                                        40390014
*          CONSTANTS                                                    40460014
         SPACE 1                                                        40530014
COMP3    CLC   OP1(1),C16X0                                             40600014
COMP4    CLC   OP1+10(1),C16X0                                          40670014
COMP5    CLC   0(1,R6),C16X0                                            40740014
CFX1     DC    F'1'                                                     40810014
CFX15    DC    F'15'                                                    40880014
BOR1     DC    XL4'00989680'                                            40950014
BOR2     DC    XL4'05F5E100'                                            41020014
BOR3     DC    XL4'3B9ACA00'       1 000 000 000                        41090014
         SPACE 1                                                        41160014
S1       DC    X'00'                                                    41230014
S2       DC    X'00'                                                    41300014
         EJECT                                                          41370014
* MULTIPLY DECIMAL                                                      41440014
         SPACE                                                          41510014
* THE MULTIPLY AND DIVIDE DECIMAL INSTRUCTIONS ARE HANDLED BY THE       41580014
* COMMON CHECKING ROUTINE. AT THE END OF THE CHECKING, DIVIDE DECIMAL   41650014
* INSTRUCTION IS PROCESSED BY THE DIVIDE DECIMAL ROUTINE.               41720014
         SPACE                                                          41790014
* THE TWO GIVEN OPERANDS TO BE MULTIPLIED ARE EACH BROKEN UP (IF        41860014
* NECESSARY) INTO PARTS CONTAINING A UNIFORM NUMBER OF CONTIGUOUS       41930014
* DIGITS, SMALL ENOUGH TO ALLOW FIXED-POINT MULTIPLICATION. THE         42000014
* MULTIPLICAND PARTS ARE MULTIPLIED BY THE MULTIPLIER PARTS AFTER THE   42070014
* PARTS HAVE BEEN CONVERTED TO BINARY.  THE RESULTANT PRODUCTS ARE USED 42140014
* TO FORM SUMS ACCORDING TO THE RELATIVE POSITIONS OF THE PARTS,SIMILAR 42210014
* TO SUMMING BY COLUMNS IN LONG-HAND MULTIPLICATION, BUT WITHOUT        42280014
* CARRIES BETWEEN SUMS. AS THE SUMS ARE CONVERTED TO BINARY, A CARRY    42350014
* IS ADDED TO THE NEXT SUM TO LEFT OF THE ONE BEING HANDLED.  THE SIGN  42420014
* OF THE PRODUCT IS PLUS IF THE SIGNS OF THE OPERANDS ARE ALIKE AND     42490014
* MINUS IF UNLIKE.                                                      42560014
         SPACE                                                          42630014
* THE NORMAL EXIT FROM THE ROUTINE IS TO THE 'END ROUTINE'. IF A        42700014
* SPECIFICATION ERROR OR A DATA CHECK IS FOUND, THE EXIT IS THE THE     42770014
* APPROPRIATE ERROR ROUTINE.                                            42840014
         SPACE 4                                                        42910014
* ERROR CHECKS                                                          42980014
         SPACE 1                                                        43050014
* THIS SECTION OF CODING CHECKS THE OPERANDS FOR MEETING SPECIFICA-     43120014
* TIONS OF THE INSTRUCTIONS.IF AN ERROR IS FOUND,A BRANCH TO THE APP-   43190014
* ROPRIATE CODE IN THE ANALYZER SECTION IS MADE                         43260014
         SPACE 1                                                        43330014
DECMP    CH    R11,CHD7       IF OP2 LENGTH GREATER THAN 8,             43400014
         BH    DECSP          SPECIFICATION ERROR                       43470014
         CR    R10,R11        IF OP1 LENGTH NOT GREATER THAN            43540014
         BNH   DECSP          SPECIFICATION ERROR                       43610014
         TM    OPCODE,X'FD'   TEST FOR DIVIDE DECIMAL                   43680014
         BO    DECDP          BRANCH IF DIVIDE DECIMAL                  43750014
         EX    R11,COMP5      CHECK OP1 FOR ZEROS EQUAL TO OP2 LENGTH   43820014
         BNE   DECDC          BRANCH TO DATA CHK ROUTINE IF NOT ENOUGH  43890014
         SPACE 3                                                        43960014
* SIGN DETERMINATION                                                    44030014
         SPACE 3                                                        44100014
* SPECIAL CASES                                                         44170014
         SPACE 1                                                        44240014
* THIS SECTION OF CODING TESTS FOR AND HANDLES THE FOLLOWING CASES      44310014
* CASE 1.EITHER OPERAND IS ZERO.                                        44380014
*        IF THE MULTIPLICAND IS ZERO,THE DETERMINED PRODUCT SIGN IS     44450014
*        ATTACHED TO THE OP1 FIELD.IF THE MULTIPLIER IS ZERO,THE OP1    44520014
*        FIELD IS CLEARED TO ZERO AND THE PRODUCT SIGN IN INSERTED.     44590014
* CASE 2.THE MULTIPLICAND IS LESS THAN OR EQUAL TO 9 DIGITS(INCLUDING   44660014
*        HIGH ORDER ZEROS)SINCE A NUMBER OF 9 DIGITS OR LESS CAN BE     44730014
*        CONTAINED IN A GENERAL REGISTER,THE PRODUCT CAN BE SO CON-     44800014
*        TAINED SINCE IT REPLACES THE MULTIPLICAND.THUS,FIXED-POINT     44870014
*        MULTIPLICATION CAN BE USED AFTER CONVERTING THE OPERANDS TO    44940014
*        BINARY.THE PRODUCT IS CONVERTED TO DECIMAL AND MOVED INTO THE  45010014
*        OP1 FIELD.LASTLY,THE PRODUCT SIGN IS INSERTED.                 45080014
         SPACE 1                                                        45150014
         SPACE 1                                                        45220014
         MVN   ZERO+15(1),OP1+15        MOVE OP1 SIGN                   45290014
         CLC   OP1(16),ZERO        COMPARE OP1 TO ZERO                  45360014
         BE    UCB4           BRANCH IF ZERO                            45430014
         MVN   ZERO+15(1),OP2+15        SIGN ZERO FLD WITH OP2 SIGN.    45500014
         CLC   ZERO(16),OP2   IF OP2 EQUALS ZERO, BRANCH                45570014
         BC    8,UDC2                                                   45640014
         CH    R10,CHD4       IS L1 GREATER THAN 4                      45710014
         BH    ROUTINE                                                  45780014
         NI    OP1+15,X'FE'   SET SIGN TO PLUS                          45850014
         NI    OP2+15,X'FE'   SET SIGN TO PLUS                          45920014
         CVB   R9,OP1+8       CONVERT OP1 TO BINARY                     45990014
         CVB   R4,OP2+8       CONVERT OP2 TO BINARY                     46060014
         MR    R8,R4          MULTIPLY OPERANDS                         46130014
         CVD   R9,OP1+8       CONVERT PRODUCT TO DECIMAL                46200014
         B     UCB4                                                     46270014
UDC2     XC    OP1(16),OP1    CLEAR OP1                                 46340014
         B     UCB4                                                     46410014
         SPACE 3                                                        46480014
* OPERAND BREAKUP AND CONVERSION                                        46550014
         SPACE 1                                                        46620014
* THIS SECTION OF CODING HANDLES THE GENERAL CASE.THE OPERANDS ARE      46690014
* BROKEN UP INTO HALFWORD GROUPS.A PADDED ZERO REPLACES THE SIGN IN     46760014
* THE LOW-ORDER GROUP OF EACH OPERAND(THAT WITH 3-DIGITS AND SIGN,AS    46830014
* OPPOSED TO 4 DIGITS IN ALL OTHER GROUPS).EACH GROUP IS CONVERTED TO   46900014
* BINARY AND STORED IN A HALFWORD.ALL THE GROUPS OF A SINGLE OPERAND    46970014
* ARE LOCATED IN CONTIGUOUS HALFWORDS,WITH THEIR RELATIVE POSITIONS     47040014
* RETAINED.                                                             47110014
         SPACE 1                                                        47180014
ROUTINE  LA    R14,6          SET INDICES AND COUNTER                   47250014
         LH    R7,OP2+8(R14)  GET FIRST GROUP OF OP2 DIGITS             47320014
         LH    R15,MINUS2                                               47390014
         N     R7,MASK2       CLEAR SIGN AND LEFT HAND 16 BITS          47460014
         B     UBA3A                                                    47530014
UBA3     LH    R7,OP2+8(R14)  GET ADDITIONAL GROUPS OF OP2 DIGITS       47600014
         N     R7,MASK1       CLEAR LEFT HAND 16 BITS OF REGISTER       47670014
UBA3A    SLL   R7,4           PAD WITH ZERO                             47740014
         ST    R7,OP2WKA1+4   SET UP FOR BINARY CONVERSION              47810014
         OI    OP2WKA1+7,X'0C'     SET SIGN TO PLUS                     47880014
         CVB   R7,OP2WKA1     CONVERT GROUPS TO BINARY                  47950014
         STH   R7,OP2WKA2(R14)     STORE CONVERTED NUMBER               48020014
         BXH   R14,R15,UBA3   BRANCH IF R14 NOT MINUS 2                 48090014
         LA    R1,14          INITIALIZE INDICES AND COUNTER            48160014
         LR    R8,R10         MOVE LENGTH OF OPERAND 1                  48230014
         SR    R8,R11         SUBTRACT LENGTH OF OPERAND 2              48300014
         LH    R7,OP1(R1)     GET FIRST GROUP OF OP1 DIGITS             48370014
         SR    R15,R15        CLEAR REGISTER 15                         48440014
         N     R7,MASK2       CLEAR SIGN AND LEFT HAND 16 BITS          48510014
         B     CONV1A                                                   48580014
CONV1    LH    R7,OP1(R1)     GET ADDITIONAL GOUPS OF OP1 DIGITS        48650014
         N     R7,MASK1       CLEAR LEFT HAND 16 BITS OF REGISTER       48720014
CONV1A   SLL   R7,4           PAD WITH ZERO                             48790014
         ST    R7,OP2WKA1+4   SET UP FOR BINARY CONVERSION              48860014
         OI    OP2WKA1+7,X'0C'     SET SIGN TO PLUS                     48930014
         CVB   R7,OP2WKA1     CONVERT GROUP TO BINARY                   49000014
         STH   R7,OP1WKA2(R1)      STORE CONVERTED NUMBER               49070014
         AR    R1,R14         ADD MINUS 2 TO COUNTER                    49140014
         BXH   R8,R14,CONV1   BRANCH IF R8 IS HIGHER THAN ZERO (R15)    49210014
         SPACE 3                                                        49280014
* MULTIPLY ROUTINE                                                      49350014
         SPACE 1                                                        49420014
* THE MULTIPLICAND GROUPS ARE MULIPLIED BY THE MULTIPLIER GROUPS.THE    49490014
* RESULTING PRODUCTS ARE USED TO FORM SUMS WHICH ARE MANIPULATED APP-   49560014
* ROPRIATELY TO FORM THE FINAL PRODUCT(THE SUM TO WHICH A PRODUCT       49630014
* BELONGS IS DETERMINED BY THE RELATIVE POSITIONS OF THE GROUPS MULT-   49700014
* IPLIED TO FORM IT IN THEIR RESPECTIVE OPERANDS).AFTER THE PRODUCT IS  49770014
* COMPLETELY FORMED IN THE OP1 FIELD,THE PRODUCT SIGN IS INSERTED.      49840014
         SPACE 1                                                        49910014
         LA    R13,6          SET OP2WKA2 INDEX                         49980014
         LA    R4,4                                                     50050014
         SR    R9,R9             ADJUSTING FACTOR.                      50120014
         LR    R7,R11         LOAD LENGTH OF L2 MINUS 1                 50190014
BACK     LA    R5,28          SET SUMS INDEX                            50260014
         SR    R5,R9          SUBTRACT ADJUSTMENT                       50330014
         LA    R2,14          SET OP1WKA2 INDEX                         50400014
         LR    R8,R10         LOAD LENGTH OF L1 MINUS 1                 50470014
         SR    R8,R11         GET L1 VALUE WITHOUT PADDED ZEROS         50540014
UBC3     LH    R0,OP1WKA2(R2) LOAD PORTION OF OP1                       50610014
         N     R0,MASK1       ZERO LEFT HALF OF REGISTER                50680014
         MH    R0,OP2WKA2(R13)     MULTIPLY OP1 BY OP2                  50750014
         A     R0,SUMS(R5)    ADD RESULT TO SUM                         50820014
         ST    R0,SUMS(R5)    SAVE RESULT IN PROPER SUM FIELD           50890014
         SR    R5,R4          SUBTRACT 4                                50960014
         AR    R2,R14         ADD MINUS 2                               51030014
         BXH   R8,R14,UBC3    BRANCH IF MORE THAN ZERO                  51100014
         AR    R9,R4          ADD 4                                     51170014
         AR    R13,R14        ADD MINUS 2                               51240014
         AR    R7,R14         ADD MINUS 2                               51310014
         BNM   BACK                                                     51380014
         LCR   R4,R4          COMPLIMENT REG 4                          51450014
         LA    R2,STORAGE+14  SET OP1 INDEX                             51520014
LOAD28   LA    R7,28          SUMS FIELD INDEX                          51590014
         L     R1,SUMS(R7)    LOAD ONE SUM FIELD                        51660014
UCD3     CVD   R1,WKAREA      CONVERT TO DECIMAL AND PLACE IN CORE      51730014
         LM    R8,R9,WKAREA   LOAD CONVERTED SUM                        51800014
         LR    R0,R9          MOVE LOW ORDER PORTION OF THE VALUE       51870014
         SRL   R0,4           REMOVE SIGN                               51940014
         SRDL  R8,20                                                    52010014
         SLDL  R8,4                                                     52080014
         CH    R7,LOAD28      COMPARE FOR FIRST SUM                     52150014
         BE    UBF3           BRANCH IF FIRST SUM                       52220014
         STH   R0,OP1-STORAGE(R2)  STORE LOW-ORDER 4 DIGITS OF SUM      52290014
         MVO   OP1-STORAGE(3,R2),OP1-STORAGE(2,R2) DESTROY SIGN         52360014
         B     UCA3                                                     52430014
UBF3     SLL   R0,16          REMOVE PADDED ZEROS                       52500014
         STH   R0,OP1-STORAGE(R2)  PLACE DIGITS IN PRODUCT AREA         52570014
UCA3     AR    R2,R14    ADD MINUS 2                                    52640014
         BXLE  R7,R4,UCA4     BRANCH WHEN R7 EQUALS R5                  52710014
         STM   R8,R9,WKAREA      ADD REMAINING HI-ORDER DIGITS          52780014
         OI    WKAREA+7,X'0C' MAKE SIGN PLUS                            52850014
         CVB   R1,WKAREA      ADD REMAINING HI-ORDER DIGITS TO NEXT SUM 52920014
         A     R1,SUMS(R7)                                              52990014
         B     UCD3                                                     53060014
UCA4     LA    R5,3           SET UP COUNTER                            53130014
         SRDL  R8,4              REMOVE SIGN.                           53200014
MOVEA    STH   R9,OP1-STORAGE(R2)  MOVE REMAINING DIGITS TO             53270014
         SRDL  R8,16             PRODUCT FIELD.                         53340014
         MVO   OP1-STORAGE(3,R2),OP1-STORAGE(2,R2) DESTROY SIGN         53410014
         AR    R2,R14         ADD MINUS 2                               53480014
         BM    MOVE0                                                    53550014
         SH    R5,CHD1                                                  53620014
         BNZ   MOVEA                                                    53690014
MOVE0    MVZ   OP1-STORAGE+4(1,R2),CHD0                                 53760014
UCB4     MVN   OP1+15(1),S1   MOVE IN SIGN                              53830014
         NI    OP1+15,X'FE'   SET SIGN TO PLUS                          53900014
         CLC   S1(1),S2       ARE SIGNS EQUAL                           53970014
         BE    MOVEEND                                                  54040014
         OI    OP1+15,X'01'   SET SIGN TO MINUS                         54110014
         B     MOVEEND                                                  54180014
         SPACE 2                                                        54250014
* CONSTANTS                                                             54320014
         SPACE 1                                                        54390014
         DS    0F                                                       54460014
MASK1    DC    X'0000FFFF'              SINGLE CONSTANTS.               54530014
MASK2    DC    X'0000FFF0'                                              54600014
CHD0     DC    H'0'                                                     54670014
CHD1     DC    H'1'                                                     54740014
MINUS2   DC    H'-2'                                                    54810014
CHD3     DC    H'3'                                                     54880014
CHD4     DC    H'4'                                                     54950014
CHD5     DC    H'5'                                                     55020014
CHD6     DC    H'6'                                                     55090014
CHD7     DC    H'7'                                                     55160014
         EJECT                                                          55230014
*        COMPARE DECIMAL                                                55300014
         SPACE 1                                                        55370014
* BOTH OPERANDS ARE COMPARED TO ZEROES.IF BOTH ARE ZERO THEY ARE CON-   55440014
* SIDERED EQUAL NO MATTER WHAT THEIR SIGNS ARE.IF ONE OPERAND IS ZERO   55510014
* AND THE OTHER NOT EQUAL ZERO,THE NON-ZERO OPERAND IS GREATER IF IT    55580014
* IS POSITIVE,LESS IF IT IS NEGATIVE.IF BOTH OPERANDS ARE NON-ZERO,     55650014
* THEY ARE COMPARED LOGICALLY.THE ONE OF GREATER ABSOLUTE VALUE IS      55720014
* CONSIDERED GREATER IF IT IS POSITIVE,LESS IF IT IS NEGATIVE.IF BOTH   55790014
* OPERANDS HAVE EQUAL ABSOLUTE VALUE,THEY ARE EQUAL IF THEIR SIGNS ARE  55860014
* ALIKE.IF THEIR SIGNS ARE OPPOSITE,THE OPERAND WITH THE PLUS SIGN IS   55930014
* GREATER.BEFORE TESTING OR COMPARING,THE OPERAND SIGNS ARE SAVED AND   56000014
* THEIR POSITIONS IN THE OPERANDS ZEROED OUT.                           56070014
         SPACE 1                                                        56140014
DECCP    NI    OP2+15,X'F0'   ZERO SIGN OF OP2                          56210014
         NI    OP1+15,X'F0'   ZERO SIGN OF OP1                          56280014
         CLC   OP1(16),C8FD0  IS OP1 ZERO                               56350014
         BNE   PAT6              NO,BRANCH TO PAT6.                     56420014
         CLC   OP2(16),C8FD0  IS OP2 ZERO                               56490014
         BNE   PAT3              NO,BRANCH TO PAT3.                     56560014
         B     REE3                                                     56630014
PAT3     TM    S2,X'01'       TEST FOR MINUS                            56700014
         BNO   SCC10          BRANCH TO SET CONDITION CODE TO 10        56770014
SFJ3     OI    PSW+4,X'20'    SET CONDITION CODE                        56840014
         B     DECNEND                                                  56910014
PAT6     CLC   OP2(16),C8FD0     OP1 NQ 0,IS OP2=0?                     56980014
         BNE   PAT7              NO,BRANCH TO PAT7.                     57050014
PAT9     TM    S1,X'01'       IS OP1 SIGN MINUS                         57120014
         BO    SCC10          TO SET CONDITION CODE TO 10               57190014
         B     SFJ3           TO SET CONDITION CODE TO 2                57260014
PAT7     CLC   OP1(16),OP2       OP1 NQ 0,OP2 NQ 0,COMPARE ABSOLUTE     57330014
         BL    PAT3           BRANCH TO CHECK SIGN                      57400014
         BNE   PAT9           BRANCH IF OP1 GREATER THAN OP2            57470014
         CLC   S1,S2          IS OP1 SIGN EQ OP2 SIGN                   57540014
         BE    REE3                                                     57610014
         B     PAT9                                                     57680014
         EJECT                                                          57750014
* DIVIDE PACKED                                                         57820014
         SPACE 1                                                        57890014
* THE'DIVIDE PACKED'ROUTINE DIVIDES ONE FIELD OF PACKED DECIMAL DATA    57960014
* INTO ANOTHER.THE DIVISION IS ACCOMPLISHED IN ONE OF TWO WAYS.IF THE   58030014
* LENGTH OF THE DIVIDEND FIELD IS FIVE BYTES OR LESS BOTH OPERANDS ARE  58100014
* CONVERTED TO BINARY AND DIVISION IS DONE IN BINARY.FOR A DIVIDEND     58170014
* FIELD LENGTH GREATER THAN 5 BYTES,MULTIPLES OF 2,4 AND 8 TIMES THE    58240014
* DIVISOR ARE CALCULATED AND ALIGNED WITH THE DIVIDEND FIELD.THESE      58310014
* MULTIPLES ARE THEN SUBTRACTED FROM THE DIVIDEND TO SIMULATE DIVISION  58380014
         SPACE 1                                                        58450014
* THE NORMAL EXIT IS TO THE END ROUTINE.  THE ERROR ROUTINE IS ENTERED  58520014
* ONLY IF THERE IS A DIVIDE CHECK.                                      58590014
         SPACE 1                                                        58660014
* HOUSEKEEPING                                                          58730014
         SPACE 1                                                        58800014
* STORAGE WORK AREAS ARE CLEARED AND CHECKS ARE PERFORMED TO ASCERTAIN  58870014
* THAT THE SPECIFICATIONS FOR THE'DIVIDE PACKED'INSTRUCTION ARE NOT     58940014
* VIOLATED.THE OPERATIONS PERFORMED IN THIS AREA ARE NECESSARY FOR      59010014
* BOTH THE BINARY DIVIDE AND THE SIMULATED DIVIDE.                      59080014
         SPACE 1                                                        59150014
DECDP    NI    OP2+15,X'F0'   ZERO OP2 SIGN                             59220014
         CLC   OP2(16),ZERO   TEST FOR DIVISOR EQUAL TO ZERO            59290014
         BE    DECDD1         BRANCH IF DIVIDE CHECK                    59360014
         LA    R9,1      LOAD REG 9 WITH A 1                            59430014
         MVO   DIVSX1-OP1(9,R6),0(8,R2) MOVE OP2                        59500014
         LR    R5,R10         CALCULATE DIFFERENCE BETWEEN L1 AND L2    59570014
         SR    R5,R11                                                   59640014
         MVN   DIVSX1+15(1),OP1+15      RE-SIGN FIELD.                  59710014
         CLC   DIVSX1(16),OP1 TEST FOR REALIGNED DIVISOR NOT GREATER    59780014
         BNH   DECDD1                   THAN DIVIDEND, DIVIDE CHECK     59850014
*                                       ERROR.                          59920014
         NI    OP1+15,X'FE'   SET SIGN TO PLUS                          59990014
         OI    OP2+15,X'0C'   SET SIGN TO PLUS                          60060014
         CH    R10,CHD4       IS L1 5 OR LESS CHARACTERS IN LENGTH      60130014
         BH    SIMDIV                                                   60200014
         SPACE 1                                                        60270014
* BINARY DIVIDE                                                         60340014
         SPACE 1                                                        60410014
* THIS DIVIDE IS PERFORMED IF THE GREATER OPERAND LENGTH IS 5 BYTES OR  60480014
* LESS.BOTH OPERANDS ARE CONVERTED TO BINARY,DIVISION IS PERFORMED,AND  60550014
* THE QUOTIENT AND REMAINDER IN DECIMAL FORM REPLACE THE DIVIDEND.      60620014
         SPACE 1                                                        60690014
         SR    R0,R0                                                    60760014
         CVB   R1,OP1+8       CONVERT OPERAND 1 TO BINARY               60830014
         CVB   R7,OP2+8       CONVERT OPERAND 2 TO BINARY               60900014
         DR    R0,R7          DIVIDE                                    60970014
         CVD   R1,DIVSX1                                                61040014
         MVN   DIVSX1+7(1),OP1+15  MOVE IN PLUS SIGN                    61110014
         CLC   S1(1),S2       ARE OP1 AND OP2 SIGNS EQUAL               61180014
         BE    CVDREM         BRANCH IF QUOTIENT IS TO BE PLUS          61250014
         OI    DIVSX1+7,X'01' SET SIGN TO MINUS                         61320014
CVDREM   CVD   R0,DIVSX2                                                61390014
         MVN   DIVSX2+7(1),S1 MOVE SIGN OF THE DIVIDEND TO REMAINDER    61460014
         LA    R4,DIVSX1+8    FIND ADDRESS OF QUOTIENT                  61530014
         SR    R4,R10         SUBTRACT L1                               61600014
         AR    R4,R11         ADD L2                                    61670014
         MVC   0(4,R6),0(R4)  MOVE QUOTIENT TO DIVIDEND FIELD           61740014
         LA    R4,DIVSX2+7    FIEND ADDRESS OF REMAINDER                61810014
         SR    R4,R11                                                   61880014
         LR    R8,R6          MOVE OP1 ADDRESS                          61950014
         AR    R8,R5          FIND LOCATION FOR REMAIDER IN DIVIDEND    62020014
         MVC   0(4,R8),0(R4)  MOVE REMAINDER TO DIVIDEND FIELD          62090014
         B     MOVEEND                                                  62160014
         SPACE 1                                                        62230014
* SIMULATED DIVIDE                                                      62300014
         SPACE 1                                                        62370014
* PRELIMINARY OPERATIONS ARE PERFORMED WHICH APPLY ONLY TO THE SIMU-    62440014
* LATED DIVIDE PROCESS.                                                 62510014
         SPACE 1                                                        62580014
SIMDIV   MVO   DIVSX1(16),DIVSX1(15)    SHIFT 1X DIVISOR                62650014
         MVC   QUOT(15),ZERO                                            62720014
         SR    R5,R9                                                    62790014
         SLA   R5,1                                                     62860014
         STH   R5,SHFTCTR                                               62930014
         SRA   R5,1           RESTORE R5                                63000014
         SPACE 1                                                        63070014
*        CALCULATE MULTIPLES                                            63140014
         SPACE 1                                                        63210014
* MULTIPLES OF 2, 4, AND 8 TIMES THE                                    63280014
* DIVISOR ARE CALCULATED IN ONE OF TWO                                  63350014
* WAYS. IF THE LENGTH OF THE DIVISOR IS                                 63420014
* 4 BYTES OR LESS ONLY ONE CONVERSION TO                                63490014
* BINARY IS NECESSARY FOR ALL THREE                                     63560014
* MULTIPLES. IF THE LENGTH OF THE                                       63630014
* DIVISOR IS GREATER THAN 4, TWO CONVER-                                63700014
* SIONS TO BINARY ARE NECESSARY TO FORM                                 63770014
* EACH MULTIPLE. AFTER CALCULATION THE                                  63840014
* MULTIPLES ARE PROPERLY ALIGNED FOR THE                                63910014
* FIRST SUBTRACTION.                                                    63980014
         SPACE 1                                                        64050014
* CALCMULT                                                              64120014
         SPACE 1                                                        64190014
* PRELIMINARY OPERATIONS NECESSARY FOR                                  64260014
* BOTH METHODS ARE PERFORMED.                                           64330014
         SPACE 1                                                        64400014
         LA    R1,DIVSX8-OP1(R6)    STOPPING FACTOR                     64470014
         LA    R7,4                                                     64540014
         LA    R4,DIVSX2-OP1(R6)                                        64610014
         LA    R0,16                                                    64680014
         SR    R2,R9          SUBTRACT PLUS 1                           64750014
         CH    R11,CHD3       IS BINARY MULTIPLICATION POSSIBLE         64820014
         BH    CALCLOOP                                                 64890014
         SPACE 1                                                        64960014
* BINARY MULTIPLICATION                                                 65030014
         SPACE 1                                                        65100014
* THE ENTIRE DIVISOR IS CONVERTED TO                                    65170014
* BINARY. THREE SUCCESSIVE SHIFTS OF THE                                65240014
* REGISTER ARE POSSIBLE WITHOUT OVER-                                   65310014
* FLOW. THE FIRST MULTIPLIES THE DIVISOR                                65380014
* BY 2, THE SECOND BY 4, THE THIRD BY 8.                                65450014
* AFTER EACH SHIFT THE MULTIPLE IS                                      65520014
* CONVERTED TO DECIMAL AND STORED IN THE                                65590014
* PROPER FIELD.                                                         65660014
         SPACE 1                                                        65730014
         MVC   DIVSX8+12(4),OP2+12 MOVE OP2 DIGITS                      65800014
         CVB   R15,DIVSX8+8   CONVERT OP2 TO BINARY                     65870014
BINLOOP  SLA   R15,1          MULTIPLY DIVISOR BY 2                     65940014
         CVD   R15,DIVSX8+8   CONVERT TO DECIMAL                        66010014
         MVC   OP2+11(5),DIVSX8+11 PUT DIVISOR MULTIPLE IN DIVISOR      66080014
         MVO   0(9,R4),0(9,R2)                                          66150014
         BXLE  R4,R0,BINLOOP  BRANCH UNTIL DIVSX8 HAS BEEN ADDRESSED    66220014
         SPACE 1                                                        66290014
* RE-SIGN                                                               66360014
         SPACE 1                                                        66430014
* CALCULATION OF THE MULTIPLES INCLUDES                                 66500014
* MULTIPLYING EACH BY A POWER OF 10 SO                                  66570014
* THAT THE WHOLE MULTIPLE FIELD MAY BE                                  66640014
* SUBTRACTED FROM THE WHOLE DIVIDEND                                    66710014
* FIELD. THIS MULTIPLICATION IS ACHIEVED                                66780014
* BY MOVING FROM THE LOW-ORDER PART OF                                  66850014
* THE WORK AREA INTO THE PROPER POSITION                                66920014
* IN THE MULTIPLE FIELD. THE LOW-ORDER                                  66990014
* PART OF THE MULTIPLE FIELD IS CLEARED,                                67060014
* THE FIELD IS RE-SIGNED WITH THE SIGN OF                               67130014
* THE DIVISOR, AND THE FIELD IS ALIGNED                                 67200014
* FOR THE FIRST SUBTRACTION.                                            67270014
         SPACE 1                                                        67340014
RESIGN   LA    R1,DIVSX8-OP1(R6)   STOPPING FACTOR                      67410014
         MVN   DIVSX1+15(1),OP1+15 SIGN DIVSX1 FIELD PLUS               67480014
         LA    R8,DIVSX2+15                                             67550014
         LA    R13,DIVSX2                                               67620014
         LA    R14,DIVSX2-OP1+1(R6)                                     67690014
         AR    R14,R11        ADD L2                                    67760014
RESIGNA  EX    R5,EXORMULT       CLEAR SIGN AND LOW ORDER               67830014
*                                       OF MULTIPLE FIELD.              67900014
         MVN   0(1,R8),OP1+15 RESIGN FIELD PLUS                         67970014
         MVO   0(16,R13),0(15,R13)      ALIGN FIELD FOR FIRST SUBTRACT  68040014
         BXH   R13,R0,TEST4   BRANCH WHEN REG 13 IS HIGHER THAN REG 1   68110014
         AR    R8,R0          ADD 16                                    68180014
         AR    R14,R0         ADD 16                                    68250014
         B     RESIGNA                  GO TO RESIGNA.                  68320014
         SPACE 1                                                        68390014
* CALCLOOP                                                              68460014
         SPACE 1                                                        68530014
* THE MULTIPLES ARE CALCULATED AS                                       68600014
* FOLLOWS. THE LOW-ORDER 5 BYTES OF THE                                 68670014
* WORK AREA ARE CONVERTED TO BINARY,                                    68740014
* SHIFTED, CONVERTED BACK TO DECIMAL,                                   68810014
* AND RESTORED IN THE WORK AREA. THE                                    68880014
* NEXT 3 BYTES ARE CONVERTED TO BINARY                                  68950014
* AND SHIFTED. OVERFLOW INTO THE 6TH                                    69020014
* BYTE OF DECIMAL DATA IS CHECKED AFTER                                 69090014
* MULTIPLICATION OF THE LOW-ORDER BYTES                                 69160014
* AND ADDED AFTER THE SECOND SHIFT IF                                   69230014
* NECESSARY. SINCE THE LENGTH OF THE                                    69300014
* DIVISOR CANNOT EXCEED 8 BYTES ONLY 2                                  69370014
* CONVERSIONS ARE NECESSARY. THE MULT-                                  69440014
* IPLE IS THEN MOVED FROM THE WORK AREA                                 69510014
* INTO THE PROPER MULTIPLE FIELD. THE                                   69580014
* MULTIPLE FIELDS ARE THEN RE-SIGNED AND                                69650014
* ALIGNED FOR THE FIRST SUBTRACTION.                                    69720014
         SPACE 1                                                        69790014
CALCLOOP SR    R8,R8          CLEAR CARRY SWITCH                        69860014
         MVC   DIVSX8(16),ZERO     CLEAR WORK AREA                      69930014
         MVC   DIVSX8+11(5),OP2+11 MOVE OP2                             70000014
         CVB   R15,DIVSX8+8   CONVERT LOW ORDER 5 BYTES OF DIVISOR      70070014
         SLA   R15,1                                                    70140014
         CVD   R15,DIVSX8+8   CONVERT MULTIPLE                          70210014
         CLI   DIVSX8+10,X'00'     CHECK FOR DECIMAL CARRY              70280014
         BE    MOVEC                                                    70350014
         LR    R8,R9          SET SWITCH ON IF CARRY                    70420014
MOVEC    MVC   OP2+11(5),DIVSX8+11 REPLACE MULTIPLIED DIGITS IN         70490014
*                                       LOW-ORDER 5 BYTES OF            70560014
*                                       DIVISOR FIELD.                  70630014
         MVO   DIVSX8+8(8),OP2+7(4)     CONVERT REST OF DIVISOR FIELD   70700014
         NI    DIVSX8+15,X'FE'     MAKE SIGN OF 2ND CONVERT PLUS        70770014
         CVB   R15,DIVSX8+8        CONVERT TO BINARY                    70840014
         SLA   R15,1          MULTIPLY REST OF DIVISOR DIGITS BY 2      70910014
         BCT   R8,CONVERTB    BRANCH IF CARRY SWITCH IS NOT SET         70980014
         AR    R15,R9         ADD 1 TO MULTIPLE                         71050014
CONVERTB CVD   R15,DIVSX8+8   CONVERT MULTIPLE                          71120014
         L     R15,DIVSX8+12                                            71190014
         SRA   R15,4          SHIFT OUT SIGN                            71260014
         ST    R15,QUOT                                                 71330014
         MVC   OP2+7(4),QUOT  REPLACE HIGH ORDER DIGITS IN DIVISOR      71400014
         MVO   0(9,R4),0(9,R2)                                          71470014
         BXLE  R4,R0,CALCLOOP BRANCH IF R4 NOT HIGHER THAN R1           71540014
         B     RESIGN                                                   71610014
         SPACE 1                                                        71680014
*            DIVIDE LOOP                                                71750014
         SPACE 1                                                        71820014
* 'PARTIAL DIVIDEND' WILL BE USED TO                                    71890014
* INDICATE THE DIVIDEND FIELD AFTER A                                   71960014
* SUBTRACTION HAS BEEN MADE. THE PARTIAL                                72030014
* DIVIDEND IS COMPARED TO EACH DIVISOR                                  72100014
* MULTIPLE TO DETERMINE THE LARGEST                                     72170014
* MULTIPLE THAT CAN BE SUBTRACTED. AFTER                                72240014
* EACH SUBTRACTION A LOW-ORDER 1 IS                                     72310014
* ADDED INTO A REGISTER AND THE REGISTER                                72380014
* IS SHIFTED LEFT IN PREPARATION FOR THE                                72450014
* NEXT SUBTRACTION. IN THIS WAY, TWO                                    72520014
* QUOTIENT DIGITS, IN PROPER BCD CODE,                                  72590014
* ARE FORMED AT A TIME. THESE ARE STORED                                72660014
* IN A WORK AREA WHERE THE QUOTIENT IS                                  72730014
* ACCUMULATED. AFTER EACH DIGIT IS                                      72800014
* FORMED THE DIVISOR MULTIPLES ARE                                      72870014
* DIVIDED BY 10 AND THE SHIFT COUNTER IS                                72940014
* DECREMENTED BY 1. WHEN THE LAST DIGIT                                 73010014
* HAS BEEN FORMED THE QUOTIENT IS SIGNED                                73080014
* AND PLACED IN THE DIVIDEND FIELD. THE                                 73150014
* REMAINDER IS RE-SIGNED.  IT IS ALREADY                                73220014
* PROPERLY PLACED AS A RESULT OF THE                                    73290014
* SUBTRACTIONS.                                                         73360014
         SPACE 1                                                        73430014
TEST4    SR    R1,R1          CLEAR REGISTER                            73500014
         LA    R8,ZERO                                                  73570014
TEST4A   CLC   OP1(16),DIVSX4      COMPARE DIVIDEND TO 4X DIVISOR       73640014
         BL    SHIFT2                                                   73710014
         CLC   OP1(16),DIVSX8      COMPARE DIVIDEND TO 8X DIVISOR       73780014
         BNL   SUB8                                                     73850014
         SLA   R1,1                                                     73920014
         MVC   OP2(16),DIVSX4      MOVE 4X DIVISOR TO COMMON AREA       73990014
         BAL   R13,SUBTRACT   SUBTRACT DIVISOR FIELD FROM DIVIDEND FLD  74060014
         AR    R1,R9          ADD 1                                     74130014
         SLA   R1,1                                                     74200014
TEST2    CLC   OP1(16),DIVSX2      COMPARE DIVIDEND TO 2X DIVISOR       74270014
         BL    SHIFT1                                                   74340014
         MVC   OP2(16),DIVSX2      MOVE 2X DIVISOR TO COMMON AREA       74410014
         BAL   R13,SUBTRACT   SUBTRACT DIVISOR FIELD FROM DIVIDEND FLD  74480014
         AR    R1,R9          ADD 1                                     74550014
SHIFT1   SLA   R1,1                                                     74620014
TEST1    CLC   OP1(16),DIVSX1      COMPARE DIVIDEND TO 1X DIVISOR       74690014
         BL    QUOTST                                                   74760014
         MVC   OP2(16),DIVSX1      MOVE 1X DIVISOR TO COMMON AREA       74830014
         BAL   R13,SUBTRACT   SUBTRACT DIVISOR FIELD FROM DIVIDEND FLD  74900014
         AR    R1,R9          ADD 1                                     74970014
QUOTST   TM    SHFTCTR+1,X'01'          ONE QUOTIENT DIGIT OR TWO       75040014
*                                       FORMED.                         75110014
         BC    8,ZET                                                    75180014
         STC   R1,0(R8)       IF 2 FORMED, STORE DIGITS IN              75250014
*                                       QUOTIENT WORK AREA.             75320014
         AR    R8,R9          ADD 1                                     75390014
         SR    R10,R9         SUBTRACT 1                                75460014
         SR    R1,R1                                                    75530014
SHIFTS   MVO   DIVSX8(16),DIVSX8(15)    SHIFT 8X DIVISOR                75600014
         MVO   DIVSX4(16),DIVSX4(15)    SHIFT 4X DIVISOR                75670014
         MVO   DIVSX2(16),DIVSX2(15)    SHIFT 2X DIVISOR                75740014
         MVO   DIVSX1(16),DIVSX1(15)    SHIFT 1X DIVISOR                75810014
         LH    R15,SHFTCTR    LOAD SHIFT COUNTER                        75880014
         SR    R15,R9         SUBTRACT 1                                75950014
         STH   R15,SHFTCTR                                              76020014
         SLA   R1,1                                                     76090014
         B     TEST4A         FORM NEXT QUOTIENT DIGIT                  76160014
SHIFT2   SLA   R1,2                                                     76230014
         B     TEST2                                                    76300014
SUB8     MVC   OP2(16),DIVSX8      MOVE 8X DIVISOR TO COMMON AREA       76370014
         BAL   R13,SUBTRACT   SUBTRACT DIVISOR FIELD FROM DIVIDEND FLD  76440014
         AR    R1,R9          ADD 1                                     76510014
         SLA   R1,3                                                     76580014
         B     TEST1                                                    76650014
ZET      CLI   SHFTCTR+1,X'00'     COMPARE FOR ZERO                     76720014
         BNE   SHIFTS                                                   76790014
         LH    R10,LENGTH1    LOAD LENGTH OF OPERAND 1                  76860014
         SLA   R1,4                                                     76930014
         STC   R1,0(R8)       STORE DIGIT IN QUOTIENT WORK AREA         77000014
         MVN   0(1,R8),S1                                               77070014
         NI    0(R8),X'FE'    SET SIGN TO PLUS                          77140014
         MVN   OP1+15(1),S1   MOVE SIGN FOR REMAINDER                   77210014
         CLC   S1(1),S2                                                 77280014
         BE    ENDDIV                                                   77350014
         OI    0(R8),X'01'    SET SIGN TO MINUS                         77420014
ENDDIV   EX    R5,STANS       STORE QUOTIENT IN DIVIDEND FIELD          77490014
         B     MOVEEND                                                  77560014
         EJECT                                                          77630014
*               SUBTRACT                                                77700014
         SPACE 1                                                        77770014
* THE DIVIDE LOOP LINKS TO THIS ROUTINE                                 77840014
* TO PERFORM THE SUBTRACTIONS. FOUR                                     77910014
* BYTES OF EACH OPERAND ARE CONVERTED AT                                77980014
* A TIME AND SUBTRACTED IN BINARY.  THIS                                78050014
* PARTIAL RESULT IS THEN REPLACED IN THE                                78120014
* DIVIDEND FIELD AND THE NEXT HIGHER-                                   78190014
* ORDER WORDS ARE CONVERTED.  TWO BOR-                                  78260014
* ROW FACTORS ARE NECESSARY BECAUSE THE                                 78330014
* LOW-ORDER WORD IS ALREADY SIGNED, AND                                 78400014
* ADDING A SIGN TO THE HIGHER-ORDER                                     78470014
* WORDS EFFECTIVELY MULTIPLIES THE WORD                                 78540014
* BY 10.                                                                78610014
         SPACE 1                                                        78680014
SUBTRACT SR    R0,R0                                                    78750014
         LA    R11,OP1+12        INITIALIZE ADDRESSES TO MOVE           78820014
*                                       FROM.                           78890014
         LA    R15,OP2+12                                               78960014
         LA    R2,3           INITIALIZE LENGTH COMPARING               79030014
*                                       FACTOR.                         79100014
         MVC   DOUBWD+4(4),0(R11) CONVERT LOW ORDER 4 BYTES OF          79170014
         CVB   R4,DOUBWD          DIVIDEND.                             79240014
         MVC   DOUBWD+4(4),0(R15) CONVERT LOW ORDER 4 BYTES OF          79310014
         CVB   R14,DOUBWD     DIVISOR FIELD                             79380014
         CR    R14,R4         SEE IF BORROW IS NECESSARY                79450014
         BNH   SUBTF                                                    79520014
         A     R4,BOR2        ADD BORROW                                79590014
         LR    R0,R9             SET BORROW SWITCH ON.                  79660014
SUBTF    SR    R4,R14                                                   79730014
         CVD   R4,DOUBWD                                                79800014
SUBTLOOP MVC   0(4,R11),DOUBWD+4   REPLACE DIFFERENCE IN DIVIDEND FIELD 79870014
         CR    R2,R10         HAS WHOLE DIVISOR FIELD BEEN              79940014
         BCR   11,R13                                                   80010014
         LA    R2,4(R2)       ADD 4                                     80080014
         SR    R15,R7         SUBTRACT 4                                80150014
         SR    R11,R7         SUBTRACT 4                                80220014
         MVO   DOUBWD(8),0(4,R11) CONVERT NEXT HIGH ORDER WORDS         80290014
         MVN   DOUBWD+7(1),OP1+15       OF BOTH OPERANDS.               80360014
         CVB   R4,DOUBWD                                                80430014
         MVO   DOUBWD(8),0(4,R15)                                       80500014
         CVB   R14,DOUBWD                                               80570014
*                                       BORROW.                         80640014
         BCT   R0,CKBORRO     BRANCH IF NO BORROW WAS REQUIRED          80710014
         SR    R4,R9                                                    80780014
CKBORRO  SR    R0,R0                                                    80850014
         CR    R14,R4         IS BORROW NECESSARY FOR THIS SUBTRACTION  80920014
         BNH   SUBTS                                                    80990014
         A     R4,BOR3                                                  81060014
         LR    R0,R9                                                    81130014
SUBTS    SR    R4,R14                                                   81200014
         CVD   R4,DOUBWD                                                81270014
         MVO   DOUBWD+3(6),DOUBWD+3(5)  CLEAR SIGN OF DIFFERENCE.       81340014
         B     SUBTLOOP                                                 81410014
         SPACE 2                                                        81480014
*              CONSTANTS                                                81550014
         SPACE 1                                                        81620014
         DS    0F                                                       81690014
EXORMULT XC    0(1,R14),0(R14)                                          81760014
STANS    MVC   0(1,R6),ZERO                                             81830014
         SPACE 1                                                        81900014
TABLE    DC    10XL16'00000000000000000000111111111111'                 81970014
         DC    16XL6'111111111111'                                      82040014
STORKEY  DS    C                 STORAGE KEY ASSOCIATED WITH OP2.       82110014
         EJECT                                                          82180014
STORAGE  DS    0D                                                       82250014
REGS     DS    16CL4  SAVE LOCATION FOR USER REGISTERS 0 THRU 15        82320014
         DS    CL2                                                      82390014
OPCODE   DS    C      OPCODE OF DECIMAL INSTRUCTION BEING SIMULATED     82460014
LENGTH   DS    C      L1-L2 FIELDS OF INSTRUCTION BEING SIMULATED       82530014
OP1ADDR  DS    CL2    B1-D1 FIELDS OF INSTRUCTION BEING SIMULATED       82600014
OP2ADDR  DS    CL2    B2-D2 FIELDS OF INSTRUCTION BEING SIMULATED       82670014
OP1      DS    CL16   ACTUAL VALUE OF OPERAND 1  RIGHT JUSTIFIED        82740014
OP2      DS    CL16   ACTUAL VALUE OF OPERAND 2  RIGHT JUSTIFIED        82810014
DIVSX1   DS    CL16                                                     82880014
DIVSX2   DS    CL16                                                     82950014
DIVSX4   DS    CL16                                                     83020014
DIVSX8   DS    CL16                                                     83090014
ZERO     DS    CL16                                                     83160014
DOUBWD   DS    D                                                        83230014
QUOT     DS    CL15                                                     83300014
SHFTCTR  DS    H                                                        83370014
LENGTH2  DC    X'0000'                                                  83440014
LENGTH1  DC    X'0000'                                                  83510014
         DC    X'00'                                                    83580014
         EJECT                                                          83650014
*        ANALYZER SECTION                                               83720014
         SPACE 1                                                        83790014
* THE'ANALYZER'SECTION IS DIVIDED INTO 6 PORTIONS FOR SIMULATING PRO-   83860014
* GRAM INTERRUPTIONS.THESE PORTIONS SIMULATE PROTECTION,SPECIFICATION,  83930014
* DECIMAL DIVIDE,ADDRESSING,DATA,AND DECIMAL OVERFLOW INTERRUPTS.       84000014
* THIS IS ACCOMPLISHED BY PLACING THE DETECTED INTERRUPTION CODE INTO   84070014
* THE OLD PSW AND MOVING THIS PSW INTO THE'OLD PROGRAM PSW AREA'.A      84140014
* BRANCH IS THEN MADE TO THE 'ERROR END'ENTRY POINT OF THE'END'SECTION  84210014
* (DECEREND).IN THE CASE OF A DECIMAL OVERFLOW,A CHECK IS FIRST MADE    84280014
* TO DETERMINE IF THIS INTERRUPT IS MASKED OFF.IF IT IS,A BRANCH IS     84350014
* MADE IMMEDIATELY TO THE'NORMAL END'ENTRY POINT OF THE'END'SECTION     84420014
* (DECNEND).                                                            84490014
* THE ANALYZER PORTIONS ARE ENTERED FROM THE VARIOUS SECTIONS(ERROR     84560014
* CHECK,ADD PACKED,ETC.)WHENEVER THEY FIND A CONDITION THAT WILL CAUSE  84630014
* A PROGRAM INTERRUPT.                                                  84700014
         SPACE 1                                                        84770014
* THE ENTRY POINTS TO THE ANALYZER SECTION FOR THE PROTECTION,SPEC-     84840014
* IFICATION,DECIMAL DIVIDE,ADDRESSING,DATA,AND DECIMAL OVERFLOW PORT-   84910014
* IONS ARE RESPECTIVELY 'DECPT','DECSP','DECDD','DECADDR','DECDC'AND    84980014
* 'DECDO'.                                                              85050014
         SPACE 1                                                        85120014
* THE 2 EXITS FROM THE ANALYZER SECTION ARE,FOR THE NORMAL END TO       85190014
* 'DECNEND'IN THE 'END'SECTION AND FOR THE'ERROR END'TO 'DECEREND'IN    85260014
* THE'END'SECTION.                                                      85330014
         SPACE 5                                                        85400014
DECPT    MVC   PSW+2(2),CHX4     PLACE PROT.INTERRUPT VALUE IN PSW      85470014
         B     RDA1                                                     85540014
         SPACE 1                                                        85610014
DECSP    MVC   PSW+2(2),CHX6            PUT 'SPECIFICATION INTERRUPT'   85680014
         B     RDA1                                                     85750014
DECDD    MVC   PSW+2(2),CHX11           PUT 'DEC DIVIDE CHK INTERRUPT'  85820014
         B     RDA1                                                     85890014
         SPACE 1                                                        85960014
DECADDR  MVC   PSW+2(2),CHX5            PUT 'ADDRESSING INTERRUPT' CODE 86030014
         B     RDA1                                                     86100014
         SPACE 1                                                        86170014
DECDC    MVC   PSW+2(2),CHX7            PUT DATA INTERRUPT CODE IN PSW, 86240014
         B     RDA1                                                     86310014
         SPACE 1                                                        86380014
DECDO    TM    PSW+4,X'04'              IS DECIMAL OVERFLOW MASKED OFF. 86450014
         BZ    MOVEEND                                                  86520014
         MVC   PSW+2(2),CHX10          PUT 'DECIMAL OVERFLOW INTERRUPT' 86590014
RDA1     CR    R10,R3         TEST FOR L1 VALUE IN R10                  86660014
         BL    DECEREND       BRANCH IF L1 IS IN R10                    86730014
         SR    R10,R3         RESTORE L1 TO R10                         86800014
         LR    R3,R6          TO PREVENT DESTRUCTION OF OPERAND 1       86870014
         EJECT                                                          86940014
*        END SECTION                                                    87010014
         SPACE 1                                                        87080014
* THE 'END'SECTION MOVES OPERAND 1 FROM THE COMMON STORAGE AREA TO ITS  87150014
* PROPER PLACE IN PROBLEM PROGRAM STORAGE.IF THE NORMAL END ENTRY POINT 87220014
* (DECNEND) WAS USED(DUE TO SUCCESSFUL COMPLETION OF SIMULATION OR      87290014
* DECIMAL OVERFLOW INTERRUPT BIT BEING MASKED OFF),REGISTERS ARE        87360014
* RESTORED, AND CONTROL IS RETURNED TO THE PROBLEM PROGRAM VIA A LPSW   87430014
* OF THE PROBLEM PROGRAM PSW OR TO TESTRAN VIA A LPSW OF THE TESTRAN    87500014
* PSW. IF THE ERROR END ENTRY POINT (DECEREND) WAS USED (DUE TO THE     87570014
* DETECTION OF AN ERROR), CONTROL IS PASSED BACK TO THE PFLIH BY A      87640014
* REGISTER BRANCH. IF TESTRAN WAS IN USE WHEN A DECIMAL INSTRUCTION WAS 87710014
* EXECUTED, PFLIH WILL SET UP A PSW AND RETURN TO TESTRAN.              87780014
         SPACE 5                                                        87850014
DECEREND MVI   ENDIND,X'01'             TURN ON ERROR SWITCH.           87920014
         SPACE                                                          87990014
DECNEND  CLI   OPCODE,X'F9'   IS OPCODE CP                              88060014
         BE    RED3                       GO TO RED3.                   88130014
         SPACE 1                                                        88200014
MOVEEND  EX    R10,MOVE            MOVE OP1 TO P/P IF NO ERROR          88270014
RED3     CLI   ENDIND,X'01'             IF ERROR SWITCH IS OFF,         88340014
         BNE   REE3                        GO TO REE3.                  88410014
         SPACE 1                                                        88480014
         MVI   ENDIND,X'02'   RESET ERROR SWITCH                        88550014
         L     R14,ERRXIT     ADDRESS OF PFLIH                          88620014
         BR    R14                                                      88690014
         SPACE 1                                                        88760014
         EXTRN IEATCBQ                                                  88830014
REE3     L     R9,TCBPTER          TCB POINTER                          88900014
         LTR   R9,R9               IS TESTRAN IN THE SYSTEM             88970014
         BZ    REE3A               BRANCH IF NOT                        89040014
         L     R9,4(R9)       OLD TCB POINTER                           89110014
         L     R9,20(R9)      TESTRAN TCB POINTER FROM OLD TCB          89180014
         LTR   R9,R9          TEST FOR TESTRAN IN USE                   89250014
         BNM   REE3A          BRANCH IF NOT IN USE                      89320014
         LPSW  448(R9)        LOAD TESTRAN PSW AND GO TO TESTRAN        89390014
REE3A    LM    0,15,REGS           RESTORE P/P REGISTERS                89460014
         LPSW  PSW                 RETURN TO PROBLEM PROGRAM            89530014
         SPACE 1                                                        89600014
         DS    0F                                                       89670014
MASIC    DC    X'000000F0'                                              89740014
ERRXIT   DC    A(ENTRY2)                                                89810014
TCBPTER  DC    A(IEATCBQ)          ZERO IF TESTRAN NOT IN SYSTEM        89880014
         DC    200X'00'           PATCH AREA                            89950014
         SPACE 1                                                        90020014
R0       EQU   0                                                        90090014
R1       EQU   1                                                        90160014
R2       EQU   2                                                        90230014
R3       EQU   3                                                        90300014
R4       EQU   4                                                        90370014
R5       EQU   5                                                        90440014
R6       EQU   6                                                        90510014
R7       EQU   7                                                        90580014
R8       EQU   8                                                        90650014
R9       EQU   9                                                        90720014
R10      EQU   10                                                       90790014
R11      EQU   11                                                       90860014
R12      EQU   12                                                       90930014
R13      EQU   13                                                       91000014
R14      EQU   14                                                       91070014
R15      EQU   15                                                       91140014
AREA   EQU     DOUBWD                                                   91210014
MS       EQU   S1                                                       91280014
PSW      EQU   40                                                       91350014
CHX4     EQU   CHD4                                                     91420014
C8FD0    EQU   DIVSX4                                                   91490014
OP1A     EQU   DIVSX1                                                   91560014
SUBT     EQU   DIVSX1                                                   91630014
MINU     EQU   DIVSX2                                                   91700014
DECDD1   EQU   DECDD                                                    91770014
CHX5     EQU   CHD5                                                     91840014
CHX6     EQU   CHD6                                                     91910014
OP1WKA2  EQU   DIVSX1                                                   91980014
OP2WKA2  EQU   DIVSX2                                                   92050014
SUMS     EQU   DIVSX4                                                   92120014
WKAREA   EQU   QUOT                                                     92190014
OP2WKA1  EQU   DOUBWD                                                   92260014
C16X0    EQU   DIVSX4                                                   92330014
CHX7     EQU   CHD7                                                     92400014
         SPACE                                                          92470014
         DS    0D                                                       92540014
MASK17   DC    XL4'00FFFFFF'                                            92610014
MOVE1    MVC   0(1,R6),0(R3)                                            92680014
MOVE2A   MVC   0(1,R2),0(R7)                                            92750014
MOVE     MVC   0(1,R3),0(R6)                                            92820014
         DS    F                                                        92890014
CHX11    DC    X'000B'                                                  92960014
CHX10    DC    X'000A'                                                  93030014
CHX800   DC    X'00FFF800'                                              93100014
ENDIND   DC    X'00'                                                    93170014
         END                                                            93240014
