         TITLE 'IEE3803D  HIERARCHY PARAMETER SCAN ROUTINE'             00300019
IEE3803D CSECT                                                          00600019
* 038000-039000,044000-045000,049000-062000,444000,540000,        I283  00800019
* 589000-591000,690000-690600,768000,840000                        I283 01000019
* C152000-155000,C370000,C514000,C595000,C628000                 A40890 01050021
*********************************************************************** 01200019
* TITLE- IEE3803D   HIERARCHY PARAMETER SCAN MODULE                   * 01300019
*                                                                     * 01400019
* FUNCTION- IEE3803D GETS CONTROL FOR START AND MOUNT COMMANDS AND    * 01480019
*        SCANS THE COMMAND OPERAND FOR THE HIERARCHY PARAMETER.       * 01560019
*        IF THE COMMAND IS VALID, IT SETS CSCB BITS INDICATING THE    * 01640019
*        DESIRED HIERARCHY AND IF A DEFAULT VALUE FOR THE HIERARCHY   * 01720019
*        MUST BE USED.                                                * 01800019
*                                                                     * 01900019
* ENTRY POINT- IEE3803D FROM CSCB CREATION MODULE,IEE0803D.           * 02000019
*                                                                     * 02100019
* ATTRIBUTES- REENTRANT, SVC TRANSIENT, READ-ONLY, SELF-RELOCATING    * 02200019
*                                                                     * 02300019
* APPLICABILITY- MVT                                                  * 02400019
*                                                                     * 02500019
* EXTERNAL REFERENCES-                                                * 02600019
*        EXTENDED SAVE AREA (IEEXSA)                                  * 02700019
*        CSCB (IEECHAIN) BIT CHHIAR(HIERARCHY),BIT CHDEF(DEFAULT)     * 02800019
*        CVT (CVT)                                                    * 02900019
*        MASTER RESIDENT CORE (IEEBASEA)                              * 03000019
*        MGCR (SVC 34)                                                * 03050019
*                                                                     * 03100019
* EXITS(NORMAL)- BR 14                                                * 03200019
*                                                                     * 03300019
* EXITS(ERROR)-XCTL TO MSG MODULE IEE0503D AFTER CSCB HAS BEEN DELETED* 03360019
*        FROM THE CHAIN.                                              * 03420019
*    MESSAGES-                                                        * 03500019
*        'IEE306I START   INVALID NUMERICS'                           * 03600019
*              WHEN H= IS SPECIFIED AS SOMETHING OTHER THAN 0 OR 1    * 03700019
*              IN A SYSTEM THAT HAS HIERARCHY SUPPORT             I283* 03760019
*        'IEE026I HIARCHY NOT SUPPORTED'                          I283* 03820019
*              WHEN 'H=' IS SPECIFIED IN A SYSTEM THAT DOES NOT   I283* 03880019
*              HAVE HIERARCHY SUPPORT.                            I283* 03940019
*                                                                     * 04000019
* INPUT- REGISTER 2 POINTS TO XSA                                     * 04100019
*        REGISTER 1 POINTS TO THE CSCB                                * 04200019
*                                                                     * 04300019
* OUTPUT- IN SYSTEMS WHICH HAVE BEEN SYSGENED FOR HIERARCHY       I283* 04306019
*        SUPPORT(HIARCHY=INCLUDE), THE FOLLOWING IS TRUE-         I283* 04312019
*                                                                 I283* 04318019
*        IF H=0 IS SPECIFIED, THE HIERARCHY BIT(CHHIAR) IS SET TO I283* 04324019
*        0 AND THE DEFAULT BIT(CHDEF) IS SET TO 0 BECAUSE THE     I283* 04330019
*        DEFAULT VALUE IS NOT TO BE USED.                         I283* 04336019
*                                                                 I283* 04342019
*        AS A RESULT, THE SYSTEM TASK CONTROL ROUTINES(L-SHAPED   I283* 04348019
*        PROGRAM) WILL RUN IN H0 AND THE FIRST PART OF THE INIT-  I283* 04354019
*        IATOR WILL RUN IN H0.                                    I283* 04360019
*        (THE SECOND PART OF THE INITIATOR WILL ALWAYS RUN IN     I283* 04366019
*        THE HEIRARCHY SPECIFIED BY THE PROBLEM PROGRAM).         I283* 04372019
*                     ***********************                     I283* 04378019
*        IF H=1 IS SPECIFIED, CHHIAR IS SET TO 1 AND CHDEF IS SET I283* 04384019
*        TO 0 BECAUSE THE DEFAULT VALUE IS NOT TO BE USED.        I283* 04390019
*                                                                 I283* 04396019
*        AS A RESULT, THE SYSTEM TASK CONTROL ROUTINES WILL RUN   I283* 04402019
*        IN H1 AND THE FIRST PART OF THE INITIATOR WILL RUN IN H1 I283* 04408019
*                     ***********************                     I283* 04414019
*        IF NO HIERARCHY PARAMETER IS SPECIFIED,CHHIAR IS SET     I283* 04420019
*        TO 0(THE DEFAULT VALUE), AND CHDEF IS SET TO 1 BECAUSE   I283* 04426019
*        THE DEFAULT VALUE IS TO BE USED.                         I283* 04432019
*                                                                 I283* 04438019
*        AS A RESULT, THE SYSTEM TASK CONTROL ROUTINES WILL RUN   I283* 04444019
*        IN H0, BUT SINCE NO OVERRIDING VALUE IS SPECIFIED FROM   I283* 04450019
*        THE CONSOLE, BOTH PARTS OF THE INITIATOR WILL RUN IN THE I283* 04456019
*        HIERARCHY SPECIFIED BY THE PROBLEM PROGRAM.              I283* 04462019
*                     ***********************                     I283* 04468019
*        IN SYSTEMS WHICH DO NOT HAVE HIERARCHY SUPPORT, COMMANDS I283* 04474019
*        CONTAINING THE HIERARCHY PARAMETER WILL BE REJECTED.     I283* 04480019
*                     ***********************                     I283* 04486019
*        FOR VALID COMMANDS WITH NO HIERARCHY PARAMETER, CHHIAR   I283* 04492019
*        IS SET TO 0(DEFAULT VALUE) AND CHDEF IS SET TO 1(DEFAULT I283* 04498019
*        INDICATED). SINCE HIERARCHIES DO NOT EXIST IN THIS CASE, I283* 04504019
*        THE SYSTEM TASK CONTROL ROUTINES WILL RUN AS USUAL IN    I283* 04510019
*        PROCESSOR STORAGE, AND BOTH PARTS OF THE INITIATOR WILL  I283* 04516019
*        RUN ACCORDING TO THE PROBLEM PROGRAM'S SPECIFICATIONS.   I283* 04522019
*                                                                 I283* 04528019
*        THE HIERARCHY PARAMETER IS REMOVED FROM THE COMMAND      I283* 04534019
*        BUFFER IN THE CSCB FOR ALL VALID COMMANDS.               I283* 04540019
*                                                                 I283* 04546019
*        THE CSCB FOR EACH INVALID COMMAND IS DELETED FROM THE    I283* 04552019
*        CHAIN AND AN ERROR MESSAGE IS SET UP IN THE XSA.         I283* 04558019
*                                                                     * 04600019
* OPERATION-                                                          * 04700019
*        GETS CONTROL FOR START AND MOUNT COMMANDS.                   * 04800019
*        SCANS THE COMMAND OPERAND FIELD FOR 'H=' AS THE FIRST    I283* 04840019
*        PARAMETER.                                               I283* 04880019
*                                                                 I283* 04920019
*        IF 'H=' IS NOT THE FIRST PARAMETER, THE OPERAND FIELD IS I283* 04960019
*        SCANNED FOR A COMMA(NEXT PARAM), OR A BLANK(END OF       I283* 05000019
*        COMMAND).                                                I283* 05040019
*                                                                 I283* 05080019
*        WHEN A COMMA IS FOUND, THE NEXT TWO CHARACTERS ARE       I283* 05120019
*        CHECKED FOR 'H='.                                        I283* 05160019
*                                                                 I283* 05200019
*        IF NO 'H=' IS FOUND AFTER THE COMMA, THE SCAN CONTINUES  I283* 05240019
*        TO THE NEXT COMMA.                                       I283* 05280019
*                                                                 I283* 05320019
*        IF 'H=' IS FOUND, CVT BIT 'CVTOPTA' IS CHECKED TO SEE    I283* 05360019
*        IF THE SYSTEM HAS BEEN SYSGENED WITH HIERARCHY SUPPORT.  I283* 05400019
*                                                                 I283* 05440019
*        IF THERE IS NO HIERARCHY SUPPORT,THE COMMAND TERMINATES. I283* 05480019
*                                                                 I283* 05520019
*        IF THERE IS HIERARCHY SUPPORT, TESTS ARE MADE TO SEE     I283* 05560019
*        THAT THE NUMBER FOLLOWING THE 'H=' IS NOT MORE THAN ONE  I283* 05600019
*        DIGIT, AND IS EITHER 0 OR 1.                             I283* 05640019
*        IF THESE CONDITIONS ARE MET-                             I283* 05680019
*                                                                 I283* 05720019
*              H=0 SPECIFIED = CHDEF=0                            I283* 05760019
*                              CHHIAR=0                           I283* 05800019
*              H=1 SPECIFIED = CHDEF=0                            I283* 05840019
*                              CHHIAR=1                           I283* 05880019
*              NOTHING SPECIFIED = CHDEF=1                        I283* 05920019
*                                  CHHIAR=0                       I283* 05960019
*                                                                 I283* 06000019
*        WHEN THE CSCB BITS HAVE BEEN SET, THE 'H= ,' PARAMETER IS RE-* 06300019
*              MOVED FROM THE COMMAND OPERAND FIELD IN THE CSCB.      * 06400019
*              IF IT IS THE LAST PARAMETER, THE END OF THE COMMAND IS * 06500019
*              BLANKED OUT.                                           * 06600019
*              IF IT IS EMBEDDED, THE REST OF THE PARAMETERS ARE      * 06700019
*              SHIFTED OVER, AND THE END GARBAGE IS BLANKED OUT.      * 06800019
*        THE ASSIGNMENT PENDING BIT IN THE CSCB IS SET ON.            * 06850019
*        THE MASTER WAIT/ATTACH ROUTINE IS POSTED.                    * 06900019
*        IF AN ERROR CONDITION IS DETECTED, THE CSCB DECHAIN AND FREE * 06920019
*              CORE BITS ARE TURNED ON AND THE MGCR MACRO IS ISSUED TO* 06940019
*              DELETE THE COMMAND'S CSCB FROM THE CHAIN. THEN AN ERROR* 06960019
*              MESSAGE IS ISSUED TO THE CONSOLE.                      * 06980019
*                                                                     * 07000019
* NOTES- THE 'H=' PARAMETER CAN OCCUR ANYWHWRE IN THE COMMAND OPERAND * 07100019
*        SPECIFYING H=0 AND LETTING THE COMMAND DEFAULT TO H0     I283* 07800019
*        DIFFER BECAUSE OF THE BIT VALUES THAT MUST BE PASSED TO  I283* 08500019
*        THE INITIATOR.(SEE 'OUTPUT' ABOVE)                       I283* 09200019
*********************************************************************** 10200019
           EJECT                                                        10500019
