         TITLE 'IEECMQWR   COMMUNICATIONS TASK WAIT AND ROUTER'         00600018
* WAIT AND ROUTER (QWR)                                                 01200018
*                                                                       01800018
* THE FUNCTION OF THIS MODULE IS TO WAIT ON ALL COMMUNICATIONS ECB'S    02400018
* (SINGLE EVENT). IT RUNS AS A SUBTASK OF THE MASTER SCHEDULER TCB      03000018
* AND GIVES CONTROL TO THE ROUTER FUNCTION WHEN ANY OF THE ECB'S        03080018
* ARE POSTED.                                                           03160018
* THE ROUTER CHECKS THE ECB'S IN A PRIORITY SCHEME AS FOLLOWS-          03240018
* RMS,EXTERNAL,ATTENTION,I/O, WTO/R, DOM, AND LOG INITIALIZATION.THESE  03280020
* ECB'S ARE CHECKED IN SUCH A WAY THAT WHENEVER AN ECB IS POSTED AND A  03320018
* SERVICE IS PERFORMED, THE ROUTINE RETURNS TO THE BEGINNING (WREXT),   03360018
* CHECKS THE RMS ECB AND CONTINUES FROM THERE.  WHEN ALL                03400020
* ECB'S HAVE BEEN CHECKED, AND NOTHING IS POSTED, THE ROUTER RETURNS    03440018
* TO THE WAIT MODULE.                                                   03480018
*                                                                       03560018
* ENTRY POINT - IEECMWRT                                                03640018
*                                                                       03720018
* MODULE NAME- IEECMQWR                                                 03800018
*                                                                       03880018
* INPUT- POSTING OF ECB'S                                               03960018
*                                                                       04040018
* OUTPUT- SERVICING POSTED ECB'S BY GIVING CONTROL TO APPROPRIATE       04120018
*         ROUTINES                                                      04200018
*                                                                       04280018
* EXTERNAL ROUTINES -                                                   04360018
*        IGCR107B FOR RMS INTERRUPT                                     04400020
*        IGCXL07B FOR EXTERNAL INTERRUPT                                04440018
*        IEECMDSV FOR ATTENTION,I/O COMPLETE, AND OUTPUT                04520018
*        IEECMWSV FOR WTO/R SERVICE                                     04600018
*        IEECMDOM FOR DOM SERVICE                                       04680018
*        IGC0907B FOR SERVICE AFTER THE LOG HAS BEEN INITIALIZED        04720018
*                                                                       04760018
* EXITS- NONE                                                           04840018
*                                                                       04920018
* ATTRIBUTES- REFRESHABLE, REENTRANT                                    05000018
*                                                                       05080018
         EJECT                                                          05160018
IEECVCTW CSECT                                                          05560018
*APARS                                                           A26818 05570019
*OWNERSHIP  19472                                                   MCH 05580019
         ENTRY IEECVCA0                                             MCH 05610019
         ENTRY IEECVCA1                                             MCH 05660019
IEECVCA0 EQU   *                                                    MCH 05710019
*MODULE CREATED FOR MCS - REL 18                                        05760018
         EXTRN IEECMDSV                                                 06000018
         EXTRN IEECMWSV                                                 06600018
         EXTRN IEECMDOM                                                 07200018
         ENTRY WRABXLE                                                  07500018
         USING CVTDSECT,10                                              07800018
R0       EQU   0                   WORKREG                              08400018
R1       EQU   1                   PARAMETER REGISTER                   09000018
R2       EQU   2                   UCM BASE                             09600018
R3       EQU   3                   RESERVED FOR DEVSERV                 10200018
R4       EQU   4                   MCS UCM BASE                         10800018
R5       EQU   5                   INDEX REGISTER                       11400018
R6       EQU   6                   WORKREG                              12000018
R7       EQU   7                   WORKREG                              12600018
R8       EQU   8                   EIL BASE                             13200018
R9       EQU   9                   BASE REG                             13800018
R10      EQU   10                  RESERVED FOR WTOSERV                 14400018
R11      EQU   11                  UCM ENTRY                            15000018
R12      EQU   12                  BXLE                                 15600018
R13      EQU   13                   REGS                                16200018
R14      EQU   14                  RETURN REG                           16300018
R15      EQU   15                  BRANCH REG                           16400018
FOUR     EQU   4                                                        16500018
ZERO     EQU   0                                                        16600018
EIGHT    EQU   8                                                        16700018
SIXTEEN  EQU   16                                                       16800018
SWRTN    EQU   72                                                       16900018
ONE      EQU   1                                                        17000018
MASK255  EQU   255                                                      17100018
HEXF0    EQU   X'F0'                                                    17200018
KWAIT    EQU   X'00'                                                    17400018
EIGHTY   EQU   X'80'                                                    17600018
TWO      EQU   X'02'                                             A26818 17700019
FD       EQU   X'FD'                                             A26818 17800019
ASYN     EQU   X'1D'               DISP. IN TCB.              BB A43808 17850021
TCBDAR   EQU   172                 DAR BIT DISP IN TCB        BB A43808 17900021
TBDAR    EQU   X'80'               DAR BIT IN TCB             BB A43808 17950021
ASYBT    EQU   X'FE'               ASY. EXIT BIT              BB A43808 17960021
      EJECT                                                             18000018
