IEE5303D CSECT                                                          00200020
*A452700-453040,465500,640500                                    A50062 00250021
*C465000,465700,504500                                           A50062 00260021
         TITLE 'IEE5303D-STAE DIAGNOSTIC/ERROR MESSAGE ASSEMBLY MODULE' 00300020
*********************************************************************** 00400020
*                                                                     * 00600020
*                                                                     * 00800020
* NAME OF ROUTINE  IEE5303D-STAE DIAGNOSTIC/ERROR MESSAGE             * 01000020
*                   ASSEMBLY MODULE                                   * 01200020
*                                                                     * 01400020
* FUNCTIONS                                                           * 01600020
*      (1) ASSEMBLES AND EDITS TWO MESSAGES.                          * 01700020
*          (A) DIAGNOSTIC/ERROR MESSAGE-                              * 01800020
*              THIS MESSAGE WILL CONTAIN DIAGNOSTIC INFORMATION       * 01900020
*              CONCERNING THE FAILURE. THE FORMAT:                    * 02000020
*                                                                     * 02100020
*          IEE404I  LOCATION/ID/ERROR CODE/ABEND CODE/ PSW            * 02200020
*              WHERE:                                                 * 02300020
*                                                                     * 02400020
*              IEE404I- MESSAGE IDENTIFICATION                        * 02500020
*              LOCATION- LOCATION OF ABEND-MASTER OR SVC-34           * 02501020
*              ID- IDENTIFICATION OF DUMP                             * 02510020
*              ERROR CODE- NUMERIC CODE INDICATING TYPE OF ERROR      * 02700020
*              ABEND CODE- ABEND COMPLETION CODE                      * 02800020
*              PSW- ABEND PROGRAM STATUS WORD                         * 02900020
*                                                                     * 03000020
*              DIAGNOSTIC/ERROR CODES DESCRIBE:                       * 03100020
*              1. VALIDITY TESTS PERFORMED                            * 03200020
*              2. ERROR DISCOVERED                                    * 03300020
*              3. RESOURCE CLEAN-UPS PERFORMED                        * 03400020
*                                                                     * 03500020
*          (B) COMMAND FAILURE MESSAGE-                               * 03600020
*              THIS MESSAGE WILL INDICATE THE COMMAND WHICH           * 03700020
*              POSSIBLY CAUSED THE ERROR. THE MESSAGE MAY NOT         * 03800020
*              BE ISSUED IF THE FAILING COMMAND CANNOT BE             * 03900020
*              DETERMINED. THE FORMAT:                                * 04000020
*                                                                     * 04100020
*              IEE403I CM  ABORTED.                                   * 04200020
*              WHERE:                                                 * 04300020
*                                                                     * 04400020
*              IEE403I- MESSAGE IDENTIFICATION                        * 04500020
*              CM- THE FAILING COMMAND VERB                           * 04600020
*                                                                     * 04700020
*       (2) DETERMINES THE ISSUER OF THE SVC 34 AND PERFORMS          * 04800020
*           PARTICULAR FUNCTIONS BEFORE RETURNING                     * 05000020
*             (A) BEFORE RETURNING TO THE COMMAND SCHEDULER'S STAE    * 05200020
*                  EXIT LINKAGE IT INITIALIZES THE RETRY ROUTINE      * 05400020
*                  CODE AND MOVES IT TO THE XSA, PLACING THIS         * 05600020
*                  ADDRESS IN REGISTER 0                              * 05800020
*             (B) BEFORE RETURNING TO THE MASTER SCHEDULER'S STAE     * 06000020
*                  EXIT LINKAGES IT ISSUES A FREEMAIN FOR THE         * 06200020
*                  STAE WORK AREA  IF ABEND WAS IN IEEVWAIT           * 06400020
*                                                                     * 06600020
* ATTRIBUTES    REENTRANT,REUSEABLE,SELF-RELOCATABLE                  * 06800020
*                                                                     * 07000020
* ENTRY POINTS  IEE5303D                                              * 07200020
*                                                                     * 07400020
* INPUT         REGISTER 2-POINTER TO THE XSA                         * 07600020
*               REGISTER 10-POINTER TO THE ABEND/STAE INTERFACE       * 07800020
*                  WORK AREA                                          * 08000020
*               REGISTER 11-POINTER TO THE STAE WORK AREA             * 08200020
* OUTPUT      (1) THE XSA BUFFER IS UTILIZED TO WTO THE TWO           * 08300020
*                  STAE MESSAGES                                      * 08400020
*             (2) REGISTER 0 CONTAINS A POINTER TO THE XSA (OF        * 08500020
*                  THE SVRB STORED IN THE STAE WORK AREA)             * 08600020
*                  CONTAINING THE RETRY ROUTINE CODE IF CONTROL IS    * 09000020
*                  TO BE RETURNED TO THE COMMAND SCHEDULER'S STAE     * 09200020
*                  EXIT LINKAGE                                       * 09400020
*             (3) REGISTER 1 CONTAINS A POINTER TO THE ABEND/STAE     * 09600020
*                  INTERFACE WORK AREA IF ONE EXISTS-IT IS ZEROED     * 09800020
*                  OUT WHEN NONE IS AVAILABLE                         * 10000020
*             (4) REGISTER 15 CONTAINS A RETURN CODE OF 4             * 10200020
*                  SPECIFYING THAT RETRY IS TO BE IMPLEMENTED         * 10400020
*                                                                     * 10600020
* TABLES/WORK AREAS                                                   * 10800020
*             (1) XSA- (A)-FOR DIAGNOSTIC/ERROR MESSAGE ASSEMBLY      * 12000020
*                      (B)-TO CONTAIN RETRY ROUTINE CODE              * 12200020
*             (2) STAE WORK AREA                                      * 12400020
*                                                                     * 12600020
* OPERATION                                                           * 12800020
*       (1) MESSAGE ASSEMBLY PROCESSING                               * 12900020
*             (A) REGISTERS 0 AND 6 SAVE THE CONSOLE ID               * 13000020
*             (B) A CHECK OF THE PARM IN THE XSA DETERMINES WHETHER   * 13100020
*               CONTROL IS FROM MASTER SCHEDULER OR SVC 34            * 13200020
*             (C) REGISTER 10 IS TESTED TO DETERMINE THE PRESENCE     * 13700020
*                  OF AN ABEND/STAE INTERFACE WORK AREA.              * 13800020
*                 1. IF NONE HAS BEEN OBTAINED, THE WTO DEFINED       * 13900020
*                     STORAGE IS MOVED INTO THE XSA AND THE           * 14000020
*                     ABEND COMPLETION CODE IS UNPACKED,TRANSLATED,   * 14100020
*                     AND STORED IN THE STADDR FIELD OF THE STAE      * 14200020
*                     WORK AREA                                       * 14300020
*                 2. IF A WORK AREA IS ACCESSIBLE, THE WTO DEFINED    * 14400020
*                     STORAGE IS MOVED INTO THE XSA BUFFER AND THE    * 14500020
*                     ABEND PSW IS UNPACKED,TRANSLATED, AND MOVED     * 14600020
*                     INTO THE XSA BUFFER. THE ABEND COMPLETION       * 14700020
*                     CODE IS UNPACKED, TRANSLATED, AND STORED IN     * 14800020
*                     THE STADDR (STAE WORK AREA) FIELD.              * 14900020
*             (D) THE MODULE NAME AND ABEND COMPLETION CODE ARE       * 15000020
*                  MOVED INTO THE XSA BUFFER. THE ERROR CODE IS       * 15100020
*                  UNPACKED, TRANSLATED, AND MOVED INTO THE XSA       * 15200020
*                  BUFFER.  REGISTER 8 IS LOADED AT ENTRY WITH THE    * 15500020
*                  DUMP ID PASSED IN XAV+4 FROM IEE5103D.  BEFORE     * 15800020
*                  THE FIRST WTO IS ISSUED, THE ID IS STORED FROM     * 16100020
*                  REGISTER 8 INTO THE MESSAGE BUFFER IN THE XSA.     * 16400020
*                                                                     * 17000020
*       (2) AFTER DETERMINING THE ISSUER OF THE SVC 34, CONTROL IS    * 18400020
*           RETURNED TO THE PARTICULAR STAE EXIT LINKAGES IN THE      * 18600020
*           FOLLOWING MANNER                                          * 18800020
*             (A) COMMAND SCHEDULER THE CODE FOR THE RETRY ROUTINE    * 19000020
*                  IS INITIALIZED AND MOVED INTO THE XSA OF THE       * 19200020
*                  SVRB ADDRESSED IN THE STAE WORK AREA THE           * 19400020
*                  ADDRESS OF THE XSA IS PLACED IN REGISTER 0         * 19600020
*             (B) MASTER SCHEDULER CORE FOR THE STAE WORK AREA IS     * 19800020
*                  FREED IF ABEND OCCURRED IN IEEVWAIT                * 20000020
*             (C) IN ALL CASES                                        * 20200020
*                   THE ADDRESS OF THE ABEND/STAE INTERFACE WORK      * 20400020
*                   AREA IS LOADED INTO REGISTER 1                    * 20600020
*                   A RETURN CODE OF 4 IS LOADED INTO REGISTER 15     * 20800020
*                   TO SPECIFY THE RETRY                              * 21000020
*                                                                     * 21200020
* EXTERNAL REFERENCES                                                 * 21400020
*                 ABEND/STAE INTERFACE WORK AREA                      * 21600020
*                 EXTENDED SAVE AREA                                  * 21800020
*                 SUPERVISOR REQUEST BLOCK                            * 22000020
*                                                                     * 22200020
* MACROS          FREEMAIN                                            * 22400020
*                 WTO                                                 * 22600020
*                 IEEXSA   XSA MAPPING                                * 22800020
*                 IHBABCTL TCB MACRO                                  * 23000020
*                                                                     * 23200020
* EXITS           BR14 TO ISSUER OF SVC 34                            * 23400020
*                                                                     * 23600020
*********************************************************************** 23800020
         EJECT                                                          24000020
