         TITLE 'IEFDSTBL'                                               00020000
*********************************************************************** 00040000
*                                                                     * 00060000
*        DATASET INTEGRITY - TREE BUILD ROUTINE                       * 00080000
*                                                                     * 00100000
*********************************************************************** 00120000
*                                                                       00140000
* STATUS - CHANGE LEVEL 000                                             00160000
*                                                                       00180000
*                                                                     * 00200000
* FUNCTION - TO BUILD A TREE (TABLE) OF UNIQUE DATASET NAMES AND      * 00220000
*            THEIR ATTRIBUTES(SHARED OR EXCUSIVE).                    * 00240000
*                                                                     * 00260000
* ENTRY POINT - IEFDSTBL FROM IEFSD161                                * 00280000
*                                                                     * 00300000
* INPUT -    REGISTER ONE CONTAINS THE ADDRESS OF A PARAMETER LIST    * 00320000
*              WORD 1 - ADDRESS OF TREE-8                               00340000
*                   2 - 1ST CHARACTER OF DATASET NAME                   00360000
*                   3 - LAST CHARACTER OF DATASET NAME                  00380000
*                                                                     * 00400000
* OUTPUT -   THE DATASET NAME DEFINED IN THE PARAMETER LIST IS        * 00420000
*            PLACED IN THE TREE IF UNIQUE.                            * 00440000
*                                                                     * 00460000
* EXTERNAL REFERENCES - IEFDSTRT - A  TRANSLATE TABLE                 * 00480000
*                                                                     * 00500000
* EXIT - REGISTER 14                                                  * 00520000
*                                                                     * 00540000
* TABLES/WORKAREAS -                                                    00560000
*                                                                       00580000
* ATTRIBUTES - REENTRANT                                                00600000
*********************************************************************** 00620000
*                                                                     * 00640000
         EJECT                                                          00660000
NODE     DSECT           'USING' STATEMENT REFERS TO THIS SYMBOL.       00680000
*********************************************************************** 00700000
*   *** NODE PROTOTYPE ***                                            * 00720000
*********************************************************************** 00740000
*     GENERALLY, NODES HAVE TWO PARTS WHICH RESIDE IN TWO SEPARATE    * 00760000
*        BLOCKS OF 'GOTTEN' CORE.  THE FIRST PART FOLLOWS IMMEDIATELY * 00780000
*********************************************************************** 00800000
NULG     EQU   4         LENGTH OF 'NULL' NODE USED FOR CORE REQUESTS.  00820000
NFCT     DC    A(0)                4 BYTES AVAILABLE FOR STORING        00840000
*                                    A FUNCTION OR ADDRESS AT THE NODE. 00860000
NLNG     EQU   *                   HI-ORDER BYTE GIVING NUMBER OF       00880000
*                                   CHARACTERS STORED IN THE NODE.      00900000
NCHSTR   DC    A(NCHAR)            ADDRESS OF THE NODE CHARACTER        00920000
*                                   STRING(THE SECOND PART OF THE NODE) 00940000
*                                   WHICH RESIDES IN A SEPARATE BLOCK   00960000
*                                   OF CORE.                            00980000
*********************************************************************** 01000000
*   THE FOLLOWING SYMBOLS ARE USED TO REFER TO A LIST OF ADDRESSES OF * 01020000
*    CONSTITUENT NODES (PART ONE), EACH ADDRESS CORRESPONDING TO A    * 01040000
*     CHARACTER IN THE NODE CHARACTER STRING.                         * 01060000
*********************************************************************** 01080000
LADLST   EQU   *     CONTAINS ADDRESS OF PART ONE OF SUBORDINATE NODE.* 01100000
NFLAG    DC    A(*)                HIGH ORDER BYTE OF 'LADLST' WHICH  * 01120000
*                                   CONTAINS NODE STATUS BITS.        * 01140000
NFLGNULL EQU   2         INDICATES THAT THE NODE IS NULL, THAT IS,    * 01160000
*                         HAS NO ASSOCIATED CHARACTER STRING.         * 01180000
NFLGCAT  EQU   1         THE NODE IS A CONCATENATION OF CONSECUTIVE   * 01200000
*                         UNARY NODES, THAT IS, NODES HAVING ONLY ONE * 01220000
*                          CHARACTER IN THE CHARACTER STRING.         * 01240000
NFLGNET  EQU   4         THIS NODE CONTAINS, IN THE 'NFCT' FIELD, THE * 01260000
*                         ADDRESS OF AN ALTERNATE NODE AT WHICH       * 01280000
*                          SCANNING MAY BE RESUMED IN THE EVENT THAT  * 01300000
*                           THE CHARACTER IS NOT FOUND IN THE NODE.   * 01320000
*********************************************************************** 01340000
*   THE SECOND PART OF THE NODE IS THE NODE CHARACTER STRING. THIS IS * 01360000
*    A STRING OF CHARACTERS FROM 1 TO 256 IN LENGTH. THE              * 01380000
*     LENGTH(MINUS ONE) IS GIVEN IN THE 'NLNG' FIELD.                 * 01400000
*********************************************************************** 01420000
         DS    0D                  PLACE ON FULL WORD BOUNDARY.         01440000