*    EQUATES                                                            10800019
K0       EQU   0                   0 CONSTANT                           11400019
K1       EQU   1                   1 CONSTANT                           12000019
K2       EQU   2                   2 CONSTANT                           12600019
K3       EQU   3                   3 CONSTANT                           12900019
K4       EQU   4                   4 CONSTANT                           13200019
K6       EQU   6                   6 CONSTANT                           13800019
K8       EQU   8                   8 CONSTANT                           14100019
K26      EQU   26                  26 CONSTANT                          15000019
BLANK    EQU   C' '                BLANK CHARACTER                      15020019
ZERO     EQU   C'0'                CHARACTER 0 (EBCDIC)                 15040019
ONE      EQU   C'1'                CHARACTER 1 (EBCDIC)                 15060019
COMMA    EQU   C','                CHARACTER COMMA (EBCDIC)             15080019
*********************************************************************** 15100019
MASK1    EQU   B'00000011'         MASK FOR HIER/DEFAULT BITS    A40890 15200021
MASK2    EQU   B'11111101'         *                             A40890 15300021
MASK3    EQU   B'11111110'         *                             A40890 15400021
MASK4    EQU   B'11111100'         *                             A40890 15500021
HEX04    EQU   X'04'               USED TO TEST FOR HIAR SUPPORT        15600019
*********************************************************************** 15800019
* REGISTER ASSIGNMENTS                                                  16300019
R1       EQU   1                   POINTER TO CSCB                      16800019
R2       EQU   2                   XSA BASE                             17400019
R3       EQU   3                   CVT BASE                             18000019
R4       EQU   4                   WORK REGISTER                        18600019
R5       EQU   5                   ERROR CODE                           19200019
R6       EQU   6                   CHARACTER COUNTER                    19800019
R7       EQU   7                   POINTER TO CURR LIST POSITION        20400019
R8       EQU   8                                                        21000019
R9       EQU   9                                                        21600019
R10      EQU   10                  MASTER RESIDENT CORE BASE            22200019
R11      EQU   11                  WORK REG                             22800019
R12      EQU   12                  PGM BASE                             23400019
R13      EQU   13                                                       24000019
R14      EQU   14                                                       24600019
R15      EQU   15                  XCTL REG                             25200019
*********************************************************************** 25800019
*   ESTABLISH PROGRAM ADDRESSABILITY                                  * 26400019
*   BRANCH AROUND MODULE IDENTIFIER                                   * 27000019
*   ESTABLISH ADDRESSABILITY TO XSA, CSCB, AND CVT.                   * 27600019
*   INITIALIZE HIERARCHY AND DEFAULT BITS IN CSCB TO 1                * 28200019
*********************************************************************** 29400019
         BALR  R12,K0              ESTABLISH PROGRAM ADDRESSABILITY     30000019
         USING *,R12                                                    30600019
         B     BRANCH              BRANCH AROUND MODULE ID              31200019
         DC    X'EEEE'                         ..                       31800019
         DC    CL8'IEE3803D'                   ..                       32400019
         DC    CL6'REL019'                     ..                       33000019
         DC    X'EEEE'                         ..                       33600019