*********************************************************************** 24200020
*                                                                     * 24400020
*        REGISTER EQUATES                                             * 24600020
*                                                                     * 24800020
*********************************************************************** 24810020
R0       EQU   0             ADDR OF RETRY CODE FOR X LINKAGE           25000020
R1       EQU   1             ADDR OF ABND/ST INT WRKAREA FOR X LNK      25200020
R2       EQU   2             BASE OF SVRB XSA RETRY RTN AND MSGE        25400020
R3       EQU   3             WORK REG FOR MSGE ASSEMBLY                 25600020
R4       EQU   4             WORK REG FOR MSGE ASSEMBLY                 25800020
R5       EQU   5             WORK REG FOR MSGE ASSEMBLY                 26000020
R6       EQU   6             WORK REG                                   26200020
R7       EQU   7             WORK REG                                   26300020
R8       EQU   8             STORAGE FOR DUMP ID                        26330020
R9       EQU   9             WORK REG                                   26360020
R10      EQU   10            BASE FOR ABEND/STAE INTERFACE WRKAREA      26400020
R11      EQU   11            BASE OF STAE WORK AREA                     26600020
R12      EQU   12            PROGRAM BASE                               26800020
R13      EQU   13            WORK REG                                   26900020
R14      EQU   14            FOR RETURN TO CALLER                       27000020
R15      EQU   15            RETURN CODE                                27200020
*                                                                       27400020
*                                                                       27600020
*                                                                       27800020
ZERO     EQU   0              *                                         28000020
O1       EQU   1              *                                         28200020
T2       EQU   2              *                                         28400020
T3       EQU   3              *                                         28600020
F4       EQU   4              *                                         28800020
F5       EQU   5              *                                         29000020
S7       EQU   7              *                                         29200020
E8       EQU   8              *                                         29400020
N8       EQU   8              *                                         29500020
N9       EQU   9              *                                         29600020
E12      EQU   12             *                                         29650020
S16      EQU   16             *                                         29850020
T25      EQU   25             *                                         30100020
T28      EQU   28             *                                         30200020
D4       EQU   4              *                                         30210020
D40      EQU   40             *                                         30700020
D48      EQU   48             *                                         30900020
T240     EQU   C'0'          *                                          31200020
INSTREAM EQU   X'80'         INPUT STREAM COMMAND FLAG                  31250020
VDSP1    EQU   C'C'          DISPLAY ACTIVE CODE                        31280020
WAT      EQU   C'W'          CHECK IF MODULE ID IS 'W'                  31600020
BLANK    EQU   C' '          *                                          31800020
ALPHA    EQU   X'C0'         CHECK IF MODULE ID IS ALPHABETIC           32000020
         EJECT                                                          32400020
