IEE5203D CSECT                                                          00200020
         TITLE 'IEE5203D STAE EXIT ROUTINE'                             00400020
************************************************************            00600020
*                                                                     * 00800020
* TITLE.  IEE5203D  STAE EXIT ROUTINE CONTINUED                       * 01000020
*                                                                     * 01200020
*                                                                     * 01400020
* STATUS.  CHANGE LEVEL 000                                           * 01600020
*                                                                     * 01800020
*                                                                     * 02000020
* ENTRY POINT.  IEE5203D                                              * 02200020
*                                                                     * 02400020
*                                                                     * 02600020
* EXIT.  IEE5303D                                                     * 02800020
*                                                                     * 03000020
*                                                                     * 03200020
* INPUT.  ON ENTRY THE REGISTER CONTENTS ARE AS FOLLOWS...            * 03400020
*        REGISTER  2 - POINTER TO XSA                                 * 03600020
*        REGISTER  3 - POINTER TO CVT                                 * 03800020
*        REGISTER  4-POINTER TO  TSO CVT                              * 04000020
*        REGISTER  6 - POINTER TO BEGINNING OF SQS                    * 04200020
*        REGISTER  7 - POINTER TO FIRST BYTE PAST SQS                 * 04400020
*        REGISTER 10 - POINTER TO ABEND /STAE WORK AREA               * 04600020
*        REGISTER 11 - POINTER TO STAE WORK AREA                      * 04800020
*        REGISTER 14 -  POINTER TO ISSUER OF SVC 34                   * 05000020
*                                                                     * 05200020
*        REGISTER 13-COUNTER FOR ERROR CODES                          * 05400020
*                                                                     * 05410020
*        XAE OF XSA-8 BYTES RESERVED FOR ERROR CODES                  * 05600020
*        XAV OF XSA- IF NO ABEND/WORK AREA,ABEND COMPL CODE           * 05800020
*        XAS OF XSA-8 BYTE PARM LIST                                  * 06000020
*                                                                     * 06200020
* OUTPUT.  REGISTER 2  - POINTER TO THE XSA                           * 06400020
*          REGISTER 10 - POINTER TO ABEND/STAE INTERFACE WORK AREA    * 06600020
*          REGISTER 11 - POINTER TO THE STAE WORK AREA                * 07000020
*          REGISTER 13 COUNTER FOR ERROR CODES                        * 07200020
*          REGISTER 14 - POINTER TO ISSUER OF SVC 34                  * 07400020
*                                                                     * 07600020
*      XAE,XAV, AND XAS OF XSA, SAME AS UPON ENTRY                    * 07800020
*                                                                     * 08000020
* TABLES AND WORK AREA.  STAE WORK AREA, EXTENDED SAVE AREA           * 08200020
*                                                                     * 08400020
*                                                                     * 08600020
         EJECT                                                          08800020
* FUNCTION.  THIS ROUTINE CONTINUES THE VALIDITY CHECKING BEGUN BY    * 09000020
*    BY MODULE IEE5103D                                               * 09200020
*                                                                     * 09400020
*                                                                     * 09600020
* OPERATIONS:                                                         * 09800020
*                                                                     * 10000020
*        UPON ENTRY TO IEE5203D,  EACH ELEMENT OF                     * 10200020
*     THE RQE CHAIN IS SCANNED TO INSURE THAT IT LIES WITHIN SQS      * 10400020
*     AND ON A DOUBLE WORD BOUNDARY. IF AN INVALID ELEMENT IS FOUND   * 10600020
*     THE CHAIN IS TRUNCATED.                                         * 10800020
*                                                                     * 11000020
*                                                                     * 11200020
*      IF THE COMMAND THAT ABENDED WAS DISPLAY ACTIVE,THE             * 11400020
*      D.A. BIT IN MASTER RESIDENCE CORE IS TURNED OFF.               * 11600020
*                                                                     * 11800020
*                                                                     * 12000020
*     AFTER AN ERROR IS FOUND OR AFTER ALL CHAINS HAVE BEEN           * 12200020
*     TESTED(IF NO ERROR HAS BEEN FOUND) THE AREAS INDICATED BY STFRM * 12400020
*     AND/OR STFRM2 ARE FREED IF THE ADDRESSES ARE NON-ZERO AND VALID.* 12600020
*                                                                     * 12800020
*                                                                     * 13000020
* ATTRIBUTES.  REENTRENT, REUSEABLE, AND SELF-RELOCATABLE             * 13200020
*                                                                     * 13400020
* NOTES.  THE WORD XAV+4 IN THE XSA POINTED TO BY R2 IS USED TO PASS  * 13430020
*         THE IDENTIFIER OF THE DUMP TAKEN IN IEE5103D TO IEE5303D,   * 13460020
*         FOR USE IN MESSAGES. HENCE, THE CONTENTS OF THIS FIELD      * 13490020
*         MUST BE PRESERVED IN IEE5203D.                              * 13520020
*                                                                     * 13550020
*                                                                     * 13600020
*********************************************************************** 13800020
         EJECT                                                          14000020
         TITLE 'IEE5203D  STAE EXIT ROUTINE CONTINUED'                  14200020
