         TITLE 'IEFDSLST'                                               00020000
*********************************************************************** 00040000
*                                                                     * 00060000
*        DATASET INTEGRITY - ENQUEUE LIST CONSTRUCTION                * 00080000
*                                                                     * 00100000
*********************************************************************** 00120000
*                                                                     * 00140000
* STATUS - CHANGE LEVEL 000                                             00160000
*                                                                       00180000
* FUNCTION - USING THE TREE (TABLE) BUILT BY IEFDSTBL, BUILD AN       * 00200000
*            ENQUEUE PARAMETER LIST CONTAINING ALL DATASET NAMES      * 00220000
*            IN THE TREE AND FREE THE CORE USED BY THE TREE             00240000
*                                                                     * 00260000
* ENTRY POINT - IEFDSLST FROM IEFSD161.                               * 00280000
*                                                                     * 00300000
* INPUT - REGISTER ONE CONTAINS ADDRESS OF PARAMETER LIST             * 00320000
*            WORD 1 - ADDRESS OF TREE-8                                 00340000
*                 2 - ADDR OF ENQ PARAMETER LIST AREA                   00360000
*                 3 - ADDR OF FIRST MINOR RESOURCE NAME (DSNAME)        00380000
*                                                                     * 00400000
* OUTPUT - A DATASET ENQUEUE PARAMETER LIST.                          * 00420000
*                                                                     * 00440000
* EXTERNAL REFERENCES - NONE                                          * 00460000
*                                                                     * 00480000
* EXIT - REGISTER 14                                                    00500000
*                                                                       00520000
* TABLES/WORKAREAS - DATASET NAME TREE                                  00540000
*                                                                       00560000
* ATTRIBUTES - REENTRANT                                                00580000
*                                                                     * 00600000
*********************************************************************** 00620000
*                                                                       00640000
********************************************************************    00660000
*                      ENQ PARAMETER LIST AREA                          00680000
*                                                                       00700000
*  ADDRESS OF THE 1ST PARM ELEMENT IS THE ADDRESS OF THE ENQ PARM LIST  00720000
*                                                                       00740000
*******************---**************************---*****************    00760000
*MAJOR   *1ST PARM*   *NTH PARM*1ST MINOR      *   *NTH MINOR      *    00780000
*RESOURCE*ELEMENT *   *ELEMENT *RESOURCE NAME  *   *RESOURCE NAME  *    00800000
*NAME    *        *   *        *               *   *               *    00820000
*8 BYTES *12 BYTES*   *12 BYTES*VARIABLE LENGTH*   *VARIABLE LENGTH*    00840000
*******************---**************************---*****************    00860000
         EJECT                                                          00880000
NODE     DSECT           'USING' STATEMENT REFERS TO THIS SYMBOL.       00900000
*********************************************************************** 00920000
*   *** NODE PROTOTYPE ***                                            * 00940000
*********************************************************************** 00960000
*     GENERALLY, NODES HAVE TWO PARTS WHICH RESIDE IN TWO SEPARATE    * 00980000
*        BLOCKS OF 'GOTTEN' CORE.  THE FIRST PART FOLLOWS IMMEDIATELY * 01000000
*********************************************************************** 01020000
NULG     EQU   4         LENGTH OF 'NULL' NODE USED FOR CORE REQUESTS.  01040000
NFCT     DC    A(0)                4 BYTES AVAILABLE FOR STORING        01060000
*                                    A FUNCTION OR ADDRESS AT THE NODE. 01080000
NLNG     EQU   *                   HI-ORDER BYTE GIVING NUMBER OF       01100000
*                                   CHARACTERS STORED IN THE NODE.      01120000
NCHSTR   DC    A(NCHAR)            ADDRESS OF THE NODE CHARACTER        01140000
*                                   STRING(THE SECOND PART OF THE NODE) 01160000
*                                   WHICH RESIDES IN A SEPARATE BLOCK   01180000
*                                   OF CORE.                            01200000
*********************************************************************** 01220000
*   THE FOLLOWING SYMBOLS ARE USED TO REFER TO A LIST OF ADDRESSES OF * 01240000
*    CONSTITUENT NODES (PART ONE), EACH ADDRESS CORRESPONDING TO A    * 01260000
*     CHARACTER IN THE NODE CHARACTER STRING.                         * 01280000
*********************************************************************** 01300000
LADLST   EQU   *     CONTAINS ADDRESS OF PART ONE OF SUBORDINATE NODE.* 01320000
NFLAG    DC    A(*)                HIGH ORDER BYTE OF 'LADLST' WHICH  * 01340000
*                                   CONTAINS NODE STATUS BITS.        * 01360000
NFLGNULL EQU   2         INDICATES THAT THE NODE IS NULL, THAT IS,    * 01380000
*                         HAS NO ASSOCIATED CHARACTER STRING.         * 01400000
NFLGCAT  EQU   1         THE NODE IS A CONCATENATION OF CONSECUTIVE   * 01420000
*                         UNARY NODES, THAT IS, NODES HAVING ONLY ONE * 01440000
*                          CHARACTER IN THE CHARACTER STRING.         * 01460000
NFLGNET  EQU   4         THIS NODE CONTAINS, IN THE 'NFCT' FIELD, THE * 01480000
*                         ADDRESS OF AN ALTERNATE NODE AT WHICH       * 01500000
*                          SCANNING MAY BE RESUMED IN THE EVENT THAT  * 01520000
*                           THE CHARACTER IS NOT FOUND IN THE NODE.   * 01540000
*********************************************************************** 01560000
*   THE SECOND PART OF THE NODE IS THE NODE CHARACTER STRING. THIS IS * 01580000
*    A STRING OF CHARACTERS FROM 1 TO 256 IN LENGTH. THE              * 01600000
*     LENGTH(MINUS ONE) IS GIVEN IN THE 'NLNG' FIELD.                 * 01620000
*********************************************************************** 01640000
         DS    0D                  PLACE ON FULL WORD BOUNDARY.         01660000