*                                                                       32600020
* BASE MODULE                                                           32800020
*                                                                       33000020
         BALR  R12,ZERO                ESTABLISH PGM ADDRESS BASE       33200020
         USING *,R12                                                    33400020
         B     IDSKIP        BRANCH AROUND ID                           33600020
         DC    X'EEEE'       ID FOR USE WHEN LOOKING AT DUMPS           33800020
         DC    CL8'IEE5303D'      *                                     34000020
         DC    X'EEEE'            *                                     34200020
IDSKIP   EQU   *                                                        34400020
*                                                                       34600020
* BASE THE XSA OF THE SVRB FOR DIAGNOSTIC MESSAGES                      34800020
*                                                                       35000020
         USING STMSGXSA,R2        BASE XSA FOR DIAGNOSTIC MSGE          35200020
*                                                                       35400020
         USING STWORK,R11         BASE STAE WORK AREA                   35500020
* GET UCMI INTO REGISTER 0                                              35600020
*                                                                       35800020
         SPACE                                                          35820020
         LA    R13,D40            MAKE R13 NON-ZERO FOR SWITCH          35920020
         L     R8,XAV+D4          RETRIEVE DUMPID FROM XSA              35970020
         SR    R4,R4              SET SWITCHES                          36020020
         SR    R3,R3              *                                     36120020
         SR    R5,R5              *                                     36220020
         SR    R0,R0              CLEAR FOR CONSOLE ID                  36320020
         CLC   XAS(F4),MASTER     IS CONTROL FROM MASTR/SCHED           36420020
         BE    INSERT             INSERT CONSOLE ID                     36520020
         LR    R9,R2              SAVE ADDR OF XSA                      36620020
         LR    R2,R11             ADDR OF OLD XSA                       36720020
         CLI   XAU,INSTREAM       COMMAND FROM INPUT STREAM             36770020
         BE    TSOTERM            IF SO, ISSUE MESSAGE TO MASTER        36780020