*********************************************************************** 14400020
*                                                                       14600020
* REGISTER EQUATES                                                      14800020
*                                                                       15000020
*********************************************************************** 15200020
R0       EQU   0                  INPUT REG FROM STAE PROCESSOR         15400020
R1       EQU   1             BASE FORCSCB,GCB,RQE,TQE,CIB               15600020
R2       EQU   2             BASE OF SVRB-XSA FOR DIAG MSGE ASSEMBLY    15800020
R3       EQU   3             BASE OF CVT                                16000020
R4       EQU   4             BASE OF UCM                                16200020
R5       EQU   5             BASE OF MRC                                16400020
R6       EQU   6             1ST WD SQS- 1 BYTE BEYOND NUCLEUS          16600020
R7       EQU   7             1 BYTE BEYOND SQS                          16800020
R8       EQU   8             INDICATION OF WHETHER STFRM2 HAS BEEN      17000020
*                            TESTED YET                                 17200020
R9       EQU   9                  WORK REG                              17400020
R10      EQU   10            BASE OF ABEND/STAE INTERFACE WORKAREA      17600020
R11      EQU   11            BASE OF STAE WORK AREA                     17800020
R12      EQU   12            PROGRAM BASE                               18000020
R13      EQU   13            COUNTER FOR ERRORS                         18200020
R14      EQU   14            TO RET TO SVC 34 ISSUER                    18400020
R15      EQU   15            TEMP WORK REG                              18600020
*********************************************************************** 18800020
*                                                                       19000020
*             CHARACTER AND NUMERIC EQUATES                             19200020
*                                                                       19400020
*********************************************************************** 19600020
*                                                                       19800020
*       NUMERIC EQUATES                                                 20000020
*                                                                       20200020
ZERO     EQU   0                 DISPLAY ACTIVE CODE                    20400020
F4       EQU   4                 *                                      20600020
F5       EQU   5                 *                                      20800020
S6       EQU   6                 *                                      21000020
E8       EQU   8                 *                                      21200020
D16      EQU   16                *                                      21400020
D1       EQU   1                  *                                     21600020
E9       EQU   9                 *                                      21800020
T29      EQU   29                A                                      22000020
RQEBDY   EQU   X'18'                    RQE ADDR NOT ON DBL WD          22200020
RQESQS   EQU   X'19'               RQE ADDR NOT IN SQS                  22400020
DISPLAY  EQU   C'C'                 DISPLAY ACTIVE CODE                 22600020
DABIT    EQU   X'1D'               DISPLAY ACTIVE VALID BIT ON          22800020
TCBBIT   EQU   X'1E'               TCB VALID BIT ON                     23000020
STFRMBDY EQU   X'1F'               STFRM ADDR NOT ON DBL WD BDY         23200020
HEXFF    EQU   X'FF'       *                                            23400020
*                                                                       23600020
         EJECT                                                          23800020
*********************************************************************** 24000020
*                                                                       24200020
* BASE MODULE                                                           24400020
*                                                                       24600020
*********************************************************************** 24800020
         BALR  R12,R0        ESTAB PROG ADDRESSABILITY                  25000020
         USING *,R12                                                    25200020
         B     IDSKIP             BRANCH AROUND ID                      25400020
         DC    X'EEEE'            ID FOR USE WHEN LOOKING AT DUMPS      25600020
         DC    CL8'IEE5203D'          *                                 25800020
         DC    X'EEEE'                *                                 26000020
IDSKIP   EQU   *                                                        26200020
         USING STMSGXSA,R2   BASE FOR MESSAGE AREA TABLE                26400020
         USING CVTSECT,R3    BASE FOR CVT                               26600020
         L     R3,CVTPTR          PTR TO CVT                            26800020
         USING STWORK,R11    BASE FOR STAE WORK AREA                    27000020
         L     R4,CVTCUCB               ADDR OF UCM                     27200020
         USING STUCM,R4      BASE FOR UCM DSECT                         27400020