*********************************************************************** 18070018
*                                                                     * 18140018
*        IEECMWRT GETS CONTROL AFTER SYSTEM INITIALIZATION.           * 18210018
*        IT SETS UP ENVIRONMENTAL REGISTERS FOR ALL COMMUNICATIONS    * 18280018
*        TASK RESIDENT ROUTINES. IT THEN GIVES CONTROL TO CTWSTART    * 18350018
*                                                                     * 18420018
*********************************************************************** 18490018
IEECMWRT EQU   *                                                        18600018
         BALR  R9,R0               SET UP BASE REGISTERS                19200018
         USING *,9                                                      19800018
         L     R10,CVTPTR              LOAD CVT POINTER                 20400018
         L     R2,CVTCUCB          GET ADRS OF UCM                      21000018
         USING UCMXECB,R2                                               21600018
         L     R3,UCMVEA           INITIALIZE UCM ENTRY PTR             22200018
         LA    R5,UCMXECB          INITIALIZE                           22600018
         LA    R4,FOUR             UCM                                  23000018
         SR    R5,R4               PREFIX                               23400018
         L     R4,CVTPTR           POINTER TO CVT.            BB A43808 23450021
         L     R4,ZERO(R4)         POINTER TO NEW-OLD         BB A43808 23460021
         L     R4,FOUR(R4)         POINTER TO CURRENT TCB     BB A43808 23500021
         TM    TCBDAR(R4),TBDAR    COMM. TASK IN DAR?         BB A43808 23550021
         BNO   NOTCBDAR            NO. NO NEED TO TURN FLAG.  BB A43808 23600021
         NI    ASYN(R4),ASYBT      TURN OFF PROHIB. ASSY.     BB A43808 23650021
*                                  EXIT BIT.                  BB A43808 23700021
NOTCBDAR EQU   *                                              BB A43808 23750021
         L     R4,ZERO(R5)         BASE REG                             24000018
         USING UCMMCENT,R4                                              24600018
         USING UCMLIST,R11                                              24610018
         L     R8,UCMLSTP          INITIALIZE EIL PTR                   24620018
         USING EIL,R8                                                   24630018
         SPACE 2                                                        24660018
*********************************************************************** 24720018
*                                                                     * 24780018
*        CTWSTART ISSUES A WAIT ON ALL COMMUNICATIONS ECB'S.          * 24840018
*        THIS BECOMES THE ENTRY POINT OF THE WAIT MODULE AFTER        * 24900018
*        IEECMWRT EXITS.                                              * 24960018
*                                                                     * 25020018
*********************************************************************** 25080018
CTWSTART EQU   *                                                        25680018
         LA    R1,EILSL                 POINT R1 TO ECB LIST            26400018
         LR    R6,R1                                                    26450018
TSTWAIT  EQU   *                                                        26500018
         TM    ZERO(R6),EIGHTY   IS THIS LAST ECB                       26550018
         BO    LASTECB            YES                                   26600018
         L     R7,ZERO(R6)        ADDRESS THE ECB                       26650018
         NI    ZERO(R7),WAITOFF   TURN WAIT BIT OFF           BE A44624 26700021
WAITOFF  EQU   X'7F'                                          BE A44624 26710021
         LA    R6,FOUR(R6)       ADDR OF NEXT ECB POINTER               26750018
         B     TSTWAIT            TEST NEXT ECB                         26800018
LASTECB  EQU   *                                                        26850018
         L     R7,ZERO(R6)        LAST ECB POINTER                      26900018
         NI    ZERO(R7),WAITOFF   TURN WAIT BIT OFF           BE A44624 26950021
