IEEVDRGN CSECT                                                     RORI 00020015
*0053000200-075800                                                 RORI 00040015
****************************************************************** RORI 00060015
*                                                                * RORI 00080015
*   TITLE- IEEVDRGN (DISPLAY ACTIVE)                             * RORI 00100015
*                                                                * RORI 00120015
*   FUNCTION- THIS    ROUTINE IS A SUBROUTINE OF IEEVDSP1. IT IS * RORI 00140015
*   USED TO CALCULATE THE AMOUNT OF SYSTEM QUEUE SPACE AND THE   * RORI 00160015
*   BEGINNING & ENDING ADDRESSES OF ALL REGIONS OWNED BY A TASK. * RORI 00180015
*                                                                * RORI 00200015
*   APPLICABILITY- OPTION 4, MULTI-PROGRAMMING WITH A VARIABLE   * RORI 00220015
*      NUMBER OF TASKS.                                          * RORI 00240015
*                                                                * RORI 00260015
*   EXTERNAL REFERENCES- NONE                                    * RORI 00280015
*                                                                * RORI 00300015
*   ENTRY POINT- IEEVDRGN, BRANCH ENTRY FROM IEEVDSP1.           * RORI 00320015
*                                                                * RORI 00340015
*   INPUT- THE INPUT FOR THE ROUTINE IS PROVIDED IN REGISTERS    * RORI 00360015
*      ZERO, ONE, AND TWO.  THEY CONTAIN THE FOLLOWING:          * RORI 00380015
*      1.  REGISTER ZERO-ADDRESS OF TCB WHOSE SQS AND REGION     * RORI 00400015
*          BOUNDS ARE TO BE CALCULATED.                          * RORI 00420015
*      2.  REGISTER ONE-ADDRESS OF START OF WORK AREA.           * RORI 00440015
*      3.  REGISTER TWO-ADDRESS OF END OF WORK AREA.             * RORI 00460015
*                                                                * RORI 00480015
*   OUTPUT- THE OUTPUT TO THIS ROUTINE IS PROVIDED IN REGISTERS  *      00500015
*      ZERO, ONE, AND TWO AND IN A WORK AREA.  THEY ARE          *      00520015
*      1.  REGISTERS ZERO AND TWO ARE THE SAME AS FOR INPUT. REG.* RORI 00540015
*          ONE NOW CONTAINS  UPDATED START OF WORK AREA ADDRESS. * RORI 00560015
*      2.  THE WORK AREA IS NOW FORMATTED AS SHOWN BELOW:        * RORI 00580015
*             BYTE 0    NUMBER OF ENTRIES                        * RORI 00600015
*             BYTES 1-3 APPROXIMATE SQS SPACE                    * RORI 00620015
*             BYTE 4 INDICATION OF OWNED,BORROWED,OR ROLLED OUT  * RORI 00640015
*             BYTES 5-7 REGION SEGMENT START ADDRESS             * RORI 00660015
*             BYTE 8    RESERVED FOR LCS                         * RORI 00680015
*             BYTES 9-11 REGION SEGMENT END ADDRESS              * RORI 00700015
*                                                                * RORI 00720015
*             BYTES 4-11 WILL BE REPEATED FOR EACH ADDITIONAL    * RORI 00740015
*                         REGION SEGMENT                         * RORI 00760015
*                                                                * RORI 00780015
*   EXTERNAL ROUTINES- NONE                                      * RORI 00800015
*                                                                * RORI 00820015
*   EXITS- ALL EXITS ARE TO IEEVDSP1.  A RETURN CODE OF ZERO     * RORI 00840015
*      INDICATES NO PROBLEMS. A RETURN CODE OF EIGHT INDICATES   * RORI 00860015
*      END OF WORK BEFORE COMPLETION OF PROCESSING.              * RORI 00880015
*                                                                * RORI 00900015
*   TABLES AND CONTROL BLOCKS REFERENCED                         * RORI 00920015
*      1.  COMMUNICATION VECTOR TABLE (CVT)                      * RORI 00940015
*          A. CVTHEAD- TOP TCB IN READY QUEUE                    * RORI 00960015
*          B. CVTABEND- ADDRESS OF SECONDARY CVT                 * RORI 00980015
*      2.  SECONDARY CVT                                         * RORI 01000015
*          A. ADDRESS OF QCB ORIGIN                              * RORI 01020015
*      3.  TASK CONTROL BLOCK                                    * RORI 01040015
*          A. TCBRBP- ADDRESS OF RB                              * RORI 01060015
*          B. TCBLLS- ADDRESS OF LLE                             * RORI 01080015
*          C. TCBJPQ- ADDRESS OF CDE                             * RORI 01100015
*          D. TCBQEL- NO. OF ENQUEUES                            * RORI 01120015
*          E. TCBTCB- ADDRESS OF NEXT LOWER PRIORITY TCB         * RORI 01140015
*          F. TCBJSTCB- ADDRESS OF JOB STEP TCB                  * RORI 01160015
*          G. TCBPQE- ADDRESS OF PQE                             * RORI 01180015
*          H. TCBAQE- ADDRESS OF AQE                             * RORI 01200015
*      4.  PARTION QUEUE ELEMENT                                 * RORI 01220015
*          A. PQEPQE- NEXT PQE                                   * RORI 01240015
*          B. PQEREGON- SIZE OF REGION                           * RORI 01260015
*          C. PQEADDR- START ADDRESS OF REGION                   * RORI 01280015
*                                                                * RORI 01300015
*   ATTRIBUTES- DISABLED,OPERATES IN SUPERVISOR STATE,RESIDENT,  * RORI 01320015
*      AND NON-REENTRANT                                         * RORI 01340015
*                                                                * RORI 01360015
*   NOTES- NONE                                                  * RORI 01380015
****************************************************************** RORI 01400015
         EJECT                                                     RORI 01420015