BRANCH   EQU   *                                                        34200019
         USING XSA,R2              XSA BASE                             34400019
         USING DCSCB,R1            BASE FOR CSCB                        34600019
         USING CVT,R3              ESTABLISH ADDRESSABILITY             34800019
         L     R3,CVTPTR           TO CVT                               35000019
         OI    CHTYPE,MASK1        INIT HIER/DEFAULT BITS TO 1   A40890 37000021
         LA    R7,CHBUF            LOAD PTR TO COMMAND OPERAND FIELD    42900019
*********************************************************************** 42950019
* SCAN THE COMMAND OPERAND FIELD FOR 'H='. IT CAN BE THE FIRST PARAM, * 43000019
* OR IF IT IS EMBEDDED, IT MUST BE PRECEDED BY A COMMA. A BLANK SIG-  * 43050019
* NIFIES THE END OF THE COMMAND.                                      * 43100019
*********************************************************************** 43150019
CHK2CHAR EQU   *                                                        43200019
         CLC   K0(K2,R7),HEQUALS   DO 2 CHARS= 'H=' FOR HIAR PARAM I283 43400019
         BE    CHKHIAR             IF H= FOUND, CHECK HIAR SUPPORT I283 43600019
CHKCOMM  EQU   *                                                        43800019
         CLI   K0(R7),COMMA        IS CURRENT CHAR A COMMA              44000019
         BNE   CHKBLNK             NO, GO TO CHECK FOR BLANK            44200019
         LA    R7,K1(R7)           YES,POINT TO CHAR AFTER COMMA        44400019
         B     CHK2CHAR            GO TO CHECK FOR 'H='                 44600019