*********************************************************************** 27600020
*                                                                     * 27800020
*         RQE  CHAIN VALIDITY CHECKING                                * 28000020
*                                                                     * 28200020
*********************************************************************** 28400020
         CH    R13,EIGHT          MORE THAN EIGHT ERRORS BEEN FOUND     28600020
         BH    EXIT                     EXIT                            28800020
         L     R1,UCMRPYQ               GET ADDR RQE CHAIN              29000020
         LA    R15,UCMRPYQ              GET ADDR OF RQE PTR             29200020
         USING RQE,R1                   RQE ADDRESSABILITY              29400020
         SSM   DISABLE                                                  29600020
SEERQES  EQU   *                                                        29800020
         LA    R1,ZERO(R1)              CLEAR HIGH ORDER BYTE           30000020
         LTR   R0,R1                    SAVE ADDR AND CHECK FOR 0       30200020
         BZ    GOON5                        GO TO NEXT TEST             30400020
         CR    R1,R6                    IS ADDR BELOW SQS               30600020
         BL    DRAT11                    YES- WRITE MSG,  TRUNCATE      30800020
         CR    R1,R7                    IS ADDR ABOVE SQS               31000020
         BNL   DRAT11                    YES- WRITE MSG , TRUNCATE      31200020
         SLL   R0,T29                  SHIFT OFF ALL BUT LOW ORDER      31400020
         LTR   R0,R0                   BITS, TEST BDY FOR DOUBLE WD     31600020
         BNZ   DRAT12                    NO- WRITE MSG , TRUNCATE       31800020
         LR    R15,R1                  SAVE ADDR LAST RQE               32000020
         L     R1,RQELKP                GET ADDR NEXT RQE               32200020
         B     SEERQES                   BRANCH TO RQE SCAN             32400020
DRAT11   EQU   *                                                        32600020
         LA    R9,RQESQS          INSERT ERROR CODE                     32800020
         B     ENDRAT5             GO TO NEXT TEST                      33000020
DRAT12   EQU   *                                                        33200020
         LA    R9,RQEBDY          INSERT ERROR CODE                     33400020
ENDRAT5  EQU   *                                                        33600020
         XC    ZERO(F4,R15),ZERO(R15)   ZERO OUT LINK FIELD             33800020
         CH    R13,EIGHT          HAS EIGHT ERRORS BEEN FOUND           34000020
         BE    GOON5               GO TO NEXT TEST                      34200020
         STC   R9,D16(R2,R13)      STORE ERROR CODE IN TABLE            34400020
         LA    R13,D1(R13)        UPDATE ERROR CODE DISPLACEMENT        34600020
         B     GOON5              GO TO NEXT TEST                       34800020
*********************************************************************** 35000020
*                                                                     * 35200020
*                  VALIDITY CHECK OF ADDRESSES IN                       35400020
*                            STFRM AND STFRM2                           35600020
*                                                                     * 35800020
*********************************************************************** 36000020
STFRMVLD EQU   *                                                        36200020
         CLC   XAS(F4),MAST       IS CONTROL FROM MATR/SCHED            36400020
         BNE   EXIT               EXIT                                  36600020
         SR    R8,R8                   CLEAR R8, CHECKING STFRM         36800020
         LA     R15,STFRPOOL      DSECT FOR CORE TO BE FREED            37000020
         USING FREECORE,R15                                             37200020
         L     R1,STFRM                 GET ADDR FROM SWA               37400020
STFRMVD2 EQU   *                                                        37600020
         LA    R1,ZERO(R1)              CLEAR HIGH ORDER BYTE           37800020
         LTR   R0,R1                    IS IT ZERO                      38000020
         BNZ   AROUND                    BRANCH AROUND                  38200020
TEST     EQU   *                                                        38400020
         LTR   R8,R8                   HAS STFRM2 BEEN TESTED           38600020
         BNZ   EXIT                     PREPARE TO EXIT                 38800020
         B     SETUP2                   PREPARE TO TEST STFRM2          39000020