*   REGISTER ASSIGNMENT                                            RORI 01440015
TCBREG   EQU   0                        INPUT TCB                  RORI 01460015
STARTREG EQU   1                        START OF WORK AREA         RORI 01480015
ENDREG   EQU   2                        END OF WORK AREA           RORI 01500015
TCBCREG  EQU   3                                                   RORI 01520015
WORKREG1 EQU   4                        GENERAL USE                RORI 01540015
WORKREG2 EQU   5                        GENERAL USE                RORI 01560015
WORKREG3 EQU   6                        GENERAL USE                RORI 01580015
SQSREG   EQU   7                       SYSTEM QUEUE SPACE REGISTER RORI 01600015
COUNTER  EQU   8                        NUMBER OF ENTRIES          RORI 01620015
LKREG2   EQU   8                       LINK REGISTER TO SUBROUTINE RORI 01640015
MIQCBREG EQU   9                                                   RORI 01660015
BASEREG  EQU   10                       BASE REGISTER              RORI 01680015
QELREG   EQU   11                                                  RORI 01700015
CVTREG   EQU   12                                                  RORI 01720015
PQEREG   EQU   12                       PQE REGISTER               RORI 01740015
SAVEREG  EQU   13                       SAVE AREA ADDRESS          RORI 01760015
MJQCBREG EQU   14                                                  RORI 01780015
RETREG   EQU   14                       RETURN ADDRESS             RORI 01800015
RETCODE  EQU   15                       RETURN CODE REGISTER       RORI 01820015
*   DISPLACEMENTS IN CVT AND SECONDARY CVT                         RORI 01840015
SCVTQCB  EQU   20                       QUEUE ORIGIN OF QCB'S      RORI 01860015
CVTHEAD  EQU   160                      HI PRIORITY TCB            RORI 01880015
CVTABEND EQU   200                      ADDRESS OF SECONDARY CVT   RORI 01900015
*   DISPLACEMENTS IN TCB                                           RORI 01920015
TCBRBP   EQU   0                        ADDRESS OF REQUEST BLOCK   RORI 01940015
TCBMSS   EQU   24                       ADDRESS OF SPQE            RORI 01960015
TCBFLGS  EQU   29                       TCB FLAG FIELD             RORI 01980015
TCBLLS   EQU   36                    ADDRESS OF LOAD LIST ELEMENT  RORI 02000015
TCBJPQ   EQU   44                       ADDRESS OF CDE             RORI 02020015
TCBQEL   EQU   112                      NUMBER OF ENQUEUES         RORI 02040015
TCBNTCB  EQU   116                 ADDRESS OF NEXT ON READY QUEUE  RORI 02060015
TCBTQEPR EQU   120 .                    ADDR OF TIMER ELEM    BC A49649 02070021
TCBJSTCB EQU   124                      ADDRESS OF JOB SREP TCB    RORI 02080015
TCBPQE   EQU   152                      ADDRESS OF PQE             RORI 02100015
TCBAQE   EQU   156                      ADDRESS OF AQE IN TCB      RORI 02120015
*   DISPLACEMENTS IN RB                                            RORI 02140015
RBSIZE   EQU   9                        SIZE OF RB                 RORI 02160015
RBSTAB   EQU   10                       FLAG BYTES IN RB           RORI 02180015
RBWCF    EQU   28                       ADDRESS OF NEXT RB         RORI 02200015
*   DISPLACEMENTS IN QCB'S AND QEL'S                               RORI 02220015
QELNEXT  EQU   0                        ADDRESS OF NEXT QEL        RORI 02240015
MINQEL   EQU   0                        ADDRESS OF QEL IN MINOR    RORI 02260015
MAJNEXT  EQU   0                                                   RORI 02280015
QCBMIN   EQU   8                   ADDRESS OF MINOR QCB IN MAJOR   RORI 02300015
MINNEXT  EQU   8                        ADDRESS OF NEXT MINOR      RORI 02320015
QELTCB   EQU   8                        ADDRESS OF OWNING TCB      RORI 02340015
MINSIZE  EQU   12                       SIZE OF MINOR NAME         RORI 02360015
*   DISPLACEMENTS IN AQE                                           RORI 02380015
AQELNGTH EQU   4                        LENGTH FIELD IN AQE        RORI 02400015
*   DISPLACEMENTS IN PQE                                           RORI 02420015
PQEPQE   EQU   8                        NEXT PQE POINTER           RORI 02440015
PQETCB   EQU   16                       ADDRESS OF OWNING TCB      RORI 02460015
PQEFLGS  EQU   28                       PQE ROLLOUT FLAGS          RORI 02480015
SCBSIZE  EQU   16                           SCB IN TCB           A40416 02490000
TCBNSTAE EQU   160                 TCB STAE FIELD            BL   M1514 02492021
         EJECT                                                     RORI 02500015
