         TITLE 'IEE5103D STAE EXIT PROCESSOR'                           00050020
*********************************************************************** 00100020
*                                                                     * 00150020
* TITLE:  IEE5103D  STAE EXIT ROUTINE                                 * 00200020
*                                                                     * 00250020
*                                                                     * 00300020
* STATUS:  CHANGE LEVEL 000                                           * 00350020
*                                                                     * 00400020
*                                                                     * 00450020
* ENTRY POINT:  IEE5103D                                              * 00500020
*                                                                     * 00550020
*                                                                     * 00600020
* EXIT:  IEE5203D                                                     * 00650020
*                                                                     * 00700020
*                                                                     * 00750020
* INPUT:  ON ENTRY TO THIS MODULE REGISTER 0 CONTAINS A POINTER TO    * 00800020
*    THE ABEND/STAE INTERFACE WORK AREA IF ONE IS AVAILABLE.  OTHER-  * 00850020
*    WISE IT CONTAINS THE COMPLEMENT OF THE ABEND COMPLETION CODE     * 00900020
*    AND R1 CONTAINS A POINTER TO A PARAMETER LIST                    * 00950020
*                                      PARM                           * 01000020
*        FROM MASTER SCHEDULER    DC   CL12'STAEMAST    '             * 01050020
*        FROM SVC 34              DC   CL12'STAE  VERB  '             * 01100020
*                                                                     * 01150020
*                                                                     * 01200020
* OUTPUT:  ON EXIT  REGISTER CONTENTS ARE AS FOLLOWS:                 * 01250020
*        REGISTER  2 - POINTER TO XSA                                 * 01300020
*        REGISTER  3 - POINTER TO CVT                                 * 01350020
*        REGISTER  5 - POINTER TO MRC                                 * 01400020
*        REGISTER  6 - POINTER TO BEGINNING OF SQS                    * 01450020
*        REGISTER  7 - POINTER TO FIRST BYTE PAST SQS                 * 01500020
*        REGISTER 10 - POINTER TO ABEND /STAE WORK AREA               * 01550020
*        REGISTER 11 - POINTER TO STAE WORK AREA                      * 01600020
*        REGISTER 13 CONTAIN NO. OF ERRORS FOUND                      * 01650020
*        REGISTER 14 -  POINTER TO ISSUER OF SVC 34                   * 01700020
*                                                                     * 01750020
*                                                                     * 01800020
* TABLES AND WORK AREAS:  STAE WORK AREA, EXTENDED SAVE AREA (XSA)    * 01850020
*    ABEND/STAE INTERFACE WORK AREA                                   * 01900020
*                                                                     * 01950020
*                                                                     * 02000020
* FUNCTION   THIS ROUTINE PROVIDES A COMPLETE CORE DUMP AND THEN      * 02050020
*    VALIDITY CHECKS THE UCME ADDRESS AND THE CSCB,CIB,LCE,AND GCB    * 02100020
*    CHAINS AND IF AN ERROR (OR ERRORS) ARE FOUND THEIR CODES ARE     * 02150020
*    SAVED IN A WORK AREA.                                            * 02200020
*                                                                     * 02250020
*                                                                     * 02300020
* OPERATION:  ONCE ADDRESSABILITY HAS BEEN ESTABLISHED AND A FULL     * 02350020
*    CORE-IMAGE DUMP PROVIDED BY MEANS OF SVC DUMP AND IT HAS         * 02400020
*    BEEN DETERMINED WHETHER OR NOT AN ABEND/STAE INTERFACE WORK AREA * 02450020
*    IS PRESENT, THE CIB,GCB,LCE,AND CSCB CHAINS ARE SCANNED.         * 02500020
*                                                                     * 02550020
*    THE FIRST CSCB ELEMENT IS FOUND AND CHECKED TO INSURE THAT IT    * 02600020
*    LIES WITHIN SQS, ON A DWB. IF THE CSCB ADDR IS                   * 02650020
*    VALID, THE CIB CHAIN OFF THAT CSCB IS SCANNED FOR VALIDITY(THE   * 02700020
*    SAME TEST AS FOR THE CSCB NEITHER IS THE LENGTH FIELD OF THE CIB * 02750020
*    EVER CHECKED). WHEN THE END OF A CIB CHAIN IS REACHED, THE       * 02800020
*    NEXT CSCB AND ITS CIB CHAIN ARE SCANNED.                         * 02850020
*      WHEN THE COMPLETE CSCB CHAIN (AND EACH CIB CHAIN OFF THE       * 02900020
*    CSCB'S) IS SCANNED, THE SAME CHEKING IS DONE FOR EACH GCB AND ITS* 02950020
*    CIB CHAIN.  EACH GCB ADDRESS SHOULD BE WITHIN SQS, ON A DOUBLE   * 03000020
*    WORD BOUNDARY AND HAVE A CORRECT LENGTH FIELD. IN THIS CASE, AS  * 03050020
*    BEFORE, THE CIB LENGTH FIELD IS NOT CHECKED.                     * 03100020
*                                                                     * 03150020
*        IF IEE5103D FINDS AN ERROR, THE PROPER CODE IS PLACED IN THE * 03200020
*     ERROR CODE AREA (STARTING AT BYTE 16 IN THE XSA) FOR LATER      * 03250020
*     PROCESSING.                                                     * 03300020
*                                                                     * 03350020
*                                                                     * 03400020
* ATTRIBUTES.  REENTRENT, SERIALLY REUSEABLE, AND SELF-RELOCATABLE    * 03450020
*                                                                     * 03500020
*                                                                     * 03550020
*********************************************************************** 03600020
         EJECT                                                          03650020
         TITLE 'IEE5103D  STAE EXIT ROUTINE'                            03700020
*********************************************************************** 03750020
*                                                                     * 03800020
*                DSECTS                                               * 03850020
*                                                                     * 03900020
*********************************************************************** 03950020
*                                                                       04000020
         IEEVSTAE                                                       04050020
STVERB   DS    D                  VERB                                  04100020
*********************************************************************** 04150020
STABST   DSECT               ABEND/STAE INTERFACE WORK AREA DSECT       04200020
ASWORK   DS    0F            @ OF STAE WORK AREA                        04250020
ASABEND  DS    F             ABEND COMPLETION CODE                      04300020
ASPSWABD DS    D             PSW AT TIME OF ABEND                       04350020
ASPSWLST DS    D             PROBLEM PROGRAM PSW                        04400020
ASREGS   DS    16F           REG SAVE AREA                              04450020
ASRB     DS    F             ADDR OF RB                                 04500020
*                                                                       04550020
*                                                                       04600020
*                                                                       04650020
*********************************************************************** 04700020
STGROUP  DSECT               GROUP CONTROL BLOCK DSECT                  04750020
GCB      DS    0D                                                       04800020
GLENGTH  DS    H             LENGTH OF GROUP CONTROL BLOCKS             04850020
         DS    H             RESERVED                                   04900020
GNEXT    DS    F             POINTER TO NEXT GCB                        04950020
GPROCNME DS    D             PROCNAME                                   05000020
GTASKNME DS    D             TASKNAME                                   05050020
GMEMCNT  DS    C             NUMBER OF MEMBERS IN GROUP                 05100020
GSTPCNT  DS    C             NUMBER OF PENDING STOP COMMANDS            05150020
GMDFYCNT DS    C             NUMBER OF PENDING MODIFIERS                05200020
         DS    C             RESERVED                                   05250020
GBACKPTR DS    F             BACK CHAIN POINTER                         05300020
ENDGCB   EQU   *             END OF STGROUP DSECT                       05350020
LTH      EQU   ENDGCB-STGROUP           LTH OF GCB                      05400020
         EJECT                                                          05450020
MRC      IEEBASEA                                                       05500020
         EJECT                                                          05550020
STMSGXSA DSECT                                                          05600020
         IEEXSA                                                         05650020
         IKJTSCVT                                                 M4842 05700020
LCEDSECT DSECT                                                          05750020
         IKJLCE                                                   M4842 05800020
         EJECT                                                          05850020
STUCM    DSECT               UCM DSECT                                  05900020
         IEECUCM                                                        05950020
         EJECT                                                          06000020
CVTSECT  DSECT                                                          06050020
         CVT                                                            06100020
         EJECT                                                          06150020
CSCB     DSECT               CSCB DSECT                                 06200020
         IEECHAIN                                                       06250020
*********************************************************************** 06300020
CIB      DSECT                                                          06350020
         DS    0D                                                       06400020
CIBNEXT  DS    F -                ADDRESS OF NEXT ON QUEUE              06450020
CIBVERB  DS    XL1 -              COMMAND VERB CODE                     06500020
CIBSTART EQU   X'04' - START COMMAND IN BUFFER                          06550020
CIBMODFY EQU   X'44'              MODIFY COMMAND IN BUFFER              06600020
CIBLEN   DS    XL1                LENGTH IN DUB WORDS OF CIB            06650020
CIBFLAGS DS    XL1                OPERATION FLAGS                       06700020
CIBADD   EQU   X'08'              ADD CIB TO QUEUE                      06750020
CIBUNCHN EQU   X'04'              UNCHAIN CIB FROM QUEUE                06800020
CIBFREE  EQU   X'02'              FREE CIB CORE                         06850020
CIBDELE  EQU   X'0C'              UNCHAIN AND FREE CIB                  06900020
         DS    XL1                RESERVED                              06950020
         DS    F                  RESERVED                              07000020
CIBCONID DS    XL1                ID OF CONSOLE ISSUING COMMAND         07050020
CIBDATA  EQU   *                  BEG OF DATA BUFFER FOR CMD OPERAND    07100020
*                                                                       07150020
*                                                                       07200020
IEE5103D CSECT                                                          07250020
*C157000                                                         A50062 07260021
*D157500-158500                                                  A50062 07270021
*********************************************************************** 07300020
*                                                                       07350020
* REGISTER EQUATES                                                      07400020
*                                                                       07450020
*********************************************************************** 07500020
R0       EQU   0             INPUT REG, TEMP WORK REG                   07550020
R1       EQU   1             BASE FORCSCB,GCB,RQE,TQE,CIB               07600020
R2       EQU   2             BASE OF SVRB-XSA FOR DIAG MSGE ASSEMBLY    07650020
R3       EQU   3             BASE OF MRC                                07700020
R4       EQU   4             CODE FOR CSCB, CIB AND GCB CHAINS          07750020
R5       EQU   5             BASE OF CVT                                07800020
R6       EQU   6             1ST WD SQS- 1 BYTE BEYOND NUCLEUS          07850020
R7       EQU   7             1 BYTE BEYOND SQS                          07900020
R8       EQU   8             MODULE        WORK REG                     07950020
R9       EQU   9             ERROR CODE REG                             08000020
R10      EQU   10            BASE OF ABEND/STAE INTERFACE WORKAREA      08050020
R11      EQU   11            BASE OF STAE WORK AREA                     08100020
R12      EQU   12            PROGRAM BASE                               08150020
R13      EQU   13            TEMP WORK REGISTER                         08200020
R14      EQU   14            TO RET TO SVC 34 ISSUER                    08250020
R15      EQU   15            SAVE ADDR IN EACH SCAN                     08300020
*********************************************************************** 08350020
*                                                                       08400020
*        CHARACTER AND NUMERIC EQUATES                                * 08450020
*                                                                       08500020
*********************************************************************** 08550020
ZERO     EQU   0                    *                                   08600020
ONE      EQU   1                   *                                    08650020
TWO      EQU   2                 *                                      08700020
T3       EQU   3                *                                       08750020
F4       EQU   4               *                                        08800020
F5       EQU   5             *            *                             08850020
S6       EQU   6                    *                                   08900020
S7       EQU   7                     *     *                            08950020
N9       EQU   9                   *          *                         09000020
T12      EQU   12                *              *                       09050020
S16      EQU   16              *                  *                     09100020
T24      EQU   24            *                     *                    09150020
F28      EQU   28        *               DISPLACEMENT                   09200020
T29      EQU   29      *                            *                   09250020
F        EQU   X'FF'                    USED IN TURNING OFF BITS        09300020
E1       EQU   1                  *                                     09350020
E2       EQU   2                  *                                     09400020
E4       EQU   4                  *                                     09450020
E8       EQU   8                  *                                     09500020
E40      EQU   40                 *                                     09550020
EF0      EQU   X'F0'              MASK TO CHANGE SIGN BYTE AFTER UNPK   09600020
CIBDISP  EQU   CHCIBP-CHAIN       DISPL TO CIB PTR IN CSCB              09650020
DUMPID   EQU   XAS+4              LOCATION OF DUMP ID IN XSA            09700020
GOVFRLB  EQU   X'6C'              DISPL TO GOVRFLB PTR                  09750020
*                                                                       09800020
D1       EQU   1                  *                                     09850020
D2       EQU   2                  *                                     09900020
D3       EQU   3                  *                                     09950020
D4       EQU   4                  *                                     10000020
D6       EQU   6                  *                                     10050020
D8       EQU   8                  *                                     10100020
D12      EQU   12                 *                                     10150020
D16      EQU   16                 *                                     10200020
BLANK    EQU   C' '               BLANK FOR DUMP ID                     10250020
DUMPCODE EQU   X'1E'              'DUMP-TAKEN' CODE FOR MESSAGE         10300020
M        EQU   C'M'               'MASTER' IDENTIFIER                   10350020
S        EQU   C'S'               'SVC 34' IDENTIFIER                   10400020
VDSP1    EQU   C'C'               VDSP1 ID                              10450020
         EJECT                                                          10500020
*********************************************************************** 10550020
*                                                                       10600020
* BASE MODULE                                                           10650020
*                                                                       10700020
*********************************************************************** 10750020
         BALR  R12,R0        ESTAB PROG ADDRESSABILITY                  10800020
         USING *,R12                                                    10850020
         B     IDSKIP             BRANCH AROUND ID                      10900020
         DC    X'EEEE'            ID FOR USE WHEN LOOKING AT DUMPS      10950020
         DC    CL8'IEE5103D'        *                                   11000020
         DC    X'EEEE'              *                                   11050020
IDSKIP   EQU   *                                                        11100020
*********************************************************************** 11150020
*                                                                       11200020
*                           ESTABLISH DSECT BASES                       11250020
*                                                                       11300020
*********************************************************************** 11350020
         USING STMSGXSA,R2              XSA PTR PASSED IN R2            11400020
         USING CVTSECT,R3               WORK AREA PTR PASSED IN R3      11450020
         LR    R11,R3                   SAVE ADDR OF WORK AREA          11500020
         LR   R10,R0                    SAVE COMPLETION CODE OR PTR TO  11550020
*                                       ABEND/STAE WORK AREA            11600020
         L     R3,CVTPTR                ADDRESS OF CVT                  11650020
         L     R5,CVTMSER               ADDRESS OF MRC(BACHN)           11700020
         USING BASE,R5                  ADDRESSABILITY FOR MRC          11750020
*                                       (BASEA USED FOR LATER           11800020
*                                       GOVERFLB CHECKING AND           11850020
*                                       STORAGE OF DUMP ID COUNTER)     11900020
          SPACE                                                         11950020
         EJECT                                                          12000020
*********************************************************************** 12050020
*                                                                     * 12100020
*                  SVC DUMP PROCESSING                                * 12150020
*                                                                     * 12200020
*********************************************************************** 12250020
         SPACE                                                          12300020
         SPACE                                                          12350020
         LR    R4,R1              SAVE R1 ACROSS DUMP MACRO             12400020
         SPACE                                                          12450020
*********************************************************************** 12500020
*                                                                     * 12550020
*        BUILD DUMP IDENTIFIER IN XSA.                                * 12600020
*                                                                     * 12650020
*********************************************************************** 12700020
         SPACE                                                          12750020
         CLC   F4(F4,R4),MAST     CONTROL FROM MASTER                   12800020
         MVI   DUMPID,M           PUT MASTER ID IN DUMP ID IN XSA       12850020
         BE    CALCID             PROVIDED CONTROL IS FROM MASTER       12900020
         MVI   DUMPID,S           PUT SVC 34 ID IN DUMP ID IN XSA       12950020
         SPACE                                                          13000020
CALCID   EQU   *                                                        13050020
         MVI   DUMPID+D1,BLANK    INSERT BLANK AFTER ID                 13100020
         SR    R6,R6              ZERO ID COUNTER REGISTER              13150020
         SSM   DISABLE            DISABLE TO PRESERVE INTEGRITY         13200020
*                                 OF DUMP ID'S                          13250020
         IC    R6,BADUMPID        GET ID FROM MRC                       13300020
         CVD   R6,XAV             CONVERT TO PACKED DECIMAL             13350020
         SPACE                                                          13400020
*********************************************************************** 13450020
*                                                                     * 13500020
*        UNPACK LAST TWO DIGITS OF NUMERICAL ID.                      * 13550020
*        NOTE THAT INCREMENTING BASEA COUNTER FROM 99, 199, AND 255   * 13600020
*        WILL YIELD AN EFFECTIVE ID OF 00.                            * 13650020
*                                                                     * 13700020
*********************************************************************** 13750020
         SPACE                                                          13800020
         UNPK  DUMPID+D2(E2),XAV+D6(E2)                                 13850020
         OI    DUMPID+D3,EF0      CHANGE SIGN BYTE TO EBCDIC DIGIT      13900020
*                                                                       13950020
*                                                                       14000020
         LA    R6,ONE(R6)         ADD ONE TO ID.                        14050020
         STC   R6,BADUMPID        STORE UPDATED ID IN MRC.              14100020
         SPACE                                                          14150020
         SSM   ENABLE             ENABLE, SINCE ID UPDATE IS COMPLETE.  14200020
         EJECT                                                          14250020
*********************************************************************** 14300020
*                                                                     * 14350020
*        SET UP PARAMETER LIST FOR SVC DUMP                           * 14400020
*                                                                     * 14450020
*********************************************************************** 14500020
         SPACE                                                          14550020
         L     R6,DUMPID          SAVE COMPLETED ID                     14600020
         MVC   XAP(E40),DUMPPARM  MOVE DUMP PARM LIST AND DUMP          14650020
*                                 HEADER TO XSA.                        14700020
         USING DUMPPARM,R2        ADDRESSABILITY TO XSA AS PARM LIST    14750020
         LA    R7,DUMPPARM+D16    GET ADDR OF DUMP HEADER IN XSA        14800020
         ST    R7,DUMPPARM+D8     STORE IT INTO DUMP PARMLIST IN XSA.   14850020
         DROP  R2                 DROP USING FOR DUMP PARM LIST         14900020
         USING STMSGXSA,R2        ADDRESSABILITY TO XSA                 14950020
         SPACE                                                          15000020
         ST    R6,DUMPID          SET USER DATA (DUMP ID) IN HEADER     15050020
         SPACE                                                          15100020
*********************************************************************** 15150020
*                                                                     * 15200020
*        DUMP CORE                                                    * 15250020
*                                                                     * 15300020
*********************************************************************** 15350020
         SPACE                                                          15400020
         SDUMP MF=(E,(R2))        DUMP ALL CORE                         15450020
         ST    R6,XAV+D4          STORE DUMP ID IN XSA FOR IEE5303D USE 15500020
         SPACE                                                          15550020
         SR    R13,R13            ZERO ERROR CODE COUNTER               15600020
         XC    S16(D8,R2),S16(R2) ZERO ERROR CODE FIELD IN XSA          15650020
         STC   R15,XAV+F5         PASS RET CODE TO MSG WRITER    A50062 15700021
         MVI   S16(R2),DUMPCODE   FIRST BYTE OF CODE FIELD IN XSA       15900020
*                                                                       15950020
         LA    R13,ONE            SET ERROR COUNT TO ONE                16000020
PASTDUMP EQU   *                                                        16050020
         LR    R1,R4              RESTORE R1 AFTER DUMP                 16100020
         XC    XAV(F4),XAV        ZERO FOR CODE                         16150020
         MVC   XAS(D8),F4(R1)     SAVE CONTENTS IN PARM                 16200020
         EJECT                                                          16250020
*********************************************************************** 16300020
*                                                                       16350020
*       DETERMINE PRESENCE OF ABEND/STAE INTERFACE WORKAREA             16400020
*                                                                       16450020
*********************************************************************** 16500020
         LTR   R0,R10                   CHECK FOR ABEND/STAE            16550020
*                                       WORK AREA                       16600020
         BNP   STNOWORK                 NEG OR 0 IS NO ABND/STAE        16650020
*                                       WORK AREA                       16700020
         USING STABST,R10               ABND/STAE WORK AREA BASE        16750020
         L     R11,ZERO(R10)            ADDR OF SWA                     16800020
STINIT   EQU   *                                                        16850020
         USING STWORK,R11               BASE FOR SWA                    16900020
*********************************************************************** 16950020
*                                                                       17000020
*                          DETERMINE RANGE OF SQS                       17050020
*                                                                       17100020
*********************************************************************** 17150020
         L     R6,CVTABEND              ADDR OF SECONDARY CVT           17200020
         L     R6,GOVFRLB(R6)           LOAD PTR TO GOVERFLB            17250020
         L     R7,ZERO(R6)              LOAD HIGH SQS BDY               17300020
         LA    R7,ZERO(R7)              CLEAR HIGH ORDER BYTE           17350020
         L     R6,F4(R6)                LOAD DQE FOR SQS                17400020
         L     R6,E8(R6)                LOAD SQS FIRST BLK PTR          17450020
         LA    R6,ZERO(R6)              CLEAR HIGH ORDER BYTE           17500020
         SR    R9,R9                    ZERO R9 FOR ERROR CODE          17550020
*********************************************************************** 17600020
*                                                                     * 17650020
*                  FIND CSCB ADDR AND SCAN THE CSCB CHAIN.            * 17700020
*                  ALSO, SCAN THE CIB CHAIN OFF EACH CSCB             * 17750020
*                                                                     * 17800020
*********************************************************************** 17850020
         CLC   XAS(F4),MAST       IS CONTROL FROM MASTER                17900020
         BNE   DOLOOP             DETERMINE ERROR                       17950020
         XC    XAU(F4),XAU        ZERO UCMU AND TSOID                   18000020
         CLI   STMID,VDSP1        IS CONTROL FROM IEEVDSP1              18050020
         BNE   DOLOOP             DETERMINE ERROR                       18100020
         MVC   STVERB,DISPLAY     MOVE IN DISPLAY ACTIVE VERB           18150020
         MVC   XAU(D1),STSVRB+D1  UCMI                                  18200020
         MVC   XAU+D2(D2),STSVRB+D2 TJID                                18250020
DOLOOP   EQU   *                                                        18300020
         LR    R15,R5                   GET ADDR OF BACHN               18350020
         L     R1,BACHN                 GET ADDR CSCB CHAIN             18400020
         LR    R8,R1                    SAVE ADDRESS                    18450020
         SR    R4,R4                    INSERT CSCB CODE OF 0 IN RE     18500020
         SSM   DISABLE                                                  18550020
SEECHAIN EQU   *                                                        18600020
         LA    R1,ZERO(R1)              CLEAR HIGH ORDER BYTE           18650020
         LTR   R0,R1                    IS ELT LAST ON CHAIN            18700020
         BZ    CHECK                    YES, GOTO NEXT STEP             18750020
         CR    R1,R6                    IS ADDR BEFORE SQS              18800020
         BL    SQS1                     BEFORE SQS                      18850020
         CR    R1,R7                    IS ADDR AFTER SQS               18900020
         BNL   SQS1                     AFTER SQS                       18950020
         SLL   R0,T29                   SHIFT OFF ALL BUT LOW ORDER     19000020
         LTR   R0,R0                    BITS, TEST BDY FOR DBLE WD      19050020
         BNZ   NONDBLE1                 NOT ON DOUBLE WORD BOUNDARY     19100020
         LTR   R4,R4                    CSCB, CIB, OR GCB               19150020
         BZ    CIBCSCB             FIND CIB OFF CSCB                    19200020
         BM    CIBGCB              FIND CIB OFF GCB                     19250020
NEXTCIB  EQU   *                                                        19300020
         LR    R15,R1                   SAVE OLD CIB ADDR               19350020
         L     R1,ZERO(R1)              GET ADDR NEXT CIB               19400020
         B     SEECHAIN                 CONTINUE SCANNING               19450020
CIBCSCB  EQU   *                                                        19500020
         LA    R15,CIBDISP(R1)    ADDR OF CIB PTR                       19550020
         L     R1,ZERO(R15)             GET CIB ADDR                    19600020
         LA    R4,E8                    INSERT CODE 8 FOR CSCBCIB       19650020
         B     SEECHAIN                 SCAN THE CHAIN                  19700020
CIBGCB   EQU   *                                                        19750020
         LA    R15,F28(R1)              ADDR OF CIB PTR                 19800020
         L     R1,ZERO(R15)             GETT CIB ADDR                   19850020
         LA    R4,F4                    INSERT CODE 4 FOR CIB           19900020
         B     SEECHAIN                 SCAN THE CHAIN                  19950020
NEXTGCB  EQU   *                                                        20000020
         LA    R4,T12                   INDICATE GCB                    20050020
         LNR   R4,R4                                                    20100020
         LR    R15,R8                   SAVE ADDRESS                    20150020
         L     R8,F4(R8)                GET ADDR NEXT GCB               20200020
         LR    R1,R8                    SAVE ADDRESS IN R8              20250020
         B     SEECHAIN                 SCAN THE CHAIN                  20300020
CHECK    EQU   *                                                        20350020
         LTR   R4,R4                                                    20400020
         BZ    GCBSCAN                  END OF CSCB CHAIN, SCAN GCB     20450020
         BM    CKGCBBIT                 END OF SCANNING                 20500020
         C     R4,FOUR                  CIBCSCB OR CIBGCB               20550020
         BE    NEXTGCB                  CIBGCB                          20600020
NEXTCSCB EQU   *                                                        20650020
         SR    R4,R4                    INDICATE CSCB                   20700020
         LR    R15,R8                   SAVE ADDRESS                    20750020
         L     R8,ZERO(R15)             GET ADDR NEXT CSCB              20800020
         LR    R1,R8                    SAVE ADDRESS IN R8              20850020
         B     SEECHAIN                 SCAN THE CHAIN                  20900020
SQS1     EQU   *                                                        20950020
         LPR   R4,R4                    MAKE SURE R4 IS POSITIVE        21000020
         B     SQS(R4)                  INSERT CODE AND TRUNCATE        21050020
NONDBLE1 EQU   *                                                        21100020
         LPR   R4,R4                    CHANGE                          21150020
         B     NONDBLE(R4)              INSERT CODE AND TRUNCATE        21200020
SQS      EQU   *                                                        21250020
         B     DRAT1                    INSERT ERROR CODE FOR CSCB      21300020
         B     DRATGCB                  INSERT CODE FOR GCBCIB          21350020
         B     DRATCSCB                 INSERT CODE FOR CSCBCIB         21400020
         B     DRAT8                    INSERT ERR CODE FOR GCB         21450020
NONDBLE  EQU   *                                                        21500020
         B     DRAT2                    INSERT ERROR CODE FOR           21550020
         B     DRAT22                   NOT BEING ON                    21600020
         B     DRAT22A                  DOUBLEWORD                      21650020
         B     DRAT9                    BOUNDARY                        21700020
DRAT2    EQU   *                                                        21750020
         IC    R9,CSCBBDY               INSERT ERROR CODE               21800020
         B     ENDRAT                   TRUNCATE CHAIN                  21850020
DRAT1    EQU   *                                                        21900020
         IC    R9,CSCBSQS               INSERT ERROR CODE               21950020
ENDRAT   EQU   *                                                        22000020
         XC    ZERO(F4,R15),ZERO(R15)   SET LINK FIELD OF LAST          22050020
*                                         VALID CHAIN ELT TO 0          22100020
         CH    R13,EIGHT          MORE THAN EIGHT ERROR CODES           22150020
         BE    DOLOOP             CONTINUE ERROR CHECKING               22200020
         STC   R9,S16(R2,R13)     PUT CODE IN XSA                       22250020
         LA    R13,ONE(R13)       UPDATE CODE PTR                       22300020
         B     DOLOOP             CONTINUE ERROR CHECKING               22350020
DRATGCB  EQU   *                                                        22400020
         IC    R9,CIBGCSQS              ERROR CODE FOR GCBCIB           22450020
         B     ENDRAT                   BRANCH AND DELETE BLOCK         22500020
DRATCSCB EQU   *                                                        22550020
         IC    R9,CIBCSSQS              ERROR CODE FOR CSCBCIB          22600020
         B     ENDRAT                   PREPARE TO EXIT                 22650020
DRAT22   EQU   *                                                        22700020
         IC    R9,CIBGCBDY              ERROR CODE FOR GCBCIB           22750020
         B     ENDRAT                   BRANCH AND DELETE BLOCK         22800020
DRAT22A  EQU   *                                                        22850020
         IC    R9,CIBCSBDY              ERROR CODE FOR CSCBCIB          22900020
         B     ENDRAT                   PREPARE TO EXIT                 22950020
*********************************************************************** 23000020
*                                                                     * 23050020
*                   FIND GCB ADDR AND SCAN GCB CHAIN.                   23100020
*                   ALSO,SCAN THE CIB CHAIN OFF EACH GCB.               23150020
*                                                                     * 23200020
*********************************************************************** 23250020
GCBSCAN  EQU   *                                                        23300020
         L     R1,BATRM                 GET PTR TO GCB                  23350020
         LR    R8,R1                    SAVE ADDRESS                    23400020
         LA    R15,BACHN               ADDR OF GCB PTR - 4              23450020
         LA    R4,T12                   LOAD GCB CODE INTO REG4         23500020
         LNR   R4,R4                    TURN ON SIGN BIT                23550020
         B     SEECHAIN                 SCAN THE CHAIN                  23600020
DRAT9    EQU   *                                                        23650020
         IC    R9,GCBBDY                INSERT ERROR CODE               23700020
         B     ENDRAT3                    AND BRANCH                    23750020
DRAT8    EQU   *                                                        23800020
         IC    R9,GCBSQS                INSERT ERROR CODE               23850020
ENDRAT3  EQU   *                                                        23900020
         XC    F4(F4,R15),F4(R15)       ZERO LINK FIELD                 23950020
         CH    R13,EIGHT          EIGHT ERROR CODES PROCESSED           24000020
         BE    CKGCBBIT           CHECK FOR GCB ERROR                   24050020
         STC   R9,S16(R2,R13)     PUT CODE IN XSA                       24100020
         LA    R13,ONE(R13)                                             24150020
CKGCBBIT EQU   *                                                        24200020
         L    R4,CVTTSCVT         ADDR OF TSO CVT                       24250020
         LTR   R4,R4              IS TSO IN SYSTEM                      24300020
         BZ    DEQU              DEQU FROM GCB                          24350020
         USING TSCVT,R4                                                 24400020
         L     R1,TSCVTLCQ        PTR TO LCE                            24450020
         LA    R15,TSCVTLCQ                                             24500020
LCELOOP  EQU   *                                                        24550020
         LA    R1,ZERO(R1)        CLEAR HIGH ORDER BYTE                 24600020
         LTR   R0,R1                                                    24650020
         BZ    DEQU               DEQUE FROM GCB                        24700020
         CR    R1,R6              IS ADDR BEFORE SQS                    24750020
         BL   LCESQS              ERROR                                 24800020
         CR   R1,R7               IS ADDR AFTER SQS                     24850020
         BNL   LCESQS             PRINT SQS ERROR                       24900020
         SLL   R0,T29                                                   24950020
         LTR   R0,R0              ADDR ON DBLE WORD BDY                 25000020
         BZ    LCELOOP3           CONTINUE ERROR SCAN                   25050020
         IC    R9,LCECODE2        INSERT ERROR CODE                     25100020
LCELOOP1 EQU   *                                                        25150020
         XC    ZERO(F4,R15),ZERO(R15) ZERO PTR                          25200020
         CH    R13,EIGHT          EIGHT ERRORS FOUND                    25250020
         BE    DEQU               DEQU FROM GCB                         25300020
         LA    R13,ONE(R13)                                             25350020
         STC   R9,S16(R2,R13)     PUT CODE IN TABLE                     25400020
         B    DEQU                DEQU FROM GCB                         25450020
LCELOOP3 EQU   *                                                        25500020
         LR    R15,R1                                                   25550020
         L     R1,ZERO(R15)       PTR TO NEXT LCE                       25600020
         B     LCELOOP            CHECH THIS CHAIN                      25650020
LCESQS   EQU   *                                                        25700020
         IC    R9,LCECODE         INSERT ERROR CODE                     25750020
         B     LCELOOP1           DELETE MEMBER FROM CHAIN              25800020
DEQU     EQU   *                                                        25850020
         SSM   ENABLE                                                   25900020
         MVC   XAX(S6),STFRM2     SAVE ADDRESS AND LENGTH               25950020
         MVC   STADDR(D2),STFRMLNG SAVE LENGTH OF CORE                  26000020
         LA    R9,STFRMLNG                                              26050020
         MVC   ZERO(LN,R9),ENQGCB MOVE TO PARM LIST                     26100020
         LA    R4,DPQN(R9)        RESOLVE QNAME                         26150020
         ST    R4,DPQA(R9)                                              26200020
         LA    R4,DPRN(R9)        RESOLVE RNAME                         26250020
         ST    R4,DPQA+F4(R9)                                           26300020
         DEQ   RET=HAVE,MF=(E,(R9)) DEQUE GCB RESORCE                   26350020
         MVC   STFRM2(S6),XAX     RESTORE LENGTH AND ADDR               26400020
         MVC   STFRMLNG(D2),STADDR                                      26450020
         LTR   R15,R15            WAS GCB RESOURCE DEQUED               26500020
         BNZ   EXIT               EXIT                                  26550020
         IC    R9,GCBLEN          DENOTE GCB DEQUED                     26600020
         CH    R13,EIGHT          EIGHT ERRORS FOUND                    26650020
         BE    EXIT               EXIT                                  26700020
         STC   R9,S16(R2,R13)     PUT ERROR CODE IN TABLE               26750020
         LA    R13,ONE(R13)       UPDATE ERROR COUNT                    26800020
*                                       DEQUEUED.                       26850020
         B     EXIT                     BRANCH AROUND                   26900020
EXIT     EQU   *                                                        26950020
         MVC   XAX(E8),STAEMOD2         STORE XCTL NAME IN XSA          27000020
ALTEXIT  EQU   *                                                        27050020
*********************************************************************** 27100020
*                                                                     * 27150020
*                 PREPARE TO EXIT                                     * 27200020
*                                                                     * 27250020
*********************************************************************** 27300020
         LA    R15,XAX                                                  27350020
         ST    R15,XAP                                                  27400020
         LA    R15,XAP                                                  27450020
         XC    XAD(F4),XAD             ZERO DCB PTR                     27500020
         XCTL  SF=(E,(15))                                              27550020
*********************************************************************** 27600020
STNOWORK EQU   *                                                        27650020
         SR    R10,R10                  IF 0, NO WORK AREA              27700020
         LPR   R0,R0                    COMPLEMENT = ABEND CODE         27750020
         ST    R0,XAV             SAVE ABEND CODE                       27800020
         B     STINIT             CONTINUE PROCESSING                   27850020
*********************************************************************** 27900020
*                                                                       27950020
         EJECT                                                          28000020
*********************************************************************** 28050020
*                                                                     * 28100020
*                STORAGE DEFINITION                                   * 28150020
*                                                                     * 28200020
* DEFINED CONSTANTS AND STORAGE                                         28250020
*                                                                       28300020
*********************************************************************** 28350020
STAEMOD2 DC    CL8'IGC5203D'         *                                  28400020
         SPACE                                                          28450020
*        PARAMETER LIST AND HEADER FOR DUMP                             28500020
*                                                                       28550020
DUMPPARM SDUMP HDR=(IEE5103D,4),MF=L                                    28600020
         SPACE                                                          28650020
ENQGCB   ENQ   (IEESGCBS,IEESRJC,E,5,SYSTEM),MF=L                       28700020
IEESGCBS DC    C'SYSJMPCH'   MAJOR NAME                                 28750020
IEESRJC  DC    C'BATRM'      MINOR NAME                                 28800020
LN       EQU   *-ENQGCB           LENGTH OF ENQ PARM LIST               28850020
         ORG   ENQGCB                                                   28900020
ETOP     DS    AL1                *                                     28950020
         DS    AL1                *                                     29000020
         DS    BL1                *                                     29050020
         DS    AL1                *                                     29100020
DPQA     EQU   *-ETOP             DISP TO QNAME ADDRESS                 29150020
         DS    F                  *                                     29200020
         DS    F                  *                                     29250020
DPQN     EQU   *-ETOP             DISPL TO QNAME                        29300020
         DS    8C                 *                                     29350020
DPRN     EQU   *-ETOP             DISPL TO RNAME                        29400020
         DS    5C                 *                                     29450020
         DS    0F                                                       29500020
FOUR     DC    X'00000004'              TO COMPARE WITH CIB CODE        29550020
NINETY   DC    X'00000090'              USED IN XCTL ALGORITHM          29600020
MAST     DC    CL4'MAST'          INDICATE CONTROL FROM MASTER          29650020
DISPLAY  DC    CL8'D A'           DISPLAY ACTIVE VERB                   29700020
EIGHT    DC    H'08'              ERROR COUNT CONST                     29750020
DISABLE  DC    X'00'              DISABLE MASK                          29800020
ENABLE   DC    X'FF'               ENABLE MASK                          29850020
LCECODE  DC    X'02'                    LCE  ADDR NOT WITHIN SQS        29900020
LCECODE2 DC    X'03'                    LCE  ADDR NOT ON DBL WD         29950020
CSCBBDY  DC    X'04'                    CSCB ADDR NOT ON DBL WD         30000020
CSCBSQS  DC    X'06'                    CSCB ADDR NOT WITHIN SQS        30050020
GCBLEN   DC    X'08'                    GCB RESOURCE DEQUED             30100020
GCBBDY   DC    X'0A'                    GCB ADDR NOT ON DBL WD BNDRY    30150020
GCBSQS   DC    X'0C'                    GCB ADDR NOT IN SQS             30200020
CIBCSBDY DC    X'0E'                    CSCBCIB ADDR NOT ON DBL WD      30250020
CIBCSSQS DC    X'10'                    CSCBCIB ADDR NOT IN SQS         30300020
CIBGCBDY DC    X'12'                    GCBCIB ADDR NOT ON DBL WD       30350020
CIBGCSQS DC    X'14'                    GCBCIB ADDR NOT IN SQS          30400020
*                                                                       30450020
         EJECT                                                          30500020
         END                                                            30550020