CHKBLNK  EQU   *                                                        44800019
         CLI   K0(R7),BLANK        HAS END OF COMMAND BEEN REACHED      45000019
         BE    DEFAULT             IF END OF BUFF,SET DEFAULT BIT       45600019
         LA    R7,K1(R7)           INCREMENT TO POINT TO NEXT CHAR      46200019
         B     CHKCOMM             REPEAT SCAN FOR COMMA BEFORE 'H='    46800019
*********************************************************************** 47400019
* THE DEFAULT BIT IS SET TO 1 IF 'H=' IS NOT SPECIFIED. IN THIS CASE, * 48200019
* THE DEFAULT HIERARCHY (H0) IS USED,                                 * 49000019
*********************************************************************** 49800019
DEFAULT  EQU   *                                                        50400019
         NI    CHTYPE,MASK2        SET HIER BIT=0,DEFAULT BIT=1  A40890 51400021
         B     POSTMS              GO TO POST MAST SCHED                53400019
*********************************************************************** 54600019
* THE 'H=' PARAM IS ONLY VALID IN SYSTEMS WITH HIERARCHY SUPPORT   I283 54700019
* SINCE THE HIERARCHY CAN ONLY BE 1 OR 0, ONLY 1 DIGIT IS VALID AFTER * 54800019
* THE 'H='.                                                           * 55000019
*********************************************************************** 55200019
CHKHIAR  EQU   *                                                   I283 55280019
         TM    CVTOPTA,HEX04       HAS HIERARCHY BEEN SYSGENED     I283 55360019
         LA    R5,K26              PRESET ERROR CODE               I283 55440019
         BZ    SETERR              NO, HIARCHY NOT SUPPORTED       I283 55520019
         CLI   K3(R7),BLANK        IS THERE A BLANK AFTER PARAM         55600019
         BE    TESTH1              YES, NUMB OF DIGITS IS VALID         56000019
         CLI   K3(R7),COMMA        NO, IS CHAR A COMMA                  56400019
         BNE   NUMERR              NO, INVALID NUMERICS ERROR           56800019