****************************************************************** RORI 02520015
*   BEGINNING OF MAINLINE CODE. IT FIRST PERFORMS INITIAL        * RORI 02540015
*   HOUSEKEEPING AND THEN RIPPLES DOWN THE READY QUEUE SEARCHING * RORI 02560015
*   FOR TCBS IN THE SAME STEP.                                   * RORI 02580015
****************************************************************** RORI 02600015
REGION   STM   RETREG,PQEREG,12(SAVEREG) SAVE INPUT REGISTERS      RORI 02620015
         BALR  BASEREG,TCBREG           ESTABLISH BASE             RORI 02640015
         USING *,BASEREG                                           RORI 02660015
         L     WORKREG1,16              ADDRESS OF CVT             RORI 02680015
         L     TCBCREG,CVTHEAD(WORKREG1) HI PRIORITY TCB IN READYQ RORI 02700015
         SR    SQSREG,SQSREG            CLEAR COUNTER              RORI 02720015
*                                                                  RORI 02740015
*   RIPPLE DOWN READY QUEUE SEARCHING FOR TCBS IN SAME STEP        RORI 02760015
*                                                                  RORI 02780015
RIPPLE   LTR   TCBCREG,TCBCREG          CHECK FOR END OF QUEUE     RORI 02800015
         BZ    STORESQS            LAST ON QUEUE, COMPUTE REGIONS  RORI 02820015
         C     TCBREG,TCBJSTCB(TCBCREG) TEST FOR SAME JOB STEP     RORI 02840015
         BNE   GETATCB                  TAKE BRANCH IF NOT         RORI 02860015
         TM    TCBFLGS(TCBCREG),X'80'   IS TASK ABENDING           RORI 02880015
         BO    GETATCB                  TAKE BRANCH IF YES         RORI 02900015
         BAL   LKREG2,GETSQS      GO COMPUTE SQS                   RORI 02920015
GETATCB  L     TCBCREG,TCBNTCB(TCBCREG) GET NEXT ON READY QUEUE    RORI 02940015
         B     RIPPLE                   GO BACK THROUGH LOOP       RORI 02960015
