         TITLE 'IEE50110 DISPLAY ACTIVE MESSAGE PROCESSOR'              00050021
*********************************************************************** 00100021
*  NAME        .IEE50110                                                00150021
*                                                                       00200021
*  FUNCTION    .TO DISPLAY ON THE OPERATOR'S CONSOLE OR TERMINAL,       00250021
*               THOSE TASKS AND TIME SHARING REGIONS ACTIVE             00300021
*               WITHIN THE OPERATING SYSTEM - TASKS RESIDING ON THE     00350021
*               SUPERVISOR IN-CORE READY/WAIT QUEUE;                    00400021
*               REGIONS MARKED AS ACTIVE IN THE RCB ARRAY               00450021
*                                                                       00500021
*  BASIC FLOW  .THE TYPE OF COMMAND IS EXAMINED AND IF IT'S A MONITOR   00750021
*               ACTIVE, THE COMMAND WILL BE ROUTED VIA MSGTYP=ACTIVE,   00800021
*               IF IT'S NOT FROM A TERMINAL.  IF IT'S FROM A TERMINAL,  00850021
*               THE COMMAND IS OUTPUTED VIA TPUT.  IF IT'S A DISPLAY    00900021
*               ACTIVE, THE COMMAND IS ROUTED TO THE RECEIVING          00950021
*               CONSOLE AND ITS AREA ID IF ANY. THE MSGTYPE FLAGS       01000021
*               ARE REQUIRED ONLY ON THE TITLE (CONTROL) LINE.          01050021
*               THE LABEL LINE IS THEN MOVED TO THE BUFFER AND          01100021
*               CONTROL IS THEN PASSED TO A GENERALIZED MESSAGE         01150021
*               ROUTINE TO OUTPUT THE MESSAGE TO A CONSOLE OR A         01200021
*               TERMINAL.  NOTE: A MONITOR ACTIVE IS ILLEGAL TO A       01250021
*               NON-CRT CONSOLE.  IT IS CONVERTED TO A DISPLAY ACTIVE   01300021
*               IN SVC 34.                                              01350021
*                                                                       01400021
*  EXIT        .VIA BR 14 TO MASTER TASK                                01450021
*                                                                       01500021
*  INPUT       .REGISTER 2 CONTAINS A POINTER TO THE WORK AREA          01550021
*               INITIALIZED BY IEEVDSP1                                 01600021
*               REGISTER 14 CONTAINS THE RETURN ADDRESS                 01650021
*                                                                       01700021
*  OUTPUT      .CONSOLE/TERMINAL MESSAGE                                01750021
*      IEE102I HH.MM.SS ACTIVE DISPLAY                            M0716 01800021
*      STRADDR ENDADDR SQA   R  SUBT  NAME1     NAME2     NAME3         01850021
*      REGION  REGION                 JOBNAME   STEPNAME  MODIFIER      01900021
*      BEGIN   END                                                      01950021
* MASTER                              MASTER SCHEDULER                  02000021
* REGION                                                                02050021
* TSO                  LSQS     ACT   TIME SHARING                      02100021
* REGION                        USERS                                   02150021
*                                                                       02200021
*  MAPPINGS   .IHBABCTL - ABEND MACRO FOR DSECT MAPPINGS OF             02250021
*                         CVT, TCB, RB                                  02300021
*             .IEFTIOT1 - TIOT MAPPING                                  02350021
*             .IEECHAIN - CSCB MAPPING                                  02400021
*             .IEEBASEA - MASTER SCHEDULER AREA                         02450021
*             .IKJTSCVT - TIME SHARING CVT                              02500021
*             .IKJRCB   - REGION CONTROL BLOCK                          02550021
*                                                                       02600021
*********************************************************************** 02650021
*                                                                       02700021
*              GENERAL REGISTER EQUATES                                 02750021
*                                                                       02800021
*********************************************************************** 02850021
R0       EQU   0                                                        02900021
R1       EQU   1                                                        02950021
R2       EQU   2                                                        03000021
R3       EQU   3                                                        03050021
R4       EQU   4                                                        03100021
R5       EQU   5                                                        03150021
R6       EQU   6                                                        03200021
R7       EQU   7                                                        03250021
R8       EQU   8                                                        03300021
R9       EQU   9                                                        03350021
R10      EQU   10                                                       03400021
R11      EQU   11                                                       03450021
R12      EQU   12                                                       03500021
R13      EQU   13                                                       03550021
R14      EQU   14                                                       03600021
R15      EQU   15                                                       03650021
ECHARK   EQU   C'K'                                                     03750021
BLANK    EQU   C' '                                                     03850021
E0       EQU   0                                                        03900021
E1       EQU   1                                                        03950021
E2       EQU   2                                                        04000021
E3       EQU   3                                                        04050021
E4       EQU   4                                                        04100021
E5       EQU   5                                                        04150021
E6       EQU   6                                                        04200021
E7       EQU   7                                                        04210021
E8       EQU   8                                                        04250021
E9       EQU   9                                                        04260021
E10      EQU   10                                                       04300021
E16      EQU   16                                                       04350021
E21      EQU   21                                                       04360021
E24      EQU   24                                                       04370021
D7       EQU   7                                                  20030 04750021
         SPACE                                                          04950021