*                                 CONSOLE (LEAVE ID IN R0 ZERO)         36790020
         IC    R0,XAU             INSERT CONSOLE ID, IF COMMAND         36800020
*                                 NOT FROM INPUT STREAM                 36810020
TSOTERM  EQU   *                                                        36812020
         LH    R4,XAJ             ID OF TSO TERMINAL                    36920020
         LR    R2,R9              RESTORE XSA PTR                       37020020
         MVC   STVERB(E8),XAS     MOVE VERB TO SWA                      37120020
         B     PROCESS            PROCESS ERRORS                        37220020
INSERT   EQU   *                                                        37320020
         CLI   XAU,INSTREAM       COMMAND FROM INPUT STREAM             37370020
         BE    MOVEDA             IF SO, ISSUE MESSAGE TO MASTER        37380020
*                                 CONSOLE (LEAVE ID IN R0 ZERO)         37390020
         IC    R0,XAU             INSERT CONSOLE ID, IF COMMAND         37420020
*                                 NOT FROM INPUT STREAM                 37430020
MOVEDA   EQU   *                                                        37470020
         LH    R4,XAJ             TJID                                  37520020
         MVC   STVERB(E8),DISPLA  INSERT D A VERB                       37620020
         LA    R3,ALPHA           INDICATE COMMAND FROM MASTER          37720020
         CLI   STMID,VDSP1        CONTROL FROM VDSP1                    37820020
         BE    PROCESS            PROCESS ERRORS                        37920020
         MVI   STVERB,BLANK       BLANK OUT VERB NAME                   38020020
         MVC   STVERB+O1(S7),STVERB RIPPLE IN BLANKS                    38120020