*                                                                  RORI 02980015
*   AT THIS POINT, ALL SQS USED BY THE TASK HAS BEEN COMPUTED.     RORI 03000015
*   THIS SECTION SEARCHES THE PQE CHAIN AND PUTS REGION ADDRESSES  RORI 03020015
*   IN THE WORK AREA.                                              RORI 03040015
*                                                                  RORI 03060015
STORESQS ST    SQSREG,0(STARTREG)       PUT SQS IN WORK AREA       RORI 03080015
         SR    COUNTER,COUNTER          INITIALIZE COUNTER TO ZERO RORI 03100015
         LR    TCBCREG,TCBREG           TRANSFER INPUT             RORI 03120015
         LA    STARTREG,4(STARTREG)    INCREMENT WORK AREA POINTER RORI 03140015
         CLR   STARTREG,ENDREG          END OF WORK AREA           RORI 03160015
         BL    OK                       TAKE BRANCH IF NOT END     RORI 03180015
*                                                                  RORI 03200015
*   AT THIS POINT THE WORK AREA IS FULL BUT ALL ENTRIES HAVE NOT   RORI 03220015
*   BEEN MADE. WE SET A RETURN CODE OF 8 TO INDICATE THIS & EXITS  RORI 03240015
*                                                                  RORI 03260015
ERREXIT  L     RETREG,12(SAVEREG)       RESTORE RETURN ADDRESS     RORI 03280015
         L     WORKREG1,24(SAVEREG)  GET START ADDR. OF WORK AREA  RORI 03300015
         STC   COUNTER,0(WORKREG1)      STORE NIMBER OF ENTRIES    RORI 03320015
         LA    RETCODE,8(0,0)           SET RC=8                   RORI 03340015
         LM    TCBCREG,PQEREG,32(SAVEREG) RESTORE REMAINDING REGS. RORI 03360015
         BR    RETREG                   RETURN TO IEEVDSP1         RORI 03380015
*                                                                  RORI 03400015
*   AT THIS POINT WORK AREA IS NOT FILLED.                         RORI 03420015
*                                                                  RORI 03440015
OK       L     PQEREG,TCBPQE(TCBCREG)   GET ADDRESS OF DUMMY       RORI 03460015
         LTR   PQEREG,PQEREG           IS THERE A DUMMY            RORI 03480015
         BZ    NODUMMY                 NO, BRANCH                  RORI 03500015
         L     PQEREG,8(PQEREG)   GET A PQE                        RORI 03520015
TESTPQE  LTR   PQEREG,PQEREG            END OF CHAIN               RORI 03540015
         BZ    FINAL                    TAKE BRANCH IF YES         RORI 03560015
         L     WORKREG1,24(PQEREG)    GET START ADDR. OF REGION    RORI 03580015
         LA    WORKREG1,0(WORKREG1)     CLEAR HI ORDER BYTE        RORI 03600015
         ST    WORKREG1,0(STARTREG)     PUT START ADDRESS IN LIST  RORI 03620015
         TM    PQEFLGS(PQEREG),X'80'  IS REGION OWNED OR BORROWED  RORI 03640015
         BC    1,BORROWED               TAKE BRANCH IF BORROWED    RORI 03660015
         TM    PQEFLGS(PQEREG),X'40'  IS REGION ROLLED OUT         RORI 03680015
         BC    1,ROLLED               YES,BRANCH                   RORI 03700015
         MVI   0(STARTREG),X'40'        SET OWNING CODE            RORI 03720015
GO       LA    STARTREG,4(STARTREG)   INCREMENT WORK AREA POINTER  RORI 03740015
         CR    STARTREG,ENDREG          CHECK END OF WORK AREA     RORI 03760015
         BNL   ERREXIT           END OF AREA SET-BAD RETURN CODE   RORI 03780015
         L     WORKREG2,20(PQEREG)      LOAD SIZE FROM PQE         RORI 03800015
         LA    WORKREG2,0(WORKREG2)     CLEAR HI ORDER BYTE        RORI 03820015
         AR    WORKREG2,WORKREG1        COMPUTE END ADDRESS        RORI 03840015
         ST    WORKREG2,0(STARTREG)     PUT END ADDRESS IN LIST    RORI 03860015
         LA    STARTREG,4(STARTREG)    INCREMENT WORK AREA POINTER RORI 03880015
         CR    STARTREG,ENDREG          TEST FOR END OF WORK AREA  RORI 03900015
         BNL   ERREXIT           END OF AREA-SET BAD RETURN CODE   RORI 03920015
         L     PQEREG,PQEPQE(PQEREG)    GET NEXT PQE               RORI 03940015
         LA    COUNTER,1(COUNTER)    INCREMENT NUMBER OF ENTRIES   RORI 03960015
         B     TESTPQE                  GO BACK THROUGH LOOP       RORI 03980015