NCHAR    DC    C'AB ... Z'        SYMBOL USED FOR CH. OR ENTIRE STRING* 01680000
LND      EQU *                     SYMBOL USED TO DELIMIT THE END OF    01700000
*                                  THE SIMPLEST NON-NULL NODE FOR       01720000
*                                   THE PURPOSE OF OBTAINING CORE.      01740000
*********************************************************************** 01760000
         EJECT                                                          01780000
BX0101X  EQU   5                                                        01800000
BX0110X  EQU   6                                                        01820000
BX1000X  EQU   8                                                        01840000
*                                                                       01860000
*********************************************************************** 01880000
*   *** CALLING SEQUENCE PROTOTYPE ***                                * 01900000
*********************************************************************** 01920000
*        LA    1,PARAM                                                * 01940000
*        L     15,=V(IEFDSLST)                                          01960000
*        BALR  14,15                                                  * 01980000
*                                                                     * 02000000
*PARAM   DC    A(TREE-8)  ADDRESS OF DATA SET NAME TREE.              * 02020000
*        DC    A(ENQBLOCK) BLOCK IN WHICH L-FORM ENQ MACROS ARE STORED* 02040000
*        DC    A(DSBLOCK) BLOCK IN WHICH DATA SET NAMES WILL BE PLACED* 02060000
*                                                                     * 02080000
*TREE    DC    A(HIGHNODE)         ADDRESS OF HIGH ORDER NODE OF TREE.* 02100000
*********************************************************************** 02120000
N        EQU   96+12              SPACE FOR 8 REG. SAVE AREAS.          02140000
R6       EQU   2                                                        02160000
R3       EQU   4                                                        02180000
R4       EQU   5                                                        02200000
R11      EQU   6                                                        02220000
R1       EQU   7                                                        02240000
R7       EQU   8                                                        02260000
BASE     EQU   9                                                        02280000
R8       EQU   10                                                       02300000
R9       EQU   11                                                       02320000
R10      EQU   12                                                       02340000
R2       EQU   13                                                       02360000
R        EQU   14                                                       02380000
IEFDSLST CSECT                                                          02400000
         SAVE  (14,12),T,*                                              02420000
         LR    BASE,15                                                  02440000
         USING IEFDSLST,BASE                                            02460000
         LM    R8,R10,0(1)                                              02480000
         USING NODE,R8                                                  02500000
         LR    R11,R9             HOLD MAJOR NAME ADDRESS IN R11.       02520000
         LA    R9,8(0,R9)          POSITION TO BEGINNING OF ENQ LIST.   02540000
         USING ENQ,R9             BASE FOR ADDRESSING  ENQ MF=L LIST.   02560000
         LA    0,45                                                     02580000
      GETMAIN  R,LV=(0)            FOR BUILDING INDIVIDUAL DS NAMES.    02600000
         LR    R1,1                                                     02620000
         USING WA,R1                                                    02640000
         LR    R7,R1              HOLD BASE ADDRESS OF WORK AREA.       02660000
         LA    R6,DWNEND-DOWN                                           02680000
         LR    R6+1,R2                                                  02700000
         BAL   R,LIST                                                   02720000
         S     R9,C12                  ADJUST TO LAST ELEMENT           02740000
         MVI   NQLST,X'FF'             END OF LIST INDICATOR            02760000
         LA    0,45                                                     02780000
      FREEMAIN R,LV=(0),A=(R7)                                          02800000
      RETURN   (14,12),T                                                02820000