*********************************************************************** 56900019
* IF NEITHER 0 NOR 1 IS SPECIFIED, THE COMMAND IS INVALID. THE HIER-  * 57000019
* ARCHY BIT IS SET TO 0 OR 1, AND THE DEFAULT BIT IS SET TO 0 BECAUSE * 57100019
* THE DEFAULT VALUE IS NOT USED.                                      * 57200019
*********************************************************************** 57300019
TESTH1   EQU   *                                                        57600019
         CLI   K2(R7),ONE          IS IT HIERARCHY 1                    58200019
         BNE   TESTH0              NO, CHECK IF HEIRARCHY 0             58800019
         NI    CHTYPE,MASK3        SET HIER BIT=1,DEFAULT BIT=0  A40890 59500021
         B     SHRINK              GO TO COMPRESS COMMAND BUFFER        60000019
TESTH0   EQU   *                                                        60600019
         CLI   K2(R7),ZERO         IS IT HIERARCHY 0                    61200019
         BNE   NUMERR              NO, INVALID NUMERICS ERROR           62100019
         NI    CHTYPE,MASK4        SET HIER BIT=0,DEFAULT BIT=0  A40890 62800021
*********************************************************************** 63600019
* IF THERE IS A BLANK AFTER THE 'H= ,' THEN THIS IS THE LAST PARAM.   * 64400019
* BLANK OUT PRECEDING COMMA AND REST OF PARAM.                        * 65200019
*********************************************************************** 66000019
SHRINK   EQU   *                                                        66600019
         CLI   K3(R7),BLANK        IS THIS THE LAST PARAM               66800019
         BNE   SAVEPTR             NO, GO TO SET UP SHIFT               67000019
         BCTR  R7,K0               DECREMENT PTR TO POINT TO PRE-       67200019
*                                  CEDING COMMA                         67400019
         MVI   K0(R7),BLANK        PUT IN FIRST BLANK                   67600019
         MVC   K1(K3,R7),K0(R7)    BLANK OUT REST OF PARAM              67800019
         B     POSTMS              GO TO POST MASTER SCHED              68000019
*********************************************************************** 68040019
* BYPASS 'H= ,' AND INCREMENT COUNTER FOR EACH CHARACTER THAT FOLLOWS,* 68080019
* UNTIL A BLANK IS FOUND.                                             * 68120019
*********************************************************************** 68160019
SAVEPTR  EQU   *                                                        68200019
         SR    R6,R6               INITIALIZE COUNTER TO 0              68600019
         LA    R11,K4(R7)          GET POINTER TO NEXT PARAM            69120019
CHECKBL  EQU   *                                                        69200019
         CLI   K0(R11),BLANK       IS THIS CHAR BLANK(END OF COMMAND)   69400019
         BE    MOVEOUT             YES, GO TO MOVE OUT PARAM            69800019
         LA    R6,K1(R6)           NO,INCREMENT COUNTER FOR CURR CHAR   70200019
         LA    R11,K1(R11)         POINT TO NEXT CHAR                   70600019
         B     CHECKBL             CHECK CURR CHAR FOR BLANK            71000019