*   AT THIS POINT THE REGION WAS BORROWED.  WE NOW DETERMINED IF   RORI 04000015
*   IT WAS A RESULT OF ROLLOUT OR IF IT CAME FROM FREE CORE        RORI 04020015
*                                                                  RORI 04040015
ROLLED   MVI   0(STARTREG),X'D9'                                   RORI 04060015
         B     GO                       RETURN TO MAINLINE         RORI 04080015
BORROWED MVI   0(STARTREG),X'C2'                                   RORI 04100015
         B     GO                       RETURN TO MAINLINE         RORI 04120015
*                                                                  RORI 04140015
*   THIS IS THE NORMAL EXIT POINT IT COMPLETES THE LIST BY STORING RORI 04160015
*   NUMBER OF ENTRIES. IT THEN SETS UP RETURN INTERFACE AND        RORI 04180015
*   BRANCHES TO IEEVDSP1 AT THE POINT SPECIFIED BY REGISTER 14.    RORI 04200015
*                                                                  RORI 04220015
FINAL    L     WORKREG1,24(SAVEREG) GET START ADDRESS OF WORK AREA RORI 04240015
         STC   COUNTER,0(WORKREG1)      STORE NUMBER OF ENTRIES    RORI 04260015
         L     RETREG,12(SAVEREG)       RESTORE REGISTER INPUT     RORI 04280015
         SR    RETCODE,RETCODE          SET RETURN CODE            RORI 04300015
         LM    TCBCREG,PQEREG,32(SAVEREG)                          RORI 04320015
         BR    RETREG                   RETURN TO IEEVDSP1         RORI 04340015
NODUMMY  SR    WORKREG1,WORKREG1                                   RORI 04360015
         ST    WORKREG1,0(STARTREG)  STORE ZERO REGION START ADDR. RORI 04380015
         MVI   0(STARTREG),X'40'       SET OWNED INDICATOR         RORI 04400015
         LA    STARTREG,4(STARTREG)    INCREMENT WORK AREA POINTER RORI 04420015
         CR    STARTREG,ENDREG         END OF WORK AREA            RORI 04440015
         BNL   ERREXIT                 YES, BRANCH                 RORI 04460015
         ST    WORKREG1,0(STARTREG)  STORE ZERO REGION END ADDRESS RORI 04480015
         LA    STARTREG,4(STARTREG)    INCREMENT WORK AREA POINTER RORI 04500015
         CR    STARTREG,ENDREG         END OF WORK AREA            RORI 04520015
         BNL   ERREXIT                 YES, BRANCH                 RORI 04540015
         LA    COUNTER,1(COUNTER)      INCREMENT N                 RORI 04560015
         B     FINAL                                               RORI 04580015
         EJECT                                                     RORI 04600015
****************************************************************** RORI 04620015
*   THIS SUBROUTINE COMPUTES THE SQS USED BY A TASK. THE CONTROL * RORI 04640015
*   BLOCKS USED ARE CDE'S, LLE'S, RB'S, QCB'S, QEL'S, AQE'S,     * RORI 04660015
*   SPQE'S, DQE'S, AQE'S, AND PQE'S.                             * RORI 04680015
****************************************************************** RORI 04700015
GETSQS   SR    WORKREG3,WORKREG3                                   RORI 04720015
         C     TCBCREG,TCBJSTCB(TCBCREG) IS THIS JOBSTEP TCB       RORI 04740015
         BNE   ANYLLES                  NO-DON'T COMPUTE CDE'S     RORI 04760015
         L     WORKREG1,TCBJPQ(TCBCREG) ADDRESS OF CDE             RORI 04820015
         LA    WORKREG1,0(WORKREG1) .    CLEAR HI ORDER BYTE  BL  M0502 04830021
         LTR   WORKREG1,WORKREG1 .       ARE THERE ANY CDE'S  BL  M0502 04832021
         BZ    ANYLLES .                 BRANCH IF NO LLE'S   BL  M0502 04834021
CDEADD   AH    SQSREG,CDESIZE           INCREMENT SQS REGISTER     RORI 04840015
         TM    0(WORKREG1),X'04'        IS THIS A MAJOR            RORI 04860015
         BZ    MAJCDE                   BRANCH IF MAJOR            RORI 04880015