*********************************************************************** 05000021
         SPACE                                                          05050021
*********************************************************************** 05100021
*                                                                       05150021
*              MAPPINGS                                                 05200021
*                                                                       05250021
*********************************************************************** 05300021
UUCM     DSECT                                                          05350021
         IEECUCM                                                        05400021
         IEEBASEA                                                       05450021
CHN      DSECT                                                          05500021
         IEECHAIN                                                       05550021
TIOT     DSECT                                                          05600021
         IEFTIOT1                                                       05650021
         IHBABCTL                                                       05700021
         EJECT                                                          05750021
*********************************************************************** 05800021
*                                                                       05850021
*              DSECT MAPPING OF MODULE WORK AREA AND BUFFER             05900021
*                                                                       05950021
*********************************************************************** 06000021
WORKAREA DSECT                     MAPPING OF DISPLAY WORKAREA          06050021
* MESSAGE PORTION IS USED AS A REGISTER SAVE AREA BETWEEN IEEVDSP1      06100021
* AND IEE50110.                                                         06150021
DSTART   DS    0F                  START OF WORKAREA                    06200021
HDR      DS    4C                  WTO LENTH + MCS FLAGS                06250021
IDENT    DS    7C                  'IEE102I'                            06300021
SP1      DS    1C                  1 BLANK                              06350021
TIME     DS    8C                  TIME OF THIS DISPLAY OR MONITOR      06400021
SP2      DS    1C                  1 BLANK                              06450021
ACTDISP  DS    14C                 'ACTIVE DISPLAY'               M0716 06500021
CODES1   DS    8C                  MCS AND MLWTO FLAGS            M0770 06550021
AREAID   EQU   CODES1+E6           AREA ID IN MESSAGE                   06600021
WTO1     EQU   *                   END FIRST WTO                        06650021
PSEUDO   DS    2C                  BLANK AREA                     M0770 06660021
UNPKAREA DS    2C                  UNPACK AREA                          06700021
UNPKARA2 DS    2C                  SECOND AREA                          06750021
UNPKARA3 DS    2C                  THIRD AREA                           06800021
         ORG   IDENT                                                    06850021