NCHAR    DC    C'AB ... Z'        SYMBOL USED FOR CH. OR ENTIRE STRING* 01460000
LND      EQU *                     SYMBOL USED TO DELIMIT THE END OF    01480000
*                                  THE SIMPLEST NON-NULL NODE FOR       01500000
*                                   THE PURPOSE OF OBTAINING CORE.      01520000
*********************************************************************** 01540000
BX0001X  EQU   1                                                        01560000
BX0010X  EQU   2                                                        01580000
BX0100X  EQU   4                                                        01600000
BX0101X  EQU   5                                                        01620000
BX0110X  EQU   6                                                        01640000
BX1000X  EQU   8                                                        01660000
BX1010X  EQU   10                                                       01680000
*********************************************************************** 01700000
*  CALLING SEQUENCE PROTOTYPE                                         * 01720000
*********************************************************************** 01740000
*        LA    1,PARAM                                                * 01760000
*        L     15,=(IEFDSLST)                                         * 01780000
*        BALR  14,15                                                  * 01800000
*                                                                     * 01820000
*PARAM   DC    A(TREE-8)           ADDRESS OF TREE TABLE              * 01840000
*        DC    A(FIELDBEG)         ADDRESS OF FIRST FIELD CHARACTER   * 01860000
*        DC    A(FIELDEND)         ADDRESS OF LAST FIELD CHARACTER    * 01880000
*  THE FOLLOWING TREE ADDRESS IS CHANGED BY CALLEE WHEN TREE RELOCATED* 01900000
*TREE    DC    X'02'               TREE INITIALLY A NULL NODE         * 01920000
*        DC    AL3(NULLNOD)                                           * 01940000
*                                                                     * 01960000
*NULLNOD DC    A(0)                AN EMPTY TREE CONSISTS OF A SINGLE * 01980000
*                                   'NULL' NODE AS SHOWN HERE.        * 02000000
*                                  AFTER FIRST ENTRY THIS NODE IS MOVED 02020000
*                                   AND NULL FLAG IN 'TREE' IS RESET  * 02040000
*********************************************************************** 02060000
R4       EQU   3                                                        02080000
R5       EQU   4                                                        02100000
R0       EQU   5                                                        02120000
R8       EQU   6                                                        02140000
R2       EQU   7                                                        02160000
R1       EQU   8                                                        02180000
R3       EQU   9                                                        02200000
R6       EQU   10                                                       02220000
BASE     EQU   12                                                       02240000
IEFDSTBL CSECT                                                          02260000
         USING IEFDSTBL,15        USE REG. 15 TEMPORARILY.              02280000
         SAVE  (2,12),T,*                                               02300000
         LM    R8,R2,0(1)                                               02320000
         L     R6+1,8(1)                                                02340000
         L     R0,TRTBL                                                 02360000
         LM    R3,R6,RIZ                                                02380000
         MVC   0(6,13),TRT             MOVE MODIFIABLE TRT TO WORK AREA 02400000
         BAL   BASE,L5             ENTER BODY OF PROGRAM AND SET BASE.  02420000
         DROP  15                                                       02440000
         USING *,BASE                                                   02460000