PROCESS  EQU   *                                                        38220020
         SR    R6,R6              INIT INDEX REG                        38320020
         MVC   STADDR(T2),XAV+O1  MOVE COMPLETION CODE TO               38350020
*                                 STAE WORK AREA                        38380020
         LA    R7,ERRCODES        ADDR OF ERROR CODES                   38420020
         MVC   ERRCODES(E8),XAR   MOVE ERROR CODES                      38520020
LOOP     EQU   *                                                        38620020
         SR    R9,R9              INIT FOR ERRCODE                      38720020
         IC    R9,ZERO(R7,R6)     INSERT ERROR CODES                    38820020
         LTR   R9,R9              ERROR?                                38920020
         BZ    TEST1              NO ERRORS NOT PROCESSED               39020020
PROCESS1 EQU   *                                                        39120020
         CVD   R9,STFRM2            CONVERT ERROR CODE                  39220020
         UNPK  STFRM(F5),STXCTLER(T3) UNPK ERROR CODE                   39320020
         SR    R13,R13              TURN OFF FIRST TIME SWITCH          39420020
         LTR   R5,R5                FIRST TIME THROUGH LOOP             39520020
         BZ    PROCESS2             CONTINUE ERROR ANALYSIS PROCESSING  39620020
         MVC   XAT(T2),STFRM+O1     MOVE IN ERROR CODE                  39720020
         B     STWTTO               ISSUE WTO                           39820020
PROCESS2 EQU   *                                                        39920020
         CLI   STVERB,BLANK         WAS A COMMAND INVOLVED?             39930020
         MVC   XAH(MSG1-MESSAGE1),MESSAGE1 MOVE WTO LIST FOR MESSAGE1   39940020
*                                   WITH DEFAULT DESCRIPTOR AND ROUTING 39950020
*                                   CODES TO XSA.                       39960020
         BNE   YES403I              IF THERE WAS A COMMAND, KEEP THEM.  39970020
         MVC   XAH(MSG1A-MESSG1A),MESSG1A  IF NO COMMAND, MOVE WTO      39980020
*                                   LIST WITH ALTERNATE CODES TO XSA.   39990020
YES403I  EQU   *                                                        40000020
         MVC   XAT(T2),STFRM+O1     MOVE IN ERROR CODE                  40010020
         LA    R5,ALPHA             INDICATE PSW AND CODE  TRANS        40020020
         LTR   R10,R10              CK R10 TO CK FOR AB/ST INT WA       41400020
         BZ    STWTO1               NO ABEND/STAE INT WRKAREA           41700020
         USING STABST,R10           BASE THE WORK AREA                  42000020
         XC    ASWORK(F4),ASWORK    ZERO OUT 1ST WD OF WORKAREA         42200020
         EJECT                                                          42400020
*********************************************************************** 42410020
*                                                                     * 42420020
*        SET UP FOR MESSAGE IEE404I IF CORE FOR AN ABEND/STAE         * 42430020
*        INTERFACE WORK AREA WAS AVAILABLE                            * 42440020
*                                                                     * 42450020
*********************************************************************** 42460020
         SPACE                                                          42470020
         UNPK  STADDR(N9),ASPSWABD(F5)  UNPACK AND TRANSLATE            42700020
         TR    STADDR(E8),STTRTAB-T240  ABEND PSW (1ST 1/2)             42800020
         MVC   XAT+N8(E8),STADDR        INSERT 1ST 1/2 PSW              42900020
         UNPK  STADDR(N9),ASPSWABD+F4(F5)  UNPACK AND TRANSLATE         43000020
         TR    STADDR(E8),STTRTAB-T240   2ND 1/2 ABEND PSW              43100020
         MVC   XAT+S16(E8),STADDR        INSERT 2ND 1/2 PSW IN BUFF     43200020
         UNPK  STADDR(F5),ASABEND+O1(T3) UNPK AND TRANSLATE             43300020
         TR    STADDR(T3),STTRTAB-T240   ABEND COMPLETION CODE          43400020
         B     STWTO                BR TO WTO ROUTINE                   44430020