STRADDR  DS    7C                  START ADDRESS OF TASK                06900021
SP3      DS    1C                  1 BLANK                              06950021
ENDADDR  DS    7C                  END ADDRESS OF TASK                  07000021
SP4      DS    1C                  1 BLANK                              07050021
SQA      DS    5C                  SUPERVISOR QUEUE AREA          M0770 07100021
SP       DS    1C                  1 BLANK                              07150021
R        DS    2C                  REGION OWNERSHIP                     07200021
SP6      DS    1C                  1 BLANK                              07250021
SUBT     DS    3C                  NUMBER OF SUBTASKS                   07300021
SP7      DS    3C                  3 BLANKS                             07350021
NAME1    DS    8C                  FIRST NAME                           07400021
SP8      DS    2C                  2 BLANKS                             07450021
NAME2    DS    8C                  SECOND NAME                          07500021
SP9      DS    2C                  2 BLANKS                             07550021
NAME3    DS    8C                  THIRD NAME                           07600021
CODES2   DS    4C                  MCS + MLWTO FLAGS                    07650021
* THIS IS PASSED FROM IEEVDSP1 TO IEE50110 SO CARE MUST BE TAKEN        07750021
* SO AS NOT TO DISTURB IT, I.E. THE NUMBER OF REGISTERS PASSED....      07800021
WTO2     EQU   *                   END 2ND WTO(LABEL LINE)              07850021
JOBNME   EQU   NAME1                                                    07900021
STEPNME  EQU   NAME2                                                    07950021
STEPMOD  EQU   NAME3                                                    08000021
SUBCNT   EQU   SUBT                                                     08050021
REGBEG   EQU   STRADDR                                                  08100021
REGEND   EQU   ENDADDR                                                  08150021
SUPVQ    EQU   SQA                                                M0770 08200021
OWN      EQU   R                                                        08250021
BADSPOFF EQU   X'FF'-BADSP                                              08300021
PACKAREA EQU   TIME+E3             UNPACK WORK AREA                     08350021
HOURS    EQU   TIME                HOUR SLOT                            08400021
PER1     EQU   TIME+E2             PERIOD                               08450021
MINUTES  EQU   TIME+E3             MINUTE SLOT                          08500021
PER2     EQU   TIME+E5             PERIOD                               08550021
SECONDS  EQU   TIME+E6             SECOND SLOT                          08600021
MNA      EQU   X'64'               MONITOR ACTIVE VERB CODE             08650021
SVCRTN   DS    1F                  RETURN ADDRESS FOR SVC               08700021
WTOEND   DS    0D                  DOUBLE WORD BOUNDARY ALIGNMENT       08750021
MSGID    DS    1F                  SAVE AREA FOR MLWTO MESSAGE ID       08800021
CONSID   DS    1C                  SAVE CONSOLE ID                      08850021
CVD      DS    1C                  SAVE AREA FOR VERB CODE              08900021
TJID     DS    2C                  SAVE AREA FOR TSO TJID               08950021
TMSTOR   EQU   MSGID               USED ONCE TO SAVE PACKED TIME OF DAY 09000021
TEMPAREA EQU   MSGID               TEMPORARY SAVE FOR CRT AREA ID       09060021
TSOWORK  DS    1F                  ADDR OF TSO W/A ADDR                 09100021
MSUBCNT  DS    1C                  MASTER SUBCOUNT                      09150021
RTRNADD  DS    3C                  RETURN ADDRESS                       09200021
MASTIOT  DS    1F                  MASTER TIOT ADDRESS                  09250021
MASTCB   DS    1F                  MASTER TCB ADDRESS                   09300021
ENTRYPNT DS    1F                  STARTING ADDRESS FOR ENTRIES         09350021
ENTRYNO  DS    2C                  NUMBER OF ENTRIES                    09400021
DISPLAYS DS    2C                  NUMBER OF DISPLAYS                   09450021
DUPLICAT DS    0F                  START OF DUPLICATE ENTRY TABLE       09500021
CORSIZE  EQU   1300                WORKAREA AND BUFFERS                 09550021
TSOENTRY DSECT                                                          09600021
         DS    0D                  BOUNDARY ALIGNMENT FOR ENTRY         09650021
TSOREGNM DS    1H                  REGION NUMBER                        09700021
TSONOUSR DS    1H                  NUMBER OF USERS IN TSO REGION        09750021
TSOLSQA  DS    1F                  AM'T OF LSQA FOR TSO REGION    M0770 09800021
TSOBGNAR DS    1F                  BEGINNING ADDR OF TSO REGION         09850021
TSOENDAR DS    1F                  ENDADDR OF TSO REGION                09900021
TSOEND   EQU   *                   END OF TSO ENTRY                     09950021
TSOMSECT DSECT                                                          10000021
TSNAME   EQU   NAME1               TIME SHARING                         10050021
TSREGNO  EQU   R                   REGION NUMBER                        10100021
TSBADDR  EQU   STRADDR             REGION BEGINNING ADDRESS             10150021
TSEADDR  EQU   ENDADDR             REGION END ADDRESS                   10200021
TSLSQA   EQU   SQA                 SIZE OF REGION'S LSQA          M0770 10250021
TSLSQAK  EQU   SQA+E4              K CHARACTER                    M0770 10300021
TSNOUSER EQU   SUBT                NUMBER USERS OF REGION               10350021
         EJECT                                                          10400021