*                                                                       02480000
         USING NODE,R4             **                                   02500000
****************************  SCAN  LOOP  ***************************** 02520000
L3       SLR   1,R5                                                     02540000
         AR    1,1                                                      02560000
         AR    1,1                                                      02580000
         LA    R8,NODE(1)          SAVE POSITION IN PRIOR NODE.         02600000
         DROP  R4                  **                                   02620000
         USING NODE,R8             **                                   02640000
L13      BXH   R2,R6,L0            EXIT AT END OF INPUT FIELD.          02660000
L5       TM    NFLAG,NFLGNULL+NFLGCAT                                   02680000
         L     R4,LADLST                                                02700000
         DROP  R8                  **                                   02720000
         USING NODE,R4             **                                   02740000
         BC    BX0101X,L9          R4,R8 ARE MEANINGFUL AT THIS EXIT.   02760000
         IC    R1,0(R2)            TAKE CHARACTER FROM FIELD.           02780000
         STC   R1,5(13)        STORE CHARACTER IN DISPLACEMENT OF TRT.  02800000
         XI    5(13),X'FF'          COMPLEMENT THE CHARACTER FOR OFFSET 02820000
         L     R5,NCHSTR           LOAD ADDRESS OF CHARACTER STRING     02840000
         IC    R3,NLNG              AND ITS LENGTH.                     02860000
         EX    R3,0(13)                EXECUTE THE TRT INSTRUCTION      02880000
         BCR   BX0110X,BASE        BRANCH IF FIELD CHAR. FOUND IN NODE. 02900000
*********************************************************************** 02920000
*   THIS ADDS THE FIELD CHARACTER TO THE NODE                         * 02940000
*     INPUT IN REGISTERS                                              * 02960000
*              R1 - THE FIELD CHARACTER                               * 02980000
*              R3 - NODE CHARACTER TABLE LENGTH MINUS ONE             * 03000000
*              R4 - ADDRESS OF NODE TO RECEIVE THE CHARACTER          * 03020000
*              R5 - ADDRESS OF CHARACTER STRING TO BE EXTENDED.       * 03040000
*              R8 - POSITION IN PRIOR NODE ADDRESS LIST LINKING TO    * 03060000
*                    THIS NODE                                        * 03080000
*********************************************************************** 03100000
         LA    R3,1(R3)            INCREMENT CHARACTER STRING LENGTH    03120000
         STC   R3,NLNG              AND STORE.                          03140000
         TM    NLNG,X'07'          TEST IF CURRENT GOTTEN CORE IS FULL. 03160000
         BC    BX0101X,L1 (CORE IS FULL WHEN MULTIPLE OF 8 IS ATTAINED) 03180000
         LA    0,8(R3)             GET NEW BLOCK                        03200000
       GETMAIN R,LV=(0)             8 BYTES LARGER.                     03220000
         BCTR  R3,0                ADJUST.                              03240000
         EX    R3,MVCHARS          MOVE CHARACTER STRING.               03260000
         ST    1,NCHSTR            STORE NEW STRING ADDRESS IN NODE.    03280000
         LA    R3,1(R3)            ADJUST.                              03300000
         STC   R3,NLNG             STORE CHARACTER STRING LENGTH.       03320000
      FREEMAIN R,LV=(R3),A=(R5)    FREE OLD STRING CORE.                03340000
         L     R5,NCHSTR           NEW STRING ADDRESS IN R5.            03360000