STWTO1   EQU   *                                                        44460020
         SPACE                                                          44461020
*********************************************************************** 44470020
*                                                                     * 44480020
*        SET UP FOR MESSAGE IEE404I IF CORE FOR AN ABEND/STAE         * 44490020
*        INTERFACE WORK AREA WAS NOT AVAILABLE                        * 44500020
*                                                                     * 44510020
*********************************************************************** 44520020
         SPACE                                                          44530020
         UNPK  STADDR(F5),STADDR(T3)    UNPK AND TRANSLATE              44630020
         TR    STADDR(T3),STTRTAB-T240  ABEND COMPLETE CODE             44860020
STWTO    EQU   *                                                        45200020
         ST    R8,XAF             MOVE IN ID CREATED IN IEE5103D        45260020
         SR    R8,R8              CLEAR FOR INSERT CHAR          A50062 45270021
         IC    R8,XAF+O1          PICK UP DUMP RETURN CODE       A50062 45280021
         MVI   XAF+O1,BLANK       CLEAR SAME FROM MSG BUFFER     A50062 45290021
         CVD   R8,STFRM2          CONVERT RET CODE TO DECIMAL    A50062 45300021
         UNPK  STFRM(F5),STXCTLER(T3)   UNPACK FOR PRINT         A50062 45302021
         MVC   XAF+F5(T2),STFRM+O1  MOVE RETURN CODE TO MESSAGE  A50062 45304021
         LR    R8,R0              SAVE CONSOLE ID ACROSS WTO            45310020
         B     MOVECODE           MOVE IN COMPLETION CODE, THEN WTO     45320020
TEST1    EQU   *                                                        45400020
         LTR   R13,R13            IS THIS FIRST PASS                    45440020
         BZ    VERBCHK            CHECK IF VERB WAS PROCESSING          45480020
         SR    R13,R13            DENOTE NOT FIRST PASS                 45520020
         B     PROCESS1           *                                     45560020
MOVECODE EQU   *                                                        45680020
         MVC   XAT+F4(T3),STADDR  MOVE IN COMPLETION CODE               45720020
STWTTO   EQU   *                                                        45722020
         LR    R0,R8              INSERT CONSOLE ID IN REG 0            45730020
         WTO   MF=(E,(R2))        WTO MSG FROM XSA MSG BUFF             45760020
         LA    R6,O1(R6)          INCREMENT TO NEXT ERRCODE             46060020
         LTR   R4,R4              WAS COMMAND FROM TSO TERMINAL?        46430020
         BNZ   TPUTMSG1           IF SO,GO DO TPUT TOO           A50062 46500021
CLEARIT  MVC   XAF+F5(T2),BLANKS  CLEAR RET CODE AFTER 1ST MSG   A50062 46550021
         B     LOOP               GO GET NEXT ERROR CODE         A50062 46570021
VERBCHK  EQU   *                                                        46660020
         CLI   STVERB,BLANK       WAS COMMAND EXECUTING                 46960020
         BE    STEXIT             EXIT                                  47260020
         MVI   XAH,BLANK          BLANK OUT XSA                         47560020
         MVC   XAH+O1(D40),XAH    *                                     47860020
         MVC   XAH(MSG2-MESSAGE2),MESSAGE2 INSERT WTO LIST              48160020
         MVC   XAH+E12(E8),STVERB MOVE VERB TO WTO LIST                 48460020
         LR    R0,R8              INSERT CONSOLE ID IN REG 0            48510020
         WTO   MF=(E,(R2))        ISSUE WTO FROM XSA                    48760020
         LTR   R4,R4              WAS COMMAND FROM TSO TERMINAL         49060020
         BZ    STEXIT             EXIT                                  49360020
         LH    R5,MESSAGE2        GET LENGTH OF IEE403I                 49460020
         B     TPUTIT             BRANCH AROUND MSG1 CODE.              49720020
TPUTMSG1 EQU   *                                                        49780020
         LH    R5,MESSAGE1        GET LENGTH OF IEE404I                 49840020