IEE50110 CSECT                                                          10450021
* THIS IS A NEW MODULE FOR RELEASE 21 PROJECT #21002.                   10452021
* C 145500                                                       A49650 10456821
* A 150100-150200,150600                                          M1877 10461621
* C 018000,065000,198000-198500                                   M0716 10466421
* A 066600                                                        M0770 10471221
* C 065500,071000,082000,098000,102500-103000,203000-203500,      M0770 10476021
* C 131500-133000,144000,145500,,182500                           M0770 10480821
* A 178600                                                        M1550 10485621
* C 180500,182000,195000,195500                                   M1550 10490421
* D 108500-111000,111500-112000,120000-122000,189500-191000       M0149 10495221
         BALR  R12,0               ESTABLISH ADDRESSABILITY             10500021
         USING *,R12                                                    10550021
         USING WORKAREA,R13                                             10600021
         LR    R13,R2              GET POINTER TO ACTIVE TASK WORK AREA 10650021
         ST    R14,SVCRTN          SAVE RETURN ADDRESS                  10700021
         LM    R3,R11,WORKAREA     GET REGISTERS PASSED BY IEEVDSP1     10750021
         MVC   HDR(WTOTL),WTOT     MOVE IN TITLE (CONTROL) LINE         10800021
         IC    R9,TEMPAREA         GET CRT AREA ID                      11110021
         TIME  DEC                 GET TIME OF DAY                      11250021
         ST    R0,TMSTOR           SAVE PACKED TIME                     11300021
         UNPK  UNPKAREA(D7),TMSTOR(E4) UNPACK TIME OF DAY               11350021
         MVC   HOURS(E2),UNPKAREA  MOVE HOURS                           11400021
         MVC   MINUTES(E2),UNPKARA2 MOVE MINUTES INTO MESSAGE           11450021
         MVC   SECONDS(E2),UNPKARA3 MOVE IN SECONDS                     11500021
         SR    R0,R0               CLEAR REGISTER SO MLWTO DOESN'T     *11550021
                                        THINK THIS IS A CONTINUATION    11600021
         CLI   CVD,MNA             IS IT MONITOR ACTIVE?                11650021
         BE    WTOA                YES, GO WRITE MESSAGE                11700021
MOVEDA   EQU   *                                                        11750021
         MVC   HDR+E2(E2),WTODAMCS MOVE IN MCS FLAGS.                   11800021
         MVC   CODES1(WTO1-CODES1),WTODACDS MOVE IN MLWTO+RTE+DESC     *11850021
                                        CODES                           11860021
         STC   R9,AREAID           PUT AREA ID IN WTO                   11960021
         IC    R0,CONSID           GET RECEIVING CONSOLE ID             12250021
WTOA     EQU   *                                                        12300021
         BAL   R14,WTOF            GO ISSUE CONTROL LINE                12350021
         MVC   HDR(WTOLL),WTOLABEL MOVE IN LABEL LINE                   12400021
         BAL   R14,WTOB            GO ISSUE LABEL LINE                  12450021
         SR    R2,R2               CLEAR WORK REGISTER                  12500021
         L     R9,ENTRYPNT         START OF OUTPUT ENTRIES              12550021
         LA    R9,E24(R9)          BYPASS NAME FIELD FOR M.S.           12600021
         LR    R6,R10              GET NUMBER OF OUTPUT MESSAGES        12650021
         MVC   JOBNME(E16),MASTNME PUT MASTER NAME INTO OUTPUT BUFFER   12700021
         IC    R2,MSUBCNT          OBTAIN MASTER SUBTASK COUNT          12750021
FILLBUFF BAL   R14,CNVRTDEC        CONVERT COUNT FROM BINARY TO DECIMAL 12800021
         MVC   SUBCNT(E2),MASTIOT+E6 PUT CONVERTED COUNT INTO OUTPUT   *12850021
                                        BUFFER                          12860021
         SR    R7,R7               CLEAR REGISTER                       12900021
         IC    R7,E4(R9)           REGION COUNT FOR THIS ENTRY          12950021
         LTR   R7,R7               TEST FOR NO REGIONS                  13000021
         BNZ   BYPASS              IF AT LEAST ONE REGION, START       *13050021
                                        PROCESSING                      13060021
         LA    R7,E1               ALLOW FOR BCT ON FIRST PASS          13100021