L1       STC   R1,0(R3,R5)         STORE CHARACTER IN STRING            03380000
         AR    R3,R3               MULTIPLY R3                          03400000
         AR    R3,R3                BY FOUR.                            03420000
         TM    NLNG,X'01'          TEST IF CORE BLOCK FULL, AND         03440000
         BC    BX0101X,L8          BRANCH IF NOT FULL.                  03460000
         LA    0,16(R3)            LENGTH OF NEW BLOCK.                 03480000
         DROP  R4                  **                                   03500000
         USING NODE,R8             **                                   03520000
      GETMAIN  R,LV=(0)                                                 03540000
         ST    1,LADLST            LINK NEW NODE TO PRIOR NODE.         03560000
         EX    R3,MVNODE           MOVE NODE TO THE LARGER BLOCK.       03580000
         LA    0,8(R3)                                                  03600000
      FREEMAIN R,LV=(0),A=(R4)     FREE THE CORE OF OLD NODE.           03620000
         L     R4,LADLST                                                03640000
         DROP  R8                  **                                   03660000
         USING NODE,R4             **                                   03680000
L8       LA    R8,NODE(R3)         R8 SET TO SLOT CORRESPONDING TO      03700000
*                                   CHARACTER JUST INSERTED INTO NODE.  03720000
*                                                                       03740000
         DROP  R4                  **                                   03760000
         EJECT                                                          03780000
*********************************************************************** 03800000
*   THIS CREATES THE 'CONCATENATION' FORM NODE REPRESENTING CONSECUTIVE 03820000
*        UNIT NODES FOR EACH REMAINING CHARACTER IN THE FIELD. IN CASE* 03840000
*        ONLY ONE CHARACTER REMAINS A SINGLE UNIT NODE IS CREATED.    * 03860000
*   THEN A 'NULL' NODE IS CREATED AND IS LINKED TO THE PRIOR NODE.    * 03880000
*     INPUT IN REGISTERS                                              * 03900000
*              R2 - INDEX TO PRESENT POSITION IN FIELD STRING         * 03920000
*              R6 - EVEN-ODD REGISTER PAIR FOR INDEXING CONTROL (BXLE)* 03940000
*              R8 - ADDRESS OF POSITION WITHIN PRIOR NODE'S ADDRESS   * 03960000
*                    LIST FOR CHAINING FIRST NODE CREATED             * 03980000
*********************************************************************** 04000000
         USING NODE,R8             **                                   04020000
L18      SR    R3,R3               SET R3 TO ZERO.                      04040000
         BXH   R2,R6,L6            GET NEXT FIELD CHARACTER, IF ANY.    04060000
*                                   IF NOT, GO TO CREATE THE NULL NODE. 04080000
L4       SLR   R6+1,R2                                                  04100000
         LA    0,NCHAR-NODE+1(R6+1)                                     04120000
      GETMAIN  R,LV=(0)            FOR THE SINGLE ENTRY NODE.           04140000
         ST    1,LADLST            LINK NEW NODE TO PRIOR ONE.          04160000
         LTR   R6+1,R6+1           TEST IF LENGTH OF REMAINING FIELD    04180000
         BC    BX1000X,L10          IS ONE. IF SO, DON'T FLAG 'NFLGCAT' 04200000
         MVI   NFLAG,NFLGCAT                                            04220000
         DROP  R8                  **                                   04240000
         USING NODE,1              **                                   04260000
L10      LA    R8,NCHAR            FORM ADDRESS OF CHARACTER STRING.    04280000
         ST    R8,NCHSTR                                                04300000
         STC   R6+1,NLNG           STORE LENGTH OF FIELD.               04320000
         EX    R6+1,MVFIELD        MOVE FIELD INTO NODE.                04340000
         ST    R3,NFCT             STORE OLD FUNCTION OR ZERO, IF NEW.  04360000
         LR    R8,1                                                     04380000
         DROP  1                   **                                   04400000
         USING NODE,R8             **                                   04420000
         SR    R3,R3               SET R3 TO ZERO.                      04440000
L6       LA    0,NULG              LENGTH OF 'NULL' NODE.               04460000
      GETMAIN  R,LV=(0)            CREATE NULL NODE AND NORMAL RETURN.  04480000
         ST    1,LADLST            LINK TO PRIOR NODE.                  04500000
         MVI   NFLAG,NFLGNULL      FLAG NODE AS 'NULL'.                 04520000
         ST    R3,NFCT-NODE(1)     SET FIELD TO ZERO.                   04540000