CDENEXT  L     WORKREG1,0(WORKREG1)     GET NEXT CDE               RORI 04900015
         LA    WORKREG1,0(WORKREG1)     CLEAR HI ORDER BYTE        RORI 04920015
         LTR   WORKREG1,WORKREG1        TEST FOR LAST ON CHAIN     RORI 04940015
         BZ    ANYLLES                  TAKE BRANCH IF LAST        RORI 04960015
         B     CDEADD                   GO INCREMENT SQS           RORI 04980015
MAJCDE   TM    20(WORKREG1),X'20'       ANY EXTENT LISTS           RORI 05000015
         BZ    CDENEXT                  TAKE BRANCH IF NONE        RORI 05020015
         L     WORKREG2,20(WORKREG1)   PICK UP EXTENT LIST POINTER RORI 05040015
         L     WORKREG2,0(WORKREG2)     PICK UP LENGTH             RORI 05060015
         AR    SQSREG,WORKREG2       INCREMENT SQS BY EXTENT LIST  RORI 05080015
         B     CDENEXT                  GO BACK THROUGH LOOP       RORI 05100015
*                                                                  RORI 05120015
*   ADD ANY LLE'S TO SYSTEM QUEUE SPACE                            RORI 05140015
*                                                                  RORI 05160015
ANYLLES  C     WORKREG3,TCBLLS(TCBCREG) ARE THERE ANY LLE'S        RORI 05180015
         BE    ANYRBS                   TAKE BRANCH IF NOT         RORI 05200015
         L     WORKREG1,TCBLLS(TCBCREG) GET FIRST LLE              RORI 05220015
ADDLLE   AH    SQSREG,LLESIZE        INCREMENT SYSTEM QUEUE SPACE  RORI 05240015
         L     WORKREG1,0(WORKREG1)     GET NEXT LLE               RORI 05260015
         LTR   WORKREG1,WORKREG1        LAST ON CHAIN?             RORI 05280015
         BC    7,ADDLLE                 TAKE BRANCH IF NO          RORI 05300015
*                                                                  RORI 05320015
*   CHECK ALL RB'S AND ADD TO SYSTEM QUEUE SPACE IF ANY EXIST      RORI 05340015
*                                                                  RORI 05360015
ANYRBS   C     WORKREG3,TCBRBP(TCBCREG) TEST FOR RB'S              RORI 05380015
         BE    ANYQCBS                  TAKE BRANCH IF NONE        RORI 05400015
         L     WORKREG1,TCBRBP(TCBCREG) GET FIRST RB               RORI 05420015
RBADD    TM    RBSTAB(WORKREG1),X'C0'   TEST FOR IRB OR SIRB       RORI 05440015
         BM    RBNEXT                   BRANCH FOR NEXT            RORI 05460015
         IC    WORKREG3,RBSIZE(WORKREG1) GET SIZE IN DOUBLE WORDS  RORI 05480015
         SLL   WORKREG3,3               MULTIPLY SIZE BY 8         RORI 05500015
         AR    SQSREG,WORKREG3          INCREMENT SQS BY RB SIZE   RORI 05520015
         SR    WORKREG3,WORKREG3                                   RORI 05540015
RBNEXT   L     WORKREG1,RBWCF(WORKREG1) ADDRESS OF NEXT RB         RORI 05560015
         LA    WORKREG1,0(WORKREG1)     CLEAR HI ORDER BYTE        RORI 05580015
         CR    WORKREG1,TCBCREG         DOES RB POINT TO TCB       RORI 05600015
         BNE   RBADD                    TAKE BRANCH IF IT DOES NOT RORI 05620015
*                                                                  RORI 05640015
*   COMPUTE ALL QCB'S AND ASSOCIATED QEL'S                         RORI 05660015
*                                                                  RORI 05680015
ANYQCBS  TM    TCBQEL(TCBCREG),X'FF'    TEST ENQUEUE COUNT         RORI 05700015
         BZ    ANYAQES                  TAKE BRANCH IF ZERO COUNT  RORI 05720015
         SR    WORKREG2,WORKREG2                                   RORI 05740015
         IC    WORKREG2,TCBQEL(TCBCREG) PICK UP COUNT              RORI 05760015
         L     CVTREG,16                GET POINTER TO CVT         RORI 05780015
         L     CVTREG,CVTABEND(CVTREG)  ADDRESS OF SECONDARY CVT   RORI 05800015
         L     MJQCBREG,SCVTQCB(CVTREG)  ADDRS OF PRT TO QCB'S     RORI 05820015
         L     MJQCBREG,MAJNEXT(MJQCBREG)  PICK UP FIRST MAJOR QCB RORI 05840015