AROUND EQU *                                                            39200020
         SLL   R0,T29                  SHIFT OFF ALL BUT LOW ORDER      39400020
         LTR   R0,R0                   BITS, TEST BDY FOR DOUBLE WD     39600020
         BZ    FREEIT                   STFRM VALID, FREE CORE          39800020
         LA    R9,STFRMBDY        INSERT ERROR CODE                     40000020
         CH    R13,EIGHT          EIGHT ERRORS FOUND                    40200020
         BE    TEST               HAS STFRM BEEN CHECKED                40400020
         STC   R9,D16(R2,R13)     SAVE ERROR CODE                       40600020
         LA    R13,D1(R13)        UPDATE ERROR INDEX                    40800020
         B     TEST                     HAS STFRM2 BEEN CHKED           41000020
GOON5    EQU   *                                                        41200020
         SSM   ENABLE                                                   41400020
GOONDA   EQU   *                                                        41600020
         L     R5,CVTMSER               ADDR OF MRC                     41800020
         USING BASE,R5                  ADDRESSABILITY FOR MRC          42000020
         CLI   STMID,DISPLAY      IS DISPLAY ACTIVE VERB                42200020
         BNE   AROUNDD            DO NOT DENOTE ERROR                   42400020
         NI    BASFL,F-BADSP            TURN OFF DA BIT IN MRC          42600020
         LA    R9,DABIT                                                 42800020
         CH    R13,EIGHT          EIGHT ERRORS FOUND                    43000020
         BE    AROUNDD            DO NOT DENOTE ERROR                   43200020
         STC   R9,D16(R2,R13)                                           43400020
         LA    R13,D1(R13)                                              43600020
AROUNDD  EQU   *                                                        43800020
         CLC   XAS(F4),MAST       IS CONTROL FROM MASTER/SCHED          44000020
         BE    STFRMVLD           YES CHECK FREEMAIN                    44200020
         B     EXIT               EXIT                                  44400020
SETUP2   EQU   *                                                        44600020
         LA    R15,STFRPOL        ADDR OF SECOND GETMAIN                44800020
         L     R1,STFRM2                GET ADDR FOR FREEMAIN           45000020
         IC    R8,ENABLE                INDICATE TESTING STFRM2         45200020
         B     STFRMVD2                 VALIDITY CHECK STFRM2           45400020
*********************************************************************** 45600020
*                                                                     * 45800020
*         FREEING  GOTTEN CORE                                        * 46000020
*                                                                     * 46200020
*********************************************************************** 46400020
FREEIT   EQU   *                                                        46600020
         LA    R9,SIX4            INSER ERROR CODE                      46800020
         CH    R13,EIGHT          EIGHT ERRORS FOUND                    47000020
         BE    CONTINUE            CONTINUE PROCESSING                  47200020
         STC   R9,D16(R2,R13)      STORE ERROR CODE IN TABLE            47400020
         LA    R13,D1(R13)        UPDATE ERROR CODE DISPLACEMENT        47600020
CONTINUE EQU   *                                                        47800020
         SR   R0,R0                                                     48000020
         IC    R0,SUBPOOLL        SUBPOOL OF CORE TO BE FREED           48200020
         SLL   R0,D16                                                   48400020
         IC   R0,CORELNG          INSERT LENGTH OF CORE                 48600020
         SLL   R0,E8                                                    48800020
         IC   R0,CORELNG+D1       INSERT LENGTH OF CORE                 49000020
         FREEMAIN R,LV=(0),A=(1)        FREE CORE                       49200020
         LTR   R8,R8                   HAS STFRM2 BEEN TESTED           49400020
         BZ    SETUP2                   NO, PREPARE TO TEST STFRM2      49600020
EXIT     EQU   *                                                        49800020
*                                                                     * 50000020
*                 PREPARE TO EXIT                                     * 50200020
*                                                                     * 50400020
*********************************************************************** 50600020
         MVC   XAX(E8),STAEMOD3         STORE XCTL NAME IN XSA          50800020
         LA    R1,XAX                  FIND ADDR OF XCTL NAME           51000020
         ST    R1,XAP                  STORE IN XCTL PTR                51200020
         LA    R15,XAP                                                  51400020
         XC    XAD(F4),XAD                                              51600020
         XCTL  SF=(E,(15))                                              51800020
*********************************************************************** 52000020
*                                                                     * 52200020
*                STORAGE DEFINITION                                   * 52400020
*                                                                     * 52600020
*********************************************************************** 52800020
         DS    0F                                                       53000020
XMAX     DC    F'-1'              *                                     53200020
SIX4     EQU   22                 *                                     53400020
F        EQU   X'FF'              *                                     53600020
STAEMOD3 DC    CL8'IGC5303D'      *                                     53800020
         DS    0H                                                       54000020