L0       SR    15,15               NORMAL RETURN                        04560000
         LR    1,R8                                                     04580000
         RETURN (2,12),T,RC=(15)                                        04600000
MVFIELD  MVC   NCHAR-NODE(0,1),0(R2)                                    04620000
*********************************************************************** 04640000
*   THE INPUT FIELD HAS MATCHED DOWN TO A 'NULL' OR 'CONCATENATION'   * 04660000
*    FORM NODE. THIS TESTS WHICH OF THE TWO FORMS IT WAS.             * 04680000
*********************************************************************** 04700000
L9       TM    NFLAG,NFLGNULL      TEST IF NODE IS 'NULL'.              04720000
         BC    BX1000X,L2          BRANCH IF 'CONCATENATION' FORM.      04740000
         EJECT                                                          04760000
*********************************************************************** 04780000
*    THE INPUT FIELD HAS MATCHED DOWN TO A 'NULL' NODE. THIS SECTION  * 04800000
*     EXTRACTS THE NFCT FIELD AND THEN FREES THE NODE. CONTROL IS THEN* 04820000
*      GIVEN TO THE PREVIOUS ROUTINE WHICH WILL CONVERT THE REMAINDER * 04840000
*       OF THE FIELD TO TREE FORM, STORING THE DISPLACED NFCT VALUE   * 04860000
*        IN A NEW NODE.                                               * 04880000
*     INPUT IS THE SAME AS FOR PREVIOUS ROUTINE WITH THE ADDED INPUT- * 04900000
*              R4 - ADDRESS OF THE 'NULL' NODE                        * 04920000
*********************************************************************** 04940000
         USING NODE,R4             **                                   04960000
         DROP  R8                  **                                   04980000
         L     R3,NFCT             PUT FUNCTION INTO R3.                05000000
         LA    0,NULG              LENGTH OF 'NULL' NODE.               05020000
      FREEMAIN R,LV=(0),A=(R4)                                          05040000
         B     L4                                                       05060000
*********************************************************************** 05080000
*   THE INPUT HAS MATCHED DOWN TO A CONCATENATION FORM NODE. THIS     * 05100000
*    SECTION COMPARES THE LENGTHS OF THE FIELD REMAINING AND THE NODE * 05120000
*     CHARACTER STRING. IF THE FIELD REMAINING IS NOT LESS THE FIELDS * 05140000
*      ARE COMPARED AND IF THEY ARE EQUAL SCANNING RESUMES AT THE NEXT* 05160000
*       LOWER NODE. OTHERWISE, CONTROL GOES TO THE FOLLOWING SECTION.*  05180000
*********************************************************************** 05200000
L2       SLR   R6+1,R2             COMPUTE LENGTH OF REMAINING FIELD.   05220000
         IC    R3,NLNG                 LENGTH OF NODE CHARACTER STRING. 05240000
         L     R5,NCHSTR           ADDRESS OF STRING.                   05260000
         CLR   R6+1,R3             COMPARE THE TWO LENGTHS AND BRANCH   05280000
         BC    BX0100X,L11          IF FIELD REMAINING IS SHORTER.      05300000
         EX    R3,CLC              COMPARE STRING WITH FIELD.           05320000
         BC    BX0110X,L12         BRANCH IF UNEQUAL.                   05340000
         ALR   R6+1,R2             RESTORE R6&1 TO ORIGINAL VALUE,      05360000
         ALR   R2,R3                POSITION TO FIELD REMAINING,        05380000
         LR    R8,R4                STEP DOWN TO NEXT NODE,             05400000
         B     L13                  AND REENTER THE SCAN LOOP.          05420000
         EJECT                                                          05440000