MAJQCHK  L     MIQCBREG,QCBMIN(MJQCBREG) ADDRESS OF MINOR QCB      RORI 05860015
         LTR   MIQCBREG,MIQCBREG .       CHECK FOR MINOR         A39877 05863000
         BZ    NEXTMAJ .                 NO,GET NEZT MAJOR       A39877 05866000
MINQCHK  L     QELREG,MINQEL(MIQCBREG)  ADDRESS OF QEL             RORI 05880015
         LTR   QELREG,QELREG .         CHECK FOR QEL          BC A46448 05886021
         BZ    NEXTMCHK .              NO,GET NEXT MINOR      BC A46448 05892021
TCBQCHK  C     TCBCREG,QELTCB(QELREG)   BELONG TO CURRENT TCB      RORI 05900015
         BNE   NEXTQEL                  TAKE BRANCH IF NO          RORI 05920015
         IC    WORKREG3,MINSIZE(MIQCBREG) PICK UP MINOR NAME SIZE  RORI 05940015
         A     WORKREG3,QCBLNGTH   ADD SIZE OF QCB'S TO NAME SIZE  RORI 05960015
         N     WORKREG3,MASKFULL      .RND BASIC SIZE TO DBLWRD         05970021
         AR    SQSREG,WORKREG3          AND THEN ADD TO SQS        RORI 05980015
         SR    WORKREG3,WORKREG3                                   RORI 06000015
         BCT   WORKREG2,NEXTMCHK  AFTER LAST IS PROCESSED GO GET   RORI 06020015
         B     ANYAQES                  AQE'S                      RORI 06040015
NEXTQEL  L     QELREG,QELNEXT(QELREG)   PICK UP NEXT QEL           RORI 06060015
         LA    QELREG,0(QELREG)         CLEAR HI ORDER BYTE        RORI 06080015
         LTR   QELREG,QELREG            LAST ON CHAIN              RORI 06100015
         BNE   TCBQCHK                  TAKE BRANCH IF NO          RORI 06120015
NEXTMCHK L     MIQCBREG,MINNEXT(MIQCBREG) PICK UP NEXT MINOR       RORI 06140015
         LTR   MIQCBREG,MIQCBREG        LAST MINOR ON CHAIN        RORI 06160015
         BNE   MINQCHK                  TAKE BRANCH IF NO          RORI 06180015
NEXTMAJ  L     MJQCBREG,MAJNEXT(MJQCBREG) PICK UP NXT MAJOR   BC A46448 06200021
         LTR   MJQCBREG,MJQCBREG        TEST FOR LAST              RORI 06220015
         BNE   MAJQCHK                  TAKE BRANCH IF NOT         RORI 06240015
ANYAQES  L     WORKREG1,TCBNSTAE(TCBCREG)    GET SCB          BL  M1514 06242021
SCBADD   LA    WORKREG1,0(WORKREG1) .       CLEAR HI ORDER BYTE  A40416 06244000
         LTR   WORKREG1,WORKREG1 .          TEST FOR ZERO        A40416 06246000
         BZ    ANYAQE .                     IF YES - NEXT TEST   A40416 06248000
         LA    SQSREG,SCBSIZE(,SQSREG)      ADD X'10' TO SQS  BL  M1514 06250421
         L     WORKREG1,0(,WORKREG1) .      PICK UP NXT SCB      A40416 06252000
         B     SCBADD                                            A40416 06254000
*                                                                  RORI 06260015
*   ADD ALL AQE LENGTHS TO SYSTEM QUEUE SPACE                      RORI 06280015
*                                                                  RORI 06300015
ANYAQE   SR    WORKREG3,WORKREG3            CLEAR REG FOR AQE           06320000
         C     WORKREG3,TCBAQE(TCBCREG) TEST FOR AQE'S             RORI 06340015
         BE    ANYSPQES                 TAKE BRANCH IF NONE        RORI 06360015
         L     WORKREG1,TCBAQE(TCBCREG) PICK UP AQE                RORI 06380015