*********************************************************************** 71050019
* THE EXECUTE INSTRUCTION SHIFTS THE REST OF THE PARAMS + 1 BLANK,    * 71100019
* 4 BYTES TO THE LEFT TO OVERLAY THE 'H= ,' PARAM. THE GARBAGE AT THE * 71150019
* END OF THE COMMAND IS THEN BLANKED OUT. (CURRENT LIST POSITION +    * 71200019
* LENGTH OF PARAMS SHIFTED = PTR TO BLANK FOLLOWING SHIFTED PARAMS).  * 71250019
* THIS BLANK IS PROPAGATED THROUGHOUT THE END GARBAGE.                * 71300019
*********************************************************************** 71350019
MOVEOUT  EQU   *                                                        71400019
         EX    R6,SHIFT            PUT LENG OF PARAM+1 IN MVC INSTR     71800019
         AR    R7,R6               POINT TO PARAM TO BE SHIFTED         72200019
         MVC   K1(K3,R7),K0(R7)    PAD REST OF PARAM WITH BLANKS        72600019
*********************************************************************** 72800019
* SET PENDING BIT AND POST MASTER WAIT/ATTACH ROUTINE                 * 73000019
*********************************************************************** 73200019
POSTMS   EQU   *                                                        73500019
         L     R10,CVTMSER         PTR TO MASTER RESIDENT CORE          73800019
         OI    CHSTS,CHAP          SET ASSIGNMENT PENDING BIT ON        74100019
         USING BASE,R10            ESTABLISH ADDRESSABILITY             74400019
         POST  BALAD               POST MASTER SCHEDULER                75600019
         BR    R14                 RETURN                               75700019
*********************************************************************** 75720019
* ERROR EXIT PROCEDURE - CAUSE CSCB TO BE DELETED AND XCTL TO IEE0503D* 75740019
*********************************************************************** 75760019
NUMERR   EQU   *                                                        75800019
         LA    R5,K6               SET INVAL NUM ERROR CODE             75900019
         B     DELETE              GO TO DELETE CSCB FROM CHAIN         76000019
SETERR   EQU   *                                                        76200019
         MVC   XAV(K8),HIARCHY     PUT HIARCHY PREFIX IN XSA       I283 76500019
DELETE   EQU   *                                                        76900019
         OI    CHSTS,CHDL+CHFC     TURN ON CSCB DECHAIN AND             77000019
*                                  FREE CORE BITS                       77100019
         MGCR  (1),CHAIN           ISSUE SVC 34 TO DELETE CSCB          77200019
         SPACE 3                                                        77300019
SETERR1  EQU   *                                                        77400019
         STC   R5,XAE              PUT ERROR CODE IN XAE                78000019
         MVC   XAX(K8),MSGMOD      PUT IGC0503D IN XAX                  78600019
         SR    R15,R15             ZERO  OUT A REG                      79200019
         ST    R15,XAD             USE IT TO ZERO OUT DCB PTR IN LIST   79800019
         LA    R15,XAX             GET PTR TO XCTL MOD NAME IN LIST     80400019
         ST    R15,XAP             PUT PTR TO XCTL MOD NAME INTO LIST   81000019
         LR    R15,R2              PUT PTR TO LIST IN REG 15            81600019
         XCTL  SF=(E,(15))         ISSUE XCTL                           82200019
*********************************************************************** 82800019
         DS    0F                  ALIGN ON FULL WORD BOUNDARY          83400019
HIARCHY  DC    CL8'HIARCHY '       HIARCHY PREFIX FOR MESSAGE      I283 84000019
SHIFT    MVC   K0(K0,R7),K4(R7)                                         84600019
MSGMOD   DC    C'IGC0503D'         ERROR MSG MODULE                     85200019
HEQUALS  DC    C'H='               HIERARCHY PARAMETER                  85800019
         EJECT                                                          86480019
DXSA     DSECT                                                          86520019
         IEEXSA                                                         86560019
         EJECT                                                          86600019
DCSCB    DSECT                                                          86640019
         IEECHAIN                                                       86680019
         EJECT                                                          86720019
CVT      DSECT                                                          86760019
         CVT                                                            86800019
         EJECT                                                          86880019
         IEEBASEA                                                       86920019
         END                                                            87000019
XSA      DSECT                                                          87600019
         IEEXSA                                                         88200019
DCSCB    DSECT                                                          88800019
         IEECHAIN                                                       89400019
CVT      DSECT                                                          90000019
         CVT                                                            90600019
         IEEBASEA                                                       91200019