CTWAIT   WAIT  ECBLIST=(1)                                              27000018
      EJECT                                                             27600018
*                                                                       28200018
*                   ROUTER   MODULE                                     28800018
*                                                                       29400018
**********************************************************************  33680018
*                                                                     * 33760018
*        SERVICE EXTERNAL INTERRUPTS BY GOING TO IGCXL07B FOR         * 33840018
*        EVERY INTERRUPT                                              * 33920018
*                                                                     * 34000018
**********************************************************************  34080018
         SSM   DISABLE                                                  34140018
WREXT    EQU   *                                                        34190020
RMSCHK   EQU   *                                                        34240020
         TM    UCMRECB,POST        RMS ECB POSTED                       34290020
         BZ    WREXT1              NO-CONTINUE NORMAL PROCESSING  20061 34340020
         LA    R1,ADRMSNAM         GET ADDRESS OF RMS MODULE      20061 34390020
         L     R0,UCMRECB          SAVE ADDRESS IN PARAMETER REG  20061 34440020
         XC    UCMRECB(FOUR),UCMRECB CLEAR ECB                    20061 34490020
         SVC   SWRTN               ISSUE SVC 72 TO ROUTER         20061 34540020
         B     WREXT               CONTINUE SEARCH FOR POSTED ECB 20061 34590020
WREXT1   EQU   *                                                  20061 34640020
         CLI   UCMXCT,ZERO         HAS EXTERNAL ECB BEEN POSTED   20061 34690020
         BE    WRATTN              NO, CHECK ATTENTION ECB              34800018
         SR    R6,R6                                                    35400018
         IC    R6,UCMXCT           GET NUMBER OF TIMES POSTED           36000018
         BCTR  R6,R0               DECREMENT BY ONE                     36600018
         STC   R6,UCMXCT           STORE NEW COUNT OF UNSERVICED POSTS  37200018
         MVC   UCMXSA+EIGHT(R8),WREXTNAM  NAME OF EXT. SWITCH RTN       37800018
         MVI   UCMXSA+SIXTEEN,XSWITCH   INDICATE                        38400018
         LA    R1,UCMXSA+EIGHT          EXTERNAL INTERRUPT              39000018
         SVC   SWRTN               SVC 72 - GO TO SWITCH RTN            39600018
         B     WREXT               SERVICE ANY UNSERVICED EXTERNAL INT. 40200018
**********************************************************************  40280018
*                                                                     * 40360018
*        GO THROUGH CONSOLE ENTRIES,AND WHENEVER AN ATTENTION IS      * 40440018
*        PENDING, GO TO ROUTINE WRATSERV.                             * 40520018
*                                                                     * 40600018
**********************************************************************  40680018
WRATTN   XC    UCMXECB(FOUR),UCMXECB    CLEAR EXTERNAL ECB              41280018
         TM    UCMAECB,POST        HAS ATTENTION ECB BEEN POSTED        41880018
         BZ    WRIOCOMP            NO,CHECK I/O ECB'S                   42600018
         TM    UCMSFLGS+ONE,TWO   WAS ATTN POSTED BY WTL         A26818 42800019
         BNO   WRALOOP1           NO - REGULAR ATTENTION         A26818 43000019
         LA    R1,EIGHT           SIGNAL CLEANUP                 A26818 43200019
         NI    UCMSFLGS+ONE,FD    TURN OFF FLAG                  A26818 43400019
         B     WRAWTLSV           GO TO DSV                      A26818 43800019
WRALOOP1 LM    R11,R13,UCMVEA     INITIALIZE BXLE UCM ENTRY REGS A26818 44000019
WRALOOP  TM    UCMSTS,UCMAF        IS ATTN PENDING FOR THIS ENTRY       44200018
         BNO   WRABXLE            NO,BRANCH TO GET NEXT ENTRY    A33847 44600020
         TM    UCMATR,ACTIVE      IS THIS DEVICE ACTIVE ?        A33847 45000020
         BO    WRATSERV            YES, BRANCH                          45600018
         NI    UCMSTS,MASK255-ATTN NO-TURN OFF ATTENTION FLAG    A33847 45900020
WRABXLE  BXLE  R11,R12,WRALOOP     NO,GET NEXT ENTRY                    46200018
         XC    UCMAECB(FOUR),UCMAECB    CLEAR ATTENTION ECB             46270018