*********************************************************************** 05460000
*   THE FIELD REMAINING IS LESS THAN THE NODE CHARACTER STRING IN     * 05480000
*    LENGTH OR IT IS UNEQUAL TO IT.                                     05500000
*********************************************************************** 05520000
L11      LR    R3,R6+1             R3 NOW HAS THE SHORTER LENGTH.       05540000
L12      ALR   R6+1,R2             RESTORE R6+1 TO ORIGINAL VALUE.      05560000
         ST    14,12(13)          SAVE RETURN ADDRESS.                  05580000
         LA    R1,WEND-WA+1(R3)    GET CORE FOR WORK AREA (BASED ON     05600000
      GETMAIN  R,LV=(R1)            LENGTH OF SHORTER STRING).          05620000
         ST 13,8(0,1)             SAVE ADDR OF HIGHER REG SAVE AREA     05640000
         LR    13,1                                                     05660000
         USING WA,13                                                    05680000
         ST    R1,WCT              SAVE LENGTH OF AREA FOR FREEMAIN.    05700000
         EX    R3,TMVC             MOVE SHORTER STRING TO WORK AREA.    05720000
         EX    R3,TXC              EXCLUSIVE OR FIELD WITH STRING.      05740000
         EX    R3,TTR        TRANSLATE '00' TO 'FF', ALL OTHERS TO '00' 05760000
         EX    R3,TTRT             TRANSLATE AND TEST TO FIRST '00'.    05780000
         BC    BX0110X,L19         IF REG-1 NOT SET BY TRT INSTRUCTION, 05800000
         LA    1,WEND+1(R3)         THEN SET IT TO END OF STRING +1.    05820000
L19      ST    R8,WPT              SET-UP PARAMETERS - TREE ADDRESS.    05840000
         ST    R5,WPFB                               - FIELD BEGINNING. 05860000
         IC    R3,NLNG                                                  05880000
         ALR   R5,R3                                                    05900000
         ST    R5,WPFE                               - FIELD ENDING.    05920000
         L     R1,LADLST           HOLD SUB-TREE ADDR. FOR RE-LINKING.  05940000
         LA    0,WEND              COMPUTE LENGTH OF EQUAL PORTION      05960000
         SLR   1,0                  OF STRINGS.                         05980000
         DROP  R4                  **                                   06000000
         USING NODE,R8             **                                   06020000
         BC    BX0010X,L14        BRANCH IF THERE IS NO EQUAL PORTION   06040000
         LR    0,1                 LENGTH FOR GETMAIN MACRO             06060000
         LR    R3,1                TEST IF LENGTH OF STRING             06080000
         BCT   R3,L15               IS ONE. IF SO, FLAG '00'.           06100000
         MVI   NFLAG,X'00'                                              06120000
L15   GETMAIN  R,LV=(0)            GET CORE FOR EQUAL STRING PORTION.   06140000
         DROP  R8                  **                                   06160000
         USING NODE,R4             **                                   06180000
         ST    1,NCHSTR            STORE ADDRESS OF STRING IN NODE.     06200000
         STC   R3,NLNG             STORE LENGTH OF STRING IN NODE.      06220000
         EX    R3,MV               MOVE STRING INTO CORE JUST OBTAINED. 06240000
         LR    R8,R4               STEP TO LOWER NODE AND INCREMENT     06260000
         ALR   R2,R3                PAST EQUAL PORTION OF INPUT FIELD.  06280000
         BXH   R2,R6,L16           BRANCH IF INPUT FIELD IS EXHAUSTED.  06300000
         DROP  R4                  **                                   06320000
         USING NODE,R8             **                                   06340000
         LA    0,NCHAR-NODE                                             06360000
      GETMAIN  R,LV=(0)            GET CORE FOR PART ONE OF A NODE, AND 06380000
         ST    1,LADLST             LINK TO PRIOR NODE.                 06400000
         SR    R3,R3               SET R3 TO ZERO.                      06420000
         ST    R3,NFCT-NODE(1)     CLEAR THE 'NFCT' FIELD IN THIS NODE. 06440000
         LR    R4,1                                                     06460000
L14      MVI   NFLAG,X'00'         '00' INDICATES A BRANCH TYPE NODE.   06480000
         DROP  R8                  **                                   06500000
         USING NODE,R4             **                                   06520000
      GETMAIN  R,LV=1              GET CORE FOR A SINGLE CHARACTER      06540000
         ST    1,NCHSTR             AND LINK TO PART ONE OF THE NODE.   06560000
         MVC   0(1,1),0(R2)        MOVE CHARACTER FROM INPUT FIELD.     06580000
         LR    R8,R4                                                    06600000
         LA    R5,L18              LOAD RETURN ADDR.                    06620000