AQEADD   A     SQSREG,AQELNGTH(WORKREG1) INCREMENT SQS             RORI 06400015
         L     WORKREG1,0(WORKREG1)     GET NEXT AQE               RORI 06420015
         LTR   WORKREG1,WORKREG1                                   RORI 06440015
         BNE   AQEADD                                              RORI 06460015
*                                                                  RORI 06480015
*   CALCULATE ALL SPQE'S AND DQE'S                                 RORI 06500015
*                                                                  RORI 06520015
ANYSPQES L     WORKREG1,TCBMSS(TCBCREG)  LOAD SPQE ADDR            RORI 06540015
ANYMORE  LA    WORKREG1,0(WORKREG1)    CLEAR HIGH ORDER BYTE       RORI 06560015
         LTR   WORKREG1,WORKREG1       ANY SPQES                   RORI 06580015
         BZ    ANYPQES                 NO, BRANCH                  RORI 06600015
SPQEADD  A     SQSREG,SPQESIZE          INCREMENT SQS              RORI 06620015
         TM    0(WORKREG1),X'80'        TEST FOR OWNING SUBPOOL    RORI 06640015
         BO    GETSPQE                  TAKE BRANCH IF SHARED      RORI 06660015
         L     WORKREG2,4(WORKREG1)    GET ADDR OF DQE             RORI 06680015
DQETEST  LA    WORKREG2,0(WORKREG2)     CLEAR HI ORDER BYTE        RORI 06700015
         LTR   WORKREG2,WORKREG2        TEST FOR DQE'S             RORI 06720015
         BZ    GETSPQE                  TAKE BRANCH IF NO DQE      RORI 06740015
         AH    SQSREG,DQESIZE           INCREMENT SQS              RORI 06760015
         L     WORKREG2,4(WORKREG2)     GET NEXT DQE               RORI 06780015
         B     DQETEST                  GO BACK THROUGH LOOP       RORI 06800015
GETSPQE  TM    0(WORKREG1),X'40'        TEST FOR LAST              RORI 06820015
         BO    ANYPQES                .BRANCH IF LAST          @JK70078 06840021
         L     WORKREG1,0(WORKREG1)     ADDRESS OF NEXT SPQE       RORI 06860021
         B     ANYMORE                 PROCESS NEXT                RORI 06880015
*                                                                  RORI 06900015
*   CALDLATE ALL PQE'S AND ADD TO SYSTEM QUEUE SPACE               RORI 06920015
*                                                                  RORI 06940015
ANYPQES  C     TCBCREG,TCBJSTCB(TCBCREG) IS THIS A JOB STEP TCB    RORI 06960015
         BCR   7,LKREG2      DON'T GO THROUGH PQE CHAIN IF         RORI 06980015
*                                       NOT JOB STEP               RORI 07000015
         L     WORKREG1,TCBPQE(TCBCREG) PICK UP DUMMY POINTER      RORI 07020015
         LTR   WORKREG1,WORKREG1       IS THERE A DUMMY PQE        RORI 07040015
         BCR   8,LKREG2                NO, BRANCH                  RORI 07060015
         A     SQSREG,SPQESIZE        .ADD SIZE OF DPQE        @JK70078 07070021
NEXTPQE  L     WORKREG1,8(WORKREG1)  ADDRESS OF PQE                RORI 07080015
         LTR   WORKREG1,WORKREG1        LAST ON CHAIN              RORI 07100015
         BCR   8,LKREG2           TAKE BRANCH IF YES               RORI 07120015
         A     SQSREG,PQESIZE           INCREMENT SQS BY PQE SIZE  RORI 07140015
         B     NEXTPQE                  GO GET NEXT                RORI 07160015
*   CONSTANTS                                                      RORI 07180015
PQESIZE  DC    F'32'                    SIZE OF PQE                RORI 07200015
QCBLNGTH DC    F'61'                  .MAJOR SIZE X'18'        @JK70078 07220021
*                                     PLUS QEL SIZE X'10'      @JK70078 07240021
*                    PLUS BASIC MINOR SIZE FOR ROUNDING X'15'  @JK70078 07260021
MASKFULL DC    X'FFFFFFF8'            MASK TO ROUND TO DBLWRD  @JK70078 07270021
SPQESIZE DC    F'8'                                                RORI 07280015
DQESIZE  DC    H'16'                                               RORI 07300015
CDESIZE  DC    H'24'                                               RORI 07320015
LLESIZE  DC    H'8'                                                RORI 07340015
         END                                                            07360015
         END                                                            07600000