TPUTIT   EQU   *                                                        49900020
         LA    R1,F4(R2)          GET ADDR OF TEXT FOR TPUT             49930020
         LA    R15,F4             CALCULATE LENGTH OF TEXT              49960020
         SR    R5,R15             IN REGISTER 5                         49990020
         TPUT  (1),(5),TJID=(4)   PUT MSG TO TERMINAL                   50020020
*                                                                       50050020
         CLC   F4(E8,R2),MESSAGE1+F4  WAS IEE404I JUST WRITTEN          50250020
         BE    CLEARIT                GO CLEAR MSG DUMP CODE     A50062 50450021
         EJECT                                                          50740021
*********************************************************************** 50750020
*                                                                     * 50760020
*        STAE EXIT LINKAGE ROUTINE                                    * 50770020
*                                                                     * 50780020
*********************************************************************** 50790020
         SPACE                                                          50791020
STEXIT   EQU   *                                                        50800020
         DROP  R2                                                       51200020
         LTR   R3,R3              CONTROL FROM MASTR/SCHED              51600020
         BP    STFREE             YES                                   52000020
         LR    R3,R11             XSA ADDRESSABILITY                    52400020
         USING STMSGXSA,R3        *                                     52800020
         MVC   XAH(RTRYLNG),STRTRY PUT RETRY RTN IN XSA                 53200020
         LR    R0,R11                                                   53600020
STRETURN EQU   *                                                        54000020
         LR    R1,R10               ADDR ABND/ST INT WRK AREA-R1        54200020
         LA    R15,F4               RET CODE=4-R15 SPECIFIES RETRY      54400020
         BR    R14                  RETURN TO CALLER                    54600020
*                                                                       54800020
*                                                                       55200020
STFREE   EQU   *                                                        55400020
         LR    R1,R11               ADDR OF CORE TO BE FREED IN R1      55600020
         LA    R0,D40               LENGTH OF CORE TO BE FREED IN R0    55700020
         CLI   STMID,WAT            CHECK IF ID IS FOR VWAIT            55970020
         BNE   STRETURN             RETURN                              56070020
XWAIT    O     R0,X251M             INSERT WAIT'S SPOOL                 56250020
XFREEIT  EQU   *                                                        56320020
         FREEMAIN R,LV=(0),A=(1)                                        56400020
         B     STRETURN            RETURN                               56600020
         DS    0F                                                       56700020
*********************************************************************** 56710020
*                                                                     * 56800020
*        RETRY ROUTINE                                                * 57000020
*                                                                     * 57200020
*********************************************************************** 57210020
STRTRY   EQU   *                                                        57400020
         USING *,R12                                                    57600020
         LR    R12,R15              R15=ADDR OF RETRY RTN               57800020
         LTR   R0,R0                TEST FOR ABND/ST INT WORKAREA       58000020
         BNZ   NOWAREA              IF NOT, FREE STAE WRKAREA ONLY      58200020
         L     R0,ABNDSTAE          LOAD THE SPOOL AND LNGTH OF         58260020
*                                   FREEMN FOR A/S WRK AREA             58320020
         FREEMAIN R,LV=(0),A=(1)                                        58400020
NOWAREA  EQU   *                                                        58500020
         LA    R15,E8               RET CODE=8 FOR ISSUER OF SVC        59800020
         BR    R14                  RETURN                              60000020
         EJECT                                                          60200020
         DS    0F                                                       60300020
ABNDSTAE DC    X'FA000068'          SUBPOOL AND LENGTH                  60400020
RTRYLNG  EQU   *-STRTRY             LENGTH OF RETRY                     60600020
         EJECT                                                          60610020
*********************************************************************** 60620020
*                                                                     * 60800020
*        DEFINED CONSTANTS AND STORAGE                                * 61000020
*                                                                     * 61200020
*********************************************************************** 61210020
         SPACE                                                          61220020
         SPACE                                                          61230020