**********************************************************************  46340018
*                                                                     * 46410018
*        GO THROUGH LIST OF I/O ECB'S, AND WHENEVER ONE IS POSTED     * 46480018
*        COMPLETE, GO TO ROUTINE WRIOSERV.                            * 46550018
*                                                                     * 46620018
**********************************************************************  46690018
WRIOCOMP LM    R11,R13,UCMVEA      GET BXLE UCM ENTRY REGS              47290018
         SR    R6,R6                                                    48000018
WRIOLOOP EQU   *                                                        49200018
         L     R1,EILIOL(R6)       GET ADRS OF THIS ENTRY'S ECB         50200018
         TM    ZERO(R1),POST       IS IT POSTED COMPLETED               51200018
         BO    WRIOSERV            YES, BRANCH                          52200018
WRIOBXLE LA    R6,FOUR(R6)         INCREMENT ECB PTR ADDRESS            52600018
         BXLE  R11,R12,WRIOLOOP    AND ENTRY ADDRESS TO DO NEXT ENTRY   53000018
         EJECT                                                          53450018
**********************************************************************  53500018
*                                                                     * 53600018
*        IF WE ARE STILL PROCESSING CONSOLE OUTPUT QUEUES,            * 53700018
*        CONTINUE PROCESSING BY GOING TO IEECMDSV WITH OUTPUT CODE.   * 53800018
*        (REGISTER 3 POINTS TO NEXT CONSOLE ENTRY TO BE PROCESSED)    * 53900018
*                                                                     * 54000018
**********************************************************************  54100018
WRDVSERV C     R3,UCMVEA           ARE WE IN THE MIDDLE OF 'DEVSERV'    54900018
         BNE   WROUTPUT            YES                                  55200018
         TM    UCMSFLGS+ONE,OUTPUT NO, BUT IS THERE H.C. OUTPUT TO DO   55500018
         BZ    WRWTO               NO, CHECK WTO/R ECB                  55800018
         NI    UCMSFLGS+ONE,MASK255-OUTPUT  TURN OFF H.C. OUTPUT FLAG   55900018
WROUTPUT EQU   *                                                        56100018
         L     R15,ADDVSV          YES, GO BACK TO 'DEVSERV'            56400018
         SR    R1,R1               CODE=0 FOR OUTPUT                    57100018
         BALR  R14,R15             GO TO 'DEVSERV'                      57800018
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         58500018
**********************************************************************  59450018
*                                                                     * 59500018
*        IF WE ARE NOT STILL PROCESSING CONSOLE OUTPUT QUEUES,        * 59550018
*        SERVICE A POSTED WTO/R ECB BY GOING TO IEECMWSV.             * 59600018
*        NOTE- WHEN IEECMWSV FINISHES QUEUEING, IT GOES TO IEECMDSV   * 59650018
*        TO START PROCESSING CONSOLE OUTPUT QUEUES. THIS GETS US      * 59700018
*        INTO THE PREVIOUS LOOP, AND THE WTO/R ECB IS NOT CHECKED     * 59750018
*        AGAIN UNTIL ALL CONSOLE QUEUES HAVE BEEN PROCESSED.          * 59800018
*                                                                     * 59850018
**********************************************************************  59900018
WRWTO    TM    UCMOECB,POST        IS WTO/R ECB POSTED                  60200018
         BZ    WRCLNUP             NO,DO NEXT SERVICE                   60600018
         XC    UCMOECB(FOUR),UCMOECB    YES, CLEAR ECB                  61200018
         L     R15,ADWTOSV         GET ADDRESS OF WTO/R SERVICE         61800018
         BALR  R14,R15             GO TO WTO/R SERVICE                  62400018
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         63000018
**********************************************************************  63680018
*                                                                     * 63760018
*        IF THE SYSTEM WQE QUEUE NEEDS TO BE CONSOLIDATED,            * 63840018
*        GO TO IEECMDSV WITH CLEANUP CODE.                            * 63920018
*                                                                     * 64000018
**********************************************************************  64080018
WRCLNUP  TM    UCMSFLGS+ONE,CLEANUP     IS CLEANUP SERVICE NEEDED       64680018
         BZ    WRDOM               NO,DO NEXT SERVICE                   65400018
         LA    R1,EIGHT            YES, CODE=4 FOR CLEANUP              66000018
         L     R15,ADDVSV          GET ADDRESS OF DEQ RTN               66600018
         NI    UCMSFLGS+ONE,MASK255-CLEANUP  TURN OFF CLEANUP INDICATOR 67200018
         BALR  R14,R15             GO TO DEQ RTN                        67800018
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         67840018
         EJECT                                                          67880018