BYPASS   L     R2,E4(R9)           SUPERVISOR QUEUE AREA          M0770 13150021
         BAL   R10,ADDRCNVT        GO TO SUBROUTINE TO CONVERT AND TO  *13200021
                                        MOVE REGION ADDRESSES AND SQA  *13250021
                                        SIZE TO MESSAGE BUFFER    M0770 13300021
         BAL   R14,MSGRTN          GO TO PUT MESSAGE TO CONSOLE/TERM    13350021
         LA    R9,E8(R9)           NEXT ENTRY OR NEXT REGION IN THIS    13400021
         LR    R2,R9                    ENTRY                           13450021
         BCT   R7,RGNCNVRT         DECREMENT COUNT AND CONVERT NEXT    *13500021
                                        REGION                          13510021
         MVC   JOBNME(E8),E0(R9)   FILL BUFFER WITH 1ST 8 BYTES OF TIOT 13550021
         MVC   STEPNME(E8),E8(R9)  FILL BUFFER WITH 2ND 8 BYTES OF TIOT 13600021
         MVC   STEPMOD(E8),E16(R9) FILL BUFFER WITH 3RD 8 BYTES OF TIOT 13650021
         LA    R9,E24(R9)          POINT TO SUBTASK COUNT OF NEXT ENTRY 13700021
         L     R2,E0(R9)           SET UP COUNT FOR CONVERT TO DECIMAL  13750021
         BCT   R6,FILLBUFF         PROCESS NEXT ENTRY                   13800021
         LTR   R3,R3               ANY TIME-SHARING MESSAGES?           13850021
         BNZ   TSOMSG              YES, GO FORMAT MESSAGES              13900021
FREEWA   EQU   *                                                        13950021
         OC    TJID(E2),TJID       IS COMMAND FROM TERMINAL?            14000021
         BNE   NOLWTO              YES, NO NEED FOR LAST WTO            14050021
         MVC   HDR(WTOEL),WTOENDIT MOVE IN END DISPLAY LINE             14100021
         BAL   R14,WTOB            GO ISSUE WTO TO END DISPLAY          14150021
NOLWTO   EQU   *                                                        14200021
         L     R14,SVCRTN          GET RETURN ADDRESS                   14250021
         BR    R14                 RETURN TO CALLER (IEEVDSP1)          14300021
ADDRCNVT EQU   *                                                        14350021
         L     R2,E4(R9)           SUPERVISOR QUEUE AREA          M0770 14400021
         LA    R2,E0(R2)           CLEAR REGION COUNT                   14450021
         BAL   R14,CNVRTDEC        CONVERT SPACE TO DECIMAL             14500021
         MVC   SUPVQ(E5),MASTIOT+E3 PUT AREA IN BUFFER           A49650 14550021
         LA    R9,E8(R9)           UPDATE POINTER TO START OF REGION    14600021
         LR    R2,R9               ADDRESS IN OUTPUT ENTRY              14650021
RGNCNVRT EQU   *                                                        14700021
         L     R2,E0(E0,R2)        GET ADDRESS IN REGISTER              14750021
         LA    R2,E0(E0,R2)        CLEAR HIGH ORDER BYTE                14800021
         SRL   R2,E10              DIVIDE BY 1024                       14850021
         BAL   R14,CNVRTDEC        CONVERT REGION START TO DECIMAL      14900021
         MVC   REGBEG(E5),MASTIOT+E3 PUT IT IN OUTPUT BUFFER            14950021
         MVI   REGBEG+E5,ECHARK    MOVE IN 'K'                          15000021
         LTR   R6,R6               NOW PROCESSING TSO OUTPUT?     M1877 15010021
         BZ    AROUND              YES, AVOID FOLLOWING OVERLAY   M1877 15020021
         MVC   OWN(E1),E0(R9)      DISPLAY REGION OWNERSHIP             15050021
AROUND   EQU   *                                                  M1877 15060021
         LA    R2,E4(E0,R9)        POINTER TO REGION END ADDRESS        15100021
         L     R2,E0(E0,R2)        GET ADDRESS IN REGISTER              15150021
         LA    R2,E0(E0,R2)        CLEAR HIGH ORDER BYTE                15200021
         SRL   R2,E10              DIVIDE BY 1024                       15250021
         BAL   R14,CNVRTDEC        CONVERT REGION END TO DECIMAL        15300021
         MVC   REGEND(E5),MASTIOT+E3 PUT IT IN OUTPUT BUFFER            15350021
         MVI   REGEND+E5,ECHARK    MOVE IN 'K'                          15400021
         BR    R10                 RETURN TO MAIN LINE CODE             15450021