*********************************************************************** 61240020
*                                                                     * 61241020
*        THIS MESSAGE IS USED IF A COMMAND WAS INVOLVED IN THE        * 61242020
*        ABEND FROM WHICH RECOVERY IS BEING ATTEMPTED.  HENCE, THE    * 61243020
*        ROUTING CODE IS 2 (MASTER CONSOLE INFORMATION) AND THE       * 61243120
*        DESCRIPTOR CODE IS 5 (IMMEDIATE COMMAND RESPONSE).           * 61243220
*                                                                     * 61246020
*********************************************************************** 61247020
         SPACE                                                          61248020
MESSAGE1 WTO   'IEE404I             000 0000000000000000',             X61268020
               MF=L,ROUTCDE=(2),DESC=(5),MCSFLAG=(REG0,RESP)            61300020
MSG1     EQU   *                                                        61350020
         SPACE                                                          61351020
*********************************************************************** 61360020
*                                                                     * 61361020
*        THIS MESSAGE IS USED IF NO COMMAND WAS INVOLVED IN THE       * 61370020
*        ABEND FROM WHICH RECOVERY IS BEING ATTEMPTED.  HENCE, THE    * 61380020
*        ROUTING CODE IS 2 (MASTER CONSOLE INFORMATION) AND THE       * 61390020
*        DESCRIPTOR CODE IS 4 (SYSTEM STATUS).                        * 61391020
*                                                                     * 61392020
*********************************************************************** 61393020
         SPACE                                                          61394020
MESSG1A  WTO   'IEE404I             000 0000000000000000',             X61395020
               MF=L,ROUTCDE=(2),DESC=(4),MCSFLAG=(REG0,RESP)            61396020
MSG1A    EQU   *                                                        61397020
         EJECT                                                          61398020
*********************************************************************** 61399120
*                                                                     * 61399220
*        THIS MESSAGE IS ISSUED ONLY IF A COMMAND WAS INVOLVED.       * 61399320
*                                                                     * 61399420
*********************************************************************** 61399520
         SPACE                                                          61399620
MESSAGE2 WTO   'IEE403I         COMMAND ABORTED',                      X61419620
               MF=L,ROUTCDE=(2),DESC=(5),MCSFLAG=(REG0,RESP)            61450020
MSG2     EQU   *                                                        61500020
         DS    0F                                                       62200020
X251M    DC    X'FB000000'          SUBPOOL                             62300020
X255M    DC    X'FF000000'          SUBPOOL                             62400020
STTRTAB  DC    C'0123456789ABCDEF'  TRANSLATE TABLE                     62600020
STIDTAB  EQU   *                    TABLE FOR PRINTING REQ MOD IDS      62800020
DISPLA   DC    CL8'D A'             DISPLAY ACTIVE VERB                 63400020
MASTER   DC    CL8'MASTER'          MASTER CODE                         64000020
BLANKS   DC    CL2' '               BLANKS TO CLEAR DUMP CODE    A50062 64050021
         EJECT                                                          65200020
*********************************************************************** 65210020
*                                                                     * 65400020
*        DSECTS                                                       * 65600020
*                                                                     * 65800020
*********************************************************************** 65810020
*                                                                       66000020
*                                                                       66200020
STMSGXSA DSECT               DSECT-DIAGNOSTIC MSGES AND RETRY RTN       66400020
         IEEXSA                                                         66600020
         EJECT                                                          66700020
         IEEVSTAE                                                       67700020
STVERB   DS    D                       CONTAINS THE VERB NAME OF CMD    68700020
ERRCODES DS    D                       ERROR CODES                      69700020
*                                                                       71600020
STABST   DSECT               ABEND/STAE INTERFACE WORK AREA DSECT       71800020
         DS    0F                                                       71900020
ASWORK   DS    F                    STAE WORK AREA ADDR                 72000020
ASABEND  DS    F                    ABEND COMPLETION CODE               72100020
ASPSWABD DS    2F                   PSW AT TIME OF ABEND                72200020
ASPSWLST DS    2F                   PROBLEM PROGRAM PSW                 72300020
ASREGS   DS    16F                  REG SAVE AREA                       72800020
ASRB     DS    F                    ADDR OF RB                          73000020
         EJECT                                                          73100020
*                                                                       73200020
*                                                                       73400020
*                                                                       73600020
         END                                                            74000020