ONE      DC    X'0001'        *                                         54200020
EIGHT    DC   H'08'           ERROR COUNT                               54400020
MAST     DC    CL4'MAST'      MASTER SCHEDULER CODE                     54600020
ENABLE   DC    X'FF'          ENABLE  MASK                              54800020
DISABLE  DC    X'00'          DISABLE MASK                              55000020
         EJECT                                                          55200020
*********************************************************************** 55400020
*                                                                     * 55600020
*                         DSECTS                                      * 55800020
*                                                                     * 56000020
*********************************************************************** 56200020
*                                                                       56400020
FREECORE DSECT                                                          56600020
SUBPOOLL DS    0C                                                       56800020
         DS    F                *                                       57000020
CORELNG  DS    H             *                                          57200020
         IEEVSTAE                                                       57400020
*                                                                       57600020
*********************************************************************** 57800020
*                                                                       58000020
STABST   DSECT               ABEND/STAE INTERFACE WORK AREA DSECT       58200020
ASWORK   DS    0F            ADDR OF STAE WORK AREA                     58400020
ASABEND  DS    F             ABEND COMPLETION CODE                      58600020
ASPSWABD DS    D             PSW AT TIME OF ABEND                       58800020
ASPSWLST DS    D             PROBLEM PROGRAM PSW                        59000020
ASREGS   DS    16F           REG SAVE AREA                              59200020
ASRB     DS    F             ADDR OF RB                                 59400020
*                                                                       59600020
*********************************************************************** 59800020
*                                                                       60000020
STGROUP  DSECT               GROUP CONTROL BLOCK DSECT                  60200020
GCB      DS    0D                                                       60400020
GLENGTH  DS    H             LENGTH OF GROUP CONTROL BLOCKS             60600020
         DS    H             RESERVED                                   60800020
GNEXT    DS    F             POINTER TO NEXT GCB                        61000020
GPROCNME DS    D             PROCNAME                                   61200020
GTASKNME DS    D             TASKNAME                                   61400020
GMEMCNT  DS    C             NUMBER OF MEMBERS IN GROUP                 61600020
GSTPCNT  DS    C             NUMBER OF PENDING STOP COMMANDS            61800020
GMDFYCNT DS    C             NUMBER OF PENDING MODIFIERS                62000020
         DS    C             RESERVED                                   62200020
GBACKPTR DS    F             BACK CHAIN POINTER                         62400020
*                                                                       62600020
*                                                                       62800020
MRC      IEEBASEA                                                       63000020
         EJECT                                                          63200020
STMSGXSA DSECT               MESSAGE AREA TABLE  XSA OF SVRB- DSECT     63400020
         IEEXSA                                                         63600020
         EJECT                                                          63800020
RQE      DSECT               RQE DSCET                                  64000020
         IEECVMUG RQE                                                   64200020
*                                                                       64400020
*********************************************************************** 64600020
*                                                                       64800020
STTQE    DSECT               TQE DSECT                                  65000020
TQEFLGS  DS    0F            INDICATORS                                 65200020
TQETCB   DS    F             ADDRESS OF TCB                             65400020
TQEFLNK  DS    F             ADDRESS OF NEXT QUEUE ELEMENT              65600020
TQEBLNK  DS    F             ADDRESS OF LAST QUEUE ELEMENT              65800020
TQEVAL   DS    F             EXPIRATION TIME-TIME LEFT                  66000020
TQELMPSW DS    F             1ST WORD PSW WHEN TQE AS IRB               66200020
TQESAV   DS    F             TO SAVE TQEVAL TASKS TO REAL               66400020
TQESADDR DS    F             ADDRESS OF PIP SAVE AREA                   66600020
TQEEXIT  DS    F             ADDRESS OF TIMER ASYNC EXIT RTN            66800020
TQEGRS   DS    16F           REG SAVE AREA IF TQE AS IRB                67000020
TQEECB   DS    0F            USED FOR IQE IF TQE AS IRB                 67200020
TQEIQ    DS    4F            FOR ECB IF PARAM=WAIT                      67400020
*                                                                       67600020
         EJECT                                                          67800020
CVTSECT  DSECT                                                          68000020
         CVT                                                            68200020
*                                                                       68400020
         EJECT                                                          68600020
STUCM    DSECT                                                          68800020
         IEECUCM                                                        69000020
*                                                                       69200020
         END                                                            69400020