CNVRTDEC XC    MASTIOT(E24),MASTIOT ZERO WORK SPACE                     15500021
         CVD   R2,MASTIOT          CONVERT INTO AN AREA                 15550021
         MVC   MASTIOT(E4),MASTIOT+E4 SET UP FOR UNPACK                 15600021
         UNPK  MASTIOT(E8),MASTIOT(E4) UNPACK IT ALL                    15650021
         OI    MASTIOT+E7,X'F0'    ADJUST SIGN BIT                      15700021
         BR    R14                 RETURN TO CALLING ROUTINE            15750021
MSGRTN   EQU   *                                                        15800021
         LA    R1,CODES2           GET TO END OF MESSAGE                15850021
COMP     EQU   *                                                        15900021
         BCTR  R1,E0               GET TO LAST CHARACTER                15950021
         CLI   E0(R1),BLANK        IS THIS A BLANK?                     16000021
         BE    COMP                YES, DECREMENT AND RE-CHECK          16050021
         LA    R1,E1(R1)           ADD ONE TO GET PROPER LENGTH         16100021
         MVC   E0(WTO2-CODES2,R1),WTODC MOVE IN MCS+MLWTO CODES         16150021
         SR    R1,R13              GET THE WTO LENGTH                   16200021
         STH   R1,HDR              STORE NEW LENGTH                     16250021
         MVC   HDR+E2(E2),WTODMCS  MOVE IN MCSFLAGS                     16300021
WTOB     EQU   *                                                        16350021
         L     R0,MSGID            GET MESSAGE ID FOR MLWTO             16400021
WTOF     EQU   *                                                        16450021
         CLI   CVD,MNA             IS IT MONITOR ACTIVE?                16500021
         BE    WTOE                YES, GO ISSUE MESSAGE                16550021
         IC    R0,CONSID           GET CONSOLE ID                       16600021
WTOC     EQU   *                                                        16650021
         OC    TJID(E2),TJID       IS COMMAND FROM TERMINAL?            16700021
         BNZ   TPUTMSG             YES, GO ISSUE TPUT MACRO             16750021
WTOE     EQU   *                                                        16800021
         LA    R1,HDR              OUTPUT BUFFER ADDRESS                16850021
         WTO   MF=(E,(1))          WRITE OUT ENTRY TO CONSOLE           16900021
         SLL   R1,E8               SHIFT MESSAGE ID TO PROPER POSITION  16950021
         ST    R1,MSGID            SAVE MLWTO MESSAGE ID                17000021
WBUF     EQU   *                                                        17050021
         MVI   HDR,BLANK           SET UP CLEAR                         17100021
         MVC   HDR+E1(WTO2-HDR-E1),HDR CLEAR WTO BUFFER                 17150021
         BR    R14                 RETURN TO PROCESS NEXT ENTRY         17200021
TPUTMSG  EQU   *                                                        17250021
         LH    R0,HDR              GET MESSAGE LENGTH                   17300021
         SH    R0,FOUR             SUBTRACT LENGTH+MCSFLAGS             17350021
         LA    R1,HDR+E4           POINT TO MESSAGE TEXT                17400021
         LH    R15,TJID            GET TERMINAL ID                      17450021
         SLL   R15,E16             MOVE TJID TO HIGH-ORDER HALFWORD     17500021
         OR    R0,R15              SET UP PARAMETERS FOR TPUT           17550021
         TPUT  (R1),(R0),R         WRITE OUT ENTRY TO TERMINAL          17600021
         B     WBUF                CLEAR BUFFER AREA                    17650021
TSOMSG   EQU   *                                                        17700021
         L     R11,TSOWORK         GET ADDRESS OF TSO WORKAREA SECTION  17750021
         USING TSOENTRY,R11                                             17800021