*********************************************************************** 06640000
*   THIS SECTION RE-INSERTS THE ORIGINAL STRING AND THEN RETURNS TO   * 06660000
*    THE BODY OF THE PROGRAM TO PROCESS THE REMAINDER OF THE INPUT    * 06680000
*    FIELD, IF ANY. R5 HAS A PRESET RETURN ADDRESS.                   * 06700000
*********************************************************************** 06720000
         DROP  R4                  **                                   06740000
         USING NODE,R8             **                                   06760000
L17      LA    1,WPT              SET  UP PARAMETER LIST ADDRESS        06780000
         L     15,EP                ENTRY POINT,                        06800000
         BALR  14,15               AND RE-ENTER THIS PROGRAM.           06820000
         L     R3,8(1)             GET ADDRESS OF 'NULL' NODE.          06840000
         ST    R1,8(1)             RECONNECT THE SUB-TREE SAVED BEFORE. 06860000
         LA    0,NULG              FREE THE 'NULL' NODE.                06880000
      FREEMAIN R,LV=(0),A=(R3)                                          06900000
         L     1,WPFB              FREE THE OLD NODE CHARACTER STRING.  06920000
         L     R3,WPFE             COMPUTE LENGTH.                      06940000
         SLR   R3,1                                                     06960000
         LA    0,1(R3)                                                  06980000
      FREEMAIN R,LV=(0),A=(1)                                           07000000
         LR    1,13                                                     07020000
         L     0,WCT                                                    07040000
         L     13,WSV+8           RESTORE ADDR OF HIGHER REG SAVE AREA  07060000
      FREEMAIN R,LV=(0),A=(1)      FREE THE WORK AREA.                  07080000
         L     14,12(13)          RESTORE RETURN ADDRESS.               07100000
         BR    R5                  RETURN TO BODY OF PROGRAM.           07120000
L16      LA    0,NULG                                                   07140000
      GETMAIN  R,LV=(0)           GET CORE FOR A 'NULL' NODE, AND       07160000
         ST    1,LADLST           LINK TO PRIOR NODE                    07180000
         MVI   NFLAG,NFLGNULL     FLAG 'NULL'                           07200000
         SR    R3,R3              SET R3 TO ZERO                        07220000
         ST    R3,NFCT-NODE(1)    CLEAR THE NFCT FIELD  IN THIS NODE    07240000
         LA    R5,L0              LOAD RETURN ADDRESS                   07260000
         B     L17                                                      07280000
MV       MVC   0(0,1),0(R2)                                             07300000
TMVC     MVC   WEND,0(R5)                                               07320000
TXC      XC    WEND,0(R2)                                               07340000
TTR      TR    WEND,255(R0)                                             07360000
TTRT     TRT   WEND,255(R0)                                             07380000
CLC      CLC   0(,R2),0(R5)                                             07400000
TRT      TRT   0(,R5),0(R0)                                             07420000
MVCHARS  MVC   0(,1),0(R5)                                              07440000
MVNODE   MVC   0(8,1),0(R4)                                             07460000
EP       DC    A(IEFDSTBL)         USED FOR REENTRY TO THIS PROGRAM.    07480000
RIZ      DC    F'0'                R3                                   07500000
         DC    F'1'                R6                                   07520000
TRTBL    DC    V(IEFDSTRT)         ADDRESS OF TRANSLATE TABLE.          07540000
WA       DSECT                                                          07560000
WSV      DC    18F'0'              REGISTER SAVE AREA.                  07580000
WCT      DC    F'0'                SIZE OF WORK AREA.                   07600000
WPT      DC    A(*)                PARAMETER LIST - TREE ADDRESS.       07620000
WPFB     DC    A(*)                               - FIELD BEGINNING.    07640000
WPFE     DC    A(*)                               - FIELD ENDING.       07660000
WEND     EQU   *                   BEGINNING OF VARIABLE LENGTH STRING. 07680000
         END                                                            07700000