**********************************************************************  67940018
*                                                                     * 68010018
*        IF THE DOM ECB HAS BEEN POSTED, GO TO THE DOM SERVICE RTN    * 68080018
*        (IEECMDOM).                                                  * 68150018
*                                                                     * 68220018
**********************************************************************  68290018
WRDOM    TM    UCMDECB,POST        IS DOM ECB POSTED                    68890018
         BZ    PXFOXL              NO, GO TO SYSLOG CHECKER ROUTINE     69390018
         SR    R0,R0                                                    69900018
         L     R15,ADDOM           YES, GET ADDRESS OF DOM SERVICE      70300018
         BALR  R14,R15             GO TO DOM SERVICE                    70800018
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         71100018
**********************************************************************  71480018
*                                                                     * 71560018
*        IF AN ATTENTION OR I/O COMPLETE IS PENDING, SERVICE BY       * 71640018
*        GOING TO IEECMDSV.                                           * 71720018
*                                                                     * 71800018
*********************************************************************** 71880018
WRIOSERV OI    UCMDEVC,IOCOMP      CODE=4 FOR ATTN OR I/O               72000018
WRATSERV LA    R1,FOUR             CODE=4 FOR ATTN OR I/O               72600018
WRAWTLSV EQU   *                                                 A26818 72900019
         L     R15,ADDVSV          GET ADDRESS OF 'DEVSERV'             73200018
         BALR  R14,R15             GO TO 'DEVSERV'                      73800018
         B     WREXT               RETURN TO CHECK EXTERNAL ECB         74400018
*********************************************************************** 74480018
*                                                                     * 74560018
*        IF THE LOG INITIALIZATION ECB HAS BEEN POSTED, GO TO         * 74640018
*        SERVICE ROUTINE (IGC0907B) TO CHECK IF HARDCOPY IS SYSLOG    * 74720018
*                                                                     * 74800018
*********************************************************************** 74880018
PXFOXL   DS    0H                                                       75000018
         TM    UCMNPECB,POST       HAS LOG JUST BEEN INITIALIZED    MCS 75080018
         BZ    CTWSTART            NO, GO TO WAIT MODULE            MCS 75160018
         LA    R1,WTL4NIP          YES, GET ADDR OF SYSLOG SERVICE  MCS 75240018
         SVC   SWRTN               SVC72 SEE IF HARDCOPY IS SYSLOG  MCS 75320018
         XC    UCMNPECB(FOUR),UCMNPECB   CLEAR LOG ECB IN UCM       MCS 75400018
         B     WREXT               GO TO CHECK EXTERNAL ECB         MCS 75480018
         SPACE 2                                                        75680018
         ENTRY PXFOXL              IDENTIFY BRANCH POINT                79200018
         EJECT                                                          80200018
CLEANUP  EQU   X'80'                                                    80400018
IOCOMP   EQU   X'08'                                                    81000018
POST     EQU   X'40'                                                    81600018
OUTPUT   EQU   X'40'                                                    81900018
ACTIVE   EQU   X'10'                                             A33847 82000020
ATTN     EQU   X'80'                                             A33847 82100020
WREXTNAM DC    CL8'IGCXL07B'       NAME OF CONSOLE SWITCH ROUTINE       82200018
WTL4NIP  DC    CL8'IGC0907B'       NAME OF SYSLOG CHECK ROUTINE     MCS 82500018
ADRMSNAM DC    CL8'IGCR107B'       NAME OF RMS MODULE             20061 82700020
ADDVSV   DC    A(IEECMDSV)         ADDRESS OF DEVSERV                   82900018
ADWTOSV  DC    A(IEECMWSV)         ADDRESS OF WRITE SERVICE             83300018
ADDOM    DC    A(IEECMDOM)         DOM RTN                              83700018
CTWCUCM  DC    V(IEECVUCM)         UCM                                  84100018
XSWITCH  EQU   X'04'                                                    84700018
DISABLE  DC    X'00'               DISABLE INTERRUPTS                   84800018
IEECVCA1 EQU   *                                                    MCH 85000019
         EJECT                                                          85200018
EIL      DSECT                                                          85800018
         IEECVMUG EIL                                                   86400018
         SPACE 3                                                        87000018
UCM      DSECT                                                          87600018
         IEECUCM                                                        88200018
WQE      DSECT                                                          88800018
         IEECVMUG    WQE                                                89400018
CVTDSECT DSECT                                                          90000018
         CVT                                                            90600018
         END                                                            91200018