TSOMSG1  EQU   *                                                        17850021
         BAL   R14,WBUF            CLEAR BUFFER AREA              M1550 17860021
         MVC   TSNAME(NAMELEN),TIMESHAR MOVE TSO IDENTIFIER TO MESSAGE  17900021
         LH    R2,TSOREGNM         CONVERT REGION NUMBER TO DECIMAL     17950021
         BAL   R14,CNVRTDEC                                             18000021
         MVC   TSREGNO(E2),E94(R13) MOVE TO MESSAGE AREA          M1550 18050021
         LH    R2,TSONOUSR         CONVERT NUMBER OF USERS IN REGION    18100021
         BAL   R14,CNVRTDEC             TO DECIMAL                      18150021
         MVC   TSNOUSER(E3),E93(R13) MOVE TO MESSAGE AREA         M1550 18200021
         MVI   TSLSQAK,C'K'        MOVE 'K' TO LSQA COLUMN        M0770 18250021
         LR    R9,R11              INPUT TO SUBROUTINE                  18300021
         BAL   R10,ADDRCNVT        GO TO SUBROUTINE TO CONVERT         *18350021
                                        REGION ADDRESS AND LSQS        *18400021
                                        SIZE AND MOVE TO MSGAREA        18450021
         LR    R1,R13              INPUT TO MESSAGE ROUTINE             18500021
         BAL   R14,MSGRTN          GO TO WRITE MESSAGE TO ISSUING      *18550021
                                        CONSOLE/TERMINAL OPERATOR       18600021
         BCT   R3,TSOMSG2          CONTINUE LOOPING UNTIL ALL          *18650021
                                        MESSAGES ARE WRITTEN            18700021
         B     FREEWA              ALL MESSAGES WRITTEN - RETURN        18750021
TSOMSG2  EQU   *                                                        18800021
         LA    R11,TSOEND-TSOENTRY(R11) INCREMENT TO NEXT ENTRY         18850021
         B     TSOMSG1             LOOP                                 18900021
         EJECT                                                          19150021
MASTNME  DC    C'MASTER SCHEDULER' NAME FOR OUTPUT                      19200021
TIMESHAR DC    C'TIME SHARING'     IDENTIFICATION FOR TSO JOBS          19250021
FOUR     DC    H'4'                FOUR                                 19300021
ENTRYSZE EQU   40                  SIZE OF EACH ENTRY IN WORKAREA       19350021
IDLEN    EQU   7                   LENGTH OF MESSAGE ID                 19400021
NAMELEN  EQU   12                  LENGTH OF TIME SHARING ID            19450021
*                    OFFSETS:                                           19460021
E94      EQU   94                  INTO W/A FOR CONVERTED NUMBER  M1550 19500021
E93      EQU   93                  INTO W/A FOR CONVERTED NUMBER  M1550 19550021
PQESIZE  EQU   20                  INTO PQE FOR SIZE OF REGION          19600021
PQEREGN  EQU   24                  INTO PQE FOR START REGION ADDRESS    19650021
WTOT     WTO   ('IEE102I HH.MM.SS ACTIVE DISPLAY',C),MF=L,DESC=(5,8,9),*19800021
               MCSFLAG=(RESP),MSGTYP=ACTIVE                       M0716 19850021
WTOT3    EQU   WTOT+E21            ACTIVE TASKS IN BUFFER               19950021
WTOTL    EQU   *-WTOT                                                   20000021
WTOTL2   EQU   *-WTOT3             LENGTH OF MESSAGE SECOND PART        20050021
WTOTSL   EQU   WTOTL-E9-E10        LENGTH WITHOUT TIME                  20100021
WTODA    WTO   (' ',C),MF=L,MCSFLAG=(REG0,RESP),DESC=(5,8,9)            20150021
WTODAMCS EQU   WTODA+E2            MCS FLAGS                            20200021
WTODACDS EQU   WTODA+E5            MLWTO+MCS CODES                      20250021
WTOLABEL WTO   ('STRADDR ENDADDR SQA   R  SUBT  NAME1     NAME2     NAM*20300021
               E3',L),MF=L         LABEL LINE                     M0770 20350021
WTOLL    EQU   *-WTOLABEL                                               20400021
WTODATA  WTO   (' ',D),MF=L        DATA LINE                            20450021
WTODMCS  EQU   WTODATA+E2          MCS FLAGS                            20500021
WTODC    EQU   WTODATA+E5          MLWTO+MCS CODES                      20550021
WTOENDIT WTO   (,E),MF=L           INDICATE LAST WTO WAS END OF DISPLAY 20600021
WTOEL    EQU   *-WTOENDIT          LENGTH OF END LINE                   20650021
         EJECT                                                          20700021
         IKJTSCVT                                                       20750021
         EJECT                                                          20800021
         IKJRCB                                                         20850021
         IEEVSTAE                                                       20900021
STVERB   DS    D                   VERB CODE                            20950021
         DS    D                   *                                    21000021
         END                                                            21050021