C12      DC    F'12'                                                    02840000
         USING DOWN,R2                                                  02860000
LIST     L     R4,LADLST           ADDRESS OF NODE TO PROCESS.          02880000
         DROP  R8                       **                              02900000
         USING NODE,R4                  **                              02920000
         L     1,NFCT                                                   02940000
         LTR   1,1                                                      02960000
         BC    BX1000X,NOT                                              02980000
         SR    R1,R7               COMPUTE LENGTH OF ACCUMULATED NAME.  03000000
         MVI   NQLST,X'00'             NOT END OF LIST                  03020000
         STC   R1,NQLEN           STORE DATA SET NAME LENGTH.           03040000
         MVI   NQATT,X'40'         SYSTEM BIT FOR ENQ                   03060000
         MVI   NQRET,X'00'               RETURN CODE                    03080000
         IC    R3,NFCT            'OR' IN THE DATA SET                  03100000
         EX    R3,OI               REFERENCE ATTRIBUTE.                 03120000
         ST    R11,NQMAJ          STORE MAJOR NAME ADDRESS.             03140000
         BCTR  R1,0               ADJUST TO MACHINE REPRESENTATION.     03160000
         EX    R1,MVDSN           MOVE DATA SET NAME INTO LIST.         03180000
         ST    R10,NQMIN          STORE THE MINOR NAME ADDRESS.         03200000
         LA    R9,ENQEND          POSITION TO NEXT ENTRY.               03220000
         LA    R10,1(R1,R10)      LIKEWISE.                             03240000
         LA    R1,1(R1,R7)        RESTORE FORMER VALUE TO R1.           03260000
         DROP  R4                       **                              03280000
         USING NODE,R8                  **                              03300000
NOT      TM    NFLAG,NFLGNULL      TEST IF THE NODE IS NULL.            03320000
         BC    BX0101X,RT          RETURN TO CALLER (INTERNAL) IF SO.   03340000
         SR    R3,R3               INITIALIZE LOOP COUNT.               03360000
SAVE     BXH   R2,R6,SVAREA        BRANCH IF NEW SAVE AREA REQUIRED.    03380000
         ST    R,DWNRET            SAVE RETURN ADDRESS.                 03400000
         ST    R4,DWNNODE          SAVE CURRENT NODE ADDRESS.           03420000
         LA    R1,1(R1)            INCREMENT TO NEXT POSITION IN NAME.  03440000
         TM    NFLAG,NFLGCAT                                            03460000
         BC    BX1000X,XX                                               03480000
         DROP  R8                       **                              03500000
         USING NODE,R4                  **                              03520000
CAT      IC    R3,NLNG                                                  03540000
         L     R8,NCHSTR          LOAD ADDRESS OF CHARACTER STRING.     03560000
         EX    R3,MVC                                                   03580000
         AR    R1,R3              INCREMENT TO NEXT POSITION IN NAME.   03600000
         LR    R8,R4                                                    03620000
         BAL   R,LIST              *RECURSIVE ENTRY*                    03640000
         L     R4,DWNNODE                                               03660000
         IC    R3,NLNG                                                  03680000
         SLR   R1,R3                                                    03700000
         LA    0,12                                                     03720000
OUT      LR    1,R4               ADDRESS OF NODE TO BE 'FREED'.        03740000
         L     R4,NCHSTR     ADDRESS OF CHARACTER STRING TO BE 'FREED'. 03760000
      FREEMAIN R,LV=(0),A=(1)     FREE PART ONE OF NODE.                03780000
         LA    0,1(R3)                                                  03800000
      FREEMAIN R,LV=(0),A=(R4)    FREE PART TWO (CHARACTER STRING).     03820000
         L     R,DWNRET            RESTORE RETURN ADDRESS.              03840000
RESTORE  SLR   R2,R6              BACK UP TO HIGHER REGISTER SAVE AREA. 03860000
         BCTR  R1,R                RETURN TO CALLER (INTERNAL).         03880000
