*********************************************************************** 00900018
*                                                                       01800018
*ROUTINE NAME  .IEEPDISC - GET/FREE REGION FOR THE DISPLAY CONSOLES     02700018
*               ROUTINE (MODLIB NAME - IEEPDISC)                        03600018
*                                                                       04500018
*FUNCTION      .TO SET UP THE NECESSARY ENVIRONMENT FOR THE DISPLAY     05400018
*               CONSOLES ROUTINE - IEEXEDNA - IN AN MVT CONFIGURATION   06300018
*                                                                       07200018
*PROGRAM FLOW  .ISSUE A GETMAIN FOR A REGION FOR IEEXEDNA               08100018
*              .ISSUE A GETMAIN FOR A 72 BYTE REGISTER SAVE AREA (RSA)  09000018
*              .STORE REGISTERS IN RSA FOR IEEXEDNA                     09900018
*              .LINK TO IEEXEDNA WITH A POINTER TO THE CSCB IN REGISTER 10800018
*               1 AND A POINTER TO RSA IN REGISTER 13                   11700018
*            ON RETURN-                                                 12600018
*              .ISSUE A FREEMAIN FOR THE CORE ACQUIRED FOR THE RSA      13500018
*              .ISSUE A FREEMAIN FOR THE REGION ACQUIRED FOR IEEXEDNA   14400018
*              .RETURN TO MASTER TASK                                   15300018
*                                                                       16200018
*CSECT NAME    .IEEPDISC - ATTACHED BY MASTER TASK                      17100018
*                                                                       18000018
*ATTRIBUTES    .REENTRANT                                               18900018
*              .READ ONLY                                               19800018
*                                                                       20700018
*********************************************************************** 21600018
* EXTERNAL     .IEEXEDNA - DISPLAY CONSOLES ROUTINE                     22500018
*REFERENCES                                                             23400018
*                                                                       24300018
*SVC USAGE     .GETMAIN                                                 25200018
*              .LINK                                                    26100018
*              .FREEMAIN                                                27000018
*              .SVC 3                                                   27900018
*                                                                       28800018
*INPUT         .REGISTER 1 CONTAINS A POINTER TO THE CSCB               29700018
*                                                                       30600018
* TABLES       .NONE                                                    31500018
*MAPPINGS                                                               32400018
*                                                                       33300018
*OUTPUT        .REGISTER 1 CONTAINS A POINTER TO THE CSCB               34200018
*                                                                       35100018
*EXIT          .RETURN TO MASTER TASK                                   36000018
*                                                                       36900018
*********************************************************************** 37800018
         SPACE                                                          38700018
*********************************************************************** 39600018
*                        REGISTER USAGE                                 40500018
*********************************************************************** 41400018
         SPACE                                                          42300018
R0       EQU   0              SUBPOOL ID AND REGION SIZE FOR GETMAIN    43200018
R1       EQU   1              PASSING PARAMETERS                        44100018
R2       EQU   2                                                        45000018
R3       EQU   3              SAVE CSCB POINTER                         45900018
R4       EQU   4                                                        46800018
R5       EQU   5                                                        47700018
R6       EQU   6                                                        48600018
R7       EQU   7              SAVES REGISTER 0                          49500018
R8       EQU   8                                                        50400018
R9       EQU   9              BASE REGISTER FOR IEEPDISC ADDRESSABILITY 51300018
R10      EQU   10                                                       52200018
R11      EQU   11                                                       53100018
R12      EQU   12                                                       54000018
R13      EQU   13             POINTER TO RSA                            54900018
R14      EQU   14                                                       55800018
R15      EQU   15                                                       56700018
ZERO     EQU   0                                                    MCS 56800018
THR      EQU   3                                                    MCS 56900018
FOUR     EQU   4                                                    MCS 57000018
TEN      EQU   10                                                   MCS 57100018
TWEL     EQU   12                                                   MCS 57200018
IEEPDISC CSECT                                                          57600018
         BALR  R9,ZERO                     SET UP ADDRESSABILITY        58500018
         USING *,R9                                                     59400018
         LR    R3,R1                    SAVE CSCB POINTER               60300018
*********************************************************************** 61200018
*                                                                     * 62100018
*      SET UP REGISTER 0 WITH SUBPOOL NUMBER 247 AND REGION SIZE OF   * 63000018
*    8K AND ISSUE GETMAIN FOR DISPLAY CONSOLES ROUTINE                * 63900018
*      ISSUE GETMAIN FOR A 72 BYTE REGISTER SAVE AREA (RSA)           * 64800018
*                                                                     * 65700018
*********************************************************************** 66600018
         LH    R0,IEESIZE               SET UP REG.0 WITH REGION SIZE   67500018
         SLL   R0,TEN                                                   68400018
         O     R0,SUBPOOL               AND SUBPOOL NUMBER              69300018
         LR    R7,R0                    SAVE REG.0 FOR FREEMAIN         70200018
         GETMAIN  R,LV=(0)              GET REGION FOR DISPLAY CONSOLES 71100018
         GETMAIN  R,LV=72               GET CORE FOR RSA                72000018
*********************************************************************** 72900018
*                                                                     * 73800018
*      STORE REGISTERS IN RSA FOR DISPLAY CONSOLES ROUTINE AND ISSUE  * 74700018
*    A LINK TO THE DISPLAY CONSOLES ROUTINE WITH A POINTER TO THE     * 75600018
*    CSCB IN REGISTER 1 AND A POINTER TO RSA IN REGISTER 13           * 76500018
*                                                                     * 77400018
*********************************************************************** 78300018
         LR    R13,R1                   SAVE RSA POINTER                79200018
         STM   R14,R12,TWEL(R13)        STORE REGS IN RSA               80100018
         LR    R1,R3                    RESTORE CSCB POINTER            81000018
         LINK  EP=IEEXEDNA              LINK TO DISPLAY CONSOLES        81900018
*********************************************************************** 82800018
*                                                                     * 83700018
*      ON RETURN- FREE THE CORE ACQUIRED FOR RSA AND THE REGION       * 84600018
*    ACQUIRED FOR DISPLAY CONSOLES AND RETURN CONTROL TO THE MASTER   * 85500018
*    TASK.                                                            * 86400018
*                                                                     * 87300018
*********************************************************************** 88200018
         LR    R1,R13                   PLACE RSA POINTER IN REG.1      89100018
         FREEMAIN  R,LV=72,A=(1)        FREE RSA                        90000018
         LR    R0,R7                    RESTORE REG.0 TO DEFINE REGION  90900018
         LA    R1,FOUR                    MAKE REG1 POSITIVE.           91800018
         FREEMAIN  R,LV=(0),A=(1)       FREE GOTTEN REGION              92700018
         SVC   THR                        RETURN CONTROL                93600018
IEESIZE  DC    H'8'                     8K REGION SIZE                  94500018
         DS    0F                                                       95400018
SUBPOOL  DC    XL1'F7'                  SUBPOOL 247                     96300018
         DC    XL3'000000'              ZERO OUT 3 BYTES                97200018
         END                                                            98100018