CLI      CLI   NLNG,X'00'                                               03900000
OI       OI    NQATT,X'00'                                              03920000
DOANODE  LA    R3,1(0,R3)           INCREMENT LOOP COUNT.               03940000
XX       L     R8,NCHSTR          GET ADDRESS OF CHARACTER STRING.      03960000
         USING NCHAR,R8                                                 03980000
         IC    R8,NCHAR(R3)       PUT CHARACTER                         04000000
         DROP  R8                   IN                                  04020000
         STC   R8,DSNAME              DATA SET NAME.                    04040000
         LR    R8,R3              MOVE LOOP INDEX TO R8 AND             04060000
         AR    R8,R8               MULTIPLY                             04080000
         AR    R8,R8                BY FOUR.                            04100000
         LA    R8,NODE(R8)        POSITION TO NEXT NODE TO PROCESS.     04120000
         ST    R3,DWNCOUNT         SAVE CURRENT LOOP COUNT.             04140000
         BAL   R,LIST              *RECURSIVE ENTRY*                    04160000
         L     R3,DWNCOUNT         RESTORE LOOP COUNT.                  04180000
         L     R4,DWNNODE          RESTORE NODE ADDRESS.                04200000
         EX    R3,CLI                                                   04220000
         BC    BX0110X,DOANODE     BRANCH TO PROCESS NEXT SUBNODE.      04240000
         LR    1,R3               NODE PROCESSING IS COMPLETE.          04260000
         ALR   1,1                                                      04280000
         LA    0,12(1,1)                                                04300000
         B     OUT                                                      04320000
RT       LA    0,4                                                      04340000
      FREEMAIN R,LV=(0),A=(R4)     FREE THE 'NULL' NODE.                04360000
         BR    R                                                        04380000
SVAREA   LA    0,N LENGTH OF BLOCKED SAVE AREAS.                        04400000
      GETMAIN  R,LV=(0)                                                 04420000
         ST    R2,0(0,1)            SAVE ADDRESS OF PRIOR BLOCK.        04440000
         LR    R2,1                ADDRESS OF NEW SAVE AREA BLOCK IN R2 04460000
         LA    R6+1,N-1(0,R2) END OF BLOCK IN R6+1.                     04480000
         ST    R,DWNRET            SAVE RETURN ADDRESS.                 04500000
         BAL   R,SAVE              RESUME.                              04520000
         L     R,DWNRET            GET ACTUAL RETURN ADDRESS.           04540000
         LR    1,R2                                                     04560000
         L     R2,0(0,1)            GET ADDRESS OF PRIOR BLOCK.         04580000
         LA    0,N                                                      04600000
      FREEMAIN R,LV=(0),A=(1)      FREE THE EXPENDED SAVE AREA BLOCK.   04620000
           SLR R2,R6              ADJUST TO POINT TO SAVE AREA.         04640000
         LR    R6+1,R2            RESTORE END OF BLOCK LIMIT.           04660000
         BR    R                  RETURN TO CALLER.                     04680000
MVC      MVC   DSNAME(0),0(R8)                                          04700000
MVDSN    MVC   0(0,R10),1(R7)                                           04720000
*                                                                       04740000
WA       DSECT                     AREA FOR BUILDING A DATA SET NAME.   04760000
DSNAME   DS    CL32                                                     04780000
         DS    CL12                                                     04800000
ENQ      DSECT                     PROTOTYPE FOR ENQ L-FORM MACRO.      04820000
NQLST    DC    X'00'               END OF LIST INDICATOR.               04840000
NQLEN    DC    X'00'               MINOR NAME (DATA SET NAME) LENGTH.   04860000
NQATT    DC    B'00000000'         REFERENCE ATTRIBUTE BIT ( HI-ORDER). 04880000
NQRET    DC    X'00'                 RETURN CODE                        04900000
NQMAJ    DC    A(*)                MAJOR NAME IS 'SYSDSN  '             04920000
NQMIN    DC    A(*)                DATA SET NAME                        04940000
ENQEND   EQU   *                                                        04960000
*                                                                       04980000
DOWN     DSECT                     REGISTER SAVE AREA FORMAT.           05000000
DWNNODE  DC    A(0)                NODE ADDRESS.                        05020000
DWNCOUNT DC    A(0)                LOOP COUNT.                          05040000
DWNRET   DC    A(0)                RETURN ADDRESS.                      05060000
DWNEND   EQU   *                                                        05080000
         END                                                            05100000
